data/qcsrc/server/miscfunctions.qc

   1 void() info_player_deathmatch; // needed for the other spawnpoints
   2 void() spawnpoint_use;
   3 string ColoredTeamName(float t);
   4
   5 float DistributeEvenly_amount;
   6 float DistributeEvenly_totalweight;
   7 void DistributeEvenly_Init(float amount, float totalweight)
   8 {
   9         if(DistributeEvenly_amount)
  10         {
  11                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  12                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  13         }
  14         if(totalweight == 0)
  15                 DistributeEvenly_amount = 0;
  16         else
  17                 DistributeEvenly_amount = amount;
  18         DistributeEvenly_totalweight = totalweight;
  19 }
  20 float DistributeEvenly_Get(float weight)
  21 {
  22         float f;
  23         if(weight <= 0)
  24                 return 0;
  25         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  26         DistributeEvenly_totalweight -= weight;
  27         DistributeEvenly_amount -= f;
  28         return f;
  29 }
  30
  31 void move_out_of_solid_expand(entity e, vector by)
  32 {
  33         float eps = 0.0625;
  34         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  35         if(trace_startsolid)
  36                 return;
  37         if(trace_fraction < 1)
  38         {
  39                 // hit something
  40                 // adjust origin in the other direction...
  41                 e.origin = e.origin - by * (1 - trace_fraction);
  42         }
  43 }
  44
  45 void move_out_of_solid(entity e)
  46 {
  47         vector o, m0, m1;
  48
  49         o = e.origin;
  50         traceline(o, o, MOVE_WORLDONLY, e);
  51         if(trace_startsolid)
  52         {
  53                 dprint("origin is in solid too! (", vtos(o), ")");
  54                 return;
  55         }
  56
  57         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  58         if(!trace_startsolid)
  59                 return;
  60
  61         m0 = e.mins;
  62         m1 = e.maxs;
  63         e.mins = '0 0 0';
  64         e.maxs = '0 0 0';
  65         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  66         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
  67         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
  68         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
  69         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
  70         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
  71         setorigin(e, e.origin);
  72
  73         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
  74         if(trace_startsolid)
  75         {
  76                 dprint("could not get out of solid (", vtos(o), ")\n");
  77                 return;
  78         }
  79 }
  80
  81 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  82 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  83 string STR_PLAYER = "player";
  84 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  85 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  86
  87 // change that to actually calling strcat when running on an engine without
  88 // unlimited tempstrings:
  89 // string strcat1(string s) = #115; // FRIK_FILE
  90 #define strcat1(s) (s)
  91
  92 float logfile_open;
  93 float logfile;
  94
  95 void(string s) bcenterprint
  96 {
  97         // TODO replace by MSG_ALL (would show it to spectators too, though)?
  98         entity head;
  99         FOR_EACH_PLAYER(head)
 100                 if(clienttype(head) == CLIENTTYPE_REAL)
 101                         centerprint(head, s);
 102 }
 103
 104 void(string s, float check_dangerous) ServerConsoleEcho =
 105 {
 106         local string ch;
 107         if (checkextension("DP_SV_PRINT"))
 108                 print(s, "\n");
 109         else
 110         {
 111                 localcmd("echo \"");
 112                 if(check_dangerous)
 113                 {
 114                         while(strlen(s))
 115                         {
 116                                 ch = substring(s, 0, 1);
 117                                 if(ch != "\"" && ch != "\r" && ch != "\n")
 118                                         localcmd(ch);
 119                                 s = substring(s, 1, strlen(s) - 1);
 120                         }
 121                 }
 122                 else
 123                 {
 124                         localcmd(s);
 125                 }
 126                 localcmd("\"\n");
 127         }
 128 }
 129
 130 void(string s, float check_dangerous) GameLogEcho =
 131 {
 132         string fn;
 133         float matches;
 134
 135         if(cvar("sv_eventlog_files"))
 136         {
 137                 if(!logfile_open)
 138                 {
 139                         logfile_open = TRUE;
 140                         matches = cvar("sv_eventlog_files_counter") + 1;
 141                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 142                         fn = ftos(matches);
 143                         if(strlen(fn) < 8)
 144                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 145                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 146                         logfile = fopen(fn, FILE_APPEND);
 147                 }
 148                 if(logfile >= 0)
 149                         fputs(logfile, strcat(s, "\n"));
 150         }
 151         if(cvar("sv_eventlog_console"))
 152         {
 153                 ServerConsoleEcho(s, check_dangerous);
 154         }
 155 }
 156
 157 void() GameLogInit =
 158 {
 159         logfile_open = 0;
 160         // will be opened later
 161 }
 162
 163 void() GameLogClose =
 164 {
 165         if(logfile_open && logfile >= 0)
 166         {
 167                 fclose(logfile);
 168                 logfile = -1;
 169         }
 170 }
 171
 172 void relocate_spawnpoint()
 173 {
 174         // nudge off the floor
 175         setorigin(self, self.origin + '0 0 1');
 176
 177         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 178         if (trace_startsolid)
 179         {
 180                 objerror("player spawn point in solid, mapper sucks!\n");
 181                 return;
 182         }
 183
 184         if(cvar("g_spawnpoints_autodrop"))
 185         {
 186                 setsize(self, PL_MIN, PL_MAX);
 187                 droptofloor();
 188         }
 189
 190         self.use = spawnpoint_use;
 191         self.team_saved = self.team;
 192 }
 193
 194 #define strstr strstrofs
 195 /*
 196 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 197 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 198 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 199 // BE CONSTANT OR strzoneD!
 200 float(string haystack, string needle, float offset) strstr =
 201 {
 202         float len, endpos;
 203         string found;
 204         len = strlen(needle);
 205         endpos = strlen(haystack) - len;
 206         while(offset <= endpos)
 207         {
 208                 found = substring(haystack, offset, len);
 209                 if(found == needle)
 210                         return offset;
 211                 offset = offset + 1;
 212         }
 213         return -1;
 214 }
 215 */
 216
 217 float NUM_NEAREST_ENTITIES = 4;
 218 entity nearest_entity[NUM_NEAREST_ENTITIES];
 219 float nearest_length[NUM_NEAREST_ENTITIES];
 220 entity(vector point, .string field, string value, vector axismod) findnearest =
 221 {
 222         entity localhead;
 223         float i;
 224         float j;
 225         float len;
 226         vector dist;
 227
 228         float num_nearest;
 229         num_nearest = 0;
 230
 231         localhead = find(world, field, value);
 232         while(localhead)
 233         {
 234                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 235                         dist = localhead.oldorigin;
 236                 else
 237                         dist = localhead.origin;
 238                 dist = dist - point;
 239                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 240                 len = vlen(dist);
 241
 242                 for(i = 0; i < num_nearest; ++i)
 243                 {
 244                         if(len < nearest_length[i])
 245                                 break;
 246                 }
 247
 248                 // now i tells us where to insert at
 249                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 250                 if(i < NUM_NEAREST_ENTITIES)
 251                 {
 252                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 253                         {
 254                                 nearest_length[j + 1] = nearest_length[j];
 255                                 nearest_entity[j + 1] = nearest_entity[j];
 256                         }
 257                         nearest_length[i] = len;
 258                         nearest_entity[i] = localhead;
 259                         if(num_nearest < NUM_NEAREST_ENTITIES)
 260                                 num_nearest = num_nearest + 1;
 261                 }
 262
 263                 localhead = find(localhead, field, value);
 264         }
 265
 266         // now use the first one from our list that we can see
 267         for(i = 0; i < num_nearest; ++i)
 268         {
 269                 traceline(point, nearest_entity[i].origin, TRUE, world);
 270                 if(trace_fraction == 1)
 271                 {
 272                         if(i != 0)
 273                         {
 274                                 dprint("Nearest point (");
 275                                 dprint(nearest_entity[0].netname);
 276                                 dprint(") is not visible, using a visible one.\n");
 277                         }
 278                         return nearest_entity[i];
 279                 }
 280         }
 281
 282         if(num_nearest == 0)
 283                 return world;
 284
 285         dprint("Not seeing any location point, using nearest as fallback.\n");
 286         /* DEBUGGING CODE:
 287         dprint("Candidates were: ");
 288         for(j = 0; j < num_nearest; ++j)
 289         {
 290                 if(j != 0)
 291                         dprint(", ");
 292                 dprint(nearest_entity[j].netname);
 293         }
 294         dprint("\n");
 295         */
 296
 297         return nearest_entity[0];
 298 }
 299
 300 void() target_location =
 301 {
 302         self.classname = "target_location";
 303         // location name in netname
 304         // eventually support: count, teamgame selectors, line of sight?
 305 };
 306
 307 void() info_location =
 308 {
 309         self.classname = "target_location";
 310         self.message = self.netname;
 311 };
 312
 313 string NearestLocation(vector p)
 314 {
 315         entity loc;
 316         string ret;
 317         ret = "somewhere";
 318         loc = findnearest(p, classname, "target_location", '1 1 1');
 319         if(loc)
 320         {
 321                 ret = loc.message;
 322         }
 323         else
 324         {
 325                 loc = findnearest(p, target, "###item###", '1 1 4');
 326                 if(loc)
 327                         ret = loc.netname;
 328         }
 329         return ret;
 330 }
 331
 332 string(string msg) formatmessage =
 333 {
 334         float p;
 335         float n;
 336         string msg_save;
 337         string escape;
 338         string replacement;
 339         msg_save = strzone(msg);
 340         p = 0;
 341         n = 7;
 342         while(1)
 343         {
 344                 if(n < 1)
 345                         break; // too many replacements
 346                 n = n - 1;
 347                 p = strstr(msg_save, "%", p); // NOTE: this destroys msg as it's a tempstring!
 348                 if(p < 0)
 349                         break;
 350                 replacement = substring(msg_save, p, 2);
 351                 escape = substring(msg_save, p + 1, 1);
 352                 if(escape == "%")
 353                         replacement = "%";
 354                 else if(escape == "a")
 355                         replacement = ftos(floor(self.armorvalue));
 356                 else if(escape == "h")
 357                         replacement = ftos(floor(self.health));
 358                 else if(escape == "l")
 359                         replacement = NearestLocation(self.origin);
 360                 else if(escape == "y")
 361                         replacement = NearestLocation(self.cursor_trace_endpos);
 362                 else if(escape == "d")
 363                         replacement = NearestLocation(self.death_origin);
 364                 else if(escape == "w")
 365                 {
 366                         float wep;
 367                         wep = self.weapon;
 368                         if(!wep)
 369                                 wep = self.switchweapon;
 370                         if(!wep)
 371                                 wep = self.cnt;
 372                         replacement = W_Name(wep);
 373                 }
 374                 else if(escape == "W")
 375                 {
 376                         if(self.items & IT_SHELLS) replacement = "shells";
 377                         else if(self.items & IT_NAILS) replacement = "bullets";
 378                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 379                         else if(self.items & IT_CELLS) replacement = "cells";
 380                         else replacement = "batteries"; // ;)
 381                 }
 382                 else if(escape == "x")
 383                 {
 384                         replacement = self.cursor_trace_ent.netname;
 385                         if(!replacement || !self.cursor_trace_ent)
 386                                 replacement = "nothing";
 387                 }
 388                 else if(escape == "p")
 389                 {
 390                         if(self.last_selected_player)
 391                                 replacement = self.last_selected_player.netname;
 392                         else
 393                                 replacement = "(nobody)";
 394                 }
 395                 msg = strcat(substring(msg_save, 0, p), replacement);
 396                 msg = strcat(msg, substring(msg_save, p+2, strlen(msg_save) - (p+2)));
 397                 strunzone(msg_save);
 398                 msg_save = strzone(msg);
 399                 p = p + 2;
 400         }
 401         msg = strcat(msg_save, "");
 402         strunzone(msg_save);
 403         return msg;
 404 }
 405
 406 /*
 407 =============
 408 GetCvars
 409 =============
 410 Called with:
 411   0:  sends the request
 412   >0: receives a cvar from name=argv(f) value=argv(f+1)
 413 */
 414 void GetCvars_handleString(float f, .string field, string name)
 415 {
 416         if(f < 0)
 417         {
 418                 if(self.field)
 419                         strunzone(self.field);
 420         }
 421         else if(f > 0)
 422         {
 423                 if(argv(f) == name)
 424                 {
 425                         if(self.field)
 426                                 strunzone(self.field);
 427                         self.field = strzone(argv(f + 1));
 428                 }
 429         }
 430         else
 431                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 432 }
 433 void GetCvars_handleFloat(float f, .float field, string name)
 434 {
 435         if(f < 0)
 436         {
 437         }
 438         else if(f > 0)
 439         {
 440                 if(argv(f) == name)
 441                         self.field = stof(argv(f + 1));
 442         }
 443         else
 444                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 445 }
 446 void GetCvars(float f)
 447 {
 448         GetCvars_handleFloat(f, autoswitch, "cl_autoswitch");
 449         GetCvars_handleFloat(f, cvar_cl_hidewaypoints, "cl_hidewaypoints");
 450         GetCvars_handleFloat(f, cvar_cl_zoomfactor, "cl_zoomfactor");
 451         GetCvars_handleFloat(f, cvar_cl_zoomspeed, "cl_zoomspeed");
 452         GetCvars_handleFloat(f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 453         GetCvars_handleFloat(f, cvar_cl_nogibs, "cl_nogibs");
 454         GetCvars_handleFloat(f, cvar_scr_centertime, "scr_centertime");
 455         GetCvars_handleFloat(f, cvar_cl_shownames, "cl_shownames");
 456         GetCvars_handleString(f, cvar_g_nexuizversion, "g_nexuizversion");
 457         GetCvars_handleFloat(f, cvar_cl_handicap, "cl_handicap");
 458 }
 459
 460 float fexists(string f)
 461 {
 462         float fh;
 463         fh = fopen(f, FILE_READ);
 464         if(fh < 0)
 465                 return FALSE;
 466         fclose(fh);
 467         return TRUE;
 468 }
 469
 470 void backtrace(string msg)
 471 {
 472         float dev;
 473         dev = cvar("developer");
 474         cvar_set("developer", "1");
 475         dprint("\n");
 476         dprint("--- CUT HERE ---\nWARNING: ");
 477         dprint(msg);
 478         dprint("\n");
 479         remove(world); // isn't there any better way to cause a backtrace?
 480         dprint("\n--- CUT UNTIL HERE ---\n");
 481         cvar_set("developer", ftos(dev));
 482 }
 483
 484 void DistributeFragsAmongTeam(entity p, float targetteam, float factor)
 485 {
 486         float nTeam;
 487         entity head;
 488         float f;
 489
 490         if(!teams_matter)
 491                 return;
 492
 493         //if(p.frags < 0)
 494         //{
 495         //      p.frags = 0; // do not harm the new team!
 496         //      return; // won't distribute negative scores
 497         //}
 498
 499         if(p.frags == -666)
 500                 return;
 501
 502         f = ceil(factor * p.frags);
 503         p.frags = p.frags - f;
 504
 505         nTeam = 0;
 506         FOR_EACH_PLAYER(head)
 507                 if(head != p)
 508                         if(head.team == targetteam)
 509                                 nTeam = nTeam + 1;
 510
 511         if(nTeam == 0)
 512                 return;
 513
 514         DistributeEvenly_Init(f, nTeam);
 515
 516         FOR_EACH_PLAYER(head)
 517                 if(head != p)
 518                         if(head.team == targetteam)
 519                                 head.frags = head.frags + DistributeEvenly_Get(1);
 520 }
 521
 522 string Team_ColorCode(float teamid)
 523 {
 524         if(teamid == COLOR_TEAM1)
 525                 return "^1";
 526         else if(teamid == COLOR_TEAM2)
 527                 return "^4";
 528         else if(teamid == COLOR_TEAM3)
 529                 return "^3";
 530         else if(teamid == COLOR_TEAM4)
 531                 return "^6";
 532         else
 533                 return "^7";
 534 }
 535 string Team_ColorName(float t)
 536 {
 537         // fixme: Search for team entities and get their .netname's!
 538         if(t == COLOR_TEAM1)
 539                 return "Red";
 540         if(t == COLOR_TEAM2)
 541                 return "Blue";
 542         if(t == COLOR_TEAM3)
 543                 return "Yellow";
 544         if(t == COLOR_TEAM4)
 545                 return "Pink";
 546         return "Neutral";
 547 }
 548 string Team_ColorNameLowerCase(float t)
 549 {
 550         // fixme: Search for team entities and get their .netname's!
 551         if(t == COLOR_TEAM1)
 552                 return "red";
 553         if(t == COLOR_TEAM2)
 554                 return "blue";
 555         if(t == COLOR_TEAM3)
 556                 return "yellow";
 557         if(t == COLOR_TEAM4)
 558                 return "pink";
 559         return "neutral";
 560 }
 561
 562 /*
 563 string decolorize(string s)
 564 {
 565         string out;
 566         out = "";
 567         while(s != "")
 568         {
 569                 float n;
 570                 string ch1, ch2;
 571                 n = 1;
 572                 ch1 = substring(s, 0, 1);
 573                 ch2 = substring(s, 1, 1);
 574                 if(ch1 == "^")
 575                 {
 576                         n = 2;
 577                         if(ch2 == "^")
 578                                 out = strcat(out, "^^");
 579                         else if(ch2 == "0")
 580                                 out = strcat1(out);
 581                         else if(ch2 == "1")
 582                                 out = strcat1(out);
 583                         else if(ch2 == "2")
 584                                 out = strcat1(out);
 585                         else if(ch2 == "3")
 586                                 out = strcat1(out);
 587                         else if(ch2 == "4")
 588                                 out = strcat1(out);
 589                         else if(ch2 == "5")
 590                                 out = strcat1(out);
 591                         else if(ch2 == "6")
 592                                 out = strcat1(out);
 593                         else if(ch2 == "7")
 594                                 out = strcat1(out);
 595                         else if(ch2 == "8")
 596                                 out = strcat1(out);
 597                         else if(ch2 == "9")
 598                                 out = strcat1(out);
 599                         else
 600                         {
 601                                 n = 1;
 602                                 out = strcat(out, "^^");
 603                         }
 604                         s = substring(s, n, strlen(s) - n);
 605                 }
 606                 else
 607                 {
 608                         s = substring(s, 1, strlen(s) - 1);
 609                         out = strcat(out, ch1);
 610                 }
 611         }
 612         return out;
 613 }
 614 #define strdecolorize(s) decolorize(s)
 615 #define strlennocol(s) strlen(decolorize(s))
 616 */
 617
 618 #define CENTERPRIO_POINT 1
 619 #define CENTERPRIO_SPAM 2
 620 #define CENTERPRIO_REBALANCE 2
 621 #define CENTERPRIO_VOTE 4
 622 #define CENTERPRIO_NORMAL 5
 623 #define CENTERPRIO_MAPVOTE 9
 624 #define CENTERPRIO_ADMIN 99
 625 .float centerprint_priority;
 626 .float centerprint_expires;
 627 void centerprint_atprio(entity e, float prio, string s)
 628 {
 629         if(intermission_running)
 630                 if(prio < CENTERPRIO_MAPVOTE)
 631                         return;
 632         if(time > e.centerprint_expires)
 633                 e.centerprint_priority = 0;
 634         if(prio >= e.centerprint_priority)
 635         {
 636                 e.centerprint_priority = prio;
 637                 e.centerprint_expires = time + e.cvar_scr_centertime;
 638                 centerprint_builtin(e, s);
 639         }
 640 }
 641 void centerprint_expire(entity e, float prio)
 642 {
 643         if(prio == e.centerprint_priority)
 644         {
 645                 e.centerprint_priority = 0;
 646                 centerprint_builtin(e, "");
 647         }
 648 }
 649 void centerprint(entity e, string s)
 650 {
 651         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 652 }
 653
 654 void VoteNag();
 655
 656 // decolorizes and team colors the player name when needed
 657 string playername(entity p)
 658 {
 659         string t;
 660         if(teams_matter && !intermission_running && p.classname == "player")
 661         {
 662                 t = Team_ColorCode(p.team);
 663                 return strcat(t, strdecolorize(p.netname));
 664         }
 665         else
 666                 return p.netname;
 667 }
 668
 669 vector(vector m1, vector m2) randompos =
 670 {
 671         local vector v;
 672         m2 = m2 - m1;
 673         v_x = m2_x * random() + m1_x;
 674         v_y = m2_y * random() + m1_y;
 675         v_z = m2_z * random() + m1_z;
 676         return  v;
 677 };
 678
 679 // requires that m2>m1 in all coordinates, and that m4>m3
 680 float(vector m1, vector m2, vector m3, vector m4) boxesoverlap = {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;};
 681
 682 // requires the same, but is a stronger condition
 683 float(vector smins, vector smaxs, vector bmins, vector bmaxs) boxinsidebox = {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;};
 684
 685 float g_pickup_shells;
 686 float g_pickup_shells_max;
 687 float g_pickup_nails;
 688 float g_pickup_nails_max;
 689 float g_pickup_rockets;
 690 float g_pickup_rockets_max;
 691 float g_pickup_cells;
 692 float g_pickup_cells_max;
 693 float g_pickup_armorsmall;
 694 float g_pickup_armorsmall_max;
 695 float g_pickup_armormedium;
 696 float g_pickup_armormedium_max;
 697 float g_pickup_armorlarge;
 698 float g_pickup_armorlarge_max;
 699 float g_pickup_healthsmall;
 700 float g_pickup_healthsmall_max;
 701 float g_pickup_healthmedium;
 702 float g_pickup_healthmedium_max;
 703 float g_pickup_healthlarge;
 704 float g_pickup_healthlarge_max;
 705 float g_pickup_healthmega;
 706 float g_pickup_healthmega_max;
 707
 708 float start_items;
 709 float start_switchweapon;
 710 float start_ammo_shells;
 711 float start_ammo_nails;
 712 float start_ammo_rockets;
 713 float start_ammo_cells;
 714 float start_health;
 715 float start_armorvalue;
 716
 717 void readlevelcvars(void)
 718 {
 719         sv_cheats = cvar("sv_cheats");
 720         g_cloaked = cvar("g_cloaked");
 721         g_footsteps = cvar("g_footsteps");
 722         g_grappling_hook = cvar("g_grappling_hook");
 723         g_instagib = cvar("g_instagib");
 724         g_laserguided_missile = cvar("g_laserguided_missile");
 725         g_midair = cvar("g_midair");
 726         g_minstagib = cvar("g_minstagib");
 727         g_nixnex = cvar("g_nixnex");
 728         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
 729         g_norecoil = cvar("g_norecoil");
 730         g_rocketarena = cvar("g_rocketarena");
 731         g_vampire = cvar("g_vampire");
 732
 733         g_pickup_shells                    = cvar("g_pickup_shells");
 734         g_pickup_shells_max                = cvar("g_pickup_shells_max");
 735         g_pickup_nails                     = cvar("g_pickup_nails");
 736         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
 737         g_pickup_rockets                   = cvar("g_pickup_rockets");
 738         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
 739         g_pickup_cells                     = cvar("g_pickup_cells");
 740         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
 741         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
 742         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
 743         g_pickup_armormedium               = cvar("g_pickup_armormedium");
 744         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
 745         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
 746         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
 747         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
 748         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
 749         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
 750         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
 751         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
 752         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
 753         g_pickup_healthmega                = cvar("g_pickup_healthmega");
 754         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
 755
 756         // initialize starting values for players
 757         start_items = 0;
 758         start_switchweapon = 0;
 759         start_ammo_shells = 0;
 760         start_ammo_nails = 0;
 761         start_ammo_rockets = 0;
 762         start_ammo_cells = 0;
 763         start_health = cvar("g_balance_health_start");
 764         start_armorvalue = cvar("g_balance_armor_start");
 765
 766         if(g_instagib)
 767         {
 768                 start_items = IT_NEX;
 769                 start_switchweapon = WEP_NEX;
 770                 weapon_action(start_switchweapon, WR_PRECACHE);
 771                 start_ammo_cells = 999;
 772         }
 773         else if(g_rocketarena)
 774         {
 775                 start_items = IT_ROCKET_LAUNCHER;
 776                 start_switchweapon = WEP_ROCKET_LAUNCHER;
 777                 weapon_action(start_switchweapon, WR_PRECACHE);
 778                 start_ammo_rockets = 999;
 779         }
 780         else if(g_nixnex)
 781         {
 782                 start_items = 0;
 783                 // will be done later
 784         }
 785         else if(g_minstagib)
 786         {
 787                 start_health = 100;
 788                 start_armorvalue = 0;
 789                 start_items = IT_NEX;
 790                 start_switchweapon = WEP_NEX;
 791                 weapon_action(start_switchweapon, WR_PRECACHE);
 792                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 793                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 794         }
 795         else
 796         {
 797                 if(g_lms)
 798                 {
 799                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 800                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 801                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 802                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 803                         start_health = cvar("g_lms_start_health");
 804                         start_armorvalue = cvar("g_lms_start_armor");
 805                 }
 806                 else if (cvar("g_use_ammunition")) {
 807                         start_ammo_shells = cvar("g_start_ammo_shells");
 808                         start_ammo_nails = cvar("g_start_ammo_nails");
 809                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 810                         start_ammo_cells = cvar("g_start_ammo_cells");
 811                 } else {
 812                         start_ammo_shells = cvar("g_pickup_shells_max");
 813                         start_ammo_nails = cvar("g_pickup_nails_max");
 814                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 815                         start_ammo_cells = cvar("g_pickup_cells_max");
 816                 }
 817
 818                 if (cvar("g_start_weapon_laser") || g_lms)
 819                 {
 820                         start_items = start_items | IT_LASER;
 821                         start_switchweapon = WEP_LASER;
 822                         weapon_action(start_switchweapon, WR_PRECACHE);
 823                 }
 824                 if (cvar("g_start_weapon_shotgun") || g_lms)
 825                 {
 826                         start_items = start_items | IT_SHOTGUN;
 827                         start_switchweapon = WEP_SHOTGUN;
 828                         weapon_action(start_switchweapon, WR_PRECACHE);
 829                 }
 830                 if (cvar("g_start_weapon_uzi") || g_lms)
 831                 {
 832                         start_items = start_items | IT_UZI;
 833                         start_switchweapon = WEP_UZI;
 834                         weapon_action(start_switchweapon, WR_PRECACHE);
 835                 }
 836                 if (cvar("g_start_weapon_grenadelauncher") || g_lms)
 837                 {
 838                         start_items = start_items | IT_GRENADE_LAUNCHER;
 839                         start_switchweapon = WEP_GRENADE_LAUNCHER;
 840                         weapon_action(start_switchweapon, WR_PRECACHE);
 841                 }
 842                 if (cvar("g_start_weapon_electro") || g_lms)
 843                 {
 844                         start_items = start_items | IT_ELECTRO;
 845                         start_switchweapon = WEP_ELECTRO;
 846                         weapon_action(start_switchweapon, WR_PRECACHE);
 847                 }
 848                 if (cvar("g_start_weapon_crylink") || g_lms)
 849                 {
 850                         start_items = start_items | IT_CRYLINK;
 851                         start_switchweapon = WEP_CRYLINK;
 852                         weapon_action(start_switchweapon, WR_PRECACHE);
 853                 }
 854                 if (cvar("g_start_weapon_nex") || g_lms)
 855                 {
 856                         start_items = start_items | IT_NEX;
 857                         start_switchweapon = WEP_NEX;
 858                         weapon_action(start_switchweapon, WR_PRECACHE);
 859                 }
 860                 if (cvar("g_start_weapon_hagar") || g_lms)
 861                 {
 862                         start_items = start_items | IT_HAGAR;
 863                         start_switchweapon = WEP_HAGAR;
 864                         weapon_action(start_switchweapon, WR_PRECACHE);
 865                 }
 866                 if (cvar("g_start_weapon_rocketlauncher") || g_lms)
 867                 {
 868                         start_items = start_items | IT_ROCKET_LAUNCHER;
 869                         start_switchweapon = WEP_ROCKET_LAUNCHER;
 870                         weapon_action(start_switchweapon, WR_PRECACHE);
 871                 }
 872         }
 873 }
 874
 875 /*
 876 // TODO sound pack system
 877 string soundpack;
 878
 879 string precache_sound_builtin (string s) = #19;
 880 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
 881 string precache_sound(string s)
 882 {
 883         return precache_sound_builtin(strcat(soundpack, s));
 884 }
 885 void play2(entity e, string filename)
 886 {
 887         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
 888 }
 889 void sound(entity e, float chan, string samp, float vol, float atten)
 890 {
 891         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
 892 }
 893 */
 894
 895 string precache_sound (string s) = #19;
 896 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
 897 void play2(entity e, string filename)
 898 {
 899         stuffcmd(e, strcat("play2 ", filename, "\n"));
 900 }
 901
 902 void play2team(float t, string filename)
 903 {
 904         local entity head;
 905         FOR_EACH_REALPLAYER(head)
 906         {
 907                 if (head.team == t)
 908                         play2(head, filename);
 909         }
 910 }
 911
 912 void PrecachePlayerSounds(string f);
 913 void precache_all_models(string pattern)
 914 {
 915         float globhandle, i, n;
 916         string f;
 917
 918         globhandle = search_begin(pattern, TRUE, FALSE);
 919         if(globhandle < 0)
 920                 return;
 921         n = search_getsize(globhandle);
 922         for(i = 0; i < n; ++i)
 923         {
 924                 //print(search_getfilename(globhandle, i), "\n");
 925                 f = search_getfilename(globhandle, i);
 926                 precache_model(f);
 927                 PrecachePlayerSounds(strcat(f, ".sounds"));
 928         }
 929         search_end(globhandle);
 930 }
 931
 932 void precache()
 933 {
 934         // gamemode related things
 935         precache_model ("models/misc/chatbubble.spr");
 936         precache_model ("models/misc/teambubble.spr");
 937         if (g_runematch)
 938         {
 939                 precache_model ("models/runematch/curse.mdl");
 940                 precache_model ("models/runematch/rune.mdl");
 941         }
 942
 943         // Precache all player models if desired
 944         if (cvar("sv_precacheplayermodels"))
 945         {
 946                 PrecachePlayerSounds("sound/player/default.sounds");
 947                 precache_all_models("models/player/*.zym");
 948                 precache_all_models("models/player/*.dpm");
 949                 precache_all_models("models/player/*.md3");
 950                 precache_all_models("models/player/*.psk");
 951                 //precache_model("models/player/carni.zym");
 952                 //precache_model("models/player/crash.zym");
 953                 //precache_model("models/player/grunt.zym");
 954                 //precache_model("models/player/headhunter.zym");
 955                 //precache_model("models/player/insurrectionist.zym");
 956                 //precache_model("models/player/jeandarc.zym");
 957                 //precache_model("models/player/lurk.zym");
 958                 //precache_model("models/player/lycanthrope.zym");
 959                 //precache_model("models/player/marine.zym");
 960                 //precache_model("models/player/nexus.zym");
 961                 //precache_model("models/player/pyria.zym");
 962                 //precache_model("models/player/shock.zym");
 963                 //precache_model("models/player/skadi.zym");
 964                 //precache_model("models/player/specop.zym");
 965                 //precache_model("models/player/visitant.zym");
 966         }
 967
 968         if (g_footsteps)
 969         {
 970                 precache_sound ("misc/footstep01.wav");
 971                 precache_sound ("misc/footstep02.wav");
 972                 precache_sound ("misc/footstep03.wav");
 973                 precache_sound ("misc/footstep04.wav");
 974                 precache_sound ("misc/footstep05.wav");
 975                 precache_sound ("misc/footstep06.wav");
 976         }
 977
 978         // gore and miscellaneous sounds
 979         //precache_sound ("misc/h2ohit.wav");
 980         precache_model ("models/gibs/bloodyskull.md3");
 981         precache_model ("models/gibs/chunk.mdl");
 982         precache_model ("models/gibs/eye.md3");
 983         precache_model ("models/gibs/gib1.md3");
 984         precache_model ("models/gibs/gib1.mdl");
 985         precache_model ("models/gibs/gib2.mdl");
 986         precache_model ("models/gibs/gib3.mdl");
 987         precache_model ("models/gibs/gib5.md3");
 988         precache_model ("models/hook.md3");
 989         precache_sound ("misc/armorimpact.wav");
 990         precache_sound ("misc/bodyimpact1.wav");
 991         precache_sound ("misc/bodyimpact2.wav");
 992         precache_sound ("misc/gib.wav");
 993         precache_sound ("misc/gib_splat01.wav");
 994         precache_sound ("misc/gib_splat02.wav");
 995         precache_sound ("misc/gib_splat03.wav");
 996         precache_sound ("misc/gib_splat04.wav");
 997         precache_sound ("misc/hit.wav");
 998         precache_sound ("misc/hitground1.wav");
 999         precache_sound ("misc/hitground2.wav");
1000         precache_sound ("misc/hitground3.wav");
1001         precache_sound ("misc/hitground4.wav");
1002         precache_sound ("misc/null.wav");
1003         precache_sound ("misc/spawn.wav");
1004         precache_sound ("misc/talk.wav");
1005         precache_sound ("misc/teleport.wav");
1006         precache_sound ("player/lava.wav");
1007         precache_sound ("player/slime.wav");
1008
1009         // announcer sounds - male
1010         //precache_sound ("announcer/male/electrobitch.wav");
1011         precache_sound ("announcer/male/03kills.wav");
1012         precache_sound ("announcer/male/05kills.wav");
1013         precache_sound ("announcer/male/10kills.wav");
1014         precache_sound ("announcer/male/15kills.wav");
1015         precache_sound ("announcer/male/20kills.wav");
1016         precache_sound ("announcer/male/25kills.wav");
1017         precache_sound ("announcer/male/30kills.wav");
1018         precache_sound ("announcer/male/botlike.wav");
1019         precache_sound ("announcer/male/yoda.wav");
1020
1021         // announcer sounds - robotic
1022         precache_sound ("announcer/robotic/1fragleft.wav");
1023         precache_sound ("announcer/robotic/1minuteremains.wav");
1024         precache_sound ("announcer/robotic/2fragsleft.wav");
1025         precache_sound ("announcer/robotic/3fragsleft.wav");
1026         if (g_minstagib)
1027         {
1028                 precache_sound ("announcer/robotic/lastsecond.wav");
1029                 precache_sound ("announcer/robotic/narrowly.wav");
1030                 precache_sound ("announcer/robotic/1.wav");
1031                 precache_sound ("announcer/robotic/2.wav");
1032                 precache_sound ("announcer/robotic/3.wav");
1033                 precache_sound ("announcer/robotic/4.wav");
1034                 precache_sound ("announcer/robotic/5.wav");
1035                 precache_sound ("announcer/robotic/6.wav");
1036                 precache_sound ("announcer/robotic/7.wav");
1037                 precache_sound ("announcer/robotic/8.wav");
1038                 precache_sound ("announcer/robotic/9.wav");
1039                 precache_sound ("announcer/robotic/10.wav");
1040         }
1041
1042         // common weapon precaches
1043         precache_sound ("weapons/weapon_switch.wav");
1044         precache_sound ("weapons/weaponpickup.wav");
1045         if (cvar("g_grappling_hook"))
1046         {
1047                 precache_sound ("weapons/hook_fire.wav"); // hook
1048                 precache_sound ("weapons/hook_impact.wav"); // hook
1049         }
1050
1051         if (cvar("sv_precacheweapons") || g_nixnex)
1052         {
1053                 //precache weapon models/sounds
1054                 local float wep;
1055                 wep = WEP_FIRST;
1056                 while (wep <= WEP_LAST)
1057                 {
1058                         weapon_action(wep, WR_PRECACHE);
1059                         wep = wep + 1;
1060                 }
1061         }
1062
1063         // plays music for the level if there is any
1064         if (self.noise)
1065         {
1066                 precache_sound (self.noise);
1067                 ambientsound ('0 0 0', self.noise, 1.00, ATTN_NONE);
1068         }
1069 }