data/qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   7 void() spawnpoint_use;
   8 string ColoredTeamName(float t);
   9
  10 float RandomSelection_totalweight;
  11 float RandomSelection_best_priority;
  12 entity RandomSelection_chosen_ent;
  13 float RandomSelection_chosen_float;
  14 void RandomSelection_Init()
  15 {
  16         RandomSelection_totalweight = 0;
  17         RandomSelection_chosen_ent = world;
  18         RandomSelection_chosen_float = 0;
  19         RandomSelection_best_priority = -1;
  20 }
  21 void RandomSelection_Add(entity e, float f, float weight, float priority)
  22 {
  23         if(priority > RandomSelection_best_priority)
  24         {
  25                 RandomSelection_best_priority = priority;
  26                 RandomSelection_chosen_ent = e;
  27                 RandomSelection_chosen_float = f;
  28                 RandomSelection_totalweight = weight;
  29         }
  30         else if(priority == RandomSelection_best_priority)
  31         {
  32                 RandomSelection_totalweight += weight;
  33                 if(random() * RandomSelection_totalweight <= weight)
  34                 {
  35                         RandomSelection_chosen_ent = e;
  36                         RandomSelection_chosen_float = f;
  37                 }
  38         }
  39 }
  40
  41 float DistributeEvenly_amount;
  42 float DistributeEvenly_totalweight;
  43 void DistributeEvenly_Init(float amount, float totalweight)
  44 {
  45         if(DistributeEvenly_amount)
  46         {
  47                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  48                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  49         }
  50         if(totalweight == 0)
  51                 DistributeEvenly_amount = 0;
  52         else
  53                 DistributeEvenly_amount = amount;
  54         DistributeEvenly_totalweight = totalweight;
  55 }
  56 float DistributeEvenly_Get(float weight)
  57 {
  58         float f;
  59         if(weight <= 0)
  60                 return 0;
  61         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  62         DistributeEvenly_totalweight -= weight;
  63         DistributeEvenly_amount -= f;
  64         return f;
  65 }
  66
  67 void move_out_of_solid_expand(entity e, vector by)
  68 {
  69         float eps = 0.0625;
  70         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  71         if(trace_startsolid)
  72                 return;
  73         if(trace_fraction < 1)
  74         {
  75                 // hit something
  76                 // adjust origin in the other direction...
  77                 e.origin = e.origin - by * (1 - trace_fraction);
  78         }
  79 }
  80
  81 float move_out_of_solid(entity e)
  82 {
  83         vector o, m0, m1;
  84
  85         o = e.origin;
  86         traceline(o, o, MOVE_WORLDONLY, e);
  87         if(trace_startsolid)
  88                 return 0;
  89
  90         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  91         if(!trace_startsolid)
  92                 return 1;
  93
  94         m0 = e.mins;
  95         m1 = e.maxs;
  96         e.mins = '0 0 0';
  97         e.maxs = '0 0 0';
  98         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  99         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
 100         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
 101         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
 102         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
 103         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
 104         setorigin(e, e.origin);
 105
 106         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 107         if(trace_startsolid)
 108         {
 109                 setorigin(e, o);
 110                 return 0;
 111         }
 112
 113         return 1;
 114 }
 115
 116 string STR_PLAYER = "player";
 117 string STR_SPECTATOR = "spectator";
 118 string STR_OBSERVER = "observer";
 119
 120 #if 0
 121 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
 122 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 123 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
 124 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
 125 #else
 126 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
 127 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
 128 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 129 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
 130 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 131 #endif
 132
 133 // copies a string to a tempstring (so one can strunzone it)
 134 string strcat1(string s) = #115; // FRIK_FILE
 135
 136 float logfile_open;
 137 float logfile;
 138
 139 void bcenterprint(string s)
 140 {
 141         // TODO replace by MSG_ALL (would show it to spectators too, though)?
 142         entity head;
 143         FOR_EACH_PLAYER(head)
 144                 if(clienttype(head) == CLIENTTYPE_REAL)
 145                         centerprint(head, s);
 146 }
 147
 148 void GameLogEcho(string s)
 149 {
 150         string fn;
 151         float matches;
 152
 153         if(cvar("sv_eventlog_files"))
 154         {
 155                 if(!logfile_open)
 156                 {
 157                         logfile_open = TRUE;
 158                         matches = cvar("sv_eventlog_files_counter") + 1;
 159                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 160                         fn = ftos(matches);
 161                         if(strlen(fn) < 8)
 162                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 163                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 164                         logfile = fopen(fn, FILE_APPEND);
 165                         fputs(logfile, ":logversion:2\n");
 166                 }
 167                 if(logfile >= 0)
 168                 {
 169                         if(cvar("sv_eventlog_files_timestamps"))
 170                                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 171                         else
 172                                 fputs(logfile, strcat(s, "\n"));
 173                 }
 174         }
 175         if(cvar("sv_eventlog_console"))
 176         {
 177                 print(s, "\n");
 178         }
 179 }
 180
 181 void GameLogInit()
 182 {
 183         logfile_open = 0;
 184         // will be opened later
 185 }
 186
 187 void GameLogClose()
 188 {
 189         if(logfile_open && logfile >= 0)
 190         {
 191                 fclose(logfile);
 192                 logfile = -1;
 193         }
 194 }
 195
 196 float spawnpoint_nag;
 197 void relocate_spawnpoint()
 198 {
 199         // nudge off the floor
 200         setorigin(self, self.origin + '0 0 1');
 201
 202         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 203         if (trace_startsolid)
 204         {
 205                 vector o;
 206                 o = self.origin;
 207                 self.mins = PL_MIN;
 208                 self.maxs = PL_MAX;
 209                 if(!move_out_of_solid(self))
 210                         objerror("could not get out of solid at all!");
 211                 print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 212                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 213                 print(" ", ftos(self.origin_y - o_y));
 214                 print(" ", ftos(self.origin_z - o_z), "'\n");
 215                 if(cvar("g_spawnpoints_auto_move_out_of_solid"))
 216                 {
 217                         if(!spawnpoint_nag)
 218                                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 219                         spawnpoint_nag = 1;
 220                 }
 221                 else
 222                 {
 223                         self.origin = o;
 224                         self.mins = self.maxs = '0 0 0';
 225                         objerror("player spawn point in solid, mapper sucks!\n");
 226                         return;
 227                 }
 228         }
 229
 230         if(cvar("g_spawnpoints_autodrop"))
 231         {
 232                 setsize(self, PL_MIN, PL_MAX);
 233                 droptofloor();
 234         }
 235
 236         self.use = spawnpoint_use;
 237         self.team_saved = self.team;
 238         if(!self.cnt)
 239                 self.cnt = 1;
 240
 241         if(g_ctf || g_assault || g_onslaught || g_domination)
 242         if(self.team)
 243                 have_team_spawns = 1;
 244
 245         if(cvar("r_showbboxes"))
 246         {
 247                 // show where spawnpoints point at too
 248                 makevectors(self.angles);
 249                 entity e;
 250                 e = spawn();
 251                 e.classname = "info_player_foo";
 252                 setorigin(e, self.origin + v_forward * 24);
 253                 setsize(e, '-8 -8 -8', '8 8 8');
 254                 e.solid = SOLID_TRIGGER;
 255         }
 256 }
 257
 258 #define strstr strstrofs
 259 /*
 260 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 261 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 262 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 263 // BE CONSTANT OR strzoneD!
 264 float strstr(string haystack, string needle, float offset)
 265 {
 266         float len, endpos;
 267         string found;
 268         len = strlen(needle);
 269         endpos = strlen(haystack) - len;
 270         while(offset <= endpos)
 271         {
 272                 found = substring(haystack, offset, len);
 273                 if(found == needle)
 274                         return offset;
 275                 offset = offset + 1;
 276         }
 277         return -1;
 278 }
 279 */
 280
 281 float NUM_NEAREST_ENTITIES = 4;
 282 entity nearest_entity[NUM_NEAREST_ENTITIES];
 283 float nearest_length[NUM_NEAREST_ENTITIES];
 284 entity findnearest(vector point, .string field, string value, vector axismod)
 285 {
 286         entity localhead;
 287         float i;
 288         float j;
 289         float len;
 290         vector dist;
 291
 292         float num_nearest;
 293         num_nearest = 0;
 294
 295         localhead = find(world, field, value);
 296         while(localhead)
 297         {
 298                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 299                         dist = localhead.oldorigin;
 300                 else
 301                         dist = localhead.origin;
 302                 dist = dist - point;
 303                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 304                 len = vlen(dist);
 305
 306                 for(i = 0; i < num_nearest; ++i)
 307                 {
 308                         if(len < nearest_length[i])
 309                                 break;
 310                 }
 311
 312                 // now i tells us where to insert at
 313                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 314                 if(i < NUM_NEAREST_ENTITIES)
 315                 {
 316                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 317                         {
 318                                 nearest_length[j + 1] = nearest_length[j];
 319                                 nearest_entity[j + 1] = nearest_entity[j];
 320                         }
 321                         nearest_length[i] = len;
 322                         nearest_entity[i] = localhead;
 323                         if(num_nearest < NUM_NEAREST_ENTITIES)
 324                                 num_nearest = num_nearest + 1;
 325                 }
 326
 327                 localhead = find(localhead, field, value);
 328         }
 329
 330         // now use the first one from our list that we can see
 331         for(i = 0; i < num_nearest; ++i)
 332         {
 333                 traceline(point, nearest_entity[i].origin, TRUE, world);
 334                 if(trace_fraction == 1)
 335                 {
 336                         if(i != 0)
 337                         {
 338                                 dprint("Nearest point (");
 339                                 dprint(nearest_entity[0].netname);
 340                                 dprint(") is not visible, using a visible one.\n");
 341                         }
 342                         return nearest_entity[i];
 343                 }
 344         }
 345
 346         if(num_nearest == 0)
 347                 return world;
 348
 349         dprint("Not seeing any location point, using nearest as fallback.\n");
 350         /* DEBUGGING CODE:
 351         dprint("Candidates were: ");
 352         for(j = 0; j < num_nearest; ++j)
 353         {
 354                 if(j != 0)
 355                         dprint(", ");
 356                 dprint(nearest_entity[j].netname);
 357         }
 358         dprint("\n");
 359         */
 360
 361         return nearest_entity[0];
 362 }
 363
 364 void spawnfunc_target_location()
 365 {
 366         self.classname = "target_location";
 367         // location name in netname
 368         // eventually support: count, teamgame selectors, line of sight?
 369 };
 370
 371 void spawnfunc_info_location()
 372 {
 373         self.classname = "target_location";
 374         self.message = self.netname;
 375 };
 376
 377 string NearestLocation(vector p)
 378 {
 379         entity loc;
 380         string ret;
 381         ret = "somewhere";
 382         loc = findnearest(p, classname, "target_location", '1 1 1');
 383         if(loc)
 384         {
 385                 ret = loc.message;
 386         }
 387         else
 388         {
 389                 loc = findnearest(p, target, "###item###", '1 1 4');
 390                 if(loc)
 391                         ret = loc.netname;
 392         }
 393         return ret;
 394 }
 395
 396 string formatmessage(string msg)
 397 {
 398         float p;
 399         float n;
 400         string msg_save;
 401         string escape;
 402         string replacement;
 403         msg_save = strzone(msg);
 404         p = 0;
 405         n = 7;
 406         while(1)
 407         {
 408                 if(n < 1)
 409                         break; // too many replacements
 410                 n = n - 1;
 411                 p = strstr(msg_save, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 if(p < 0)
 413                         break;
 414                 replacement = substring(msg_save, p, 2);
 415                 escape = substring(msg_save, p + 1, 1);
 416                 if(escape == "%")
 417                         replacement = "%";
 418                 else if(escape == "a")
 419                         replacement = ftos(floor(self.armorvalue));
 420                 else if(escape == "h")
 421                         replacement = ftos(floor(self.health));
 422                 else if(escape == "l")
 423                         replacement = NearestLocation(self.origin);
 424                 else if(escape == "y")
 425                         replacement = NearestLocation(self.cursor_trace_endpos);
 426                 else if(escape == "d")
 427                         replacement = NearestLocation(self.death_origin);
 428                 else if(escape == "w")
 429                 {
 430                         float wep;
 431                         wep = self.weapon;
 432                         if(!wep)
 433                                 wep = self.switchweapon;
 434                         if(!wep)
 435                                 wep = self.cnt;
 436                         replacement = W_Name(wep);
 437                 }
 438                 else if(escape == "W")
 439                 {
 440                         if(self.items & IT_SHELLS) replacement = "shells";
 441                         else if(self.items & IT_NAILS) replacement = "bullets";
 442                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 443                         else if(self.items & IT_CELLS) replacement = "cells";
 444                         else replacement = "batteries"; // ;)
 445                 }
 446                 else if(escape == "x")
 447                 {
 448                         replacement = self.cursor_trace_ent.netname;
 449                         if(!replacement || !self.cursor_trace_ent)
 450                                 replacement = "nothing";
 451                 }
 452                 else if(escape == "p")
 453                 {
 454                         if(self.last_selected_player)
 455                                 replacement = self.last_selected_player.netname;
 456                         else
 457                                 replacement = "(nobody)";
 458                 }
 459                 msg = strcat(substring(msg_save, 0, p), replacement);
 460                 msg = strcat(msg, substring(msg_save, p+2, strlen(msg_save) - (p+2)));
 461                 strunzone(msg_save);
 462                 msg_save = strzone(msg);
 463                 p = p + 2;
 464         }
 465         msg = strcat(msg_save, "");
 466         strunzone(msg_save);
 467         return msg;
 468 }
 469
 470 /*
 471 =============
 472 GetCvars
 473 =============
 474 Called with:
 475   0:  sends the request
 476   >0: receives a cvar from name=argv(f) value=argv(f+1)
 477 */
 478 void GetCvars_handleString(string thisname, float f, .string field, string name)
 479 {
 480         if(f < 0)
 481         {
 482                 if(self.field)
 483                         strunzone(self.field);
 484         }
 485         else if(f > 0)
 486         {
 487                 if(thisname == name)
 488                 {
 489                         if(self.field)
 490                                 strunzone(self.field);
 491                         self.field = strzone(argv(f + 1));
 492                 }
 493         }
 494         else
 495                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 496 }
 497 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 498 {
 499         GetCvars_handleString(thisname, f, field, name);
 500         if(f >= 0) // also initialize to the fitting value for "" when sending cvars out
 501         if(thisname == name)
 502         {
 503                 string s;
 504                 s = func(strcat1(self.field));
 505                 if(s != self.field)
 506                 {
 507                         strunzone(self.field);
 508                         self.field = strzone(s);
 509                 }
 510         }
 511 }
 512 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 513 {
 514         if(f < 0)
 515         {
 516         }
 517         else if(f > 0)
 518         {
 519                 if(thisname == name)
 520                         self.field = stof(argv(f + 1));
 521         }
 522         else
 523                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 524 }
 525 string W_FixWeaponOrder_ForceComplete(string s);
 526 string W_FixWeaponOrder_AllowIncomplete(string s);
 527 float w_getbestweapon(entity e);
 528 void GetCvars(float f)
 529 {
 530         string s;
 531         if(f > 0)
 532                 s = strcat1(argv(f));
 533         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 534         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 535         GetCvars_handleFloat(s, f, cvar_cl_nogibs, "cl_nogibs");
 536         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 537         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 538         GetCvars_handleString(s, f, cvar_g_nexuizversion, "g_nexuizversion");
 539         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 540         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 541         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 542         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 543         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 551
 552         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 553         if(f > 0)
 554         {
 555                 if(s == "cl_weaponpriority")
 556                         self.switchweapon = w_getbestweapon(self);
 557         }
 558 }
 559
 560 float fexists(string f)
 561 {
 562         float fh;
 563         fh = fopen(f, FILE_READ);
 564         if(fh < 0)
 565                 return FALSE;
 566         fclose(fh);
 567         return TRUE;
 568 }
 569
 570 void backtrace(string msg)
 571 {
 572         float dev;
 573         dev = cvar("developer");
 574         cvar_set("developer", "1");
 575         dprint("\n");
 576         dprint("--- CUT HERE ---\nWARNING: ");
 577         dprint(msg);
 578         dprint("\n");
 579         remove(world); // isn't there any better way to cause a backtrace?
 580         dprint("\n--- CUT UNTIL HERE ---\n");
 581         cvar_set("developer", ftos(dev));
 582 }
 583
 584 string Team_ColorCode(float teamid)
 585 {
 586         if(teamid == COLOR_TEAM1)
 587                 return "^1";
 588         else if(teamid == COLOR_TEAM2)
 589                 return "^4";
 590         else if(teamid == COLOR_TEAM3)
 591                 return "^3";
 592         else if(teamid == COLOR_TEAM4)
 593                 return "^6";
 594         else
 595                 return "^7";
 596 }
 597 string Team_ColorName(float t)
 598 {
 599         // fixme: Search for team entities and get their .netname's!
 600         if(t == COLOR_TEAM1)
 601                 return "Red";
 602         if(t == COLOR_TEAM2)
 603                 return "Blue";
 604         if(t == COLOR_TEAM3)
 605                 return "Yellow";
 606         if(t == COLOR_TEAM4)
 607                 return "Pink";
 608         return "Neutral";
 609 }
 610 string Team_ColorNameLowerCase(float t)
 611 {
 612         // fixme: Search for team entities and get their .netname's!
 613         if(t == COLOR_TEAM1)
 614                 return "red";
 615         if(t == COLOR_TEAM2)
 616                 return "blue";
 617         if(t == COLOR_TEAM3)
 618                 return "yellow";
 619         if(t == COLOR_TEAM4)
 620                 return "pink";
 621         return "neutral";
 622 }
 623
 624 #define CENTERPRIO_POINT 1
 625 #define CENTERPRIO_SPAM 2
 626 #define CENTERPRIO_REBALANCE 2
 627 #define CENTERPRIO_VOTE 4
 628 #define CENTERPRIO_NORMAL 5
 629 #define CENTERPRIO_MAPVOTE 9
 630 #define CENTERPRIO_IDLEKICK 50
 631 #define CENTERPRIO_ADMIN 99
 632 .float centerprint_priority;
 633 .float centerprint_expires;
 634 void centerprint_atprio(entity e, float prio, string s)
 635 {
 636         if(intermission_running)
 637                 if(prio < CENTERPRIO_MAPVOTE)
 638                         return;
 639         if(time > e.centerprint_expires)
 640                 e.centerprint_priority = 0;
 641         if(prio >= e.centerprint_priority)
 642         {
 643                 e.centerprint_priority = prio;
 644                 if(timeoutStatus == 2)
 645                         e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 646                 else
 647                         e.centerprint_expires = time + e.cvar_scr_centertime;
 648                 centerprint_builtin(e, s);
 649         }
 650 }
 651 void centerprint_expire(entity e, float prio)
 652 {
 653         if(prio == e.centerprint_priority)
 654         {
 655                 e.centerprint_priority = 0;
 656                 centerprint_builtin(e, "");
 657         }
 658 }
 659 void centerprint(entity e, string s)
 660 {
 661         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 662 }
 663
 664 // decolorizes and team colors the player name when needed
 665 string playername(entity p)
 666 {
 667         string t;
 668         if(teams_matter && !intermission_running && p.classname == "player")
 669         {
 670                 t = Team_ColorCode(p.team);
 671                 return strcat(t, strdecolorize(p.netname));
 672         }
 673         else
 674                 return p.netname;
 675 }
 676
 677 vector randompos(vector m1, vector m2)
 678 {
 679         local vector v;
 680         m2 = m2 - m1;
 681         v_x = m2_x * random() + m1_x;
 682         v_y = m2_y * random() + m1_y;
 683         v_z = m2_z * random() + m1_z;
 684         return  v;
 685 };
 686
 687 // requires that m2>m1 in all coordinates, and that m4>m3
 688 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;};
 689
 690 // requires the same, but is a stronger condition
 691 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;};
 692
 693 float g_pickup_shells;
 694 float g_pickup_shells_max;
 695 float g_pickup_nails;
 696 float g_pickup_nails_max;
 697 float g_pickup_rockets;
 698 float g_pickup_rockets_max;
 699 float g_pickup_cells;
 700 float g_pickup_cells_max;
 701 float g_pickup_armorsmall;
 702 float g_pickup_armorsmall_max;
 703 float g_pickup_armormedium;
 704 float g_pickup_armormedium_max;
 705 float g_pickup_armorlarge;
 706 float g_pickup_armorlarge_max;
 707 float g_pickup_healthsmall;
 708 float g_pickup_healthsmall_max;
 709 float g_pickup_healthmedium;
 710 float g_pickup_healthmedium_max;
 711 float g_pickup_healthlarge;
 712 float g_pickup_healthlarge_max;
 713 float g_pickup_healthmega;
 714 float g_pickup_healthmega_max;
 715
 716 float start_weapons;
 717 float start_items;
 718 float start_ammo_shells;
 719 float start_ammo_nails;
 720 float start_ammo_rockets;
 721 float start_ammo_cells;
 722 float start_health;
 723 float start_armorvalue;
 724 float warmup_start_weapons;
 725 float warmup_start_ammo_shells;
 726 float warmup_start_ammo_nails;
 727 float warmup_start_ammo_rockets;
 728 float warmup_start_ammo_cells;
 729 float warmup_start_health;
 730 float warmup_start_armorvalue;
 731
 732 entity get_weaponinfo(float w);
 733
 734 void readplayerstartcvars()
 735 {
 736         entity e;
 737         float i;
 738
 739         // initialize starting values for players
 740         start_weapons = 0;
 741         start_items = 0;
 742         start_ammo_shells = 0;
 743         start_ammo_nails = 0;
 744         start_ammo_rockets = 0;
 745         start_ammo_cells = 0;
 746         start_health = cvar("g_balance_health_start");
 747         start_armorvalue = cvar("g_balance_armor_start");
 748
 749         if(g_rocketarena)
 750         {
 751                 start_weapons = WEPBIT_ROCKET_LAUNCHER;
 752                 weapon_action(WEP_ROCKET_LAUNCHER, WR_PRECACHE);
 753                 start_ammo_rockets = 999;
 754                 start_items |= IT_UNLIMITED_AMMO;
 755         }
 756         else if(g_nixnex)
 757         {
 758                 start_weapons = 0;
 759                 // will be done later
 760         }
 761         else if(g_minstagib)
 762         {
 763                 start_health = 100;
 764                 start_armorvalue = 0;
 765                 start_weapons = WEPBIT_MINSTANEX;
 766                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 767                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 768                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 769         }
 770         else
 771         {
 772                 if(g_lms)
 773                 {
 774                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 775                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 776                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 777                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 778                         start_health = cvar("g_lms_start_health");
 779                         start_armorvalue = cvar("g_lms_start_armor");
 780                 } else if (cvar("g_use_ammunition")) {
 781                         start_ammo_shells = cvar("g_start_ammo_shells");
 782                         start_ammo_nails = cvar("g_start_ammo_nails");
 783                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 784                         start_ammo_cells = cvar("g_start_ammo_cells");
 785                 } else {
 786                         start_ammo_shells = cvar("g_pickup_shells_max");
 787                         start_ammo_nails = cvar("g_pickup_nails_max");
 788                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 789                         start_ammo_cells = cvar("g_pickup_cells_max");
 790                         start_items |= IT_UNLIMITED_AMMO;
 791                 }
 792
 793                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 794                 {
 795                         e = get_weaponinfo(i);
 796                         if(!(e.weapon))
 797                                 continue;
 798                         if(((e.spawnflags & 1) && g_lms) || cvar(strcat("g_start_weapon_", e.netname)))
 799                         {
 800                                 start_weapons |= e.weapons;
 801                                 weapon_action(e.weapon, WR_PRECACHE);
 802                         }
 803                 }
 804         }
 805
 806         if(inWarmupStage)
 807         {
 808                 warmup_start_ammo_shells = start_ammo_shells;
 809                 warmup_start_ammo_nails = start_ammo_nails;
 810                 warmup_start_ammo_rockets = start_ammo_rockets;
 811                 warmup_start_ammo_cells = start_ammo_cells;
 812                 warmup_start_health = start_health;
 813                 warmup_start_armorvalue = start_armorvalue;
 814                 warmup_start_weapons = start_weapons;
 815
 816                 if(!g_rocketarena && !g_nixnex && !g_minstagib)
 817                 {
 818                         if(cvar("g_use_ammunition"))
 819                         {
 820                                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 821                                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 822                                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 823                                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 824                         }
 825                         warmup_start_health = cvar("g_warmup_start_health");
 826                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 827                         if(cvar("g_warmup_allguns"))
 828                         {
 829                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 830                                 {
 831                                         e = get_weaponinfo(i);
 832                                         if(!(e.weapon))
 833                                                 continue;
 834                                         if(e.spawnflags & 1)
 835                                         {
 836                                                 warmup_start_weapons |= e.weapons;
 837                                                 weapon_action(e.weapon, WR_PRECACHE);
 838                                         }
 839                                 }
 840                         }
 841                 }
 842         }
 843 }
 844
 845 void readlevelcvars(void)
 846 {
 847         sv_cheats = cvar("sv_cheats");
 848         sv_gentle = cvar("sv_gentle");
 849         sv_foginterval = cvar("sv_foginterval");
 850         g_cloaked = cvar("g_cloaked");
 851         g_jump_grunt = cvar("g_jump_grunt");
 852         g_footsteps = cvar("g_footsteps");
 853         g_grappling_hook = cvar("g_grappling_hook");
 854         g_laserguided_missile = cvar("g_laserguided_missile");
 855         g_midair = cvar("g_midair");
 856         g_minstagib = cvar("g_minstagib");
 857         g_nixnex = cvar("g_nixnex");
 858         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
 859         g_norecoil = cvar("g_norecoil");
 860         g_rocketarena = cvar("g_rocketarena");
 861         g_vampire = cvar("g_vampire");
 862         sv_maxidle = cvar("sv_maxidle");
 863         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
 864         sv_pogostick = cvar("sv_pogostick");
 865         sv_doublejump = cvar("sv_doublejump");
 866
 867         inWarmupStage = cvar("g_warmup");
 868         g_warmup_limit = cvar("g_warmup_limit");
 869         g_warmup_allguns = cvar("g_warmup_allguns");
 870         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
 871
 872         if(g_race && g_race_qualifying == 2 || g_arena || g_assault || cvar("g_campaign"))
 873                 inWarmupStage = 0; // these modes cannot work together, sorry
 874
 875         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
 876         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
 877         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
 878         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
 879
 880         if(g_minstagib) g_nixnex = g_rocketarena = 0;
 881         if(g_nixnex) g_rocketarena = 0;
 882
 883         g_pickup_shells                    = cvar("g_pickup_shells");
 884         g_pickup_shells_max                = cvar("g_pickup_shells_max");
 885         g_pickup_nails                     = cvar("g_pickup_nails");
 886         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
 887         g_pickup_rockets                   = cvar("g_pickup_rockets");
 888         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
 889         g_pickup_cells                     = cvar("g_pickup_cells");
 890         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
 891         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
 892         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
 893         g_pickup_armormedium               = cvar("g_pickup_armormedium");
 894         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
 895         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
 896         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
 897         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
 898         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
 899         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
 900         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
 901         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
 902         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
 903         g_pickup_healthmega                = cvar("g_pickup_healthmega");
 904         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
 905
 906         readplayerstartcvars();
 907 }
 908
 909 /*
 910 // TODO sound pack system
 911 string soundpack;
 912
 913 string precache_sound_builtin (string s) = #19;
 914 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
 915 string precache_sound(string s)
 916 {
 917         return precache_sound_builtin(strcat(soundpack, s));
 918 }
 919 void play2(entity e, string filename)
 920 {
 921         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
 922 }
 923 void sound(entity e, float chan, string samp, float vol, float atten)
 924 {
 925         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
 926 }
 927 */
 928
 929 // Sound functions
 930 string precache_sound (string s) = #19;
 931 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
 932 float precache_sound_index (string s) = #19;
 933
 934 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
 935 {
 936         WriteByte(dest, 6);
 937         WriteByte(dest, 27); // all bits except SND_LOOPING
 938         WriteByte(dest, vol * 255);
 939         WriteByte(dest, atten * 64);
 940         WriteEntity(dest, e);
 941         WriteByte(dest, chan);
 942         WriteShort(dest, precache_sound_index(samp));
 943         WriteCoord(dest, o_x);
 944         WriteCoord(dest, o_y);
 945         WriteCoord(dest, o_z);
 946 }
 947 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
 948 {
 949         vector o;
 950         o = e.origin + 0.5 * (e.mins + e.maxs);
 951         soundtoat(dest, e, o, chan, samp, vol, atten);
 952 }
 953 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
 954 {
 955         soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
 956 }
 957
 958 void play2(entity e, string filename)
 959 {
 960         //stuffcmd(e, strcat("play2 ", filename, "\n"));
 961         msg_entity = e;
 962         soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
 963 }
 964
 965 .float announcetime;
 966 float announce(entity player, string msg)
 967 {
 968         if(time > player.announcetime)
 969         if(clienttype(player) == CLIENTTYPE_REAL)
 970         {
 971                 player.announcetime = time + 0.3;
 972                 play2(player, msg);
 973                 return TRUE;
 974         }
 975         return FALSE;
 976 }
 977
 978 void play2team(float t, string filename)
 979 {
 980         local entity head;
 981         FOR_EACH_REALPLAYER(head)
 982         {
 983                 if (head.team == t)
 984                         play2(head, filename);
 985         }
 986 }
 987
 988 void play2all(string samp)
 989 {
 990         sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
 991 }
 992
 993 void PrecachePlayerSounds(string f);
 994 void precache_all_models(string pattern)
 995 {
 996         float globhandle, i, n;
 997         string f;
 998
 999         globhandle = search_begin(pattern, TRUE, FALSE);
1000         if(globhandle < 0)
1001                 return;
1002         n = search_getsize(globhandle);
1003         for(i = 0; i < n; ++i)
1004         {
1005                 //print(search_getfilename(globhandle, i), "\n");
1006                 f = search_getfilename(globhandle, i);
1007                 precache_model(f);
1008                 PrecachePlayerSounds(strcat(f, ".sounds"));
1009         }
1010         search_end(globhandle);
1011 }
1012
1013 void precache()
1014 {
1015         // gamemode related things
1016         precache_model ("models/misc/chatbubble.spr");
1017         precache_model ("models/misc/teambubble.spr");
1018         if (g_runematch)
1019         {
1020                 precache_model ("models/runematch/curse.mdl");
1021                 precache_model ("models/runematch/rune.mdl");
1022         }
1023
1024 #ifdef TTURRETS_ENABLED
1025     if(cvar("g_turrets"))
1026         turrets_precash();
1027 #endif
1028
1029         // Precache all player models if desired
1030         if (cvar("sv_precacheplayermodels"))
1031         {
1032                 PrecachePlayerSounds("sound/player/default.sounds");
1033                 precache_all_models("models/player/*.zym");
1034                 precache_all_models("models/player/*.dpm");
1035                 precache_all_models("models/player/*.md3");
1036                 precache_all_models("models/player/*.psk");
1037                 //precache_model("models/player/carni.zym");
1038                 //precache_model("models/player/crash.zym");
1039                 //precache_model("models/player/grunt.zym");
1040                 //precache_model("models/player/headhunter.zym");
1041                 //precache_model("models/player/insurrectionist.zym");
1042                 //precache_model("models/player/jeandarc.zym");
1043                 //precache_model("models/player/lurk.zym");
1044                 //precache_model("models/player/lycanthrope.zym");
1045                 //precache_model("models/player/marine.zym");
1046                 //precache_model("models/player/nexus.zym");
1047                 //precache_model("models/player/pyria.zym");
1048                 //precache_model("models/player/shock.zym");
1049                 //precache_model("models/player/skadi.zym");
1050                 //precache_model("models/player/specop.zym");
1051                 //precache_model("models/player/visitant.zym");
1052         }
1053
1054         if (g_footsteps)
1055         {
1056                 PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1057                 PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1058         }
1059
1060         // gore and miscellaneous sounds
1061         //precache_sound ("misc/h2ohit.wav");
1062         precache_model ("models/gibs/bloodyskull.md3");
1063         precache_model ("models/gibs/chunk.mdl");
1064         precache_model ("models/gibs/eye.md3");
1065         precache_model ("models/gibs/gib1.md3");
1066         precache_model ("models/gibs/gib2.md3");
1067         precache_model ("models/gibs/gib3.md3");
1068         precache_model ("models/gibs/gib4.md3");
1069         precache_model ("models/gibs/gib5.md3");
1070         precache_model ("models/gibs/gib6.md3");
1071         precache_model ("models/gibs/smallchest.md3");
1072         precache_model ("models/gibs/chest.md3");
1073         precache_model ("models/gibs/arm.md3");
1074         precache_model ("models/gibs/leg1.md3");
1075         precache_model ("models/gibs/leg2.md3");
1076         precache_model ("models/hook.md3");
1077         precache_sound ("misc/armorimpact.wav");
1078         precache_sound ("misc/bodyimpact1.wav");
1079         precache_sound ("misc/bodyimpact2.wav");
1080         precache_sound ("misc/gib.wav");
1081         precache_sound ("misc/gib_splat01.wav");
1082         precache_sound ("misc/gib_splat02.wav");
1083         precache_sound ("misc/gib_splat03.wav");
1084         precache_sound ("misc/gib_splat04.wav");
1085         precache_sound ("misc/hit.wav");
1086         PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1087         PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1088         precache_sound ("misc/null.wav");
1089         precache_sound ("misc/spawn.wav");
1090         precache_sound ("misc/talk.wav");
1091         precache_sound ("misc/teleport.wav");
1092         precache_sound ("player/lava.wav");
1093         precache_sound ("player/slime.wav");
1094
1095         // announcer sounds - male
1096         //precache_sound ("announcer/male/electrobitch.wav");
1097         precache_sound ("announcer/male/03kills.wav");
1098         precache_sound ("announcer/male/05kills.wav");
1099         precache_sound ("announcer/male/10kills.wav");
1100         precache_sound ("announcer/male/15kills.wav");
1101         precache_sound ("announcer/male/20kills.wav");
1102         precache_sound ("announcer/male/25kills.wav");
1103         precache_sound ("announcer/male/30kills.wav");
1104         precache_sound ("announcer/male/botlike.wav");
1105         precache_sound ("announcer/male/yoda.ogg");
1106         precache_sound ("announcer/male/headshot.ogg");
1107         precache_sound ("announcer/male/impressive.ogg");
1108
1109         // announcer sounds - robotic
1110         precache_sound ("announcer/robotic/prepareforbattle.wav");
1111         precache_sound ("announcer/robotic/begin.wav");
1112         precache_sound ("announcer/robotic/timeoutcalled.wav");
1113         precache_sound ("announcer/robotic/1fragleft.wav");
1114         precache_sound ("announcer/robotic/1minuteremains.wav");
1115         precache_sound ("announcer/robotic/2fragsleft.wav");
1116         precache_sound ("announcer/robotic/3fragsleft.wav");
1117         if (g_minstagib)
1118         {
1119                 precache_sound ("announcer/robotic/lastsecond.wav");
1120                 precache_sound ("announcer/robotic/narrowly.wav");
1121         }
1122
1123         precache_model ("models/sprites/1.spr32");
1124         precache_model ("models/sprites/2.spr32");
1125         precache_model ("models/sprites/3.spr32");
1126         precache_model ("models/sprites/4.spr32");
1127         precache_model ("models/sprites/5.spr32");
1128         precache_model ("models/sprites/6.spr32");
1129         precache_model ("models/sprites/7.spr32");
1130         precache_model ("models/sprites/8.spr32");
1131         precache_model ("models/sprites/9.spr32");
1132         precache_model ("models/sprites/10.spr32");
1133         precache_sound ("announcer/robotic/1.ogg");
1134         precache_sound ("announcer/robotic/2.ogg");
1135         precache_sound ("announcer/robotic/3.ogg");
1136         precache_sound ("announcer/robotic/4.ogg");
1137         precache_sound ("announcer/robotic/5.ogg");
1138         precache_sound ("announcer/robotic/6.ogg");
1139         precache_sound ("announcer/robotic/7.ogg");
1140         precache_sound ("announcer/robotic/8.ogg");
1141         precache_sound ("announcer/robotic/9.ogg");
1142         precache_sound ("announcer/robotic/10.ogg");
1143
1144         // common weapon precaches
1145         precache_sound ("weapons/weapon_switch.wav");
1146         precache_sound ("weapons/weaponpickup.wav");
1147         if (cvar("g_grappling_hook"))
1148         {
1149                 precache_sound ("weapons/hook_fire.wav"); // hook
1150                 precache_sound ("weapons/hook_impact.wav"); // hook
1151         }
1152
1153         if (cvar("sv_precacheweapons") || g_nixnex)
1154         {
1155                 //precache weapon models/sounds
1156                 local float wep;
1157                 wep = WEP_FIRST;
1158                 while (wep <= WEP_LAST)
1159                 {
1160                         weapon_action(wep, WR_PRECACHE);
1161                         wep = wep + 1;
1162                 }
1163         }
1164
1165         // plays music for the level if there is any
1166         if (self.noise)
1167         {
1168                 precache_sound (self.noise);
1169                 ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1170         }
1171 }
1172
1173 // sorry, but using \ in macros breaks line numbers
1174 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1175 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1176 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1177
1178 vector ExactTriggerHit_mins;
1179 vector ExactTriggerHit_maxs;
1180 float ExactTriggerHit_Recurse()
1181 {
1182         float s;
1183         entity se;
1184         float f;
1185
1186         tracebox('0 0 0', ExactTriggerHit_mins, ExactTriggerHit_maxs, '0 0 0', MOVE_NORMAL, other);
1187         if not(trace_ent)
1188                 return 0;
1189         if(trace_ent == self)
1190                 return 1;
1191
1192         se = trace_ent;
1193         s = se.solid;
1194         se.solid = SOLID_NOT;
1195         f = ExactTriggerHit_Recurse();
1196         se.solid = s;
1197
1198         return f;
1199 }
1200
1201 float ExactTriggerHit()
1202 {
1203         float f, s;
1204
1205         if not(self.modelindex)
1206                 return 1;
1207
1208         s = self.solid;
1209         self.solid = SOLID_BSP;
1210         ExactTriggerHit_mins = other.absmin;
1211         ExactTriggerHit_maxs = other.absmax;
1212         f = ExactTriggerHit_Recurse();
1213         self.solid = s;
1214
1215         return f;
1216 }
1217
1218 // WARNING: this kills the trace globals
1219 #define EXACTTRIGGER_TOUCH if not(ExactTriggerHit()) return
1220 #define EXACTTRIGGER_INIT  InitSolidBSPTrigger(); self.solid = SOLID_TRIGGER
1221
1222 #define INITPRIO_FIRST              0
1223 #define INITPRIO_GAMETYPE           0
1224 #define INITPRIO_GAMETYPE_FALLBACK  1
1225 #define INITPRIO_CVARS              5
1226 #define INITPRIO_FINDTARGET        10
1227 #define INITPRIO_DROPTOFLOOR       20
1228 #define INITPRIO_SETLOCATION       90
1229 #define INITPRIO_LINKDOORS         91
1230 #define INITPRIO_LAST              99
1231
1232 .void(void) initialize_entity;
1233 .float initialize_entity_order;
1234 .entity initialize_entity_next;
1235 entity initialize_entity_first;
1236
1237 void make_safe_for_remove(entity e)
1238 {
1239         if(e.initialize_entity)
1240         {
1241                 entity ent, prev;
1242                 for(ent = initialize_entity_first; ent; )
1243                 {
1244                         if((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1245                         {
1246                                 print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1247                                 // skip it in linked list
1248                                 if(prev)
1249                                 {
1250                                         prev.initialize_entity_next = ent.initialize_entity_next;
1251                                         ent = prev.initialize_entity_next;
1252                                 }
1253                                 else
1254                                 {
1255                                         initialize_entity_first = ent.initialize_entity_next;
1256                                         ent = initialize_entity_first;
1257                                 }
1258                         }
1259                         else
1260                         {
1261                                 prev = ent;
1262                                 ent = ent.initialize_entity_next;
1263                         }
1264                 }
1265         }
1266 }
1267
1268 void objerror(string s)
1269 {
1270         make_safe_for_remove(self);
1271         objerror_builtin(s);
1272 }
1273
1274 void remove_safely(entity e)
1275 {
1276         make_safe_for_remove(e);
1277         remove_builtin(e);
1278 }
1279
1280 void InitializeEntity(entity e, void(void) func, float order)
1281 {
1282         entity prev, cur;
1283
1284         if(!e || e.initialize_entity)
1285         {
1286                 // make a proxy initializer entity
1287                 entity e_old;
1288                 e_old = e;
1289                 e = spawn();
1290                 e.classname = "initialize_entity";
1291                 e.enemy = e_old;
1292         }
1293
1294         e.initialize_entity = func;
1295         e.initialize_entity_order = order;
1296
1297         cur = initialize_entity_first;
1298         for(;;)
1299         {
1300                 if(!cur || cur.initialize_entity_order > order)
1301                 {
1302                         // insert between prev and cur
1303                         if(prev)
1304                                 prev.initialize_entity_next = e;
1305                         else
1306                                 initialize_entity_first = e;
1307                         e.initialize_entity_next = cur;
1308                         return;
1309                 }
1310                 prev = cur;
1311                 cur = cur.initialize_entity_next;
1312         }
1313 }
1314 void InitializeEntitiesRun()
1315 {
1316         for(self = initialize_entity_first; self; )
1317         {
1318                 entity e;
1319                 var void(void) func;
1320                 e = self.initialize_entity_next;
1321                 func = self.initialize_entity;
1322                 self.initialize_entity_order = 0;
1323                 self.initialize_entity = func_null;
1324                 self.initialize_entity_next = world;
1325                 if(self.classname == "initialize_entity")
1326                 {
1327                         entity e_old;
1328                         e_old = self.enemy;
1329                         remove_builtin(self);
1330                         self = e_old;
1331                 }
1332                 dprint("Delayed initialization: ", self.classname, "\n");
1333                 func();
1334                 self = e;
1335         }
1336         initialize_entity_first = world;
1337 }
1338
1339 .float uncustomizeentityforclient_set;
1340 .void(void) uncustomizeentityforclient;
1341 void(void) SUB_Nullpointer = #0;
1342 void UncustomizeEntitiesRun()
1343 {
1344         entity oldself;
1345         oldself = self;
1346         for(self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1347                 self.uncustomizeentityforclient();
1348         self = oldself;
1349 }
1350 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1351 {
1352         e.customizeentityforclient = customizer;
1353         e.uncustomizeentityforclient = uncustomizer;
1354         e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1355 }
1356
1357 .float nottargeted;
1358 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1359
1360 float power2of(float e)
1361 {
1362         return pow(2, e);
1363 }
1364 float log2of(float x)
1365 {
1366         // NOTE: generated code
1367         if(x > 2048)
1368                 if(x > 131072)
1369                         if(x > 1048576)
1370                                 if(x > 4194304)
1371                                         return 23;
1372                                 else
1373                                         if(x > 2097152)
1374                                                 return 22;
1375                                         else
1376                                                 return 21;
1377                         else
1378                                 if(x > 524288)
1379                                         return 20;
1380                                 else
1381                                         if(x > 262144)
1382                                                 return 19;
1383                                         else
1384                                                 return 18;
1385                 else
1386                         if(x > 16384)
1387                                 if(x > 65536)
1388                                         return 17;
1389                                 else
1390                                         if(x > 32768)
1391                                                 return 16;
1392                                         else
1393                                                 return 15;
1394                         else
1395                                 if(x > 8192)
1396                                         return 14;
1397                                 else
1398                                         if(x > 4096)
1399                                                 return 13;
1400                                         else
1401                                                 return 12;
1402         else
1403                 if(x > 32)
1404                         if(x > 256)
1405                                 if(x > 1024)
1406                                         return 11;
1407                                 else
1408                                         if(x > 512)
1409                                                 return 10;
1410                                         else
1411                                                 return 9;
1412                         else
1413                                 if(x > 128)
1414                                         return 8;
1415                                 else
1416                                         if(x > 64)
1417                                                 return 7;
1418                                         else
1419                                                 return 6;
1420                 else
1421                         if(x > 4)
1422                                 if(x > 16)
1423                                         return 5;
1424                                 else
1425                                         if(x > 8)
1426                                                 return 4;
1427                                         else
1428                                                 return 3;
1429                         else
1430                                 if(x > 2)
1431                                         return 2;
1432                                 else
1433                                         if(x > 1)
1434                                                 return 1;
1435                                         else
1436                                                 return 0;
1437 }
1438
1439 //
1440 // func_breakable
1441 // - basically func_assault_destructible for general gameplay use
1442 //
1443 float () crandom;
1444 void () SUB_UseTargets, assault_destructible_use, SUB_Remove, SUB_Null;
1445 void LaunchDebris (string debrisname) =
1446 {
1447         local   entity dbr;
1448
1449         if (debrisname == "" || !debrisname)
1450                 return;
1451
1452         dbr = spawn();
1453         dbr.origin = self.origin;
1454         setmodel (dbr, debrisname );
1455         setsize (dbr, '0 0 0', '0 0 0');
1456         dbr.velocity_x = 70 * crandom();
1457         dbr.velocity_y = 70 * crandom();
1458         dbr.velocity_z = 140 + 70 * random();
1459         dbr.movetype = MOVETYPE_BOUNCE;
1460         dbr.solid = SOLID_BBOX;
1461         dbr.avelocity_x = random()*600;
1462         dbr.avelocity_y = random()*600;
1463         dbr.avelocity_z = random()*600;
1464         dbr.think = SUB_Remove;
1465         dbr.nextthink = time + 13 + random()*10;
1466 };
1467
1468 .string debris1, debris2, debris3;
1469 .string mdl_dead;
1470 void func_breakable_destroy() {
1471         if (self.mdl_dead)
1472                 setmodel(self, self.mdl_dead);
1473         else {
1474                 self.model = "";
1475                 self.solid = SOLID_NOT;
1476         }
1477         self.takedamage = DAMAGE_NO;
1478
1479         // now throw around the debris
1480         LaunchDebris(self.debris1);
1481         LaunchDebris(self.debris2);
1482         LaunchDebris(self.debris3);
1483
1484         SUB_UseTargets();
1485
1486         self.event_damage = SUB_Null;
1487 }
1488
1489 void func_breakable_damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force) {
1490
1491         if(self.cnt > 0) {
1492                 self.health = self.health - damage;
1493                 // add pain effects?
1494         }
1495
1496         if(self.health < 0) {
1497                 activator = attacker;
1498                 func_breakable_destroy();
1499         }
1500 }
1501
1502 // destructible walls that can be used to trigger target_objective_decrease
1503 void spawnfunc_func_breakable() {
1504         if(!self.health)
1505                 self.health = 100;
1506
1507         self.max_health = self.health;
1508
1509         //self.cnt = 0; // not yet activated
1510
1511
1512
1513         self.classname = "func_breakable";
1514         self.mdl = self.model;
1515         setmodel(self, self.mdl);
1516
1517         self.solid = SOLID_BSP;
1518
1519         // precache all the models
1520         if (self.mdl_dead)
1521                 precache_model(self.mdl_dead);
1522         if (self.debris1)
1523                 precache_model(self.debris1);
1524         if (self.debris2)
1525                 precache_model(self.debris2);
1526         if (self.debris3)
1527                 precache_model(self.debris3);
1528
1529         self.use = assault_destructible_use;    // shared use function, b/c they woudl do the same thing anyways
1530         self.event_damage = func_breakable_damage;
1531 }
1532
1533 void Net_LinkEntity(entity e)
1534 {
1535         e.model = "net_entity";
1536         e.modelindex = 1;
1537         e.effects = EF_NODEPTHTEST | EF_LOWPRECISION;
1538 }
1539
1540 void adaptor_think2touch()
1541 {
1542         entity o;
1543         o = other;
1544         other = world;
1545         self.touch();
1546         other = o;
1547 }
1548
1549 void adaptor_think2use()
1550 {
1551         entity o, a;
1552         o = other;
1553         a = activator;
1554         activator = world;
1555         other = world;
1556         self.use();
1557         other = o;
1558         activator = a;
1559 }
1560
1561 // deferred dropping
1562 void DropToFloor_Handler()
1563 {
1564         droptofloor_builtin();
1565         self.dropped_origin = self.origin;
1566 }
1567
1568 void droptofloor()
1569 {
1570         InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1571 }
1572
1573
1574
1575 float trace_hits_box_a0, trace_hits_box_a1;
1576
1577 float trace_hits_box_1d(float end, float thmi, float thma)
1578 {
1579         if(end == 0)
1580         {
1581                 // just check if x is in range
1582                 if(0 < thmi)
1583                         return FALSE;
1584                 if(0 > thma)
1585                         return FALSE;
1586         }
1587         else
1588         {
1589                 // do the trace with respect to x
1590                 // 0 -> end has to stay in thmi -> thma
1591                 trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1592                 trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1593                 if(trace_hits_box_a0 > trace_hits_box_a1)
1594                         return FALSE;
1595         }
1596         return TRUE;
1597 }
1598
1599 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1600 {
1601         end -= start;
1602         thmi -= start;
1603         thma -= start;
1604         // now it is a trace from 0 to end
1605
1606         trace_hits_box_a0 = 0;
1607         trace_hits_box_a1 = 1;
1608
1609         if(!trace_hits_box_1d(end_x, thmi_x, thma_x))
1610                 return FALSE;
1611         if(!trace_hits_box_1d(end_y, thmi_y, thma_y))
1612                 return FALSE;
1613         if(!trace_hits_box_1d(end_z, thmi_z, thma_z))
1614                 return FALSE;
1615
1616         return TRUE;
1617 }
1618
1619 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1620 {
1621         return trace_hits_box(start, end, thmi - ma, thma - mi);
1622 }