ctf: always sort scoreboard by personal score
[divverent/nexuiz.git] / data / qcsrc / server / scores_rules.qc
1 float c1, c2, c3, c4;
2 void CheckAllowedTeams (entity for_whom);
3
4 // NOTE: SP_ constants may not be >= MAX_SCORE; ST_constants may not be >= MAX_TEAMSCORE
5 // scores that should be in all modes:
6 float ScoreRules_teams;
7 void ScoreRules_basics(float teams, float sprio, float stprio, float score_enabled)
8 {
9         float i;
10         for(i = 0; i < MAX_SCORE; ++i)
11                 ScoreInfo_SetLabel_PlayerScore(i, "", 0);
12         for(i = 0; i < MAX_TEAMSCORE; ++i)
13                 ScoreInfo_SetLabel_TeamScore(i, "", 0);
14
15         ScoreRules_teams = teams;
16
17         if(score_enabled)
18                 ScoreInfo_SetLabel_TeamScore  (ST_SCORE,        "score",     stprio);
19
20         if not(independent_players)
21                 ScoreInfo_SetLabel_PlayerScore(SP_KILLS,        "kills",     0);
22
23         ScoreInfo_SetLabel_PlayerScore(SP_DEATHS,       "deaths",    SFL_LOWER_IS_BETTER);
24
25         if not(independent_players)
26                 ScoreInfo_SetLabel_PlayerScore(SP_SUICIDES,     "suicides",  SFL_LOWER_IS_BETTER);
27
28         if(score_enabled)
29                 ScoreInfo_SetLabel_PlayerScore(SP_SCORE,        "score",     sprio);
30 }
31 void ScoreRules_basics_end()
32 {
33         ScoreInfo_Init(ScoreRules_teams);
34 }
35 void ScoreRules_generic()
36 {
37         CheckAllowedTeams(world);
38         if(teamplay)
39         {
40                 CheckAllowedTeams(world);
41                 ScoreRules_basics(((c4>=0) ? 4 : (c3>=0) ? 3 : 2), SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, TRUE);
42         }
43         else
44                 ScoreRules_basics(0, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, TRUE);
45         ScoreRules_basics_end();
46 }
47
48 // g_ctf
49 #define ST_CTF_CAPS 1
50 #define SP_CTF_CAPS 4
51 #define SP_CTF_PICKUPS 5
52 #define SP_CTF_DROPS 6
53 #define SP_CTF_FCKILLS 7
54 #define SP_CTF_RETURNS 8
55 void ScoreRules_ctf()
56 {
57         float sp_score, sp_caps;
58         sp_score = sp_caps = 0;
59         switch(cvar("g_ctf_win_mode"))
60         {
61                 case 0: // caps only
62                         sp_caps = SFL_SORT_PRIO_PRIMARY;
63                         sp_score = SFL_SORT_PRIO_SECONDARY;
64                         break;
65                 case 1: // caps, then score
66                         sp_caps = SFL_SORT_PRIO_PRIMARY;
67                         sp_score = SFL_SORT_PRIO_SECONDARY;
68                         break;
69                 case 2: // score only
70                 default:
71                         sp_caps = SFL_SORT_PRIO_SECONDARY; // looks better ;)
72                         sp_score = SFL_SORT_PRIO_PRIMARY;
73                         break;
74         }
75
76         CheckAllowedTeams(world);
77         ScoreRules_basics(2 + (c3>=0), SFL_SORT_PRIO_PRIMARY, sp_score, TRUE); // NOTE this assumes that the rogue team is team 3
78         ScoreInfo_SetLabel_TeamScore  (ST_CTF_CAPS,     "caps",      sp_caps);
79         ScoreInfo_SetLabel_PlayerScore(SP_CTF_CAPS,     "caps",      SFL_SORT_PRIO_SECONDARY);
80         ScoreInfo_SetLabel_PlayerScore(SP_CTF_PICKUPS,  "pickups",   0);
81         ScoreInfo_SetLabel_PlayerScore(SP_CTF_FCKILLS,  "fckills",   0);
82         ScoreInfo_SetLabel_PlayerScore(SP_CTF_RETURNS,  "returns",   0);
83         ScoreInfo_SetLabel_PlayerScore(SP_CTF_DROPS,    "drops",     SFL_LOWER_IS_BETTER);
84         ScoreRules_basics_end();
85 }
86
87 // g_domination
88 #define ST_DOM_TICKS 1
89 #define SP_DOM_TICKS 4
90 #define SP_DOM_TAKES 5
91 void ScoreRules_dom()
92 {
93         float sp_domticks, sp_score;
94         sp_score = sp_domticks = 0;
95         if(cvar("g_domination_disable_frags"))
96                 sp_domticks = SFL_SORT_PRIO_PRIMARY;
97         else
98                 sp_score = SFL_SORT_PRIO_PRIMARY;
99         CheckAllowedTeams(world);
100         ScoreRules_basics(((c4>=0) ? 4 : (c3>=0) ? 3 : 2), sp_score, sp_score, TRUE);
101         ScoreInfo_SetLabel_TeamScore  (ST_DOM_TICKS,    "ticks",     sp_domticks);
102         ScoreInfo_SetLabel_PlayerScore(SP_DOM_TICKS,    "ticks",     sp_domticks);
103         ScoreInfo_SetLabel_PlayerScore(SP_DOM_TAKES,    "takes",     0);
104         ScoreRules_basics_end();
105 }
106
107 // LMS stuff
108 #define SP_LMS_LIVES 4
109 #define SP_LMS_RANK 5
110 void ScoreRules_lms()
111 {
112         ScoreRules_basics(0, 0, 0, FALSE);
113         ScoreInfo_SetLabel_PlayerScore(SP_LMS_LIVES,    "lives",     SFL_SORT_PRIO_SECONDARY);
114         ScoreInfo_SetLabel_PlayerScore(SP_LMS_RANK,     "rank",      SFL_LOWER_IS_BETTER | SFL_RANK | SFL_SORT_PRIO_PRIMARY | SFL_ALLOW_HIDE);
115         ScoreRules_basics_end();
116 }
117
118 // Key hunt stuff
119 #define ST_KH_CAPS 1
120 #define SP_KH_CAPS 4
121 #define SP_KH_PUSHES 5
122 #define SP_KH_DESTROYS 6
123 #define SP_KH_PICKUPS 7
124 #define SP_KH_KCKILLS 8
125 #define SP_KH_LOSSES 9
126 void ScoreRules_kh(float teams)
127 {
128         ScoreRules_basics(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, TRUE);
129         ScoreInfo_SetLabel_TeamScore  (ST_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
130         ScoreInfo_SetLabel_PlayerScore(SP_KH_CAPS,      "caps",      SFL_SORT_PRIO_SECONDARY);
131         ScoreInfo_SetLabel_PlayerScore(SP_KH_PUSHES,    "pushes",    0);
132         ScoreInfo_SetLabel_PlayerScore(SP_KH_DESTROYS,  "destroyed", SFL_LOWER_IS_BETTER);
133         ScoreInfo_SetLabel_PlayerScore(SP_KH_PICKUPS,   "pickups",   0);
134         ScoreInfo_SetLabel_PlayerScore(SP_KH_KCKILLS,   "kckills",   0);
135         ScoreInfo_SetLabel_PlayerScore(SP_KH_LOSSES,    "losses",    SFL_LOWER_IS_BETTER);
136         ScoreRules_basics_end();
137 }
138
139 // Race stuff
140 #define ST_RACE_LAPS 1
141 #define SP_RACE_LAPS 4
142 #define SP_RACE_FASTEST 5
143 #define SP_RACE_TIME 5
144 void ScoreRules_race()
145 {
146         ScoreRules_basics(race_teams, 0, 0, FALSE);
147         if(race_teams)
148         {
149                 ScoreInfo_SetLabel_TeamScore(  ST_RACE_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
150                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
151                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_TIME,    "time",      SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
152         }
153         else if(g_race_qualifying)
154         {
155                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_FASTEST, "fastest",   SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
156         }
157         else
158         {
159                 ScoreInfo_SetLabel_TeamScore(  ST_RACE_LAPS,    "laps",      0);
160                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_LAPS,    "laps",      SFL_SORT_PRIO_PRIMARY);
161                 ScoreInfo_SetLabel_PlayerScore(SP_RACE_TIME,    "time",      SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
162         }
163         ScoreRules_basics_end();
164 }