data/qcsrc/server/mode_onslaught.qc

   1 void onslaught_generator_updatesprite(entity e);
   2 void onslaught_controlpoint_updatesprite(entity e);
   3 void onslaught_link_checkupdate();
   4
   5 .entity sprite;
   6 .string target2;
   7 .float iscaptured;
   8 .float islinked;
   9 .float isgenneighbor_red;
  10 .float isgenneighbor_blue;
  11 .float iscpneighbor_red;
  12 .float iscpneighbor_blue;
  13 .float isshielded;
  14 .float lasthealth;
  15 .float lastteam;
  16 .float lastshielded;
  17
  18 .string model1, model2, model3;
  19
  20 void onslaught_updatelinks()
  21 {
  22         local entity l, links;
  23         local float stop, t1, t2, t3, t4;
  24         // first check if the game has ended
  25         dprint("--- updatelinks ---\n");
  26         links = findchain(classname, "onslaught_link");
  27         // mark generators as being shielded and networked
  28         l = findchain(classname, "onslaught_generator");
  29         while (l)
  30         {
  31                 if (l.iscaptured)
  32                         dprint(etos(l), " (generator) belongs to team ", ftos(l.team), "\n");
  33                 else
  34                         dprint(etos(l), " (generator) is destroyed\n");
  35                 l.islinked = l.iscaptured;
  36                 l.isshielded = l.iscaptured;
  37                 l = l.chain;
  38         }
  39         // mark points as shielded and not networked
  40         l = findchain(classname, "onslaught_controlpoint");
  41         while (l)
  42         {
  43                 l.islinked = FALSE;
  44                 l.isshielded = TRUE;
  45                 l.isgenneighbor_red = FALSE;
  46                 l.isgenneighbor_blue = FALSE;
  47                 l.iscpneighbor_red = FALSE;
  48                 l.iscpneighbor_blue = FALSE;
  49                 dprint(etos(l), " (point) belongs to team ", ftos(l.team), "\n");
  50                 l = l.chain;
  51         }
  52         // flow power outward from the generators through the network
  53         l = links;
  54         while (l)
  55         {
  56                 dprint(etos(l), " (link) connects ", etos(l.goalentity), " with ", etos(l.enemy), "\n");
  57                 l = l.chain;
  58         }
  59         stop = FALSE;
  60         while (!stop)
  61         {
  62                 stop = TRUE;
  63                 l = links;
  64                 while (l)
  65                 {
  66                         // if both points are captured by the same team, and only one of
  67                         // them is powered, mark the other one as powered as well
  68                         if (l.enemy.iscaptured && l.goalentity.iscaptured)
  69                         if (l.enemy.islinked != l.goalentity.islinked)
  70                         if (l.enemy.team == l.goalentity.team)
  71                         {
  72                                 if (!l.goalentity.islinked)
  73                                 {
  74                                         stop = FALSE;
  75                                         l.goalentity.islinked = TRUE;
  76                                         dprint(etos(l), " (link) is marking ", etos(l.goalentity), " (point) because its team matches ", etos(l.enemy), " (point)\n");
  77                                 }
  78                                 else if (!l.enemy.islinked)
  79                                 {
  80                                         stop = FALSE;
  81                                         l.enemy.islinked = TRUE;
  82                                         dprint(etos(l), " (link) is marking ", etos(l.enemy), " (point) because its team matches ", etos(l.goalentity), " (point)\n");
  83                                 }
  84                         }
  85                         l = l.chain;
  86                 }
  87         }
  88         // now that we know which points are powered we can mark their neighbors
  89         // as unshielded if team differs
  90         l = links;
  91         while (l)
  92         {
  93                 if (l.goalentity.team != l.enemy.team)
  94                 {
  95                         if (l.goalentity.islinked)
  96                         {
  97                                 dprint(etos(l), " (link) is unshielding ", etos(l.enemy), " (point) because its team does not match ", etos(l.goalentity), " (point)\n");
  98                                 l.enemy.isshielded = FALSE;
  99                                 if(l.goalentity.classname == "onslaught_generator")
 100                                 {
 101                                         if(l.goalentity.team == COLOR_TEAM1)
 102                                                 l.enemy.isgenneighbor_red = TRUE;
 103                                         else if(l.goalentity.team == COLOR_TEAM2)
 104                                                 l.enemy.isgenneighbor_blue = TRUE;
 105                                 }
 106                                 else
 107                                 {
 108                                         if(l.goalentity.team == COLOR_TEAM1)
 109                                                 l.enemy.iscpneighbor_red = TRUE;
 110                                         else if(l.goalentity.team == COLOR_TEAM2)
 111                                                 l.enemy.iscpneighbor_blue = TRUE;
 112                                 }
 113                         }
 114                         if (l.enemy.islinked)
 115                         {
 116                                 dprint(etos(l), " (link) is unshielding ", etos(l.goalentity), " (point) because its team does not match ", etos(l.enemy), " (point)\n");
 117                                 l.goalentity.isshielded = FALSE;
 118                                 if(l.enemy.classname == "onslaught_generator")
 119                                 {
 120                                         if(l.enemy.team == COLOR_TEAM1)
 121                                                 l.goalentity.isgenneighbor_red = TRUE;
 122                                         else if(l.enemy.team == COLOR_TEAM2)
 123                                                 l.goalentity.isgenneighbor_blue = TRUE;
 124                                 }
 125                                 else
 126                                 {
 127                                         if(l.enemy.team == COLOR_TEAM1)
 128                                                 l.goalentity.iscpneighbor_red = TRUE;
 129                                         else if(l.enemy.team == COLOR_TEAM2)
 130                                                 l.goalentity.iscpneighbor_blue = TRUE;
 131                                 }
 132                         }
 133                 }
 134                 l = l.chain;
 135         }
 136         // now update the takedamage and alpha variables on generator shields
 137         l = findchain(classname, "onslaught_generator");
 138         while (l)
 139         {
 140                 if (l.isshielded)
 141                 {
 142                         dprint(etos(l), " (generator) is shielded\n");
 143                         l.enemy.alpha = 1;
 144                         l.takedamage = DAMAGE_NO;
 145                         l.bot_attack = FALSE;
 146                 }
 147                 else
 148                 {
 149                         dprint(etos(l), " (generator) is not shielded\n");
 150                         l.enemy.alpha = -1;
 151                         l.takedamage = DAMAGE_AIM;
 152                         l.bot_attack = TRUE;
 153                 }
 154                 l = l.chain;
 155         }
 156         // now update the takedamage and alpha variables on control point icons
 157         l = findchain(classname, "onslaught_controlpoint");
 158         while (l)
 159         {
 160                 if (l.isshielded)
 161                 {
 162                         dprint(etos(l), " (point) is shielded\n");
 163                         l.enemy.alpha = 1;
 164                         if (l.goalentity)
 165                         {
 166                                 l.goalentity.takedamage = DAMAGE_NO;
 167                                 l.goalentity.bot_attack = FALSE;
 168                         }
 169                 }
 170                 else
 171                 {
 172                         dprint(etos(l), " (point) is not shielded\n");
 173                         l.enemy.alpha = -1;
 174                         if (l.goalentity)
 175                         {
 176                                 l.goalentity.takedamage = DAMAGE_AIM;
 177                                 l.goalentity.bot_attack = TRUE;
 178                         }
 179                 }
 180                 onslaught_controlpoint_updatesprite(l);
 181                 l = l.chain;
 182         }
 183         // count generators owned by each team
 184         t1 = t2 = t3 = t4 = 0;
 185         l = findchain(classname, "onslaught_generator");
 186         while (l)
 187         {
 188                 if (l.iscaptured)
 189                 {
 190                         if (l.team == COLOR_TEAM1) t1 = 1;
 191                         if (l.team == COLOR_TEAM2) t2 = 1;
 192                         if (l.team == COLOR_TEAM3) t3 = 1;
 193                         if (l.team == COLOR_TEAM4) t4 = 1;
 194                 }
 195                 onslaught_generator_updatesprite(l);
 196                 l = l.chain;
 197         }
 198         // see if multiple teams remain (if not, it's game over)
 199         if (t1 + t2 + t3 + t4 < 2)
 200                 dprint("--- game over ---\n");
 201         else
 202                 dprint("--- done updating links ---\n");
 203 };
 204
 205 float onslaught_controlpoint_can_be_linked(entity cp, float t)
 206 {
 207         if(t == COLOR_TEAM1)
 208         {
 209                 if(cp.isgenneighbor_red)
 210                         return 2;
 211                 if(cp.iscpneighbor_red)
 212                         return 1;
 213         }
 214         else if(t == COLOR_TEAM2)
 215         {
 216                 if(cp.isgenneighbor_blue)
 217                         return 2;
 218                 if(cp.iscpneighbor_blue)
 219                         return 1;
 220         }
 221         return 0;
 222 /*
 223         entity e;
 224         // check to see if this player has a legitimate claim to capture this
 225         // control point - more specifically that there is a captured path of
 226         // points leading back to the team generator
 227         e = findchain(classname, "onslaught_link");
 228         while (e)
 229         {
 230                 if (e.goalentity == cp)
 231                 {
 232                         dprint(etos(e), " (link) connects to ", etos(e.enemy), " (point)");
 233                         if (e.enemy.islinked)
 234                         {
 235                                 dprint(" which is linked");
 236                                 if (e.enemy.team == t)
 237                                 {
 238                                         dprint(" and has the correct team!\n");
 239                                         return 1;
 240                                 }
 241                                 else
 242                                         dprint(" but has the wrong team\n");
 243                         }
 244                         else
 245                                 dprint("\n");
 246                 }
 247                 else if (e.enemy == cp)
 248                 {
 249                         dprint(etos(e), " (link) connects to ", etos(e.goalentity), " (point)");
 250                         if (e.goalentity.islinked)
 251                         {
 252                                 dprint(" which is linked");
 253                                 if (e.goalentity.team == t)
 254                                 {
 255                                         dprint(" and has a team!\n");
 256                                         return 1;
 257                                 }
 258                                 else
 259                                         dprint(" but has the wrong team\n");
 260                         }
 261                         else
 262                                 dprint("\n");
 263                 }
 264                 e = e.chain;
 265         }
 266         return 0;
 267 */
 268 }
 269
 270 float onslaught_controlpoint_attackable(entity cp, float t)
 271 // -2: SAME TEAM, attackable by enemy!
 272 // -1: SAME TEAM!
 273 // 0:  off limits
 274 // 1:  attack it
 275 // 2:  touch it
 276 // 3:  attack it (HIGH PRIO)
 277 // 4:  touch it (HIGH PRIO)
 278 {
 279         float a;
 280
 281         if(cp.isshielded)
 282         {
 283                 return 0;
 284         }
 285         else if(cp.goalentity)
 286         {
 287                 // if there's already an icon built, nothing happens
 288                 if(cp.team == t)
 289                 {
 290                         a = onslaught_controlpoint_can_be_linked(cp, COLOR_TEAM1 + COLOR_TEAM2 - t);
 291                         if(a) // attackable by enemy?
 292                                 return -2; // EMERGENCY!
 293                         return -1;
 294                 }
 295                 // we know it can be linked, so no need to check
 296                 // but...
 297                 a = onslaught_controlpoint_can_be_linked(cp, t);
 298                 if(a == 2) // near our generator?
 299                         return 3; // EMERGENCY!
 300                 return 1;
 301         }
 302         else
 303         {
 304                 // free point
 305                 if(onslaught_controlpoint_can_be_linked(cp, t))
 306                 {
 307                         a = onslaught_controlpoint_can_be_linked(cp, COLOR_TEAM1 + COLOR_TEAM2 - t);
 308                         if(a == 2)
 309                                 return 4; // GET THIS ONE NOW!
 310                         else
 311                                 return 2; // TOUCH ME
 312                 }
 313         }
 314         return 0;
 315 }
 316
 317 void onslaught_generator_think()
 318 {
 319         local float d;
 320         local entity e;
 321         self.nextthink = ceil(time + 1);
 322         if (cvar("timelimit"))
 323         if (time > cvar("timelimit") * 60 - 60)
 324         {
 325                 // self.max_health / 300 gives 5 minutes of overtime.
 326                 // control points reduce the overtime duration.
 327                 sound(self, CHAN_TRIGGER, "sound/onslaught/generator_decay.wav", VOL_BASE, ATTN_NORM);
 328                 d = 1;
 329                 e = findchain(classname, "onslaught_controlpoint");
 330                 while (e)
 331                 {
 332                         if (e.team != self.team)
 333                         if (e.islinked)
 334                                 d = d + 1;
 335                         e = e.chain;
 336                 }
 337                 d = d * self.max_health / 300;
 338                 Damage(self, self, self, d, DEATH_HURTTRIGGER, self.origin, '0 0 0');
 339         }
 340 };
 341
 342 void onslaught_generator_deaththink()
 343 {
 344         local vector org;
 345         if (self.count > 0)
 346         {
 347                 self.nextthink = time + 0.1;
 348                 self.count = self.count - 1;
 349                 org = randompos(self.origin + self.mins + '8 8 8', self.origin + self.maxs + '-8 -8 -8');
 350                 pointparticles(particleeffectnum("onslaught_generator_smallexplosion"), org, '0 0 0', 1);
 351                 sound(self, CHAN_TRIGGER, "sound/weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 352         }
 353         else
 354         {
 355                 org = self.origin;
 356                 pointparticles(particleeffectnum("onslaught_generator_finalexplosion"), org, '0 0 0', 1);
 357                 sound(self, CHAN_TRIGGER, "sound/weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 358         }
 359 };
 360
 361 void onslaught_generator_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 362 {
 363         if (damage <= 0)
 364                 return;
 365         if (attacker != self)
 366         {
 367                 if (self.isshielded)
 368                 {
 369                         // this is protected by a shield, so ignore the damage
 370                         if (time > self.pain_finished)
 371                         if (attacker.classname == "player")
 372                         {
 373                                 play2(attacker, "sound/onslaught/damageblockedbyshield.wav");
 374                                 self.pain_finished = time + 1;
 375                         }
 376                         return;
 377                 }
 378                 if (time > self.pain_finished)
 379                 {
 380                         self.pain_finished = time + 5;
 381                         bprint(ColoredTeamName(self.team), " generator under attack!\n");
 382                         play2team(self.team, "sound/onslaught/generator_underattack.wav");
 383                 }
 384         }
 385         self.health = self.health - damage;
 386         // choose an animation frame based on health
 387         self.frame = 10 * bound(0, (1 - self.health / self.max_health), 1);
 388         // see if the generator is still functional, or dying
 389         if (self.health > 0)
 390         {
 391                 float h, lh;
 392                 lh = ceil(self.lasthealth / 100) * 100;
 393                 h = ceil(self.health / 100) * 100;
 394                 if(lh != h)
 395                         bprint(ColoredTeamName(self.team), " generator has less than ", ftos(h), " health remaining\n");
 396                 self.lasthealth = self.health;
 397         }
 398         else
 399         {
 400                 if (attacker == self)
 401                         bprint(ColoredTeamName(self.team), " generator spontaneously exploded due to overtime!\n");
 402                 else
 403                 {
 404                         string t;
 405                         t = ColoredTeamName(attacker.team);
 406                         bprint(ColoredTeamName(self.team), " generator destroyed by ", t, "!\n");
 407                 }
 408                 self.iscaptured = FALSE;
 409                 self.islinked = FALSE;
 410                 self.isshielded = FALSE;
 411                 self.takedamage = DAMAGE_NO; // can't be hurt anymore
 412                 self.event_damage = SUB_Null; // won't do anything if hurt
 413                 self.count = 30; // 30 explosions
 414                 self.think = onslaught_generator_deaththink; // explosion sequence
 415                 self.nextthink = time; // start exploding immediately
 416                 self.think(); // do the first explosion now
 417                 onslaught_updatelinks();
 418         }
 419 };
 420
 421 // update links after a delay
 422 void onslaught_generator_delayed()
 423 {
 424         onslaught_updatelinks();
 425         // now begin normal thinking
 426         self.think = onslaught_generator_think;
 427         self.nextthink = time;
 428 };
 429
 430 string onslaught_generator_waypointsprite_for_team(entity e, float t)
 431 {
 432         if(t == e.team)
 433         {
 434                 if(e.team == COLOR_TEAM1)
 435                         return "ons-gen-red";
 436                 else if(e.team == COLOR_TEAM2)
 437                         return "ons-gen-blue";
 438         }
 439         if(e.isshielded)
 440                 return "ons-gen-shielded";
 441         if(e.team == COLOR_TEAM1)
 442                 return "ons-gen-red";
 443         else if(e.team == COLOR_TEAM2)
 444                 return "ons-gen-blue";
 445         return "";
 446 }
 447
 448 void onslaught_generator_updatesprite(entity e)
 449 {
 450         string s1, s2, s3;
 451         s1 = onslaught_generator_waypointsprite_for_team(e, COLOR_TEAM1);
 452         s2 = onslaught_generator_waypointsprite_for_team(e, COLOR_TEAM2);
 453         s3 = onslaught_generator_waypointsprite_for_team(e, -1);
 454         WaypointSprite_UpdateSprites(e.sprite, s1, s2, s3);
 455
 456         if(e.lastteam != e.team + 2 || e.lastshielded != e.isshielded)
 457         {
 458                 e.lastteam = e.team + 2;
 459                 e.lastshielded = e.isshielded;
 460                 if(e.lastshielded)
 461                 {
 462                         if(e.team == COLOR_TEAM1)
 463                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0 0');
 464                         else if(e.team == COLOR_TEAM2)
 465                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0 0 0.5');
 466                         else
 467                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.5 0.5 0.5');
 468                 }
 469                 else
 470                 {
 471                         if(e.team == COLOR_TEAM1)
 472                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '1 0 0');
 473                         else if(e.team == COLOR_TEAM2)
 474                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0 0 1');
 475                         else
 476                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_GENERATOR, '0.75 0.75 0.75');
 477                 }
 478                 WaypointSprite_Ping(e.sprite);
 479         }
 480 }
 481
 482 string onslaught_controlpoint_waypointsprite_for_team(entity e, float t)
 483 {
 484         float a;
 485         if(t != -1)
 486         {
 487                 a = onslaught_controlpoint_attackable(e, t);
 488                 if(a == 3 || a == 4) // ATTACK/TOUCH THIS ONE NOW
 489                 {
 490                         if(e.team == COLOR_TEAM1)
 491                                 return "ons-cp-atck-red";
 492                         else if(e.team == COLOR_TEAM2)
 493                                 return "ons-cp-atck-blue";
 494                         else
 495                                 return "ons-cp-atck-neut";
 496                 }
 497                 else if(a == -2) // DEFEND THIS ONE NOW
 498                 {
 499                         if(e.team == COLOR_TEAM1)
 500                                 return "ons-cp-dfnd-red";
 501                         else if(e.team == COLOR_TEAM2)
 502                                 return "ons-cp-dfnd-blue";
 503                 }
 504                 else if(e.team == t || a == -1 || a == 1) // own point, or fire at it
 505                 {
 506                         if(e.team == COLOR_TEAM1)
 507                                 return "ons-cp-red";
 508                         else if(e.team == COLOR_TEAM2)
 509                                 return "ons-cp-blue";
 510                 }
 511                 else if(a == 2) // touch it
 512                         return "ons-cp-neut";
 513         }
 514         else
 515         {
 516                 if(e.team == COLOR_TEAM1)
 517                         return "ons-cp-red";
 518                 else if(e.team == COLOR_TEAM2)
 519                         return "ons-cp-blue";
 520                 else
 521                         return "ons-cp-neut";
 522         }
 523         return "";
 524 }
 525
 526 void onslaught_controlpoint_updatesprite(entity e)
 527 {
 528         string s1, s2, s3;
 529         s1 = onslaught_controlpoint_waypointsprite_for_team(e, COLOR_TEAM1);
 530         s2 = onslaught_controlpoint_waypointsprite_for_team(e, COLOR_TEAM2);
 531         s3 = onslaught_controlpoint_waypointsprite_for_team(e, -1);
 532         WaypointSprite_UpdateSprites(e.sprite, s1, s2, s3);
 533
 534         float sh;
 535         sh = !(onslaught_controlpoint_can_be_linked(e, COLOR_TEAM1) || onslaught_controlpoint_can_be_linked(e, COLOR_TEAM2));
 536
 537         if(e.lastteam != e.team + 2 || e.lastshielded != sh)
 538         {
 539                 e.lastteam = e.team + 2;
 540                 e.lastshielded = sh;
 541                 if(e.lastshielded)
 542                 {
 543                         if(e.team == COLOR_TEAM1)
 544                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0 0');
 545                         else if(e.team == COLOR_TEAM2)
 546                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0 0 0.5');
 547                         else
 548                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.5 0.5 0.5');
 549                 }
 550                 else
 551                 {
 552                         if(e.team == COLOR_TEAM1)
 553                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '1 0 0');
 554                         else if(e.team == COLOR_TEAM2)
 555                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0 0 1');
 556                         else
 557                                 WaypointSprite_UpdateTeamRadar(e.sprite, RADARICON_CONTROLPOINT, '0.75 0.75 0.75');
 558                 }
 559                 WaypointSprite_Ping(e.sprite);
 560         }
 561 }
 562
 563 /*QUAKED spawnfunc_onslaught_generator (0 .5 .8) (-32 -32 -24) (32 32 64)
 564 Base generator.
 565
 566 spawnfunc_onslaught_link entities can target this.
 567
 568 keys:
 569 "team" - team that owns this generator (5 = red, 14 = blue, etc), MUST BE SET.
 570 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
 571 */
 572 void spawnfunc_onslaught_generator()
 573 {
 574         if (!g_onslaught)
 575         {
 576                 remove(self);
 577                 return;
 578         }
 579
 580         local entity e;
 581         precache_model("models/onslaught/generator.md3");
 582         precache_model("models/onslaught/generator_shield.md3");
 583         precache_sound("sound/onslaught/generator_decay.wav");
 584         precache_sound("sound/weapons/grenade_impact.wav");
 585         precache_sound("sound/weapons/rocket_impact.wav");
 586         precache_sound("sound/onslaught/generator_underattack.wav");
 587         if (!self.team)
 588                 objerror("team must be set");
 589         self.team_saved = self.team;
 590         self.colormap = 1024 + (self.team - 1) * 17;
 591         self.solid = SOLID_BSP;
 592         self.movetype = MOVETYPE_NONE;
 593         self.lasthealth = self.max_health = self.health = cvar("g_onslaught_gen_health");
 594         setmodel(self, "models/onslaught/generator.md3");
 595         //setsize(self, '-32 -32 -24', '32 32 64');
 596         setorigin(self, self.origin);
 597         self.takedamage = DAMAGE_AIM;
 598         self.bot_attack = TRUE;
 599         self.event_damage = onslaught_generator_damage;
 600         self.iscaptured = TRUE;
 601         self.islinked = TRUE;
 602         self.isshielded = TRUE;
 603         // spawn shield model which indicates whether this can be damaged
 604         self.enemy = e = spawn();
 605         e.solid = SOLID_NOT;
 606         e.movetype = MOVETYPE_NONE;
 607         e.effects = EF_ADDITIVE;
 608         setmodel(e, "models/onslaught/generator_shield.md3");
 609         //setsize(e, '-32 -32 0', '32 32 128');
 610         setorigin(e, self.origin);
 611         e.colormap = self.colormap;
 612         e.team = self.team;
 613         self.think = onslaught_generator_delayed;
 614         self.nextthink = time + 0.2;
 615
 616         WaypointSprite_SpawnFixed(string_null, e.origin + '0 0 1' * e.maxs_z, self, sprite);
 617         WaypointSprite_UpdateRule(self.sprite, COLOR_TEAM2, SPRITERULE_TEAMPLAY);
 618
 619         onslaught_updatelinks();
 620 };
 621
 622 void onslaught_generator_reset()
 623 {
 624         self.team = self.team_saved;
 625         self.lasthealth = self.max_health = self.health = cvar("g_onslaught_gen_health");
 626         self.takedamage = DAMAGE_AIM;
 627         self.bot_attack = TRUE;
 628         self.iscaptured = TRUE;
 629         self.islinked = TRUE;
 630         self.isshielded = TRUE;
 631         self.enemy.solid = SOLID_NOT;
 632         self.think = onslaught_generator_delayed;
 633         self.nextthink = time + 0.2;
 634 }
 635
 636 void onslaught_controlpoint_icon_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 637 {
 638         entity oself;
 639         if (damage <= 0)
 640                 return;
 641         if (self.owner.isshielded)
 642         {
 643                 // this is protected by a shield, so ignore the damage
 644                 if (time > self.pain_finished)
 645                 if (attacker.classname == "player")
 646                 {
 647                         play2(attacker, "sound/onslaught/damageblockedbyshield.wav");
 648                         self.pain_finished = time + 1;
 649                 }
 650                 return;
 651         }
 652         if (time > self.pain_finished)
 653         if (attacker.classname == "player")
 654         {
 655                 play2team(self.team, "sound/onslaught/controlpoint_underattack.wav");
 656                 self.pain_finished = time + 5;
 657         }
 658         self.health = self.health - damage;
 659         self.alpha = self.health / self.max_health;
 660         self.pain_finished = time + 1;
 661         // colormod flash when shot
 662         self.colormod = '2 2 2';
 663         if (self.health < 0)
 664         {
 665                 sound(self, CHAN_TRIGGER, "sound/weapons/grenade_impact.wav", VOL_BASE, ATTN_NORM);
 666                 pointparticles(particleeffectnum("onslaught_controlpoint_explosion"), self.origin, '0 0 0', 1);
 667                 {
 668                         string t;
 669                         t = ColoredTeamName(attacker.team);
 670                         bprint(ColoredTeamName(self.team), " ", self.message, " control point destroyed by ", t, "\n");
 671                 }
 672                 self.owner.goalentity = world;
 673                 self.owner.islinked = FALSE;
 674                 self.owner.iscaptured = FALSE;
 675                 self.owner.team = 0;
 676                 self.owner.colormap = 1024;
 677                 onslaught_updatelinks();
 678
 679                 // Use targets now (somebody make sure this is in the right place..)
 680                 oself = self;
 681                 self = self.owner;
 682                 activator = self.owner;
 683                 SUB_UseTargets ();
 684                 self = oself;
 685
 686                 remove(self);
 687         }
 688 };
 689
 690 void onslaught_controlpoint_icon_think()
 691 {
 692         self.nextthink = time + 0.1;
 693         if (time > self.pain_finished + 1)
 694         {
 695                 self.health = self.health + self.count;
 696                 if (self.health >= self.max_health)
 697                         self.health = self.max_health;
 698         }
 699         self.alpha = self.health / self.max_health;
 700         // colormod flash when shot
 701         self.colormod = '1 1 1' * (2 - bound(0, (self.pain_finished - time) / 10, 1));
 702 };
 703
 704 void onslaught_controlpoint_icon_buildthink()
 705 {
 706         local entity oself;
 707
 708         self.nextthink = time + 0.1;
 709         self.health = self.health + self.count;
 710         if (self.health >= self.max_health)
 711         {
 712                 self.health = self.max_health;
 713                 self.count = self.count * 0.2; // slow repair rate from now on
 714                 self.think = onslaught_controlpoint_icon_think;
 715                 sound(self, CHAN_TRIGGER, "sound/onslaught/controlpoint_built.wav", VOL_BASE, ATTN_NORM);
 716                 bprint(ColoredTeamName(self.team), " captured ", self.owner.message, " control point\n");
 717                 self.owner.iscaptured = TRUE;
 718                 onslaught_updatelinks();
 719
 720                 // Use targets now (somebody make sure this is in the right place..)
 721                 oself = self;
 722                 self = self.owner;
 723                 activator = self;
 724                 SUB_UseTargets ();
 725                 self = oself;
 726         }
 727         self.alpha = self.health / self.max_health;
 728         // colormod flash when shot
 729         self.colormod = '1 1 1' * (2 - bound(0, (self.pain_finished - time) / 10, 1));
 730 };
 731
 732 void onslaught_controlpoint_touch()
 733 {
 734         local entity e;
 735         float a;
 736         if (other.classname != "player")
 737                 return;
 738         a = onslaught_controlpoint_attackable(self, other.team);
 739         if(a != 2 && a != 4)
 740                 return;
 741         // we've verified that this player has a legitimate claim to this point,
 742         // so start building the captured point icon (which only captures this
 743         // point if it successfully builds without being destroyed first)
 744         self.goalentity = e = spawn();
 745         e.owner = self;
 746         e.max_health = cvar("g_onslaught_cp_health");
 747         e.health = e.max_health * 0.1;
 748         e.alpha = e.health / e.max_health;
 749         e.solid = SOLID_BBOX;
 750         e.movetype = MOVETYPE_NONE;
 751         setmodel(e, "models/onslaught/controlpoint_icon.md3");
 752         setsize(e, '-32 -32 -32', '32 32 32');
 753         setorigin(e, self.origin + '0 0 96');
 754         e.takedamage = DAMAGE_AIM;
 755         e.bot_attack = TRUE;
 756         e.event_damage = onslaught_controlpoint_icon_damage;
 757         e.team = other.team;
 758         e.colormap = 1024 + (e.team - 1) * 17;
 759         e.think = onslaught_controlpoint_icon_buildthink;
 760         e.nextthink = time + 0.1;
 761         e.count = e.max_health / 50; // how long it takes to build
 762         sound(e, CHAN_TRIGGER, "sound/onslaught/controlpoint_build.wav", VOL_BASE, ATTN_NORM);
 763         self.team = e.team;
 764         self.colormap = e.colormap;
 765 };
 766
 767 /*QUAKED spawnfunc_onslaught_controlpoint (0 .5 .8) (-32 -32 0) (32 32 128)
 768 Control point.  Be sure to give this enough clearance so that the shootable part has room to exist
 769
 770 This should link to an spawnfunc_onslaught_controlpoint entity or spawnfunc_onslaught_generator entity.
 771
 772 keys:
 773 "targetname" - name that spawnfunc_onslaught_link entities will use to target this.
 774 "target" - target any entities that are tied to this control point, such as vehicles and buildable structure entities.
 775 "message" - name of this control point (should reflect the location in the map, such as "center bridge", "north tower", etc)
 776 */
 777 void spawnfunc_onslaught_controlpoint()
 778 {
 779         local entity e;
 780         if (!g_onslaught)
 781         {
 782                 remove(self);
 783                 return;
 784         }
 785         precache_model("models/onslaught/controlpoint_pad.md3");
 786         precache_model("models/onslaught/controlpoint_shield.md3");
 787         precache_model("models/onslaught/controlpoint_icon.md3");
 788         precache_sound("sound/onslaught/controlpoint_build.wav");
 789         precache_sound("sound/onslaught/controlpoint_built.wav");
 790         precache_sound("sound/weapons/grenade_impact.wav");
 791         precache_sound("sound/onslaught/damageblockedbyshield.wav");
 792         precache_sound("sound/onslaught/controlpoint_underattack.wav");
 793         self.solid = SOLID_BSP;
 794         self.movetype = MOVETYPE_NONE;
 795         setmodel(self, "models/onslaught/controlpoint_pad.md3");
 796         //setsize(self, '-32 -32 0', '32 32 8');
 797         setorigin(self, self.origin);
 798         self.touch = onslaught_controlpoint_touch;
 799         self.team = 0;
 800         self.colormap = 1024;
 801         self.iscaptured = FALSE;
 802         self.islinked = FALSE;
 803         self.isshielded = TRUE;
 804         // spawn shield model which indicates whether this can be damaged
 805         self.enemy = e = spawn();
 806         e.solid = SOLID_NOT;
 807         e.movetype = MOVETYPE_NONE;
 808         e.effects = EF_ADDITIVE;
 809         setmodel(e, "models/onslaught/controlpoint_shield.md3");
 810         //setsize(e, '-32 -32 0', '32 32 128');
 811         setorigin(e, self.origin);
 812         e.colormap = self.colormap;
 813
 814         waypoint_spawnforitem(self);
 815
 816         WaypointSprite_SpawnFixed(string_null, e.origin + '0 0 1' * e.maxs_z, self, sprite);
 817         WaypointSprite_UpdateRule(self.sprite, COLOR_TEAM2, SPRITERULE_TEAMPLAY);
 818
 819         onslaught_updatelinks();
 820 };
 821
 822 void onslaught_controlpoint_reset()
 823 {
 824         if(self.goalentity && self.goalentity != world)
 825                 remove(self.goalentity);
 826         self.goalentity = world;
 827         self.team = 0;
 828         self.colormap = 1024;
 829         self.iscaptured = FALSE;
 830         self.islinked = FALSE;
 831         self.isshielded = TRUE;
 832         self.enemy.solid = SOLID_NOT;
 833         self.enemy.colormap = self.colormap;
 834         self.think = self.enemy.think = SUB_Null;
 835         self.nextthink = 0; // don't like SUB_Null :P
 836
 837         onslaught_updatelinks();
 838
 839         activator = self;
 840         SUB_UseTargets(); // to reset the structures, playerspawns etc.
 841 }
 842
 843 float onslaught_link_send(entity to, float sendflags)
 844 {
 845         WriteByte(MSG_ENTITY, ENT_CLIENT_RADARLINK);
 846         WriteByte(MSG_ENTITY, sendflags);
 847         if(sendflags & 1)
 848         {
 849                 WriteCoord(MSG_ENTITY, self.goalentity.origin_x);
 850                 WriteCoord(MSG_ENTITY, self.goalentity.origin_y);
 851                 WriteCoord(MSG_ENTITY, self.goalentity.origin_z);
 852         }
 853         if(sendflags & 2)
 854         {
 855                 WriteCoord(MSG_ENTITY, self.enemy.origin_x);
 856                 WriteCoord(MSG_ENTITY, self.enemy.origin_y);
 857                 WriteCoord(MSG_ENTITY, self.enemy.origin_z);
 858         }
 859         if(sendflags & 4)
 860         {
 861                 WriteByte(MSG_ENTITY, self.clientcolors); // which is goalentity's color + enemy's color * 16
 862         }
 863         return TRUE;
 864 }
 865
 866 void onslaught_link_checkupdate()
 867 {
 868         // TODO check if the two sides have moved (currently they won't move anyway)
 869         float redpower, bluepower;
 870
 871         redpower = bluepower = 0;
 872         if(self.goalentity.islinked)
 873         {
 874                 if(self.goalentity.team == COLOR_TEAM1)
 875                         redpower = 1;
 876                 else if(self.goalentity.team == COLOR_TEAM2)
 877                         bluepower = 1;
 878         }
 879         if(self.enemy.islinked)
 880         {
 881                 if(self.enemy.team == COLOR_TEAM1)
 882                         redpower = 2;
 883                 else if(self.enemy.team == COLOR_TEAM2)
 884                         bluepower = 2;
 885         }
 886
 887         float cc;
 888         if(redpower == 1 && bluepower == 2)
 889                 cc = (COLOR_TEAM1 - 1) * 0x01 + (COLOR_TEAM2 - 1) * 0x10;
 890         else if(redpower == 2 && bluepower == 1)
 891                 cc = (COLOR_TEAM1 - 1) * 0x10 + (COLOR_TEAM2 - 1) * 0x01;
 892         else if(redpower)
 893                 cc = (COLOR_TEAM1 - 1) * 0x11;
 894         else if(bluepower)
 895                 cc = (COLOR_TEAM2 - 1) * 0x11;
 896         else
 897                 cc = 0;
 898
 899         if(cc != self.clientcolors)
 900         {
 901                 self.clientcolors = cc;
 902                 self.SendFlags |= 4;
 903         }
 904
 905         self.nextthink = time;
 906 }
 907
 908 void onslaught_link_delayed()
 909 {
 910         self.goalentity = find(world, targetname, self.target);
 911         self.enemy = find(world, targetname, self.target2);
 912         if (!self.goalentity)
 913                 objerror("can not find target\n");
 914         if (!self.enemy)
 915                 objerror("can not find target2\n");
 916         dprint(etos(self.goalentity), " linked with ", etos(self.enemy), "\n");
 917
 918         self.SendFlags |= 3;
 919         self.think = onslaught_link_checkupdate;
 920         self.nextthink = time;
 921 }
 922
 923 /*QUAKED spawnfunc_onslaught_link (0 .5 .8) (-16 -16 -16) (16 16 16)
 924 Link between control points.
 925
 926 This entity targets two different spawnfunc_onslaught_controlpoint or spawnfunc_onslaught_generator entities, and suppresses shielding on both if they are owned by different teams.
 927
 928 keys:
 929 "target" - first control point.
 930 "target2" - second control point.
 931 */
 932 void spawnfunc_onslaught_link()
 933 {
 934         if (!g_onslaught)
 935         {
 936                 remove(self);
 937                 return;
 938         }
 939         if (self.target == "" || self.target2 == "")
 940                 objerror("target and target2 must be set\n");
 941         self.think = onslaught_link_delayed;
 942         self.nextthink = time + 0.1;
 943         self.SendEntity = onslaught_link_send;
 944         Net_LinkEntity(self);
 945 };