svn propset svn:eol-style native **/*.{c,h,qm,qc,qh} again (WHY WAS IT NOT SET ON...
[divverent/nexuiz.git] / data / qcsrc / server / mode_onslaught.qc
1
2 .string target2;
3 .float iscaptured;
4 .float islinked;
5 .float isshielded;
6 void() onslaught_updatelinks =
7 {
8         local entity l, links;
9         local float stop, t1, t2, t3, t4;
10         // first check if the game has ended
11         dprint("--- updatelinks ---\n");
12         links = findchain(classname, "onslaught_link");
13         // mark generators as being shielded and networked
14         l = findchain(classname, "onslaught_generator");
15         while (l)
16         {
17                 if (l.iscaptured)
18                         dprint(etos(l), " (generator) belongs to team ", ftos(l.team), "\n");
19                 else
20                         dprint(etos(l), " (generator) is destroyed\n");
21                 l.islinked = l.iscaptured;
22                 l.isshielded = l.iscaptured;
23                 l = l.chain;
24         }
25         // mark points as shielded and not networked
26         l = findchain(classname, "onslaught_controlpoint");
27         while (l)
28         {
29                 l.islinked = FALSE;
30                 l.isshielded = TRUE;
31                 dprint(etos(l), " (point) belongs to team ", ftos(l.team), "\n");
32                 l = l.chain;
33         }
34         // flow power outward from the generators through the network
35         l = links;
36         while (l)
37         {
38                 dprint(etos(l), " (link) connects ", etos(l.goalentity), " with ", etos(l.enemy), "\n");
39                 l = l.chain;
40         }
41         stop = FALSE;
42         while (!stop)
43         {
44                 stop = TRUE;
45                 l = links;
46                 while (l)
47                 {
48                         // if both points are captured by the same team, and only one of
49                         // them is powered, mark the other one as powered as well
50                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
51                         if (l.enemy.islinked != l.goalentity.islinked)
52                         if (l.enemy.team == l.goalentity.team)
53                         {
54                                 if (!l.goalentity.islinked)
55                                 {
56                                         stop = FALSE;
57                                         l.goalentity.islinked = TRUE;
58                                         dprint(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)\n");
59                                 }
60                                 else if (!l.enemy.islinked)
61                                 {
62                                         stop = FALSE;
63                                         l.enemy.islinked = TRUE;
64                                         dprint(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)\n");
65                                 }
66                         }
67                         l = l.chain;
68                 }
69         }
70         // now that we know which points are powered we can mark their neighbors
71         // as unshielded if team differs
72         l = links;
73         while (l)
74         {
75                 if (l.goalentity.team != l.enemy.team)
76                 {
77                         if (l.goalentity.islinked)
78                         {
79                                 dprint(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)\n");
80                                 l.enemy.isshielded = FALSE;
81                         }
82                         if (l.enemy.islinked)
83                         {
84                                 dprint(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)\n");
85                                 l.goalentity.isshielded = FALSE;
86                         }
87                 }
88                 l = l.chain;
89         }
90         // now update the takedamage and alpha variables on generator shields
91         l = findchain(classname, "onslaught_generator");
92         while (l)
93         {
94                 if (l.isshielded)
95                 {
96                         dprint(etos(l), " (generator) is shielded\n");
97                         l.enemy.alpha = 1;
98                         l.takedamage = DAMAGE_NO;
99                         l.bot_attack = FALSE;
100                 }
101                 else
102                 {
103                         dprint(etos(l), " (generator) is not shielded\n");
104                         l.enemy.alpha = -1;
105                         l.takedamage = DAMAGE_AIM;
106                         l.bot_attack = TRUE;
107                 }
108                 l = l.chain;
109         }
110         // now update the takedamage and alpha variables on control point icons
111         l = findchain(classname, "onslaught_controlpoint");
112         while (l)
113         {
114                 if (l.isshielded)
115                 {
116                         dprint(etos(l), " (point) is shielded\n");
117                         l.enemy.alpha = 1;
118                         if (l.goalentity)
119                         {
120                                 l.goalentity.takedamage = DAMAGE_NO;
121                                 l.goalentity.bot_attack = FALSE;
122                         }
123                 }
124                 else
125                 {
126                         dprint(etos(l), " (point) is not shielded\n");
127                         l.enemy.alpha = -1;
128                         if (l.goalentity)
129                         {
130                                 l.goalentity.takedamage = DAMAGE_AIM;
131                                 l.goalentity.bot_attack = TRUE;
132                         }
133                 }
134                 l = l.chain;
135         }
136         // count generators owned by each team
137         t1 = t2 = t3 = t4 = 0;
138         l = findchain(classname, "onslaught_generator");
139         while (l)
140         {
141                 if (l.iscaptured)
142                 {
143                         if (l.team == COLOR_TEAM1) t1 = 1;
144                         if (l.team == COLOR_TEAM2) t2 = 1;
145                         if (l.team == COLOR_TEAM3) t3 = 1;
146                         if (l.team == COLOR_TEAM4) t4 = 1;
147                 }
148                 l = l.chain;
149         }
150         // see if multiple teams remain (if not, it's game over)
151         if (t1 + t2 + t3 + t4 < 2)
152                 dprint("--- game over ---\n");
153         else
154                 dprint("--- done updating links ---\n");
155 };
156
157 void() onslaught_generator_think =
158 {
159         local float d;
160         local entity e;
161         self.nextthink = ceil(time + 1);
162         if (cvar("timelimit"))
163         if (time > cvar("timelimit") * 60 - 60)
164         {
165                 // self.max_health / 300 gives 5 minutes of overtime.
166                 // control points reduce the overtime duration.
167                 sound(self, CHAN_AUTO, "sound/onslaught/generator_decay.wav", 1, ATTN_NORM);
168                 d = 1;
169                 e = findchain(classname, "onslaught_controlpoint");
170                 while (e)
171                 {
172                         if (e.team != self.team)
173                         if (e.islinked)
174                                 d = d + 1;
175                         e = e.chain;
176                 }
177                 d = d * self.max_health / 300;
178                 Damage(self, self, self, d, DEATH_HURTTRIGGER, self.origin, '0 0 0');
179         }
180 };
181
182 void() onslaught_generator_deaththink =
183 {
184         local vector org;
185         if (self.count > 0)
186         {
187                 self.nextthink = time + 0.1;
188                 self.count = self.count - 1;
189                 org = randompos(self.origin + self.mins + '8 8 8', self.origin + self.maxs + '-8 -8 -8');
190                 pointparticles(particleeffectnum("onslaught_generator_smallexplosion"), org, '0 0 0', 1);
191                 sound(self, CHAN_AUTO, "sound/weapons/grenade_impact.wav", 1, ATTN_NORM);
192         }
193         else
194         {
195                 org = self.origin;
196                 pointparticles(particleeffectnum("onslaught_generator_finalexplosion"), org, '0 0 0', 1);
197                 sound(self, CHAN_AUTO, "sound/weapons/rocket_impact.wav", 1, ATTN_NORM);
198         }
199 };
200
201 void(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force) onslaught_generator_damage =
202 {
203         if (damage <= 0)
204                 return;
205         if (attacker != self)
206         {
207                 if (self.isshielded)
208                 {
209                         // this is protected by a shield, so ignore the damage
210                         if (time > self.pain_finished)
211                         if (attacker.classname == "player")
212                         {
213                                 play2(attacker, "sound/onslaught/damageblockedbyshield.wav");
214                                 self.pain_finished = time + 1;
215                         }
216                         return;
217                 }
218                 if (time > self.pain_finished)
219                 {
220                         self.pain_finished = time + 5;
221                         bprint(ColoredTeamName(self.team), " generator under attack!\n");
222                         play2team(self.team, "sound/onslaught/generator_underattack.wav");
223                 }
224         }
225         self.health = self.health - damage;
226         // choose an animation frame based on health
227         self.frame = 10 * bound(0, (1 - self.health / self.max_health), 1);
228         // see if the generator is still functional, or dying
229         if (self.health > 0)
230                 bprint(ColoredTeamName(self.team), " generator has ", ftos(floor(self.health)), " health remaining\n");
231         else
232         {
233                 if (attacker == self)
234                         bprint(ColoredTeamName(self.team), " generator spontaneously exploded due to overtime!\n");
235                 else
236                         bprint(ColoredTeamName(self.team), " generator destroyed by ", ColoredTeamName(attacker.team), "!\n");
237                 self.iscaptured = FALSE;
238                 self.islinked = FALSE;
239                 self.isshielded = FALSE;
240                 self.takedamage = DAMAGE_NO; // can't be hurt anymore
241                 self.event_damage = SUB_Null; // won't do anything if hurt
242                 self.count = 30; // 30 explosions
243                 self.think = onslaught_generator_deaththink; // explosion sequence
244                 self.nextthink = time; // start exploding immediately
245                 self.think(); // do the first explosion now
246                 onslaught_updatelinks();
247         }
248 };
249
250 // update links after a delay
251 void() onslaught_generator_delayed =
252 {
253         onslaught_updatelinks();
254         // now begin normal thinking
255         self.think = onslaught_generator_think;
256         self.nextthink = time;
257 };
258
259 /*QUAKED onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
260 Base generator.
261
262 onslaught_link entities can target this.
263
264 keys:
265 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
266 "targetname" - name that onslaught_link entities will use to target this.
267 */
268 void() onslaught_generator =
269 {
270         if (!g_onslaught)
271         {
272                 remove(self);
273                 return;
274         }
275         local entity e;
276         precache_model("models/onslaught/generator.md3");
277         precache_model("models/onslaught/generator_shield.md3");
278         precache_sound("sound/onslaught/generator_decay.wav");
279         precache_sound("sound/weapons/grenade_impact.wav");
280         precache_sound("sound/weapons/rocket_impact.wav");
281         precache_sound("sound/onslaught/generator_underattack.wav");
282         if (!self.team)
283                 objerror("team must be set");
284         self.colormap = 1024 + (self.team - 1) * 17;
285         self.solid = SOLID_BSP;
286         self.movetype = MOVETYPE_NONE;
287         self.max_health = self.health = 3000;
288         setmodel(self, "models/onslaught/generator.md3");
289         //setsize(self, '-32 -32 -24', '32 32 64');
290         setorigin(self, self.origin);
291         self.takedamage = DAMAGE_AIM;
292         self.bot_attack = TRUE;
293         self.event_damage = onslaught_generator_damage;
294         self.iscaptured = TRUE;
295         self.islinked = TRUE;
296         self.isshielded = TRUE;
297         // spawn shield model which indicates whether this can be damaged
298         self.enemy = e = spawn();
299         e.solid = SOLID_NOT;
300         e.movetype = MOVETYPE_NONE;
301         e.effects = EF_ADDITIVE;
302         setmodel(e, "models/onslaught/generator_shield.md3");
303         //setsize(e, '-32 -32 0', '32 32 128');
304         setorigin(e, self.origin);
305         e.colormap = self.colormap;
306         e.team = self.team;
307         self.think = onslaught_generator_delayed;
308         self.nextthink = time + 0.2;
309 };
310
311 void(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force) onslaught_controlpoint_icon_damage =
312 {
313         if (damage <= 0)
314                 return;
315         if (self.owner.isshielded)
316         {
317                 // this is protected by a shield, so ignore the damage
318                 if (time > self.pain_finished)
319                 if (attacker.classname == "player")
320                 {
321                         play2(attacker, "sound/onslaught/damageblockedbyshield.wav");
322                         self.pain_finished = time + 1;
323                 }
324                 return;
325         }
326         if (time > self.pain_finished)
327         if (attacker.classname == "player")
328         {
329                 play2team(self.team, "sound/onslaught/controlpoint_underattack.wav");
330                 self.pain_finished = time + 5;
331         }
332         self.health = self.health - damage;
333         self.alpha = self.health / self.max_health;
334         self.pain_finished = time + 1;
335         // colormod flash when shot
336         self.colormod = '2 2 2';
337         if (self.health < 0)
338         {
339                 sound(self, CHAN_AUTO, "sound/weapons/grenade_impact.wav", 1, ATTN_NORM);
340                 pointparticles(particleeffectnum("onslaught_controlpoint_explosion"), self.origin, '0 0 0', 1);
341                 bprint(ColoredTeamName(self.team), " ", self.message, " control point destroyed by ", ColoredTeamName(attacker.team), "\n");
342                 self.owner.goalentity = world;
343                 self.owner.islinked = FALSE;
344                 self.owner.iscaptured = FALSE;
345                 self.owner.team = 0;
346                 self.owner.colormap = 1024;
347                 onslaught_updatelinks();
348                 remove(self);
349         }
350 };
351
352 void() onslaught_controlpoint_icon_think =
353 {
354         self.nextthink = time + 0.1;
355         if (time > self.pain_finished + 1)
356         {
357                 self.health = self.health + self.count;
358                 if (self.health >= self.max_health)
359                         self.health = self.max_health;
360         }
361         self.alpha = self.health / self.max_health;
362         // colormod flash when shot
363         self.colormod = '1 1 1' * (2 - bound(0, (self.pain_finished - time) / 10, 1));
364 };
365
366 void() onslaught_controlpoint_icon_buildthink =
367 {
368         local entity oself;
369         oself = self;
370
371         self.nextthink = time + 0.1;
372         self.health = self.health + self.count;
373         if (self.health >= self.max_health)
374         {
375                 self.health = self.max_health;
376                 self.count = self.count * 0.2; // slow repair rate from now on
377                 self.think = onslaught_controlpoint_icon_think;
378                 sound(self, CHAN_BODY, "sound/onslaught/controlpoint_built.wav", 1, ATTN_NORM);
379                 bprint(ColoredTeamName(self.team), " captured ", self.owner.message, " control point\n");
380                 self.owner.iscaptured = TRUE;
381                 onslaught_updatelinks();
382
383                 // Use targets now (somebody make sure this is in the right place..)
384                 self = self.owner;
385                 activator = self;
386                 SUB_UseTargets ();
387                 self = oself;
388         }
389         self.alpha = self.health / self.max_health;
390         // colormod flash when shot
391         self.colormod = '1 1 1' * (2 - bound(0, (self.pain_finished - time) / 10, 1));
392 };
393
394 void() onslaught_controlpoint_touch =
395 {
396         local entity e;
397         if (other.classname != "player")
398                 return;
399         // if there's already an icon built, nothing happens
400         if (self.goalentity)
401         {
402                 dprint("a\n");
403                 return;
404         }
405         // shielded points are definitely off-limits
406         if (self.isshielded)
407         {
408                 dprint("b\n");
409                 return;
410         }
411         // check to see if this player has a legitimate claim to capture this
412         // control point - more specifically that there is a captured path of
413         // points leading back to the team generator
414         e = findchain(classname, "onslaught_link");
415         while (e)
416         {
417                 if (e.goalentity == self)
418                 {
419                         dprint(etos(e), " (link) connects to ", etos(e.enemy), " (point)");
420                         if (e.enemy.islinked)
421                         {
422                                 dprint(" which is linked");
423                                 if (e.enemy.team == other.team)
424                                 {
425                                         dprint(" and has the correct team!\n");
426                                         break;
427                                 }
428                                 else
429                                         dprint(" but has the wrong team\n");
430                         }
431                         else
432                                 dprint("\n");
433                 }
434                 else if (e.enemy == self)
435                 {
436                         dprint(etos(e), " (link) connects to ", etos(e.goalentity), " (point)");
437                         if (e.goalentity.islinked)
438                         {
439                                 dprint(" which is linked");
440                                 if (e.goalentity.team == other.team)
441                                 {
442                                         dprint(" and has a team!\n");
443                                         break;
444                                 }
445                                 else
446                                         dprint(" but has the wrong team\n");
447                         }
448                         else
449                                 dprint("\n");
450                 }
451                 e = e.chain;
452         }
453         if (!e)
454         {
455                 dprint("c\n");
456                 return;
457         }
458         // we've verified that this player has a legitimate claim to this point,
459         // so start building the captured point icon (which only captures this
460         // point if it successfully builds without being destroyed first)
461         self.goalentity = e = spawn();
462         e.owner = self;
463         e.max_health = 1000;
464         e.health = e.max_health * 0.1;
465         e.alpha = e.health / e.max_health;
466         e.solid = SOLID_BBOX;
467         e.movetype = MOVETYPE_NONE;
468         setmodel(e, "models/onslaught/controlpoint_icon.md3");
469         setsize(e, '-32 -32 -32', '32 32 32');
470         setorigin(e, self.origin + '0 0 96');
471         e.takedamage = DAMAGE_AIM;
472         e.bot_attack = TRUE;
473         e.event_damage = onslaught_controlpoint_icon_damage;
474         e.team = other.team;
475         e.colormap = 1024 + (e.team - 1) * 17;
476         e.think = onslaught_controlpoint_icon_buildthink;
477         e.nextthink = time + 0.1;
478         e.count = e.max_health / 50; // how long it takes to build
479         sound(e, CHAN_BODY, "sound/onslaught/controlpoint_build.wav", 1, ATTN_NORM);
480         self.team = e.team;
481         self.colormap = e.colormap;
482 };
483
484 /*QUAKED onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
485 Control point.  Be sure to give this enough clearance so that the shootable part has room to exist
486
487 This should link to an onslaught_controlpoint entity or onslaught_generator entity.
488
489 keys:
490 "targetname" - name that onslaught_link entities will use to target this.
491 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
492 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
493 */
494 void() onslaught_controlpoint =
495 {
496         local entity e;
497         if (!g_onslaught)
498         {
499                 remove(self);
500                 return;
501         }
502         precache_model("models/onslaught/controlpoint_pad.md3");
503         precache_model("models/onslaught/controlpoint_shield.md3");
504         precache_model("models/onslaught/controlpoint_icon.md3");
505         precache_sound("sound/onslaught/controlpoint_build.wav");
506         precache_sound("sound/onslaught/controlpoint_built.wav");
507         precache_sound("sound/weapons/grenade_impact.wav");
508         precache_sound("sound/onslaught/damageblockedbyshield.wav");
509         precache_sound("sound/onslaught/controlpoint_underattack.wav");
510         self.solid = SOLID_BSP;
511         self.movetype = MOVETYPE_NONE;
512         setmodel(self, "models/onslaught/controlpoint_pad.md3");
513         //setsize(self, '-32 -32 0', '32 32 8');
514         setorigin(self, self.origin);
515         self.touch = onslaught_controlpoint_touch;
516         self.team = 0;
517         self.colormap = 1024;
518         self.iscaptured = FALSE;
519         self.islinked = FALSE;
520         self.isshielded = TRUE;
521         // spawn shield model which indicates whether this can be damaged
522         self.enemy = e = spawn();
523         e.solid = SOLID_NOT;
524         e.movetype = MOVETYPE_NONE;
525         e.effects = EF_ADDITIVE;
526         setmodel(e, "models/onslaught/controlpoint_shield.md3");
527         //setsize(e, '-32 -32 0', '32 32 128');
528         setorigin(e, self.origin);
529         e.colormap = self.colormap;
530         onslaught_updatelinks();
531 };
532
533 void() onslaught_link_delayed =
534 {
535         self.goalentity = find(world, targetname, self.target);
536         self.enemy = find(world, targetname, self.target2);
537         if (!self.goalentity)
538                 objerror("can not find target\n");
539         if (!self.enemy)
540                 objerror("can not find target2\n");
541         dprint(etos(self.goalentity), " linked with ", etos(self.enemy), "\n");
542 }
543
544 /*QUAKED onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
545 Link between control points.
546
547 This entity targets two different onslaught_controlpoint or onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
548
549 keys:
550 "target" - first control point.
551 "target2" - second control point.
552 */
553 void() onslaught_link =
554 {
555         if (!g_onslaught)
556         {
557                 remove(self);
558                 return;
559         }
560         if (self.target == "" || self.target2 == "")
561                 objerror("target and target2 must be set\n");
562         self.think = onslaught_link_delayed;
563         self.nextthink = time + 0.1;
564 };
565
566 void() onslaught_spawnpoint_use =
567 {
568         self.team = activator.team;
569 };