data/qcsrc/server/portals.qc

   1 #define SAFENUDGE '1 1 1'
   2 #define SAFERNUDGE '8 8 8'
   3
   4 .vector portal_transform;
   5 .vector portal_safe_origin;
   6 .float portal_wants_to_vanish;
   7 .float portal_activatetime;
   8
   9 vector Portal_Transform_Apply(vector transform, vector v)
  10 {
  11         fixedmakevectors(transform);
  12         return v_forward * v_x
  13              + v_right   * (-v_y)
  14                  + v_up      * v_z;
  15 }
  16
  17 vector Portal_Transform_Multiply(vector t1, vector t2)
  18 {
  19         vector m_forward, m_up;
  20         fixedmakevectors(t2); m_forward = v_forward; m_up = v_up;
  21         m_forward = Portal_Transform_Apply(t1, m_forward); m_up = Portal_Transform_Apply(t1, m_up);
  22         return fixedvectoangles2(m_forward, m_up);
  23 }
  24
  25 vector Portal_Transform_Invert(vector transform)
  26 {
  27         vector i_forward, i_up;
  28         fixedmakevectors(transform);
  29         // we want angles that turn v_forward into '1 0 0', v_right into '0 1 0' and v_up into '0 0 1'
  30         // but these are orthogonal unit vectors!
  31         // so to invert, we can simply fixedvectoangles the TRANSPOSED matrix
  32         // TODO is this always -transform?
  33         i_forward_x = v_forward_x;
  34         i_forward_y = -v_right_x;
  35         i_forward_z = v_up_x;
  36         i_up_x = v_forward_z;
  37         i_up_y = -v_right_z;
  38         i_up_z = v_up_z;
  39 #ifdef DEBUG
  40         vector v;
  41         v = fixedvectoangles2(i_forward, i_up);
  42         print("Transform: ", vtos(transform), "\n");
  43         print("Inverted: ", vtos(v), "\n");
  44         print("Verify: ", vtos(Portal_Transform_Multiply(v, transform)), "\n");
  45         fixedmakevectors(Portal_Transform_Multiply(v, transform));
  46         print("Verify: ", vtos(v_forward), "\n");
  47         print("Verify: ", vtos(v_right), "\n");
  48         print("Verify: ", vtos(v_up), "\n");
  49 #endif
  50         return fixedvectoangles2(i_forward, i_up);
  51 }
  52
  53 vector Portal_Transform_TurnDirection(vector transform)
  54 {
  55         // turn 180 degrees around v_up
  56         // changes in-direction to out-direction
  57         fixedmakevectors(transform);
  58         return fixedvectoangles2(-1 * v_forward, 1 * v_up);
  59 }
  60
  61 vector Portal_Transform_Divide(vector to_transform, vector from_transform)
  62 {
  63         return Portal_Transform_Multiply(to_transform, Portal_Transform_Invert(from_transform));
  64 }
  65
  66 float PlayerEdgeDistance(entity p, vector v)
  67 {
  68         vector vbest;
  69
  70         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  71         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  72         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  73
  74         return vbest * v;
  75 }
  76
  77 .vector right_vector;
  78 float Portal_TeleportPlayer(entity teleporter, entity player)
  79 {
  80         vector from, to, safe, step, transform, ang, newvel;
  81         vector new_forward, new_up;
  82         vector old_forward, old_up;
  83         vector new_yawforward;
  84         vector old_yawforward;
  85         float planeshift, s, t;
  86
  87         if not(teleporter.enemy)
  88         {
  89                 backtrace("Portal_TeleportPlayer called without other portal being set. Stop.");
  90                 return 0;
  91         }
  92
  93         from = teleporter.origin;
  94         transform = teleporter.portal_transform;
  95
  96         to = teleporter.enemy.origin;
  97         to = to + Portal_Transform_Apply(teleporter.portal_transform, player.origin - from);
  98         newvel = Portal_Transform_Apply(transform, player.velocity);
  99         // this now is INSIDE the plane... can't use that
 100
 101         // shift it out
 102         fixedmakevectors(teleporter.enemy.angles);
 103
 104         // first shift it ON the plane if needed
 105         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
 106         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
 107                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
 108                 to += newvel * (planeshift / (newvel * v_forward));
 109         else
 110                 to += trace_plane_normal * planeshift;
 111
 112         s = (to - teleporter.enemy.origin) * v_right;
 113         t = (to - teleporter.enemy.origin) * v_up;
 114         s = bound(-48, s, 48);
 115         t = bound(-48, t, 48);
 116         to = teleporter.enemy.origin
 117            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 118            +     s                                        * v_right
 119            +     t                                        * v_up;
 120
 121         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 122         step = to + ((safe - to) * v_forward) * v_forward;
 123         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, step, MOVE_NOMONSTERS, player);
 124         if(trace_startsolid)
 125         {
 126                 print("'safe' teleport location is not safe!\n");
 127                 // FAIL TODO why does this happen?
 128                 return 0;
 129         }
 130         safe = trace_endpos + normalize(safe - trace_endpos) * 0;
 131         tracebox(safe, player.mins - SAFENUDGE, player.maxs + SAFENUDGE, to, MOVE_NOMONSTERS, player);
 132         if(trace_startsolid)
 133         {
 134                 print("trace_endpos in solid, this can't be!\n");
 135                 // FAIL TODO why does this happen? (reported by MrBougo)
 136                 return 0;
 137         }
 138         to = trace_endpos + normalize(safe - trace_endpos) * 0;
 139         //print(vtos(to), "\n");
 140
 141         // ang_x stuff works around weird quake angles
 142         if(player.classname == "player")
 143         {
 144                 ang = player.v_angle;
 145                 /*
 146                 ang_x = bound(-89, mod(-ang_x + 180, 360) - 180, 89);
 147                 ang = Portal_Transform_Multiply(transform, ang);
 148                 */
 149
 150                 // PLAYERS use different math
 151                 ang_x = -ang_x;
 152
 153                 //print("reference: ", vtos(Portal_Transform_Multiply(transform, ang)), "\n");
 154
 155                 fixedmakevectors(ang);
 156                 old_forward = v_forward;
 157                 old_up = v_up;
 158                 fixedmakevectors(ang_y * '0 1 0');
 159                 old_yawforward = v_forward;
 160
 161                 // their aiming directions are portalled...
 162                 new_forward = Portal_Transform_Apply(transform, old_forward);
 163                 new_up = Portal_Transform_Apply(transform, old_up);
 164                 new_yawforward = Portal_Transform_Apply(transform, old_yawforward);
 165
 166                 // but now find a new sense of direction
 167                 // this is NOT easy!
 168                 // assume new_forward points straight up.
 169                 // What is our yaw?
 170                 //
 171                 // new_up could now point forward OR backward... which direction to choose?
 172
 173                 if(new_forward_z > 0.7 || new_forward_z < -0.7) // far up; in this case, the "up" vector points backwards
 174                 {
 175                         // new_yawforward and new_yawup define the new aiming half-circle
 176                         // we "just" need to find out whether new_up or -new_up is in that half circle
 177                         ang = fixedvectoangles(new_forward); // this still gets us a nice pitch value...
 178                         if(new_up * new_yawforward < 0)
 179                                 new_up = -1 * new_up;
 180                         ang_y = vectoyaw(new_up); // this vector is the yaw we want
 181                         //print("UP/DOWN path: ", vtos(ang), "\n");
 182                 }
 183                 else
 184                 {
 185                         // good angles; here, "forward" suffices
 186                         ang = fixedvectoangles(new_forward);
 187                         //print("GOOD path: ", vtos(ang), "\n");
 188                 }
 189
 190                 ang_x = -ang_x;
 191                 ang_z = player.angles_z;
 192         }
 193         else
 194         {
 195                 ang = player.angles;
 196                 ang = Portal_Transform_Multiply(transform, player.angles);
 197         }
 198
 199         // factor -1 allows chaining portals, but may be weird
 200         player.right_vector = -1 * Portal_Transform_Apply(transform, player.right_vector);
 201
 202         if(player.flagcarried)
 203                 DropFlag(player.flagcarried, player, world);
 204
 205         if not(teleporter.enemy)
 206         {
 207                 backtrace("Portal_TeleportPlayer ended up without other portal being set BEFORE TeleportPlayer. Stop.");
 208                 return 0;
 209         }
 210
 211         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax);
 212
 213         if not(teleporter.enemy)
 214         {
 215                 backtrace("Portal_TeleportPlayer ended up without other portal being set AFTER TeleportPlayer. Stop.");
 216                 return 0;
 217         }
 218
 219         // reset fade counter
 220         teleporter.portal_wants_to_vanish = 0;
 221         teleporter.fade_time = time + cvar("g_balance_portal_lifetime");
 222         teleporter.health = cvar("g_balance_portal_health");
 223         teleporter.enemy.health = cvar("g_balance_portal_health");
 224
 225         return 1;
 226 }
 227
 228 float Portal_FindSafeOrigin(entity portal)
 229 {
 230         vector o;
 231         o = portal.origin;
 232         portal.mins = PL_MIN - SAFERNUDGE;
 233         portal.maxs = PL_MAX + SAFERNUDGE;
 234         fixedmakevectors(portal.angles);
 235         portal.origin += 16 * v_forward;
 236         if(!move_out_of_solid(portal))
 237         {
 238 #ifdef DEBUG
 239                 print("NO SAFE ORIGIN\n");
 240 #endif
 241                 return 0;
 242         }
 243         portal.portal_safe_origin = portal.origin;
 244         setorigin(portal, o);
 245         return 1;
 246 }
 247
 248 float Portal_WillHitPlane(vector eorg, vector emins, vector emaxs, vector evel, vector porg, vector pnorm, float psize)
 249 {
 250         float dist, distpersec, delta;
 251         vector v;
 252
 253         dist = (eorg - porg) * pnorm;
 254         dist += min(emins_x * pnorm_x, emaxs_x * pnorm_x);
 255         dist += min(emins_y * pnorm_y, emaxs_y * pnorm_y);
 256         dist += min(emins_z * pnorm_z, emaxs_z * pnorm_z);
 257         if(dist < -1) // other side?
 258                 return 0;
 259         distpersec = evel * pnorm;
 260         if(distpersec >= 0) // going away from the portal?
 261                 return 0;
 262         delta = dist / distpersec;
 263         v = eorg - evel * delta - porg;
 264         v = v - pnorm * (pnorm * v);
 265         return vlen(v) < psize;
 266 }
 267
 268 void Portal_Touch()
 269 {
 270         vector g;
 271
 272         // portal is being removed?
 273         if(self.solid != SOLID_TRIGGER)
 274                 return; // possibly engine bug
 275
 276         if(other.classname == "player")
 277                 return; // handled by think
 278
 279         if(other.classname == "item_flag_team")
 280                 return; // never portal these
 281
 282         if(other.classname == "grapplinghook")
 283                 return; // handled by think
 284
 285         if(!self.enemy)
 286                 error("Portal_Touch called for a broken portal\n");
 287
 288         if(trace_fraction < 1)
 289                 return; // only handle TouchAreaGrid ones (only these can teleport)
 290                 // for some unknown reason, this also gets collisions from SV_Impact sometimes
 291
 292         if(other.classname == "porto")
 293         {
 294                 if(other.portal_id == self.portal_id)
 295                         return;
 296         }
 297         if(time < self.portal_activatetime)
 298                 if(other == self.owner)
 299                 {
 300                         self.portal_activatetime = time + 0.1;
 301                         return;
 302                 }
 303         if(other != self.owner)
 304                 if(other.classname == "player")
 305                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.owner))
 306                                 return; // cannot go through someone else's portal
 307         if(other.owner != self.owner)
 308                 if(other.owner.classname == "player")
 309                         if(IS_INDEPENDENT_PLAYER(other.owner) || IS_INDEPENDENT_PLAYER(self.owner))
 310                                 return; // cannot go through someone else's portal
 311         fixedmakevectors(self.angles);
 312         g = frametime * '0 0 -1' * cvar("sv_gravity");
 313         if(!Portal_WillHitPlane(other.origin, other.mins, other.maxs, other.velocity + g, self.origin, v_forward, self.maxs_x))
 314                 return;
 315
 316         /*
 317         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 318         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 319         {
 320                 // can't teleport this
 321                 return;
 322         }
 323         */
 324
 325         if(Portal_TeleportPlayer(self, other))
 326                 if(other.classname == "porto")
 327                         if(other.effects & EF_RED)
 328                                 other.effects += EF_BLUE - EF_RED;
 329 }
 330
 331 void Portal_Think();
 332 void Portal_MakeBrokenPortal(entity portal)
 333 {
 334         portal.skin = 2;
 335         portal.solid = SOLID_NOT;
 336         portal.touch = SUB_Null;
 337         portal.think = SUB_Null;
 338         portal.effects = 0;
 339         portal.nextthink = 0;
 340         portal.takedamage = DAMAGE_NO;
 341 }
 342
 343 void Portal_MakeWaitingPortal(entity portal)
 344 {
 345         portal.skin = 2;
 346         portal.solid = SOLID_NOT;
 347         portal.touch = SUB_Null;
 348         portal.think = SUB_Null;
 349         portal.effects = EF_ADDITIVE;
 350         portal.nextthink = 0;
 351         portal.takedamage = DAMAGE_YES;
 352 }
 353
 354 void Portal_MakeInPortal(entity portal)
 355 {
 356         portal.skin = 0;
 357         portal.solid = SOLID_TRIGGER;
 358         portal.touch = Portal_Touch;
 359         portal.think = Portal_Think;
 360         portal.effects = EF_RED;
 361         portal.nextthink = time;
 362         portal.takedamage = DAMAGE_NO;
 363 }
 364
 365 void Portal_MakeOutPortal(entity portal)
 366 {
 367         portal.skin = 1;
 368         portal.solid = SOLID_NOT;
 369         portal.touch = SUB_Null;
 370         portal.think = SUB_Null;
 371         portal.effects = EF_STARDUST | EF_BLUE;
 372         portal.nextthink = 0;
 373         portal.takedamage = DAMAGE_YES;
 374 }
 375
 376 void Portal_Disconnect(entity teleporter, entity destination)
 377 {
 378         teleporter.enemy = world;
 379         destination.enemy = world;
 380         Portal_MakeBrokenPortal(teleporter);
 381         Portal_MakeBrokenPortal(destination);
 382 }
 383
 384 void Portal_Connect(entity teleporter, entity destination)
 385 {
 386         teleporter.portal_transform = Portal_Transform_Divide(Portal_Transform_TurnDirection(destination.angles), teleporter.angles);
 387
 388 #ifdef DEBUG
 389         {
 390                 // let's verify the transform
 391                 vector in_f, in_r, in_u;
 392                 vector out_f, out_r, out_u;
 393                 fixedmakevectors(teleporter.angles);
 394                 in_f = v_forward;
 395                 in_r = v_right;
 396                 in_u = v_up;
 397                 print("teleporter: ", vtos(in_f), " ", vtos(in_r), " ", vtos(in_u), "\n");
 398                 fixedmakevectors(destination.angles);
 399                 out_f = v_forward;
 400                 out_r = v_right;
 401                 out_u = v_up;
 402                 print("dest: ", vtos(out_f), " ", vtos(out_r), " ", vtos(out_u), "\n");
 403                 // INTENDED TRANSFORM:
 404                 //   in_f -> -out_f
 405                 //   in_r -> -out_r
 406                 //   in_u -> +out_u
 407                 print("FORWARD: ", vtos(in_f), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_f)), ", should be", vtos(-1 * out_f), "\n");
 408                 print("RIGHT: ", vtos(in_r), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_r)), ", should be", vtos(-1 * out_r), "\n");
 409                 print("UP: ", vtos(in_u), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_u)), ", should be", vtos(out_u), "\n");
 410
 411                 te_lightning3(world, teleporter.origin, teleporter.origin + in_r * 1000);
 412                 te_lightning3(world, destination.origin, destination.origin + out_r * 1000);
 413         }
 414 #endif
 415
 416         teleporter.enemy = destination;
 417         destination.enemy = teleporter;
 418         Portal_MakeInPortal(teleporter);
 419         Portal_MakeOutPortal(destination);
 420         teleporter.fade_time = time + 15;
 421         destination.fade_time = time + 15;
 422         teleporter.portal_wants_to_vanish = 0;
 423         destination.portal_wants_to_vanish = 0;
 424 }
 425
 426 void Portal_Remove(entity portal, float killed)
 427 {
 428         entity e;
 429         e = portal.enemy;
 430
 431         if(e)
 432         {
 433                 Portal_Disconnect(portal, e);
 434                 Portal_Remove(e, killed);
 435         }
 436
 437         if(portal == portal.owner.portal_in)
 438                 portal.owner.portal_in = world;
 439         if(portal == portal.owner.portal_out)
 440                 portal.owner.portal_out = world;
 441         //portal.owner = world;
 442
 443         // makes the portal vanish
 444         if(killed)
 445         {
 446                 fixedmakevectors(portal.angles);
 447                 sound(portal, CHAN_PROJECTILE, "porto/explode.wav", VOL_BASE, ATTN_NORM);
 448                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 449                 remove(portal);
 450         }
 451         else
 452         {
 453                 Portal_MakeBrokenPortal(portal);
 454                 sound(portal, CHAN_PROJECTILE, "porto/expire.wav", VOL_BASE, ATTN_NORM);
 455                 SUB_SetFade(portal, time, 0.5);
 456         }
 457 }
 458
 459 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 460 {
 461         if(deathtype == DEATH_TELEFRAG)
 462                 return;
 463         if(attacker != self.owner)
 464                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.owner))
 465                         return;
 466         self.health -= damage;
 467         if(self.health < 0)
 468                 Portal_Remove(self, 1);
 469 }
 470
 471 void Portal_Think_TryTeleportPlayer(entity e, vector g)
 472 {
 473         if(!Portal_WillHitPlane(e.origin, e.mins, e.maxs, e.velocity + g, self.origin, v_forward, self.maxs_x))
 474                 return;
 475
 476         // if e would hit the portal in a frame...
 477         // already teleport him
 478         tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 479         if(trace_ent == self)
 480                 Portal_TeleportPlayer(self, e);
 481 }
 482
 483 void Portal_Think()
 484 {
 485         entity e, o;
 486         vector g;
 487
 488         // portal is being removed?
 489         if(self.solid != SOLID_TRIGGER)
 490                 return; // possibly engine bug
 491
 492         if(!self.enemy)
 493                 error("Portal_Think called for a broken portal\n");
 494
 495         o = self.owner;
 496         self.solid = SOLID_BBOX;
 497         self.owner = world;
 498
 499         g = frametime * '0 0 -1' * cvar("sv_gravity");
 500
 501         fixedmakevectors(self.angles);
 502
 503         FOR_EACH_PLAYER(e)
 504         {
 505                 if(e != o)
 506                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 507                                 continue; // cannot go through someone else's portal
 508
 509                 if(e != o || time >= self.portal_activatetime)
 510                         Portal_Think_TryTeleportPlayer(e, g);
 511
 512                 if(e.hook)
 513                         Portal_Think_TryTeleportPlayer(e.hook, g);
 514         }
 515         self.solid = SOLID_TRIGGER;
 516         self.owner = o;
 517
 518         self.nextthink = time;
 519
 520         if(time > self.fade_time)
 521                 Portal_Remove(self, 0);
 522 }
 523
 524 float Portal_Customize()
 525 {
 526         if(other.classname == "spectator")
 527                 other = other.enemy;
 528         if(other == self.owner)
 529         {
 530                 self.modelindex = self.modelindex_lod0;
 531         }
 532         else if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.owner))
 533         {
 534                 self.modelindex = 0;
 535         }
 536         else
 537         {
 538                 self.modelindex = self.modelindex_lod0;
 539         }
 540         return TRUE;
 541 }
 542
 543 // cleanup:
 544 //   when creating in-portal:
 545 //     disconnect
 546 //     clear existing in-portal
 547 //     set as in-portal
 548 //     connect
 549 //   when creating out-portal:
 550 //     disconnect
 551 //     clear existing out-portal
 552 //     set as out-portal
 553 //   when player dies:
 554 //     disconnect portals
 555 //     clear both portals
 556 //   after timeout of in-portal:
 557 //     disconnect portals
 558 //     clear both portals
 559 //   TODO: ensure only one portal shot at once
 560 float Portal_SetInPortal(entity own, entity portal)
 561 {
 562         if(own.portal_in)
 563         {
 564                 if(own.portal_out)
 565                         Portal_Disconnect(own.portal_in, own.portal_out);
 566                 Portal_Remove(own.portal_in, 0);
 567         }
 568         own.portal_in = portal;
 569         if(own.portal_out)
 570         {
 571                 own.portal_out.portal_id = portal.portal_id;
 572                 Portal_Connect(own.portal_in, own.portal_out);
 573         }
 574         return 2;
 575 }
 576 float Portal_SetOutPortal(entity own, entity portal)
 577 {
 578         if(own.portal_out)
 579         {
 580                 if(own.portal_in)
 581                         Portal_Disconnect(own.portal_in, own.portal_out);
 582                 Portal_Remove(own.portal_out, 0);
 583         }
 584         own.portal_out = portal;
 585         if(own.portal_in)
 586         {
 587                 own.portal_in.portal_id = portal.portal_id;
 588                 Portal_Connect(own.portal_in, own.portal_out);
 589         }
 590         return 1;
 591 }
 592 void Portal_ClearAll_PortalsOnly(entity own)
 593 {
 594         if(own.portal_in)
 595                 Portal_Remove(own.portal_in, 0);
 596         if(own.portal_out)
 597                 Portal_Remove(own.portal_out, 0);
 598 }
 599 void Portal_ClearAll(entity own)
 600 {
 601         Portal_ClearAll_PortalsOnly(own);
 602         W_Porto_Remove(own);
 603 }
 604 void Portal_RemoveLater_Think()
 605 {
 606         Portal_Remove(self, self.cnt);
 607 }
 608 void Portal_RemoveLater(entity portal, float kill)
 609 {
 610         Portal_MakeBrokenPortal(portal);
 611         portal.cnt = kill;
 612         portal.think = Portal_RemoveLater_Think;
 613         portal.nextthink = time;
 614 }
 615 void Portal_ClearAllLater_PortalsOnly(entity own)
 616 {
 617         if(own.portal_in)
 618                 Portal_RemoveLater(own.portal_in, 0);
 619         if(own.portal_out)
 620                 Portal_RemoveLater(own.portal_out, 0);
 621 }
 622 void Portal_ClearAllLater(entity own)
 623 {
 624         Portal_ClearAllLater_PortalsOnly(own);
 625         W_Porto_Remove(own);
 626 }
 627 void Portal_ClearWithID(entity own, float id)
 628 {
 629         if(own.portal_in)
 630                 if(own.portal_in.portal_id == id)
 631                 {
 632                         if(own.portal_out)
 633                                 Portal_Disconnect(own.portal_in, own.portal_out);
 634                         Portal_Remove(own.portal_in, 0);
 635                 }
 636         if(own.portal_out)
 637                 if(own.portal_out.portal_id == id)
 638                 {
 639                         if(own.portal_in)
 640                                 Portal_Disconnect(own.portal_in, own.portal_out);
 641                         Portal_Remove(own.portal_out, 0);
 642                 }
 643 }
 644
 645 entity Portal_Spawn(entity own, vector org, vector ang)
 646 {
 647         entity portal;
 648
 649         fixedmakevectors(ang);
 650         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 651                 return world;
 652
 653         portal = spawn();
 654         portal.classname = "portal";
 655         portal.owner = own;
 656         portal.origin = org;
 657         portal.angles = ang;
 658         portal.think = Portal_Think;
 659         portal.nextthink = 0;
 660         portal.portal_activatetime = time + 0.1;
 661         portal.event_damage = Portal_Damage;
 662         portal.health = 200;
 663         portal.fade_time = time + cvar("g_balance_portal_lifetime");
 664         portal.health = cvar("g_balance_portal_health");
 665         setmodel(portal, "models/portal.md3");
 666         portal.modelindex_lod0 = portal.modelindex;
 667         portal.customizeentityforclient = Portal_Customize;
 668
 669         if(!Portal_FindSafeOrigin(portal))
 670         {
 671                 remove(portal);
 672                 return world;
 673         }
 674
 675         setsize(portal, '-48 -48 -48', '48 48 48');
 676         Portal_MakeWaitingPortal(portal);
 677
 678         return portal;
 679 }
 680
 681 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 682 {
 683         entity portal;
 684         vector ang;
 685         vector org;
 686
 687         org = trace_endpos;
 688         ang = fixedvectoangles2(trace_plane_normal, dir);
 689         fixedmakevectors(ang);
 690
 691         portal = Portal_Spawn(own, org, ang);
 692         if(!portal)
 693         {
 694                 // if(!own.portal_out || own.portal_out.portal_id == portal_id_val)
 695                         Portal_ClearAll_PortalsOnly(own);
 696                 return 0;
 697         }
 698
 699         portal.portal_id = portal_id_val;
 700         Portal_SetInPortal(own, portal);
 701
 702         return 1;
 703 }
 704
 705 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 706 {
 707         entity portal;
 708         vector ang;
 709         vector org;
 710
 711         org = trace_endpos;
 712         ang = fixedvectoangles2(trace_plane_normal, dir);
 713         fixedmakevectors(ang);
 714
 715         portal = Portal_Spawn(own, org, ang);
 716         if(!portal)
 717         {
 718                 // if(!own.portal_in || own.portal_in.portal_id == portal_id_val)
 719                         Portal_ClearAll_PortalsOnly(own);
 720                 return 0;
 721         }
 722
 723         portal.portal_id = portal_id_val;
 724         Portal_SetOutPortal(own, portal);
 725
 726         return 1;
 727 }