data/qcsrc/server/portals.qc

   1 .vector portal_transform;
   2 .vector portal_safe_origin;
   3 .float portal_wants_to_vanish;
   4 .float portal_activatetime;
   5 .float portal_id;
   6
   7 .entity portal_in, portal_out;
   8
   9 vector Portal_Transform_Apply(vector transform, vector v)
  10 {
  11         fixedmakevectors(transform);
  12         return v_forward * v_x
  13              + v_right   * (-v_y)
  14                  + v_up      * v_z;
  15 }
  16
  17 vector Portal_Transform_Multiply(vector t1, vector t2)
  18 {
  19         vector m_forward, m_up;
  20         fixedmakevectors(t2); m_forward = v_forward; m_up = v_up;
  21         m_forward = Portal_Transform_Apply(t1, m_forward);
  22         m_up = Portal_Transform_Apply(t1, m_up);
  23         return vectoangles2(m_forward, m_up);
  24 }
  25
  26 vector Portal_Transform_Invert(vector transform)
  27 {
  28         vector i_forward, i_up;
  29         fixedmakevectors(transform);
  30         // we want angles that turn v_forward into '1 0 0', v_right into '0 1 0' and v_up into '0 0 1'
  31         // but these are orthogonal unit vectors!
  32         // so to invert, we can simply vectoangles the TRANSPOSED matrix
  33         // TODO is this always -transform?
  34         i_forward_x = v_forward_x;
  35         i_forward_y = -v_right_x;
  36         i_forward_z = v_up_x;
  37         i_up_x = v_forward_z;
  38         i_up_y = -v_right_z;
  39         i_up_z = v_up_z;
  40 #ifdef DEBUG
  41         vector v;
  42         v = vectoangles2(i_forward, i_up);
  43         print("Transform: ", vtos(transform), "\n");
  44         print("Inverted: ", vtos(v), "\n");
  45         print("Verify: ", vtos(Portal_Transform_Multiply(v, transform)), "\n");
  46         fixedmakevectors(Portal_Transform_Multiply(v, transform));
  47         print("Verify: ", vtos(v_forward), "\n");
  48         print("Verify: ", vtos(v_right), "\n");
  49         print("Verify: ", vtos(v_up), "\n");
  50 #endif
  51         return vectoangles2(i_forward, i_up);
  52 }
  53
  54 vector Portal_Transform_TurnDirection(vector transform)
  55 {
  56         // turn 180 degrees around v_up
  57         // changes in-direction to out-direction
  58         fixedmakevectors(transform);
  59         return vectoangles2(-1 * v_forward, 1 * v_up);
  60 }
  61
  62 vector Portal_Transform_Divide(vector to_transform, vector from_transform)
  63 {
  64         return Portal_Transform_Multiply(to_transform, Portal_Transform_Invert(from_transform));
  65 }
  66
  67 float PlayerEdgeDistance(entity p, vector v)
  68 {
  69         vector vbest;
  70
  71         if(v_x < 0) vbest_x = p.mins_x; else vbest_x = p.maxs_x;
  72         if(v_y < 0) vbest_y = p.mins_y; else vbest_y = p.maxs_y;
  73         if(v_z < 0) vbest_z = p.mins_z; else vbest_z = p.maxs_z;
  74
  75         return vbest * v;
  76 }
  77
  78 .vector right_vector;
  79 float Portal_TeleportPlayer(entity teleporter, entity player)
  80 {
  81         vector from, to, safe, step, transform, ang, newvel;
  82         float planeshift, s, t;
  83         from = teleporter.origin;
  84         transform = teleporter.portal_transform;
  85
  86         to = teleporter.enemy.origin;
  87         to = to + Portal_Transform_Apply(teleporter.portal_transform, player.origin - from);
  88         newvel = Portal_Transform_Apply(transform, player.velocity);
  89         // this now is INSIDE the plane... can't use that
  90
  91         // shift it out
  92         fixedmakevectors(teleporter.enemy.angles);
  93
  94         // first shift it ON the plane if needed
  95         planeshift = ((teleporter.enemy.origin - to) * v_forward) + PlayerEdgeDistance(player, v_forward) + 1;
  96         if(planeshift > 0 && (newvel * v_forward) > vlen(newvel) * 0.01)
  97                 // if we can't, let us not do the planeshift and do somewhat incorrect transformation in the end
  98                 to += newvel * (planeshift / (newvel * v_forward));
  99         else
 100                 to += trace_plane_normal * planeshift;
 101
 102         s = (to - teleporter.enemy.origin) * v_right;
 103         t = (to - teleporter.enemy.origin) * v_up;
 104         s = bound(-48, s, 48);
 105         t = bound(-48, t, 48);
 106         to = teleporter.enemy.origin
 107            + ((to - teleporter.enemy.origin) * v_forward) * v_forward
 108            +     s                                        * v_right
 109            +     t                                        * v_up;
 110
 111         safe = teleporter.enemy.portal_safe_origin; // a valid player origin
 112         step = to + ((safe - to) * v_forward) * v_forward;
 113         tracebox(safe, PL_MIN, PL_MAX, step, MOVE_NOMONSTERS, player);
 114         if(trace_startsolid)
 115         {
 116                 bprint("'safe' teleport location is not safe!\n");
 117                 // FAIL TODO why does this happen?
 118                 return 0;
 119         }
 120         safe = trace_endpos;
 121         tracebox(safe, PL_MIN, PL_MAX, to, MOVE_NOMONSTERS, player);
 122         if(trace_startsolid)
 123                 error("trace_endpos in solid!");
 124         to = trace_endpos;
 125
 126         // ang_x stuff works around weird quake angles
 127         if(player.classname == "player")
 128         {
 129                 ang = player.v_angle;
 130                 ang_x = -ang_x;
 131                 ang = Portal_Transform_Multiply(transform, ang);
 132                 ang_z = player.angles_z;
 133         }
 134         else
 135         {
 136                 ang = player.angles;
 137                 ang_x = -ang_x;
 138                 ang = Portal_Transform_Multiply(transform, player.angles);
 139         }
 140         ang_x = -ang_x;
 141
 142         // factor -1 allows chaining portals, but may be weird
 143         player.right_vector = -1 * Portal_Transform_Apply(transform, player.right_vector);
 144
 145         if(player.flagcarried)
 146                 DropFlag(player.flagcarried);
 147         TeleportPlayer(teleporter, player, to, ang, newvel, teleporter.enemy.absmin, teleporter.enemy.absmax);
 148
 149         // reset fade counter
 150         teleporter.portal_wants_to_vanish = 0;
 151         teleporter.fade_time = time + 15;
 152         teleporter.enemy.health = 300;
 153
 154         return 1;
 155 }
 156
 157 float Portal_FindSafeOrigin(entity portal)
 158 {
 159         vector o;
 160         o = portal.origin;
 161         portal.mins = PL_MIN - '8 8 8';
 162         portal.maxs = PL_MAX + '8 8 8';
 163         fixedmakevectors(portal.angles);
 164         portal.origin += 16 * v_forward;
 165         if(!move_out_of_solid(portal))
 166         {
 167 #ifdef DEBUG
 168                 print("NO SAFE ORIGIN\n");
 169 #endif
 170                 return 0;
 171         }
 172         portal.portal_safe_origin = portal.origin;
 173         setorigin(portal, o);
 174         return 1;
 175 }
 176
 177 void Portal_Touch()
 178 {
 179         if(trace_fraction < 1)
 180                 return; // only handle TouchAreaGrid ones (only these can teleport)
 181                 // for some unknown reason, this also gets collisions from SV_Impact sometimes
 182         if(!self.enemy)
 183         {
 184                 objerror("Portal_Touch called for [unconnected] portal\n");
 185                 return;
 186         }
 187         if(other.classname == "porto")
 188         {
 189                 if(other.portal_id == self.portal_id)
 190                         return;
 191         }
 192         if(time < self.portal_activatetime)
 193                 if(other == self.owner)
 194                 {
 195                         self.portal_activatetime = time + 0.1;
 196                         return;
 197                 }
 198         if(other != self.owner)
 199                 if(other.classname == "player")
 200                         if(IS_INDEPENDENT_PLAYER(other) || IS_INDEPENDENT_PLAYER(self.owner))
 201                                 return; // cannot go through someone else's portal
 202         fixedmakevectors(self.angles);
 203         if((other.origin - self.origin) * v_forward < 0)
 204                 return;
 205         if(other.mins_x < PL_MIN_x || other.mins_y < PL_MIN_y || other.mins_z < PL_MIN_z
 206         || other.maxs_x > PL_MAX_x || other.maxs_y > PL_MAX_y || other.maxs_z > PL_MAX_z)
 207         {
 208                 // can't teleport this
 209                 return;
 210         }
 211
 212         if(Portal_TeleportPlayer(self, other))
 213                 if(other.classname == "porto")
 214                         if(other.effects & EF_RED)
 215                                 other.effects += EF_BLUE - EF_RED;
 216 }
 217
 218 void Portal_MakeBrokenPortal(entity portal)
 219 {
 220         portal.solid = SOLID_NOT;
 221         portal.touch = SUB_Null;
 222         portal.effects = 0;
 223         //portal.colormod = '1 1 1';
 224         portal.nextthink = 0;
 225         portal.takedamage = DAMAGE_NO;
 226 }
 227
 228 void Portal_MakeWaitingPortal(entity portal)
 229 {
 230         portal.solid = SOLID_NOT;
 231         portal.touch = SUB_Null;
 232         portal.effects = EF_ADDITIVE;
 233         portal.colormod = '1 1 1';
 234         portal.nextthink = 0;
 235         portal.takedamage = DAMAGE_YES;
 236 }
 237
 238 void Portal_MakeInPortal(entity portal)
 239 {
 240         portal.solid = SOLID_TRIGGER;
 241         portal.touch = Portal_Touch;
 242         portal.effects = EF_RED;
 243         portal.colormod = '1 0 0';
 244         portal.nextthink = time;
 245         portal.takedamage = DAMAGE_NO;
 246 }
 247
 248 void Portal_MakeOutPortal(entity portal)
 249 {
 250         portal.solid = SOLID_NOT;
 251         portal.touch = SUB_Null;
 252         portal.effects = EF_STARDUST | EF_BLUE;
 253         portal.colormod = '0 0 1';
 254         portal.nextthink = 0;
 255         portal.takedamage = DAMAGE_YES;
 256 }
 257
 258 void Portal_Disconnect(entity teleporter, entity destination)
 259 {
 260         teleporter.enemy = world;
 261         destination.enemy = world;
 262         Portal_MakeBrokenPortal(teleporter);
 263         Portal_MakeBrokenPortal(destination);
 264 }
 265
 266 void Portal_Connect(entity teleporter, entity destination)
 267 {
 268         teleporter.portal_transform = Portal_Transform_Divide(Portal_Transform_TurnDirection(destination.angles), teleporter.angles);
 269
 270 #ifdef DEBUG
 271         {
 272                 // let's verify the transform
 273                 vector in_f, in_r, in_u;
 274                 vector out_f, out_r, out_u;
 275                 fixedmakevectors(teleporter.angles);
 276                 in_f = v_forward;
 277                 in_r = v_right;
 278                 in_u = v_up;
 279                 print("teleporter: ", vtos(in_f), " ", vtos(in_r), " ", vtos(in_u), "\n");
 280                 fixedmakevectors(destination.angles);
 281                 out_f = v_forward;
 282                 out_r = v_right;
 283                 out_u = v_up;
 284                 print("dest: ", vtos(out_f), " ", vtos(out_r), " ", vtos(out_u), "\n");
 285                 // INTENDED TRANSFORM:
 286                 //   in_f -> -out_f
 287                 //   in_r -> -out_r
 288                 //   in_u -> +out_u
 289                 print("FORWARD: ", vtos(in_f), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_f)), ", should be", vtos(-1 * out_f), "\n");
 290                 print("RIGHT: ", vtos(in_r), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_r)), ", should be", vtos(-1 * out_r), "\n");
 291                 print("UP: ", vtos(in_u), " -> ", vtos(Portal_Transform_Apply(teleporter.portal_transform, in_u)), ", should be", vtos(out_u), "\n");
 292
 293                 te_lightning3(world, teleporter.origin, teleporter.origin + in_r * 1000);
 294                 te_lightning3(world, destination.origin, destination.origin + out_r * 1000);
 295         }
 296 #endif
 297
 298         teleporter.enemy = destination;
 299         destination.enemy = teleporter;
 300         Portal_MakeInPortal(teleporter);
 301         Portal_MakeOutPortal(destination);
 302         teleporter.fade_time = time + 15;
 303         destination.fade_time = time + 15;
 304         teleporter.portal_wants_to_vanish = 0;
 305         destination.portal_wants_to_vanish = 0;
 306 }
 307
 308 void Portal_Remove(entity portal, float killed)
 309 {
 310         entity e;
 311         e = portal.enemy;
 312
 313         if(e)
 314         {
 315                 Portal_Disconnect(portal, e);
 316                 Portal_Remove(e, killed);
 317         }
 318
 319         if(portal == portal.owner.portal_in)
 320                 portal.owner.portal_in = world;
 321         if(portal == portal.owner.portal_out)
 322                 portal.owner.portal_out = world;
 323         portal.owner = world;
 324
 325         // makes the portal vanish
 326         if(killed)
 327         {
 328                 fixedmakevectors(portal.angles);
 329                 pointparticles(particleeffectnum("rocket_explode"), portal.origin + v_forward * 16, v_forward * 1024, 4);
 330                 remove(portal);
 331         }
 332         else
 333         {
 334                 Portal_MakeBrokenPortal(portal);
 335                 SUB_SetFade(portal, time, 0.5);
 336         }
 337 }
 338
 339 void Portal_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 340 {
 341         if(deathtype == DEATH_TELEFRAG)
 342                 return;
 343         if(attacker != self.owner)
 344                 if(IS_INDEPENDENT_PLAYER(attacker) || IS_INDEPENDENT_PLAYER(self.owner))
 345                         return;
 346         self.health -= damage;
 347         if(self.health < 0)
 348         {
 349                 Portal_Remove(self, 1);
 350         }
 351 }
 352
 353 void Portal_Think()
 354 {
 355         entity e, o;
 356
 357         if(self.solid != SOLID_TRIGGER)
 358                 error("Portal_Think called for a portal that should not be thinking");
 359
 360         o = self.owner;
 361         self.solid = SOLID_BBOX;
 362         self.owner = world;
 363         FOR_EACH_PLAYER(e)
 364         {
 365                 if(time < self.portal_activatetime)
 366                         if(e == o)
 367                                 continue;
 368                 if(e != o)
 369                         if(IS_INDEPENDENT_PLAYER(e) || IS_INDEPENDENT_PLAYER(o))
 370                                 continue; // cannot go through someone else's portal
 371                 // if e would hit the portal in a frame...
 372                 // already teleport him
 373                 tracebox(e.origin, e.mins, e.maxs, e.origin + e.velocity * 2 * frametime, MOVE_NORMAL, e);
 374                 if(trace_ent == self)
 375                         Portal_TeleportPlayer(self, e);
 376         }
 377         self.solid = SOLID_TRIGGER;
 378         self.owner = o;
 379
 380         self.nextthink = time;
 381
 382         if(time > self.fade_time)
 383                 Portal_Remove(self, 0);
 384 }
 385
 386 float Portal_Customize()
 387 {
 388         if(other.classname == "spectator")
 389                 other = other.enemy;
 390         if(other == self.owner)
 391                 return TRUE;
 392         if(IS_INDEPENDENT_PLAYER(other))
 393                 return FALSE;
 394         if(IS_INDEPENDENT_PLAYER(self.owner))
 395                 return FALSE;
 396         return TRUE;
 397 }
 398
 399 // cleanup:
 400 //   when creating in-portal:
 401 //     disconnect
 402 //     clear existing in-portal
 403 //     set as in-portal
 404 //     connect
 405 //   when creating out-portal:
 406 //     disconnect
 407 //     clear existing out-portal
 408 //     set as out-portal
 409 //   when player dies:
 410 //     disconnect portals
 411 //     clear both portals
 412 //   after timeout of in-portal:
 413 //     disconnect portals
 414 //     clear both portals
 415 //   TODO: ensure only one portal shot at once
 416 float Portal_SetInPortal(entity own, entity portal)
 417 {
 418         if(own.portal_in)
 419         {
 420                 if(own.portal_out)
 421                         Portal_Disconnect(own.portal_in, own.portal_out);
 422                 Portal_Remove(own.portal_in, 0);
 423         }
 424         own.portal_in = portal;
 425         if(own.portal_out)
 426         {
 427                 own.portal_out.portal_id = portal.portal_id;
 428                 Portal_Connect(own.portal_in, own.portal_out);
 429         }
 430         return 2;
 431 }
 432 float Portal_SetOutPortal(entity own, entity portal)
 433 {
 434         if(own.portal_out)
 435         {
 436                 if(own.portal_in)
 437                         Portal_Disconnect(own.portal_in, own.portal_out);
 438                 Portal_Remove(own.portal_out, 0);
 439         }
 440         own.portal_out = portal;
 441         if(own.portal_in)
 442         {
 443                 own.portal_in.portal_id = portal.portal_id;
 444                 Portal_Connect(own.portal_in, own.portal_out);
 445         }
 446         return 1;
 447 }
 448 void Portal_ClearAll(entity own)
 449 {
 450         if(own.portal_in)
 451                 Portal_Remove(own.portal_in, 0);
 452         if(own.portal_out)
 453                 Portal_Remove(own.portal_out, 0);
 454 }
 455 void Portal_ClearWithID(entity own, float id)
 456 {
 457         if(own.portal_in)
 458                 if(own.portal_in.portal_id == id)
 459                 {
 460                         if(own.portal_out)
 461                                 Portal_Disconnect(own.portal_in, own.portal_out);
 462                         Portal_Remove(own.portal_in, 0);
 463                 }
 464         if(own.portal_out)
 465                 if(own.portal_out.portal_id == id)
 466                 {
 467                         if(own.portal_in)
 468                                 Portal_Disconnect(own.portal_in, own.portal_out);
 469                         Portal_Remove(own.portal_out, 0);
 470                 }
 471 }
 472
 473 entity Portal_Spawn(entity own, vector org, vector ang)
 474 {
 475         entity portal;
 476
 477         fixedmakevectors(ang);
 478         if(!CheckWireframeBox(own, org - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 479                 return world;
 480
 481         portal = spawn();
 482         portal.classname = "portal";
 483         portal.owner = own;
 484         portal.origin = org;
 485         portal.angles = ang;
 486         portal.think = Portal_Think;
 487         portal.nextthink = 0;
 488         portal.fade_time = time + 15;
 489         portal.portal_activatetime = time + 0.1;
 490         portal.event_damage = Portal_Damage;
 491         portal.health = 300;
 492         setmodel(portal, "models/portal.md3");
 493         portal.customizeentityforclient = Portal_Customize;
 494
 495         if(!Portal_FindSafeOrigin(portal))
 496         {
 497                 remove(portal);
 498                 return world;
 499         }
 500
 501         setsize(portal, '-48 -48 -48', '48 48 48');
 502         Portal_MakeWaitingPortal(portal);
 503
 504         return portal;
 505 }
 506
 507 float Portal_SpawnInPortalAtTrace(entity own, vector dir, float portal_id_val)
 508 {
 509         entity portal;
 510         vector ang;
 511         vector org;
 512
 513         if(trace_ent.movetype == MOVETYPE_WALK)
 514         {
 515                 trace_endpos = trace_ent.origin + '0 0 1' * PL_MIN_z;
 516                 trace_plane_normal = '0 0 1';
 517                 dir = -1 * dir; // create telefrag portals the other way round
 518         }
 519
 520         org = trace_endpos;
 521         ang = vectoangles2(trace_plane_normal, dir);
 522         fixedmakevectors(ang);
 523
 524         portal = Portal_Spawn(own, org, ang);
 525         if(!portal)
 526         {
 527                 if(!self.portal_out || self.portal_out.portal_id == portal_id_val)
 528                         Portal_ClearAll(own);
 529                 return 0;
 530         }
 531
 532         portal.portal_id = portal_id_val;
 533         Portal_SetInPortal(own, portal);
 534         sound(portal, CHAN_PROJECTILE, "misc/invshot.wav", VOL_BASE, ATTN_NORM);
 535
 536         return 1;
 537 }
 538
 539 float Portal_SpawnOutPortalAtTrace(entity own, vector dir, float portal_id_val)
 540 {
 541         entity portal;
 542         vector ang;
 543         vector org;
 544
 545         if(trace_ent.movetype == MOVETYPE_WALK)
 546         {
 547                 trace_endpos = trace_ent.origin + '0 0 1' * PL_MIN_z;
 548                 trace_plane_normal = '0 0 1';
 549                 dir = -1 * dir; // create telefrag portals the other way round
 550         }
 551
 552         org = trace_endpos;
 553         ang = vectoangles2(trace_plane_normal, dir);
 554         fixedmakevectors(ang);
 555
 556         portal = Portal_Spawn(own, org, ang);
 557         if(!portal)
 558         {
 559                 if(!self.portal_in || self.portal_in.portal_id == portal_id_val)
 560                         Portal_ClearAll(own);
 561                 return 0;
 562         }
 563
 564         portal.portal_id = portal_id_val;
 565         Portal_SetOutPortal(own, portal);
 566         sound(portal, CHAN_PROJECTILE, "misc/invshot.wav", VOL_BASE, ATTN_NORM);
 567
 568         return 1;
 569 }