data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43
  44 float Item_Customize()
  45 {
  46         if(self.spawnshieldtime)
  47                 return TRUE;
  48         if(self.weapons != (self.weapons & other.weapons))
  49         {
  50                 self.alpha = 0.5 + 0.5 * g_ghost_items; // halfway more alpha
  51                 return TRUE;
  52         }
  53         else
  54         {
  55                 if(g_ghost_items)
  56                 {
  57                         self.alpha = g_ghost_items;
  58                         return TRUE;
  59                 }
  60                 else
  61                         return FALSE;
  62         }
  63 }
  64
  65 void Item_Show (entity e, float mode)
  66 {
  67         e.effects &~= EF_ADDITIVE | EF_STARDUST | EF_FULLBRIGHT;
  68         if (mode > 0)
  69         {
  70                 // make the item look normal, and be touchable
  71                 e.model = e.mdl;
  72                 e.solid = SOLID_TRIGGER;
  73                 //e.colormod = '0 0 0';
  74                 e.alpha = 0;
  75                 e.customizeentityforclient = func_null;
  76
  77                 e.spawnshieldtime = 1;
  78         }
  79         else if (mode < 0)
  80         {
  81                 // hide the item completely
  82                 e.model = string_null;
  83                 e.solid = SOLID_NOT;
  84                 //e.colormod = '0 0 0';
  85                 e.alpha = 0;
  86                 e.customizeentityforclient = func_null;
  87
  88                 e.spawnshieldtime = 1;
  89         }
  90         else if((e.flags & FL_WEAPON) && (g_weapon_stay == 3))
  91         {
  92                 // make the item translucent green and not touchable
  93                 e.model = e.mdl;
  94                 e.solid = SOLID_TRIGGER; // can STILL be picked up!
  95                 e.effects |= EF_STARDUST;
  96                 //e.colormod = '0.2 1 0.2';
  97                 //e.alpha = 0.5; // will be overridden by CEFC though...
  98                 e.customizeentityforclient = Item_Customize;
  99
 100                 e.spawnshieldtime = 0; // field indicates whether picking it up may give you anything other than the weapon
 101         }
 102         else if(g_ghost_items)
 103         {
 104                 // make the item translucent green and not touchable
 105                 e.model = e.mdl;
 106                 e.solid = SOLID_NOT;
 107                 //e.colormod = '0.2 1 0.2';
 108                 e.alpha = g_ghost_items;
 109                 e.customizeentityforclient = func_null;
 110
 111                 e.spawnshieldtime = 1;
 112         }
 113         else
 114         {
 115                 // hide the item completely
 116                 e.model = string_null;
 117                 e.solid = SOLID_NOT;
 118                 //e.colormod = '0 0 0';
 119                 e.alpha = 0;
 120                 e.customizeentityforclient = func_null;
 121
 122                 e.spawnshieldtime = 1;
 123         }
 124
 125         if (e.strength_finished || e.invincible_finished)
 126                 e.effects |= EF_ADDITIVE | EF_FULLBRIGHT;
 127         if (cvar("g_fullbrightitems"))
 128                 e.effects |= EF_FULLBRIGHT;
 129
 130         // relink entity (because solid may have changed)
 131         setorigin(e, e.origin);
 132 }
 133
 134 void Item_Respawn (void)
 135 {
 136         Item_Show(self, 1);
 137         if(!g_minstagib && self.items == IT_STRENGTH)
 138                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
 139         else if(!g_minstagib && self.items == IT_INVINCIBLE)
 140                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
 141         else
 142                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
 143         setorigin (self, self.origin);
 144
 145         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
 146         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
 147 }
 148
 149 void Item_RespawnCountdown (void)
 150 {
 151         if(self.count >= ITEM_RESPAWN_TICKS)
 152         {
 153                 if(self.waypointsprite_attached)
 154                         WaypointSprite_Kill(self.waypointsprite_attached);
 155                 Item_Respawn();
 156         }
 157         else
 158         {
 159                 self.nextthink = time + 1;
 160                 self.count += 1;
 161                 if(self.count == 1)
 162                 {
 163                         string name;
 164                         vector rgb;
 165                         name = string_null;
 166                         if(g_minstagib)
 167                         {
 168                                 switch(self.items)
 169                                 {
 170                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
 171                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
 172                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
 173                                 }
 174                         }
 175                         else
 176                         {
 177                                 switch(self.items)
 178                                 {
 179                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
 180                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
 181                                 }
 182                         }
 183                         switch(self.items)
 184                         {
 185                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
 186                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
 187                         }
 188                         if(name)
 189                         {
 190                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, TRUE);
 191                                 if(self.waypointsprite_attached)
 192                                 {
 193                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 194                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 195                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 196                                 }
 197                         }
 198                 }
 199                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 200                 if(self.waypointsprite_attached)
 201                 {
 202                         WaypointSprite_Ping(self.waypointsprite_attached);
 203                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 204                 }
 205         }
 206 }
 207
 208 void Item_ScheduleRespawnIn(entity e, float t)
 209 {
 210         if(e.flags & FL_POWERUP)
 211         {
 212                 e.think = Item_RespawnCountdown;
 213                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 214                 e.count = 0;
 215         }
 216         else
 217         {
 218                 e.think = Item_Respawn;
 219                 e.nextthink = time + t;
 220         }
 221 }
 222
 223 void Item_ScheduleRespawn(entity e)
 224 {
 225         Item_Show(e, 0);
 226         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 227 }
 228
 229 void Item_ScheduleInitialRespawn(entity e)
 230 {
 231         Item_Show(e, 0);
 232         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 233 }
 234
 235 float Item_GiveTo(entity item, entity player)
 236 {
 237         float _switchweapon;
 238         float pickedup;
 239         float it;
 240         float i;
 241         entity e;
 242
 243         // if nothing happens to player, just return without taking the item
 244         pickedup = FALSE;
 245         _switchweapon = FALSE;
 246
 247         if (g_minstagib)
 248         {
 249                 if(item.spawnshieldtime)
 250                 {
 251                         if (item.ammo_fuel)
 252                         if (player.ammo_fuel < g_pickup_fuel_max)
 253                         {
 254                                 pickedup = TRUE;
 255                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 256                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 257                         }
 258                         if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 259                         {
 260                                 pickedup = TRUE;
 261                                 player.items |= it;
 262                                 sprint (player, strcat("You got the ^2", item.netname, "\n"));
 263                         }
 264
 265                         _switchweapon = TRUE;
 266                         if (item.ammo_cells)
 267                         {
 268                                 pickedup = TRUE;
 269                                 // play some cool sounds ;)
 270                                 centerprint(player, "\n");
 271                                 if (clienttype(player) == CLIENTTYPE_REAL)
 272                                 {
 273                                         if(player.health <= 5)
 274                                                 play2(player, "announcer/robotic/lastsecond.wav");
 275                                         else if(player.health < 50)
 276                                                 play2(player, "announcer/robotic/narrowly.wav");
 277                                 }
 278                                 // sound not available
 279                                 // else if(item.items == IT_CELLS)
 280                                 //      play2(player, "announce/robotic/ammo.wav");
 281
 282                                 if (item.weapons & WEPBIT_MINSTANEX)
 283                                         W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 284                                 if (item.ammo_cells)
 285                                         player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 286                                 player.health = 100;
 287                         }
 288
 289                         // extralife powerup
 290                         if (item.max_health)
 291                         {
 292                                 pickedup = TRUE;
 293                                 // sound not available
 294                                 // play2(player, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.wav");
 295                                 player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 296                                 sprint(player, "^3You picked up some extra lives\n");
 297                         }
 298
 299                         // invis powerup
 300                         if (item.strength_finished)
 301                         {
 302                                 pickedup = TRUE;
 303                                 // sound not available
 304                                 // play2(player, "announce/robotic/invisible.wav");
 305                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 306                         }
 307
 308                         // speed powerup
 309                         if (item.invincible_finished)
 310                         {
 311                                 pickedup = TRUE;
 312                                 // sound not available
 313                                 // play2(player, "announce/robotic/speed.wav");
 314                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 315                         }
 316
 317                         if (item.ammo_fuel)
 318                         if (player.ammo_fuel < g_pickup_fuel_max)
 319                         {
 320                                 pickedup = TRUE;
 321                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 322                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 323                         }
 324                 }
 325         }
 326         else
 327         {
 328                 if (g_weapon_stay == 1)
 329                 if not(item.flags & FL_NO_WEAPON_STAY)
 330                 if (item.flags & FL_WEAPON)
 331                 {
 332                         if(item.classname == "droppedweapon")
 333                         {
 334                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 335                                         goto skip;
 336                         }
 337                         else
 338                         {
 339                                 if (player.weapons & item.weapons)
 340                                         goto skip;
 341                         }
 342                 }
 343
 344                 // in case the player has autoswitch enabled do the following:
 345                 // if the player is using their best weapon before items are given, they
 346                 // probably want to switch to an even better weapon after items are given
 347                 if (player.autoswitch)
 348                 if (player.switchweapon == w_getbestweapon(player))
 349                         _switchweapon = TRUE;
 350
 351                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 352                         _switchweapon = TRUE;
 353
 354                 if(item.spawnshieldtime)
 355                 {
 356                         if (item.ammo_shells)
 357                         if (player.ammo_shells < g_pickup_shells_max)
 358                         {
 359                                 pickedup = TRUE;
 360                                 player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 361                         }
 362                         if (item.ammo_nails)
 363                         if (player.ammo_nails < g_pickup_nails_max)
 364                         {
 365                                 pickedup = TRUE;
 366                                 player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 367                         }
 368                         if (item.ammo_rockets)
 369                         if (player.ammo_rockets < g_pickup_rockets_max)
 370                         {
 371                                 pickedup = TRUE;
 372                                 player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 373                         }
 374                         if (item.ammo_cells)
 375                         if (player.ammo_cells < g_pickup_cells_max)
 376                         {
 377                                 pickedup = TRUE;
 378                                 player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 379                         }
 380                         if (item.ammo_fuel)
 381                         if (player.ammo_fuel < g_pickup_fuel_max)
 382                         {
 383                                 pickedup = TRUE;
 384                                 player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 385                                 player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 386                         }
 387                 }
 388
 389                 if (item.flags & FL_WEAPON)
 390                 if ((it = item.weapons - (item.weapons & player.weapons)))
 391                 {
 392                         pickedup = TRUE;
 393                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 394                         {
 395                                 e = get_weaponinfo(i);
 396                                 if(it & e.weapons)
 397                                         W_GiveWeapon (player, e.weapon, item.netname);
 398                         }
 399                 }
 400
 401                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 402                 {
 403                         pickedup = TRUE;
 404                         player.items |= it;
 405                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 406                 }
 407
 408                 if(item.spawnshieldtime)
 409                 {
 410                         if (item.strength_finished)
 411                         {
 412                                 pickedup = TRUE;
 413                                 player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 414                         }
 415                         if (item.invincible_finished)
 416                         {
 417                                 pickedup = TRUE;
 418                                 player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 419                         }
 420                         //if (item.speed_finished)
 421                         //{
 422                         //      pickedup = TRUE;
 423                         //      player.speed_finished = max(player.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 424                         //}
 425                         //if (item.slowmo_finished)
 426                         //{
 427                         //      pickedup = TRUE;
 428                         //      player.slowmo_finished = max(player.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 429                         //}
 430
 431                         if (item.health)
 432                         if (player.health < item.max_health)
 433                         {
 434                                 pickedup = TRUE;
 435                                 player.health = min(player.health + item.health, item.max_health);
 436                                 player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 437                         }
 438                         if (item.armorvalue)
 439                         if (player.armorvalue < item.max_armorvalue)
 440                         {
 441                                 pickedup = TRUE;
 442                                 player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 443                                 player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 444                         }
 445                 }
 446         }
 447
 448 :skip
 449         // always eat teamed entities
 450         if(item.team)
 451                 pickedup = TRUE;
 452
 453         if (!pickedup)
 454                 return 0;
 455
 456         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 457         if (_switchweapon)
 458                 if (player.switchweapon != w_getbestweapon(player))
 459                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 460
 461         return 1;
 462 }
 463
 464 void Item_Touch (void)
 465 {
 466         entity e, head;
 467
 468         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 469         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 470         {
 471                 remove(self);
 472                 return;
 473         }
 474         if (other.classname != "player")
 475                 return;
 476         if (other.deadflag)
 477                 return;
 478         if (self.solid != SOLID_TRIGGER)
 479                 return;
 480         if (self.owner == other)
 481                 return;
 482
 483         if(!Item_GiveTo(self, other))
 484                 return;
 485
 486         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 487
 488         if (self.classname == "droppedweapon")
 489                 remove (self);
 490         else if not(self.spawnshieldtime)
 491                 return;
 492         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && (g_weapon_stay == 1 || g_weapon_stay == 2))
 493                 return;
 494         else
 495         {
 496                 if(self.team)
 497                 {
 498                         RandomSelection_Init();
 499                         for(head = world; (head = findfloat(head, team, self.team)); )
 500                         {
 501                                 if(head.flags & FL_ITEM)
 502                                 {
 503                                         Item_Show(head, -1);
 504                                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 505                                 }
 506                         }
 507                         e = RandomSelection_chosen_ent;
 508                 }
 509                 else
 510                         e = self;
 511                 Item_ScheduleRespawn(e);
 512         }
 513 }
 514
 515 void Item_FindTeam()
 516 {
 517         entity head, e;
 518
 519         if(self.effects & EF_NODRAW)
 520         {
 521                 // marker for item team search
 522                 dprint("Initializing item team ", ftos(self.team), "\n");
 523                 RandomSelection_Init();
 524                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 525                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 526                 e = RandomSelection_chosen_ent;
 527                 e.state = 0;
 528                 Item_Show(e, 1);
 529
 530                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 531                 {
 532                         if(head != e)
 533                         {
 534                                 // make it a non-spawned item
 535                                 Item_Show(head, -1);
 536                                 head.state = 1; // state 1 = initially hidden item
 537                         }
 538                         head.effects &~= EF_NODRAW;
 539                 }
 540
 541                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 542                         Item_ScheduleInitialRespawn(e);
 543         }
 544 }
 545
 546 void Item_Reset()
 547 {
 548         Item_Show(self, !self.state);
 549         setorigin (self, self.origin);
 550         self.think = SUB_Null;
 551         self.nextthink = 0;
 552
 553         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 554                 Item_ScheduleInitialRespawn(self);
 555 }
 556
 557 // Savage: used for item garbage-collection
 558 // TODO: perhaps nice special effect?
 559 void RemoveItem(void)
 560 {
 561         remove(self);
 562 }
 563
 564 // pickup evaluation functions
 565 // these functions decide how desirable an item is to the bots
 566
 567 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 568
 569 float weapon_pickupevalfunc(entity player, entity item)
 570 {
 571         float c, i, j, position;
 572
 573         // See if I have it already
 574         if(player.weapons & item.weapons == item.weapons)
 575         {
 576                 // If I can pick it up
 577                 if(g_weapon_stay == 1 || g_weapon_stay == 2 || !item.spawnshieldtime)
 578                         c = 0;
 579                 else if(player.ammo_cells || player.ammo_shells || player.ammo_nails || player.ammo_rockets)
 580                 {
 581                         // Skilled bots will grab more
 582                         c = bound(0, skill / 10, 1) * 0.5;
 583                 }
 584                 else
 585                         c = 0;
 586         }
 587         else
 588                 c = 1;
 589
 590         // If custom weapon priorities for bots is enabled rate most wanted weapons higher
 591         if( bot_custom_weapon && c )
 592         {
 593                 for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 594                 {
 595                         // Find weapon
 596                         if( (get_weaponinfo(i)).weapons & item.weapons  != item.weapons )
 597                                 continue;
 598
 599                         // Find the highest position on any range
 600                         position = -1;
 601                         for(j = 0; j < WEP_LAST ; ++j){
 602                                 if(
 603                                                 bot_weapons_far[j] == i ||
 604                                                 bot_weapons_mid[j] == i ||
 605                                                 bot_weapons_close[j] == i
 606                                   )
 607                                 {
 608                                         position = j;
 609                                         break;
 610                                 }
 611                         }
 612
 613                         // Rate it
 614                         if (position >= 0 )
 615                         {
 616                                 position = WEP_LAST - position;
 617                                 // item.bot_pickupbasevalue is overwritten here
 618                                 return (BOT_PICKUP_RATING_LOW + ( (BOT_PICKUP_RATING_HIGH - BOT_PICKUP_RATING_LOW) * (position / WEP_LAST ))) * c;
 619                         }
 620                 }
 621         }
 622
 623         return item.bot_pickupbasevalue * c;
 624 };
 625
 626 float commodity_pickupevalfunc(entity player, entity item)
 627 {
 628         float c, i, need_shells, need_nails, need_rockets, need_cells;
 629         entity wi;
 630         c = 0;
 631
 632         // Detect needed ammo
 633         for(i = WEP_FIRST; i < WEP_LAST ; ++i)
 634         {
 635                 wi = get_weaponinfo(i);
 636
 637                 if not(wi.weapons & player.weapons)
 638                         continue;
 639
 640                 if(wi.items & IT_SHELLS)
 641                         need_shells = TRUE;
 642                 else if(wi.items & IT_NAILS)
 643                         need_nails = TRUE;
 644                 else if(wi.items & IT_ROCKETS)
 645                         need_rockets = TRUE;
 646                 else if(wi.items & IT_CELLS)
 647                         need_cells = TRUE;
 648         }
 649
 650         // TODO: figure out if the player even has the weapon this ammo is for?
 651         // may not affect strategy much though...
 652         // find out how much more ammo/armor/health the player can hold
 653         if (need_shells)
 654         if (item.ammo_shells)
 655         if (player.ammo_shells < g_pickup_shells_max)
 656                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 657         if (need_nails)
 658         if (item.ammo_nails)
 659         if (player.ammo_nails < g_pickup_nails_max)
 660                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 661         if (need_rockets)
 662         if (item.ammo_rockets)
 663         if (player.ammo_rockets < g_pickup_rockets_max)
 664                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 665         if (need_cells)
 666         if (item.ammo_cells)
 667         if (player.ammo_cells < g_pickup_cells_max)
 668                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 669         if (item.armorvalue)
 670         if (player.armorvalue < item.max_armorvalue)
 671                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 672         if (item.health)
 673         if (player.health < item.max_health)
 674                 c = c + max(0, 1 - player.health / item.max_health);
 675
 676         return item.bot_pickupbasevalue * c;
 677 };
 678
 679
 680 .float is_item;
 681 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 682 {
 683         startitem_failed = FALSE;
 684
 685         // is it a dropped weapon?
 686         if (self.classname == "droppedweapon")
 687         {
 688                 self.reset = SUB_Remove;
 689                 // it's a dropped weapon
 690                 self.movetype = MOVETYPE_TOSS;
 691                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 692                 self.think = RemoveItem;
 693                 self.nextthink = time + 60;
 694                 // don't drop if in a NODROP zone (such as lava)
 695                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 696                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 697                 {
 698                         startitem_failed = TRUE;
 699                         remove(self);
 700                         return;
 701                 }
 702         }
 703         else
 704         {
 705                 self.reset = Item_Reset;
 706                 // it's a level item
 707                 if(self.spawnflags & 1)
 708                         self.noalign = 1;
 709                 if (self.noalign)
 710                         self.movetype = MOVETYPE_NONE;
 711                 else
 712                         self.movetype = MOVETYPE_TOSS;
 713                 // do item filtering according to game mode and other things
 714                 if (!self.noalign)
 715                 {
 716                         // first nudge it off the floor a little bit to avoid math errors
 717                         setorigin(self, self.origin + '0 0 1');
 718                         // set item size before we spawn a spawnfunc_waypoint
 719                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 720                                 setsize (self, '-16 -16 0', '16 16 48');
 721                         else
 722                                 setsize (self, '-16 -16 0', '16 16 32');
 723                         // note droptofloor returns FALSE if stuck/or would fall too far
 724                         droptofloor();
 725                         waypoint_spawnforitem(self);
 726                 }
 727
 728                 if(teams_matter)
 729                 {
 730                         if(self.notteam)
 731                         {
 732                                 print("removed non-teamplay ", self.classname, "\n");
 733                                 startitem_failed = TRUE;
 734                                 remove (self);
 735                                 return;
 736                         }
 737                 }
 738                 else
 739                 {
 740                         if(self.notfree)
 741                         {
 742                                 print("removed non-FFA ", self.classname, "\n");
 743                                 startitem_failed = TRUE;
 744                                 remove (self);
 745                                 return;
 746                         }
 747                 }
 748
 749                 if(self.notq3a)
 750                 {
 751                         // We aren't TA or something like that, so we keep the Q3A entities
 752                         print("removed non-Q3A ", self.classname, "\n");
 753                         startitem_failed = TRUE;
 754                         remove (self);
 755                         return;
 756                 }
 757
 758                 /*
 759                  * can't do it that way, as it would break maps
 760                  * TODO make a target_give like entity another way, that perhaps has
 761                  * the weapon name in a key
 762                 if(self.targetname)
 763                 {
 764                         // target_give not yet supported; maybe later
 765                         print("removed targeted ", self.classname, "\n");
 766                         startitem_failed = TRUE;
 767                         remove (self);
 768                         return;
 769                 }
 770                 */
 771
 772                 if(cvar("spawn_debug") >= 2)
 773                 {
 774                         entity otheritem;
 775                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 776                         {
 777                                 if(otheritem.is_item)
 778                                 {
 779                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 780                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 781                                         error("Mapper sucks.");
 782                                 }
 783                         }
 784                         self.is_item = TRUE;
 785                 }
 786
 787                 weaponsInMap |= weaponid;
 788
 789                 if(g_lms)
 790                 {
 791                         startitem_failed = TRUE;
 792                         remove(self);
 793                         return;
 794                 }
 795                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 796                 {
 797                         startitem_failed = TRUE;
 798                         remove(self);
 799                         return;
 800                 }
 801                 else if (g_minstagib)
 802                 {
 803                         // don't remove dropped items and powerups
 804                         if (self.classname != "minstagib")
 805                         {
 806                                 startitem_failed = TRUE;
 807                                 remove (self);
 808                                 return;
 809                         }
 810                 }
 811                 else if (g_nixnex)
 812                 {
 813                         local float rm;
 814
 815                         rm = 1;
 816                         switch (itemid)
 817                         {
 818                                 case IT_HEALTH:
 819                                 case IT_5HP:
 820                                 case IT_25HP:
 821                                 case IT_ARMOR:
 822                                 case IT_ARMOR_SHARD:
 823                                         if (cvar("g_nixnex_with_healtharmor"))
 824                                                 rm = 0;
 825                                         break;
 826                                 case IT_STRENGTH:
 827                                 case IT_INVINCIBLE:
 828                                         if (cvar("g_nixnex_with_powerups"))
 829                                                 rm = 0;
 830                                         break;
 831                         }
 832
 833                         if(rm)
 834                         {
 835                                 startitem_failed = TRUE;
 836                                 remove (self);
 837                                 return;
 838                         }
 839                 }
 840                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 841                 {
 842                         startitem_failed = TRUE;
 843                         remove (self);
 844                         return;
 845                 }
 846
 847                 precache_model (itemmodel);
 848                 precache_sound (pickupsound);
 849                 precache_sound ("misc/itemrespawn.wav");
 850                 precache_sound ("misc/itemrespawncountdown.wav");
 851
 852                 if(itemid == IT_STRENGTH)
 853                         precache_sound ("misc/strength_respawn.wav");
 854                 if(itemid == IT_INVINCIBLE)
 855                         precache_sound ("misc/shield_respawn.wav");
 856
 857                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 858                         self.target = "###item###"; // for finding the nearest item using find()
 859         }
 860
 861         self.bot_pickup = TRUE;
 862         self.bot_pickupevalfunc = pickupevalfunc;
 863         self.bot_pickupbasevalue = pickupbasevalue;
 864         self.mdl = itemmodel;
 865         self.item_pickupsound = pickupsound;
 866         // let mappers override respawntime
 867         if(!self.respawntime) // both set
 868         {
 869                 self.respawntime = defaultrespawntime;
 870                 self.respawntimejitter = defaultrespawntimejitter;
 871         }
 872         self.netname = itemname;
 873         self.items = itemid;
 874         self.weapons = weaponid;
 875         self.flags = FL_ITEM | itemflags;
 876         self.touch = Item_Touch;
 877         setmodel (self, self.mdl); // precision set below
 878         self.effects |= EF_LOWPRECISION;
 879         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 880                 setsize (self, '-16 -16 0', '16 16 48');
 881         else
 882                 setsize (self, '-16 -16 0', '16 16 32');
 883         if(itemflags & FL_WEAPON)
 884                 self.modelflags |= MF_ROTATE;
 885
 886         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 887         if (itemflags & FL_WEAPON)
 888         {
 889                 // neutral team color for pickup weapons
 890                 self.colormap = 1024; // color shirt=0 pants=0 grey
 891         }
 892
 893         Item_Show(self, 1);
 894         self.state = 0;
 895         if(self.team)
 896         {
 897                 if(!self.cnt)
 898                         self.cnt = 1; // item probability weight
 899                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 900                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 901         }
 902         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 903                 Item_ScheduleInitialRespawn(self);
 904 }
 905
 906 /* replace items in minstagib
 907  * IT_STRENGTH   = invisibility
 908  * IT_NAILS      = extra lives
 909  * IT_INVINCIBLE = speed
 910  */
 911 void minstagib_items (float itemid)
 912 {
 913         // we don't want to replace dropped weapons ;)
 914         if (self.classname == "droppedweapon")
 915         {
 916                 self.ammo_cells = 25;
 917                 StartItem ("models/weapons/g_nex.md3",
 918                         "weapons/weaponpickup.wav", 15, 0,
 919                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 920                 return;
 921         }
 922
 923         local float rnd;
 924         self.classname = "minstagib";
 925
 926         // replace rocket launchers and nex guns with ammo cells
 927         if (itemid == IT_CELLS)
 928         {
 929                 self.ammo_cells = 1;
 930                 StartItem ("models/items/a_cells.md3",
 931                         "misc/itempickup.wav", 45, 0,
 932                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 933                 return;
 934         }
 935
 936         // randomize
 937         rnd = random() * 3;
 938         if (rnd <= 1)
 939                 itemid = IT_STRENGTH;
 940         else if (rnd <= 2)
 941                 itemid = IT_NAILS;
 942         else
 943                 itemid = IT_INVINCIBLE;
 944
 945         // replace with invis
 946         if (itemid == IT_STRENGTH)
 947         {
 948                 self.strength_finished = 30;
 949                 StartItem ("models/items/g_strength.md3",
 950                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 951                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 952         }
 953         // replace with extra lives
 954         if (itemid == IT_NAILS)
 955         {
 956                 self.max_health = 1;
 957                 StartItem ("models/items/g_h100.md3",
 958                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 959                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 960
 961         }
 962         // replace with speed
 963         if (itemid == IT_INVINCIBLE)
 964         {
 965                 self.invincible_finished = 30;
 966                 StartItem ("models/items/g_invincible.md3",
 967                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 968                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 969         }
 970
 971 }
 972
 973 float minst_no_auto_cells;
 974 void minst_remove_item (void) {
 975         if(minst_no_auto_cells)
 976                 remove(self);
 977 }
 978
 979 float weaponswapping;
 980 float internalteam;
 981
 982 void weapon_defaultspawnfunc(float wpn)
 983 {
 984         entity e;
 985         float t;
 986         var .float ammofield;
 987         string s;
 988         entity oldself;
 989         float i, j;
 990
 991         // set the respawntime in advance (so replaced weapons can copy it)
 992
 993         if(!self.respawntime)
 994         {
 995                 e = get_weaponinfo(wpn);
 996                 if(e.items == IT_SUPERWEAPON)
 997                 {
 998                         self.respawntime = g_pickup_respawntime_powerup;
 999                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
1000                 }
1001                 else
1002                 {
1003                         self.respawntime = g_pickup_respawntime_weapon;
1004                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
1005                 }
1006         }
1007
1008         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
1009         {
1010                 e = get_weaponinfo(wpn);
1011                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
1012                 if(s == "0")
1013                 {
1014                         remove(self);
1015                         startitem_failed = TRUE;
1016                         return;
1017                 }
1018                 t = tokenize_console(s);
1019                 if(t >= 2)
1020                 {
1021                         self.team = --internalteam;
1022                         oldself = self;
1023                         for(i = 1; i < t; ++i)
1024                         {
1025                                 s = argv(i);
1026                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1027                                 {
1028                                         e = get_weaponinfo(j);
1029                                         if(e.netname == s)
1030                                         {
1031                                                 self = spawn();
1032                                                 copyentity(oldself, self);
1033                                                 self.classname = "replacedweapon";
1034                                                 weapon_defaultspawnfunc(j);
1035                                                 break;
1036                                         }
1037                                 }
1038                                 if(j > WEP_LAST)
1039                                 {
1040                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1041                                 }
1042                         }
1043                         self = oldself;
1044                 }
1045                 if(t >= 1)
1046                 {
1047                         s = argv(0);
1048                         wpn = 0;
1049                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1050                         {
1051                                 e = get_weaponinfo(j);
1052                                 if(e.netname == s)
1053                                 {
1054                                         wpn = j;
1055                                         break;
1056                                 }
1057                         }
1058                         if(j > WEP_LAST)
1059                         {
1060                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
1061                         }
1062                 }
1063                 if(wpn == 0)
1064                 {
1065                         remove(self);
1066                         startitem_failed = TRUE;
1067                         return;
1068                 }
1069         }
1070
1071         e = get_weaponinfo(wpn);
1072
1073         if(e.items && e.items != IT_SUPERWEAPON)
1074         {
1075                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
1076                 {
1077                         if(e.items & j)
1078                         {
1079                                 ammofield = Item_CounterField(j);
1080                                 if(!self.ammofield)
1081                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
1082                         }
1083                 }
1084         }
1085         else
1086         {
1087                 self.flags |= FL_NO_WEAPON_STAY;
1088         }
1089
1090         // weapon stay isn't supported for teamed weapons
1091         if(self.team)
1092                 self.flags |= FL_NO_WEAPON_STAY;
1093
1094         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
1095         {
1096                 self.ammo_shells = 0;
1097                 self.ammo_nails = 0;
1098                 self.ammo_cells = 0;
1099                 self.ammo_rockets = 0;
1100                 // weapon stay 2: don't use ammo on weapon pickups; instead
1101                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
1102         }
1103
1104         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
1105         if (self.modelindex) // don't precache if self was removed
1106                 weapon_action(e.weapon, WR_PRECACHE);
1107 }
1108
1109 void spawnfunc_weapon_shotgun (void);
1110 void spawnfunc_weapon_uzi (void) {
1111         if(q3acompat_machineshotgunswap)
1112         if(self.classname != "droppedweapon")
1113         {
1114                 weapon_defaultspawnfunc(WEP_SHOTGUN);
1115                 return;
1116         }
1117         weapon_defaultspawnfunc(WEP_UZI);
1118 }
1119
1120 void spawnfunc_weapon_shotgun (void) {
1121         if(q3acompat_machineshotgunswap)
1122         if(self.classname != "droppedweapon")
1123         {
1124                 weapon_defaultspawnfunc(WEP_UZI);
1125                 return;
1126         }
1127         weapon_defaultspawnfunc(WEP_SHOTGUN);
1128 }
1129
1130 void spawnfunc_weapon_nex (void)
1131 {
1132         if (g_minstagib)
1133         {
1134                 minstagib_items(IT_CELLS);
1135                 self.think = minst_remove_item;
1136                 self.nextthink = time;
1137                 return;
1138         }
1139         weapon_defaultspawnfunc(WEP_NEX);
1140 }
1141
1142 void spawnfunc_weapon_minstanex (void)
1143 {
1144         if (g_minstagib)
1145         {
1146                 minstagib_items(IT_CELLS);
1147                 self.think = minst_remove_item;
1148                 self.nextthink = time;
1149                 return;
1150         }
1151         weapon_defaultspawnfunc(WEP_MINSTANEX);
1152 }
1153
1154 void spawnfunc_weapon_rocketlauncher (void)
1155 {
1156         if (g_minstagib)
1157         {
1158                 minstagib_items(IT_CELLS);
1159                 self.think = minst_remove_item;
1160                 self.nextthink = time;
1161                 return;
1162         }
1163         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1164 }
1165
1166 void spawnfunc_item_rockets (void) {
1167         if(!self.ammo_rockets)
1168                 self.ammo_rockets = g_pickup_rockets;
1169         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1170 }
1171
1172 void spawnfunc_item_shells (void);
1173 void spawnfunc_item_bullets (void) {
1174         if(!weaponswapping)
1175         if(q3acompat_machineshotgunswap)
1176         if(self.classname != "droppedweapon")
1177         {
1178                 weaponswapping = TRUE;
1179                 spawnfunc_item_shells();
1180                 weaponswapping = FALSE;
1181                 return;
1182         }
1183
1184         if(!self.ammo_nails)
1185                 self.ammo_nails = g_pickup_nails;
1186         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1187 }
1188
1189 void spawnfunc_item_cells (void) {
1190         if(!self.ammo_cells)
1191                 self.ammo_cells = g_pickup_cells;
1192         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1193 }
1194
1195 void spawnfunc_item_shells (void) {
1196         if(!weaponswapping)
1197         if(q3acompat_machineshotgunswap)
1198         if(self.classname != "droppedweapon")
1199         {
1200                 weaponswapping = TRUE;
1201                 spawnfunc_item_bullets();
1202                 weaponswapping = FALSE;
1203                 return;
1204         }
1205
1206         if(!self.ammo_shells)
1207                 self.ammo_shells = g_pickup_shells;
1208         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1209 }
1210
1211 void spawnfunc_item_armor_small (void) {
1212         if(!self.armorvalue)
1213                 self.armorvalue = g_pickup_armorsmall;
1214         if(!self.max_armorvalue)
1215                 self.max_armorvalue = g_pickup_armorsmall_max;
1216         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1217 }
1218
1219 void spawnfunc_item_armor_medium (void) {
1220         if(!self.armorvalue)
1221                 self.armorvalue = g_pickup_armormedium;
1222         if(!self.max_armorvalue)
1223                 self.max_armorvalue = g_pickup_armormedium_max;
1224         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1225 }
1226
1227 void spawnfunc_item_armor_big (void) {
1228         if(!self.armorvalue)
1229                 self.armorvalue = g_pickup_armorbig;
1230         if(!self.max_armorvalue)
1231                 self.max_armorvalue = g_pickup_armorbig_max;
1232         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1233 }
1234
1235 void spawnfunc_item_armor_large (void) {
1236         if(!self.armorvalue)
1237                 self.armorvalue = g_pickup_armorlarge;
1238         if(!self.max_armorvalue)
1239                 self.max_armorvalue = g_pickup_armorlarge_max;
1240         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1241 }
1242
1243 void spawnfunc_item_health_small (void) {
1244         if(!self.max_health)
1245                 self.max_health = g_pickup_healthsmall_max;
1246         if(!self.health)
1247                 self.health = g_pickup_healthsmall;
1248         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1249 }
1250
1251 void spawnfunc_item_health_medium (void) {
1252         if(!self.max_health)
1253                 self.max_health = g_pickup_healthmedium_max;
1254         if(!self.health)
1255                 self.health = g_pickup_healthmedium;
1256         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1257 }
1258
1259 void spawnfunc_item_health_large (void) {
1260         if(!self.max_health)
1261                 self.max_health = g_pickup_healthlarge_max;
1262         if(!self.health)
1263                 self.health = g_pickup_healthlarge;
1264         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1265 }
1266
1267 void spawnfunc_item_health_mega (void) {
1268         if(!cvar("g_powerup_superhealth"))
1269                 return;
1270
1271         if(g_arena && !cvar("g_arena_powerups"))
1272                 return;
1273
1274         if(g_minstagib) {
1275                 minstagib_items(IT_NAILS);
1276         } else {
1277                 if(!self.max_health)
1278                         self.max_health = g_pickup_healthmega_max;
1279                 if(!self.health)
1280                         self.health = g_pickup_healthmega;
1281                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1282         }
1283 }
1284
1285 // support old misnamed entities
1286 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
1287 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1288 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1289 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1290 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1291
1292 void spawnfunc_item_strength (void) {
1293         if(!cvar("g_powerup_strength"))
1294                 return;
1295
1296         if(g_arena && !cvar("g_arena_powerups"))
1297                 return;
1298
1299         if(g_minstagib) {
1300                 minstagib_items(IT_STRENGTH);
1301         } else {
1302                 precache_sound("weapons/strength_fire.wav");
1303                 self.strength_finished = 30;
1304                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1305         }
1306 }
1307
1308 void spawnfunc_item_invincible (void) {
1309         if(!cvar("g_powerup_shield"))
1310                 return;
1311
1312         if(g_arena && !cvar("g_arena_powerups"))
1313                 return;
1314
1315         if(g_minstagib) {
1316                 minstagib_items(IT_INVINCIBLE);
1317         } else {
1318                 self.invincible_finished = 30;
1319                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1320         }
1321 }
1322
1323 void spawnfunc_item_minst_cells (void) {
1324         if (g_minstagib)
1325         {
1326                 minst_no_auto_cells = 1;
1327                 minstagib_items(IT_CELLS);
1328         }
1329         else
1330                 remove(self);
1331 }
1332
1333 // compatibility:
1334 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1335
1336 float target_item_func_set(float a, float b)
1337 {
1338         if(b == 0)
1339                 return a;
1340         else if(b < 0)
1341                 return 0;
1342         else
1343                 return b;
1344 }
1345
1346 float target_item_func_min(float a, float b)
1347 {
1348         if(b == 0)
1349                 return a;
1350         else if(b < 0)
1351                 return 0;
1352         else
1353                 return min(a, b);
1354 }
1355
1356 float target_item_func_max(float a, float b)
1357 {
1358         return max(a, b);
1359 }
1360
1361 float target_item_func_bitset(float a, float b)
1362 {
1363         return b;
1364 }
1365
1366 float target_item_func_and(float a, float b)
1367 {
1368         return a & b;
1369 }
1370
1371 float target_item_func_itembitset(float a, float b)
1372 {
1373         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | b;
1374 }
1375
1376 float target_item_func_itemand(float a, float b)
1377 {
1378         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | (a & b);
1379 }
1380
1381 float target_item_func_or(float a, float b)
1382 {
1383         return a | b;
1384 }
1385
1386 float target_item_func_andnot(float a, float b)
1387 {
1388         return a - (a & b);
1389 }
1390
1391 float target_item_changed;
1392 void target_item_change(float binary, .float field, float(float a, float b) func, string sound_increase, string sound_decrease)
1393 {
1394         float n, d;
1395         n = func(activator.field, self.field);
1396
1397         if(binary)
1398         {
1399                 d = n & activator.field;
1400                 if(d != n) // bits added?
1401                         d = +1;
1402                 else if(d != activator.field) // bits removed?
1403                         d = -1;
1404                 else
1405                         d = 0;
1406         }
1407         else
1408                 d = n - activator.field;
1409
1410         if(d < 0)
1411         {
1412                 if(sound_decrease != "")
1413                         sound (activator, CHAN_AUTO, sound_decrease, VOL_BASE, ATTN_NORM);
1414                 target_item_changed = 1;
1415         }
1416         else if(d > 0)
1417         {
1418                 if(sound_increase != "")
1419                         sound (activator, CHAN_AUTO, sound_increase, VOL_BASE, ATTN_NORM);
1420                 target_item_changed = 1;
1421         }
1422         activator.field = n;
1423 }
1424
1425 void target_items_use (void)
1426 {
1427         float h0, a0, f0;
1428
1429         if(activator.classname == "droppedweapon")
1430         {
1431                 EXACTTRIGGER_TOUCH;
1432                 remove(activator);
1433                 return;
1434         }
1435
1436         if(activator.classname != "player")
1437                 return;
1438         if(activator.deadflag != DEAD_NO)
1439                 return;
1440         EXACTTRIGGER_TOUCH;
1441
1442         entity e;
1443         for(e = world; (e = find(e, classname, "droppedweapon")); )
1444                 if(e.enemy == activator)
1445                         remove(e);
1446
1447         float _switchweapon;
1448         _switchweapon = FALSE;
1449         if (activator.autoswitch)
1450                 if (activator.switchweapon == w_getbestweapon(activator))
1451                         _switchweapon = TRUE;
1452
1453         a0 = activator.armorvalue;
1454         h0 = activator.health;
1455         f0 = activator.ammo_fuel;
1456         target_item_changed = 0;
1457
1458         if(self.spawnflags == 0) // SET
1459         {
1460                 target_item_change(0, ammo_shells, target_item_func_set, "misc/itempickup.wav", "");
1461                 target_item_change(0, ammo_nails, target_item_func_set, "misc/itempickup.wav", "");
1462                 target_item_change(0, ammo_rockets, target_item_func_set, "misc/itempickup.wav", "");
1463                 target_item_change(0, ammo_cells, target_item_func_set, "misc/itempickup.wav", "");
1464                 target_item_change(0, ammo_fuel, target_item_func_set, "misc/itempickup.wav", "");
1465                 target_item_change(0, health, target_item_func_set, "misc/megahealth.wav", "");
1466                 target_item_change(0, armorvalue, target_item_func_set, "misc/armor25.wav", "");
1467                 target_item_change(1, items, target_item_func_itembitset, "misc/powerup.wav", "misc/poweroff.wav");
1468                 target_item_change(1, weapons, target_item_func_bitset, "weapons/weaponpickup.wav", "");
1469
1470                 if((self.items & activator.items) & IT_STRENGTH)
1471                         activator.strength_finished = time + self.strength_finished;
1472                 if((self.items & activator.items) & IT_INVINCIBLE)
1473                         activator.invincible_finished = time + self.invincible_finished;
1474         }
1475         else if(self.spawnflags == 1) // AND/MIN
1476         {
1477                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1478                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1479                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1480                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1481                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1482                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1483                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1484                 target_item_change(1, items, target_item_func_itemand, "misc/powerup.wav", "misc/poweroff.wav");
1485                 target_item_change(1, weapons, target_item_func_and, "weapons/weaponpickup.wav", "");
1486
1487                 if((self.items & activator.items) & IT_STRENGTH)
1488                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1489                 if((self.items & activator.items) & IT_INVINCIBLE)
1490                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1491         }
1492         else if(self.spawnflags == 2) // OR/MAX
1493         {
1494                 target_item_change(0, ammo_shells, target_item_func_max, "misc/itempickup.wav", "");
1495                 target_item_change(0, ammo_nails, target_item_func_max, "misc/itempickup.wav", "");
1496                 target_item_change(0, ammo_rockets, target_item_func_max, "misc/itempickup.wav", "");
1497                 target_item_change(0, ammo_cells, target_item_func_max, "misc/itempickup.wav", "");
1498                 target_item_change(0, ammo_fuel, target_item_func_max, "misc/itempickup.wav", "");
1499                 target_item_change(0, health, target_item_func_max, "misc/megahealth.wav", "");
1500                 target_item_change(0, armorvalue, target_item_func_max, "misc/armor25.wav", "");
1501                 target_item_change(1, items, target_item_func_or, "misc/powerup.wav", "misc/poweroff.wav");
1502                 target_item_change(1, weapons, target_item_func_or, "weapons/weaponpickup.wav", "");
1503
1504                 if((self.items & activator.items) & IT_STRENGTH)
1505                         activator.strength_finished = max(activator.strength_finished, time + self.strength_finished);
1506                 if((self.items & activator.items) & IT_INVINCIBLE)
1507                         activator.invincible_finished = max(activator.invincible_finished, time + self.invincible_finished);
1508         }
1509         else if(self.spawnflags == 4) // ANDNOT/MIN
1510         {
1511                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1512                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1513                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1514                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1515                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1516                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1517                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1518                 target_item_change(1, items, target_item_func_andnot, "misc/powerup.wav", "misc/poweroff.wav");
1519                 target_item_change(1, weapons, target_item_func_andnot, "weapons/weaponpickup.wav", "");
1520
1521                 if((self.items & activator.items) & IT_STRENGTH)
1522                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1523                 if((self.items & activator.items) & IT_INVINCIBLE)
1524                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1525         }
1526
1527         if not(activator.items & IT_STRENGTH)
1528                 activator.strength_finished = 0;
1529         if not(activator.items & IT_INVINCIBLE)
1530                 activator.invincible_finished = 0;
1531
1532         if(activator.health > h0)
1533                 activator.pauserothealth_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1534         else if(activator.health < h0)
1535                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
1536
1537         if(activator.ammo_fuel > f0)
1538                 activator.pauserotfuel_finished = max(activator.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
1539         else if(activator.ammo_fuel < f0)
1540                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1541
1542         if(activator.armorvalue > a0)
1543                 activator.pauserotarmor_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1544
1545         if not(activator.weapons & W_WeaponBit(activator.switchweapon))
1546                 _switchweapon = TRUE;
1547         if(_switchweapon)
1548                 W_SwitchWeapon_Force(activator, w_getbestweapon(activator));
1549
1550         if(target_item_changed)
1551                 centerprint(activator, self.message);
1552 }
1553
1554 void spawnfunc_target_items (void)
1555 {
1556         float n, i, j;
1557         entity e;
1558
1559         if(g_nixnex)
1560         {
1561                 // items triggers cannot work in nixnex (as they change weapons/ammo)
1562                 remove(self);
1563                 return;
1564         }
1565
1566         self.use = target_items_use;
1567         if(!self.strength_finished)
1568                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1569         if(!self.invincible_finished)
1570                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1571
1572         precache_sound("misc/itempickup.wav");
1573         precache_sound("misc/itempickup.wav");
1574         precache_sound("misc/itempickup.wav");
1575         precache_sound("misc/itempickup.wav");
1576         precache_sound("misc/megahealth.wav");
1577         precache_sound("misc/armor25.wav");
1578         precache_sound("misc/powerup.wav");
1579         precache_sound("misc/poweroff.wav");
1580         precache_sound("weapons/weaponpickup.wav");
1581
1582         n = tokenize_console(self.netname);
1583         for(i = 0; i < n; ++i)
1584         {
1585                 if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1586                 else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1587                 else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1588                 else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1589                 else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1590                 else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1591                 else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1592                 else
1593                 {
1594                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1595                         {
1596                                 e = get_weaponinfo(j);
1597                                 if(argv(i) == e.netname)
1598                                 {
1599                                         self.weapons |= e.weapons;
1600                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1601                                                 weapon_action(e.weapon, WR_PRECACHE);
1602                                         break;
1603                                 }
1604                         }
1605                         if(j > WEP_LAST)
1606                                 print("target_items: invalid item ", argv(i), "\n");
1607                 }
1608         }
1609 }
1610
1611 void spawnfunc_item_fuel(void)
1612 {
1613         if(!self.ammo_fuel)
1614                 self.ammo_fuel = g_pickup_fuel;
1615         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1616 }
1617
1618 void spawnfunc_item_fuel_regen(void)
1619 {
1620         if(start_items & IT_FUEL_REGEN)
1621         {
1622                 spawnfunc_item_fuel();
1623                 return;
1624         }
1625         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1626 }
1627
1628 void spawnfunc_item_jetpack(void)
1629 {
1630         if(g_grappling_hook)
1631                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1632         if(!self.ammo_fuel)
1633                 self.ammo_fuel = g_pickup_fuel_jetpack;
1634         if(start_items & IT_JETPACK)
1635         {
1636                 spawnfunc_item_fuel();
1637                 return;
1638         }
1639         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1640 }
1641
1642 // we no longer have the seeker
1643 void spawnfunc_weapon_seeker()
1644 {
1645         spawnfunc_weapon_fireball();
1646 }