data/qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   7 void() spawnpoint_use;
   8 string ColoredTeamName(float t);
   9
  10 float RandomSelection_totalweight;
  11 float RandomSelection_best_priority;
  12 entity RandomSelection_chosen_ent;
  13 float RandomSelection_chosen_float;
  14 void RandomSelection_Init()
  15 {
  16         RandomSelection_totalweight = 0;
  17         RandomSelection_chosen_ent = world;
  18         RandomSelection_chosen_float = 0;
  19         RandomSelection_best_priority = -1;
  20 }
  21 void RandomSelection_Add(entity e, float f, float weight, float priority)
  22 {
  23         if(priority > RandomSelection_best_priority)
  24         {
  25                 RandomSelection_best_priority = priority;
  26                 RandomSelection_chosen_ent = e;
  27                 RandomSelection_chosen_float = f;
  28                 RandomSelection_totalweight = weight;
  29         }
  30         else if(priority == RandomSelection_best_priority)
  31         {
  32                 RandomSelection_totalweight += weight;
  33                 if(random() * RandomSelection_totalweight <= weight)
  34                 {
  35                         RandomSelection_chosen_ent = e;
  36                         RandomSelection_chosen_float = f;
  37                 }
  38         }
  39 }
  40
  41 float DistributeEvenly_amount;
  42 float DistributeEvenly_totalweight;
  43 void DistributeEvenly_Init(float amount, float totalweight)
  44 {
  45         if(DistributeEvenly_amount)
  46         {
  47                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  48                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  49         }
  50         if(totalweight == 0)
  51                 DistributeEvenly_amount = 0;
  52         else
  53                 DistributeEvenly_amount = amount;
  54         DistributeEvenly_totalweight = totalweight;
  55 }
  56 float DistributeEvenly_Get(float weight)
  57 {
  58         float f;
  59         if(weight <= 0)
  60                 return 0;
  61         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  62         DistributeEvenly_totalweight -= weight;
  63         DistributeEvenly_amount -= f;
  64         return f;
  65 }
  66
  67 void move_out_of_solid_expand(entity e, vector by)
  68 {
  69         float eps = 0.0625;
  70         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  71         if(trace_startsolid)
  72                 return;
  73         if(trace_fraction < 1)
  74         {
  75                 // hit something
  76                 // adjust origin in the other direction...
  77                 e.origin = e.origin - by * (1 - trace_fraction);
  78         }
  79 }
  80
  81 float move_out_of_solid(entity e)
  82 {
  83         vector o, m0, m1;
  84
  85         o = e.origin;
  86         traceline(o, o, MOVE_WORLDONLY, e);
  87         if(trace_startsolid)
  88                 return 0;
  89
  90         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  91         if(!trace_startsolid)
  92                 return 1;
  93
  94         m0 = e.mins;
  95         m1 = e.maxs;
  96         e.mins = '0 0 0';
  97         e.maxs = '0 0 0';
  98         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  99         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
 100         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
 101         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
 102         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
 103         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
 104         setorigin(e, e.origin);
 105
 106         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 107         if(trace_startsolid)
 108         {
 109                 setorigin(e, o);
 110                 return 0;
 111         }
 112
 113         return 1;
 114 }
 115
 116 string STR_PLAYER = "player";
 117 string STR_SPECTATOR = "spectator";
 118 string STR_OBSERVER = "observer";
 119
 120 #if 0
 121 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
 122 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 123 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
 124 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
 125 #else
 126 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
 127 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
 128 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 129 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
 130 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 131 #endif
 132
 133 // copies a string to a tempstring (so one can strunzone it)
 134 string strcat1(string s) = #115; // FRIK_FILE
 135
 136 float logfile_open;
 137 float logfile;
 138
 139 void bcenterprint(string s)
 140 {
 141         // TODO replace by MSG_ALL (would show it to spectators too, though)?
 142         entity head;
 143         FOR_EACH_PLAYER(head)
 144                 if(clienttype(head) == CLIENTTYPE_REAL)
 145                         centerprint(head, s);
 146 }
 147
 148 void GameLogEcho(string s)
 149 {
 150         string fn;
 151         float matches;
 152
 153         if(cvar("sv_eventlog_files"))
 154         {
 155                 if(!logfile_open)
 156                 {
 157                         logfile_open = TRUE;
 158                         matches = cvar("sv_eventlog_files_counter") + 1;
 159                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 160                         fn = ftos(matches);
 161                         if(strlen(fn) < 8)
 162                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 163                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 164                         logfile = fopen(fn, FILE_APPEND);
 165                         fputs(logfile, ":logversion:2\n");
 166                 }
 167                 if(logfile >= 0)
 168                 {
 169                         if(cvar("sv_eventlog_files_timestamps"))
 170                                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 171                         else
 172                                 fputs(logfile, strcat(s, "\n"));
 173                 }
 174         }
 175         if(cvar("sv_eventlog_console"))
 176         {
 177                 print(s, "\n");
 178         }
 179 }
 180
 181 void GameLogInit()
 182 {
 183         logfile_open = 0;
 184         // will be opened later
 185 }
 186
 187 void GameLogClose()
 188 {
 189         if(logfile_open && logfile >= 0)
 190         {
 191                 fclose(logfile);
 192                 logfile = -1;
 193         }
 194 }
 195
 196 float spawnpoint_nag;
 197 void relocate_spawnpoint()
 198 {
 199         // nudge off the floor
 200         setorigin(self, self.origin + '0 0 1');
 201
 202         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 203         if (trace_startsolid)
 204         {
 205                 vector o;
 206                 o = self.origin;
 207                 self.mins = PL_MIN;
 208                 self.maxs = PL_MAX;
 209                 if(!move_out_of_solid(self))
 210                         objerror("could not get out of solid at all!");
 211                 print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 212                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 213                 print(" ", ftos(self.origin_y - o_y));
 214                 print(" ", ftos(self.origin_z - o_z), "'\n");
 215                 if(cvar("g_spawnpoints_auto_move_out_of_solid"))
 216                 {
 217                         if(!spawnpoint_nag)
 218                                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 219                         spawnpoint_nag = 1;
 220                 }
 221                 else
 222                 {
 223                         self.origin = o;
 224                         self.mins = self.maxs = '0 0 0';
 225                         objerror("player spawn point in solid, mapper sucks!\n");
 226                         return;
 227                 }
 228         }
 229
 230         if(cvar("g_spawnpoints_autodrop"))
 231         {
 232                 setsize(self, PL_MIN, PL_MAX);
 233                 droptofloor();
 234         }
 235
 236         self.use = spawnpoint_use;
 237         self.team_saved = self.team;
 238         if(!self.cnt)
 239                 self.cnt = 1;
 240
 241         if(g_ctf || g_assault || g_onslaught || g_domination)
 242         if(self.team)
 243                 have_team_spawns = 1;
 244
 245         if(cvar("r_showbboxes"))
 246         {
 247                 // show where spawnpoints point at too
 248                 makevectors(self.angles);
 249                 entity e;
 250                 e = spawn();
 251                 e.classname = "info_player_foo";
 252                 setorigin(e, self.origin + v_forward * 24);
 253                 setsize(e, '-8 -8 -8', '8 8 8');
 254                 e.solid = SOLID_TRIGGER;
 255         }
 256 }
 257
 258 #define strstr strstrofs
 259 /*
 260 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 261 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 262 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 263 // BE CONSTANT OR strzoneD!
 264 float strstr(string haystack, string needle, float offset)
 265 {
 266         float len, endpos;
 267         string found;
 268         len = strlen(needle);
 269         endpos = strlen(haystack) - len;
 270         while(offset <= endpos)
 271         {
 272                 found = substring(haystack, offset, len);
 273                 if(found == needle)
 274                         return offset;
 275                 offset = offset + 1;
 276         }
 277         return -1;
 278 }
 279 */
 280
 281 float NUM_NEAREST_ENTITIES = 4;
 282 entity nearest_entity[NUM_NEAREST_ENTITIES];
 283 float nearest_length[NUM_NEAREST_ENTITIES];
 284 entity findnearest(vector point, .string field, string value, vector axismod)
 285 {
 286         entity localhead;
 287         float i;
 288         float j;
 289         float len;
 290         vector dist;
 291
 292         float num_nearest;
 293         num_nearest = 0;
 294
 295         localhead = find(world, field, value);
 296         while(localhead)
 297         {
 298                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 299                         dist = localhead.oldorigin;
 300                 else
 301                         dist = localhead.origin;
 302                 dist = dist - point;
 303                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 304                 len = vlen(dist);
 305
 306                 for(i = 0; i < num_nearest; ++i)
 307                 {
 308                         if(len < nearest_length[i])
 309                                 break;
 310                 }
 311
 312                 // now i tells us where to insert at
 313                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 314                 if(i < NUM_NEAREST_ENTITIES)
 315                 {
 316                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 317                         {
 318                                 nearest_length[j + 1] = nearest_length[j];
 319                                 nearest_entity[j + 1] = nearest_entity[j];
 320                         }
 321                         nearest_length[i] = len;
 322                         nearest_entity[i] = localhead;
 323                         if(num_nearest < NUM_NEAREST_ENTITIES)
 324                                 num_nearest = num_nearest + 1;
 325                 }
 326
 327                 localhead = find(localhead, field, value);
 328         }
 329
 330         // now use the first one from our list that we can see
 331         for(i = 0; i < num_nearest; ++i)
 332         {
 333                 traceline(point, nearest_entity[i].origin, TRUE, world);
 334                 if(trace_fraction == 1)
 335                 {
 336                         if(i != 0)
 337                         {
 338                                 dprint("Nearest point (");
 339                                 dprint(nearest_entity[0].netname);
 340                                 dprint(") is not visible, using a visible one.\n");
 341                         }
 342                         return nearest_entity[i];
 343                 }
 344         }
 345
 346         if(num_nearest == 0)
 347                 return world;
 348
 349         dprint("Not seeing any location point, using nearest as fallback.\n");
 350         /* DEBUGGING CODE:
 351         dprint("Candidates were: ");
 352         for(j = 0; j < num_nearest; ++j)
 353         {
 354                 if(j != 0)
 355                         dprint(", ");
 356                 dprint(nearest_entity[j].netname);
 357         }
 358         dprint("\n");
 359         */
 360
 361         return nearest_entity[0];
 362 }
 363
 364 void spawnfunc_target_location()
 365 {
 366         self.classname = "target_location";
 367         // location name in netname
 368         // eventually support: count, teamgame selectors, line of sight?
 369 };
 370
 371 void spawnfunc_info_location()
 372 {
 373         self.classname = "target_location";
 374         self.message = self.netname;
 375 };
 376
 377 string NearestLocation(vector p)
 378 {
 379         entity loc;
 380         string ret;
 381         ret = "somewhere";
 382         loc = findnearest(p, classname, "target_location", '1 1 1');
 383         if(loc)
 384         {
 385                 ret = loc.message;
 386         }
 387         else
 388         {
 389                 loc = findnearest(p, target, "###item###", '1 1 4');
 390                 if(loc)
 391                         ret = loc.netname;
 392         }
 393         return ret;
 394 }
 395
 396 string formatmessage(string msg)
 397 {
 398         float p;
 399         float n;
 400         string msg_save;
 401         string escape;
 402         string replacement;
 403         msg_save = strzone(msg);
 404         p = 0;
 405         n = 7;
 406         while(1)
 407         {
 408                 if(n < 1)
 409                         break; // too many replacements
 410                 n = n - 1;
 411                 p = strstr(msg_save, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 if(p < 0)
 413                         break;
 414                 replacement = substring(msg_save, p, 2);
 415                 escape = substring(msg_save, p + 1, 1);
 416                 if(escape == "%")
 417                         replacement = "%";
 418                 else if(escape == "a")
 419                         replacement = ftos(floor(self.armorvalue));
 420                 else if(escape == "h")
 421                         replacement = ftos(floor(self.health));
 422                 else if(escape == "l")
 423                         replacement = NearestLocation(self.origin);
 424                 else if(escape == "y")
 425                         replacement = NearestLocation(self.cursor_trace_endpos);
 426                 else if(escape == "d")
 427                         replacement = NearestLocation(self.death_origin);
 428                 else if(escape == "w")
 429                 {
 430                         float wep;
 431                         wep = self.weapon;
 432                         if(!wep)
 433                                 wep = self.switchweapon;
 434                         if(!wep)
 435                                 wep = self.cnt;
 436                         replacement = W_Name(wep);
 437                 }
 438                 else if(escape == "W")
 439                 {
 440                         if(self.items & IT_SHELLS) replacement = "shells";
 441                         else if(self.items & IT_NAILS) replacement = "bullets";
 442                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 443                         else if(self.items & IT_CELLS) replacement = "cells";
 444                         else replacement = "batteries"; // ;)
 445                 }
 446                 else if(escape == "x")
 447                 {
 448                         replacement = self.cursor_trace_ent.netname;
 449                         if(!replacement || !self.cursor_trace_ent)
 450                                 replacement = "nothing";
 451                 }
 452                 else if(escape == "p")
 453                 {
 454                         if(self.last_selected_player)
 455                                 replacement = self.last_selected_player.netname;
 456                         else
 457                                 replacement = "(nobody)";
 458                 }
 459                 msg = strcat(substring(msg_save, 0, p), replacement);
 460                 msg = strcat(msg, substring(msg_save, p+2, strlen(msg_save) - (p+2)));
 461                 strunzone(msg_save);
 462                 msg_save = strzone(msg);
 463                 p = p + 2;
 464         }
 465         msg = strcat(msg_save, "");
 466         strunzone(msg_save);
 467         return msg;
 468 }
 469
 470 /*
 471 =============
 472 GetCvars
 473 =============
 474 Called with:
 475   0:  sends the request
 476   >0: receives a cvar from name=argv(f) value=argv(f+1)
 477 */
 478 void GetCvars_handleString(string thisname, float f, .string field, string name)
 479 {
 480         if(f < 0)
 481         {
 482                 if(self.field)
 483                         strunzone(self.field);
 484                 self.field = string_null;
 485         }
 486         else if(f > 0)
 487         {
 488                 if(thisname == name)
 489                 {
 490                         if(self.field)
 491                                 strunzone(self.field);
 492                         self.field = strzone(argv(f + 1));
 493                 }
 494         }
 495         else
 496                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 497 }
 498 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 499 {
 500         GetCvars_handleString(thisname, f, field, name);
 501         if(f >= 0) // also initialize to the fitting value for "" when sending cvars out
 502         if(thisname == name)
 503         {
 504                 string s;
 505                 s = func(strcat1(self.field));
 506                 if(s != self.field)
 507                 {
 508                         strunzone(self.field);
 509                         self.field = strzone(s);
 510                 }
 511         }
 512 }
 513 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 514 {
 515         if(f < 0)
 516         {
 517         }
 518         else if(f > 0)
 519         {
 520                 if(thisname == name)
 521                         self.field = stof(argv(f + 1));
 522         }
 523         else
 524                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 525 }
 526 string W_FixWeaponOrder_ForceComplete(string s);
 527 string W_FixWeaponOrder_AllowIncomplete(string s);
 528 float w_getbestweapon(entity e);
 529 void GetCvars(float f)
 530 {
 531         string s;
 532         if(f > 0)
 533                 s = strcat1(argv(f));
 534         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 535         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 536         GetCvars_handleFloat(s, f, cvar_cl_nogibs, "cl_nogibs");
 537         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 538         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 539         GetCvars_handleString(s, f, cvar_g_nexuizversion, "g_nexuizversion");
 540         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 541         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 542         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 543         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 552
 553         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 554         if(f > 0)
 555         {
 556                 if(s == "cl_weaponpriority")
 557                         self.switchweapon = w_getbestweapon(self);
 558         }
 559 }
 560
 561 float fexists(string f)
 562 {
 563         float fh;
 564         fh = fopen(f, FILE_READ);
 565         if(fh < 0)
 566                 return FALSE;
 567         fclose(fh);
 568         return TRUE;
 569 }
 570
 571 void backtrace(string msg)
 572 {
 573         float dev;
 574         dev = cvar("developer");
 575         cvar_set("developer", "1");
 576         dprint("\n");
 577         dprint("--- CUT HERE ---\nWARNING: ");
 578         dprint(msg);
 579         dprint("\n");
 580         remove(world); // isn't there any better way to cause a backtrace?
 581         dprint("\n--- CUT UNTIL HERE ---\n");
 582         cvar_set("developer", ftos(dev));
 583 }
 584
 585 string Team_ColorCode(float teamid)
 586 {
 587         if(teamid == COLOR_TEAM1)
 588                 return "^1";
 589         else if(teamid == COLOR_TEAM2)
 590                 return "^4";
 591         else if(teamid == COLOR_TEAM3)
 592                 return "^3";
 593         else if(teamid == COLOR_TEAM4)
 594                 return "^6";
 595         else
 596                 return "^7";
 597 }
 598 string Team_ColorName(float t)
 599 {
 600         // fixme: Search for team entities and get their .netname's!
 601         if(t == COLOR_TEAM1)
 602                 return "Red";
 603         if(t == COLOR_TEAM2)
 604                 return "Blue";
 605         if(t == COLOR_TEAM3)
 606                 return "Yellow";
 607         if(t == COLOR_TEAM4)
 608                 return "Pink";
 609         return "Neutral";
 610 }
 611 string Team_ColorNameLowerCase(float t)
 612 {
 613         // fixme: Search for team entities and get their .netname's!
 614         if(t == COLOR_TEAM1)
 615                 return "red";
 616         if(t == COLOR_TEAM2)
 617                 return "blue";
 618         if(t == COLOR_TEAM3)
 619                 return "yellow";
 620         if(t == COLOR_TEAM4)
 621                 return "pink";
 622         return "neutral";
 623 }
 624
 625 #define CENTERPRIO_POINT 1
 626 #define CENTERPRIO_SPAM 2
 627 #define CENTERPRIO_REBALANCE 2
 628 #define CENTERPRIO_VOTE 4
 629 #define CENTERPRIO_NORMAL 5
 630 #define CENTERPRIO_SHIELDING 7
 631 #define CENTERPRIO_MAPVOTE 9
 632 #define CENTERPRIO_IDLEKICK 50
 633 #define CENTERPRIO_ADMIN 99
 634 .float centerprint_priority;
 635 .float centerprint_expires;
 636 void centerprint_atprio(entity e, float prio, string s)
 637 {
 638         if(intermission_running)
 639                 if(prio < CENTERPRIO_MAPVOTE)
 640                         return;
 641         if(time > e.centerprint_expires)
 642                 e.centerprint_priority = 0;
 643         if(prio >= e.centerprint_priority)
 644         {
 645                 e.centerprint_priority = prio;
 646                 if(timeoutStatus == 2)
 647                         e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 648                 else
 649                         e.centerprint_expires = time + e.cvar_scr_centertime;
 650                 centerprint_builtin(e, s);
 651         }
 652 }
 653 void centerprint_expire(entity e, float prio)
 654 {
 655         if(prio == e.centerprint_priority)
 656         {
 657                 e.centerprint_priority = 0;
 658                 centerprint_builtin(e, "");
 659         }
 660 }
 661 void centerprint(entity e, string s)
 662 {
 663         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 664 }
 665
 666 // decolorizes and team colors the player name when needed
 667 string playername(entity p)
 668 {
 669         string t;
 670         if(teams_matter && !intermission_running && p.classname == "player")
 671         {
 672                 t = Team_ColorCode(p.team);
 673                 return strcat(t, strdecolorize(p.netname));
 674         }
 675         else
 676                 return p.netname;
 677 }
 678
 679 vector randompos(vector m1, vector m2)
 680 {
 681         local vector v;
 682         m2 = m2 - m1;
 683         v_x = m2_x * random() + m1_x;
 684         v_y = m2_y * random() + m1_y;
 685         v_z = m2_z * random() + m1_z;
 686         return  v;
 687 };
 688
 689 // requires that m2>m1 in all coordinates, and that m4>m3
 690 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;};
 691
 692 // requires the same, but is a stronger condition
 693 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;};
 694
 695 float g_pickup_shells;
 696 float g_pickup_shells_max;
 697 float g_pickup_nails;
 698 float g_pickup_nails_max;
 699 float g_pickup_rockets;
 700 float g_pickup_rockets_max;
 701 float g_pickup_cells;
 702 float g_pickup_cells_max;
 703 float g_pickup_armorsmall;
 704 float g_pickup_armorsmall_max;
 705 float g_pickup_armormedium;
 706 float g_pickup_armormedium_max;
 707 float g_pickup_armorlarge;
 708 float g_pickup_armorlarge_max;
 709 float g_pickup_healthsmall;
 710 float g_pickup_healthsmall_max;
 711 float g_pickup_healthmedium;
 712 float g_pickup_healthmedium_max;
 713 float g_pickup_healthlarge;
 714 float g_pickup_healthlarge_max;
 715 float g_pickup_healthmega;
 716 float g_pickup_healthmega_max;
 717 float g_weaponarena;
 718 string g_weaponarena_list;
 719
 720 float start_weapons;
 721 float start_items;
 722 float start_ammo_shells;
 723 float start_ammo_nails;
 724 float start_ammo_rockets;
 725 float start_ammo_cells;
 726 float start_health;
 727 float start_armorvalue;
 728 float warmup_start_weapons;
 729 float warmup_start_ammo_shells;
 730 float warmup_start_ammo_nails;
 731 float warmup_start_ammo_rockets;
 732 float warmup_start_ammo_cells;
 733 float warmup_start_health;
 734 float warmup_start_armorvalue;
 735
 736 entity get_weaponinfo(float w);
 737
 738 void readplayerstartcvars()
 739 {
 740         entity e;
 741         float i, j, t;
 742         string s;
 743
 744         // initialize starting values for players
 745         start_weapons = 0;
 746         start_items = 0;
 747         start_ammo_shells = 0;
 748         start_ammo_nails = 0;
 749         start_ammo_rockets = 0;
 750         start_ammo_cells = 0;
 751         start_health = cvar("g_balance_health_start");
 752         start_armorvalue = cvar("g_balance_armor_start");
 753
 754         g_weaponarena = 0;
 755         s = cvar_string("g_weaponarena");
 756         if(s == "0")
 757         {
 758         }
 759         else if(s == "all")
 760         {
 761                 g_weaponarena_list = "All Weapons";
 762                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 763                 {
 764                         e = get_weaponinfo(j);
 765                         g_weaponarena |= e.weapons;
 766                         weapon_action(e.weapon, WR_PRECACHE);
 767                 }
 768         }
 769         else if(s == "most")
 770         {
 771                 g_weaponarena_list = "Most Weapons";
 772                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 773                 {
 774                         e = get_weaponinfo(j);
 775                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 776                         {
 777                                 g_weaponarena |= e.weapons;
 778                                 weapon_action(e.weapon, WR_PRECACHE);
 779                         }
 780                 }
 781         }
 782         else
 783         {
 784                 t = tokenize_sane(s);
 785                 g_weaponarena_list = "";
 786                 for(i = 0; i < t; ++i)
 787                 {
 788                         s = argv(i);
 789                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 790                         {
 791                                 e = get_weaponinfo(j);
 792                                 if(e.netname == s)
 793                                 {
 794                                         g_weaponarena |= e.weapons;
 795                                         weapon_action(e.weapon, WR_PRECACHE);
 796                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 797                                         break;
 798                                 }
 799                         }
 800                         if(j > WEP_LAST)
 801                         {
 802                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 803                         }
 804                 }
 805                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 806         }
 807
 808         if(g_weaponarena)
 809         {
 810                 start_weapons = g_weaponarena;
 811                 start_ammo_rockets = 999;
 812                 start_ammo_shells = 999;
 813                 start_ammo_cells = 999;
 814                 start_ammo_nails = 999;
 815                 start_items |= IT_UNLIMITED_AMMO;
 816         }
 817         else if(g_nixnex)
 818         {
 819                 start_weapons = 0;
 820                 // will be done later
 821                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 822                 {
 823                         e = get_weaponinfo(i);
 824                         if(!(e.weapon))
 825                                 continue;
 826                         weapon_action(e.weapon, WR_PRECACHE);
 827                 }
 828         }
 829         else if(g_minstagib)
 830         {
 831                 start_health = 100;
 832                 start_armorvalue = 0;
 833                 start_weapons = WEPBIT_MINSTANEX;
 834                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 835                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 836                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 837         }
 838         else
 839         {
 840                 if(g_lms)
 841                 {
 842                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 843                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 844                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 845                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 846                         start_health = cvar("g_lms_start_health");
 847                         start_armorvalue = cvar("g_lms_start_armor");
 848                 } else if (cvar("g_use_ammunition")) {
 849                         start_ammo_shells = cvar("g_start_ammo_shells");
 850                         start_ammo_nails = cvar("g_start_ammo_nails");
 851                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 852                         start_ammo_cells = cvar("g_start_ammo_cells");
 853                 } else {
 854                         start_ammo_shells = cvar("g_pickup_shells_max");
 855                         start_ammo_nails = cvar("g_pickup_nails_max");
 856                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 857                         start_ammo_cells = cvar("g_pickup_cells_max");
 858                         start_items |= IT_UNLIMITED_AMMO;
 859                 }
 860
 861                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 862                 {
 863                         e = get_weaponinfo(i);
 864                         if(!(e.weapon))
 865                                 continue;
 866                         if(((e.spawnflags & WEPSPAWNFLAG_NORMAL) && g_lms) || cvar(strcat("g_start_weapon_", e.netname)))
 867                         {
 868                                 start_weapons |= e.weapons;
 869                                 weapon_action(e.weapon, WR_PRECACHE);
 870                         }
 871                 }
 872         }
 873
 874         if(inWarmupStage)
 875         {
 876                 warmup_start_ammo_shells = start_ammo_shells;
 877                 warmup_start_ammo_nails = start_ammo_nails;
 878                 warmup_start_ammo_rockets = start_ammo_rockets;
 879                 warmup_start_ammo_cells = start_ammo_cells;
 880                 warmup_start_health = start_health;
 881                 warmup_start_armorvalue = start_armorvalue;
 882                 warmup_start_weapons = start_weapons;
 883
 884                 if(!g_weaponarena && !g_nixnex && !g_minstagib)
 885                 {
 886                         if(cvar("g_use_ammunition"))
 887                         {
 888                                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 889                                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 890                                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 891                                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 892                         }
 893                         warmup_start_health = cvar("g_warmup_start_health");
 894                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 895                         if(cvar("g_warmup_allguns"))
 896                         {
 897                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 898                                 {
 899                                         e = get_weaponinfo(i);
 900                                         if(!(e.weapon))
 901                                                 continue;
 902                                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 903                                         {
 904                                                 warmup_start_weapons |= e.weapons;
 905                                                 weapon_action(e.weapon, WR_PRECACHE);
 906                                         }
 907                                 }
 908                         }
 909                 }
 910         }
 911
 912         if(g_grappling_hook) // offhand hook
 913         {
 914                 start_weapons (-) WEPBIT_HOOK;
 915                 warmup_start_weapons (-) WEPBIT_HOOK;
 916         }
 917 }
 918
 919 void readlevelcvars(void)
 920 {
 921         sv_clones = cvar("sv_clones");
 922         sv_cheats = cvar("sv_cheats");
 923         sv_gentle = cvar("sv_gentle");
 924         sv_foginterval = cvar("sv_foginterval");
 925         g_cloaked = cvar("g_cloaked");
 926         g_jump_grunt = cvar("g_jump_grunt");
 927         g_footsteps = cvar("g_footsteps");
 928         g_grappling_hook = cvar("g_grappling_hook");
 929         g_laserguided_missile = cvar("g_laserguided_missile");
 930         g_midair = cvar("g_midair");
 931         g_minstagib = cvar("g_minstagib");
 932         g_nixnex = cvar("g_nixnex");
 933         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
 934         g_norecoil = cvar("g_norecoil");
 935         g_vampire = cvar("g_vampire");
 936         sv_maxidle = cvar("sv_maxidle");
 937         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 938         sv_pogostick = cvar("sv_pogostick");
 939         sv_doublejump = cvar("sv_doublejump");
 940         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 941         g_ctf_reverse = cvar("g_ctf_reverse");
 942
 943         inWarmupStage = cvar("g_warmup");
 944         g_warmup_limit = cvar("g_warmup_limit");
 945         g_warmup_allguns = cvar("g_warmup_allguns");
 946         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 947
 948         if(g_race && g_race_qualifying == 2 || g_arena || g_assault || cvar("g_campaign"))
 949                 inWarmupStage = 0; // these modes cannot work together, sorry
 950
 951         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 952         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 953         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 954         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 955
 956         if(g_minstagib) g_nixnex = g_weaponarena = 0;
 957         if(g_nixnex) g_weaponarena = 0;
 958         g_weaponarena = 0;
 959
 960         g_pickup_shells                    = cvar("g_pickup_shells");
 961         g_pickup_shells_max                = cvar("g_pickup_shells_max");
 962         g_pickup_nails                     = cvar("g_pickup_nails");
 963         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
 964         g_pickup_rockets                   = cvar("g_pickup_rockets");
 965         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
 966         g_pickup_cells                     = cvar("g_pickup_cells");
 967         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
 968         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
 969         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
 970         g_pickup_armormedium               = cvar("g_pickup_armormedium");
 971         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
 972         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
 973         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
 974         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
 975         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
 976         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
 977         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
 978         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
 979         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
 980         g_pickup_healthmega                = cvar("g_pickup_healthmega");
 981         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
 982
 983         if not(inWarmupStage)
 984         {
 985                 game_starttime                 = cvar("g_start_delay");
 986                 if(game_starttime)
 987                 {
 988                         restartAnnouncer = spawn();
 989                         restartAnnouncer.think = restartAnnouncer_Think;
 990                         restartAnnouncer.nextthink = time + 0.1;
 991                         restartAnnouncer.spawnflags = 0;
 992                 }
 993         }
 994
 995         readplayerstartcvars();
 996 }
 997
 998 /*
 999 // TODO sound pack system
1000 string soundpack;
1001
1002 string precache_sound_builtin (string s) = #19;
1003 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1004 string precache_sound(string s)
1005 {
1006         return precache_sound_builtin(strcat(soundpack, s));
1007 }
1008 void play2(entity e, string filename)
1009 {
1010         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1011 }
1012 void sound(entity e, float chan, string samp, float vol, float atten)
1013 {
1014         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1015 }
1016 */
1017
1018 // Sound functions
1019 string precache_sound (string s) = #19;
1020 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
1021 float precache_sound_index (string s) = #19;
1022
1023 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1024 {
1025         WriteByte(dest, 6);
1026         WriteByte(dest, 27); // all bits except SND_LOOPING
1027         WriteByte(dest, vol * 255);
1028         WriteByte(dest, atten * 64);
1029         WriteEntity(dest, e);
1030         WriteByte(dest, chan);
1031         WriteShort(dest, precache_sound_index(samp));
1032         WriteCoord(dest, o_x);
1033         WriteCoord(dest, o_y);
1034         WriteCoord(dest, o_z);
1035 }
1036 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1037 {
1038         vector o;
1039         o = e.origin + 0.5 * (e.mins + e.maxs);
1040         soundtoat(dest, e, o, chan, samp, vol, atten);
1041 }
1042 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1043 {
1044         soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1045 }
1046
1047 void play2(entity e, string filename)
1048 {
1049         //stuffcmd(e, strcat("play2 ", filename, "\n"));
1050         msg_entity = e;
1051         soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1052 }
1053
1054 .float announcetime;
1055 float announce(entity player, string msg)
1056 {
1057         if(time > player.announcetime)
1058         if(clienttype(player) == CLIENTTYPE_REAL)
1059         {
1060                 player.announcetime = time + 0.3;
1061                 play2(player, msg);
1062                 return TRUE;
1063         }
1064         return FALSE;
1065 }
1066
1067 void play2team(float t, string filename)
1068 {
1069         local entity head;
1070         FOR_EACH_REALPLAYER(head)
1071         {
1072                 if (head.team == t)
1073                         play2(head, filename);
1074         }
1075 }
1076
1077 void play2all(string samp)
1078 {
1079         sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1080 }
1081
1082 void PrecachePlayerSounds(string f);
1083 void precache_all_models(string pattern)
1084 {
1085         float globhandle, i, n;
1086         string f;
1087
1088         globhandle = search_begin(pattern, TRUE, FALSE);
1089         if(globhandle < 0)
1090                 return;
1091         n = search_getsize(globhandle);
1092         for(i = 0; i < n; ++i)
1093         {
1094                 //print(search_getfilename(globhandle, i), "\n");
1095                 f = search_getfilename(globhandle, i);
1096                 precache_model(f);
1097                 PrecachePlayerSounds(strcat(f, ".sounds"));
1098         }
1099         search_end(globhandle);
1100 }
1101
1102 void precache()
1103 {
1104         // gamemode related things
1105         precache_model ("models/misc/chatbubble.spr");
1106         precache_model ("models/misc/teambubble.spr");
1107         if (g_runematch)
1108         {
1109                 precache_model ("models/runematch/curse.mdl");
1110                 precache_model ("models/runematch/rune.mdl");
1111         }
1112
1113 #ifdef TTURRETS_ENABLED
1114     if(cvar("g_turrets"))
1115         turrets_precash();
1116 #endif
1117
1118         // Precache all player models if desired
1119         if (cvar("sv_precacheplayermodels"))
1120         {
1121                 PrecachePlayerSounds("sound/player/default.sounds");
1122                 precache_all_models("models/player/*.zym");
1123                 precache_all_models("models/player/*.dpm");
1124                 precache_all_models("models/player/*.md3");
1125                 precache_all_models("models/player/*.psk");
1126                 //precache_model("models/player/carni.zym");
1127                 //precache_model("models/player/crash.zym");
1128                 //precache_model("models/player/grunt.zym");
1129                 //precache_model("models/player/headhunter.zym");
1130                 //precache_model("models/player/insurrectionist.zym");
1131                 //precache_model("models/player/jeandarc.zym");
1132                 //precache_model("models/player/lurk.zym");
1133                 //precache_model("models/player/lycanthrope.zym");
1134                 //precache_model("models/player/marine.zym");
1135                 //precache_model("models/player/nexus.zym");
1136                 //precache_model("models/player/pyria.zym");
1137                 //precache_model("models/player/shock.zym");
1138                 //precache_model("models/player/skadi.zym");
1139                 //precache_model("models/player/specop.zym");
1140                 //precache_model("models/player/visitant.zym");
1141         }
1142
1143         if (g_footsteps)
1144         {
1145                 PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1146                 PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1147         }
1148
1149         // gore and miscellaneous sounds
1150         //precache_sound ("misc/h2ohit.wav");
1151         precache_model ("models/gibs/bloodyskull.md3");
1152         precache_model ("models/gibs/chunk.mdl");
1153         precache_model ("models/gibs/eye.md3");
1154         precache_model ("models/gibs/gib1.md3");
1155         precache_model ("models/gibs/gib2.md3");
1156         precache_model ("models/gibs/gib3.md3");
1157         precache_model ("models/gibs/gib4.md3");
1158         precache_model ("models/gibs/gib5.md3");
1159         precache_model ("models/gibs/gib6.md3");
1160         precache_model ("models/gibs/smallchest.md3");
1161         precache_model ("models/gibs/chest.md3");
1162         precache_model ("models/gibs/arm.md3");
1163         precache_model ("models/gibs/leg1.md3");
1164         precache_model ("models/gibs/leg2.md3");
1165         precache_model ("models/hook.md3");
1166         precache_sound ("misc/armorimpact.wav");
1167         precache_sound ("misc/bodyimpact1.wav");
1168         precache_sound ("misc/bodyimpact2.wav");
1169         precache_sound ("misc/gib.wav");
1170         precache_sound ("misc/gib_splat01.wav");
1171         precache_sound ("misc/gib_splat02.wav");
1172         precache_sound ("misc/gib_splat03.wav");
1173         precache_sound ("misc/gib_splat04.wav");
1174         precache_sound ("misc/hit.wav");
1175         PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1176         PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1177         precache_sound ("misc/null.wav");
1178         precache_sound ("misc/spawn.wav");
1179         precache_sound ("misc/talk.wav");
1180         precache_sound ("misc/teleport.wav");
1181         precache_sound ("player/lava.wav");
1182         precache_sound ("player/slime.wav");
1183
1184         // announcer sounds - male
1185         precache_sound ("announcer/male/electrobitch.wav");
1186         precache_sound ("announcer/male/airshot.wav");
1187         precache_sound ("announcer/male/03kills.wav");
1188         precache_sound ("announcer/male/05kills.wav");
1189         precache_sound ("announcer/male/10kills.wav");
1190         precache_sound ("announcer/male/15kills.wav");
1191         precache_sound ("announcer/male/20kills.wav");
1192         precache_sound ("announcer/male/25kills.wav");
1193         precache_sound ("announcer/male/30kills.wav");
1194         precache_sound ("announcer/male/botlike.wav");
1195         precache_sound ("announcer/male/yoda.wav");
1196         precache_sound ("announcer/male/headshot.wav");
1197         precache_sound ("announcer/male/impressive.wav");
1198
1199         // announcer sounds - robotic
1200         precache_sound ("announcer/robotic/prepareforbattle.wav");
1201         precache_sound ("announcer/robotic/begin.wav");
1202         precache_sound ("announcer/robotic/timeoutcalled.wav");
1203         precache_sound ("announcer/robotic/1fragleft.wav");
1204         precache_sound ("announcer/robotic/1minuteremains.wav");
1205         precache_sound ("announcer/robotic/2fragsleft.wav");
1206         precache_sound ("announcer/robotic/3fragsleft.wav");
1207         if (g_minstagib)
1208         {
1209                 precache_sound ("announcer/robotic/lastsecond.wav");
1210                 precache_sound ("announcer/robotic/narrowly.wav");
1211         }
1212
1213         precache_model ("models/sprites/1.spr32");
1214         precache_model ("models/sprites/2.spr32");
1215         precache_model ("models/sprites/3.spr32");
1216         precache_model ("models/sprites/4.spr32");
1217         precache_model ("models/sprites/5.spr32");
1218         precache_model ("models/sprites/6.spr32");
1219         precache_model ("models/sprites/7.spr32");
1220         precache_model ("models/sprites/8.spr32");
1221         precache_model ("models/sprites/9.spr32");
1222         precache_model ("models/sprites/10.spr32");
1223         precache_sound ("announcer/robotic/1.wav");
1224         precache_sound ("announcer/robotic/2.wav");
1225         precache_sound ("announcer/robotic/3.wav");
1226         precache_sound ("announcer/robotic/4.wav");
1227         precache_sound ("announcer/robotic/5.wav");
1228         precache_sound ("announcer/robotic/6.wav");
1229         precache_sound ("announcer/robotic/7.wav");
1230         precache_sound ("announcer/robotic/8.wav");
1231         precache_sound ("announcer/robotic/9.wav");
1232         precache_sound ("announcer/robotic/10.wav");
1233
1234         // common weapon precaches
1235         precache_sound ("weapons/weapon_switch.wav");
1236         precache_sound ("weapons/weaponpickup.wav");
1237         if (cvar("g_grappling_hook"))
1238         {
1239                 precache_sound ("weapons/hook_fire.wav"); // hook
1240                 precache_sound ("weapons/hook_impact.wav"); // hook
1241         }
1242
1243         if (cvar("sv_precacheweapons") || g_nixnex)
1244         {
1245                 //precache weapon models/sounds
1246                 local float wep;
1247                 wep = WEP_FIRST;
1248                 while (wep <= WEP_LAST)
1249                 {
1250                         weapon_action(wep, WR_PRECACHE);
1251                         wep = wep + 1;
1252                 }
1253         }
1254
1255         if (!self.noise && self.music) // quake 3 uses the music field
1256                 self.noise = self.music;
1257
1258         // plays music for the level if there is any
1259         if (self.noise)
1260         {
1261                 precache_sound (self.noise);
1262                 ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1263         }
1264 }
1265
1266 // sorry, but using \ in macros breaks line numbers
1267 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1268 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1269 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1270
1271 vector ExactTriggerHit_mins;
1272 vector ExactTriggerHit_maxs;
1273 float ExactTriggerHit_Recurse()
1274 {
1275         float s;
1276         entity se;
1277         float f;
1278
1279         tracebox('0 0 0', ExactTriggerHit_mins, ExactTriggerHit_maxs, '0 0 0', MOVE_NORMAL, other);
1280         if not(trace_ent)
1281                 return 0;
1282         if(trace_ent == self)
1283                 return 1;
1284
1285         se = trace_ent;
1286         s = se.solid;
1287         se.solid = SOLID_NOT;
1288         f = ExactTriggerHit_Recurse();
1289         se.solid = s;
1290
1291         return f;
1292 }
1293
1294 float ExactTriggerHit()
1295 {
1296         float f, s;
1297
1298         if not(self.modelindex)
1299                 return 1;
1300
1301         s = self.solid;
1302         self.solid = SOLID_BSP;
1303         ExactTriggerHit_mins = other.absmin;
1304         ExactTriggerHit_maxs = other.absmax;
1305         f = ExactTriggerHit_Recurse();
1306         self.solid = s;
1307
1308         return f;
1309 }
1310
1311 // WARNING: this kills the trace globals
1312 #define EXACTTRIGGER_TOUCH if not(ExactTriggerHit()) return
1313 #define EXACTTRIGGER_INIT  InitSolidBSPTrigger(); self.solid = SOLID_TRIGGER
1314
1315 #define INITPRIO_FIRST              0
1316 #define INITPRIO_GAMETYPE           0
1317 #define INITPRIO_GAMETYPE_FALLBACK  1
1318 #define INITPRIO_CVARS              5
1319 #define INITPRIO_FINDTARGET        10
1320 #define INITPRIO_DROPTOFLOOR       20
1321 #define INITPRIO_SETLOCATION       90
1322 #define INITPRIO_LINKDOORS         91
1323 #define INITPRIO_LAST              99
1324
1325 .void(void) initialize_entity;
1326 .float initialize_entity_order;
1327 .entity initialize_entity_next;
1328 entity initialize_entity_first;
1329
1330 void make_safe_for_remove(entity e)
1331 {
1332         if(e.initialize_entity)
1333         {
1334                 entity ent, prev;
1335                 for(ent = initialize_entity_first; ent; )
1336                 {
1337                         if((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1338                         {
1339                                 print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1340                                 // skip it in linked list
1341                                 if(prev)
1342                                 {
1343                                         prev.initialize_entity_next = ent.initialize_entity_next;
1344                                         ent = prev.initialize_entity_next;
1345                                 }
1346                                 else
1347                                 {
1348                                         initialize_entity_first = ent.initialize_entity_next;
1349                                         ent = initialize_entity_first;
1350                                 }
1351                         }
1352                         else
1353                         {
1354                                 prev = ent;
1355                                 ent = ent.initialize_entity_next;
1356                         }
1357                 }
1358         }
1359 }
1360
1361 void objerror(string s)
1362 {
1363         make_safe_for_remove(self);
1364         objerror_builtin(s);
1365 }
1366
1367 void remove_unsafely(entity e)
1368 {
1369         remove_builtin(e);
1370 }
1371
1372 void remove_safely(entity e)
1373 {
1374         make_safe_for_remove(e);
1375         remove_builtin(e);
1376 }
1377
1378 void InitializeEntity(entity e, void(void) func, float order)
1379 {
1380         entity prev, cur;
1381
1382         if(!e || e.initialize_entity)
1383         {
1384                 // make a proxy initializer entity
1385                 entity e_old;
1386                 e_old = e;
1387                 e = spawn();
1388                 e.classname = "initialize_entity";
1389                 e.enemy = e_old;
1390         }
1391
1392         e.initialize_entity = func;
1393         e.initialize_entity_order = order;
1394
1395         cur = initialize_entity_first;
1396         for(;;)
1397         {
1398                 if(!cur || cur.initialize_entity_order > order)
1399                 {
1400                         // insert between prev and cur
1401                         if(prev)
1402                                 prev.initialize_entity_next = e;
1403                         else
1404                                 initialize_entity_first = e;
1405                         e.initialize_entity_next = cur;
1406                         return;
1407                 }
1408                 prev = cur;
1409                 cur = cur.initialize_entity_next;
1410         }
1411 }
1412 void InitializeEntitiesRun()
1413 {
1414         entity startoflist;
1415         startoflist = initialize_entity_first;
1416         initialize_entity_first = world;
1417         for(self = startoflist; self; )
1418         {
1419                 entity e;
1420                 var void(void) func;
1421                 e = self.initialize_entity_next;
1422                 func = self.initialize_entity;
1423                 self.initialize_entity_order = 0;
1424                 self.initialize_entity = func_null;
1425                 self.initialize_entity_next = world;
1426                 if(self.classname == "initialize_entity")
1427                 {
1428                         entity e_old;
1429                         e_old = self.enemy;
1430                         remove_builtin(self);
1431                         self = e_old;
1432                 }
1433                 dprint("Delayed initialization: ", self.classname, "\n");
1434                 func();
1435                 self = e;
1436         }
1437 }
1438
1439 .float uncustomizeentityforclient_set;
1440 .void(void) uncustomizeentityforclient;
1441 void(void) SUB_Nullpointer = #0;
1442 void UncustomizeEntitiesRun()
1443 {
1444         entity oldself;
1445         oldself = self;
1446         for(self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1447                 self.uncustomizeentityforclient();
1448         self = oldself;
1449 }
1450 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1451 {
1452         e.customizeentityforclient = customizer;
1453         e.uncustomizeentityforclient = uncustomizer;
1454         e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1455 }
1456
1457 .float nottargeted;
1458 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1459
1460 void Net_LinkEntity(entity e)
1461 {
1462         e.model = "net_entity";
1463         e.modelindex = 1;
1464         e.effects = EF_NODEPTHTEST | EF_LOWPRECISION;
1465 }
1466
1467 void adaptor_think2touch()
1468 {
1469         entity o;
1470         o = other;
1471         other = world;
1472         self.touch();
1473         other = o;
1474 }
1475
1476 void adaptor_think2use()
1477 {
1478         entity o, a;
1479         o = other;
1480         a = activator;
1481         activator = world;
1482         other = world;
1483         self.use();
1484         other = o;
1485         activator = a;
1486 }
1487
1488 // deferred dropping
1489 void DropToFloor_Handler()
1490 {
1491         droptofloor_builtin();
1492         self.dropped_origin = self.origin;
1493 }
1494
1495 void droptofloor()
1496 {
1497         InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1498 }
1499
1500
1501
1502 float trace_hits_box_a0, trace_hits_box_a1;
1503
1504 float trace_hits_box_1d(float end, float thmi, float thma)
1505 {
1506         if(end == 0)
1507         {
1508                 // just check if x is in range
1509                 if(0 < thmi)
1510                         return FALSE;
1511                 if(0 > thma)
1512                         return FALSE;
1513         }
1514         else
1515         {
1516                 // do the trace with respect to x
1517                 // 0 -> end has to stay in thmi -> thma
1518                 trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1519                 trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1520                 if(trace_hits_box_a0 > trace_hits_box_a1)
1521                         return FALSE;
1522         }
1523         return TRUE;
1524 }
1525
1526 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1527 {
1528         end -= start;
1529         thmi -= start;
1530         thma -= start;
1531         // now it is a trace from 0 to end
1532
1533         trace_hits_box_a0 = 0;
1534         trace_hits_box_a1 = 1;
1535
1536         if(!trace_hits_box_1d(end_x, thmi_x, thma_x))
1537                 return FALSE;
1538         if(!trace_hits_box_1d(end_y, thmi_y, thma_y))
1539                 return FALSE;
1540         if(!trace_hits_box_1d(end_z, thmi_z, thma_z))
1541                 return FALSE;
1542
1543         return TRUE;
1544 }
1545
1546 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1547 {
1548         return trace_hits_box(start, end, thmi - ma, thma - mi);
1549 }
1550
1551 float SUB_NoImpactCheck()
1552 {
1553         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1554                 return 1;
1555         if(other == world && self.size != '0 0 0')
1556         {
1557                 vector tic;
1558                 tic = self.velocity * sys_ticrate;
1559                 tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1560                 traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1561                 if(trace_fraction >= 1)
1562                 {
1563                         dprint("Odd... did not hit...?\n");
1564                 }
1565                 else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1566                 {
1567                         dprint("Detected and prevented the sky-grapple bug.\n");
1568                         return 1;
1569                 }
1570         }
1571
1572         return 0;
1573 }
1574
1575 #define SUB_OwnerCheck() (other && (other == self.owner))
1576
1577 #define PROJECTILE_TOUCH do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { remove(self); return; } } while(0)
1578 const string STR_MISC_NULL_WAV = "misc/null.wav";
1579 #define PROJECTILE_TOUCH_NOSOUND do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { sound (self, CHAN_PROJECTILE, STR_MISC_NULL_WAV, VOL_BASE, ATTN_NORM); remove(self); return; } } while(0)