data/qcsrc/server/miscfunctions.qc

   1 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   2 void() spawnpoint_use;
   3 string ColoredTeamName(float t);
   4
   5 float RandomSelection_totalweight;
   6 float RandomSelection_best_priority;
   7 entity RandomSelection_chosen_ent;
   8 float RandomSelection_chosen_float;
   9 void RandomSelection_Init()
  10 {
  11         RandomSelection_totalweight = 0;
  12         RandomSelection_chosen_ent = world;
  13         RandomSelection_chosen_float = 0;
  14         RandomSelection_best_priority = -1;
  15 }
  16 void RandomSelection_Add(entity e, float f, float weight, float priority)
  17 {
  18         if(priority > RandomSelection_best_priority)
  19         {
  20                 RandomSelection_best_priority = priority;
  21                 RandomSelection_chosen_ent = e;
  22                 RandomSelection_chosen_float = f;
  23                 RandomSelection_totalweight = weight;
  24         }
  25         else if(priority == RandomSelection_best_priority)
  26         {
  27                 RandomSelection_totalweight += weight;
  28                 if(random() * RandomSelection_totalweight <= weight)
  29                 {
  30                         RandomSelection_chosen_ent = e;
  31                         RandomSelection_chosen_float = f;
  32                 }
  33         }
  34 }
  35
  36 float DistributeEvenly_amount;
  37 float DistributeEvenly_totalweight;
  38 void DistributeEvenly_Init(float amount, float totalweight)
  39 {
  40         if(DistributeEvenly_amount)
  41         {
  42                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  43                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  44         }
  45         if(totalweight == 0)
  46                 DistributeEvenly_amount = 0;
  47         else
  48                 DistributeEvenly_amount = amount;
  49         DistributeEvenly_totalweight = totalweight;
  50 }
  51 float DistributeEvenly_Get(float weight)
  52 {
  53         float f;
  54         if(weight <= 0)
  55                 return 0;
  56         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  57         DistributeEvenly_totalweight -= weight;
  58         DistributeEvenly_amount -= f;
  59         return f;
  60 }
  61
  62 void move_out_of_solid_expand(entity e, vector by)
  63 {
  64         float eps = 0.0625;
  65         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  66         if(trace_startsolid)
  67                 return;
  68         if(trace_fraction < 1)
  69         {
  70                 // hit something
  71                 // adjust origin in the other direction...
  72                 e.origin = e.origin - by * (1 - trace_fraction);
  73         }
  74 }
  75
  76 void move_out_of_solid(entity e)
  77 {
  78         vector o, m0, m1;
  79
  80         o = e.origin;
  81         traceline(o, o, MOVE_WORLDONLY, e);
  82         if(trace_startsolid)
  83         {
  84                 dprint("origin is in solid too! (", vtos(o), ")");
  85                 return;
  86         }
  87
  88         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  89         if(!trace_startsolid)
  90                 return;
  91
  92         m0 = e.mins;
  93         m1 = e.maxs;
  94         e.mins = '0 0 0';
  95         e.maxs = '0 0 0';
  96         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  97         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
  98         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
  99         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
 100         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
 101         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
 102         setorigin(e, e.origin);
 103
 104         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 105         if(trace_startsolid)
 106         {
 107                 dprint("could not get out of solid (", vtos(o), ")\n");
 108                 return;
 109         }
 110 }
 111
 112 string STR_PLAYER = "player";
 113
 114 #if 0
 115 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
 116 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 117 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
 118 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
 119 #else
 120 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
 121 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
 122 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 123 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
 124 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 125 #endif
 126
 127 // change that to actually calling strcat when running on an engine without
 128 // unlimited tempstrings:
 129 // string strcat1(string s) = #115; // FRIK_FILE
 130 #define strcat1(s) (s)
 131
 132 float logfile_open;
 133 float logfile;
 134
 135 void bcenterprint(string s)
 136 {
 137         // TODO replace by MSG_ALL (would show it to spectators too, though)?
 138         entity head;
 139         FOR_EACH_PLAYER(head)
 140                 if(clienttype(head) == CLIENTTYPE_REAL)
 141                         centerprint(head, s);
 142 }
 143
 144 void ServerConsoleEcho(string s, float check_dangerous)
 145 {
 146         local string ch;
 147         if (checkextension("DP_SV_PRINT"))
 148                 print(s, "\n");
 149         else
 150         {
 151                 localcmd("echo \"");
 152                 if(check_dangerous)
 153                 {
 154                         while(strlen(s))
 155                         {
 156                                 ch = substring(s, 0, 1);
 157                                 if(ch != "\"" && ch != "\r" && ch != "\n")
 158                                         localcmd(ch);
 159                                 s = substring(s, 1, strlen(s) - 1);
 160                         }
 161                 }
 162                 else
 163                 {
 164                         localcmd(s);
 165                 }
 166                 localcmd("\"\n");
 167         }
 168 }
 169
 170 void GameLogEcho(string s, float check_dangerous)
 171 {
 172         string fn;
 173         float matches;
 174
 175         if(cvar("sv_eventlog_files"))
 176         {
 177                 if(!logfile_open)
 178                 {
 179                         logfile_open = TRUE;
 180                         matches = cvar("sv_eventlog_files_counter") + 1;
 181                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 182                         fn = ftos(matches);
 183                         if(strlen(fn) < 8)
 184                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 185                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 186                         logfile = fopen(fn, FILE_APPEND);
 187                         fputs(logfile, ":logversion:2\n");
 188                 }
 189                 if(logfile >= 0)
 190                 {
 191                         if(cvar("sv_eventlog_files_timestamps"))
 192                                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 193                         else
 194                                 fputs(logfile, strcat(s, "\n"));
 195                 }
 196         }
 197         if(cvar("sv_eventlog_console"))
 198         {
 199                 ServerConsoleEcho(s, check_dangerous);
 200         }
 201 }
 202
 203 void GameLogInit()
 204 {
 205         logfile_open = 0;
 206         // will be opened later
 207 }
 208
 209 void GameLogClose()
 210 {
 211         if(logfile_open && logfile >= 0)
 212         {
 213                 fclose(logfile);
 214                 logfile = -1;
 215         }
 216 }
 217
 218 void relocate_spawnpoint()
 219 {
 220         // nudge off the floor
 221         setorigin(self, self.origin + '0 0 1');
 222
 223         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 224         if (trace_startsolid)
 225         {
 226                 objerror("player spawn point in solid, mapper sucks!\n");
 227                 return;
 228         }
 229
 230         if(cvar("g_spawnpoints_autodrop"))
 231         {
 232                 setsize(self, PL_MIN, PL_MAX);
 233                 droptofloor();
 234         }
 235
 236         self.use = spawnpoint_use;
 237         self.team_saved = self.team;
 238         if(!self.cnt)
 239                 self.cnt = 1;
 240
 241         if(g_ctf || g_assault || g_onslaught || g_domination)
 242         if(self.team)
 243                 have_team_spawns = 1;
 244 }
 245
 246 #define strstr strstrofs
 247 /*
 248 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 249 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 250 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 251 // BE CONSTANT OR strzoneD!
 252 float strstr(string haystack, string needle, float offset)
 253 {
 254         float len, endpos;
 255         string found;
 256         len = strlen(needle);
 257         endpos = strlen(haystack) - len;
 258         while(offset <= endpos)
 259         {
 260                 found = substring(haystack, offset, len);
 261                 if(found == needle)
 262                         return offset;
 263                 offset = offset + 1;
 264         }
 265         return -1;
 266 }
 267 */
 268
 269 float NUM_NEAREST_ENTITIES = 4;
 270 entity nearest_entity[NUM_NEAREST_ENTITIES];
 271 float nearest_length[NUM_NEAREST_ENTITIES];
 272 entity findnearest(vector point, .string field, string value, vector axismod)
 273 {
 274         entity localhead;
 275         float i;
 276         float j;
 277         float len;
 278         vector dist;
 279
 280         float num_nearest;
 281         num_nearest = 0;
 282
 283         localhead = find(world, field, value);
 284         while(localhead)
 285         {
 286                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 287                         dist = localhead.oldorigin;
 288                 else
 289                         dist = localhead.origin;
 290                 dist = dist - point;
 291                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 292                 len = vlen(dist);
 293
 294                 for(i = 0; i < num_nearest; ++i)
 295                 {
 296                         if(len < nearest_length[i])
 297                                 break;
 298                 }
 299
 300                 // now i tells us where to insert at
 301                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 302                 if(i < NUM_NEAREST_ENTITIES)
 303                 {
 304                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 305                         {
 306                                 nearest_length[j + 1] = nearest_length[j];
 307                                 nearest_entity[j + 1] = nearest_entity[j];
 308                         }
 309                         nearest_length[i] = len;
 310                         nearest_entity[i] = localhead;
 311                         if(num_nearest < NUM_NEAREST_ENTITIES)
 312                                 num_nearest = num_nearest + 1;
 313                 }
 314
 315                 localhead = find(localhead, field, value);
 316         }
 317
 318         // now use the first one from our list that we can see
 319         for(i = 0; i < num_nearest; ++i)
 320         {
 321                 traceline(point, nearest_entity[i].origin, TRUE, world);
 322                 if(trace_fraction == 1)
 323                 {
 324                         if(i != 0)
 325                         {
 326                                 dprint("Nearest point (");
 327                                 dprint(nearest_entity[0].netname);
 328                                 dprint(") is not visible, using a visible one.\n");
 329                         }
 330                         return nearest_entity[i];
 331                 }
 332         }
 333
 334         if(num_nearest == 0)
 335                 return world;
 336
 337         dprint("Not seeing any location point, using nearest as fallback.\n");
 338         /* DEBUGGING CODE:
 339         dprint("Candidates were: ");
 340         for(j = 0; j < num_nearest; ++j)
 341         {
 342                 if(j != 0)
 343                         dprint(", ");
 344                 dprint(nearest_entity[j].netname);
 345         }
 346         dprint("\n");
 347         */
 348
 349         return nearest_entity[0];
 350 }
 351
 352 void spawnfunc_target_location()
 353 {
 354         self.classname = "target_location";
 355         // location name in netname
 356         // eventually support: count, teamgame selectors, line of sight?
 357 };
 358
 359 void spawnfunc_info_location()
 360 {
 361         self.classname = "target_location";
 362         self.message = self.netname;
 363 };
 364
 365 string NearestLocation(vector p)
 366 {
 367         entity loc;
 368         string ret;
 369         ret = "somewhere";
 370         loc = findnearest(p, classname, "target_location", '1 1 1');
 371         if(loc)
 372         {
 373                 ret = loc.message;
 374         }
 375         else
 376         {
 377                 loc = findnearest(p, target, "###item###", '1 1 4');
 378                 if(loc)
 379                         ret = loc.netname;
 380         }
 381         return ret;
 382 }
 383
 384 string formatmessage(string msg)
 385 {
 386         float p;
 387         float n;
 388         string msg_save;
 389         string escape;
 390         string replacement;
 391         msg_save = strzone(msg);
 392         p = 0;
 393         n = 7;
 394         while(1)
 395         {
 396                 if(n < 1)
 397                         break; // too many replacements
 398                 n = n - 1;
 399                 p = strstr(msg_save, "%", p); // NOTE: this destroys msg as it's a tempstring!
 400                 if(p < 0)
 401                         break;
 402                 replacement = substring(msg_save, p, 2);
 403                 escape = substring(msg_save, p + 1, 1);
 404                 if(escape == "%")
 405                         replacement = "%";
 406                 else if(escape == "a")
 407                         replacement = ftos(floor(self.armorvalue));
 408                 else if(escape == "h")
 409                         replacement = ftos(floor(self.health));
 410                 else if(escape == "l")
 411                         replacement = NearestLocation(self.origin);
 412                 else if(escape == "y")
 413                         replacement = NearestLocation(self.cursor_trace_endpos);
 414                 else if(escape == "d")
 415                         replacement = NearestLocation(self.death_origin);
 416                 else if(escape == "w")
 417                 {
 418                         float wep;
 419                         wep = self.weapon;
 420                         if(!wep)
 421                                 wep = self.switchweapon;
 422                         if(!wep)
 423                                 wep = self.cnt;
 424                         replacement = W_Name(wep);
 425                 }
 426                 else if(escape == "W")
 427                 {
 428                         if(self.items & IT_SHELLS) replacement = "shells";
 429                         else if(self.items & IT_NAILS) replacement = "bullets";
 430                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 431                         else if(self.items & IT_CELLS) replacement = "cells";
 432                         else replacement = "batteries"; // ;)
 433                 }
 434                 else if(escape == "x")
 435                 {
 436                         replacement = self.cursor_trace_ent.netname;
 437                         if(!replacement || !self.cursor_trace_ent)
 438                                 replacement = "nothing";
 439                 }
 440                 else if(escape == "p")
 441                 {
 442                         if(self.last_selected_player)
 443                                 replacement = self.last_selected_player.netname;
 444                         else
 445                                 replacement = "(nobody)";
 446                 }
 447                 msg = strcat(substring(msg_save, 0, p), replacement);
 448                 msg = strcat(msg, substring(msg_save, p+2, strlen(msg_save) - (p+2)));
 449                 strunzone(msg_save);
 450                 msg_save = strzone(msg);
 451                 p = p + 2;
 452         }
 453         msg = strcat(msg_save, "");
 454         strunzone(msg_save);
 455         return msg;
 456 }
 457
 458 /*
 459 =============
 460 GetCvars
 461 =============
 462 Called with:
 463   0:  sends the request
 464   >0: receives a cvar from name=argv(f) value=argv(f+1)
 465 */
 466 void GetCvars_handleString(float f, .string field, string name)
 467 {
 468         if(f < 0)
 469         {
 470                 if(self.field)
 471                         strunzone(self.field);
 472         }
 473         else if(f > 0)
 474         {
 475                 if(argv(f) == name)
 476                 {
 477                         if(self.field)
 478                                 strunzone(self.field);
 479                         self.field = strzone(argv(f + 1));
 480                 }
 481         }
 482         else
 483                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 484 }
 485 void GetCvars_handleFloat(float f, .float field, string name)
 486 {
 487         if(f < 0)
 488         {
 489         }
 490         else if(f > 0)
 491         {
 492                 if(argv(f) == name)
 493                         self.field = stof(argv(f + 1));
 494         }
 495         else
 496                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 497 }
 498 void GetCvars(float f)
 499 {
 500         GetCvars_handleFloat(f, autoswitch, "cl_autoswitch");
 501         GetCvars_handleFloat(f, cvar_cl_hidewaypoints, "cl_hidewaypoints");
 502         GetCvars_handleFloat(f, cvar_cl_zoomfactor, "cl_zoomfactor");
 503         GetCvars_handleFloat(f, cvar_cl_zoomspeed, "cl_zoomspeed");
 504         GetCvars_handleFloat(f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 505         GetCvars_handleFloat(f, cvar_cl_nogibs, "cl_nogibs");
 506         GetCvars_handleFloat(f, cvar_scr_centertime, "scr_centertime");
 507         GetCvars_handleFloat(f, cvar_cl_shownames, "cl_shownames");
 508         GetCvars_handleString(f, cvar_g_nexuizversion, "g_nexuizversion");
 509         GetCvars_handleFloat(f, cvar_cl_handicap, "cl_handicap");
 510 }
 511
 512 float fexists(string f)
 513 {
 514         float fh;
 515         fh = fopen(f, FILE_READ);
 516         if(fh < 0)
 517                 return FALSE;
 518         fclose(fh);
 519         return TRUE;
 520 }
 521
 522 void backtrace(string msg)
 523 {
 524         float dev;
 525         dev = cvar("developer");
 526         cvar_set("developer", "1");
 527         dprint("\n");
 528         dprint("--- CUT HERE ---\nWARNING: ");
 529         dprint(msg);
 530         dprint("\n");
 531         remove(world); // isn't there any better way to cause a backtrace?
 532         dprint("\n--- CUT UNTIL HERE ---\n");
 533         cvar_set("developer", ftos(dev));
 534 }
 535
 536 #if 0
 537 void DistributeFragsAmongTeam(entity p, float targetteam, float factor)
 538 {
 539         float nTeam;
 540         entity head;
 541         float f;
 542
 543         if(!teams_matter)
 544                 return;
 545
 546         //if(p.frags < 0)
 547         //{
 548         //      p.frags = 0; // do not harm the new team!
 549         //      return; // won't distribute negative scores
 550         //}
 551
 552         if(p.frags == -666)
 553                 return;
 554
 555         f = ceil(factor * p.frags);
 556         p.frags = p.frags - f;
 557
 558         nTeam = 0;
 559         FOR_EACH_PLAYER(head)
 560                 if(head != p)
 561                         if(head.team == targetteam)
 562                                 nTeam = nTeam + 1;
 563
 564         if(nTeam == 0)
 565                 return;
 566
 567         DistributeEvenly_Init(f, nTeam);
 568
 569         FOR_EACH_PLAYER(head)
 570                 if(head != p)
 571                         if(head.team == targetteam)
 572                                 head.frags = head.frags + DistributeEvenly_Get(1);
 573 }
 574 #endif
 575
 576 string Team_ColorCode(float teamid)
 577 {
 578         if(teamid == COLOR_TEAM1)
 579                 return "^1";
 580         else if(teamid == COLOR_TEAM2)
 581                 return "^4";
 582         else if(teamid == COLOR_TEAM3)
 583                 return "^3";
 584         else if(teamid == COLOR_TEAM4)
 585                 return "^6";
 586         else
 587                 return "^7";
 588 }
 589 string Team_ColorName(float t)
 590 {
 591         // fixme: Search for team entities and get their .netname's!
 592         if(t == COLOR_TEAM1)
 593                 return "Red";
 594         if(t == COLOR_TEAM2)
 595                 return "Blue";
 596         if(t == COLOR_TEAM3)
 597                 return "Yellow";
 598         if(t == COLOR_TEAM4)
 599                 return "Pink";
 600         return "Neutral";
 601 }
 602 string Team_ColorNameLowerCase(float t)
 603 {
 604         // fixme: Search for team entities and get their .netname's!
 605         if(t == COLOR_TEAM1)
 606                 return "red";
 607         if(t == COLOR_TEAM2)
 608                 return "blue";
 609         if(t == COLOR_TEAM3)
 610                 return "yellow";
 611         if(t == COLOR_TEAM4)
 612                 return "pink";
 613         return "neutral";
 614 }
 615
 616 /*
 617 string decolorize(string s)
 618 {
 619         string out;
 620         out = "";
 621         while(s != "")
 622         {
 623                 float n;
 624                 string ch1, ch2;
 625                 n = 1;
 626                 ch1 = substring(s, 0, 1);
 627                 ch2 = substring(s, 1, 1);
 628                 if(ch1 == "^")
 629                 {
 630                         n = 2;
 631                         if(ch2 == "^")
 632                                 out = strcat(out, "^^");
 633                         else if(ch2 == "0")
 634                                 out = strcat1(out);
 635                         else if(ch2 == "1")
 636                                 out = strcat1(out);
 637                         else if(ch2 == "2")
 638                                 out = strcat1(out);
 639                         else if(ch2 == "3")
 640                                 out = strcat1(out);
 641                         else if(ch2 == "4")
 642                                 out = strcat1(out);
 643                         else if(ch2 == "5")
 644                                 out = strcat1(out);
 645                         else if(ch2 == "6")
 646                                 out = strcat1(out);
 647                         else if(ch2 == "7")
 648                                 out = strcat1(out);
 649                         else if(ch2 == "8")
 650                                 out = strcat1(out);
 651                         else if(ch2 == "9")
 652                                 out = strcat1(out);
 653                         else
 654                         {
 655                                 n = 1;
 656                                 out = strcat(out, "^^");
 657                         }
 658                         s = substring(s, n, strlen(s) - n);
 659                 }
 660                 else
 661                 {
 662                         s = substring(s, 1, strlen(s) - 1);
 663                         out = strcat(out, ch1);
 664                 }
 665         }
 666         return out;
 667 }
 668 #define strdecolorize(s) decolorize(s)
 669 #define strlennocol(s) strlen(decolorize(s))
 670 */
 671
 672 #define CENTERPRIO_POINT 1
 673 #define CENTERPRIO_SPAM 2
 674 #define CENTERPRIO_REBALANCE 2
 675 #define CENTERPRIO_VOTE 4
 676 #define CENTERPRIO_NORMAL 5
 677 #define CENTERPRIO_MAPVOTE 9
 678 #define CENTERPRIO_IDLEKICK 50
 679 #define CENTERPRIO_ADMIN 99
 680 .float centerprint_priority;
 681 .float centerprint_expires;
 682 void centerprint_atprio(entity e, float prio, string s)
 683 {
 684         if(intermission_running)
 685                 if(prio < CENTERPRIO_MAPVOTE)
 686                         return;
 687         if(time > e.centerprint_expires)
 688                 e.centerprint_priority = 0;
 689         if(prio >= e.centerprint_priority)
 690         {
 691                 e.centerprint_priority = prio;
 692                 if(timeoutStatus == 2)
 693                         e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 694                 else
 695                         e.centerprint_expires = time + e.cvar_scr_centertime;
 696                 centerprint_builtin(e, s);
 697         }
 698 }
 699 void centerprint_expire(entity e, float prio)
 700 {
 701         if(prio == e.centerprint_priority)
 702         {
 703                 e.centerprint_priority = 0;
 704                 centerprint_builtin(e, "");
 705         }
 706 }
 707 void centerprint(entity e, string s)
 708 {
 709         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 710 }
 711
 712 void VoteNag();
 713
 714 // decolorizes and team colors the player name when needed
 715 string playername(entity p)
 716 {
 717         string t;
 718         if(teams_matter && !intermission_running && p.classname == "player")
 719         {
 720                 t = Team_ColorCode(p.team);
 721                 return strcat(t, strdecolorize(p.netname));
 722         }
 723         else
 724                 return p.netname;
 725 }
 726
 727 vector randompos(vector m1, vector m2)
 728 {
 729         local vector v;
 730         m2 = m2 - m1;
 731         v_x = m2_x * random() + m1_x;
 732         v_y = m2_y * random() + m1_y;
 733         v_z = m2_z * random() + m1_z;
 734         return  v;
 735 };
 736
 737 // requires that m2>m1 in all coordinates, and that m4>m3
 738 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;};
 739
 740 // requires the same, but is a stronger condition
 741 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;};
 742
 743 float g_pickup_shells;
 744 float g_pickup_shells_max;
 745 float g_pickup_nails;
 746 float g_pickup_nails_max;
 747 float g_pickup_rockets;
 748 float g_pickup_rockets_max;
 749 float g_pickup_cells;
 750 float g_pickup_cells_max;
 751 float g_pickup_armorsmall;
 752 float g_pickup_armorsmall_max;
 753 float g_pickup_armormedium;
 754 float g_pickup_armormedium_max;
 755 float g_pickup_armorlarge;
 756 float g_pickup_armorlarge_max;
 757 float g_pickup_healthsmall;
 758 float g_pickup_healthsmall_max;
 759 float g_pickup_healthmedium;
 760 float g_pickup_healthmedium_max;
 761 float g_pickup_healthlarge;
 762 float g_pickup_healthlarge_max;
 763 float g_pickup_healthmega;
 764 float g_pickup_healthmega_max;
 765
 766 float start_items;
 767 float start_switchweapon;
 768 float start_ammo_shells;
 769 float start_ammo_nails;
 770 float start_ammo_rockets;
 771 float start_ammo_cells;
 772 float start_health;
 773 float start_armorvalue;
 774
 775 void readlevelcvars(void)
 776 {
 777         sv_cheats = cvar("sv_cheats");
 778         sv_gentle = cvar("sv_gentle");
 779         sv_foginterval = cvar("sv_foginterval");
 780         g_cloaked = cvar("g_cloaked");
 781         g_footsteps = cvar("g_footsteps");
 782         g_grappling_hook = cvar("g_grappling_hook");
 783         g_instagib = cvar("g_instagib");
 784         g_laserguided_missile = cvar("g_laserguided_missile");
 785         g_midair = cvar("g_midair");
 786         g_minstagib = cvar("g_minstagib");
 787         g_nixnex = cvar("g_nixnex");
 788         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
 789         g_norecoil = cvar("g_norecoil");
 790         g_rocketarena = cvar("g_rocketarena");
 791         g_vampire = cvar("g_vampire");
 792         g_tourney = cvar("g_tourney");
 793         sv_maxidle = cvar("sv_maxidle");
 794         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 795         sv_pogostick = cvar("sv_pogostick");
 796         sv_doublejump = cvar("sv_doublejump");
 797
 798         g_pickup_shells                    = cvar("g_pickup_shells");
 799         g_pickup_shells_max                = cvar("g_pickup_shells_max");
 800         g_pickup_nails                     = cvar("g_pickup_nails");
 801         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
 802         g_pickup_rockets                   = cvar("g_pickup_rockets");
 803         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
 804         g_pickup_cells                     = cvar("g_pickup_cells");
 805         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
 806         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
 807         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
 808         g_pickup_armormedium               = cvar("g_pickup_armormedium");
 809         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
 810         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
 811         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
 812         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
 813         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
 814         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
 815         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
 816         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
 817         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
 818         g_pickup_healthmega                = cvar("g_pickup_healthmega");
 819         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
 820
 821         // initialize starting values for players
 822         start_items = 0;
 823         start_switchweapon = 0;
 824         start_ammo_shells = 0;
 825         start_ammo_nails = 0;
 826         start_ammo_rockets = 0;
 827         start_ammo_cells = 0;
 828         start_health = cvar("g_balance_health_start");
 829         start_armorvalue = cvar("g_balance_armor_start");
 830
 831         if(g_instagib)
 832         {
 833                 start_items = IT_NEX;
 834                 start_switchweapon = WEP_NEX;
 835                 weapon_action(start_switchweapon, WR_PRECACHE);
 836                 start_ammo_cells = 999;
 837         }
 838         else if(g_rocketarena)
 839         {
 840                 start_items = IT_ROCKET_LAUNCHER;
 841                 start_switchweapon = WEP_ROCKET_LAUNCHER;
 842                 weapon_action(start_switchweapon, WR_PRECACHE);
 843                 start_ammo_rockets = 999;
 844         }
 845         else if(g_nixnex)
 846         {
 847                 start_items = 0;
 848                 // will be done later
 849         }
 850         else if(g_minstagib)
 851         {
 852                 start_health = 100;
 853                 start_armorvalue = 0;
 854                 start_items = IT_NEX;
 855                 start_switchweapon = WEP_NEX;
 856                 weapon_action(start_switchweapon, WR_PRECACHE);
 857                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 858                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 859         }
 860         else
 861         {
 862                 if(g_lms)
 863                 {
 864                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 865                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 866                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 867                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 868                         start_health = cvar("g_lms_start_health");
 869                         start_armorvalue = cvar("g_lms_start_armor");
 870                 }
 871                 else if(g_tourney) {
 872                         start_ammo_shells = cvar("g_tourney_start_ammo_shells");
 873                         start_ammo_nails = cvar("g_tourney_start_ammo_nails");
 874                         start_ammo_rockets = cvar("g_tourney_start_ammo_rockets");
 875                         start_ammo_cells = cvar("g_tourney_start_ammo_cells");
 876                         start_health = cvar("g_tourney_start_health");
 877                         start_armorvalue = cvar("g_tourney_start_armor");
 878                 }
 879                 else if (cvar("g_use_ammunition")) {
 880                         start_ammo_shells = cvar("g_start_ammo_shells");
 881                         start_ammo_nails = cvar("g_start_ammo_nails");
 882                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 883                         start_ammo_cells = cvar("g_start_ammo_cells");
 884                 } else {
 885                         start_ammo_shells = cvar("g_pickup_shells_max");
 886                         start_ammo_nails = cvar("g_pickup_nails_max");
 887                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 888                         start_ammo_cells = cvar("g_pickup_cells_max");
 889                 }
 890
 891                 if (cvar("g_start_weapon_laser") || g_lms)
 892                 {
 893                         start_items = start_items | IT_LASER;
 894                         start_switchweapon = WEP_LASER;
 895                         weapon_action(start_switchweapon, WR_PRECACHE);
 896                 }
 897                 if (cvar("g_start_weapon_shotgun") || g_lms)
 898                 {
 899                         start_items = start_items | IT_SHOTGUN;
 900                         start_switchweapon = WEP_SHOTGUN;
 901                         weapon_action(start_switchweapon, WR_PRECACHE);
 902                 }
 903                 if (cvar("g_start_weapon_uzi") || g_lms || g_tourney)
 904                 {
 905                         start_items = start_items | IT_UZI;
 906                         start_switchweapon = WEP_UZI;
 907                         weapon_action(start_switchweapon, WR_PRECACHE);
 908                 }
 909                 if (cvar("g_start_weapon_grenadelauncher") || g_lms || g_tourney)
 910                 {
 911                         start_items = start_items | IT_GRENADE_LAUNCHER;
 912                         start_switchweapon = WEP_GRENADE_LAUNCHER;
 913                         weapon_action(start_switchweapon, WR_PRECACHE);
 914                 }
 915                 if (cvar("g_start_weapon_electro") || g_lms || g_tourney)
 916                 {
 917                         start_items = start_items | IT_ELECTRO;
 918                         start_switchweapon = WEP_ELECTRO;
 919                         weapon_action(start_switchweapon, WR_PRECACHE);
 920                 }
 921                 if (cvar("g_start_weapon_crylink") || g_lms || g_tourney)
 922                 {
 923                         start_items = start_items | IT_CRYLINK;
 924                         start_switchweapon = WEP_CRYLINK;
 925                         weapon_action(start_switchweapon, WR_PRECACHE);
 926                 }
 927                 if (cvar("g_start_weapon_nex") || g_lms || g_tourney)
 928                 {
 929                         start_items = start_items | IT_NEX;
 930                         start_switchweapon = WEP_NEX;
 931                         weapon_action(start_switchweapon, WR_PRECACHE);
 932                 }
 933                 if (cvar("g_start_weapon_hagar") || g_lms || g_tourney)
 934                 {
 935                         start_items = start_items | IT_HAGAR;
 936                         start_switchweapon = WEP_HAGAR;
 937                         weapon_action(start_switchweapon, WR_PRECACHE);
 938                 }
 939                 if (cvar("g_start_weapon_rocketlauncher") || g_lms || g_tourney)
 940                 {
 941                         start_items = start_items | IT_ROCKET_LAUNCHER;
 942                         start_switchweapon = WEP_ROCKET_LAUNCHER;
 943                         weapon_action(start_switchweapon, WR_PRECACHE);
 944                 }
 945         }
 946 }
 947
 948 /*
 949 // TODO sound pack system
 950 string soundpack;
 951
 952 string precache_sound_builtin (string s) = #19;
 953 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
 954 string precache_sound(string s)
 955 {
 956         return precache_sound_builtin(strcat(soundpack, s));
 957 }
 958 void play2(entity e, string filename)
 959 {
 960         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
 961 }
 962 void sound(entity e, float chan, string samp, float vol, float atten)
 963 {
 964         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
 965 }
 966 */
 967
 968 string precache_sound (string s) = #19;
 969 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
 970 void play2(entity e, string filename)
 971 {
 972         stuffcmd(e, strcat("play2 ", filename, "\n"));
 973 }
 974
 975 void play2team(float t, string filename)
 976 {
 977         local entity head;
 978         FOR_EACH_REALPLAYER(head)
 979         {
 980                 if (head.team == t)
 981                         play2(head, filename);
 982         }
 983 }
 984
 985 void PrecachePlayerSounds(string f);
 986 void precache_all_models(string pattern)
 987 {
 988         float globhandle, i, n;
 989         string f;
 990
 991         globhandle = search_begin(pattern, TRUE, FALSE);
 992         if(globhandle < 0)
 993                 return;
 994         n = search_getsize(globhandle);
 995         for(i = 0; i < n; ++i)
 996         {
 997                 //print(search_getfilename(globhandle, i), "\n");
 998                 f = search_getfilename(globhandle, i);
 999                 precache_model(f);
1000                 PrecachePlayerSounds(strcat(f, ".sounds"));
1001         }
1002         search_end(globhandle);
1003 }
1004
1005 void precache()
1006 {
1007         // gamemode related things
1008         precache_model ("models/misc/chatbubble.spr");
1009         precache_model ("models/misc/teambubble.spr");
1010         if (g_runematch)
1011         {
1012                 precache_model ("models/runematch/curse.mdl");
1013                 precache_model ("models/runematch/rune.mdl");
1014         }
1015
1016         // Precache all player models if desired
1017         if (cvar("sv_precacheplayermodels"))
1018         {
1019                 PrecachePlayerSounds("sound/player/default.sounds");
1020                 precache_all_models("models/player/*.zym");
1021                 precache_all_models("models/player/*.dpm");
1022                 precache_all_models("models/player/*.md3");
1023                 precache_all_models("models/player/*.psk");
1024                 //precache_model("models/player/carni.zym");
1025                 //precache_model("models/player/crash.zym");
1026                 //precache_model("models/player/grunt.zym");
1027                 //precache_model("models/player/headhunter.zym");
1028                 //precache_model("models/player/insurrectionist.zym");
1029                 //precache_model("models/player/jeandarc.zym");
1030                 //precache_model("models/player/lurk.zym");
1031                 //precache_model("models/player/lycanthrope.zym");
1032                 //precache_model("models/player/marine.zym");
1033                 //precache_model("models/player/nexus.zym");
1034                 //precache_model("models/player/pyria.zym");
1035                 //precache_model("models/player/shock.zym");
1036                 //precache_model("models/player/skadi.zym");
1037                 //precache_model("models/player/specop.zym");
1038                 //precache_model("models/player/visitant.zym");
1039         }
1040
1041         if (g_footsteps)
1042         {
1043                 precache_sound ("misc/footstep01.wav");
1044                 precache_sound ("misc/footstep02.wav");
1045                 precache_sound ("misc/footstep03.wav");
1046                 precache_sound ("misc/footstep04.wav");
1047                 precache_sound ("misc/footstep05.wav");
1048                 precache_sound ("misc/footstep06.wav");
1049         }
1050
1051         // gore and miscellaneous sounds
1052         //precache_sound ("misc/h2ohit.wav");
1053         precache_model ("models/gibs/bloodyskull.md3");
1054         precache_model ("models/gibs/chunk.mdl");
1055         precache_model ("models/gibs/eye.md3");
1056         precache_model ("models/gibs/gib1.md3");
1057         precache_model ("models/gibs/gib2.md3");
1058         precache_model ("models/gibs/gib3.md3");
1059         precache_model ("models/gibs/gib4.md3");
1060         precache_model ("models/gibs/gib5.md3");
1061         precache_model ("models/gibs/gib6.md3");
1062         precache_model ("models/gibs/smallchest.md3");
1063         precache_model ("models/gibs/chest.md3");
1064         precache_model ("models/gibs/arm.md3");
1065         precache_model ("models/gibs/leg1.md3");
1066         precache_model ("models/gibs/leg2.md3");
1067         precache_model ("models/hook.md3");
1068         precache_sound ("misc/armorimpact.wav");
1069         precache_sound ("misc/bodyimpact1.wav");
1070         precache_sound ("misc/bodyimpact2.wav");
1071         precache_sound ("misc/gib.wav");
1072         precache_sound ("misc/gib_splat01.wav");
1073         precache_sound ("misc/gib_splat02.wav");
1074         precache_sound ("misc/gib_splat03.wav");
1075         precache_sound ("misc/gib_splat04.wav");
1076         precache_sound ("misc/hit.wav");
1077         precache_sound ("misc/hitground1.wav");
1078         precache_sound ("misc/hitground2.wav");
1079         precache_sound ("misc/hitground3.wav");
1080         precache_sound ("misc/hitground4.wav");
1081         precache_sound ("misc/null.wav");
1082         precache_sound ("misc/spawn.wav");
1083         precache_sound ("misc/talk.wav");
1084         precache_sound ("misc/teleport.wav");
1085         precache_sound ("player/lava.wav");
1086         precache_sound ("player/slime.wav");
1087
1088         // announcer sounds - male
1089         //precache_sound ("announcer/male/electrobitch.wav");
1090         precache_sound ("announcer/male/03kills.wav");
1091         precache_sound ("announcer/male/05kills.wav");
1092         precache_sound ("announcer/male/10kills.wav");
1093         precache_sound ("announcer/male/15kills.wav");
1094         precache_sound ("announcer/male/20kills.wav");
1095         precache_sound ("announcer/male/25kills.wav");
1096         precache_sound ("announcer/male/30kills.wav");
1097         precache_sound ("announcer/male/botlike.wav");
1098         precache_sound ("announcer/male/yoda.wav");
1099
1100         // announcer sounds - robotic
1101         precache_sound ("announcer/robotic/prepareforbattle.wav");
1102         precache_sound ("announcer/robotic/begin.wav");
1103         precache_sound ("announcer/robotic/timeoutcalled.wav");
1104         precache_sound ("announcer/robotic/1fragleft.wav");
1105         precache_sound ("announcer/robotic/1minuteremains.wav");
1106         precache_sound ("announcer/robotic/2fragsleft.wav");
1107         precache_sound ("announcer/robotic/3fragsleft.wav");
1108         if (g_minstagib)
1109         {
1110                 precache_sound ("announcer/robotic/lastsecond.wav");
1111                 precache_sound ("announcer/robotic/narrowly.wav");
1112         }
1113
1114         precache_model ("models/sprites/1.spr32");
1115         precache_model ("models/sprites/2.spr32");
1116         precache_model ("models/sprites/3.spr32");
1117         precache_model ("models/sprites/4.spr32");
1118         precache_model ("models/sprites/5.spr32");
1119         precache_model ("models/sprites/6.spr32");
1120         precache_model ("models/sprites/7.spr32");
1121         precache_model ("models/sprites/8.spr32");
1122         precache_model ("models/sprites/9.spr32");
1123         precache_model ("models/sprites/10.spr32");
1124         precache_sound ("announcer/robotic/1.ogg");
1125         precache_sound ("announcer/robotic/2.ogg");
1126         precache_sound ("announcer/robotic/3.ogg");
1127         precache_sound ("announcer/robotic/4.ogg");
1128         precache_sound ("announcer/robotic/5.ogg");
1129         precache_sound ("announcer/robotic/6.ogg");
1130         precache_sound ("announcer/robotic/7.ogg");
1131         precache_sound ("announcer/robotic/8.ogg");
1132         precache_sound ("announcer/robotic/9.ogg");
1133         precache_sound ("announcer/robotic/10.ogg");
1134
1135         // common weapon precaches
1136         precache_sound ("weapons/weapon_switch.wav");
1137         precache_sound ("weapons/weaponpickup.wav");
1138         if (cvar("g_grappling_hook"))
1139         {
1140                 precache_sound ("weapons/hook_fire.wav"); // hook
1141                 precache_sound ("weapons/hook_impact.wav"); // hook
1142         }
1143
1144         if (cvar("sv_precacheweapons") || g_nixnex)
1145         {
1146                 //precache weapon models/sounds
1147                 local float wep;
1148                 wep = WEP_FIRST;
1149                 while (wep <= WEP_LAST)
1150                 {
1151                         weapon_action(wep, WR_PRECACHE);
1152                         wep = wep + 1;
1153                 }
1154         }
1155
1156         // plays music for the level if there is any
1157         if (self.noise)
1158         {
1159                 precache_sound (self.noise);
1160                 ambientsound ('0 0 0', self.noise, 1.00, ATTN_NONE);
1161         }
1162 }