data/qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   7 void() spawnpoint_use;
   8 string ColoredTeamName(float t);
   9
  10 float RandomSelection_totalweight;
  11 float RandomSelection_best_priority;
  12 entity RandomSelection_chosen_ent;
  13 float RandomSelection_chosen_float;
  14 void RandomSelection_Init()
  15 {
  16         RandomSelection_totalweight = 0;
  17         RandomSelection_chosen_ent = world;
  18         RandomSelection_chosen_float = 0;
  19         RandomSelection_best_priority = -1;
  20 }
  21 void RandomSelection_Add(entity e, float f, float weight, float priority)
  22 {
  23         if(priority > RandomSelection_best_priority)
  24         {
  25                 RandomSelection_best_priority = priority;
  26                 RandomSelection_chosen_ent = e;
  27                 RandomSelection_chosen_float = f;
  28                 RandomSelection_totalweight = weight;
  29         }
  30         else if(priority == RandomSelection_best_priority)
  31         {
  32                 RandomSelection_totalweight += weight;
  33                 if(random() * RandomSelection_totalweight <= weight)
  34                 {
  35                         RandomSelection_chosen_ent = e;
  36                         RandomSelection_chosen_float = f;
  37                 }
  38         }
  39 }
  40
  41 float DistributeEvenly_amount;
  42 float DistributeEvenly_totalweight;
  43 void DistributeEvenly_Init(float amount, float totalweight)
  44 {
  45         if(DistributeEvenly_amount)
  46         {
  47                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  48                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  49         }
  50         if(totalweight == 0)
  51                 DistributeEvenly_amount = 0;
  52         else
  53                 DistributeEvenly_amount = amount;
  54         DistributeEvenly_totalweight = totalweight;
  55 }
  56 float DistributeEvenly_Get(float weight)
  57 {
  58         float f;
  59         if(weight <= 0)
  60                 return 0;
  61         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  62         DistributeEvenly_totalweight -= weight;
  63         DistributeEvenly_amount -= f;
  64         return f;
  65 }
  66
  67 void move_out_of_solid_expand(entity e, vector by)
  68 {
  69         float eps = 0.0625;
  70         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  71         if(trace_startsolid)
  72                 return;
  73         if(trace_fraction < 1)
  74         {
  75                 // hit something
  76                 // adjust origin in the other direction...
  77                 e.origin = e.origin - by * (1 - trace_fraction);
  78         }
  79 }
  80
  81 float move_out_of_solid(entity e)
  82 {
  83         vector o, m0, m1;
  84
  85         o = e.origin;
  86         traceline(o, o, MOVE_WORLDONLY, e);
  87         if(trace_startsolid)
  88                 return 0;
  89
  90         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  91         if(!trace_startsolid)
  92                 return 1;
  93
  94         m0 = e.mins;
  95         m1 = e.maxs;
  96         e.mins = '0 0 0';
  97         e.maxs = '0 0 0';
  98         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  99         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
 100         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
 101         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
 102         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
 103         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
 104         setorigin(e, e.origin);
 105
 106         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 107         if(trace_startsolid)
 108         {
 109                 setorigin(e, o);
 110                 return 0;
 111         }
 112
 113         return 1;
 114 }
 115
 116 string STR_PLAYER = "player";
 117 string STR_SPECTATOR = "spectator";
 118 string STR_OBSERVER = "observer";
 119
 120 #if 0
 121 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
 122 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 123 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
 124 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
 125 #else
 126 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
 127 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
 128 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 129 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
 130 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 131 #endif
 132
 133 // copies a string to a tempstring (so one can strunzone it)
 134 string strcat1(string s) = #115; // FRIK_FILE
 135
 136 float logfile_open;
 137 float logfile;
 138
 139 void bcenterprint(string s)
 140 {
 141         // TODO replace by MSG_ALL (would show it to spectators too, though)?
 142         entity head;
 143         FOR_EACH_PLAYER(head)
 144                 if(clienttype(head) == CLIENTTYPE_REAL)
 145                         centerprint(head, s);
 146 }
 147
 148 void GameLogEcho(string s)
 149 {
 150         string fn;
 151         float matches;
 152
 153         if(cvar("sv_eventlog_files"))
 154         {
 155                 if(!logfile_open)
 156                 {
 157                         logfile_open = TRUE;
 158                         matches = cvar("sv_eventlog_files_counter") + 1;
 159                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 160                         fn = ftos(matches);
 161                         if(strlen(fn) < 8)
 162                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 163                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 164                         logfile = fopen(fn, FILE_APPEND);
 165                         fputs(logfile, ":logversion:3\n");
 166                 }
 167                 if(logfile >= 0)
 168                 {
 169                         if(cvar("sv_eventlog_files_timestamps"))
 170                                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 171                         else
 172                                 fputs(logfile, strcat(s, "\n"));
 173                 }
 174         }
 175         if(cvar("sv_eventlog_console"))
 176         {
 177                 print(s, "\n");
 178         }
 179 }
 180
 181 void GameLogInit()
 182 {
 183         logfile_open = 0;
 184         // will be opened later
 185 }
 186
 187 void GameLogClose()
 188 {
 189         if(logfile_open && logfile >= 0)
 190         {
 191                 fclose(logfile);
 192                 logfile = -1;
 193         }
 194 }
 195
 196 float spawnpoint_nag;
 197 void relocate_spawnpoint()
 198 {
 199         // nudge off the floor
 200         setorigin(self, self.origin + '0 0 1');
 201
 202         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 203         if (trace_startsolid)
 204         {
 205                 vector o;
 206                 o = self.origin;
 207                 self.mins = PL_MIN;
 208                 self.maxs = PL_MAX;
 209                 if(!move_out_of_solid(self))
 210                         objerror("could not get out of solid at all!");
 211                 print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 212                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 213                 print(" ", ftos(self.origin_y - o_y));
 214                 print(" ", ftos(self.origin_z - o_z), "'\n");
 215                 if(cvar("g_spawnpoints_auto_move_out_of_solid"))
 216                 {
 217                         if(!spawnpoint_nag)
 218                                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 219                         spawnpoint_nag = 1;
 220                 }
 221                 else
 222                 {
 223                         self.origin = o;
 224                         self.mins = self.maxs = '0 0 0';
 225                         objerror("player spawn point in solid, mapper sucks!\n");
 226                         return;
 227                 }
 228         }
 229
 230         if(cvar("g_spawnpoints_autodrop"))
 231         {
 232                 setsize(self, PL_MIN, PL_MAX);
 233                 droptofloor();
 234         }
 235
 236         self.use = spawnpoint_use;
 237         self.team_saved = self.team;
 238         if(!self.cnt)
 239                 self.cnt = 1;
 240
 241         if(g_ctf || g_assault || g_onslaught || g_domination)
 242         if(self.team)
 243                 have_team_spawns = 1;
 244
 245         if(cvar("r_showbboxes"))
 246         {
 247                 // show where spawnpoints point at too
 248                 makevectors(self.angles);
 249                 entity e;
 250                 e = spawn();
 251                 e.classname = "info_player_foo";
 252                 setorigin(e, self.origin + v_forward * 24);
 253                 setsize(e, '-8 -8 -8', '8 8 8');
 254                 e.solid = SOLID_TRIGGER;
 255         }
 256 }
 257
 258 #define strstr strstrofs
 259 /*
 260 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 261 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 262 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 263 // BE CONSTANT OR strzoneD!
 264 float strstr(string haystack, string needle, float offset)
 265 {
 266         float len, endpos;
 267         string found;
 268         len = strlen(needle);
 269         endpos = strlen(haystack) - len;
 270         while(offset <= endpos)
 271         {
 272                 found = substring(haystack, offset, len);
 273                 if(found == needle)
 274                         return offset;
 275                 offset = offset + 1;
 276         }
 277         return -1;
 278 }
 279 */
 280
 281 float NUM_NEAREST_ENTITIES = 4;
 282 entity nearest_entity[NUM_NEAREST_ENTITIES];
 283 float nearest_length[NUM_NEAREST_ENTITIES];
 284 entity findnearest(vector point, .string field, string value, vector axismod)
 285 {
 286         entity localhead;
 287         float i;
 288         float j;
 289         float len;
 290         vector dist;
 291
 292         float num_nearest;
 293         num_nearest = 0;
 294
 295         localhead = find(world, field, value);
 296         while(localhead)
 297         {
 298                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 299                         dist = localhead.oldorigin;
 300                 else
 301                         dist = localhead.origin;
 302                 dist = dist - point;
 303                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 304                 len = vlen(dist);
 305
 306                 for(i = 0; i < num_nearest; ++i)
 307                 {
 308                         if(len < nearest_length[i])
 309                                 break;
 310                 }
 311
 312                 // now i tells us where to insert at
 313                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 314                 if(i < NUM_NEAREST_ENTITIES)
 315                 {
 316                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 317                         {
 318                                 nearest_length[j + 1] = nearest_length[j];
 319                                 nearest_entity[j + 1] = nearest_entity[j];
 320                         }
 321                         nearest_length[i] = len;
 322                         nearest_entity[i] = localhead;
 323                         if(num_nearest < NUM_NEAREST_ENTITIES)
 324                                 num_nearest = num_nearest + 1;
 325                 }
 326
 327                 localhead = find(localhead, field, value);
 328         }
 329
 330         // now use the first one from our list that we can see
 331         for(i = 0; i < num_nearest; ++i)
 332         {
 333                 traceline(point, nearest_entity[i].origin, TRUE, world);
 334                 if(trace_fraction == 1)
 335                 {
 336                         if(i != 0)
 337                         {
 338                                 dprint("Nearest point (");
 339                                 dprint(nearest_entity[0].netname);
 340                                 dprint(") is not visible, using a visible one.\n");
 341                         }
 342                         return nearest_entity[i];
 343                 }
 344         }
 345
 346         if(num_nearest == 0)
 347                 return world;
 348
 349         dprint("Not seeing any location point, using nearest as fallback.\n");
 350         /* DEBUGGING CODE:
 351         dprint("Candidates were: ");
 352         for(j = 0; j < num_nearest; ++j)
 353         {
 354                 if(j != 0)
 355                         dprint(", ");
 356                 dprint(nearest_entity[j].netname);
 357         }
 358         dprint("\n");
 359         */
 360
 361         return nearest_entity[0];
 362 }
 363
 364 void spawnfunc_target_location()
 365 {
 366         self.classname = "target_location";
 367         // location name in netname
 368         // eventually support: count, teamgame selectors, line of sight?
 369 };
 370
 371 void spawnfunc_info_location()
 372 {
 373         self.classname = "target_location";
 374         self.message = self.netname;
 375 };
 376
 377 string NearestLocation(vector p)
 378 {
 379         entity loc;
 380         string ret;
 381         ret = "somewhere";
 382         loc = findnearest(p, classname, "target_location", '1 1 1');
 383         if(loc)
 384         {
 385                 ret = loc.message;
 386         }
 387         else
 388         {
 389                 loc = findnearest(p, target, "###item###", '1 1 4');
 390                 if(loc)
 391                         ret = loc.netname;
 392         }
 393         return ret;
 394 }
 395
 396 string formatmessage(string msg)
 397 {
 398         float p, p1, p2;
 399         float n;
 400         string escape;
 401         string replacement;
 402         p = 0;
 403         n = 7;
 404         while(1)
 405         {
 406                 if(n < 1)
 407                         break; // too many replacements
 408                 n = n - 1;
 409                 p1 = strstr(msg, "%", p); // NOTE: this destroys msg as it's a tempstring!
 410                 p2 = strstr(msg, "\\", p); // NOTE: this destroys msg as it's a tempstring!
 411
 412                 if(p1 < 0)
 413                         p1 = p2;
 414                 if(p2 < 0)
 415                         p2 = p1;
 416                 p = min(p1, p2);
 417
 418                 if(p < 0)
 419                         break;
 420                 replacement = substring(msg, p, 2);
 421                 escape = substring(msg, p + 1, 1);
 422                 if(escape == "%")
 423                         replacement = "%";
 424                 else if(escape == "\\")
 425                         replacement = "\\";
 426                 else if(escape == "n")
 427                         replacement = "\n";
 428                 else if(escape == "a")
 429                         replacement = ftos(floor(self.armorvalue));
 430                 else if(escape == "h")
 431                         replacement = ftos(floor(self.health));
 432                 else if(escape == "l")
 433                         replacement = NearestLocation(self.origin);
 434                 else if(escape == "y")
 435                         replacement = NearestLocation(self.cursor_trace_endpos);
 436                 else if(escape == "d")
 437                         replacement = NearestLocation(self.death_origin);
 438                 else if(escape == "w")
 439                 {
 440                         float wep;
 441                         wep = self.weapon;
 442                         if(!wep)
 443                                 wep = self.switchweapon;
 444                         if(!wep)
 445                                 wep = self.cnt;
 446                         replacement = W_Name(wep);
 447                 }
 448                 else if(escape == "W")
 449                 {
 450                         if(self.items & IT_SHELLS) replacement = "shells";
 451                         else if(self.items & IT_NAILS) replacement = "bullets";
 452                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 453                         else if(self.items & IT_CELLS) replacement = "cells";
 454                         else replacement = "batteries"; // ;)
 455                 }
 456                 else if(escape == "x")
 457                 {
 458                         replacement = self.cursor_trace_ent.netname;
 459                         if(!replacement || !self.cursor_trace_ent)
 460                                 replacement = "nothing";
 461                 }
 462                 else if(escape == "p")
 463                 {
 464                         if(self.last_selected_player)
 465                                 replacement = self.last_selected_player.netname;
 466                         else
 467                                 replacement = "(nobody)";
 468                 }
 469                 msg = strcat(substring(msg, 0, p), replacement, substring(msg, p+2, strlen(msg) - (p+2)));
 470                 p = p + strlen(replacement);
 471         }
 472         return msg;
 473 }
 474
 475 /*
 476 =============
 477 GetCvars
 478 =============
 479 Called with:
 480   0:  sends the request
 481   >0: receives a cvar from name=argv(f) value=argv(f+1)
 482 */
 483 void GetCvars_handleString(string thisname, float f, .string field, string name)
 484 {
 485         if(f < 0)
 486         {
 487                 if(self.field)
 488                         strunzone(self.field);
 489                 self.field = string_null;
 490         }
 491         else if(f > 0)
 492         {
 493                 if(thisname == name)
 494                 {
 495                         if(self.field)
 496                                 strunzone(self.field);
 497                         self.field = strzone(argv(f + 1));
 498                 }
 499         }
 500         else
 501                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 502 }
 503 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 504 {
 505         GetCvars_handleString(thisname, f, field, name);
 506         if(f >= 0) // also initialize to the fitting value for "" when sending cvars out
 507         if(thisname == name)
 508         {
 509                 string s;
 510                 s = func(strcat1(self.field));
 511                 if(s != self.field)
 512                 {
 513                         strunzone(self.field);
 514                         self.field = strzone(s);
 515                 }
 516         }
 517 }
 518 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 519 {
 520         if(f < 0)
 521         {
 522         }
 523         else if(f > 0)
 524         {
 525                 if(thisname == name)
 526                         self.field = stof(argv(f + 1));
 527         }
 528         else
 529                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 530 }
 531 string W_FixWeaponOrder_ForceComplete(string s);
 532 string W_FixWeaponOrder_AllowIncomplete(string s);
 533 float w_getbestweapon(entity e);
 534 void GetCvars(float f)
 535 {
 536         string s;
 537         if(f > 0)
 538                 s = strcat1(argv(f));
 539         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 540         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 541         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 542         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 543         GetCvars_handleString(s, f, cvar_g_nexuizversion, "g_nexuizversion");
 544         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 553         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 554         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 555         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 556         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 557         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 558         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 559         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 560
 561         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 562         if(f > 0)
 563         {
 564                 if(s == "cl_weaponpriority")
 565                         self.switchweapon = w_getbestweapon(self);
 566         }
 567 }
 568
 569 float fexists(string f)
 570 {
 571         float fh;
 572         fh = fopen(f, FILE_READ);
 573         if(fh < 0)
 574                 return FALSE;
 575         fclose(fh);
 576         return TRUE;
 577 }
 578
 579 void backtrace(string msg)
 580 {
 581         float dev;
 582         dev = cvar("developer");
 583         cvar_set("developer", "1");
 584         dprint("\n");
 585         dprint("--- CUT HERE ---\nWARNING: ");
 586         dprint(msg);
 587         dprint("\n");
 588         remove(world); // isn't there any better way to cause a backtrace?
 589         dprint("\n--- CUT UNTIL HERE ---\n");
 590         cvar_set("developer", ftos(dev));
 591 }
 592
 593 string Team_ColorCode(float teamid)
 594 {
 595         if(teamid == COLOR_TEAM1)
 596                 return "^1";
 597         else if(teamid == COLOR_TEAM2)
 598                 return "^4";
 599         else if(teamid == COLOR_TEAM3)
 600                 return "^3";
 601         else if(teamid == COLOR_TEAM4)
 602                 return "^6";
 603         else
 604                 return "^7";
 605 }
 606 string Team_ColorName(float t)
 607 {
 608         // fixme: Search for team entities and get their .netname's!
 609         if(t == COLOR_TEAM1)
 610                 return "Red";
 611         if(t == COLOR_TEAM2)
 612                 return "Blue";
 613         if(t == COLOR_TEAM3)
 614                 return "Yellow";
 615         if(t == COLOR_TEAM4)
 616                 return "Pink";
 617         return "Neutral";
 618 }
 619 string Team_ColorNameLowerCase(float t)
 620 {
 621         // fixme: Search for team entities and get their .netname's!
 622         if(t == COLOR_TEAM1)
 623                 return "red";
 624         if(t == COLOR_TEAM2)
 625                 return "blue";
 626         if(t == COLOR_TEAM3)
 627                 return "yellow";
 628         if(t == COLOR_TEAM4)
 629                 return "pink";
 630         return "neutral";
 631 }
 632
 633 #define CENTERPRIO_POINT 1
 634 #define CENTERPRIO_SPAM 2
 635 #define CENTERPRIO_VOTE 4
 636 #define CENTERPRIO_NORMAL 5
 637 #define CENTERPRIO_SHIELDING 7
 638 #define CENTERPRIO_MAPVOTE 9
 639 #define CENTERPRIO_IDLEKICK 50
 640 #define CENTERPRIO_ADMIN 99
 641 .float centerprint_priority;
 642 .float centerprint_expires;
 643 void centerprint_atprio(entity e, float prio, string s)
 644 {
 645         if(intermission_running)
 646                 if(prio < CENTERPRIO_MAPVOTE)
 647                         return;
 648         if(time > e.centerprint_expires)
 649                 e.centerprint_priority = 0;
 650         if(prio >= e.centerprint_priority)
 651         {
 652                 e.centerprint_priority = prio;
 653                 if(timeoutStatus == 2)
 654                         e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 655                 else
 656                         e.centerprint_expires = time + e.cvar_scr_centertime;
 657                 centerprint_builtin(e, s);
 658         }
 659 }
 660 void centerprint_expire(entity e, float prio)
 661 {
 662         if(prio == e.centerprint_priority)
 663         {
 664                 e.centerprint_priority = 0;
 665                 centerprint_builtin(e, "");
 666         }
 667 }
 668 void centerprint(entity e, string s)
 669 {
 670         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 671 }
 672
 673 // decolorizes and team colors the player name when needed
 674 string playername(entity p)
 675 {
 676         string t;
 677         if(teams_matter && !intermission_running && p.classname == "player")
 678         {
 679                 t = Team_ColorCode(p.team);
 680                 return strcat(t, strdecolorize(p.netname));
 681         }
 682         else
 683                 return p.netname;
 684 }
 685
 686 vector randompos(vector m1, vector m2)
 687 {
 688         local vector v;
 689         m2 = m2 - m1;
 690         v_x = m2_x * random() + m1_x;
 691         v_y = m2_y * random() + m1_y;
 692         v_z = m2_z * random() + m1_z;
 693         return  v;
 694 };
 695
 696 float g_pickup_shells;
 697 float g_pickup_shells_max;
 698 float g_pickup_nails;
 699 float g_pickup_nails_max;
 700 float g_pickup_rockets;
 701 float g_pickup_rockets_max;
 702 float g_pickup_cells;
 703 float g_pickup_cells_max;
 704 float g_pickup_armorsmall;
 705 float g_pickup_armorsmall_max;
 706 float g_pickup_armormedium;
 707 float g_pickup_armormedium_max;
 708 float g_pickup_armorbig;
 709 float g_pickup_armorbig_max;
 710 float g_pickup_armorlarge;
 711 float g_pickup_armorlarge_max;
 712 float g_pickup_healthsmall;
 713 float g_pickup_healthsmall_max;
 714 float g_pickup_healthmedium;
 715 float g_pickup_healthmedium_max;
 716 float g_pickup_healthlarge;
 717 float g_pickup_healthlarge_max;
 718 float g_pickup_healthmega;
 719 float g_pickup_healthmega_max;
 720 float g_weaponarena;
 721 string g_weaponarena_list;
 722
 723 float start_weapons;
 724 float start_items;
 725 float start_ammo_shells;
 726 float start_ammo_nails;
 727 float start_ammo_rockets;
 728 float start_ammo_cells;
 729 float start_health;
 730 float start_armorvalue;
 731 float warmup_start_weapons;
 732 float warmup_start_ammo_shells;
 733 float warmup_start_ammo_nails;
 734 float warmup_start_ammo_rockets;
 735 float warmup_start_ammo_cells;
 736 float warmup_start_health;
 737 float warmup_start_armorvalue;
 738 float g_weapon_stay;
 739
 740 entity get_weaponinfo(float w);
 741
 742 void readplayerstartcvars()
 743 {
 744         entity e;
 745         float i, j, t;
 746         string s;
 747
 748         // initialize starting values for players
 749         start_weapons = 0;
 750         start_items = 0;
 751         start_ammo_shells = 0;
 752         start_ammo_nails = 0;
 753         start_ammo_rockets = 0;
 754         start_ammo_cells = 0;
 755         start_health = cvar("g_balance_health_start");
 756         start_armorvalue = cvar("g_balance_armor_start");
 757
 758         g_weaponarena = 0;
 759         s = cvar_string("g_weaponarena");
 760         if(s == "0")
 761         {
 762         }
 763         else if(s == "all")
 764         {
 765                 g_weaponarena_list = "All Weapons";
 766                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 767                 {
 768                         e = get_weaponinfo(j);
 769                         g_weaponarena |= e.weapons;
 770                         weapon_action(e.weapon, WR_PRECACHE);
 771                 }
 772         }
 773         else if(s == "most")
 774         {
 775                 g_weaponarena_list = "Most Weapons";
 776                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 777                 {
 778                         e = get_weaponinfo(j);
 779                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 780                         {
 781                                 g_weaponarena |= e.weapons;
 782                                 weapon_action(e.weapon, WR_PRECACHE);
 783                         }
 784                 }
 785         }
 786         else
 787         {
 788                 t = tokenize_sane(s);
 789                 g_weaponarena_list = "";
 790                 for(i = 0; i < t; ++i)
 791                 {
 792                         s = argv(i);
 793                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 794                         {
 795                                 e = get_weaponinfo(j);
 796                                 if(e.netname == s)
 797                                 {
 798                                         g_weaponarena |= e.weapons;
 799                                         weapon_action(e.weapon, WR_PRECACHE);
 800                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 801                                         break;
 802                                 }
 803                         }
 804                         if(j > WEP_LAST)
 805                         {
 806                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 807                         }
 808                 }
 809                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 810         }
 811
 812         if(g_weaponarena)
 813         {
 814                 start_weapons = g_weaponarena;
 815                 start_ammo_rockets = 999;
 816                 start_ammo_shells = 999;
 817                 start_ammo_cells = 999;
 818                 start_ammo_nails = 999;
 819                 start_items |= IT_UNLIMITED_AMMO;
 820         }
 821         else if(g_nixnex)
 822         {
 823                 start_weapons = 0;
 824                 // will be done later
 825                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 826                 {
 827                         e = get_weaponinfo(i);
 828                         if(!(e.weapon))
 829                                 continue;
 830                         weapon_action(e.weapon, WR_PRECACHE);
 831                 }
 832         }
 833         else if(g_minstagib)
 834         {
 835                 start_health = 100;
 836                 start_armorvalue = 0;
 837                 start_weapons = WEPBIT_MINSTANEX;
 838                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 839                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 840                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 841
 842                 if(g_minstagib_invis_alpha <= 0)
 843                         g_minstagib_invis_alpha = -1;
 844         }
 845         else
 846         {
 847                 if(g_lms)
 848                 {
 849                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 850                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 851                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 852                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 853                         start_health = cvar("g_lms_start_health");
 854                         start_armorvalue = cvar("g_lms_start_armor");
 855                 } else if (cvar("g_use_ammunition")) {
 856                         start_ammo_shells = cvar("g_start_ammo_shells");
 857                         start_ammo_nails = cvar("g_start_ammo_nails");
 858                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 859                         start_ammo_cells = cvar("g_start_ammo_cells");
 860                 } else {
 861                         start_ammo_shells = cvar("g_pickup_shells_max");
 862                         start_ammo_nails = cvar("g_pickup_nails_max");
 863                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 864                         start_ammo_cells = cvar("g_pickup_cells_max");
 865                         start_items |= IT_UNLIMITED_AMMO;
 866                 }
 867
 868                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 869                 {
 870                         e = get_weaponinfo(i);
 871                         if(!(e.weapon))
 872                                 continue;
 873
 874                         t = cvar(strcat("g_start_weapon_", e.netname));
 875
 876                         if(t < 0) // "default" weapon selection
 877                         {
 878                                 if(g_lms)
 879                                         t = (e.spawnflags & WEPSPAWNFLAG_NORMAL);
 880                                 else if(g_race)
 881                                         t = (i == WEP_LASER);
 882                                 else
 883                                         t = (i == WEP_LASER || i == WEP_SHOTGUN);
 884                                 if(g_grappling_hook) // if possible, redirect off-hand hook to on-hand hook
 885                                         t += (i == WEP_HOOK);
 886                         }
 887
 888                         if(t)
 889                         {
 890                                 start_weapons |= e.weapons;
 891                                 weapon_action(e.weapon, WR_PRECACHE);
 892                         }
 893                 }
 894         }
 895
 896         if(inWarmupStage)
 897         {
 898                 warmup_start_ammo_shells = start_ammo_shells;
 899                 warmup_start_ammo_nails = start_ammo_nails;
 900                 warmup_start_ammo_rockets = start_ammo_rockets;
 901                 warmup_start_ammo_cells = start_ammo_cells;
 902                 warmup_start_health = start_health;
 903                 warmup_start_armorvalue = start_armorvalue;
 904                 warmup_start_weapons = start_weapons;
 905
 906                 if(!g_weaponarena && !g_nixnex && !g_minstagib)
 907                 {
 908                         if(cvar("g_use_ammunition"))
 909                         {
 910                                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 911                                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 912                                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 913                                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 914                         }
 915                         warmup_start_health = cvar("g_warmup_start_health");
 916                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 917                         if(cvar("g_warmup_allguns"))
 918                         {
 919                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 920                                 {
 921                                         e = get_weaponinfo(i);
 922                                         if(!(e.weapon))
 923                                                 continue;
 924                                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 925                                         {
 926                                                 warmup_start_weapons |= e.weapons;
 927                                                 weapon_action(e.weapon, WR_PRECACHE);
 928                                         }
 929                                 }
 930                         }
 931                 }
 932         }
 933
 934         if(start_weapons & WEPBIT_HOOK)
 935         {
 936                 // can't have off-hand hook, if hook weapon is enabled
 937
 938                 // note: if g_grappling_hook is 1, also give some initial cells
 939                 if(g_grappling_hook)
 940                 {
 941                         if(!start_ammo_cells)
 942                                 start_ammo_cells = g_pickup_cells;
 943                         if(!warmup_start_ammo_cells)
 944                                 warmup_start_ammo_cells = g_pickup_cells;
 945                 }
 946
 947                 g_grappling_hook = 0;
 948         }
 949
 950         if(g_jetpack)
 951                 g_grappling_hook = 0; // these two can't coexist, as they use the same button
 952
 953         if(g_weapon_stay == 2)
 954         {
 955                 if(!start_ammo_shells) start_ammo_shells = g_pickup_shells;
 956                 if(!start_ammo_nails) start_ammo_nails = g_pickup_nails;
 957                 if(!start_ammo_cells) start_ammo_cells = g_pickup_cells;
 958                 if(!start_ammo_rockets) start_ammo_rockets = g_pickup_rockets;
 959                 if(!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
 960                 if(!warmup_start_ammo_nails) warmup_start_ammo_nails = g_pickup_nails;
 961                 if(!warmup_start_ammo_cells) warmup_start_ammo_cells = g_pickup_cells;
 962                 if(!warmup_start_ammo_rockets) warmup_start_ammo_rockets = g_pickup_rockets;
 963         }
 964
 965         start_ammo_shells = max(0, start_ammo_shells);
 966         start_ammo_nails = max(0, start_ammo_nails);
 967         start_ammo_cells = max(0, start_ammo_cells);
 968         start_ammo_rockets = max(0, start_ammo_rockets);
 969
 970         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 971         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 972         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 973         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 974 }
 975
 976 float g_bugrigs;
 977 float g_bugrigs_planar_movement;
 978 float g_bugrigs_planar_movement_car_jumping;
 979 float g_bugrigs_reverse_spinning;
 980 float g_bugrigs_reverse_speeding;
 981 float g_bugrigs_reverse_stopping;
 982 float g_bugrigs_air_steering;
 983 float g_bugrigs_angle_smoothing;
 984 float g_bugrigs_friction_floor;
 985 float g_bugrigs_friction_brake;
 986 float g_bugrigs_friction_air;
 987 float g_bugrigs_accel;
 988 float g_bugrigs_speed_ref;
 989 float g_bugrigs_speed_pow;
 990 float g_bugrigs_steer;
 991
 992 float g_touchexplode;
 993 float g_touchexplode_radius;
 994 float g_touchexplode_damage;
 995 float g_touchexplode_edgedamage;
 996 float g_touchexplode_force;
 997
 998 void readlevelcvars(void)
 999 {
1000         g_bugrigs = cvar("g_bugrigs");
1001         g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
1002         g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
1003         g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
1004         g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
1005         g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
1006         g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
1007         g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
1008         g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
1009         g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
1010         g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
1011         g_bugrigs_accel = cvar("g_bugrigs_accel");
1012         g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
1013         g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
1014         g_bugrigs_steer = cvar("g_bugrigs_steer");
1015
1016         g_touchexplode = cvar("g_touchexplode");
1017         g_touchexplode_radius = cvar("g_touchexplode_radius");
1018         g_touchexplode_damage = cvar("g_touchexplode_damage");
1019         g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
1020         g_touchexplode_force = cvar("g_touchexplode_force");
1021
1022         sv_clones = cvar("sv_clones");
1023         sv_cheats = cvar("sv_cheats");
1024         sv_gentle = cvar("sv_gentle");
1025         sv_foginterval = cvar("sv_foginterval");
1026         g_cloaked = cvar("g_cloaked");
1027         g_jump_grunt = cvar("g_jump_grunt");
1028         g_footsteps = cvar("g_footsteps");
1029         g_grappling_hook = cvar("g_grappling_hook");
1030         g_jetpack = cvar("g_jetpack");
1031         g_laserguided_missile = cvar("g_laserguided_missile");
1032         g_midair = cvar("g_midair");
1033         g_minstagib = cvar("g_minstagib");
1034         g_nixnex = cvar("g_nixnex");
1035         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
1036         g_norecoil = cvar("g_norecoil");
1037         g_vampire = cvar("g_vampire");
1038         g_bloodloss = cvar("g_bloodloss");
1039         sv_maxidle = cvar("sv_maxidle");
1040         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1041         sv_pogostick = cvar("sv_pogostick");
1042         sv_doublejump = cvar("sv_doublejump");
1043         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
1044         g_ctf_reverse = cvar("g_ctf_reverse");
1045
1046         inWarmupStage = cvar("g_warmup");
1047         g_warmup_limit = cvar("g_warmup_limit");
1048         g_warmup_allguns = cvar("g_warmup_allguns");
1049         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1050
1051         if(g_race && g_race_qualifying == 2 || g_arena || g_assault || cvar("g_campaign"))
1052                 inWarmupStage = 0; // these modes cannot work together, sorry
1053
1054         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1055         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1056         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1057         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1058         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1059         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1060
1061         if(g_minstagib) g_nixnex = g_weaponarena = 0;
1062         if(g_nixnex) g_weaponarena = 0;
1063         g_weaponarena = 0;
1064
1065         g_pickup_shells                    = cvar("g_pickup_shells");
1066         g_pickup_shells_max                = cvar("g_pickup_shells_max");
1067         g_pickup_nails                     = cvar("g_pickup_nails");
1068         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
1069         g_pickup_rockets                   = cvar("g_pickup_rockets");
1070         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
1071         g_pickup_cells                     = cvar("g_pickup_cells");
1072         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
1073         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
1074         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
1075         g_pickup_armormedium               = cvar("g_pickup_armormedium");
1076         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
1077         g_pickup_armorbig                  = cvar("g_pickup_armorbig");
1078         g_pickup_armorbig_max              = cvar("g_pickup_armorbig_max");
1079         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
1080         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
1081         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
1082         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
1083         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
1084         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
1085         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
1086         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
1087         g_pickup_healthmega                = cvar("g_pickup_healthmega");
1088         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
1089
1090         g_pinata = cvar("g_pinata");
1091
1092         g_weapon_stay = cvar("g_weapon_stay");
1093         if(!g_weapon_stay && (cvar("deathmatch") == 2))
1094                 g_weapon_stay = 1;
1095
1096         if not(inWarmupStage)
1097                 game_starttime                 = cvar("g_start_delay");
1098
1099         readplayerstartcvars();
1100 }
1101
1102 /*
1103 // TODO sound pack system
1104 string soundpack;
1105
1106 string precache_sound_builtin (string s) = #19;
1107 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1108 string precache_sound(string s)
1109 {
1110         return precache_sound_builtin(strcat(soundpack, s));
1111 }
1112 void play2(entity e, string filename)
1113 {
1114         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1115 }
1116 void sound(entity e, float chan, string samp, float vol, float atten)
1117 {
1118         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1119 }
1120 */
1121
1122 // Sound functions
1123 string precache_sound (string s) = #19;
1124 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
1125 float precache_sound_index (string s) = #19;
1126
1127 #define SND_VOLUME      1
1128 #define SND_ATTENUATION 2
1129 #define SND_LARGEENTITY 8
1130 #define SND_LARGESOUND  16
1131
1132 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1133 {
1134         float entno, idx;
1135         entno = num_for_edict(e);
1136         idx = precache_sound_index(samp);
1137
1138         float sflags;
1139         sflags = 0;
1140
1141         atten = floor(atten * 64);
1142         vol = floor(vol * 255);
1143
1144         if(vol != 255)
1145                 sflags |= SND_VOLUME;
1146         if(atten != 64)
1147                 sflags |= SND_ATTENUATION;
1148         if(entno >= 8192)
1149                 sflags |= SND_LARGEENTITY;
1150         if(idx >= 256)
1151                 sflags |= SND_LARGESOUND;
1152
1153         WriteByte(dest, SVC_SOUND);
1154         WriteByte(dest, sflags);
1155         if(sflags & SND_VOLUME)
1156                 WriteByte(dest, vol * 255);
1157         if(sflags & SND_ATTENUATION)
1158                 WriteByte(dest, atten);
1159         if(sflags & SND_LARGEENTITY)
1160         {
1161                 WriteShort(dest, entno);
1162                 WriteByte(dest, chan);
1163         }
1164         else
1165         {
1166                 WriteShort(dest, entno * 8 + chan);
1167         }
1168         if(sflags & SND_LARGESOUND)
1169                 WriteShort(dest, idx);
1170         else
1171                 WriteByte(dest, idx);
1172
1173         WriteCoord(dest, o_x);
1174         WriteCoord(dest, o_y);
1175         WriteCoord(dest, o_z);
1176 }
1177 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1178 {
1179         vector o;
1180         o = e.origin + 0.5 * (e.mins + e.maxs);
1181         soundtoat(dest, e, o, chan, samp, vol, atten);
1182 }
1183 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1184 {
1185         soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1186 }
1187 void stopsoundto(float dest, entity e, float chan)
1188 {
1189         float entno;
1190         entno = num_for_edict(e);
1191
1192         if(entno >= 8192)
1193         {
1194                 float idx, sflags;
1195                 idx = precache_sound_index("misc/null.wav");
1196                 sflags = SND_LARGEENTITY;
1197                 if(idx >= 256)
1198                         sflags |= SND_LARGESOUND;
1199                 WriteByte(dest, SVC_SOUND);
1200                 WriteByte(dest, sflags);
1201                 WriteShort(dest, entno);
1202                 WriteByte(dest, chan);
1203                 if(sflags & SND_LARGESOUND)
1204                         WriteShort(dest, idx);
1205                 else
1206                         WriteByte(dest, idx);
1207                 WriteCoord(dest, e.origin_x);
1208                 WriteCoord(dest, e.origin_y);
1209                 WriteCoord(dest, e.origin_z);
1210         }
1211         else
1212         {
1213                 WriteByte(dest, SVC_STOPSOUND);
1214                 WriteShort(dest, entno * 8 + chan);
1215         }
1216 }
1217 void stopsound(entity e, float chan)
1218 {
1219         stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1220         stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1221 }
1222
1223 void play2(entity e, string filename)
1224 {
1225         //stuffcmd(e, strcat("play2 ", filename, "\n"));
1226         msg_entity = e;
1227         soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1228 }
1229
1230 .float announcetime;
1231 float announce(entity player, string msg)
1232 {
1233         if(time > player.announcetime)
1234         if(clienttype(player) == CLIENTTYPE_REAL)
1235         {
1236                 player.announcetime = time + 0.8;
1237                 play2(player, msg);
1238                 return TRUE;
1239         }
1240         return FALSE;
1241 }
1242
1243 void play2team(float t, string filename)
1244 {
1245         local entity head;
1246         FOR_EACH_REALPLAYER(head)
1247         {
1248                 if (head.team == t)
1249                         play2(head, filename);
1250         }
1251 }
1252
1253 void play2all(string samp)
1254 {
1255         sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1256 }
1257
1258 void PrecachePlayerSounds(string f);
1259 void precache_all_models(string pattern)
1260 {
1261         float globhandle, i, n;
1262         string f;
1263
1264         globhandle = search_begin(pattern, TRUE, FALSE);
1265         if(globhandle < 0)
1266                 return;
1267         n = search_getsize(globhandle);
1268         for(i = 0; i < n; ++i)
1269         {
1270                 //print(search_getfilename(globhandle, i), "\n");
1271                 f = search_getfilename(globhandle, i);
1272                 precache_model(f);
1273                 PrecachePlayerSounds(strcat(f, ".sounds"));
1274         }
1275         search_end(globhandle);
1276 }
1277
1278 void precache()
1279 {
1280         // gamemode related things
1281         precache_model ("models/misc/chatbubble.spr");
1282         precache_model ("models/misc/teambubble.spr");
1283         if (g_runematch)
1284         {
1285                 precache_model ("models/runematch/curse.mdl");
1286                 precache_model ("models/runematch/rune.mdl");
1287         }
1288
1289 #ifdef TTURRETS_ENABLED
1290     if(cvar("g_turrets"))
1291         turrets_precash();
1292 #endif
1293
1294         // Precache all player models if desired
1295         if (cvar("sv_precacheplayermodels"))
1296         {
1297                 PrecachePlayerSounds("sound/player/default.sounds");
1298                 precache_all_models("models/player/*.zym");
1299                 precache_all_models("models/player/*.dpm");
1300                 precache_all_models("models/player/*.md3");
1301                 precache_all_models("models/player/*.psk");
1302                 //precache_model("models/player/carni.zym");
1303                 //precache_model("models/player/crash.zym");
1304                 //precache_model("models/player/grunt.zym");
1305                 //precache_model("models/player/headhunter.zym");
1306                 //precache_model("models/player/insurrectionist.zym");
1307                 //precache_model("models/player/jeandarc.zym");
1308                 //precache_model("models/player/lurk.zym");
1309                 //precache_model("models/player/lycanthrope.zym");
1310                 //precache_model("models/player/marine.zym");
1311                 //precache_model("models/player/nexus.zym");
1312                 //precache_model("models/player/pyria.zym");
1313                 //precache_model("models/player/shock.zym");
1314                 //precache_model("models/player/skadi.zym");
1315                 //precache_model("models/player/specop.zym");
1316                 //precache_model("models/player/visitant.zym");
1317         }
1318
1319         if(cvar("sv_defaultcharacter"))
1320         {
1321                 string s;
1322                 s = cvar_string("sv_defaultplayermodel_red");
1323                 if(s != "")
1324                 {
1325                         precache_model(s);
1326                         PrecachePlayerSounds(strcat(s, ".sounds"));
1327                 }
1328                 s = cvar_string("sv_defaultplayermodel_blue");
1329                 if(s != "")
1330                 {
1331                         precache_model(s);
1332                         PrecachePlayerSounds(strcat(s, ".sounds"));
1333                 }
1334                 s = cvar_string("sv_defaultplayermodel_yellow");
1335                 if(s != "")
1336                 {
1337                         precache_model(s);
1338                         PrecachePlayerSounds(strcat(s, ".sounds"));
1339                 }
1340                 s = cvar_string("sv_defaultplayermodel_pink");
1341                 if(s != "")
1342                 {
1343                         precache_model(s);
1344                         PrecachePlayerSounds(strcat(s, ".sounds"));
1345                 }
1346                 s = cvar_string("sv_defaultplayermodel");
1347                 if(s != "")
1348                 {
1349                         precache_model(s);
1350                         PrecachePlayerSounds(strcat(s, ".sounds"));
1351                 }
1352         }
1353
1354         if (g_footsteps)
1355         {
1356                 PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1357                 PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1358         }
1359
1360         // gore and miscellaneous sounds
1361         //precache_sound ("misc/h2ohit.wav");
1362         precache_model ("models/hook.md3");
1363         precache_sound ("misc/armorimpact.wav");
1364         precache_sound ("misc/bodyimpact1.wav");
1365         precache_sound ("misc/bodyimpact2.wav");
1366         precache_sound ("misc/gib.wav");
1367         precache_sound ("misc/gib_splat01.wav");
1368         precache_sound ("misc/gib_splat02.wav");
1369         precache_sound ("misc/gib_splat03.wav");
1370         precache_sound ("misc/gib_splat04.wav");
1371         precache_sound ("misc/hit.wav");
1372         PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1373         PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1374         precache_sound ("misc/null.wav");
1375         precache_sound ("misc/spawn.wav");
1376         precache_sound ("misc/talk.wav");
1377         precache_sound ("misc/teleport.wav");
1378         precache_sound ("player/lava.wav");
1379         precache_sound ("player/slime.wav");
1380
1381         // announcer sounds - male
1382         precache_sound ("announcer/male/electrobitch.wav");
1383         precache_sound ("announcer/male/airshot.wav");
1384         precache_sound ("announcer/male/03kills.wav");
1385         precache_sound ("announcer/male/05kills.wav");
1386         precache_sound ("announcer/male/10kills.wav");
1387         precache_sound ("announcer/male/15kills.wav");
1388         precache_sound ("announcer/male/20kills.wav");
1389         precache_sound ("announcer/male/25kills.wav");
1390         precache_sound ("announcer/male/30kills.wav");
1391         precache_sound ("announcer/male/botlike.wav");
1392         precache_sound ("announcer/male/yoda.wav");
1393         precache_sound ("announcer/male/headshot.wav");
1394         precache_sound ("announcer/male/impressive.wav");
1395
1396         // announcer sounds - robotic
1397         precache_sound ("announcer/robotic/prepareforbattle.wav");
1398         precache_sound ("announcer/robotic/begin.wav");
1399         precache_sound ("announcer/robotic/timeoutcalled.wav");
1400         precache_sound ("announcer/robotic/1fragleft.wav");
1401         precache_sound ("announcer/robotic/1minuteremains.wav");
1402         precache_sound ("announcer/robotic/2fragsleft.wav");
1403         precache_sound ("announcer/robotic/3fragsleft.wav");
1404         if (g_minstagib)
1405         {
1406                 precache_sound ("announcer/robotic/lastsecond.wav");
1407                 precache_sound ("announcer/robotic/narrowly.wav");
1408         }
1409
1410         precache_model ("models/sprites/1.spr32");
1411         precache_model ("models/sprites/2.spr32");
1412         precache_model ("models/sprites/3.spr32");
1413         precache_model ("models/sprites/4.spr32");
1414         precache_model ("models/sprites/5.spr32");
1415         precache_model ("models/sprites/6.spr32");
1416         precache_model ("models/sprites/7.spr32");
1417         precache_model ("models/sprites/8.spr32");
1418         precache_model ("models/sprites/9.spr32");
1419         precache_model ("models/sprites/10.spr32");
1420         precache_sound ("announcer/robotic/1.wav");
1421         precache_sound ("announcer/robotic/2.wav");
1422         precache_sound ("announcer/robotic/3.wav");
1423         precache_sound ("announcer/robotic/4.wav");
1424         precache_sound ("announcer/robotic/5.wav");
1425         precache_sound ("announcer/robotic/6.wav");
1426         precache_sound ("announcer/robotic/7.wav");
1427         precache_sound ("announcer/robotic/8.wav");
1428         precache_sound ("announcer/robotic/9.wav");
1429         precache_sound ("announcer/robotic/10.wav");
1430
1431         // common weapon precaches
1432         precache_sound ("weapons/weapon_switch.wav");
1433         precache_sound ("weapons/weaponpickup.wav");
1434         if(g_grappling_hook)
1435         {
1436                 precache_sound ("weapons/hook_fire.wav"); // hook
1437                 precache_sound ("weapons/hook_impact.wav"); // hook
1438         }
1439
1440         if (cvar("sv_precacheweapons") || g_nixnex)
1441         {
1442                 //precache weapon models/sounds
1443                 local float wep;
1444                 wep = WEP_FIRST;
1445                 while (wep <= WEP_LAST)
1446                 {
1447                         weapon_action(wep, WR_PRECACHE);
1448                         wep = wep + 1;
1449                 }
1450         }
1451
1452         precache_model("models/elaser.mdl");
1453         precache_model("models/laser.mdl");
1454         precache_model("models/ebomb.mdl");
1455
1456 #if 0
1457         // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1458
1459         if (!self.noise && self.music) // quake 3 uses the music field
1460                 self.noise = self.music;
1461
1462         // plays music for the level if there is any
1463         if (self.noise)
1464         {
1465                 precache_sound (self.noise);
1466                 ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1467         }
1468 #endif
1469 }
1470
1471 // sorry, but using \ in macros breaks line numbers
1472 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1473 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1474 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1475
1476 vector ExactTriggerHit_mins;
1477 vector ExactTriggerHit_maxs;
1478 float ExactTriggerHit_Recurse()
1479 {
1480         float s;
1481         entity se;
1482         float f;
1483
1484         tracebox('0 0 0', ExactTriggerHit_mins, ExactTriggerHit_maxs, '0 0 0', MOVE_NORMAL, other);
1485         if not(trace_ent)
1486                 return 0;
1487         if(trace_ent == self)
1488                 return 1;
1489
1490         se = trace_ent;
1491         s = se.solid;
1492         se.solid = SOLID_NOT;
1493         f = ExactTriggerHit_Recurse();
1494         se.solid = s;
1495
1496         return f;
1497 }
1498
1499 float ExactTriggerHit()
1500 {
1501         float f, s;
1502
1503         if not(self.modelindex)
1504                 return 1;
1505
1506         s = self.solid;
1507         self.solid = SOLID_BSP;
1508         ExactTriggerHit_mins = other.absmin;
1509         ExactTriggerHit_maxs = other.absmax;
1510         f = ExactTriggerHit_Recurse();
1511         self.solid = s;
1512
1513         return f;
1514 }
1515
1516 // WARNING: this kills the trace globals
1517 #define EXACTTRIGGER_TOUCH if not(ExactTriggerHit()) return
1518 #define EXACTTRIGGER_INIT  InitSolidBSPTrigger(); self.solid = SOLID_TRIGGER
1519
1520 #define INITPRIO_FIRST              0
1521 #define INITPRIO_GAMETYPE           0
1522 #define INITPRIO_GAMETYPE_FALLBACK  1
1523 #define INITPRIO_CVARS              5
1524 #define INITPRIO_FINDTARGET        10
1525 #define INITPRIO_DROPTOFLOOR       20
1526 #define INITPRIO_SETLOCATION       90
1527 #define INITPRIO_LINKDOORS         91
1528 #define INITPRIO_LAST              99
1529
1530 .void(void) initialize_entity;
1531 .float initialize_entity_order;
1532 .entity initialize_entity_next;
1533 entity initialize_entity_first;
1534
1535 void make_safe_for_remove(entity e)
1536 {
1537         if(e.initialize_entity)
1538         {
1539                 entity ent, prev;
1540                 for(ent = initialize_entity_first; ent; )
1541                 {
1542                         if((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1543                         {
1544                                 //print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1545                                 // skip it in linked list
1546                                 if(prev)
1547                                 {
1548                                         prev.initialize_entity_next = ent.initialize_entity_next;
1549                                         ent = prev.initialize_entity_next;
1550                                 }
1551                                 else
1552                                 {
1553                                         initialize_entity_first = ent.initialize_entity_next;
1554                                         ent = initialize_entity_first;
1555                                 }
1556                         }
1557                         else
1558                         {
1559                                 prev = ent;
1560                                 ent = ent.initialize_entity_next;
1561                         }
1562                 }
1563         }
1564 }
1565
1566 void objerror(string s)
1567 {
1568         make_safe_for_remove(self);
1569         objerror_builtin(s);
1570 }
1571
1572 void remove_unsafely(entity e)
1573 {
1574         remove_builtin(e);
1575 }
1576
1577 void remove_safely(entity e)
1578 {
1579         make_safe_for_remove(e);
1580         remove_builtin(e);
1581 }
1582
1583 void InitializeEntity(entity e, void(void) func, float order)
1584 {
1585         entity prev, cur;
1586
1587         if(!e || e.initialize_entity)
1588         {
1589                 // make a proxy initializer entity
1590                 entity e_old;
1591                 e_old = e;
1592                 e = spawn();
1593                 e.classname = "initialize_entity";
1594                 e.enemy = e_old;
1595         }
1596
1597         e.initialize_entity = func;
1598         e.initialize_entity_order = order;
1599
1600         cur = initialize_entity_first;
1601         for(;;)
1602         {
1603                 if(!cur || cur.initialize_entity_order > order)
1604                 {
1605                         // insert between prev and cur
1606                         if(prev)
1607                                 prev.initialize_entity_next = e;
1608                         else
1609                                 initialize_entity_first = e;
1610                         e.initialize_entity_next = cur;
1611                         return;
1612                 }
1613                 prev = cur;
1614                 cur = cur.initialize_entity_next;
1615         }
1616 }
1617 void InitializeEntitiesRun()
1618 {
1619         entity startoflist;
1620         startoflist = initialize_entity_first;
1621         initialize_entity_first = world;
1622         for(self = startoflist; self; )
1623         {
1624                 entity e;
1625                 var void(void) func;
1626                 e = self.initialize_entity_next;
1627                 func = self.initialize_entity;
1628                 self.initialize_entity_order = 0;
1629                 self.initialize_entity = func_null;
1630                 self.initialize_entity_next = world;
1631                 if(self.classname == "initialize_entity")
1632                 {
1633                         entity e_old;
1634                         e_old = self.enemy;
1635                         remove_builtin(self);
1636                         self = e_old;
1637                 }
1638                 //dprint("Delayed initialization: ", self.classname, "\n");
1639                 func();
1640                 self = e;
1641         }
1642 }
1643
1644 .float uncustomizeentityforclient_set;
1645 .void(void) uncustomizeentityforclient;
1646 void(void) SUB_Nullpointer = #0;
1647 void UncustomizeEntitiesRun()
1648 {
1649         entity oldself;
1650         oldself = self;
1651         for(self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1652                 self.uncustomizeentityforclient();
1653         self = oldself;
1654 }
1655 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1656 {
1657         e.customizeentityforclient = customizer;
1658         e.uncustomizeentityforclient = uncustomizer;
1659         e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1660 }
1661
1662 .float nottargeted;
1663 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1664
1665 void() SUB_Remove;
1666 void Net_LinkEntity(entity e, float docull, float dt, float(entity, float) sendfunc)
1667 {
1668         vector mi, ma;
1669
1670         if(e.classname == "")
1671                 e.classname = "net_linked";
1672
1673         if(e.model == "" || self.modelindex == 0)
1674         {
1675                 mi = e.mins;
1676                 ma = e.maxs;
1677                 setmodel(e, "null");
1678                 setsize(e, mi, ma);
1679         }
1680
1681         e.SendEntity = sendfunc;
1682         e.SendFlags = 0xFFFFFF;
1683
1684         if(!docull)
1685                 e.effects |= EF_NODEPTHTEST;
1686
1687         if(dt)
1688         {
1689                 e.nextthink = time + dt;
1690                 e.think = SUB_Remove;
1691         }
1692 }
1693
1694 void adaptor_think2touch()
1695 {
1696         entity o;
1697         o = other;
1698         other = world;
1699         self.touch();
1700         other = o;
1701 }
1702
1703 void adaptor_think2use()
1704 {
1705         entity o, a;
1706         o = other;
1707         a = activator;
1708         activator = world;
1709         other = world;
1710         self.use();
1711         other = o;
1712         activator = a;
1713 }
1714
1715 // deferred dropping
1716 void DropToFloor_Handler()
1717 {
1718         droptofloor_builtin();
1719         self.dropped_origin = self.origin;
1720 }
1721
1722 void droptofloor()
1723 {
1724         InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1725 }
1726
1727
1728
1729 float trace_hits_box_a0, trace_hits_box_a1;
1730
1731 float trace_hits_box_1d(float end, float thmi, float thma)
1732 {
1733         if(end == 0)
1734         {
1735                 // just check if x is in range
1736                 if(0 < thmi)
1737                         return FALSE;
1738                 if(0 > thma)
1739                         return FALSE;
1740         }
1741         else
1742         {
1743                 // do the trace with respect to x
1744                 // 0 -> end has to stay in thmi -> thma
1745                 trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1746                 trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1747                 if(trace_hits_box_a0 > trace_hits_box_a1)
1748                         return FALSE;
1749         }
1750         return TRUE;
1751 }
1752
1753 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1754 {
1755         end -= start;
1756         thmi -= start;
1757         thma -= start;
1758         // now it is a trace from 0 to end
1759
1760         trace_hits_box_a0 = 0;
1761         trace_hits_box_a1 = 1;
1762
1763         if(!trace_hits_box_1d(end_x, thmi_x, thma_x))
1764                 return FALSE;
1765         if(!trace_hits_box_1d(end_y, thmi_y, thma_y))
1766                 return FALSE;
1767         if(!trace_hits_box_1d(end_z, thmi_z, thma_z))
1768                 return FALSE;
1769
1770         return TRUE;
1771 }
1772
1773 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1774 {
1775         return trace_hits_box(start, end, thmi - ma, thma - mi);
1776 }
1777
1778 float SUB_NoImpactCheck()
1779 {
1780         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1781                 return 1;
1782         if(other == world && self.size != '0 0 0')
1783         {
1784                 vector tic;
1785                 tic = self.velocity * sys_ticrate;
1786                 tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1787                 traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1788                 if(trace_fraction >= 1)
1789                 {
1790                         dprint("Odd... did not hit...?\n");
1791                 }
1792                 else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1793                 {
1794                         dprint("Detected and prevented the sky-grapple bug.\n");
1795                         return 1;
1796                 }
1797         }
1798
1799         return 0;
1800 }
1801
1802 #define SUB_OwnerCheck() (other && (other == self.owner))
1803
1804 #define PROJECTILE_TOUCH do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { remove(self); return; } if(trace_ent && trace_ent.solid > SOLID_TRIGGER) UpdateCSQCProjectileNextFrame(self); } while(0)
1805
1806 float MAX_IPBAN_URIS = 16;
1807
1808 float URI_GET_DISCARD   = 0;
1809 float URI_GET_IPBAN     = 1;
1810 float URI_GET_IPBAN_END = 16;
1811
1812 void URI_Get_Callback(float id, float status, string data)
1813 {
1814         dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is\n:");
1815         dprint(data);
1816         dprint("\nEnd of data.\n");
1817
1818         if(id == URI_GET_DISCARD)
1819         {
1820                 // discard
1821         }
1822         else if(id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1823         {
1824                 // online ban list
1825                 OnlineBanList_URI_Get_Callback(id, status, data);
1826         }
1827         else
1828         {
1829                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1830         }
1831 }
1832
1833 void print_to(entity e, string s)
1834 {
1835         if(e)
1836                 sprint(e, strcat(s, "\n"));
1837         else
1838                 print(s, "\n");
1839 }
1840
1841 string getrecords()
1842 {
1843         float rec;
1844         string h;
1845         float r;
1846         float i;
1847         string s;
1848
1849         rec = 0;
1850
1851         s = "";
1852
1853         if(g_ctf)
1854         {
1855                 for(i = 0; i < MapInfo_count; ++i)
1856                 {
1857                         if(MapInfo_Get_ByID(i))
1858                         {
1859                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
1860                                 if(r == 0)
1861                                         continue;
1862                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
1863                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
1864                                 ++rec;
1865                         }
1866                 }
1867         }
1868
1869         if(g_race)
1870         {
1871                 for(i = 0; i < MapInfo_count; ++i)
1872                 {
1873                         if(MapInfo_Get_ByID(i))
1874                         {
1875                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/time")));
1876                                 if(r == 0)
1877                                         continue;
1878                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/netname"));
1879                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, mmsss(r)), " ", h, "\n");
1880                                 ++rec;
1881                         }
1882                 }
1883         }
1884         MapInfo_ClearTemps();
1885
1886         if(s == "")
1887                 return "No records are available on this server.\n";
1888         else
1889                 return strcat("Records on this server:\n", s);
1890 }
1891
1892 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1893 {
1894         float m, i;
1895         vector start, org, delta, end, enddown, mstart;
1896
1897         m = e.dphitcontentsmask;
1898         e.dphitcontentsmask = goodcontents | badcontents;
1899
1900         org = world.mins;
1901         delta = world.maxs - world.mins;
1902
1903         for(i = 0; i < attempts; ++i)
1904         {
1905                 start_x = org_x + random() * delta_x;
1906                 start_y = org_y + random() * delta_y;
1907                 start_z = org_z + random() * delta_z;
1908
1909                 // rule 1: start inside world bounds, and outside
1910                 // solid, and don't start from somewhere where you can
1911                 // fall down to evil
1912                 tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta_z, MOVE_NORMAL, e);
1913                 if(trace_fraction >= 1)
1914                         continue;
1915                 if(trace_startsolid)
1916                         continue;
1917                 if(trace_dphitcontents & badcontents)
1918                         continue;
1919                 if(trace_dphitq3surfaceflags & badsurfaceflags)
1920                         continue;
1921
1922                 // rule 2: if we are too high, lower the point
1923                 if(trace_fraction * delta_z > maxaboveground)
1924                         start = trace_endpos + '0 0 1' * maxaboveground;
1925                 enddown = trace_endpos;
1926
1927                 // rule 3: make sure we aren't outside the map. This only works
1928                 // for somewhat well formed maps. A good rule of thumb is that
1929                 // the map should have a convex outside hull.
1930                 // these can be traceLINES as we already verified the starting box
1931                 mstart = start + 0.5 * (e.mins + e.maxs);
1932                 traceline(mstart, mstart + '1 0 0' * delta_x, MOVE_NORMAL, e);
1933                 if(trace_fraction >= 1)
1934                         continue;
1935                 traceline(mstart, mstart - '1 0 0' * delta_x, MOVE_NORMAL, e);
1936                 if(trace_fraction >= 1)
1937                         continue;
1938                 traceline(mstart, mstart + '0 1 0' * delta_y, MOVE_NORMAL, e);
1939                 if(trace_fraction >= 1)
1940                         continue;
1941                 traceline(mstart, mstart - '0 1 0' * delta_y, MOVE_NORMAL, e);
1942                 if(trace_fraction >= 1)
1943                         continue;
1944                 traceline(mstart, mstart + '0 0 1' * delta_z, MOVE_NORMAL, e);
1945                 if(trace_fraction >= 1)
1946                         continue;
1947
1948                 // find a random vector to "look at"
1949                 end_x = org_x + random() * delta_x;
1950                 end_y = org_y + random() * delta_y;
1951                 end_z = org_z + random() * delta_z;
1952                 end = start + normalize(end - start) * vlen(delta);
1953
1954                 // rule 4: start TO end must not be too short
1955                 tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1956                 if(trace_startsolid)
1957                         continue;
1958                 if(trace_fraction < minviewdistance / vlen(delta))
1959                         continue;
1960
1961                 // rule 5: don't want to look at sky
1962                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1963                         continue;
1964
1965                 // rule 6: we must not end up in trigger_hurt
1966                 if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1967                 {
1968                         dprint("trigger_hurt! ouch! and nothing else could find it!\n");
1969                         continue;
1970                 }
1971
1972                 break;
1973         }
1974
1975         e.dphitcontentsmask = m;
1976
1977         if(i < attempts)
1978         {
1979                 setorigin(e, start);
1980                 e.angles = vectoangles(end - start);
1981                 dprint("Needed ", ftos(i + 1), " attempts\n");
1982                 return TRUE;
1983         }
1984         else
1985                 return FALSE;
1986 }
1987
1988 void zcurveparticles(float effectno, vector start, vector end, float end_dz, float spd)
1989 {
1990         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
1991         WriteByte(MSG_BROADCAST, TE_CSQC_ZCURVEPARTICLES);
1992         WriteShort(MSG_BROADCAST, effectno);
1993         WriteCoord(MSG_BROADCAST, start_x);
1994         WriteCoord(MSG_BROADCAST, start_y);
1995         WriteCoord(MSG_BROADCAST, start_z);
1996         WriteCoord(MSG_BROADCAST, end_x);
1997         WriteCoord(MSG_BROADCAST, end_y);
1998         WriteCoord(MSG_BROADCAST, end_z);
1999         WriteCoord(MSG_BROADCAST, end_dz);
2000         WriteShort(MSG_BROADCAST, spd / 16);
2001 }
2002
2003 void zcurveparticles_from_tracetoss(float effectno, vector start, vector end, vector vel)
2004 {
2005         float end_dz;
2006         vector vecxy, velxy;
2007
2008         vecxy = end - start; vecxy_z = 0;
2009         velxy = vel;         velxy_z = 0;
2010
2011         if(vlen(velxy) < 0.000001 * fabs(vel_z))
2012         {
2013                 trailparticles(world, effectno, start, end);
2014                 return;
2015         }
2016
2017         end_dz = vlen(vecxy) / vlen(velxy) * vel_z - (end_z - start_z);
2018         zcurveparticles(effectno, start, end, end_dz, vlen(vel));
2019 }
2020
2021 string GetGametype(); // g_world.qc
2022 void write_recordmarker(entity pl, float tstart, float dt)
2023 {
2024         GameLogEcho(strcat(":recordset:", ftos(pl.playerid), ":", ftos(dt / 10)));
2025
2026         // also write a marker into demo files for demotc-race-record-extractor to find
2027         stuffcmd(pl,
2028                 strcat(
2029                         strcat("//", strconv(2, 0, 0, GetGametype()), " RECORD SET ", mmsss(dt * 10)),
2030                         " ", ftos(tstart), " ", ftos(dt), "\n"));
2031 }
2032
2033 vector shotorg_adjust(vector vecs, float y_is_right, float visual)
2034 {
2035         if (cvar("g_shootfromeye"))
2036         {
2037                 if(visual)
2038                 {
2039                         vecs_y = 0;
2040                         vecs_z -= 4;
2041                 }
2042                 else
2043                 {
2044                         vecs_y = 0;
2045                         vecs_z = 0;
2046                 }
2047         }
2048         else if (cvar("g_shootfromcenter"))
2049         {
2050                 vecs_y = 0;
2051                 vecs_z -= 4;
2052         }
2053         return vecs;
2054 }
2055
2056
2057
2058 void attach_sameorigin(entity e, entity to, string tag)
2059 {
2060         vector org, t_forward, t_left, t_up, e_forward, e_up;
2061         vector org0, ang0;
2062         float tagscale;
2063
2064         ang0 = e.angles;
2065         org0 = e.origin;
2066
2067         org = e.origin - gettaginfo(to, gettagindex(to, tag));
2068         tagscale = pow(vlen(v_forward), -2); // undo a scale on the tag
2069         t_forward = v_forward * tagscale;
2070         t_left = v_right * -tagscale;
2071         t_up = v_up * tagscale;
2072
2073         e.origin_x = org * t_forward;
2074         e.origin_y = org * t_left;
2075         e.origin_z = org * t_up;
2076
2077         // current forward and up directions
2078         if(substring(e.model, 0, 1) == "*") // bmodels have their own rules
2079                 e.angles_x = -e.angles_x;
2080         fixedmakevectors(e.angles);
2081
2082         // untransform forward, up!
2083         e_forward_x = v_forward * t_forward;
2084         e_forward_y = v_forward * t_left;
2085         e_forward_z = v_forward * t_up;
2086         e_up_x = v_up * t_forward;
2087         e_up_y = v_up * t_left;
2088         e_up_z = v_up * t_up;
2089
2090         e.angles = fixedvectoangles2(e_forward, e_up);
2091         if(substring(e.model, 0, 1) == "*") // bmodels have their own rules
2092                 e.angles_x = -e.angles_x;
2093
2094         setattachment(e, to, tag);
2095         setorigin(e, e.origin);
2096 }
2097
2098 void detach_sameorigin(entity e)
2099 {
2100         vector org;
2101         org = gettaginfo(e, 0);
2102         e.angles = fixedvectoangles2(v_forward, v_up);
2103         if(substring(e.model, 0, 1) == "*") // bmodels have their own rules
2104                 e.angles_x = -e.angles_x;
2105         e.origin = org;
2106         setattachment(e, world, "");
2107         setorigin(e, e.origin);
2108 }
2109
2110 void follow_sameorigin(entity e, entity to)
2111 {
2112         e.movetype = MOVETYPE_FOLLOW; // make the hole follow
2113         e.aiment = to; // make the hole follow bmodel
2114         e.punchangle = to.angles; // the original angles of bmodel
2115         e.view_ofs = e.origin - to.origin; // relative origin
2116         e.v_angle = e.angles - to.angles; // relative angles
2117 }
2118
2119 void unfollow_sameorigin(entity e)
2120 {
2121         e.movetype = MOVETYPE_NONE;
2122 }
2123
2124 entity gettaginfo_relative_ent;
2125 vector gettaginfo_relative(entity e, float tag)
2126 {
2127         if(!gettaginfo_relative_ent)
2128         {
2129                 gettaginfo_relative_ent = spawn();
2130                 gettaginfo_relative_ent.effects = EF_NODRAW;
2131         }
2132         gettaginfo_relative_ent.model = e.model;
2133         gettaginfo_relative_ent.modelindex = e.modelindex;
2134         gettaginfo_relative_ent.frame = e.frame;
2135         return gettaginfo(gettaginfo_relative_ent, tag);
2136 }