data/qcsrc/server/miscfunctions.qc

   1 var void remove(entity e);
   2 void objerror(string s);
   3 void droptofloor();
   4 .vector dropped_origin;
   5
   6 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   7 void() spawnpoint_use;
   8 string ColoredTeamName(float t);
   9
  10 float RandomSelection_totalweight;
  11 float RandomSelection_best_priority;
  12 entity RandomSelection_chosen_ent;
  13 float RandomSelection_chosen_float;
  14 void RandomSelection_Init()
  15 {
  16         RandomSelection_totalweight = 0;
  17         RandomSelection_chosen_ent = world;
  18         RandomSelection_chosen_float = 0;
  19         RandomSelection_best_priority = -1;
  20 }
  21 void RandomSelection_Add(entity e, float f, float weight, float priority)
  22 {
  23         if(priority > RandomSelection_best_priority)
  24         {
  25                 RandomSelection_best_priority = priority;
  26                 RandomSelection_chosen_ent = e;
  27                 RandomSelection_chosen_float = f;
  28                 RandomSelection_totalweight = weight;
  29         }
  30         else if(priority == RandomSelection_best_priority)
  31         {
  32                 RandomSelection_totalweight += weight;
  33                 if(random() * RandomSelection_totalweight <= weight)
  34                 {
  35                         RandomSelection_chosen_ent = e;
  36                         RandomSelection_chosen_float = f;
  37                 }
  38         }
  39 }
  40
  41 float DistributeEvenly_amount;
  42 float DistributeEvenly_totalweight;
  43 void DistributeEvenly_Init(float amount, float totalweight)
  44 {
  45         if(DistributeEvenly_amount)
  46         {
  47                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  48                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  49         }
  50         if(totalweight == 0)
  51                 DistributeEvenly_amount = 0;
  52         else
  53                 DistributeEvenly_amount = amount;
  54         DistributeEvenly_totalweight = totalweight;
  55 }
  56 float DistributeEvenly_Get(float weight)
  57 {
  58         float f;
  59         if(weight <= 0)
  60                 return 0;
  61         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  62         DistributeEvenly_totalweight -= weight;
  63         DistributeEvenly_amount -= f;
  64         return f;
  65 }
  66
  67 void move_out_of_solid_expand(entity e, vector by)
  68 {
  69         float eps = 0.0625;
  70         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  71         if(trace_startsolid)
  72                 return;
  73         if(trace_fraction < 1)
  74         {
  75                 // hit something
  76                 // adjust origin in the other direction...
  77                 e.origin = e.origin - by * (1 - trace_fraction);
  78         }
  79 }
  80
  81 float move_out_of_solid(entity e)
  82 {
  83         vector o, m0, m1;
  84
  85         o = e.origin;
  86         traceline(o, o, MOVE_WORLDONLY, e);
  87         if(trace_startsolid)
  88                 return 0;
  89
  90         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  91         if(!trace_startsolid)
  92                 return 1;
  93
  94         m0 = e.mins;
  95         m1 = e.maxs;
  96         e.mins = '0 0 0';
  97         e.maxs = '0 0 0';
  98         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  99         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
 100         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
 101         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
 102         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
 103         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
 104         setorigin(e, e.origin);
 105
 106         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
 107         if(trace_startsolid)
 108         {
 109                 setorigin(e, o);
 110                 return 0;
 111         }
 112
 113         return 1;
 114 }
 115
 116 string STR_PLAYER = "player";
 117 string STR_SPECTATOR = "spectator";
 118 string STR_OBSERVER = "observer";
 119
 120 #if 0
 121 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
 122 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 123 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
 124 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
 125 #else
 126 #define FOR_EACH_CLIENTSLOT(v) for(v = world; (v = nextent(v)) && (num_for_edict(v) <= maxclients); )
 127 #define FOR_EACH_CLIENT(v) FOR_EACH_CLIENTSLOT(v) if(v.flags & FL_CLIENT)
 128 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
 129 #define FOR_EACH_PLAYER(v) FOR_EACH_CLIENT(v) if(v.classname == STR_PLAYER)
 130 #define FOR_EACH_REALPLAYER(v) FOR_EACH_REALCLIENT(v) if(v.classname == STR_PLAYER)
 131 #endif
 132
 133 // copies a string to a tempstring (so one can strunzone it)
 134 string strcat1(string s) = #115; // FRIK_FILE
 135
 136 float logfile_open;
 137 float logfile;
 138
 139 void bcenterprint(string s)
 140 {
 141         // TODO replace by MSG_ALL (would show it to spectators too, though)?
 142         entity head;
 143         FOR_EACH_PLAYER(head)
 144                 if(clienttype(head) == CLIENTTYPE_REAL)
 145                         centerprint(head, s);
 146 }
 147
 148 void GameLogEcho(string s)
 149 {
 150         string fn;
 151         float matches;
 152
 153         if(cvar("sv_eventlog_files"))
 154         {
 155                 if(!logfile_open)
 156                 {
 157                         logfile_open = TRUE;
 158                         matches = cvar("sv_eventlog_files_counter") + 1;
 159                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 160                         fn = ftos(matches);
 161                         if(strlen(fn) < 8)
 162                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 163                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 164                         logfile = fopen(fn, FILE_APPEND);
 165                         fputs(logfile, ":logversion:3\n");
 166                 }
 167                 if(logfile >= 0)
 168                 {
 169                         if(cvar("sv_eventlog_files_timestamps"))
 170                                 fputs(logfile, strcat(":time:", strftime(TRUE, "%Y-%m-%d %H:%M:%S", "\n", s, "\n")));
 171                         else
 172                                 fputs(logfile, strcat(s, "\n"));
 173                 }
 174         }
 175         if(cvar("sv_eventlog_console"))
 176         {
 177                 print(s, "\n");
 178         }
 179 }
 180
 181 void GameLogInit()
 182 {
 183         logfile_open = 0;
 184         // will be opened later
 185 }
 186
 187 void GameLogClose()
 188 {
 189         if(logfile_open && logfile >= 0)
 190         {
 191                 fclose(logfile);
 192                 logfile = -1;
 193         }
 194 }
 195
 196 float spawnpoint_nag;
 197 void relocate_spawnpoint()
 198 {
 199         // nudge off the floor
 200         setorigin(self, self.origin + '0 0 1');
 201
 202         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 203         if (trace_startsolid)
 204         {
 205                 vector o;
 206                 o = self.origin;
 207                 self.mins = PL_MIN;
 208                 self.maxs = PL_MAX;
 209                 if(!move_out_of_solid(self))
 210                         objerror("could not get out of solid at all!");
 211                 print("^1NOTE: this map needs FIXING. Spawnpoint at ", vtos(o - '0 0 1'));
 212                 print(" needs to be moved out of solid, e.g. by '", ftos(self.origin_x - o_x));
 213                 print(" ", ftos(self.origin_y - o_y));
 214                 print(" ", ftos(self.origin_z - o_z), "'\n");
 215                 if(cvar("g_spawnpoints_auto_move_out_of_solid"))
 216                 {
 217                         if(!spawnpoint_nag)
 218                                 print("\{1}^1NOTE: this map needs FIXING (it contains spawnpoints in solid, see server log)\n");
 219                         spawnpoint_nag = 1;
 220                 }
 221                 else
 222                 {
 223                         self.origin = o;
 224                         self.mins = self.maxs = '0 0 0';
 225                         objerror("player spawn point in solid, mapper sucks!\n");
 226                         return;
 227                 }
 228         }
 229
 230         if(cvar("g_spawnpoints_autodrop"))
 231         {
 232                 setsize(self, PL_MIN, PL_MAX);
 233                 droptofloor();
 234         }
 235
 236         self.use = spawnpoint_use;
 237         self.team_saved = self.team;
 238         if(!self.cnt)
 239                 self.cnt = 1;
 240
 241         if(g_ctf || g_assault || g_onslaught || g_domination)
 242         if(self.team)
 243                 have_team_spawns = 1;
 244
 245         if(cvar("r_showbboxes"))
 246         {
 247                 // show where spawnpoints point at too
 248                 makevectors(self.angles);
 249                 entity e;
 250                 e = spawn();
 251                 e.classname = "info_player_foo";
 252                 setorigin(e, self.origin + v_forward * 24);
 253                 setsize(e, '-8 -8 -8', '8 8 8');
 254                 e.solid = SOLID_TRIGGER;
 255         }
 256 }
 257
 258 #define strstr strstrofs
 259 /*
 260 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 261 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 262 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 263 // BE CONSTANT OR strzoneD!
 264 float strstr(string haystack, string needle, float offset)
 265 {
 266         float len, endpos;
 267         string found;
 268         len = strlen(needle);
 269         endpos = strlen(haystack) - len;
 270         while(offset <= endpos)
 271         {
 272                 found = substring(haystack, offset, len);
 273                 if(found == needle)
 274                         return offset;
 275                 offset = offset + 1;
 276         }
 277         return -1;
 278 }
 279 */
 280
 281 float NUM_NEAREST_ENTITIES = 4;
 282 entity nearest_entity[NUM_NEAREST_ENTITIES];
 283 float nearest_length[NUM_NEAREST_ENTITIES];
 284 entity findnearest(vector point, .string field, string value, vector axismod)
 285 {
 286         entity localhead;
 287         float i;
 288         float j;
 289         float len;
 290         vector dist;
 291
 292         float num_nearest;
 293         num_nearest = 0;
 294
 295         localhead = find(world, field, value);
 296         while(localhead)
 297         {
 298                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 299                         dist = localhead.oldorigin;
 300                 else
 301                         dist = localhead.origin;
 302                 dist = dist - point;
 303                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 304                 len = vlen(dist);
 305
 306                 for(i = 0; i < num_nearest; ++i)
 307                 {
 308                         if(len < nearest_length[i])
 309                                 break;
 310                 }
 311
 312                 // now i tells us where to insert at
 313                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 314                 if(i < NUM_NEAREST_ENTITIES)
 315                 {
 316                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 317                         {
 318                                 nearest_length[j + 1] = nearest_length[j];
 319                                 nearest_entity[j + 1] = nearest_entity[j];
 320                         }
 321                         nearest_length[i] = len;
 322                         nearest_entity[i] = localhead;
 323                         if(num_nearest < NUM_NEAREST_ENTITIES)
 324                                 num_nearest = num_nearest + 1;
 325                 }
 326
 327                 localhead = find(localhead, field, value);
 328         }
 329
 330         // now use the first one from our list that we can see
 331         for(i = 0; i < num_nearest; ++i)
 332         {
 333                 traceline(point, nearest_entity[i].origin, TRUE, world);
 334                 if(trace_fraction == 1)
 335                 {
 336                         if(i != 0)
 337                         {
 338                                 dprint("Nearest point (");
 339                                 dprint(nearest_entity[0].netname);
 340                                 dprint(") is not visible, using a visible one.\n");
 341                         }
 342                         return nearest_entity[i];
 343                 }
 344         }
 345
 346         if(num_nearest == 0)
 347                 return world;
 348
 349         dprint("Not seeing any location point, using nearest as fallback.\n");
 350         /* DEBUGGING CODE:
 351         dprint("Candidates were: ");
 352         for(j = 0; j < num_nearest; ++j)
 353         {
 354                 if(j != 0)
 355                         dprint(", ");
 356                 dprint(nearest_entity[j].netname);
 357         }
 358         dprint("\n");
 359         */
 360
 361         return nearest_entity[0];
 362 }
 363
 364 void spawnfunc_target_location()
 365 {
 366         self.classname = "target_location";
 367         // location name in netname
 368         // eventually support: count, teamgame selectors, line of sight?
 369 };
 370
 371 void spawnfunc_info_location()
 372 {
 373         self.classname = "target_location";
 374         self.message = self.netname;
 375 };
 376
 377 string NearestLocation(vector p)
 378 {
 379         entity loc;
 380         string ret;
 381         ret = "somewhere";
 382         loc = findnearest(p, classname, "target_location", '1 1 1');
 383         if(loc)
 384         {
 385                 ret = loc.message;
 386         }
 387         else
 388         {
 389                 loc = findnearest(p, target, "###item###", '1 1 4');
 390                 if(loc)
 391                         ret = loc.netname;
 392         }
 393         return ret;
 394 }
 395
 396 string formatmessage(string msg)
 397 {
 398         float p;
 399         float n;
 400         string msg_save;
 401         string escape;
 402         string replacement;
 403         msg_save = strzone(msg);
 404         p = 0;
 405         n = 7;
 406         while(1)
 407         {
 408                 if(n < 1)
 409                         break; // too many replacements
 410                 n = n - 1;
 411                 p = strstr(msg_save, "%", p); // NOTE: this destroys msg as it's a tempstring!
 412                 if(p < 0)
 413                         break;
 414                 replacement = substring(msg_save, p, 2);
 415                 escape = substring(msg_save, p + 1, 1);
 416                 if(escape == "%")
 417                         replacement = "%";
 418                 else if(escape == "a")
 419                         replacement = ftos(floor(self.armorvalue));
 420                 else if(escape == "h")
 421                         replacement = ftos(floor(self.health));
 422                 else if(escape == "l")
 423                         replacement = NearestLocation(self.origin);
 424                 else if(escape == "y")
 425                         replacement = NearestLocation(self.cursor_trace_endpos);
 426                 else if(escape == "d")
 427                         replacement = NearestLocation(self.death_origin);
 428                 else if(escape == "w")
 429                 {
 430                         float wep;
 431                         wep = self.weapon;
 432                         if(!wep)
 433                                 wep = self.switchweapon;
 434                         if(!wep)
 435                                 wep = self.cnt;
 436                         replacement = W_Name(wep);
 437                 }
 438                 else if(escape == "W")
 439                 {
 440                         if(self.items & IT_SHELLS) replacement = "shells";
 441                         else if(self.items & IT_NAILS) replacement = "bullets";
 442                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 443                         else if(self.items & IT_CELLS) replacement = "cells";
 444                         else replacement = "batteries"; // ;)
 445                 }
 446                 else if(escape == "x")
 447                 {
 448                         replacement = self.cursor_trace_ent.netname;
 449                         if(!replacement || !self.cursor_trace_ent)
 450                                 replacement = "nothing";
 451                 }
 452                 else if(escape == "p")
 453                 {
 454                         if(self.last_selected_player)
 455                                 replacement = self.last_selected_player.netname;
 456                         else
 457                                 replacement = "(nobody)";
 458                 }
 459                 msg = strcat(substring(msg_save, 0, p), replacement);
 460                 msg = strcat(msg, substring(msg_save, p+2, strlen(msg_save) - (p+2)));
 461                 strunzone(msg_save);
 462                 msg_save = strzone(msg);
 463                 p = p + 2;
 464         }
 465         msg = strcat(msg_save, "");
 466         strunzone(msg_save);
 467         return msg;
 468 }
 469
 470 /*
 471 =============
 472 GetCvars
 473 =============
 474 Called with:
 475   0:  sends the request
 476   >0: receives a cvar from name=argv(f) value=argv(f+1)
 477 */
 478 void GetCvars_handleString(string thisname, float f, .string field, string name)
 479 {
 480         if(f < 0)
 481         {
 482                 if(self.field)
 483                         strunzone(self.field);
 484                 self.field = string_null;
 485         }
 486         else if(f > 0)
 487         {
 488                 if(thisname == name)
 489                 {
 490                         if(self.field)
 491                                 strunzone(self.field);
 492                         self.field = strzone(argv(f + 1));
 493                 }
 494         }
 495         else
 496                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 497 }
 498 void GetCvars_handleString_Fixup(string thisname, float f, .string field, string name, string(string) func)
 499 {
 500         GetCvars_handleString(thisname, f, field, name);
 501         if(f >= 0) // also initialize to the fitting value for "" when sending cvars out
 502         if(thisname == name)
 503         {
 504                 string s;
 505                 s = func(strcat1(self.field));
 506                 if(s != self.field)
 507                 {
 508                         strunzone(self.field);
 509                         self.field = strzone(s);
 510                 }
 511         }
 512 }
 513 void GetCvars_handleFloat(string thisname, float f, .float field, string name)
 514 {
 515         if(f < 0)
 516         {
 517         }
 518         else if(f > 0)
 519         {
 520                 if(thisname == name)
 521                         self.field = stof(argv(f + 1));
 522         }
 523         else
 524                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 525 }
 526 string W_FixWeaponOrder_ForceComplete(string s);
 527 string W_FixWeaponOrder_AllowIncomplete(string s);
 528 float w_getbestweapon(entity e);
 529 void GetCvars(float f)
 530 {
 531         string s;
 532         if(f > 0)
 533                 s = strcat1(argv(f));
 534         GetCvars_handleFloat(s, f, autoswitch, "cl_autoswitch");
 535         GetCvars_handleFloat(s, f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 536         GetCvars_handleFloat(s, f, cvar_cl_nogibs, "cl_nogibs");
 537         GetCvars_handleFloat(s, f, cvar_scr_centertime, "scr_centertime");
 538         GetCvars_handleFloat(s, f, cvar_cl_shownames, "cl_shownames");
 539         GetCvars_handleString(s, f, cvar_g_nexuizversion, "g_nexuizversion");
 540         GetCvars_handleFloat(s, f, cvar_cl_handicap, "cl_handicap");
 541         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriority, "cl_weaponpriority", W_FixWeaponOrder_ForceComplete);
 542         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[0], "cl_weaponpriority0", W_FixWeaponOrder_AllowIncomplete);
 543         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[1], "cl_weaponpriority1", W_FixWeaponOrder_AllowIncomplete);
 544         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[2], "cl_weaponpriority2", W_FixWeaponOrder_AllowIncomplete);
 545         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[3], "cl_weaponpriority3", W_FixWeaponOrder_AllowIncomplete);
 546         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[4], "cl_weaponpriority4", W_FixWeaponOrder_AllowIncomplete);
 547         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[5], "cl_weaponpriority5", W_FixWeaponOrder_AllowIncomplete);
 548         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[6], "cl_weaponpriority6", W_FixWeaponOrder_AllowIncomplete);
 549         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[7], "cl_weaponpriority7", W_FixWeaponOrder_AllowIncomplete);
 550         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[8], "cl_weaponpriority8", W_FixWeaponOrder_AllowIncomplete);
 551         GetCvars_handleString_Fixup(s, f, cvar_cl_weaponpriorities[9], "cl_weaponpriority9", W_FixWeaponOrder_AllowIncomplete);
 552         GetCvars_handleFloat(s, f, cvar_cl_autotaunt, "cl_autotaunt");
 553         GetCvars_handleFloat(s, f, cvar_cl_voice_directional, "cl_voice_directional");
 554         GetCvars_handleFloat(s, f, cvar_cl_voice_directional_taunt_attenuation, "cl_voice_directional_taunt_attenuation");
 555         GetCvars_handleFloat(s, f, cvar_cl_hitsound, "cl_hitsound");
 556
 557         // fixup of switchweapon (needed for LMS or when spectating is disabled, as PutClientInServer comes too early)
 558         if(f > 0)
 559         {
 560                 if(s == "cl_weaponpriority")
 561                         self.switchweapon = w_getbestweapon(self);
 562         }
 563 }
 564
 565 float fexists(string f)
 566 {
 567         float fh;
 568         fh = fopen(f, FILE_READ);
 569         if(fh < 0)
 570                 return FALSE;
 571         fclose(fh);
 572         return TRUE;
 573 }
 574
 575 void backtrace(string msg)
 576 {
 577         float dev;
 578         dev = cvar("developer");
 579         cvar_set("developer", "1");
 580         dprint("\n");
 581         dprint("--- CUT HERE ---\nWARNING: ");
 582         dprint(msg);
 583         dprint("\n");
 584         remove(world); // isn't there any better way to cause a backtrace?
 585         dprint("\n--- CUT UNTIL HERE ---\n");
 586         cvar_set("developer", ftos(dev));
 587 }
 588
 589 string Team_ColorCode(float teamid)
 590 {
 591         if(teamid == COLOR_TEAM1)
 592                 return "^1";
 593         else if(teamid == COLOR_TEAM2)
 594                 return "^4";
 595         else if(teamid == COLOR_TEAM3)
 596                 return "^3";
 597         else if(teamid == COLOR_TEAM4)
 598                 return "^6";
 599         else
 600                 return "^7";
 601 }
 602 string Team_ColorName(float t)
 603 {
 604         // fixme: Search for team entities and get their .netname's!
 605         if(t == COLOR_TEAM1)
 606                 return "Red";
 607         if(t == COLOR_TEAM2)
 608                 return "Blue";
 609         if(t == COLOR_TEAM3)
 610                 return "Yellow";
 611         if(t == COLOR_TEAM4)
 612                 return "Pink";
 613         return "Neutral";
 614 }
 615 string Team_ColorNameLowerCase(float t)
 616 {
 617         // fixme: Search for team entities and get their .netname's!
 618         if(t == COLOR_TEAM1)
 619                 return "red";
 620         if(t == COLOR_TEAM2)
 621                 return "blue";
 622         if(t == COLOR_TEAM3)
 623                 return "yellow";
 624         if(t == COLOR_TEAM4)
 625                 return "pink";
 626         return "neutral";
 627 }
 628
 629 #define CENTERPRIO_POINT 1
 630 #define CENTERPRIO_SPAM 2
 631 #define CENTERPRIO_VOTE 4
 632 #define CENTERPRIO_NORMAL 5
 633 #define CENTERPRIO_SHIELDING 7
 634 #define CENTERPRIO_MAPVOTE 9
 635 #define CENTERPRIO_IDLEKICK 50
 636 #define CENTERPRIO_ADMIN 99
 637 .float centerprint_priority;
 638 .float centerprint_expires;
 639 void centerprint_atprio(entity e, float prio, string s)
 640 {
 641         if(intermission_running)
 642                 if(prio < CENTERPRIO_MAPVOTE)
 643                         return;
 644         if(time > e.centerprint_expires)
 645                 e.centerprint_priority = 0;
 646         if(prio >= e.centerprint_priority)
 647         {
 648                 e.centerprint_priority = prio;
 649                 if(timeoutStatus == 2)
 650                         e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 651                 else
 652                         e.centerprint_expires = time + e.cvar_scr_centertime;
 653                 centerprint_builtin(e, s);
 654         }
 655 }
 656 void centerprint_expire(entity e, float prio)
 657 {
 658         if(prio == e.centerprint_priority)
 659         {
 660                 e.centerprint_priority = 0;
 661                 centerprint_builtin(e, "");
 662         }
 663 }
 664 void centerprint(entity e, string s)
 665 {
 666         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 667 }
 668
 669 // decolorizes and team colors the player name when needed
 670 string playername(entity p)
 671 {
 672         string t;
 673         if(teams_matter && !intermission_running && p.classname == "player")
 674         {
 675                 t = Team_ColorCode(p.team);
 676                 return strcat(t, strdecolorize(p.netname));
 677         }
 678         else
 679                 return p.netname;
 680 }
 681
 682 vector randompos(vector m1, vector m2)
 683 {
 684         local vector v;
 685         m2 = m2 - m1;
 686         v_x = m2_x * random() + m1_x;
 687         v_y = m2_y * random() + m1_y;
 688         v_z = m2_z * random() + m1_z;
 689         return  v;
 690 };
 691
 692 // requires that m2>m1 in all coordinates, and that m4>m3
 693 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;};
 694
 695 // requires the same, but is a stronger condition
 696 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;};
 697
 698 float g_pickup_shells;
 699 float g_pickup_shells_max;
 700 float g_pickup_nails;
 701 float g_pickup_nails_max;
 702 float g_pickup_rockets;
 703 float g_pickup_rockets_max;
 704 float g_pickup_cells;
 705 float g_pickup_cells_max;
 706 float g_pickup_armorsmall;
 707 float g_pickup_armorsmall_max;
 708 float g_pickup_armormedium;
 709 float g_pickup_armormedium_max;
 710 float g_pickup_armorlarge;
 711 float g_pickup_armorlarge_max;
 712 float g_pickup_healthsmall;
 713 float g_pickup_healthsmall_max;
 714 float g_pickup_healthmedium;
 715 float g_pickup_healthmedium_max;
 716 float g_pickup_healthlarge;
 717 float g_pickup_healthlarge_max;
 718 float g_pickup_healthmega;
 719 float g_pickup_healthmega_max;
 720 float g_weaponarena;
 721 string g_weaponarena_list;
 722
 723 float start_weapons;
 724 float start_items;
 725 float start_ammo_shells;
 726 float start_ammo_nails;
 727 float start_ammo_rockets;
 728 float start_ammo_cells;
 729 float start_health;
 730 float start_armorvalue;
 731 float warmup_start_weapons;
 732 float warmup_start_ammo_shells;
 733 float warmup_start_ammo_nails;
 734 float warmup_start_ammo_rockets;
 735 float warmup_start_ammo_cells;
 736 float warmup_start_health;
 737 float warmup_start_armorvalue;
 738 float g_weapon_stay;
 739
 740 entity get_weaponinfo(float w);
 741
 742 void readplayerstartcvars()
 743 {
 744         entity e;
 745         float i, j, t;
 746         string s;
 747
 748         // initialize starting values for players
 749         start_weapons = 0;
 750         start_items = 0;
 751         start_ammo_shells = 0;
 752         start_ammo_nails = 0;
 753         start_ammo_rockets = 0;
 754         start_ammo_cells = 0;
 755         start_health = cvar("g_balance_health_start");
 756         start_armorvalue = cvar("g_balance_armor_start");
 757
 758         g_weaponarena = 0;
 759         s = cvar_string("g_weaponarena");
 760         if(s == "0")
 761         {
 762         }
 763         else if(s == "all")
 764         {
 765                 g_weaponarena_list = "All Weapons";
 766                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 767                 {
 768                         e = get_weaponinfo(j);
 769                         g_weaponarena |= e.weapons;
 770                         weapon_action(e.weapon, WR_PRECACHE);
 771                 }
 772         }
 773         else if(s == "most")
 774         {
 775                 g_weaponarena_list = "Most Weapons";
 776                 for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 777                 {
 778                         e = get_weaponinfo(j);
 779                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 780                         {
 781                                 g_weaponarena |= e.weapons;
 782                                 weapon_action(e.weapon, WR_PRECACHE);
 783                         }
 784                 }
 785         }
 786         else
 787         {
 788                 t = tokenize_sane(s);
 789                 g_weaponarena_list = "";
 790                 for(i = 0; i < t; ++i)
 791                 {
 792                         s = argv(i);
 793                         for(j = WEP_FIRST; j <= WEP_LAST; ++j)
 794                         {
 795                                 e = get_weaponinfo(j);
 796                                 if(e.netname == s)
 797                                 {
 798                                         g_weaponarena |= e.weapons;
 799                                         weapon_action(e.weapon, WR_PRECACHE);
 800                                         g_weaponarena_list = strcat(g_weaponarena_list, e.message, " & ");
 801                                         break;
 802                                 }
 803                         }
 804                         if(j > WEP_LAST)
 805                         {
 806                                 print("The weapon mutator list contains an unknown weapon ", s, ". Skipped.\n");
 807                         }
 808                 }
 809                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
 810         }
 811
 812         if(g_weaponarena)
 813         {
 814                 start_weapons = g_weaponarena;
 815                 start_ammo_rockets = 999;
 816                 start_ammo_shells = 999;
 817                 start_ammo_cells = 999;
 818                 start_ammo_nails = 999;
 819                 start_items |= IT_UNLIMITED_AMMO;
 820         }
 821         else if(g_nixnex)
 822         {
 823                 start_weapons = 0;
 824                 // will be done later
 825                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 826                 {
 827                         e = get_weaponinfo(i);
 828                         if(!(e.weapon))
 829                                 continue;
 830                         weapon_action(e.weapon, WR_PRECACHE);
 831                 }
 832         }
 833         else if(g_minstagib)
 834         {
 835                 start_health = 100;
 836                 start_armorvalue = 0;
 837                 start_weapons = WEPBIT_MINSTANEX;
 838                 weapon_action(WEP_MINSTANEX, WR_PRECACHE);
 839                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 840                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 841         }
 842         else
 843         {
 844                 if(g_lms)
 845                 {
 846                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 847                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 848                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 849                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 850                         start_health = cvar("g_lms_start_health");
 851                         start_armorvalue = cvar("g_lms_start_armor");
 852                 } else if (cvar("g_use_ammunition")) {
 853                         start_ammo_shells = cvar("g_start_ammo_shells");
 854                         start_ammo_nails = cvar("g_start_ammo_nails");
 855                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 856                         start_ammo_cells = cvar("g_start_ammo_cells");
 857                 } else {
 858                         start_ammo_shells = cvar("g_pickup_shells_max");
 859                         start_ammo_nails = cvar("g_pickup_nails_max");
 860                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 861                         start_ammo_cells = cvar("g_pickup_cells_max");
 862                         start_items |= IT_UNLIMITED_AMMO;
 863                 }
 864
 865                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 866                 {
 867                         e = get_weaponinfo(i);
 868                         if(!(e.weapon))
 869                                 continue;
 870                         if(((e.spawnflags & WEPSPAWNFLAG_NORMAL) && g_lms) || cvar(strcat("g_start_weapon_", e.netname)))
 871                         {
 872                                 start_weapons |= e.weapons;
 873                                 weapon_action(e.weapon, WR_PRECACHE);
 874                         }
 875                 }
 876         }
 877
 878         if(inWarmupStage)
 879         {
 880                 warmup_start_ammo_shells = start_ammo_shells;
 881                 warmup_start_ammo_nails = start_ammo_nails;
 882                 warmup_start_ammo_rockets = start_ammo_rockets;
 883                 warmup_start_ammo_cells = start_ammo_cells;
 884                 warmup_start_health = start_health;
 885                 warmup_start_armorvalue = start_armorvalue;
 886                 warmup_start_weapons = start_weapons;
 887
 888                 if(!g_weaponarena && !g_nixnex && !g_minstagib)
 889                 {
 890                         if(cvar("g_use_ammunition"))
 891                         {
 892                                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
 893                                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
 894                                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
 895                                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
 896                         }
 897                         warmup_start_health = cvar("g_warmup_start_health");
 898                         warmup_start_armorvalue = cvar("g_warmup_start_armor");
 899                         if(cvar("g_warmup_allguns"))
 900                         {
 901                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 902                                 {
 903                                         e = get_weaponinfo(i);
 904                                         if(!(e.weapon))
 905                                                 continue;
 906                                         if(e.spawnflags & WEPSPAWNFLAG_NORMAL)
 907                                         {
 908                                                 warmup_start_weapons |= e.weapons;
 909                                                 weapon_action(e.weapon, WR_PRECACHE);
 910                                         }
 911                                 }
 912                         }
 913                 }
 914         }
 915
 916         if(g_grappling_hook) // offhand hook
 917         {
 918                 start_weapons &~= WEPBIT_HOOK;
 919                 warmup_start_weapons &~= WEPBIT_HOOK;
 920         }
 921
 922         if(g_weapon_stay == 2)
 923         {
 924                 if(!start_ammo_shells) start_ammo_shells = g_pickup_shells;
 925                 if(!start_ammo_nails) start_ammo_shells = g_pickup_nails;
 926                 if(!start_ammo_cells) start_ammo_shells = g_pickup_cells;
 927                 if(!start_ammo_rockets) start_ammo_shells = g_pickup_rockets;
 928                 if(!warmup_start_ammo_shells) warmup_start_ammo_shells = g_pickup_shells;
 929                 if(!warmup_start_ammo_nails) warmup_start_ammo_shells = g_pickup_nails;
 930                 if(!warmup_start_ammo_cells) warmup_start_ammo_shells = g_pickup_cells;
 931                 if(!warmup_start_ammo_rockets) warmup_start_ammo_shells = g_pickup_rockets;
 932         }
 933
 934         start_ammo_shells = max(0, start_ammo_shells);
 935         start_ammo_nails = max(0, start_ammo_nails);
 936         start_ammo_cells = max(0, start_ammo_cells);
 937         start_ammo_rockets = max(0, start_ammo_rockets);
 938
 939         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
 940         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
 941         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
 942         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
 943 }
 944
 945 float g_bugrigs;
 946 float g_bugrigs_planar_movement;
 947 float g_bugrigs_planar_movement_car_jumping;
 948 float g_bugrigs_reverse_spinning;
 949 float g_bugrigs_reverse_speeding;
 950 float g_bugrigs_reverse_stopping;
 951 float g_bugrigs_air_steering;
 952 float g_bugrigs_angle_smoothing;
 953 float g_bugrigs_friction_floor;
 954 float g_bugrigs_friction_brake;
 955 float g_bugrigs_friction_air;
 956 float g_bugrigs_accel;
 957 float g_bugrigs_speed_ref;
 958 float g_bugrigs_speed_pow;
 959 float g_bugrigs_steer;
 960
 961 float g_touchexplode;
 962 float g_touchexplode_radius;
 963 float g_touchexplode_damage;
 964 float g_touchexplode_edgedamage;
 965 float g_touchexplode_force;
 966
 967 void readlevelcvars(void)
 968 {
 969         g_bugrigs = cvar("g_bugrigs");
 970         g_bugrigs_planar_movement = cvar("g_bugrigs_planar_movement");
 971         g_bugrigs_planar_movement_car_jumping = cvar("g_bugrigs_planar_movement_car_jumping");
 972         g_bugrigs_reverse_spinning = cvar("g_bugrigs_reverse_spinning");
 973         g_bugrigs_reverse_speeding = cvar("g_bugrigs_reverse_speeding");
 974         g_bugrigs_reverse_stopping = cvar("g_bugrigs_reverse_stopping");
 975         g_bugrigs_air_steering = cvar("g_bugrigs_air_steering");
 976         g_bugrigs_angle_smoothing = cvar("g_bugrigs_angle_smoothing");
 977         g_bugrigs_friction_floor = cvar("g_bugrigs_friction_floor");
 978         g_bugrigs_friction_brake = cvar("g_bugrigs_friction_brake");
 979         g_bugrigs_friction_air = cvar("g_bugrigs_friction_air");
 980         g_bugrigs_accel = cvar("g_bugrigs_accel");
 981         g_bugrigs_speed_ref = cvar("g_bugrigs_speed_ref");
 982         g_bugrigs_speed_pow = cvar("g_bugrigs_speed_pow");
 983         g_bugrigs_steer = cvar("g_bugrigs_steer");
 984
 985         g_touchexplode = cvar("g_touchexplode");
 986         g_touchexplode_radius = cvar("g_touchexplode_radius");
 987         g_touchexplode_damage = cvar("g_touchexplode_damage");
 988         g_touchexplode_edgedamage = cvar("g_touchexplode_edgedamage");
 989         g_touchexplode_force = cvar("g_touchexplode_force");
 990
 991         sv_clones = cvar("sv_clones");
 992         sv_cheats = cvar("sv_cheats");
 993         sv_gentle = cvar("sv_gentle");
 994         sv_foginterval = cvar("sv_foginterval");
 995         g_cloaked = cvar("g_cloaked");
 996         g_jump_grunt = cvar("g_jump_grunt");
 997         g_footsteps = cvar("g_footsteps");
 998         g_grappling_hook = cvar("g_grappling_hook");
 999         g_laserguided_missile = cvar("g_laserguided_missile");
1000         g_midair = cvar("g_midair");
1001         g_minstagib = cvar("g_minstagib");
1002         g_nixnex = cvar("g_nixnex");
1003         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
1004         g_norecoil = cvar("g_norecoil");
1005         g_vampire = cvar("g_vampire");
1006         sv_maxidle = cvar("sv_maxidle");
1007         sv_maxidle_spectatorsareidle = cvar("sv_maxidle_spectatorsareidle");
1008         sv_pogostick = cvar("sv_pogostick");
1009         sv_doublejump = cvar("sv_doublejump");
1010         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
1011         g_ctf_reverse = cvar("g_ctf_reverse");
1012
1013         inWarmupStage = cvar("g_warmup");
1014         g_warmup_limit = cvar("g_warmup_limit");
1015         g_warmup_allguns = cvar("g_warmup_allguns");
1016         g_warmup_allow_timeout = cvar("g_warmup_allow_timeout");
1017
1018         if(g_race && g_race_qualifying == 2 || g_arena || g_assault || cvar("g_campaign"))
1019                 inWarmupStage = 0; // these modes cannot work together, sorry
1020
1021         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
1022         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
1023         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
1024         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
1025         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
1026         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
1027
1028         if(g_minstagib) g_nixnex = g_weaponarena = 0;
1029         if(g_nixnex) g_weaponarena = 0;
1030         g_weaponarena = 0;
1031
1032         g_pickup_shells                    = cvar("g_pickup_shells");
1033         g_pickup_shells_max                = cvar("g_pickup_shells_max");
1034         g_pickup_nails                     = cvar("g_pickup_nails");
1035         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
1036         g_pickup_rockets                   = cvar("g_pickup_rockets");
1037         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
1038         g_pickup_cells                     = cvar("g_pickup_cells");
1039         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
1040         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
1041         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
1042         g_pickup_armormedium               = cvar("g_pickup_armormedium");
1043         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
1044         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
1045         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
1046         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
1047         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
1048         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
1049         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
1050         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
1051         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
1052         g_pickup_healthmega                = cvar("g_pickup_healthmega");
1053         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
1054
1055         g_weapon_stay = cvar("g_weapon_stay");
1056         if(!g_weapon_stay && (cvar("deathmatch") == 2))
1057                 g_weapon_stay = 1;
1058
1059         if not(inWarmupStage)
1060         {
1061                 game_starttime                 = cvar("g_start_delay");
1062                 if(game_starttime)
1063                 {
1064                         restartAnnouncer = spawn();
1065                         restartAnnouncer.think = restartAnnouncer_Think;
1066                         restartAnnouncer.nextthink = time + 0.1;
1067                         restartAnnouncer.spawnflags = 0;
1068                 }
1069         }
1070
1071         readplayerstartcvars();
1072 }
1073
1074 /*
1075 // TODO sound pack system
1076 string soundpack;
1077
1078 string precache_sound_builtin (string s) = #19;
1079 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
1080 string precache_sound(string s)
1081 {
1082         return precache_sound_builtin(strcat(soundpack, s));
1083 }
1084 void play2(entity e, string filename)
1085 {
1086         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
1087 }
1088 void sound(entity e, float chan, string samp, float vol, float atten)
1089 {
1090         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
1091 }
1092 */
1093
1094 // Sound functions
1095 string precache_sound (string s) = #19;
1096 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
1097 float precache_sound_index (string s) = #19;
1098
1099 #define SND_VOLUME      1
1100 #define SND_ATTENUATION 2
1101 #define SND_LARGEENTITY 8
1102 #define SND_LARGESOUND  16
1103
1104 void soundtoat(float dest, entity e, vector o, float chan, string samp, float vol, float atten)
1105 {
1106         float entno, idx;
1107         entno = num_for_edict(e);
1108         idx = precache_sound_index(samp);
1109
1110         float sflags;
1111         sflags = 0;
1112
1113         atten = floor(atten * 64);
1114         vol = floor(vol * 255);
1115
1116         if(vol != 255)
1117                 sflags |= SND_VOLUME;
1118         if(atten != 64)
1119                 sflags |= SND_ATTENUATION;
1120         if(entno >= 8192)
1121                 sflags |= SND_LARGEENTITY;
1122         if(idx >= 256)
1123                 sflags |= SND_LARGESOUND;
1124
1125         WriteByte(dest, SVC_SOUND);
1126         WriteByte(dest, sflags);
1127         if(sflags & SND_VOLUME)
1128                 WriteByte(dest, vol * 255);
1129         if(sflags & SND_ATTENUATION)
1130                 WriteByte(dest, atten);
1131         if(sflags & SND_LARGEENTITY)
1132         {
1133                 WriteShort(dest, entno);
1134                 WriteByte(dest, chan);
1135         }
1136         else
1137         {
1138                 WriteShort(dest, entno * 8 + chan);
1139         }
1140         if(sflags & SND_LARGESOUND)
1141                 WriteShort(dest, idx);
1142         else
1143                 WriteByte(dest, idx);
1144
1145         WriteCoord(dest, o_x);
1146         WriteCoord(dest, o_y);
1147         WriteCoord(dest, o_z);
1148 }
1149 void soundto(float dest, entity e, float chan, string samp, float vol, float atten)
1150 {
1151         vector o;
1152         o = e.origin + 0.5 * (e.mins + e.maxs);
1153         soundtoat(dest, e, o, chan, samp, vol, atten);
1154 }
1155 void soundat(entity e, vector o, float chan, string samp, float vol, float atten)
1156 {
1157         soundtoat(MSG_BROADCAST, e, o, chan, samp, vol, atten);
1158 }
1159 void stopsoundto(float dest, entity e, float chan)
1160 {
1161         float entno;
1162         entno = num_for_edict(e);
1163
1164         if(entno >= 8192)
1165         {
1166                 float idx, sflags;
1167                 idx = precache_sound_index("misc/null.wav");
1168                 sflags = SND_LARGEENTITY;
1169                 if(idx >= 256)
1170                         sflags |= SND_LARGESOUND;
1171                 WriteByte(dest, SVC_SOUND);
1172                 WriteByte(dest, sflags);
1173                 WriteShort(dest, entno);
1174                 WriteByte(dest, chan);
1175                 if(sflags & SND_LARGESOUND)
1176                         WriteShort(dest, idx);
1177                 else
1178                         WriteByte(dest, idx);
1179                 WriteCoord(dest, e.origin_x);
1180                 WriteCoord(dest, e.origin_y);
1181                 WriteCoord(dest, e.origin_z);
1182         }
1183         else
1184         {
1185                 WriteByte(dest, SVC_STOPSOUND);
1186                 WriteShort(dest, entno * 8 + chan);
1187         }
1188 }
1189 void stopsound(entity e, float chan)
1190 {
1191         stopsoundto(MSG_BROADCAST, e, chan); // unreliable, gets there fast
1192         stopsoundto(MSG_ALL, e, chan); // in case of packet loss
1193 }
1194
1195 void play2(entity e, string filename)
1196 {
1197         //stuffcmd(e, strcat("play2 ", filename, "\n"));
1198         msg_entity = e;
1199         soundtoat(MSG_ONE, world, '0 0 0', CHAN_AUTO, filename, VOL_BASE, ATTN_NONE);
1200 }
1201
1202 .float announcetime;
1203 float announce(entity player, string msg)
1204 {
1205         if(time > player.announcetime)
1206         if(clienttype(player) == CLIENTTYPE_REAL)
1207         {
1208                 player.announcetime = time + 1;
1209                 play2(player, msg);
1210                 return TRUE;
1211         }
1212         return FALSE;
1213 }
1214
1215 void play2team(float t, string filename)
1216 {
1217         local entity head;
1218         FOR_EACH_REALPLAYER(head)
1219         {
1220                 if (head.team == t)
1221                         play2(head, filename);
1222         }
1223 }
1224
1225 void play2all(string samp)
1226 {
1227         sound(world, CHAN_AUTO, samp, VOL_BASE, ATTN_NONE);
1228 }
1229
1230 void PrecachePlayerSounds(string f);
1231 void precache_all_models(string pattern)
1232 {
1233         float globhandle, i, n;
1234         string f;
1235
1236         globhandle = search_begin(pattern, TRUE, FALSE);
1237         if(globhandle < 0)
1238                 return;
1239         n = search_getsize(globhandle);
1240         for(i = 0; i < n; ++i)
1241         {
1242                 //print(search_getfilename(globhandle, i), "\n");
1243                 f = search_getfilename(globhandle, i);
1244                 precache_model(f);
1245                 PrecachePlayerSounds(strcat(f, ".sounds"));
1246         }
1247         search_end(globhandle);
1248 }
1249
1250 void precache()
1251 {
1252         // gamemode related things
1253         precache_model ("null");
1254         precache_model ("models/misc/chatbubble.spr");
1255         precache_model ("models/misc/teambubble.spr");
1256         if (g_runematch)
1257         {
1258                 precache_model ("models/runematch/curse.mdl");
1259                 precache_model ("models/runematch/rune.mdl");
1260         }
1261
1262 #ifdef TTURRETS_ENABLED
1263     if(cvar("g_turrets"))
1264         turrets_precash();
1265 #endif
1266
1267         // Precache all player models if desired
1268         if (cvar("sv_precacheplayermodels"))
1269         {
1270                 PrecachePlayerSounds("sound/player/default.sounds");
1271                 precache_all_models("models/player/*.zym");
1272                 precache_all_models("models/player/*.dpm");
1273                 precache_all_models("models/player/*.md3");
1274                 precache_all_models("models/player/*.psk");
1275                 //precache_model("models/player/carni.zym");
1276                 //precache_model("models/player/crash.zym");
1277                 //precache_model("models/player/grunt.zym");
1278                 //precache_model("models/player/headhunter.zym");
1279                 //precache_model("models/player/insurrectionist.zym");
1280                 //precache_model("models/player/jeandarc.zym");
1281                 //precache_model("models/player/lurk.zym");
1282                 //precache_model("models/player/lycanthrope.zym");
1283                 //precache_model("models/player/marine.zym");
1284                 //precache_model("models/player/nexus.zym");
1285                 //precache_model("models/player/pyria.zym");
1286                 //precache_model("models/player/shock.zym");
1287                 //precache_model("models/player/skadi.zym");
1288                 //precache_model("models/player/specop.zym");
1289                 //precache_model("models/player/visitant.zym");
1290         }
1291
1292         if(cvar("sv_defaultcharacter"))
1293         {
1294                 string s;
1295                 s = cvar_string("sv_defaultplayermodel_red");
1296                 if(s != "")
1297                 {
1298                         precache_model(s);
1299                         PrecachePlayerSounds(strcat(s, ".sounds"));
1300                 }
1301                 s = cvar_string("sv_defaultplayermodel_blue");
1302                 if(s != "")
1303                 {
1304                         precache_model(s);
1305                         PrecachePlayerSounds(strcat(s, ".sounds"));
1306                 }
1307                 s = cvar_string("sv_defaultplayermodel_yellow");
1308                 if(s != "")
1309                 {
1310                         precache_model(s);
1311                         PrecachePlayerSounds(strcat(s, ".sounds"));
1312                 }
1313                 s = cvar_string("sv_defaultplayermodel_pink");
1314                 if(s != "")
1315                 {
1316                         precache_model(s);
1317                         PrecachePlayerSounds(strcat(s, ".sounds"));
1318                 }
1319                 s = cvar_string("sv_defaultplayermodel");
1320                 if(s != "")
1321                 {
1322                         precache_model(s);
1323                         PrecachePlayerSounds(strcat(s, ".sounds"));
1324                 }
1325         }
1326
1327         if (g_footsteps)
1328         {
1329                 PrecacheGlobalSound((globalsound_step = "misc/footstep0 6"));
1330                 PrecacheGlobalSound((globalsound_metalstep = "misc/metalfootstep0 6"));
1331         }
1332
1333         // gore and miscellaneous sounds
1334         //precache_sound ("misc/h2ohit.wav");
1335         precache_model ("models/gibs/bloodyskull.md3");
1336         precache_model ("models/gibs/chunk.mdl");
1337         precache_model ("models/gibs/eye.md3");
1338         precache_model ("models/gibs/gib1.md3");
1339         precache_model ("models/gibs/gib2.md3");
1340         precache_model ("models/gibs/gib3.md3");
1341         precache_model ("models/gibs/gib4.md3");
1342         precache_model ("models/gibs/gib5.md3");
1343         precache_model ("models/gibs/gib6.md3");
1344         precache_model ("models/gibs/smallchest.md3");
1345         precache_model ("models/gibs/chest.md3");
1346         precache_model ("models/gibs/arm.md3");
1347         precache_model ("models/gibs/leg1.md3");
1348         precache_model ("models/gibs/leg2.md3");
1349         precache_model ("models/hook.md3");
1350         precache_sound ("misc/armorimpact.wav");
1351         precache_sound ("misc/bodyimpact1.wav");
1352         precache_sound ("misc/bodyimpact2.wav");
1353         precache_sound ("misc/gib.wav");
1354         precache_sound ("misc/gib_splat01.wav");
1355         precache_sound ("misc/gib_splat02.wav");
1356         precache_sound ("misc/gib_splat03.wav");
1357         precache_sound ("misc/gib_splat04.wav");
1358         precache_sound ("misc/hit.wav");
1359         PrecacheGlobalSound((globalsound_fall = "misc/hitground 4"));
1360         PrecacheGlobalSound((globalsound_metalfall = "misc/metalhitground 4"));
1361         precache_sound ("misc/null.wav");
1362         precache_sound ("misc/spawn.wav");
1363         precache_sound ("misc/talk.wav");
1364         precache_sound ("misc/teleport.wav");
1365         precache_sound ("player/lava.wav");
1366         precache_sound ("player/slime.wav");
1367
1368         // announcer sounds - male
1369         precache_sound ("announcer/male/electrobitch.wav");
1370         precache_sound ("announcer/male/airshot.wav");
1371         precache_sound ("announcer/male/03kills.wav");
1372         precache_sound ("announcer/male/05kills.wav");
1373         precache_sound ("announcer/male/10kills.wav");
1374         precache_sound ("announcer/male/15kills.wav");
1375         precache_sound ("announcer/male/20kills.wav");
1376         precache_sound ("announcer/male/25kills.wav");
1377         precache_sound ("announcer/male/30kills.wav");
1378         precache_sound ("announcer/male/botlike.wav");
1379         precache_sound ("announcer/male/yoda.wav");
1380         precache_sound ("announcer/male/headshot.wav");
1381         precache_sound ("announcer/male/impressive.wav");
1382
1383         // announcer sounds - robotic
1384         precache_sound ("announcer/robotic/prepareforbattle.wav");
1385         precache_sound ("announcer/robotic/begin.wav");
1386         precache_sound ("announcer/robotic/timeoutcalled.wav");
1387         precache_sound ("announcer/robotic/1fragleft.wav");
1388         precache_sound ("announcer/robotic/1minuteremains.wav");
1389         precache_sound ("announcer/robotic/2fragsleft.wav");
1390         precache_sound ("announcer/robotic/3fragsleft.wav");
1391         if (g_minstagib)
1392         {
1393                 precache_sound ("announcer/robotic/lastsecond.wav");
1394                 precache_sound ("announcer/robotic/narrowly.wav");
1395         }
1396
1397         precache_model ("models/sprites/1.spr32");
1398         precache_model ("models/sprites/2.spr32");
1399         precache_model ("models/sprites/3.spr32");
1400         precache_model ("models/sprites/4.spr32");
1401         precache_model ("models/sprites/5.spr32");
1402         precache_model ("models/sprites/6.spr32");
1403         precache_model ("models/sprites/7.spr32");
1404         precache_model ("models/sprites/8.spr32");
1405         precache_model ("models/sprites/9.spr32");
1406         precache_model ("models/sprites/10.spr32");
1407         precache_sound ("announcer/robotic/1.wav");
1408         precache_sound ("announcer/robotic/2.wav");
1409         precache_sound ("announcer/robotic/3.wav");
1410         precache_sound ("announcer/robotic/4.wav");
1411         precache_sound ("announcer/robotic/5.wav");
1412         precache_sound ("announcer/robotic/6.wav");
1413         precache_sound ("announcer/robotic/7.wav");
1414         precache_sound ("announcer/robotic/8.wav");
1415         precache_sound ("announcer/robotic/9.wav");
1416         precache_sound ("announcer/robotic/10.wav");
1417
1418         // common weapon precaches
1419         precache_sound ("weapons/weapon_switch.wav");
1420         precache_sound ("weapons/weaponpickup.wav");
1421         if (cvar("g_grappling_hook"))
1422         {
1423                 precache_sound ("weapons/hook_fire.wav"); // hook
1424                 precache_sound ("weapons/hook_impact.wav"); // hook
1425         }
1426
1427         if (cvar("sv_precacheweapons") || g_nixnex)
1428         {
1429                 //precache weapon models/sounds
1430                 local float wep;
1431                 wep = WEP_FIRST;
1432                 while (wep <= WEP_LAST)
1433                 {
1434                         weapon_action(wep, WR_PRECACHE);
1435                         wep = wep + 1;
1436                 }
1437         }
1438
1439 #if 0
1440         // Disabled this code because it simply does not work (e.g. ignores bgmvolume, overlaps with "cd loop" controlled tracks).
1441
1442         if (!self.noise && self.music) // quake 3 uses the music field
1443                 self.noise = self.music;
1444
1445         // plays music for the level if there is any
1446         if (self.noise)
1447         {
1448                 precache_sound (self.noise);
1449                 ambientsound ('0 0 0', self.noise, VOL_BASE, ATTN_NONE);
1450         }
1451 #endif
1452 }
1453
1454 // sorry, but using \ in macros breaks line numbers
1455 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname,statement) entity varname; varname = msg_entity; FOR_EACH_REALCLIENT(msg_entity) if(msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) statement msg_entity = varname
1456 #define WRITESPECTATABLE_MSG_ONE(statement) WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement)
1457 #define WRITESPECTATABLE(msg,statement) if(msg == MSG_ONE) { WRITESPECTATABLE_MSG_ONE(statement); } else statement float WRITESPECTATABLE_workaround = 0
1458
1459 vector ExactTriggerHit_mins;
1460 vector ExactTriggerHit_maxs;
1461 float ExactTriggerHit_Recurse()
1462 {
1463         float s;
1464         entity se;
1465         float f;
1466
1467         tracebox('0 0 0', ExactTriggerHit_mins, ExactTriggerHit_maxs, '0 0 0', MOVE_NORMAL, other);
1468         if not(trace_ent)
1469                 return 0;
1470         if(trace_ent == self)
1471                 return 1;
1472
1473         se = trace_ent;
1474         s = se.solid;
1475         se.solid = SOLID_NOT;
1476         f = ExactTriggerHit_Recurse();
1477         se.solid = s;
1478
1479         return f;
1480 }
1481
1482 float ExactTriggerHit()
1483 {
1484         float f, s;
1485
1486         if not(self.modelindex)
1487                 return 1;
1488
1489         s = self.solid;
1490         self.solid = SOLID_BSP;
1491         ExactTriggerHit_mins = other.absmin;
1492         ExactTriggerHit_maxs = other.absmax;
1493         f = ExactTriggerHit_Recurse();
1494         self.solid = s;
1495
1496         return f;
1497 }
1498
1499 // WARNING: this kills the trace globals
1500 #define EXACTTRIGGER_TOUCH if not(ExactTriggerHit()) return
1501 #define EXACTTRIGGER_INIT  InitSolidBSPTrigger(); self.solid = SOLID_TRIGGER
1502
1503 #define INITPRIO_FIRST              0
1504 #define INITPRIO_GAMETYPE           0
1505 #define INITPRIO_GAMETYPE_FALLBACK  1
1506 #define INITPRIO_CVARS              5
1507 #define INITPRIO_FINDTARGET        10
1508 #define INITPRIO_DROPTOFLOOR       20
1509 #define INITPRIO_SETLOCATION       90
1510 #define INITPRIO_LINKDOORS         91
1511 #define INITPRIO_LAST              99
1512
1513 .void(void) initialize_entity;
1514 .float initialize_entity_order;
1515 .entity initialize_entity_next;
1516 entity initialize_entity_first;
1517
1518 void make_safe_for_remove(entity e)
1519 {
1520         if(e.initialize_entity)
1521         {
1522                 entity ent, prev;
1523                 for(ent = initialize_entity_first; ent; )
1524                 {
1525                         if((ent == e) || ((ent.classname == "initialize_entity") && (ent.enemy == e)))
1526                         {
1527                                 print("make_safe_for_remove: getting rid of initializer ", etos(ent), "\n");
1528                                 // skip it in linked list
1529                                 if(prev)
1530                                 {
1531                                         prev.initialize_entity_next = ent.initialize_entity_next;
1532                                         ent = prev.initialize_entity_next;
1533                                 }
1534                                 else
1535                                 {
1536                                         initialize_entity_first = ent.initialize_entity_next;
1537                                         ent = initialize_entity_first;
1538                                 }
1539                         }
1540                         else
1541                         {
1542                                 prev = ent;
1543                                 ent = ent.initialize_entity_next;
1544                         }
1545                 }
1546         }
1547 }
1548
1549 void objerror(string s)
1550 {
1551         make_safe_for_remove(self);
1552         objerror_builtin(s);
1553 }
1554
1555 void remove_unsafely(entity e)
1556 {
1557         remove_builtin(e);
1558 }
1559
1560 void remove_safely(entity e)
1561 {
1562         make_safe_for_remove(e);
1563         remove_builtin(e);
1564 }
1565
1566 void InitializeEntity(entity e, void(void) func, float order)
1567 {
1568         entity prev, cur;
1569
1570         if(!e || e.initialize_entity)
1571         {
1572                 // make a proxy initializer entity
1573                 entity e_old;
1574                 e_old = e;
1575                 e = spawn();
1576                 e.classname = "initialize_entity";
1577                 e.enemy = e_old;
1578         }
1579
1580         e.initialize_entity = func;
1581         e.initialize_entity_order = order;
1582
1583         cur = initialize_entity_first;
1584         for(;;)
1585         {
1586                 if(!cur || cur.initialize_entity_order > order)
1587                 {
1588                         // insert between prev and cur
1589                         if(prev)
1590                                 prev.initialize_entity_next = e;
1591                         else
1592                                 initialize_entity_first = e;
1593                         e.initialize_entity_next = cur;
1594                         return;
1595                 }
1596                 prev = cur;
1597                 cur = cur.initialize_entity_next;
1598         }
1599 }
1600 void InitializeEntitiesRun()
1601 {
1602         entity startoflist;
1603         startoflist = initialize_entity_first;
1604         initialize_entity_first = world;
1605         for(self = startoflist; self; )
1606         {
1607                 entity e;
1608                 var void(void) func;
1609                 e = self.initialize_entity_next;
1610                 func = self.initialize_entity;
1611                 self.initialize_entity_order = 0;
1612                 self.initialize_entity = func_null;
1613                 self.initialize_entity_next = world;
1614                 if(self.classname == "initialize_entity")
1615                 {
1616                         entity e_old;
1617                         e_old = self.enemy;
1618                         remove_builtin(self);
1619                         self = e_old;
1620                 }
1621                 //dprint("Delayed initialization: ", self.classname, "\n");
1622                 func();
1623                 self = e;
1624         }
1625 }
1626
1627 .float uncustomizeentityforclient_set;
1628 .void(void) uncustomizeentityforclient;
1629 void(void) SUB_Nullpointer = #0;
1630 void UncustomizeEntitiesRun()
1631 {
1632         entity oldself;
1633         oldself = self;
1634         for(self = world; (self = findfloat(self, uncustomizeentityforclient_set, 1)); )
1635                 self.uncustomizeentityforclient();
1636         self = oldself;
1637 }
1638 void SetCustomizer(entity e, float(void) customizer, void(void) uncustomizer)
1639 {
1640         e.customizeentityforclient = customizer;
1641         e.uncustomizeentityforclient = uncustomizer;
1642         e.uncustomizeentityforclient_set = (uncustomizer != SUB_Nullpointer);
1643 }
1644
1645 .float nottargeted;
1646 #define IFTARGETED if(!self.nottargeted && self.targetname != "")
1647
1648 void Net_LinkEntity(entity e)
1649 {
1650         setmodel(e, "null");
1651         e.effects = EF_NODEPTHTEST | EF_LOWPRECISION;
1652 }
1653
1654 void adaptor_think2touch()
1655 {
1656         entity o;
1657         o = other;
1658         other = world;
1659         self.touch();
1660         other = o;
1661 }
1662
1663 void adaptor_think2use()
1664 {
1665         entity o, a;
1666         o = other;
1667         a = activator;
1668         activator = world;
1669         other = world;
1670         self.use();
1671         other = o;
1672         activator = a;
1673 }
1674
1675 // deferred dropping
1676 void DropToFloor_Handler()
1677 {
1678         droptofloor_builtin();
1679         self.dropped_origin = self.origin;
1680 }
1681
1682 void droptofloor()
1683 {
1684         InitializeEntity(self, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
1685 }
1686
1687
1688
1689 float trace_hits_box_a0, trace_hits_box_a1;
1690
1691 float trace_hits_box_1d(float end, float thmi, float thma)
1692 {
1693         if(end == 0)
1694         {
1695                 // just check if x is in range
1696                 if(0 < thmi)
1697                         return FALSE;
1698                 if(0 > thma)
1699                         return FALSE;
1700         }
1701         else
1702         {
1703                 // do the trace with respect to x
1704                 // 0 -> end has to stay in thmi -> thma
1705                 trace_hits_box_a0 = max(trace_hits_box_a0, min(thmi / end, thma / end));
1706                 trace_hits_box_a1 = min(trace_hits_box_a1, max(thmi / end, thma / end));
1707                 if(trace_hits_box_a0 > trace_hits_box_a1)
1708                         return FALSE;
1709         }
1710         return TRUE;
1711 }
1712
1713 float trace_hits_box(vector start, vector end, vector thmi, vector thma)
1714 {
1715         end -= start;
1716         thmi -= start;
1717         thma -= start;
1718         // now it is a trace from 0 to end
1719
1720         trace_hits_box_a0 = 0;
1721         trace_hits_box_a1 = 1;
1722
1723         if(!trace_hits_box_1d(end_x, thmi_x, thma_x))
1724                 return FALSE;
1725         if(!trace_hits_box_1d(end_y, thmi_y, thma_y))
1726                 return FALSE;
1727         if(!trace_hits_box_1d(end_z, thmi_z, thma_z))
1728                 return FALSE;
1729
1730         return TRUE;
1731 }
1732
1733 float tracebox_hits_box(vector start, vector mi, vector ma, vector end, vector thmi, vector thma)
1734 {
1735         return trace_hits_box(start, end, thmi - ma, thma - mi);
1736 }
1737
1738 float SUB_NoImpactCheck()
1739 {
1740         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1741                 return 1;
1742         if(other == world && self.size != '0 0 0')
1743         {
1744                 vector tic;
1745                 tic = self.velocity * sys_ticrate;
1746                 tic = tic + normalize(tic) * vlen(self.maxs - self.mins);
1747                 traceline(self.origin - tic, self.origin + tic, MOVE_NORMAL, self);
1748                 if(trace_fraction >= 1)
1749                 {
1750                         dprint("Odd... did not hit...?\n");
1751                 }
1752                 else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
1753                 {
1754                         dprint("Detected and prevented the sky-grapple bug.\n");
1755                         return 1;
1756                 }
1757         }
1758
1759         return 0;
1760 }
1761
1762 #define SUB_OwnerCheck() (other && (other == self.owner))
1763
1764 #define PROJECTILE_TOUCH do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { remove(self); return; } } while(0)
1765 #define PROJECTILE_TOUCH_NOSOUND do { if(SUB_OwnerCheck()) return; if(SUB_NoImpactCheck()) { stopsound(self, CHAN_PAIN); remove(self); return; } } while(0)
1766
1767 float MAX_IPBAN_URIS = 16;
1768
1769 float URI_GET_DISCARD   = 0;
1770 float URI_GET_IPBAN     = 1;
1771 float URI_GET_IPBAN_END = 16;
1772
1773 void URI_Get_Callback(float id, float status, string data)
1774 {
1775         dprint("Received HTTP request data for id ", ftos(id), "; status is ", ftos(status), "\nData is\n:");
1776         dprint(data);
1777         dprint("\nEnd of data.\n");
1778
1779         if(id == URI_GET_DISCARD)
1780         {
1781                 // discard
1782         }
1783         else if(id >= URI_GET_IPBAN && id <= URI_GET_IPBAN_END)
1784         {
1785                 // online ban list
1786                 OnlineBanList_URI_Get_Callback(id, status, data);
1787         }
1788         else
1789         {
1790                 print("Received HTTP request data for an invalid id ", ftos(id), ".\n");
1791         }
1792 }
1793
1794 void print_to(entity e, string s)
1795 {
1796         if(e)
1797                 sprint(e, strcat(s, "\n"));
1798         else
1799                 print(s, "\n");
1800 }
1801
1802 string getrecords()
1803 {
1804         float rec;
1805         string h;
1806         float r;
1807         float i;
1808         string s;
1809
1810         rec = 0;
1811
1812         s = "";
1813
1814         if(g_ctf)
1815         {
1816                 for(i = 0; i < MapInfo_count; ++i)
1817                 {
1818                         if(MapInfo_Get_ByID(i))
1819                         {
1820                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/time")));
1821                                 if(r == 0)
1822                                         continue;
1823                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/captimerecord/netname"));
1824                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-6, ftos_decimals(r, 2)), " ", h, "\n");
1825                                 ++rec;
1826                         }
1827                 }
1828         }
1829
1830         if(g_race)
1831         {
1832                 for(i = 0; i < MapInfo_count; ++i)
1833                 {
1834                         if(MapInfo_Get_ByID(i))
1835                         {
1836                                 r = stof(db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/time")));
1837                                 if(r == 0)
1838                                         continue;
1839                                 h = db_get(ServerProgsDB, strcat(MapInfo_Map_bspname, "/racerecord/netname"));
1840                                 s = strcat(s, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, mmsss(r)), " ", h, "\n");
1841                                 ++rec;
1842                         }
1843                 }
1844         }
1845
1846         if(s == "")
1847                 return "No records are available on this server.\n";
1848         else
1849                 return strcat("Records on this server:\n", s);
1850 }