data/qcsrc/server/t_items.qc

   1 //void Item_ClearRespawnEffect (void) {
   2 //      self.effects = self.effects - (self.effects & EF_STARDUST);
   3 //}
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // LordHavoc: replaced respawn stardust effect with a custom te_wizspike
  13         te_wizspike(self.origin + self.mins_z * '0 0 1' + '0 0 48');
  14         //// Savage: Add simple Respawn effect and make sure it gets removed
  15         //self.effects = self.effects | EF_STARDUST;
  16         //self.think = Item_ClearRespawnEffect;
  17         //self.nextthink = time + 0.1;
  18 }
  19
  20 void Item_Touch (void)
  21 {
  22         local entity oldself;
  23         local float _switchweapon;
  24
  25         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  26         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  27         {
  28                 remove(self);
  29                 return;
  30         }
  31         if (other.classname != "player")
  32                 return;
  33         if (other.deadflag)
  34                 return;
  35         if (self.solid != SOLID_TRIGGER)
  36                 return;
  37         if (self.health && other.health >= other.max_health)
  38                 return;
  39         if (self.owner == other)
  40                 return;
  41         // Savage: Remove the respawn effect if still present
  42         self.effects = self.effects - (self.effects & EF_STARDUST);
  43
  44         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  45
  46         // in case the player has autoswitch enabled do the following:
  47         // if the player is using their best weapon before items are given, they
  48         // probably want to switch to an even better weapon after items are given
  49         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)) || cvar("g_minstagib"));
  50
  51         if (cvar("g_minstagib"))
  52         {
  53                 if (self.ammo_cells)
  54                 {
  55                         // play some cool sounds ;)
  56                         centerprint(other, "\n");
  57                         if(other.health <= 5)
  58                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
  59                         else if(other.health < 50)
  60                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
  61                         // sound not available
  62                         // else if(self.items == IT_CELLS)
  63                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
  64
  65                         if (self.items & IT_NEX)
  66                                 W_GiveWeapon (other, IT_NEX, "Nex");
  67                         if (self.ammo_cells)
  68                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  69                         other.health = 100;
  70                 }
  71
  72                 // extralife powerup
  73                 if (self.max_health)
  74                 {
  75                         // sound not available
  76                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
  77                         other.armorvalue = other.armorvalue + cvar("g_minstagib_extralives");
  78                         sprint(other, "^3You picked up some extra lives\n");
  79                 }
  80
  81                 // invis powerup
  82                 if (self.strength_finished)
  83                 {
  84                         // sound not available
  85                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
  86                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  87                 }
  88
  89                 // speed powerup
  90                 if (self.invincible_finished)
  91                 {
  92                         // sound not available
  93                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
  94                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  95                 }
  96         }
  97         else
  98         {
  99                 if (cvar("deathmatch") == 2 || cvar("g_weapon_stay"))
 100                 {
 101                         if (self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
 102                                 return;
 103                         if (other.items & self.items && self.flags & FL_TOSSED) // don't let players stack ammo by tossing weapons
 104                                 return;
 105                 }
 106
 107                 if (self.ammo_shells)
 108                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
 109                 if (self.ammo_nails)
 110                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
 111                 if (self.ammo_rockets)
 112                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
 113                 if (self.ammo_cells)
 114                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
 115
 116                 if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 117                 if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 118                 if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 119                 if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 120                 if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 121                 if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 122                 if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 123                 if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 124
 125                 if (self.strength_finished)
 126                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 127                 if (self.invincible_finished)
 128                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 129                 //if (self.speed_finished)
 130                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 131                 //if (self.slowmo_finished)
 132                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 133
 134                 if (self.max_health)
 135                 {
 136                         other.health = other.health + self.max_health;
 137                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 138                 }
 139                 if (self.health && other.health < other.max_health)
 140                         other.health = min(other.health + self.health, other.max_health);
 141                 if (self.armorvalue)
 142                 {
 143                         other.armorvalue = other.armorvalue + self.armorvalue;
 144                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 145                 }
 146         }
 147
 148         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 149
 150         oldself = self;
 151         self = other;
 152
 153         if (_switchweapon)
 154                 self.switchweapon = w_getbestweapon(self);
 155         if (self.switchweapon != self.weapon)
 156                 self.cnt = self.weapon;
 157
 158         self = oldself;
 159
 160         if (self.classname == "droppedweapon")
 161                 remove (self);
 162         else if(self.flags & FL_WEAPON && (cvar("deathmatch") == 2 || cvar("g_weapon_stay")))
 163                 return;
 164         else
 165         {
 166                 self.solid = SOLID_NOT;
 167                 self.model = string_null;
 168                 self.nextthink = time + self.respawntime;
 169                 self.think = Item_Respawn;
 170                 setorigin (self, self.origin);
 171         }
 172 }
 173
 174 // Savage: used for item garbage-collection
 175 // TODO: perhaps nice special effect?
 176 void RemoveItem(void) = {
 177         remove(self);
 178 }
 179
 180 // pickup evaluation functions
 181 // these functions decide how desirable an item is to the bots
 182
 183 float(entity player, entity item) generic_pickupevalfunc = {return item.bot_pickupbasevalue;};
 184
 185 float(entity player, entity item) weapon_pickupevalfunc =
 186 {
 187         // if we already have the weapon, rate it 1/5th normal value
 188         if ((player.items & item.items) == item.items)
 189                 return item.bot_pickupbasevalue * 0.2;
 190         return item.bot_pickupbasevalue;
 191 };
 192
 193 float(entity player, entity item) commodity_pickupevalfunc =
 194 {
 195         float c;
 196         c = 0;
 197         // TODO: figure out if the player even has the weapon this ammo is for?
 198         // may not affect strategy much though...
 199         // find out how much ammo the player has, in terms of this ammo pickup
 200         // (how many of these ammo pickups it would take to total the player's
 201         // current ammo)
 202         if (item.ammo_shells)
 203                 c = c + player.ammo_shells / item.ammo_shells;
 204         if (item.ammo_nails)
 205                 c = c + player.ammo_nails / item.ammo_nails;
 206         if (item.ammo_rockets)
 207                 c = c + player.ammo_rockets / item.ammo_rockets;
 208         if (item.ammo_cells)
 209                 c = c + player.ammo_cells / item.ammo_cells;
 210         if (item.armorvalue)
 211                 c = c + player.armorvalue / item.armorvalue;
 212         if (item.health)
 213                 c = c + player.health / item.health / 10;
 214         // the more ammo the player has, the less desirable this pickup becomes
 215         c = 1 / (1 + c);
 216
 217         if (cvar("deathmatch") == 2) // weapon stay is on, so weapons the player already has are of no interest
 218         if (item.flags & FL_WEAPON)
 219         if (self.items & item.items)
 220         if (item.classname != "droppedweapon")
 221                 c = 0;
 222
 223         return item.bot_pickupbasevalue * c;
 224 };
 225
 226
 227 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags, float(entity player, entity item) pickupevalfunc, float pickupbasevalue)
 228 {
 229         vector org;
 230         org = self.origin;
 231
 232         startitem_failed = FALSE;
 233
 234         if (self.classname != "droppedweapon" && !self.noalign)
 235         {
 236                 vector z_offset;
 237
 238                 z_offset = '0 0 1';
 239
 240                 if (itemid == IT_SHELLS)
 241                         z_offset = '0 0 4';
 242                 else if (itemid == IT_ROCKETS)
 243                         z_offset = '0 0 4';
 244                 else if (itemid == IT_NAILS)
 245                         z_offset = '0 0 0';
 246                 else if (itemid == IT_25HP)
 247                         z_offset = '0 0 5';
 248                 else if (itemid == IT_ARMOR)
 249                         z_offset = '0 0 3';
 250
 251                 org = find_floor(org) + z_offset;
 252                 setorigin(self, org);
 253         }
 254
 255         if (self.classname != "droppedweapon")
 256                 waypoint_spawnforitem(self);
 257
 258         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
 259                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemid != IT_HEALTH)
 260         {
 261                 startitem_failed = TRUE;
 262                 remove (self);
 263                 return;
 264         }
 265
 266         if (cvar("g_minstagib"))
 267         {
 268                 // don't remove dropped items and powerups
 269                 if (self.classname != "droppedweapon" &&
 270                     self.classname != "minstagib")
 271                 {
 272                         startitem_failed = TRUE;
 273                         remove (self);
 274                         return;
 275                 }
 276         }
 277
 278         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 279         {
 280                 startitem_failed = TRUE;
 281                 remove(self);
 282                 return;
 283         }
 284
 285         if(cvar("g_instagib") || cvar("g_rocketarena"))
 286         {
 287                 startitem_failed = TRUE;
 288                 remove(self);
 289                 return;
 290         }
 291
 292         if (self.classname == "droppedweapon")
 293         {
 294                 // don't drop if in a NODROP zone (such as lava)
 295                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 296                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 297                 {
 298                         startitem_failed = TRUE;
 299                         remove(self);
 300                         return;
 301                 }
 302         }
 303
 304         if(itemid & (IT_STRENGTH | IT_INVINCIBLE | IT_HEALTH | IT_ARMOR | IT_KEY1 | IT_KEY2 |
 305                                 IT_ROCKET_LAUNCHER | IT_HAGAR | IT_NEX | IT_CRYLINK | IT_ELECTRO |
 306                                 IT_GRENADE_LAUNCHER | IT_UZI | IT_SHOTGUN | IT_LASER) && self.classname != "droppedweapon")
 307         {
 308                 self.target = "###item###"; // for finding the nearest item using find()
 309         }
 310         self.bot_pickup = TRUE;
 311         self.bot_pickupevalfunc = pickupevalfunc;
 312         self.bot_pickupbasevalue = pickupbasevalue;
 313         self.mdl = itemmodel;
 314         //self.noise = pickupsound;
 315         self.item_pickupsound = pickupsound;
 316         // let mappers override respawntime
 317         if (!self.respawntime)
 318                 self.respawntime = defaultrespawntime;
 319         self.netname = itemname;
 320         self.items = itemid;
 321         self.flags = FL_ITEM | itemflags;
 322         setmodel (self, self.mdl);
 323         if (itemflags & FL_WEAPON)
 324         {
 325                 setorigin (self, self.origin + '0 0 23');
 326                 setsize (self, '-12 -12 -12', '12 12 12');
 327
 328                 // neutral team color for pickup weapons
 329                 self.colormap = 160 * 1024 + 160;
 330         }
 331         else
 332         {
 333                 setorigin (self, self.origin + '0 0 25');
 334         //      setsize (self, '-8 -8 -5', '8 8 8');
 335         }
 336         self.movetype = MOVETYPE_TOSS;
 337         self.solid = SOLID_TRIGGER;
 338         self.touch = Item_Touch;
 339
 340         // Savage: remove thrown items after a certain period of time ("garbage collection")
 341         if (self.classname == "droppedweapon")
 342         {
 343                 self.think = RemoveItem;
 344                 self.nextthink = time + 60;
 345         }
 346         else
 347         {
 348                 self.movetype = MOVETYPE_NONE;
 349                 setorigin(self, org);
 350         }
 351
 352         if (cvar("g_fullbrightitems"))
 353                 self.effects = self.effects | EF_FULLBRIGHT;
 354 }
 355
 356 /* replace items in minstagib
 357  * IT_STRENGTH   = invisibility
 358  * IT_NAILS      = extra lives
 359  * IT_INVINCIBLE = speed
 360  */
 361 void minstagib_items (float itemid)
 362 {
 363         // we don't want to replace dropped weapons ;)
 364         if (self.classname == "droppedweapon")
 365         {
 366                 self.ammo_cells = 25;
 367                 StartItem ("models/weapons/g_nex.md3",
 368                         "weapons/weaponpickup.ogg", 15,
 369                         "Nex Gun", IT_NEX, FL_WEAPON, generic_pickupevalfunc, 1000);
 370                 return;
 371         }
 372
 373         local float rnd;
 374         self.classname = "minstagib";
 375
 376         // replace rocket launchers and nex guns with ammo cells
 377         if (itemid == IT_CELLS)
 378         {
 379                 self.ammo_cells = 1;
 380                 StartItem ("models/items/a_cells.md3",
 381                         "misc/itempickup.ogg", 45,
 382                         "Nex Ammo", IT_CELLS, 0, generic_pickupevalfunc, 100);
 383                 return;
 384         }
 385
 386         // randomize
 387         rnd = random() * 3;
 388         if (rnd <= 1)
 389                 itemid = IT_STRENGTH;
 390         else if (rnd <= 2)
 391                 itemid = IT_NAILS;
 392         else
 393                 itemid = IT_INVINCIBLE;
 394
 395         // replace with invis
 396         if (itemid == IT_STRENGTH)
 397         {
 398                 self.effects = EF_ADDITIVE;
 399                 self.strength_finished = 30;
 400                 StartItem ("models/items/g_strength.md3",
 401                         "misc/powerup.ogg", 120,
 402                         "Invisibility", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 1000);
 403         }
 404         // replace with extra lives
 405         if (itemid == IT_NAILS)
 406         {
 407                 self.max_health = 1;
 408                 StartItem ("models/items/g_h100.md3",
 409                         "misc/megahealth.ogg", 120,
 410                         "Extralife", IT_NAILS, FL_POWERUP, generic_pickupevalfunc, 1000);
 411
 412         }
 413         // replace with ammo
 414         if (itemid == IT_INVINCIBLE)
 415         {
 416                 self.effects = EF_ADDITIVE;
 417                 self.invincible_finished = 30;
 418                 StartItem ("models/items/g_invincible.md3",
 419                         "misc/powerup_shield.ogg", 120,
 420                         "Speed", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 1000);
 421         }
 422
 423 }
 424
 425 void weapon_uzi (void) {
 426         self.ammo_nails = 120;
 427         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON, weapon_pickupevalfunc, 1000);
 428 }
 429
 430 void weapon_shotgun (void) {
 431         self.ammo_shells = 15;
 432         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON, weapon_pickupevalfunc, 1000);
 433 }
 434
 435 void weapon_grenadelauncher (void) {
 436         self.ammo_rockets = 15;
 437         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 438 }
 439
 440 void weapon_electro (void) {
 441         self.ammo_cells = 25;
 442         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON, weapon_pickupevalfunc, 1000);
 443 }
 444
 445 void weapon_crylink (void) {
 446         self.ammo_cells = 25;
 447         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON, weapon_pickupevalfunc, 1000);
 448 }
 449
 450 void weapon_nex (void) {
 451         if (cvar("g_minstagib")) {
 452                 minstagib_items(IT_CELLS);
 453         } else {
 454                 float nextime;
 455                 self.ammo_cells = 25;
 456                 nextime = cvar("g_balance_nex_respawntime_modifier");
 457                 if(nextime)
 458                         nextime = 15 * nextime;
 459                 else
 460                         nextime = 15;
 461                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", nextime, W_Name(WEP_NEX), IT_NEX, FL_WEAPON, weapon_pickupevalfunc, 1000);
 462         }
 463 }
 464
 465 void weapon_hagar (void) {
 466         self.ammo_rockets = 15;
 467         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON, weapon_pickupevalfunc, 1000);
 468 }
 469
 470 void weapon_rocketlauncher (void) {
 471         if (cvar("g_minstagib")) {
 472                 minstagib_items(IT_CELLS);
 473         } else {
 474                 self.ammo_rockets = 15;
 475                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON, weapon_pickupevalfunc, 1000);
 476         }
 477 }
 478
 479 void item_rockets (void) {
 480         self.ammo_rockets = 15;
 481         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0, commodity_pickupevalfunc, 100);
 482 }
 483
 484 void item_bullets (void) {
 485         self.ammo_nails = 120;
 486         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0, commodity_pickupevalfunc, 100);
 487 }
 488
 489 void item_cells (void) {
 490         self.ammo_cells = 25;
 491         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0, commodity_pickupevalfunc, 100);
 492 }
 493
 494 void item_shells (void) {
 495         self.ammo_shells = 15;
 496         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0, commodity_pickupevalfunc, 100);
 497 }
 498
 499 void item_armor1 (void) {
 500         self.armorvalue = 5;
 501         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", IT_ARMOR_SHARD, 0, commodity_pickupevalfunc, 100);
 502 }
 503
 504 void item_armor25 (void) {
 505         self.armorvalue = 100;
 506         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", IT_ARMOR, 0, commodity_pickupevalfunc, 2000);
 507 }
 508
 509 void item_health1 (void) {
 510         self.max_health = 5;
 511         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", IT_5HP, 0, commodity_pickupevalfunc, 100);
 512 }
 513
 514 void item_health25 (void) {
 515         self.max_health = 25;
 516         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", IT_25HP, 0, commodity_pickupevalfunc, 500);
 517 }
 518
 519 void item_health100 (void) {
 520         if(!cvar("g_powerup_superhealth"))
 521                 return;
 522
 523         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 524                 return;
 525
 526         if(cvar("g_minstagib")) {
 527                 minstagib_items(IT_NAILS);
 528         } else {
 529                 self.max_health = 100;
 530                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", IT_HEALTH, 0, commodity_pickupevalfunc, 2000);
 531         }
 532 }
 533
 534 void item_strength (void) {
 535         if(!cvar("g_powerup_strength"))
 536                 return;
 537
 538         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 539                 return;
 540
 541         if(cvar("g_minstagib")) {
 542                 minstagib_items(IT_STRENGTH);
 543         } else {
 544                 self.strength_finished = 30;
 545                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP, generic_pickupevalfunc, 10000);
 546         }
 547 }
 548
 549 void item_invincible (void) {
 550         if(!cvar("g_powerup_shield"))
 551                 return;
 552
 553         if(cvar("g_arena") && !cvar("g_arena_powerups"))
 554                 return;
 555
 556         if(cvar("g_minstagib")) {
 557                 minstagib_items(IT_INVINCIBLE);
 558         } else {
 559                 self.invincible_finished = 30;
 560                 self.effects = EF_ADDITIVE;
 561                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP, generic_pickupevalfunc, 10000);
 562         }
 563 }
 564 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP, generic_pickupevalfunc, 10000);}
 565 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP, generic_pickupevalfunc, 10000);}
 566
 567 // compatibility:
 568 void item_quad (void) {self.classname = "item_strength";item_strength();}
 569
 570 void misc_models (void)
 571 {
 572         precache_model (self.model);
 573         setmodel (self, self.model);
 574         setsize (self, self.mins, self.maxs);
 575 }
 576
 577
 578
 579
 580
 581 floatfield Item_CounterField(float it)
 582 {
 583         switch(it)
 584         {
 585                 case IT_SHELLS:      return ammo_shells;
 586                 case IT_NAILS:       return ammo_nails;
 587                 case IT_ROCKETS:     return ammo_rockets;
 588                 case IT_CELLS:       return ammo_cells;
 589                 case IT_5HP:         return health;
 590                 case IT_25HP:        return health;
 591                 case IT_HEALTH:      return health;
 592                 case IT_ARMOR_SHARD: return armorvalue;
 593                 case IT_ARMOR:       return armorvalue;
 594                 // add more things here (health, armor)
 595                 default:             error("requested item has no counter field");
 596         }
 597 }
 598
 599 float Item_WeaponCode(float it)
 600 {
 601         switch(it)
 602         {
 603                 case IT_LASER:            return WEP_LASER;
 604                 case IT_SHOTGUN:          return WEP_SHOTGUN;
 605                 case IT_UZI:              return WEP_UZI;
 606                 case IT_GRENADE_LAUNCHER: return WEP_GRENADE_LAUNCHER;
 607                 case IT_ELECTRO:          return WEP_ELECTRO;
 608                 case IT_CRYLINK:          return WEP_CRYLINK;
 609                 case IT_NEX:              return WEP_NEX;
 610                 case IT_HAGAR:            return WEP_HAGAR;
 611                 case IT_ROCKET_LAUNCHER:  return WEP_ROCKET_LAUNCHER;
 612                 default:                  return 0;
 613         }
 614 }
 615
 616 spawnfunc Item_SpawnFunc(float it)
 617 {
 618         switch(it)
 619         {
 620                 case IT_SHOTGUN:          return weapon_shotgun;
 621                 case IT_UZI:              return weapon_uzi;
 622                 case IT_GRENADE_LAUNCHER: return weapon_grenadelauncher;
 623                 case IT_ELECTRO:          return weapon_electro;
 624                 case IT_CRYLINK:          return weapon_crylink;
 625                 case IT_NEX:              return weapon_nex;
 626                 case IT_HAGAR:            return weapon_hagar;
 627                 case IT_ROCKET_LAUNCHER:  return weapon_rocketlauncher;
 628                 // add all other item spawn functions here
 629                 default:                  error("requested item can't be spawned");
 630         }
 631 }