data/qcsrc/server/t_items.qc

   1 #define ITEM_RESPAWN_TICKS 10
   2
   3 #define ITEM_RESPAWNTIME(i)         ((i).respawntime + crandom() * (i).respawntimejitter)
   4         // range: respawntime - respawntimejitter .. respawntime + respawntimejitter
   5 #define ITEM_RESPAWNTIME_INITIAL(i) (ITEM_RESPAWN_TICKS + random() * ((i).respawntime + (i).respawntimejitter - ITEM_RESPAWN_TICKS))
   6         // range: 10 .. respawntime + respawntimejitter
   7
   8 floatfield Item_CounterField(float it)
   9 {
  10         switch(it)
  11         {
  12                 case IT_SHELLS:      return ammo_shells;
  13                 case IT_NAILS:       return ammo_nails;
  14                 case IT_ROCKETS:     return ammo_rockets;
  15                 case IT_CELLS:       return ammo_cells;
  16                 case IT_FUEL:        return ammo_fuel;
  17                 case IT_5HP:         return health;
  18                 case IT_25HP:        return health;
  19                 case IT_HEALTH:      return health;
  20                 case IT_ARMOR_SHARD: return armorvalue;
  21                 case IT_ARMOR:       return armorvalue;
  22                 // add more things here (health, armor)
  23                 default:             error("requested item has no counter field");
  24         }
  25 }
  26
  27 string Item_CounterFieldName(float it)
  28 {
  29         switch(it)
  30         {
  31                 case IT_SHELLS:      return "shells";
  32                 case IT_NAILS:       return "nails";
  33                 case IT_ROCKETS:     return "rockets";
  34                 case IT_CELLS:       return "cells";
  35                 case IT_FUEL:        return "fuel";
  36
  37                 // add more things here (health, armor)
  38                 default:             error("requested item has no counter field name");
  39         }
  40 }
  41
  42 .float max_armorvalue;
  43
  44 void Item_Respawn (void)
  45 {
  46         self.model = self.mdl;          // restore original model
  47         self.solid = SOLID_TRIGGER;     // allow it to be touched again
  48         if(!g_minstagib && self.items == IT_STRENGTH)
  49                 sound (self, CHAN_TRIGGER, "misc/strength_respawn.wav", VOL_BASE, ATTN_NORM);   // play respawn sound
  50         else if(!g_minstagib && self.items == IT_INVINCIBLE)
  51                 sound (self, CHAN_TRIGGER, "misc/shield_respawn.wav", VOL_BASE, ATTN_NORM);     // play respawn sound
  52         else
  53                 sound (self, CHAN_TRIGGER, "misc/itemrespawn.wav", VOL_BASE, ATTN_NORM);        // play respawn sound
  54         setorigin (self, self.origin);
  55
  56         //pointparticles(particleeffectnum("item_respawn"), self.origin + self.mins_z * '0 0 1' + '0 0 48', '0 0 0', 1);
  57         pointparticles(particleeffectnum("item_respawn"), self.origin + 0.5 * (self.mins + self.maxs), '0 0 0', 1);
  58 }
  59
  60 void Item_RespawnCountdown (void)
  61 {
  62         if(self.count >= ITEM_RESPAWN_TICKS)
  63         {
  64                 if(self.waypointsprite_attached)
  65                         WaypointSprite_Kill(self.waypointsprite_attached);
  66                 Item_Respawn();
  67         }
  68         else
  69         {
  70                 self.nextthink = time + 1;
  71                 self.count += 1;
  72                 if(self.count == 1)
  73                 {
  74                         string name;
  75                         vector rgb;
  76                         name = string_null;
  77                         if(g_minstagib)
  78                         {
  79                                 switch(self.items)
  80                                 {
  81                                         case IT_STRENGTH:   name = "item-invis"; rgb = '0 0 1'; break;
  82                                         case IT_NAILS:      name = "item-extralife"; rgb = '1 0 0'; break;
  83                                         case IT_INVINCIBLE: name = "item-speed"; rgb = '1 0 1'; break;
  84                                 }
  85                         }
  86                         else
  87                         {
  88                                 switch(self.items)
  89                                 {
  90                                         case IT_STRENGTH:   name = "item-strength"; rgb = '0 0 1'; break;
  91                                         case IT_INVINCIBLE: name = "item-shield"; rgb = '1 0 1'; break;
  92                                 }
  93                         }
  94                         switch(self.items)
  95                         {
  96                                 case IT_FUEL_REGEN:     name = "item-fuelregen"; rgb = '1 0.5 0'; break;
  97                                 case IT_JETPACK:        name = "item-jetpack"; rgb = '0.5 0.5 0.5'; break;
  98                         }
  99                         if(name)
 100                         {
 101                                 WaypointSprite_Spawn(name, 0, 0, self, '0 0 64', world, 0, self, waypointsprite_attached, FALSE);
 102                                 if(self.waypointsprite_attached)
 103                                 {
 104                                         WaypointSprite_UpdateTeamRadar(self.waypointsprite_attached, RADARICON_POWERUP, rgb);
 105                                         //WaypointSprite_UpdateMaxHealth(self.waypointsprite_attached, ITEM_RESPAWN_TICKS + 1);
 106                                         WaypointSprite_UpdateBuildFinished(self.waypointsprite_attached, time + ITEM_RESPAWN_TICKS);
 107                                 }
 108                         }
 109                 }
 110                 sound (self, CHAN_TRIGGER, "misc/itemrespawncountdown.wav", VOL_BASE, ATTN_NORM);       // play respawn sound
 111                 if(self.waypointsprite_attached)
 112                 {
 113                         WaypointSprite_Ping(self.waypointsprite_attached);
 114                         //WaypointSprite_UpdateHealth(self.waypointsprite_attached, self.count);
 115                 }
 116         }
 117 }
 118
 119 void Item_ScheduleRespawnIn(entity e, float t)
 120 {
 121         if(e.flags & FL_POWERUP)
 122         {
 123                 e.think = Item_RespawnCountdown;
 124                 e.nextthink = time + max(0, t - ITEM_RESPAWN_TICKS);
 125                 e.count = 0;
 126         }
 127         else
 128         {
 129                 e.think = Item_Respawn;
 130                 e.nextthink = time + t;
 131         }
 132 }
 133
 134 void Item_ScheduleRespawn(entity e)
 135 {
 136         Item_ScheduleRespawnIn(e, ITEM_RESPAWNTIME(e));
 137 }
 138
 139 void Item_ScheduleInitialRespawn(entity e)
 140 {
 141         Item_ScheduleRespawnIn(e, game_starttime - time + ITEM_RESPAWNTIME_INITIAL(e));
 142 }
 143
 144 float Item_GiveTo(entity item, entity player)
 145 {
 146         float _switchweapon;
 147         float pickedup;
 148         float it;
 149         float i;
 150         entity e;
 151
 152         // if nothing happens to player, just return without taking the item
 153         pickedup = FALSE;
 154         _switchweapon = FALSE;
 155
 156         if (g_minstagib)
 157         {
 158                 if (item.ammo_fuel)
 159                 if (player.ammo_fuel < g_pickup_fuel_max)
 160                 {
 161                         pickedup = TRUE;
 162                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 163                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 164                 }
 165                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 166                 {
 167                         pickedup = TRUE;
 168                         player.items |= it;
 169                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 170                 }
 171
 172                 _switchweapon = TRUE;
 173                 if (item.ammo_cells)
 174                 {
 175                         pickedup = TRUE;
 176                         // play some cool sounds ;)
 177                         centerprint(player, "\n");
 178                         if(player.health <= 5)
 179                                 announce(player, "announcer/robotic/lastsecond.wav");
 180                         else if(player.health < 50)
 181                                 announce(player, "announcer/robotic/narrowly.wav");
 182                         // sound not available
 183                         // else if(item.items == IT_CELLS)
 184                         //      play2(player, "announce/robotic/ammo.wav");
 185
 186                         if (item.weapons & WEPBIT_MINSTANEX)
 187                                 W_GiveWeapon (player, WEP_MINSTANEX, "Nex");
 188                         if (item.ammo_cells)
 189                                 player.ammo_cells = min (player.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
 190                         player.health = 100;
 191                 }
 192
 193                 // extralife powerup
 194                 if (item.max_health)
 195                 {
 196                         pickedup = TRUE;
 197                         // sound not available
 198                         // play2(player, "announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.wav");
 199                         player.armorvalue = player.armorvalue + cvar("g_minstagib_extralives");
 200                         sprint(player, "^3You picked up some extra lives\n");
 201                 }
 202
 203                 // invis powerup
 204                 if (item.strength_finished)
 205                 {
 206                         pickedup = TRUE;
 207                         // sound not available
 208                         // play2(player, "announce/robotic/invisible.wav");
 209                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 210                 }
 211
 212                 // speed powerup
 213                 if (item.invincible_finished)
 214                 {
 215                         pickedup = TRUE;
 216                         // sound not available
 217                         // play2(player, "announce/robotic/speed.wav");
 218                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
 219                 }
 220
 221                 if (item.ammo_fuel)
 222                 if (player.ammo_fuel < g_pickup_fuel_max)
 223                 {
 224                         pickedup = TRUE;
 225                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 226                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 227                 }
 228
 229         }
 230         else
 231         {
 232                 if (g_weapon_stay == 1)
 233                 if not(item.flags & FL_NO_WEAPON_STAY)
 234                 if (item.flags & FL_WEAPON)
 235                 {
 236                         if(item.classname == "droppedweapon")
 237                         {
 238                                 if (player.weapons & item.weapons)      // don't let players stack ammo by tossing weapons
 239                                         goto skip;
 240                         }
 241                         else
 242                         {
 243                                 if (player.weapons & item.weapons)
 244                                         goto skip;
 245                         }
 246                 }
 247
 248                 // in case the player has autoswitch enabled do the following:
 249                 // if the player is using their best weapon before items are given, they
 250                 // probably want to switch to an even better weapon after items are given
 251                 if (player.autoswitch)
 252                 if (player.switchweapon == w_getbestweapon(player))
 253                         _switchweapon = TRUE;
 254
 255                 if not(player.weapons & W_WeaponBit(player.switchweapon))
 256                         _switchweapon = TRUE;
 257
 258                 if (item.ammo_shells)
 259                 if (player.ammo_shells < g_pickup_shells_max)
 260                 {
 261                         pickedup = TRUE;
 262                         player.ammo_shells = min (player.ammo_shells + item.ammo_shells, g_pickup_shells_max);
 263                 }
 264                 if (item.ammo_nails)
 265                 if (player.ammo_nails < g_pickup_nails_max)
 266                 {
 267                         pickedup = TRUE;
 268                         player.ammo_nails = min (player.ammo_nails + item.ammo_nails, g_pickup_nails_max);
 269                 }
 270                 if (item.ammo_rockets)
 271                 if (player.ammo_rockets < g_pickup_rockets_max)
 272                 {
 273                         pickedup = TRUE;
 274                         player.ammo_rockets = min (player.ammo_rockets + item.ammo_rockets, g_pickup_rockets_max);
 275                 }
 276                 if (item.ammo_cells)
 277                 if (player.ammo_cells < g_pickup_cells_max)
 278                 {
 279                         pickedup = TRUE;
 280                         player.ammo_cells = min (player.ammo_cells + item.ammo_cells, g_pickup_cells_max);
 281                 }
 282                 if (item.ammo_fuel)
 283                 if (player.ammo_fuel < g_pickup_fuel_max)
 284                 {
 285                         pickedup = TRUE;
 286                         player.ammo_fuel = min(player.ammo_fuel + item.ammo_fuel, g_pickup_fuel_max);
 287                         player.pauserotfuel_finished = max(player.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
 288                 }
 289
 290                 if (item.flags & FL_WEAPON)
 291                 if ((it = item.weapons - (item.weapons & player.weapons)))
 292                 {
 293                         pickedup = TRUE;
 294                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 295                         {
 296                                 e = get_weaponinfo(i);
 297                                 if(it & e.weapons)
 298                                         W_GiveWeapon (player, e.weapon, item.netname);
 299                         }
 300                 }
 301
 302                 if((it = (item.items - (item.items & player.items)) & IT_PICKUPMASK))
 303                 {
 304                         pickedup = TRUE;
 305                         player.items |= it;
 306                         sprint (player, strcat("You got the ^2", item.netname, "\n"));
 307                 }
 308
 309                 if (item.strength_finished)
 310                 {
 311                         pickedup = TRUE;
 312                         player.strength_finished = max(player.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 313                 }
 314                 if (item.invincible_finished)
 315                 {
 316                         pickedup = TRUE;
 317                         player.invincible_finished = max(player.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 318                 }
 319                 //if (item.speed_finished)
 320                 //{
 321                 //      pickedup = TRUE;
 322                 //      player.speed_finished = max(player.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 323                 //}
 324                 //if (item.slowmo_finished)
 325                 //{
 326                 //      pickedup = TRUE;
 327                 //      player.slowmo_finished = max(player.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 328                 //}
 329
 330                 if (item.health)
 331                 if (player.health < item.max_health)
 332                 {
 333                         pickedup = TRUE;
 334                         player.health = min(player.health + item.health, item.max_health);
 335                         player.pauserothealth_finished = max(player.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 336                 }
 337                 if (item.armorvalue)
 338                 if (player.armorvalue < item.max_armorvalue)
 339                 {
 340                         pickedup = TRUE;
 341                         player.armorvalue = min(player.armorvalue + item.armorvalue, item.max_armorvalue);
 342                         player.pauserotarmor_finished = max(player.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 343                 }
 344         }
 345
 346 :skip
 347         // always eat teamed entities
 348         if(item.team)
 349                 pickedup = TRUE;
 350
 351         if (!pickedup)
 352                 return 0;
 353
 354         sound (player, CHAN_AUTO, item.item_pickupsound, VOL_BASE, ATTN_NORM);
 355         if (_switchweapon)
 356                 if (player.switchweapon != w_getbestweapon(player))
 357                         W_SwitchWeapon_Force(player, w_getbestweapon(player));
 358
 359         return 1;
 360 }
 361
 362 void Item_Touch (void)
 363 {
 364         entity e, head;
 365
 366         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
 367         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 368         {
 369                 remove(self);
 370                 return;
 371         }
 372         if (other.classname != "player")
 373                 return;
 374         if (other.deadflag)
 375                 return;
 376         if (self.solid != SOLID_TRIGGER)
 377                 return;
 378         if (self.owner == other)
 379                 return;
 380
 381         if(!Item_GiveTo(self, other))
 382                 return;
 383
 384         pointparticles(particleeffectnum("item_pickup"), self.origin, '0 0 0', 1);
 385
 386         if (self.classname == "droppedweapon")
 387                 remove (self);
 388         else if((self.flags & FL_WEAPON) && !(self.flags & FL_NO_WEAPON_STAY) && g_weapon_stay)
 389                 return;
 390         else
 391         {
 392                 self.solid = SOLID_NOT;
 393                 self.model = string_null;
 394                 if(self.team)
 395                 {
 396                         RandomSelection_Init();
 397                         for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 398                                 RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 399                         e = RandomSelection_chosen_ent;
 400                 }
 401                 else
 402                         e = self;
 403                 Item_ScheduleRespawn(e);
 404         }
 405 }
 406
 407 void Item_FindTeam()
 408 {
 409         entity head, e;
 410
 411         if(self.effects & EF_NODRAW)
 412         {
 413                 // marker for item team search
 414                 dprint("Initializing item team ", ftos(self.team), "\n");
 415                 RandomSelection_Init();
 416                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 417                         RandomSelection_Add(head, 0, string_null, head.cnt, 0);
 418                 e = RandomSelection_chosen_ent;
 419                 e.state = 0;
 420
 421                 for(head = world; (head = findfloat(head, team, self.team)); ) if(head.flags & FL_ITEM)
 422                 {
 423                         if(head != e)
 424                         {
 425                                 // make it a non-spawned item
 426                                 head.solid = SOLID_NOT;
 427                                 head.model = string_null;
 428                                 head.state = 1; // state 1 = initially hidden item
 429                         }
 430                         head.effects &~= EF_NODRAW;
 431                 }
 432
 433                 if(e.flags & FL_POWERUP) // do not spawn powerups initially!
 434                 {
 435                         e.solid = SOLID_NOT;
 436                         e.model = string_null;
 437                         Item_ScheduleInitialRespawn(e);
 438                 }
 439         }
 440 }
 441
 442 void Item_Reset()
 443 {
 444         if(self.state == 1)
 445         {
 446                 self.model = string_null;
 447                 self.solid = SOLID_NOT;
 448         }
 449         else
 450         {
 451                 self.model = self.mdl;
 452                 self.solid = SOLID_TRIGGER;
 453         }
 454         setorigin (self, self.origin);
 455         self.think = SUB_Null;
 456         self.nextthink = 0;
 457
 458         if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 459         {
 460                 self.solid = SOLID_NOT;
 461                 self.model = string_null;
 462                 Item_ScheduleInitialRespawn(self);
 463         }
 464 }
 465
 466 // Savage: used for item garbage-collection
 467 // TODO: perhaps nice special effect?
 468 void RemoveItem(void)
 469 {
 470         remove(self);
 471 }
 472
 473 // pickup evaluation functions
 474 // these functions decide how desirable an item is to the bots
 475
 476 float generic_pickupevalfunc(entity player, entity item) {return item.bot_pickupbasevalue;};
 477
 478 float weapon_pickupevalfunc(entity player, entity item)
 479 {
 480         // if we already have the weapon, rate it 1/5th normal value
 481         if ((player.weapons & item.weapons) == item.weapons)
 482                 return item.bot_pickupbasevalue * 0.2;
 483         return item.bot_pickupbasevalue;
 484 };
 485
 486 float commodity_pickupevalfunc(entity player, entity item)
 487 {
 488         float c;
 489         c = 0;
 490         // TODO: figure out if the player even has the weapon this ammo is for?
 491         // may not affect strategy much though...
 492         // find out how much more ammo/armor/health the player can hold
 493         if (item.ammo_shells)
 494         if (player.ammo_shells < g_pickup_shells_max)
 495                 c = c + max(0, 1 - player.ammo_shells / g_pickup_shells_max);
 496         if (item.ammo_nails)
 497         if (player.ammo_nails < g_pickup_nails_max)
 498                 c = c + max(0, 1 - player.ammo_nails / g_pickup_nails_max);
 499         if (item.ammo_rockets)
 500         if (player.ammo_rockets < g_pickup_rockets_max)
 501                 c = c + max(0, 1 - player.ammo_rockets / g_pickup_rockets_max);
 502         if (item.ammo_cells)
 503         if (player.ammo_cells < g_pickup_cells_max)
 504                 c = c + max(0, 1 - player.ammo_cells / g_pickup_cells_max);
 505         if (item.armorvalue)
 506         if (player.armorvalue < item.max_armorvalue)
 507                 c = c + max(0, 1 - player.armorvalue / item.max_armorvalue);
 508         if (item.health)
 509         if (player.health < item.max_health)
 510                 c = c + max(0, 1 - player.health / item.max_health);
 511
 512         return item.bot_pickupbasevalue * c;
 513 };
 514
 515
 516 .float is_item;
 517 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, float defaultrespawntimejitter, string itemname, float itemid, float weaponid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 518 {
 519         startitem_failed = FALSE;
 520
 521         // is it a dropped weapon?
 522         if (self.classname == "droppedweapon")
 523         {
 524                 self.reset = SUB_Remove;
 525                 // it's a dropped weapon
 526                 self.movetype = MOVETYPE_TOSS;
 527                 self.solid = SOLID_TRIGGER;
 528                 // Savage: remove thrown items after a certain period of time ("garbage collection")
 529                 self.think = RemoveItem;
 530                 self.nextthink = time + 60;
 531                 // don't drop if in a NODROP zone (such as lava)
 532                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 533                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 534                 {
 535                         startitem_failed = TRUE;
 536                         remove(self);
 537                         return;
 538                 }
 539         }
 540         else
 541         {
 542                 self.reset = Item_Reset;
 543                 // it's a level item
 544                 if(self.spawnflags & 1)
 545                         self.noalign = 1;
 546                 if (self.noalign)
 547                         self.movetype = MOVETYPE_NONE;
 548                 else
 549                         self.movetype = MOVETYPE_TOSS;
 550                 self.solid = SOLID_TRIGGER;
 551                 // do item filtering according to game mode and other things
 552                 if (!self.noalign)
 553                 {
 554                         // first nudge it off the floor a little bit to avoid math errors
 555                         setorigin(self, self.origin + '0 0 1');
 556                         // set item size before we spawn a spawnfunc_waypoint
 557                         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 558                                 setsize (self, '-16 -16 0', '16 16 48');
 559                         else
 560                                 setsize (self, '-16 -16 0', '16 16 32');
 561                         // note droptofloor returns FALSE if stuck/or would fall too far
 562                         droptofloor();
 563                         waypoint_spawnforitem(self);
 564                 }
 565
 566                 if(teams_matter)
 567                 {
 568                         if(self.notteam)
 569                         {
 570                                 print("removed non-teamplay ", self.classname, "\n");
 571                                 startitem_failed = TRUE;
 572                                 remove (self);
 573                                 return;
 574                         }
 575                 }
 576                 else
 577                 {
 578                         if(self.notfree)
 579                         {
 580                                 print("removed non-FFA ", self.classname, "\n");
 581                                 startitem_failed = TRUE;
 582                                 remove (self);
 583                                 return;
 584                         }
 585                 }
 586
 587                 if(self.notq3a)
 588                 {
 589                         // We aren't TA or something like that, so we keep the Q3A entities
 590                         print("removed non-Q3A ", self.classname, "\n");
 591                         startitem_failed = TRUE;
 592                         remove (self);
 593                         return;
 594                 }
 595
 596                 /*
 597                  * can't do it that way, as it would break maps
 598                  * TODO make a target_give like entity another way, that perhaps has
 599                  * the weapon name in a key
 600                 if(self.targetname)
 601                 {
 602                         // target_give not yet supported; maybe later
 603                         print("removed targeted ", self.classname, "\n");
 604                         startitem_failed = TRUE;
 605                         remove (self);
 606                         return;
 607                 }
 608                 */
 609
 610                 if(cvar("spawn_debug") >= 2)
 611                 {
 612                         entity otheritem;
 613                         for(otheritem = findradius(self.origin, 3); otheritem; otheritem = otheritem.chain)
 614                         {
 615                                 if(otheritem.is_item)
 616                                 {
 617                                         dprint("XXX Found duplicated item: ", itemname, vtos(self.origin));
 618                                         dprint(" vs ", otheritem.netname, vtos(otheritem.origin), "\n");
 619                                         error("Mapper sucks.");
 620                                 }
 621                         }
 622                         self.is_item = TRUE;
 623                 }
 624
 625                 weaponsInMap |= weaponid;
 626
 627                 if(g_lms)
 628                 {
 629                         startitem_failed = TRUE;
 630                         remove(self);
 631                         return;
 632                 }
 633                 else if (g_weaponarena && ((weaponid & WEPBIT_ALL) || (itemid & IT_AMMO)))
 634                 {
 635                         startitem_failed = TRUE;
 636                         remove(self);
 637                         return;
 638                 }
 639                 else if (g_minstagib)
 640                 {
 641                         // don't remove dropped items and powerups
 642                         if (self.classname != "minstagib")
 643                         {
 644                                 startitem_failed = TRUE;
 645                                 remove (self);
 646                                 return;
 647                         }
 648                 }
 649                 else if (g_nixnex)
 650                 {
 651                         local float rm;
 652
 653                         rm = 1;
 654                         switch (itemid)
 655                         {
 656                                 case IT_HEALTH:
 657                                 case IT_5HP:
 658                                 case IT_25HP:
 659                                 case IT_ARMOR:
 660                                 case IT_ARMOR_SHARD:
 661                                         if (cvar("g_nixnex_with_healtharmor"))
 662                                                 rm = 0;
 663                                         break;
 664                                 case IT_STRENGTH:
 665                                 case IT_INVINCIBLE:
 666                                         if (cvar("g_nixnex_with_powerups"))
 667                                                 rm = 0;
 668                                         break;
 669                         }
 670
 671                         if(rm)
 672                         {
 673                                 startitem_failed = TRUE;
 674                                 remove (self);
 675                                 return;
 676                         }
 677                 }
 678                 else if (!cvar("g_pickup_items") && itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 679                 {
 680                         startitem_failed = TRUE;
 681                         remove (self);
 682                         return;
 683                 }
 684
 685                 precache_model (itemmodel);
 686                 precache_sound (pickupsound);
 687                 precache_sound ("misc/itemrespawn.wav");
 688                 precache_sound ("misc/itemrespawncountdown.wav");
 689
 690                 if(itemid == IT_STRENGTH)
 691                         precache_sound ("misc/strength_respawn.wav");
 692                 if(itemid == IT_INVINCIBLE)
 693                         precache_sound ("misc/shield_respawn.wav");
 694
 695                 if((itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2)) || (weaponid & WEPBIT_ALL))
 696                         self.target = "###item###"; // for finding the nearest item using find()
 697         }
 698
 699         self.bot_pickup = TRUE;
 700         self.bot_pickupevalfunc = pickupevalfunc;
 701         self.bot_pickupbasevalue = pickupbasevalue;
 702         self.mdl = itemmodel;
 703         self.item_pickupsound = pickupsound;
 704         // let mappers override respawntime
 705         if(!self.respawntime) // both set
 706         {
 707                 self.respawntime = defaultrespawntime;
 708                 self.respawntimejitter = defaultrespawntimejitter;
 709         }
 710         self.netname = itemname;
 711         self.items = itemid;
 712         self.weapons = weaponid;
 713         self.flags = FL_ITEM | itemflags;
 714         self.touch = Item_Touch;
 715         setmodel (self, self.mdl); // precision set below
 716         self.effects |= EF_LOWPRECISION;
 717         if((itemflags & FL_POWERUP) || self.health || self.armorvalue)
 718                 setsize (self, '-16 -16 0', '16 16 48');
 719         else
 720                 setsize (self, '-16 -16 0', '16 16 32');
 721         if(itemflags & FL_WEAPON)
 722                 self.modelflags |= MF_ROTATE;
 723
 724         if (self.classname != "droppedweapon") // if dropped, colormap is already set up nicely
 725         if (itemflags & FL_WEAPON)
 726         {
 727                 // neutral team color for pickup weapons
 728                 self.colormap = 1024; // color shirt=0 pants=0 grey
 729         }
 730
 731         if (cvar("g_fullbrightitems"))
 732                 self.effects = self.effects | EF_FULLBRIGHT;
 733
 734         self.state = 0;
 735         if(self.team)
 736         {
 737                 if(!self.cnt)
 738                         self.cnt = 1; // item probability weight
 739                 self.effects = self.effects | EF_NODRAW; // marker for item team search
 740                 InitializeEntity(self, Item_FindTeam, INITPRIO_FINDTARGET);
 741         }
 742         else if(self.flags & FL_POWERUP) // do not spawn powerups initially!
 743         {
 744                 self.solid = SOLID_NOT;
 745                 self.model = string_null;
 746                 Item_ScheduleInitialRespawn(self);
 747         }
 748 }
 749
 750 /* replace items in minstagib
 751  * IT_STRENGTH   = invisibility
 752  * IT_NAILS      = extra lives
 753  * IT_INVINCIBLE = speed
 754  */
 755 void minstagib_items (float itemid)
 756 {
 757         // we don't want to replace dropped weapons ;)
 758         if (self.classname == "droppedweapon")
 759         {
 760                 self.ammo_cells = 25;
 761                 StartItem ("models/weapons/g_nex.md3",
 762                         "weapons/weaponpickup.wav", 15, 0,
 763                         "MinstaNex", 0, WEPBIT_MINSTANEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 764                 return;
 765         }
 766
 767         local float rnd;
 768         self.classname = "minstagib";
 769
 770         // replace rocket launchers and nex guns with ammo cells
 771         if (itemid == IT_CELLS)
 772         {
 773                 self.ammo_cells = 1;
 774                 StartItem ("models/items/a_cells.md3",
 775                         "misc/itempickup.wav", 45, 0,
 776                         "Nex Ammo", IT_CELLS, 0, 0, generic_pickupevalfunc, 100);
 777                 return;
 778         }
 779
 780         // randomize
 781         rnd = random() * 3;
 782         if (rnd <= 1)
 783                 itemid = IT_STRENGTH;
 784         else if (rnd <= 2)
 785                 itemid = IT_NAILS;
 786         else
 787                 itemid = IT_INVINCIBLE;
 788
 789         // replace with invis
 790         if (itemid == IT_STRENGTH)
 791         {
 792                 self.effects = EF_ADDITIVE;
 793                 self.strength_finished = 30;
 794                 StartItem ("models/items/g_strength.md3",
 795                         "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 796                         "Invisibility", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 797         }
 798         // replace with extra lives
 799         if (itemid == IT_NAILS)
 800         {
 801                 self.max_health = 1;
 802                 StartItem ("models/items/g_h100.md3",
 803                         "misc/megahealth.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 804                         "Extralife", IT_NAILS, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
 805
 806         }
 807         // replace with speed
 808         if (itemid == IT_INVINCIBLE)
 809         {
 810                 self.effects = EF_ADDITIVE;
 811                 self.invincible_finished = 30;
 812                 StartItem ("models/items/g_invincible.md3",
 813                         "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup,
 814                         "Speed", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, BOT_PICKUP_RATING_MID);
 815         }
 816
 817 }
 818
 819 float minst_no_auto_cells;
 820 void minst_remove_item (void) {
 821         if(minst_no_auto_cells)
 822                 remove(self);
 823 }
 824
 825 float weaponswapping;
 826 float internalteam;
 827
 828 void weapon_defaultspawnfunc(float wpn)
 829 {
 830         entity e;
 831         float t;
 832         var .float ammofield;
 833         string s;
 834         entity oldself;
 835         float i, j;
 836
 837         // set the respawntime in advance (so replaced weapons can copy it)
 838
 839         if(!self.respawntime)
 840         {
 841                 e = get_weaponinfo(wpn);
 842                 if(e.items == IT_SUPERWEAPON)
 843                 {
 844                         self.respawntime = g_pickup_respawntime_powerup;
 845                         self.respawntimejitter = g_pickup_respawntimejitter_powerup;
 846                 }
 847                 else
 848                 {
 849                         self.respawntime = g_pickup_respawntime_weapon;
 850                         self.respawntimejitter = g_pickup_respawntimejitter_weapon;
 851                 }
 852         }
 853
 854         if(self.classname != "droppedweapon" && self.classname != "replacedweapon")
 855         {
 856                 e = get_weaponinfo(wpn);
 857                 s = cvar_string(strcat("g_weaponreplace_", e.netname));
 858                 if(s == "0")
 859                 {
 860                         remove(self);
 861                         startitem_failed = TRUE;
 862                         return;
 863                 }
 864                 t = tokenize_console(s);
 865                 if(t >= 2)
 866                 {
 867                         self.team = --internalteam;
 868                         oldself = self;
 869                         for(i = 1; i < t; ++i)
 870                         {
 871                                 s = argv(i);
 872                                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 873                                 {
 874                                         e = get_weaponinfo(j);
 875                                         if(e.netname == s)
 876                                         {
 877                                                 self = spawn();
 878                                                 copyentity(oldself, self);
 879                                                 self.classname = "replacedweapon";
 880                                                 weapon_defaultspawnfunc(j);
 881                                                 break;
 882                                         }
 883                                 }
 884                                 if(j > WEP_LAST)
 885                                 {
 886                                         print("The weapon replace list for ", oldself.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 887                                 }
 888                         }
 889                         self = oldself;
 890                 }
 891                 if(t >= 1)
 892                 {
 893                         s = argv(0);
 894                         wpn = 0;
 895                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 896                         {
 897                                 e = get_weaponinfo(j);
 898                                 if(e.netname == s)
 899                                 {
 900                                         wpn = j;
 901                                         break;
 902                                 }
 903                         }
 904                         if(j > WEP_LAST)
 905                         {
 906                                 print("The weapon replace list for ", self.classname, " contains an unknown weapon ", s, ". Skipped.\n");
 907                         }
 908                 }
 909                 if(wpn == 0)
 910                 {
 911                         remove(self);
 912                         startitem_failed = TRUE;
 913                         return;
 914                 }
 915         }
 916
 917         e = get_weaponinfo(wpn);
 918
 919         if(e.items && e.items != IT_SUPERWEAPON)
 920         {
 921                 for(i = 0, j = 1; i < 24; ++i, j *= 2)
 922                 {
 923                         if(e.items & j)
 924                         {
 925                                 ammofield = Item_CounterField(j);
 926                                 if(!self.ammofield)
 927                                         self.ammofield = cvar(strcat("g_pickup_", Item_CounterFieldName(j)));
 928                         }
 929                 }
 930         }
 931         else
 932         {
 933                 self.flags |= FL_NO_WEAPON_STAY;
 934         }
 935
 936         // weapon stay isn't supported for teamed weapons
 937         if(self.team)
 938                 self.flags |= FL_NO_WEAPON_STAY;
 939
 940         if(g_weapon_stay == 2 && self.classname != "droppedweapon")
 941         {
 942                 self.ammo_shells = 0;
 943                 self.ammo_nails = 0;
 944                 self.ammo_cells = 0;
 945                 self.ammo_rockets = 0;
 946                 // weapon stay 2: don't use ammo on weapon pickups; instead
 947                 // initialize all ammo types to the pickup ammo unless set by g_start_ammo_*
 948         }
 949
 950         StartItem(e.model, "weapons/weaponpickup.wav", self.respawntime, self.respawntimejitter, e.message, 0, e.weapons, FL_WEAPON, weapon_pickupevalfunc, e.bot_pickupbasevalue);
 951         if (self.modelindex) // don't precache if self was removed
 952                 weapon_action(e.weapon, WR_PRECACHE);
 953 }
 954
 955 void spawnfunc_weapon_shotgun (void);
 956 void spawnfunc_weapon_uzi (void) {
 957         if(q3acompat_machineshotgunswap)
 958         if(self.classname != "droppedweapon")
 959         {
 960                 weapon_defaultspawnfunc(WEP_SHOTGUN);
 961                 return;
 962         }
 963         weapon_defaultspawnfunc(WEP_UZI);
 964 }
 965
 966 void spawnfunc_weapon_shotgun (void) {
 967         if(q3acompat_machineshotgunswap)
 968         if(self.classname != "droppedweapon")
 969         {
 970                 weapon_defaultspawnfunc(WEP_UZI);
 971                 return;
 972         }
 973         weapon_defaultspawnfunc(WEP_SHOTGUN);
 974 }
 975
 976 void spawnfunc_weapon_nex (void)
 977 {
 978         if (g_minstagib)
 979         {
 980                 minstagib_items(IT_CELLS);
 981                 self.think = minst_remove_item;
 982                 self.nextthink = time;
 983                 return;
 984         }
 985         weapon_defaultspawnfunc(WEP_NEX);
 986 }
 987
 988 void spawnfunc_weapon_minstanex (void)
 989 {
 990         if (g_minstagib)
 991         {
 992                 minstagib_items(IT_CELLS);
 993                 self.think = minst_remove_item;
 994                 self.nextthink = time;
 995                 return;
 996         }
 997         weapon_defaultspawnfunc(WEP_MINSTANEX);
 998 }
 999
1000 void spawnfunc_weapon_rocketlauncher (void)
1001 {
1002         if (g_minstagib)
1003         {
1004                 minstagib_items(IT_CELLS);
1005                 self.think = minst_remove_item;
1006                 self.nextthink = time;
1007                 return;
1008         }
1009         weapon_defaultspawnfunc(WEP_ROCKET_LAUNCHER);
1010 }
1011
1012 void spawnfunc_item_rockets (void) {
1013         if(!self.ammo_rockets)
1014                 self.ammo_rockets = g_pickup_rockets;
1015         StartItem ("models/items/a_rockets.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "rockets", IT_ROCKETS, 0, 0, commodity_pickupevalfunc, 3000);
1016 }
1017
1018 void spawnfunc_item_shells (void);
1019 void spawnfunc_item_bullets (void) {
1020         if(!weaponswapping)
1021         if(q3acompat_machineshotgunswap)
1022         if(self.classname != "droppedweapon")
1023         {
1024                 weaponswapping = TRUE;
1025                 spawnfunc_item_shells();
1026                 weaponswapping = FALSE;
1027                 return;
1028         }
1029
1030         if(!self.ammo_nails)
1031                 self.ammo_nails = g_pickup_nails;
1032         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "bullets", IT_NAILS, 0, 0, commodity_pickupevalfunc, 2000);
1033 }
1034
1035 void spawnfunc_item_cells (void) {
1036         if(!self.ammo_cells)
1037                 self.ammo_cells = g_pickup_cells;
1038         StartItem ("models/items/a_cells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "cells", IT_CELLS, 0, 0, commodity_pickupevalfunc, 2000);
1039 }
1040
1041 void spawnfunc_item_shells (void) {
1042         if(!weaponswapping)
1043         if(q3acompat_machineshotgunswap)
1044         if(self.classname != "droppedweapon")
1045         {
1046                 weaponswapping = TRUE;
1047                 spawnfunc_item_bullets();
1048                 weaponswapping = FALSE;
1049                 return;
1050         }
1051
1052         if(!self.ammo_shells)
1053                 self.ammo_shells = g_pickup_shells;
1054         StartItem ("models/items/a_shells.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "shells", IT_SHELLS, 0, 0, commodity_pickupevalfunc, 500);
1055 }
1056
1057 void spawnfunc_item_armor_small (void) {
1058         if(!self.armorvalue)
1059                 self.armorvalue = g_pickup_armorsmall;
1060         if(!self.max_armorvalue)
1061                 self.max_armorvalue = g_pickup_armorsmall_max;
1062         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Armor", IT_ARMOR_SHARD, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1063 }
1064
1065 void spawnfunc_item_armor_medium (void) {
1066         if(!self.armorvalue)
1067                 self.armorvalue = g_pickup_armormedium;
1068         if(!self.max_armorvalue)
1069                 self.max_armorvalue = g_pickup_armormedium_max;
1070         StartItem ("models/items/g_armormedium.md3", "misc/armor10.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "25 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1071 }
1072
1073 void spawnfunc_item_armor_big (void) {
1074         if(!self.armorvalue)
1075                 self.armorvalue = g_pickup_armorbig;
1076         if(!self.max_armorvalue)
1077                 self.max_armorvalue = g_pickup_armorbig_max;
1078         StartItem ("models/items/g_a50.md3", "misc/armor17_5.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "50 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, 20000);
1079 }
1080
1081 void spawnfunc_item_armor_large (void) {
1082         if(!self.armorvalue)
1083                 self.armorvalue = g_pickup_armorlarge;
1084         if(!self.max_armorvalue)
1085                 self.max_armorvalue = g_pickup_armorlarge_max;
1086         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Armor", IT_ARMOR, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1087 }
1088
1089 void spawnfunc_item_health_small (void) {
1090         if(!self.max_health)
1091                 self.max_health = g_pickup_healthsmall_max;
1092         if(!self.health)
1093                 self.health = g_pickup_healthsmall;
1094         StartItem ("models/items/g_h1.md3", "misc/minihealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "5 Health", IT_5HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1095 }
1096
1097 void spawnfunc_item_health_medium (void) {
1098         if(!self.max_health)
1099                 self.max_health = g_pickup_healthmedium_max;
1100         if(!self.health)
1101                 self.health = g_pickup_healthmedium;
1102         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.wav", g_pickup_respawntime_short, g_pickup_respawntimejitter_short, "25 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1103 }
1104
1105 void spawnfunc_item_health_large (void) {
1106         if(!self.max_health)
1107                 self.max_health = g_pickup_healthlarge_max;
1108         if(!self.health)
1109                 self.health = g_pickup_healthlarge;
1110         StartItem ("models/items/g_h50.md3", "misc/mediumhealth.wav", g_pickup_respawntime_medium, g_pickup_respawntimejitter_medium, "50 Health", IT_25HP, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_MID);
1111 }
1112
1113 void spawnfunc_item_health_mega (void) {
1114         if(!cvar("g_powerup_superhealth"))
1115                 return;
1116
1117         if(g_arena && !cvar("g_arena_powerups"))
1118                 return;
1119
1120         if(g_minstagib) {
1121                 minstagib_items(IT_NAILS);
1122         } else {
1123                 if(!self.max_health)
1124                         self.max_health = g_pickup_healthmega_max;
1125                 if(!self.health)
1126                         self.health = g_pickup_healthmega;
1127                 StartItem ("models/items/g_h100.md3", "misc/megahealth.wav", g_pickup_respawntime_long, g_pickup_respawntimejitter_long, "100 Health", IT_HEALTH, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_HIGH);
1128         }
1129 }
1130
1131 // support old misnamed entities
1132 void spawnfunc_item_armor1() { spawnfunc_item_armor_small(); }  // FIXME: in Quake this is green armor, in Nexuiz maps it is an armor shard
1133 void spawnfunc_item_armor25() { spawnfunc_item_armor_large(); }
1134 void spawnfunc_item_health1() { spawnfunc_item_health_small(); }
1135 void spawnfunc_item_health25() { spawnfunc_item_health_medium(); }
1136 void spawnfunc_item_health100() { spawnfunc_item_health_mega(); }
1137
1138 void spawnfunc_item_strength (void) {
1139         if(!cvar("g_powerup_strength"))
1140                 return;
1141
1142         if(g_arena && !cvar("g_arena_powerups"))
1143                 return;
1144
1145         if(g_minstagib) {
1146                 minstagib_items(IT_STRENGTH);
1147         } else {
1148                 precache_sound("weapons/strength_fire.wav");
1149                 self.strength_finished = 30;
1150                 self.effects = EF_ADDITIVE;
1151                 StartItem ("models/items/g_strength.md3", "misc/powerup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Strength Powerup", IT_STRENGTH, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1152         }
1153 }
1154
1155 void spawnfunc_item_invincible (void) {
1156         if(!cvar("g_powerup_shield"))
1157                 return;
1158
1159         if(g_arena && !cvar("g_arena_powerups"))
1160                 return;
1161
1162         if(g_minstagib) {
1163                 minstagib_items(IT_INVINCIBLE);
1164         } else {
1165                 self.invincible_finished = 30;
1166                 self.effects = EF_ADDITIVE;
1167                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Shield", IT_INVINCIBLE, 0, FL_POWERUP, generic_pickupevalfunc, 100000);
1168         }
1169 }
1170
1171 void spawnfunc_item_minst_cells (void) {
1172         if (g_minstagib)
1173         {
1174                 minst_no_auto_cells = 1;
1175                 minstagib_items(IT_CELLS);
1176         }
1177         else
1178                 remove(self);
1179 }
1180
1181 // compatibility:
1182 void spawnfunc_item_quad (void) {self.classname = "item_strength";spawnfunc_item_strength();}
1183
1184 float target_item_func_set(float a, float b)
1185 {
1186         if(b == 0)
1187                 return a;
1188         else if(b < 0)
1189                 return 0;
1190         else
1191                 return b;
1192 }
1193
1194 float target_item_func_min(float a, float b)
1195 {
1196         if(b == 0)
1197                 return a;
1198         else if(b < 0)
1199                 return 0;
1200         else
1201                 return min(a, b);
1202 }
1203
1204 float target_item_func_max(float a, float b)
1205 {
1206         return max(a, b);
1207 }
1208
1209 float target_item_func_bitset(float a, float b)
1210 {
1211         return b;
1212 }
1213
1214 float target_item_func_and(float a, float b)
1215 {
1216         return a & b;
1217 }
1218
1219 float target_item_func_itembitset(float a, float b)
1220 {
1221         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | b;
1222 }
1223
1224 float target_item_func_itemand(float a, float b)
1225 {
1226         return (a - (a & (IT_PICKUPMASK | IT_STRENGTH | IT_INVINCIBLE))) | (a & b);
1227 }
1228
1229 float target_item_func_or(float a, float b)
1230 {
1231         return a | b;
1232 }
1233
1234 float target_item_func_andnot(float a, float b)
1235 {
1236         return a - (a & b);
1237 }
1238
1239 float target_item_changed;
1240 void target_item_change(float binary, .float field, float(float a, float b) func, string sound_increase, string sound_decrease)
1241 {
1242         float n, d;
1243         n = func(activator.field, self.field);
1244
1245         if(binary)
1246         {
1247                 d = n & activator.field;
1248                 if(d != n) // bits added?
1249                         d = +1;
1250                 else if(d != activator.field) // bits removed?
1251                         d = -1;
1252                 else
1253                         d = 0;
1254         }
1255         else
1256                 d = n - activator.field;
1257
1258         if(d < 0)
1259         {
1260                 if(sound_decrease != "")
1261                         sound (activator, CHAN_AUTO, sound_decrease, VOL_BASE, ATTN_NORM);
1262                 target_item_changed = 1;
1263         }
1264         else if(d > 0)
1265         {
1266                 if(sound_increase != "")
1267                         sound (activator, CHAN_AUTO, sound_increase, VOL_BASE, ATTN_NORM);
1268                 target_item_changed = 1;
1269         }
1270         activator.field = n;
1271 }
1272
1273 void target_items_use (void)
1274 {
1275         float h0, a0, f0;
1276
1277         if(activator.classname == "droppedweapon")
1278         {
1279                 EXACTTRIGGER_TOUCH;
1280                 remove(activator);
1281                 return;
1282         }
1283
1284         if(activator.classname != "player")
1285                 return;
1286         if(activator.deadflag != DEAD_NO)
1287                 return;
1288         EXACTTRIGGER_TOUCH;
1289
1290         entity e;
1291         for(e = world; (e = find(e, classname, "droppedweapon")); )
1292                 if(e.enemy == activator)
1293                         remove(e);
1294
1295         float _switchweapon;
1296         _switchweapon = FALSE;
1297         if (activator.autoswitch)
1298                 if (activator.switchweapon == w_getbestweapon(activator))
1299                         _switchweapon = TRUE;
1300
1301         a0 = activator.armorvalue;
1302         h0 = activator.health;
1303         f0 = activator.ammo_fuel;
1304         target_item_changed = 0;
1305
1306         if(self.spawnflags == 0) // SET
1307         {
1308                 target_item_change(0, ammo_shells, target_item_func_set, "misc/itempickup.wav", "");
1309                 target_item_change(0, ammo_nails, target_item_func_set, "misc/itempickup.wav", "");
1310                 target_item_change(0, ammo_rockets, target_item_func_set, "misc/itempickup.wav", "");
1311                 target_item_change(0, ammo_cells, target_item_func_set, "misc/itempickup.wav", "");
1312                 target_item_change(0, ammo_fuel, target_item_func_set, "misc/itempickup.wav", "");
1313                 target_item_change(0, health, target_item_func_set, "misc/megahealth.wav", "");
1314                 target_item_change(0, armorvalue, target_item_func_set, "misc/armor25.wav", "");
1315                 target_item_change(1, items, target_item_func_itembitset, "misc/powerup.wav", "misc/poweroff.wav");
1316                 target_item_change(1, weapons, target_item_func_bitset, "weapons/weaponpickup.wav", "");
1317
1318                 if((self.items & activator.items) & IT_STRENGTH)
1319                         activator.strength_finished = time + self.strength_finished;
1320                 if((self.items & activator.items) & IT_INVINCIBLE)
1321                         activator.invincible_finished = time + self.invincible_finished;
1322         }
1323         else if(self.spawnflags == 1) // AND/MIN
1324         {
1325                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1326                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1327                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1328                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1329                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1330                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1331                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1332                 target_item_change(1, items, target_item_func_itemand, "misc/powerup.wav", "misc/poweroff.wav");
1333                 target_item_change(1, weapons, target_item_func_and, "weapons/weaponpickup.wav", "");
1334
1335                 if((self.items & activator.items) & IT_STRENGTH)
1336                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1337                 if((self.items & activator.items) & IT_INVINCIBLE)
1338                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1339         }
1340         else if(self.spawnflags == 2) // OR/MAX
1341         {
1342                 target_item_change(0, ammo_shells, target_item_func_max, "misc/itempickup.wav", "");
1343                 target_item_change(0, ammo_nails, target_item_func_max, "misc/itempickup.wav", "");
1344                 target_item_change(0, ammo_rockets, target_item_func_max, "misc/itempickup.wav", "");
1345                 target_item_change(0, ammo_cells, target_item_func_max, "misc/itempickup.wav", "");
1346                 target_item_change(0, ammo_fuel, target_item_func_max, "misc/itempickup.wav", "");
1347                 target_item_change(0, health, target_item_func_max, "misc/megahealth.wav", "");
1348                 target_item_change(0, armorvalue, target_item_func_max, "misc/armor25.wav", "");
1349                 target_item_change(1, items, target_item_func_or, "misc/powerup.wav", "misc/poweroff.wav");
1350                 target_item_change(1, weapons, target_item_func_or, "weapons/weaponpickup.wav", "");
1351
1352                 if((self.items & activator.items) & IT_STRENGTH)
1353                         activator.strength_finished = max(activator.strength_finished, time + self.strength_finished);
1354                 if((self.items & activator.items) & IT_INVINCIBLE)
1355                         activator.invincible_finished = max(activator.invincible_finished, time + self.invincible_finished);
1356         }
1357         else if(self.spawnflags == 4) // ANDNOT/MIN
1358         {
1359                 target_item_change(0, ammo_shells, target_item_func_min, "misc/itempickup.wav", "");
1360                 target_item_change(0, ammo_nails, target_item_func_min, "misc/itempickup.wav", "");
1361                 target_item_change(0, ammo_rockets, target_item_func_min, "misc/itempickup.wav", "");
1362                 target_item_change(0, ammo_cells, target_item_func_min, "misc/itempickup.wav", "");
1363                 target_item_change(0, ammo_fuel, target_item_func_min, "misc/itempickup.wav", "");
1364                 target_item_change(0, health, target_item_func_min, "misc/megahealth.wav", "");
1365                 target_item_change(0, armorvalue, target_item_func_min, "misc/armor25.wav", "");
1366                 target_item_change(1, items, target_item_func_andnot, "misc/powerup.wav", "misc/poweroff.wav");
1367                 target_item_change(1, weapons, target_item_func_andnot, "weapons/weaponpickup.wav", "");
1368
1369                 if((self.items & activator.items) & IT_STRENGTH)
1370                         activator.strength_finished = min(activator.strength_finished, time + self.strength_finished);
1371                 if((self.items & activator.items) & IT_INVINCIBLE)
1372                         activator.invincible_finished = min(activator.invincible_finished, time + self.invincible_finished);
1373         }
1374
1375         if not(activator.items & IT_STRENGTH)
1376                 activator.strength_finished = 0;
1377         if not(activator.items & IT_INVINCIBLE)
1378                 activator.invincible_finished = 0;
1379
1380         if(activator.health > h0)
1381                 activator.pauserothealth_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1382         else if(activator.health < h0)
1383                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_health_regen"));
1384
1385         if(activator.ammo_fuel > f0)
1386                 activator.pauserotfuel_finished = max(activator.pauserotfuel_finished, time + cvar("g_balance_pause_fuel_rot"));
1387         else if(activator.ammo_fuel < f0)
1388                 activator.pauseregen_finished = max(activator.pauseregen_finished, time + cvar("g_balance_pause_fuel_regen"));
1389
1390         if(activator.armorvalue > a0)
1391                 activator.pauserotarmor_finished = max(activator.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
1392
1393         if not(activator.weapons & W_WeaponBit(activator.switchweapon))
1394                 _switchweapon = TRUE;
1395         if(_switchweapon)
1396                 W_SwitchWeapon_Force(activator, w_getbestweapon(activator));
1397
1398         if(target_item_changed)
1399                 centerprint(activator, self.message);
1400 }
1401
1402 void spawnfunc_target_items (void)
1403 {
1404         float n, i, j;
1405         entity e;
1406         self.use = target_items_use;
1407         if(!self.strength_finished)
1408                 self.strength_finished = cvar("g_balance_powerup_strength_time");
1409         if(!self.invincible_finished)
1410                 self.invincible_finished = cvar("g_balance_powerup_invincible_time");
1411
1412         precache_sound("misc/itempickup.wav");
1413         precache_sound("misc/itempickup.wav");
1414         precache_sound("misc/itempickup.wav");
1415         precache_sound("misc/itempickup.wav");
1416         precache_sound("misc/megahealth.wav");
1417         precache_sound("misc/armor25.wav");
1418         precache_sound("misc/powerup.wav");
1419         precache_sound("misc/poweroff.wav");
1420         precache_sound("weapons/weaponpickup.wav");
1421
1422         n = tokenize_console(self.netname);
1423         for(i = 0; i < n; ++i)
1424         {
1425                 if     (argv(i) == "unlimited_ammo")         self.items |= IT_UNLIMITED_AMMO;
1426                 else if(argv(i) == "unlimited_weapon_ammo")  self.items |= IT_UNLIMITED_WEAPON_AMMO;
1427                 else if(argv(i) == "unlimited_superweapons") self.items |= IT_UNLIMITED_SUPERWEAPONS;
1428                 else if(argv(i) == "strength")               self.items |= IT_STRENGTH;
1429                 else if(argv(i) == "invincible")             self.items |= IT_INVINCIBLE;
1430                 else if(argv(i) == "jetpack")                self.items |= IT_JETPACK;
1431                 else if(argv(i) == "fuel_regen")             self.items |= IT_FUEL_REGEN;
1432                 else
1433                 {
1434                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
1435                         {
1436                                 e = get_weaponinfo(j);
1437                                 if(argv(i) == e.netname)
1438                                 {
1439                                         self.weapons |= e.weapons;
1440                                         if(self.spawnflags == 0 || self.spawnflags == 2)
1441                                                 weapon_action(e.weapon, WR_PRECACHE);
1442                                         break;
1443                                 }
1444                         }
1445                         if(j > WEP_LAST)
1446                                 print("target_items: invalid item ", argv(i), "\n");
1447                 }
1448         }
1449 }
1450
1451 void spawnfunc_item_fuel(void)
1452 {
1453         if(!self.ammo_fuel)
1454                 self.ammo_fuel = g_pickup_fuel;
1455         StartItem ("models/items/g_fuel.md3", "misc/itempickup.wav", g_pickup_respawntime_ammo, g_pickup_respawntimejitter_ammo, "Fuel", IT_FUEL, 0, 0, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1456 }
1457
1458 void spawnfunc_item_fuel_regen(void)
1459 {
1460         if(start_items & IT_FUEL_REGEN)
1461         {
1462                 spawnfunc_item_fuel();
1463                 return;
1464         }
1465         StartItem ("models/items/g_fuelregen.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Fuel regenerator", IT_FUEL_REGEN, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1466 }
1467
1468 void spawnfunc_item_jetpack(void)
1469 {
1470         if(g_grappling_hook)
1471                 return; // sorry, but these two can't coexist (same button); spawn fuel instead
1472         if(!self.ammo_fuel)
1473                 self.ammo_fuel = g_pickup_fuel_jetpack;
1474         if(start_items & IT_JETPACK)
1475         {
1476                 spawnfunc_item_fuel();
1477                 return;
1478         }
1479         StartItem ("models/items/g_jetpack.md3", "misc/itempickup.wav", g_pickup_respawntime_powerup, g_pickup_respawntimejitter_powerup, "Jet pack", IT_JETPACK, 0, FL_POWERUP, commodity_pickupevalfunc, BOT_PICKUP_RATING_LOW);
1480 }