data/qcsrc/server/miscfunctions.qc

   1 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   2 void() spawnpoint_use;
   3 string ColoredTeamName(float t);
   4
   5 float RandomSelection_totalweight;
   6 float RandomSelection_best_priority;
   7 entity RandomSelection_chosen_ent;
   8 float RandomSelection_chosen_float;
   9 void RandomSelection_Init()
  10 {
  11         RandomSelection_totalweight = 0;
  12         RandomSelection_chosen_ent = world;
  13         RandomSelection_chosen_float = 0;
  14         RandomSelection_best_priority = -1;
  15 }
  16 void RandomSelection_Add(entity e, float f, float weight, float priority)
  17 {
  18         if(priority > RandomSelection_best_priority)
  19         {
  20                 RandomSelection_best_priority = priority;
  21                 RandomSelection_chosen_ent = e;
  22                 RandomSelection_chosen_float = f;
  23                 RandomSelection_totalweight = weight;
  24         }
  25         else if(priority == RandomSelection_best_priority)
  26         {
  27                 RandomSelection_totalweight += weight;
  28                 if(random() * RandomSelection_totalweight <= weight)
  29                 {
  30                         RandomSelection_chosen_ent = e;
  31                         RandomSelection_chosen_float = f;
  32                 }
  33         }
  34 }
  35
  36 float DistributeEvenly_amount;
  37 float DistributeEvenly_totalweight;
  38 void DistributeEvenly_Init(float amount, float totalweight)
  39 {
  40         if(DistributeEvenly_amount)
  41         {
  42                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  43                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  44         }
  45         if(totalweight == 0)
  46                 DistributeEvenly_amount = 0;
  47         else
  48                 DistributeEvenly_amount = amount;
  49         DistributeEvenly_totalweight = totalweight;
  50 }
  51 float DistributeEvenly_Get(float weight)
  52 {
  53         float f;
  54         if(weight <= 0)
  55                 return 0;
  56         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  57         DistributeEvenly_totalweight -= weight;
  58         DistributeEvenly_amount -= f;
  59         return f;
  60 }
  61
  62 void move_out_of_solid_expand(entity e, vector by)
  63 {
  64         float eps = 0.0625;
  65         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  66         if(trace_startsolid)
  67                 return;
  68         if(trace_fraction < 1)
  69         {
  70                 // hit something
  71                 // adjust origin in the other direction...
  72                 e.origin = e.origin - by * (1 - trace_fraction);
  73         }
  74 }
  75
  76 float move_out_of_solid(entity e)
  77 {
  78         vector o, m0, m1;
  79
  80         o = e.origin;
  81         traceline(o, o, MOVE_WORLDONLY, e);
  82         if(trace_startsolid)
  83                 return 0;
  84
  85         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  86         if(!trace_startsolid)
  87                 return 1;
  88
  89         m0 = e.mins;
  90         m1 = e.maxs;
  91         e.mins = '0 0 0';
  92         e.maxs = '0 0 0';
  93         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  94         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
  95         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
  96         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
  97         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
  98         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
  99         setorigin(e, e.origin);
 100
 101         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 102         if(trace_startsolid)
 103         {
 104                 setorigin(e, o);
 105                 return 0;
 106         }
 107
 108         return 1;
 109 }
 110
 111 string STR_PLAYER = "player";
 112 string STR_SPECTATOR = "spectator";
 113 string STR_OBSERVER = "observer";
 114
 115 #if 0
 116 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
 117 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 118 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
 119 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
 120 #else
 121 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
 122 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
 123 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 124 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
 125 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 126 #endif
 127
 128 // copies a string to a tempstring (so one can strunzone it)
 129 string strcat1(string s) = #115; // FRIK_FILE
 130
 131 float logfile_open;
 132 float logfile;
 133
 134 void bcenterprint(string s)
 135 {
 136         // TODO replace by MSG_ALL (would show it to spectators too, though)?
 137         entity head;
 138         FOR_EACH_PLAYER(head)
 139                 if(clienttype(head) == CLIENTTYPE_REAL)
 140                         centerprint(head, s);
 141 }
 142
 143 void GameLogEcho(string s)
 144 {
 145         string fn;
 146         float matches;
 147
 148         if(cvar("sv_eventlog_files"))
 149         {
 150                 if(!logfile_open)
 151                 {
 152                         logfile_open = TRUE;
 153                         matches = cvar("sv_eventlog_files_counter") + 1;
 154                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 155                         fn = ftos(matches);
 156                         if(strlen(fn) < 8)
 157                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 158                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 159                         logfile = fopen(fn, FILE_APPEND);
 160                         fputs(logfile, ":logversion:2\n");
 161                 }
 162                 if(logfile >= 0)
 163                 {
 164                         if(cvar("sv_eventlog_files_timestamps"))
 165                                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 166                         else
 167                                 fputs(logfile, strcat(s, "\n"));
 168                 }
 169         }
 170         if(cvar("sv_eventlog_console"))
 171         {
 172                 print(s, "\n");
 173         }
 174 }
 175
 176 void GameLogInit()
 177 {
 178         logfile_open = 0;
 179         // will be opened later
 180 }
 181
 182 void GameLogClose()
 183 {
 184         if(logfile_open && logfile >= 0)
 185         {
 186                 fclose(logfile);
 187                 logfile = -1;
 188         }
 189 }
 190
 191 float spawnpoint_nag;
 192 void relocate_spawnpoint()
 193 {
 194         // nudge off the floor
 195         setorigin(self, self.origin + '0 0 1');
 196
 197         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 198         if (trace_startsolid)
 199         {
 200                 vector o;
 201                 o = self.origin;
 202                 self.mins = PL_MIN;
 203                 self.maxs = PL_MAX;
 204                 if(!move_out_of_solid(self))
 205                         objerror("could not get out of solid at all!");
 206                 print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 207                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 208                 print(" ", ftos(self.origin_y - o_y));
 209                 print(" ", ftos(self.origin_z - o_z), "'\n");
 210                 if(cvar("g_spawnpoints_auto_move_out_of_solid"))
 211                 {
 212                         if(!spawnpoint_nag)
 213                                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 214                         spawnpoint_nag = 1;
 215                 }
 216                 else
 217                 {
 218                         self.origin = o;
 219                         self.mins = self.maxs = '0 0 0';
 220                         objerror("player spawn point in solid, mapper sucks!\n");
 221                         return;
 222                 }
 223         }
 224
 225         if(cvar("g_spawnpoints_autodrop"))
 226         {
 227                 setsize(self, PL_MIN, PL_MAX);
 228                 droptofloor();
 229         }
 230
 231         self.use = spawnpoint_use;
 232         self.team_saved = self.team;
 233         if(!self.cnt)
 234                 self.cnt = 1;
 235
 236         if(g_ctf || g_assault || g_onslaught || g_domination)
 237         if(self.team)
 238                 have_team_spawns = 1;
 239
 240         if(cvar("r_showbboxes"))
 241         {
 242                 // show where spawnpoints point at too
 243                 makevectors(self.angles);
 244                 entity e;
 245                 e = spawn();
 246                 e.classname = "info_player_foo";
 247                 setorigin(e, self.origin + v_forward * 24);
 248                 setsize(e, '-8 -8 -8', '8 8 8');
 249                 e.solid = SOLID_TRIGGER;
 250         }
 251 }
 252
 253 #define strstr strstrofs
 254 /*
 255 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 256 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 257 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 258 // BE CONSTANT OR strzoneD!
 259 float strstr(string haystack, string needle, float offset)
 260 {
 261         float len, endpos;
 262         string found;
 263         len = strlen(needle);
 264         endpos = strlen(haystack) - len;
 265         while(offset <= endpos)
 266         {
 267                 found = substring(haystack, offset, len);
 268                 if(found == needle)
 269                         return offset;
 270                 offset = offset + 1;
 271         }
 272         return -1;
 273 }
 274 */
 275
 276 float NUM_NEAREST_ENTITIES = 4;
 277 entity nearest_entity[NUM_NEAREST_ENTITIES];
 278 float nearest_length[NUM_NEAREST_ENTITIES];
 279 entity findnearest(vector point, .string field, string value, vector axismod)
 280 {
 281         entity localhead;
 282         float i;
 283         float j;
 284         float len;
 285         vector dist;
 286
 287         float num_nearest;
 288         num_nearest = 0;
 289
 290         localhead = find(world, field, value);
 291         while(localhead)
 292         {
 293                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 294                         dist = localhead.oldorigin;
 295                 else
 296                         dist = localhead.origin;
 297                 dist = dist - point;
 298                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 299                 len = vlen(dist);
 300
 301                 for(i = 0; i < num_nearest; ++i)
 302                 {
 303                         if(len < nearest_length[i])
 304                                 break;
 305                 }
 306
 307                 // now i tells us where to insert at
 308                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 309                 if(i < NUM_NEAREST_ENTITIES)
 310                 {
 311                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 312                         {
 313                                 nearest_length[j + 1] = nearest_length[j];
 314                                 nearest_entity[j + 1] = nearest_entity[j];
 315                         }
 316                         nearest_length[i] = len;
 317                         nearest_entity[i] = localhead;
 318                         if(num_nearest < NUM_NEAREST_ENTITIES)
 319                                 num_nearest = num_nearest + 1;
 320                 }
 321
 322                 localhead = find(localhead, field, value);
 323         }
 324
 325         // now use the first one from our list that we can see
 326         for(i = 0; i < num_nearest; ++i)
 327         {
 328                 traceline(point, nearest_entity[i].origin, TRUE, world);
 329                 if(trace_fraction == 1)
 330                 {
 331                         if(i != 0)
 332                         {
 333                                 dprint("Nearest point (");
 334                                 dprint(nearest_entity[0].netname);
 335                                 dprint(") is not visible, using a visible one.\n");
 336                         }
 337                         return nearest_entity[i];
 338                 }
 339         }
 340
 341         if(num_nearest == 0)
 342                 return world;
 343
 344         dprint("Not seeing any location point, using nearest as fallback.\n");
 345         /* DEBUGGING CODE:
 346         dprint("Candidates were: ");
 347         for(j = 0; j < num_nearest; ++j)
 348         {
 349                 if(j != 0)
 350                         dprint(", ");
 351                 dprint(nearest_entity[j].netname);
 352         }
 353         dprint("\n");
 354         */
 355
 356         return nearest_entity[0];
 357 }
 358
 359 void spawnfunc_target_location()
 360 {
 361         self.classname = "target_location";
 362         // location name in netname
 363         // eventually support: count, teamgame selectors, line of sight?
 364 };
 365
 366 void spawnfunc_info_location()
 367 {
 368         self.classname = "target_location";
 369         self.message = self.netname;
 370 };
 371
 372 string NearestLocation(vector p)
 373 {
 374         entity loc;
 375         string ret;
 376         ret = "somewhere";
 377         loc = findnearest(p, classname, "target_location", '1 1 1');
 378         if(loc)
 379         {
 380                 ret = loc.message;
 381         }
 382         else
 383         {
 384                 loc = findnearest(p, target, "###item###", '1 1 4');
 385                 if(loc)
 386                         ret = loc.netname;
 387         }
 388         return ret;
 389 }
 390
 391 string formatmessage(string msg)
 392 {
 393         float p;
 394         float n;
 395         string msg_save;
 396         string escape;
 397         string replacement;
 398         msg_save = strzone(msg);
 399         p = 0;
 400         n = 7;
 401         while(1)
 402         {
 403                 if(n < 1)
 404                         break; // too many replacements
 405                 n = n - 1;
 406                 p = strstr(msg_save, "%", p); // NOTE: this destroys msg as it's a tempstring!
 407                 if(p < 0)
 408                         break;
 409                 replacement = substring(msg_save, p, 2);
 410                 escape = substring(msg_save, p + 1, 1);
 411                 if(escape == "%")
 412                         replacement = "%";
 413                 else if(escape == "a")
 414                         replacement = ftos(floor(self.armorvalue));
 415                 else if(escape == "h")
 416                         replacement = ftos(floor(self.health));
 417                 else if(escape == "l")
 418                         replacement = NearestLocation(self.origin);
 419                 else if(escape == "y")
 420                         replacement = NearestLocation(self.cursor_trace_endpos);
 421                 else if(escape == "d")
 422                         replacement = NearestLocation(self.death_origin);
 423                 else if(escape == "w")
 424                 {
 425                         float wep;
 426                         wep = self.weapon;
 427                         if(!wep)
 428                                 wep = self.switchweapon;
 429                         if(!wep)
 430                                 wep = self.cnt;
 431                         replacement = W_Name(wep);
 432                 }
 433                 else if(escape == "W")
 434                 {
 435                         if(self.items & IT_SHELLS) replacement = "shells";
 436                         else if(self.items & IT_NAILS) replacement = "bullets";
 437                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 438                         else if(self.items & IT_CELLS) replacement = "cells";
 439                         else replacement = "batteries"; // ;)
 440                 }
 441                 else if(escape == "x")
 442                 {
 443                         replacement = self.cursor_trace_ent.netname;
 444                         if(!replacement || !self.cursor_trace_ent)
 445                                 replacement = "nothing";
 446                 }
 447                 else if(escape == "p")
 448                 {
 449                         if(self.last_selected_player)
 450                                 replacement = self.last_selected_player.netname;
 451                         else
 452                                 replacement = "(nobody)";
 453                 }
 454                 msg = strcat(substring(msg_save, 0, p), replacement);
 455                 msg = strcat(msg, substring(msg_save, p+2, strlen(msg_save) - (p+2)));
 456                 strunzone(msg_save);
 457                 msg_save = strzone(msg);
 458                 p = p + 2;
 459         }
 460         msg = strcat(msg_save, "");
 461         strunzone(msg_save);
 462         return msg;
 463 }
 464
 465 /*
 466 =============
 467 GetCvars
 468 =============
 469 Called with:
 470   0:  sends the request
 471   >0: receives a cvar from name=argv(f) value=argv(f+1)
 472 */
 473 void GetCvars_handleString(float f, .string field, string name)
 474 {
 475         if(f < 0)
 476         {
 477                 if(self.field)
 478                         strunzone(self.field);
 479         }
 480         else if(f > 0)
 481         {
 482                 if(argv(f) == name)
 483                 {
 484                         if(self.field)
 485                                 strunzone(self.field);
 486                         self.field = strzone(argv(f + 1));
 487                 }
 488         }
 489         else
 490                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 491 }
 492 void GetCvars_handleString_Fixup(float f, .string field, string name, string(string) func)
 493 {
 494         GetCvars_handleString(f, field, name);
 495         if(f >= 0) // also initialize to the fitting value for "" when sending cvars out
 496         if(argv(f) == name)
 497         {
 498                 string s;
 499                 s = func(strcat1(self.field));
 500                 if(s != self.field)
 501                 {
 502                         strunzone(self.field);
 503                         self.field = strzone(s);
 504                 }
 505         }
 506 }
 507 void GetCvars_handleFloat(float f, .float field, string name)
 508 {
 509         if(f < 0)
 510         {
 511         }
 512         else if(f > 0)
 513         {
 514                 if(argv(f) == name)
 515                         self.field = stof(argv(f + 1));
 516         }
 517         else
 518                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 519 }
 520 string W_FixWeaponOrder_ForceComplete(string s);
 521 string W_FixWeaponOrder_AllowIncomplete(string s);
 522 void GetCvars(float f)
 523 {
 524         GetCvars_handleFloat(f, autoswitch, "cl_autoswitch");
 525         GetCvars_handleFloat(f, cvar_cl_hidewaypoints, "cl_hidewaypoints");
 526         GetCvars_handleFloat(f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 527         GetCvars_handleFloat(f, cvar_cl_nogibs, "cl_nogibs");
 528         GetCvars_handleFloat(f, cvar_scr_centertime, "scr_centertime");
 529         GetCvars_handleFloat(f, cvar_cl_shownames, "cl_shownames");
 530         GetCvars_handleString(f, cvar_g_nexuizversion, "g_nexuizversion");
 531         GetCvars_handleFloat(f, cvar_cl_handicap, "cl_handicap");
 532         GetCvars_handleString_Fixup(f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 533         GetCvars_handleString_Fixup(f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 534         GetCvars_handleString_Fixup(f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 535         GetCvars_handleString_Fixup(f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 536         GetCvars_handleString_Fixup(f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 537         GetCvars_handleString_Fixup(f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 538         GetCvars_handleString_Fixup(f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 539         GetCvars_handleString_Fixup(f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 540         GetCvars_handleString_Fixup(f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 541         GetCvars_handleString_Fixup(f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 542         GetCvars_handleString_Fixup(f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 543 }
 544
 545 float fexists(string f)
 546 {
 547         float fh;
 548         fh = fopen(f, FILE_READ);
 549         if(fh < 0)
 550                 return FALSE;
 551         fclose(fh);
 552         return TRUE;
 553 }
 554
 555 void backtrace(string msg)
 556 {
 557         float dev;
 558         dev = cvar("developer");
 559         cvar_set("developer", "1");
 560         dprint("\n");
 561         dprint("--- CUT HERE ---\nWARNING: ");
 562         dprint(msg);
 563         dprint("\n");
 564         remove(world); // isn't there any better way to cause a backtrace?
 565         dprint("\n--- CUT UNTIL HERE ---\n");
 566         cvar_set("developer", ftos(dev));
 567 }
 568
 569 string Team_ColorCode(float teamid)
 570 {
 571         if(teamid == COLOR_TEAM1)
 572                 return "^1";
 573         else if(teamid == COLOR_TEAM2)
 574                 return "^4";
 575         else if(teamid == COLOR_TEAM3)
 576                 return "^3";
 577         else if(teamid == COLOR_TEAM4)
 578                 return "^6";
 579         else
 580                 return "^7";
 581 }
 582 string Team_ColorName(float t)
 583 {
 584         // fixme: Search for team entities and get their .netname's!
 585         if(t == COLOR_TEAM1)
 586                 return "Red";
 587         if(t == COLOR_TEAM2)
 588                 return "Blue";
 589         if(t == COLOR_TEAM3)
 590                 return "Yellow";
 591         if(t == COLOR_TEAM4)
 592                 return "Pink";
 593         return "Neutral";
 594 }
 595 string Team_ColorNameLowerCase(float t)
 596 {
 597         // fixme: Search for team entities and get their .netname's!
 598         if(t == COLOR_TEAM1)
 599                 return "red";
 600         if(t == COLOR_TEAM2)
 601                 return "blue";
 602         if(t == COLOR_TEAM3)
 603                 return "yellow";
 604         if(t == COLOR_TEAM4)
 605                 return "pink";
 606         return "neutral";
 607 }
 608
 609 #define CENTERPRIO_POINT 1
 610 #define CENTERPRIO_SPAM 2
 611 #define CENTERPRIO_REBALANCE 2
 612 #define CENTERPRIO_VOTE 4
 613 #define CENTERPRIO_NORMAL 5
 614 #define CENTERPRIO_MAPVOTE 9
 615 #define CENTERPRIO_IDLEKICK 50
 616 #define CENTERPRIO_ADMIN 99
 617 .float centerprint_priority;
 618 .float centerprint_expires;
 619 void centerprint_atprio(entity e, float prio, string s)
 620 {
 621         if(intermission_running)
 622                 if(prio < CENTERPRIO_MAPVOTE)
 623                         return;
 624         if(time > e.centerprint_expires)
 625                 e.centerprint_priority = 0;
 626         if(prio >= e.centerprint_priority)
 627         {
 628                 e.centerprint_priority = prio;
 629                 if(timeoutStatus == 2)
 630                         e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 631                 else
 632                         e.centerprint_expires = time + e.cvar_scr_centertime;
 633                 centerprint_builtin(e, s);
 634         }
 635 }
 636 void centerprint_expire(entity e, float prio)
 637 {
 638         if(prio == e.centerprint_priority)
 639         {
 640                 e.centerprint_priority = 0;
 641                 centerprint_builtin(e, "");
 642         }
 643 }
 644 void centerprint(entity e, string s)
 645 {
 646         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 647 }
 648
 649 void VoteNag();
 650
 651 // decolorizes and team colors the player name when needed
 652 string playername(entity p)
 653 {
 654         string t;
 655         if(teams_matter && !intermission_running && p.classname == "player")
 656         {
 657                 t = Team_ColorCode(p.team);
 658                 return strcat(t, strdecolorize(p.netname));
 659         }
 660         else
 661                 return p.netname;
 662 }
 663
 664 vector randompos(vector m1, vector m2)
 665 {
 666         local vector v;
 667         m2 = m2 - m1;
 668         v_x = m2_x * random() + m1_x;
 669         v_y = m2_y * random() + m1_y;
 670         v_z = m2_z * random() + m1_z;
 671         return  v;
 672 };
 673
 674 // requires that m2>m1 in all coordinates, and that m4>m3
 675 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;};
 676
 677 // requires the same, but is a stronger condition
 678 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;};
 679
 680 float g_pickup_shells;
 681 float g_pickup_shells_max;
 682 float g_pickup_nails;
 683 float g_pickup_nails_max;
 684 float g_pickup_rockets;
 685 float g_pickup_rockets_max;
 686 float g_pickup_cells;
 687 float g_pickup_cells_max;
 688 float g_pickup_armorsmall;
 689 float g_pickup_armorsmall_max;
 690 float g_pickup_armormedium;
 691 float g_pickup_armormedium_max;
 692 float g_pickup_armorlarge;
 693 float g_pickup_armorlarge_max;
 694 float g_pickup_healthsmall;
 695 float g_pickup_healthsmall_max;
 696 float g_pickup_healthmedium;
 697 float g_pickup_healthmedium_max;
 698 float g_pickup_healthlarge;
 699 float g_pickup_healthlarge_max;
 700 float g_pickup_healthmega;
 701 float g_pickup_healthmega_max;
 702
 703 float start_weapons;
 704 float start_switchweapon;
 705 float start_ammo_shells;
 706 float start_ammo_nails;
 707 float start_ammo_rockets;
 708 float start_ammo_cells;
 709 float start_health;
 710 float start_armorvalue;
 711
 712 entity get_weaponinfo(float w);
 713
 714 void readlevelcvars(void)
 715 {
 716         entity e;
 717         float i;
 718
 719         sv_cheats = cvar("sv_cheats");
 720         sv_gentle = cvar("sv_gentle");
 721         sv_foginterval = cvar("sv_foginterval");
 722         g_cloaked = cvar("g_cloaked");
 723         g_jump_grunt = cvar("g_jump_grunt");
 724         g_footsteps = cvar("g_footsteps");
 725         g_grappling_hook = cvar("g_grappling_hook");
 726         g_laserguided_missile = cvar("g_laserguided_missile");
 727         g_midair = cvar("g_midair");
 728         g_minstagib = cvar("g_minstagib");
 729         g_nixnex = cvar("g_nixnex");
 730         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
 731         g_norecoil = cvar("g_norecoil");
 732         g_rocketarena = cvar("g_rocketarena");
 733         g_vampire = cvar("g_vampire");
 734         g_tourney = cvar("g_tourney");
 735         sv_maxidle = cvar("sv_maxidle");
 736         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 737         sv_pogostick = cvar("sv_pogostick");
 738         sv_doublejump = cvar("sv_doublejump");
 739
 740         if(g_minstagib) g_nixnex = g_rocketarena = 0;
 741         if(g_nixnex) g_rocketarena = 0;
 742
 743         g_pickup_shells                    = cvar("g_pickup_shells");
 744         g_pickup_shells_max                = cvar("g_pickup_shells_max");
 745         g_pickup_nails                     = cvar("g_pickup_nails");
 746         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
 747         g_pickup_rockets                   = cvar("g_pickup_rockets");
 748         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
 749         g_pickup_cells                     = cvar("g_pickup_cells");
 750         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
 751         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
 752         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
 753         g_pickup_armormedium               = cvar("g_pickup_armormedium");
 754         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
 755         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
 756         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
 757         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
 758         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
 759         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
 760         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
 761         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
 762         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
 763         g_pickup_healthmega                = cvar("g_pickup_healthmega");
 764         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
 765
 766         // initialize starting values for players
 767         start_weapons = 0;
 768         start_switchweapon = 0;
 769         start_ammo_shells = 0;
 770         start_ammo_nails = 0;
 771         start_ammo_rockets = 0;
 772         start_ammo_cells = 0;
 773         start_health = cvar("g_balance_health_start");
 774         start_armorvalue = cvar("g_balance_armor_start");
 775
 776         if(g_rocketarena)
 777         {
 778                 start_weapons = WEPBIT_ROCKET_LAUNCHER;
 779                 start_switchweapon = WEP_ROCKET_LAUNCHER;
 780                 weapon_action(start_switchweapon, WR_PRECACHE);
 781                 start_ammo_rockets = 999;
 782         }
 783         else if(g_nixnex)
 784         {
 785                 start_weapons = 0;
 786                 // will be done later
 787         }
 788         else if(g_minstagib)
 789         {
 790                 start_health = 100;
 791                 start_armorvalue = 0;
 792                 start_weapons = WEPBIT_MINSTANEX;
 793                 start_switchweapon = WEP_MINSTANEX;
 794                 weapon_action(start_switchweapon, WR_PRECACHE);
 795                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 796                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 797         }
 798         else
 799         {
 800                 if(g_lms)
 801                 {
 802                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 803                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 804                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 805                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 806                         start_health = cvar("g_lms_start_health");
 807                         start_armorvalue = cvar("g_lms_start_armor");
 808                 }
 809                 else if(g_tourney) {
 810                         start_ammo_shells = cvar("g_tourney_start_ammo_shells");
 811                         start_ammo_nails = cvar("g_tourney_start_ammo_nails");
 812                         start_ammo_rockets = cvar("g_tourney_start_ammo_rockets");
 813                         start_ammo_cells = cvar("g_tourney_start_ammo_cells");
 814                         start_health = cvar("g_tourney_start_health");
 815                         start_armorvalue = cvar("g_tourney_start_armor");
 816                 }
 817                 else if (cvar("g_use_ammunition")) {
 818                         start_ammo_shells = cvar("g_start_ammo_shells");
 819                         start_ammo_nails = cvar("g_start_ammo_nails");
 820                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 821                         start_ammo_cells = cvar("g_start_ammo_cells");
 822                 } else {
 823                         start_ammo_shells = cvar("g_pickup_shells_max");
 824                         start_ammo_nails = cvar("g_pickup_nails_max");
 825                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 826                         start_ammo_cells = cvar("g_pickup_cells_max");
 827                 }
 828
 829                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 830                 {
 831                         e = get_weaponinfo(i);
 832                         if(!(e.weapon))
 833                                 continue;
 834                         if(((e.spawnflags & 1) && (g_lms || g_tourney)) || cvar(strcat("g_start_weapon_", e.netname)))
 835                         {
 836                                 start_weapons |= e.weapons;
 837                                 start_switchweapon = e.weapon;
 838                                 weapon_action(e.weapon, WR_PRECACHE);
 839                         }
 840                 }
 841         }
 842 }
 843
 844 /*
 845 // TODO sound pack system
 846 string soundpack;
 847
 848 string precache_sound_builtin (string s) = #19;
 849 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
 850 string precache_sound(string s)
 851 {
 852         return precache_sound_builtin(strcat(soundpack, s));
 853 }
 854 void play2(entity e, string filename)
 855 {
 856         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
 857 }
 858 void sound(entity e, float chan, string samp, float vol, float atten)
 859 {
 860         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
 861 }
 862 */
 863
 864 // Sound functions
 865 string precache_sound (string s) = #19;
 866 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
 867 float precache_sound_index (string s) = #19;
 868
 869 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
 870 {
 871         WriteByte(dest, 6);
 872         WriteByte(dest, 27); // all bits except SND_LOOPING
 873         WriteByte(dest, vol * 255);
 874         WriteByte(dest, atten * 64);
 875         WriteEntity(dest, e);
 876         WriteByte(dest, chan);
 877         WriteShort(dest, precache_sound_index(samp));
 878         WriteCoord(dest, o_x);
 879         WriteCoord(dest, o_y);
 880         WriteCoord(dest, o_z);
 881 }
 882 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
 883 {
 884         vector o;
 885         o = e.origin + 0.5 * (e.mins + e.maxs);
 886         soundtoat(dest, e, o, chan, samp, vol, atten);
 887 }
 888 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
 889 {
 890         soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
 891 }
 892
 893 void play2(entity e, string filename)
 894 {
 895         //stuffcmd(e, strcat("play2 ", filename, "\n"));
 896         msg_entity = e;
 897         soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
 898 }
 899
 900 .float announcetime;
 901 void announce(entity player, string msg)
 902 {
 903         if(time > player.announcetime)
 904         if(clienttype(player) == CLIENTTYPE_REAL)
 905         {
 906                 player.announcetime = time + 0.3;
 907                 play2(player, msg);
 908         }
 909 }
 910
 911 void play2team(float t, string filename)
 912 {
 913         local entity head;
 914         FOR_EACH_REALPLAYER(head)
 915         {
 916                 if (head.team == t)
 917                         play2(head, filename);
 918         }
 919 }
 920
 921 void play2all(string samp)
 922 {
 923         sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
 924 }
 925
 926 void PrecachePlayerSounds(string f);
 927 void precache_all_models(string pattern)
 928 {
 929         float globhandle, i, n;
 930         string f;
 931
 932         globhandle = search_begin(pattern, TRUE, FALSE);
 933         if(globhandle < 0)
 934                 return;
 935         n = search_getsize(globhandle);
 936         for(i = 0; i < n; ++i)
 937         {
 938                 //print(search_getfilename(globhandle, i), "\n");
 939                 f = search_getfilename(globhandle, i);
 940                 precache_model(f);
 941                 PrecachePlayerSounds(strcat(f, ".sounds"));
 942         }
 943         search_end(globhandle);
 944 }
 945
 946 void precache()
 947 {
 948         // gamemode related things
 949         precache_model ("models/misc/chatbubble.spr");
 950         precache_model ("models/misc/teambubble.spr");
 951         if (g_runematch)
 952         {
 953                 precache_model ("models/runematch/curse.mdl");
 954                 precache_model ("models/runematch/rune.mdl");
 955         }
 956
 957         // Precache all player models if desired
 958         if (cvar("sv_precacheplayermodels"))
 959         {
 960                 PrecachePlayerSounds("sound/player/default.sounds");
 961                 precache_all_models("models/player/*.zym");
 962                 precache_all_models("models/player/*.dpm");
 963                 precache_all_models("models/player/*.md3");
 964                 precache_all_models("models/player/*.psk");
 965                 //precache_model("models/player/carni.zym");
 966                 //precache_model("models/player/crash.zym");
 967                 //precache_model("models/player/grunt.zym");
 968                 //precache_model("models/player/headhunter.zym");
 969                 //precache_model("models/player/insurrectionist.zym");
 970                 //precache_model("models/player/jeandarc.zym");
 971                 //precache_model("models/player/lurk.zym");
 972                 //precache_model("models/player/lycanthrope.zym");
 973                 //precache_model("models/player/marine.zym");
 974                 //precache_model("models/player/nexus.zym");
 975                 //precache_model("models/player/pyria.zym");
 976                 //precache_model("models/player/shock.zym");
 977                 //precache_model("models/player/skadi.zym");
 978                 //precache_model("models/player/specop.zym");
 979                 //precache_model("models/player/visitant.zym");
 980         }
 981
 982         if (g_footsteps)
 983         {
 984                 PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
 985                 PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
 986         }
 987
 988         // gore and miscellaneous sounds
 989         //precache_sound ("misc/h2ohit.wav");
 990         precache_model ("models/gibs/bloodyskull.md3");
 991         precache_model ("models/gibs/chunk.mdl");
 992         precache_model ("models/gibs/eye.md3");
 993         precache_model ("models/gibs/gib1.md3");
 994         precache_model ("models/gibs/gib2.md3");
 995         precache_model ("models/gibs/gib3.md3");
 996         precache_model ("models/gibs/gib4.md3");
 997         precache_model ("models/gibs/gib5.md3");
 998         precache_model ("models/gibs/gib6.md3");
 999         precache_model ("models/gibs/smallchest.md3");
1000         precache_model ("models/gibs/chest.md3");
1001         precache_model ("models/gibs/arm.md3");
1002         precache_model ("models/gibs/leg1.md3");
1003         precache_model ("models/gibs/leg2.md3");
1004         precache_model ("models/hook.md3");
1005         precache_sound ("misc/armorimpact.wav");
1006         precache_sound ("misc/bodyimpact1.wav");
1007         precache_sound ("misc/bodyimpact2.wav");
1008         precache_sound ("misc/gib.wav");
1009         precache_sound ("misc/gib_splat01.wav");
1010         precache_sound ("misc/gib_splat02.wav");
1011         precache_sound ("misc/gib_splat03.wav");
1012         precache_sound ("misc/gib_splat04.wav");
1013         precache_sound ("misc/hit.wav");
1014         PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1015         PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1016         precache_sound ("misc/null.wav");
1017         precache_sound ("misc/spawn.wav");
1018         precache_sound ("misc/talk.wav");
1019         precache_sound ("misc/teleport.wav");
1020         precache_sound ("player/lava.wav");
1021         precache_sound ("player/slime.wav");
1022
1023         // announcer sounds - male
1024         //precache_sound ("announcer/male/electrobitch.wav");
1025         precache_sound ("announcer/male/03kills.wav");
1026         precache_sound ("announcer/male/05kills.wav");
1027         precache_sound ("announcer/male/10kills.wav");
1028         precache_sound ("announcer/male/15kills.wav");
1029         precache_sound ("announcer/male/20kills.wav");
1030         precache_sound ("announcer/male/25kills.wav");
1031         precache_sound ("announcer/male/30kills.wav");
1032         precache_sound ("announcer/male/botlike.wav");
1033         precache_sound ("announcer/male/yoda.wav");
1034
1035         // announcer sounds - robotic
1036         precache_sound ("announcer/robotic/prepareforbattle.wav");
1037         precache_sound ("announcer/robotic/begin.wav");
1038         precache_sound ("announcer/robotic/timeoutcalled.wav");
1039         precache_sound ("announcer/robotic/1fragleft.wav");
1040         precache_sound ("announcer/robotic/1minuteremains.wav");
1041         precache_sound ("announcer/robotic/2fragsleft.wav");
1042         precache_sound ("announcer/robotic/3fragsleft.wav");
1043         if (g_minstagib)
1044         {
1045                 precache_sound ("announcer/robotic/lastsecond.wav");
1046                 precache_sound ("announcer/robotic/narrowly.wav");
1047         }
1048
1049         precache_model ("models/sprites/1.spr32");
1050         precache_model ("models/sprites/2.spr32");
1051         precache_model ("models/sprites/3.spr32");
1052         precache_model ("models/sprites/4.spr32");
1053         precache_model ("models/sprites/5.spr32");
1054         precache_model ("models/sprites/6.spr32");
1055         precache_model ("models/sprites/7.spr32");
1056         precache_model ("models/sprites/8.spr32");
1057         precache_model ("models/sprites/9.spr32");
1058         precache_model ("models/sprites/10.spr32");
1059         precache_sound ("announcer/robotic/1.ogg");
1060         precache_sound ("announcer/robotic/2.ogg");
1061         precache_sound ("announcer/robotic/3.ogg");
1062         precache_sound ("announcer/robotic/4.ogg");
1063         precache_sound ("announcer/robotic/5.ogg");
1064         precache_sound ("announcer/robotic/6.ogg");
1065         precache_sound ("announcer/robotic/7.ogg");
1066         precache_sound ("announcer/robotic/8.ogg");
1067         precache_sound ("announcer/robotic/9.ogg");
1068         precache_sound ("announcer/robotic/10.ogg");
1069
1070         // common weapon precaches
1071         precache_sound ("weapons/weapon_switch.wav");
1072         precache_sound ("weapons/weaponpickup.wav");
1073         if (cvar("g_grappling_hook"))
1074         {
1075                 precache_sound ("weapons/hook_fire.wav"); // hook
1076                 precache_sound ("weapons/hook_impact.wav"); // hook
1077         }
1078
1079         if (cvar("sv_precacheweapons") || g_nixnex)
1080         {
1081                 //precache weapon models/sounds
1082                 local float wep;
1083                 wep = WEP_FIRST;
1084                 while (wep <= WEP_LAST)
1085                 {
1086                         weapon_action(wep, WR_PRECACHE);
1087                         wep = wep + 1;
1088                 }
1089         }
1090
1091         // plays music for the level if there is any
1092         if (self.noise)
1093         {
1094                 precache_sound (self.noise);
1095                 ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1096         }
1097 }
1098
1099 // sorry, but using \ in macros breaks line numbers
1100 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1101 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1102 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1103
1104 vector ExactTriggerHit_mins;
1105 vector ExactTriggerHit_maxs;
1106 float ExactTriggerHit_Recurse()
1107 {
1108         float s;
1109         entity se;
1110         float f;
1111
1112         tracebox('0 0 0', ExactTriggerHit_mins, ExactTriggerHit_maxs, '0 0 0', MOVE_NORMAL, other);
1113         if not(trace_ent)
1114                 return 0;
1115         if(trace_ent == self)
1116                 return 1;
1117
1118         se = trace_ent;
1119         s = se.solid;
1120         se.solid = SOLID_NOT;
1121         f = ExactTriggerHit_Recurse();
1122         se.solid = s;
1123
1124         return f;
1125 }
1126
1127 float ExactTriggerHit()
1128 {
1129         float f, s;
1130
1131         if not(self.modelindex)
1132                 return 1;
1133
1134         s = self.solid;
1135         self.solid = SOLID_BSP;
1136         ExactTriggerHit_mins = other.absmin;
1137         ExactTriggerHit_maxs = other.absmax;
1138         f = ExactTriggerHit_Recurse();
1139         self.solid = s;
1140
1141         return f;
1142 }
1143
1144 // WARNING: this kills the trace globals
1145 #define EXACTTRIGGER_TOUCH if not(ExactTriggerHit()) return
1146 #define EXACTTRIGGER_INIT  InitSolidBSPTrigger(); self.solid = SOLID_TRIGGER
1147
1148 #define INITPRIO_FIRST              0
1149 #define INITPRIO_GAMETYPE           0
1150 #define INITPRIO_GAMETYPE_FALLBACK  1
1151 #define INITPRIO_FINDTARGET        10
1152 #define INITPRIO_SETLOCATION       90
1153 #define INITPRIO_LINKDOORS         91
1154 #define INITPRIO_LAST              99
1155
1156 .void(void) initialize_entity;
1157 .float initialize_entity_order;
1158 .entity initialize_entity_next;
1159 entity initialize_entity_first;
1160 void InitializeEntity(entity e, void(void) func, float order)
1161 {
1162         entity prev, cur;
1163
1164         if(!e || e.initialize_entity)
1165         {
1166                 // make a proxy initializer entity
1167                 entity e_old;
1168                 e_old = e;
1169                 e = spawn();
1170                 e.classname = "initialize_entity";
1171                 e.enemy = e_old;
1172         }
1173
1174         e.initialize_entity = func;
1175         e.initialize_entity_order = order;
1176
1177         cur = initialize_entity_first;
1178         for(;;)
1179         {
1180                 if(!cur || cur.initialize_entity_order > order)
1181                 {
1182                         // insert between prev and cur
1183                         if(prev)
1184                                 prev.initialize_entity_next = e;
1185                         else
1186                                 initialize_entity_first = e;
1187                         e.initialize_entity_next = cur;
1188                         return;
1189                 }
1190                 prev = cur;
1191                 cur = cur.initialize_entity_next;
1192         }
1193 }
1194 void InitializeEntitiesRun()
1195 {
1196         for(self = initialize_entity_first; self; )
1197         {
1198                 entity e;
1199                 var void(void) func;
1200                 e = self.initialize_entity_next;
1201                 func = self.initialize_entity;
1202                 self.initialize_entity_order = 0;
1203                 self.initialize_entity = func_null;
1204                 self.initialize_entity_next = world;
1205                 if(self.classname == "initialize_entity")
1206                 {
1207                         entity e_old;
1208                         e_old = self.enemy;
1209                         remove(self);
1210                         self = e_old;
1211                 }
1212                 dprint("Delayed initialization: ", self.classname, "\n");
1213                 func();
1214                 self = e;
1215         }
1216         initialize_entity_first = world;
1217 }
1218
1219 .float nottargeted;
1220 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1221
1222 float power2of(float e)
1223 {
1224         return pow(2, e);
1225 }
1226 float log2of(float x)
1227 {
1228         // NOTE: generated code
1229         if(x > 2048)
1230                 if(x > 131072)
1231                         if(x > 1048576)
1232                                 if(x > 4194304)
1233                                         return 23;
1234                                 else
1235                                         if(x > 2097152)
1236                                                 return 22;
1237                                         else
1238                                                 return 21;
1239                         else
1240                                 if(x > 524288)
1241                                         return 20;
1242                                 else
1243                                         if(x > 262144)
1244                                                 return 19;
1245                                         else
1246                                                 return 18;
1247                 else
1248                         if(x > 16384)
1249                                 if(x > 65536)
1250                                         return 17;
1251                                 else
1252                                         if(x > 32768)
1253                                                 return 16;
1254                                         else
1255                                                 return 15;
1256                         else
1257                                 if(x > 8192)
1258                                         return 14;
1259                                 else
1260                                         if(x > 4096)
1261                                                 return 13;
1262                                         else
1263                                                 return 12;
1264         else
1265                 if(x > 32)
1266                         if(x > 256)
1267                                 if(x > 1024)
1268                                         return 11;
1269                                 else
1270                                         if(x > 512)
1271                                                 return 10;
1272                                         else
1273                                                 return 9;
1274                         else
1275                                 if(x > 128)
1276                                         return 8;
1277                                 else
1278                                         if(x > 64)
1279                                                 return 7;
1280                                         else
1281                                                 return 6;
1282                 else
1283                         if(x > 4)
1284                                 if(x > 16)
1285                                         return 5;
1286                                 else
1287                                         if(x > 8)
1288                                                 return 4;
1289                                         else
1290                                                 return 3;
1291                         else
1292                                 if(x > 2)
1293                                         return 2;
1294                                 else
1295                                         if(x > 1)
1296                                                 return 1;
1297                                         else
1298                                                 return 0;
1299 }
1300
1301 //
1302 // func_breakable
1303 // - basically func_assault_destructible for general gameplay use
1304 //
1305 float () crandom;
1306 void () SUB_UseTargets, assault_destructible_use, SUB_Remove, SUB_Null;
1307 void LaunchDebris (string debrisname) =
1308 {
1309         local   entity dbr;
1310
1311         if (debrisname == "" || !debrisname)
1312                 return;
1313
1314         dbr = spawn();
1315         dbr.origin = self.origin;
1316         setmodel (dbr, debrisname );
1317         setsize (dbr, '0 0 0', '0 0 0');
1318         dbr.velocity_x = 70 * crandom();
1319         dbr.velocity_y = 70 * crandom();
1320         dbr.velocity_z = 140 + 70 * random();
1321         dbr.movetype = MOVETYPE_BOUNCE;
1322         dbr.solid = SOLID_BBOX;
1323         dbr.avelocity_x = random()*600;
1324         dbr.avelocity_y = random()*600;
1325         dbr.avelocity_z = random()*600;
1326         dbr.think = SUB_Remove;
1327         dbr.nextthink = time + 13 + random()*10;
1328 };
1329
1330 .string debris1, debris2, debris3;
1331 .string mdl_dead;
1332 void func_breakable_destroy() {
1333         if (self.mdl_dead)
1334                 setmodel(self, self.mdl_dead);
1335         else {
1336                 self.model = "";
1337                 self.solid = SOLID_NOT;
1338         }
1339         self.takedamage = DAMAGE_NO;
1340
1341         // now throw around the debris
1342         LaunchDebris(self.debris1);
1343         LaunchDebris(self.debris2);
1344         LaunchDebris(self.debris3);
1345
1346         SUB_UseTargets();
1347
1348         self.event_damage = SUB_Null;
1349 }
1350
1351 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force) {
1352
1353         if(self.cnt > 0) {
1354                 self.health = self.health - damage;
1355                 // add pain effects?
1356         }
1357
1358         if(self.health < 0) {
1359                 activator = attacker;
1360                 func_breakable_destroy();
1361         }
1362 }
1363
1364 // destructible walls that can be used to trigger target_objective_decrease
1365 void spawnfunc_func_breakable() {
1366         if(!self.health)
1367                 self.health = 100;
1368
1369         self.max_health = self.health;
1370
1371         //self.cnt = 0; // not yet activated
1372
1373
1374
1375         self.classname = "func_breakable";
1376         self.mdl = self.model;
1377         setmodel(self, self.mdl);
1378
1379         self.solid = SOLID_BSP;
1380
1381         // precache all the models
1382         if (self.mdl_dead)
1383                 precache_model(self.mdl_dead);
1384         if (self.debris1)
1385                 precache_model(self.debris1);
1386         if (self.debris2)
1387                 precache_model(self.debris2);
1388         if (self.debris3)
1389                 precache_model(self.debris3);
1390
1391         self.use = assault_destructible_use;    // shared use function, b/c they woudl do the same thing anyways
1392         self.event_damage = func_breakable_damage;
1393 }