data/qcsrc/server/miscfunctions.qc

   1 void() spawnfunc_info_player_deathmatch; // needed for the other spawnpoints
   2 void() spawnpoint_use;
   3 string ColoredTeamName(float t);
   4
   5 float DistributeEvenly_amount;
   6 float DistributeEvenly_totalweight;
   7 void DistributeEvenly_Init(float amount, float totalweight)
   8 {
   9         if(DistributeEvenly_amount)
  10         {
  11                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  12                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  13         }
  14         if(totalweight == 0)
  15                 DistributeEvenly_amount = 0;
  16         else
  17                 DistributeEvenly_amount = amount;
  18         DistributeEvenly_totalweight = totalweight;
  19 }
  20 float DistributeEvenly_Get(float weight)
  21 {
  22         float f;
  23         if(weight <= 0)
  24                 return 0;
  25         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  26         DistributeEvenly_totalweight -= weight;
  27         DistributeEvenly_amount -= f;
  28         return f;
  29 }
  30
  31 void move_out_of_solid_expand(entity e, vector by)
  32 {
  33         float eps = 0.0625;
  34         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  35         if(trace_startsolid)
  36                 return;
  37         if(trace_fraction < 1)
  38         {
  39                 // hit something
  40                 // adjust origin in the other direction...
  41                 e.origin = e.origin - by * (1 - trace_fraction);
  42         }
  43 }
  44
  45 void move_out_of_solid(entity e)
  46 {
  47         vector o, m0, m1;
  48
  49         o = e.origin;
  50         traceline(o, o, MOVE_WORLDONLY, e);
  51         if(trace_startsolid)
  52         {
  53                 dprint("origin is in solid too! (", vtos(o), ")");
  54                 return;
  55         }
  56
  57         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  58         if(!trace_startsolid)
  59                 return;
  60
  61         m0 = e.mins;
  62         m1 = e.maxs;
  63         e.mins = '0 0 0';
  64         e.maxs = '0 0 0';
  65         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  66         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
  67         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
  68         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
  69         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
  70         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
  71         setorigin(e, e.origin);
  72
  73         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
  74         if(trace_startsolid)
  75         {
  76                 dprint("could not get out of solid (", vtos(o), ")\n");
  77                 return;
  78         }
  79 }
  80
  81 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  82 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  83 string STR_PLAYER = "player";
  84 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  85 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  86
  87 // change that to actually calling strcat when running on an engine without
  88 // unlimited tempstrings:
  89 // string strcat1(string s) = #115; // FRIK_FILE
  90 #define strcat1(s) (s)
  91
  92 float logfile_open;
  93 float logfile;
  94
  95 void(string s) bcenterprint
  96 {
  97         // TODO replace by MSG_ALL (would show it to spectators too, though)?
  98         entity head;
  99         FOR_EACH_PLAYER(head)
 100                 if(clienttype(head) == CLIENTTYPE_REAL)
 101                         centerprint(head, s);
 102 }
 103
 104 void(string s, float check_dangerous) ServerConsoleEcho =
 105 {
 106         local string ch;
 107         if (checkextension("DP_SV_PRINT"))
 108                 print(s, "\n");
 109         else
 110         {
 111                 localcmd("echo \"");
 112                 if(check_dangerous)
 113                 {
 114                         while(strlen(s))
 115                         {
 116                                 ch = substring(s, 0, 1);
 117                                 if(ch != "\"" && ch != "\r" && ch != "\n")
 118                                         localcmd(ch);
 119                                 s = substring(s, 1, strlen(s) - 1);
 120                         }
 121                 }
 122                 else
 123                 {
 124                         localcmd(s);
 125                 }
 126                 localcmd("\"\n");
 127         }
 128 }
 129
 130 void(string s, float check_dangerous) GameLogEcho =
 131 {
 132         string fn;
 133         float matches;
 134
 135         if(cvar("sv_eventlog_files"))
 136         {
 137                 if(!logfile_open)
 138                 {
 139                         logfile_open = TRUE;
 140                         matches = cvar("sv_eventlog_files_counter") + 1;
 141                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 142                         fn = ftos(matches);
 143                         if(strlen(fn) < 8)
 144                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 145                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 146                         logfile = fopen(fn, FILE_APPEND);
 147                 }
 148                 if(logfile >= 0)
 149                         fputs(logfile, strcat(s, "\n"));
 150         }
 151         if(cvar("sv_eventlog_console"))
 152         {
 153                 ServerConsoleEcho(s, check_dangerous);
 154         }
 155 }
 156
 157 void() GameLogInit =
 158 {
 159         logfile_open = 0;
 160         // will be opened later
 161 }
 162
 163 void() GameLogClose =
 164 {
 165         if(logfile_open && logfile >= 0)
 166         {
 167                 fclose(logfile);
 168                 logfile = -1;
 169         }
 170 }
 171
 172 void relocate_spawnpoint()
 173 {
 174         // nudge off the floor
 175         setorigin(self, self.origin + '0 0 1');
 176
 177         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 178         if (trace_startsolid)
 179         {
 180                 objerror("player spawn point in solid, mapper sucks!\n");
 181                 return;
 182         }
 183
 184         if(cvar("g_spawnpoints_autodrop"))
 185         {
 186                 setsize(self, PL_MIN, PL_MAX);
 187                 droptofloor();
 188         }
 189
 190         self.use = spawnpoint_use;
 191         self.team_saved = self.team;
 192
 193         if(g_ctf || g_assault || g_onslaught || g_domination)
 194         if(self.team)
 195                 have_team_spawns = 1;
 196 }
 197
 198 #define strstr strstrofs
 199 /*
 200 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 201 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 202 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 203 // BE CONSTANT OR strzoneD!
 204 float(string haystack, string needle, float offset) strstr =
 205 {
 206         float len, endpos;
 207         string found;
 208         len = strlen(needle);
 209         endpos = strlen(haystack) - len;
 210         while(offset <= endpos)
 211         {
 212                 found = substring(haystack, offset, len);
 213                 if(found == needle)
 214                         return offset;
 215                 offset = offset + 1;
 216         }
 217         return -1;
 218 }
 219 */
 220
 221 float NUM_NEAREST_ENTITIES = 4;
 222 entity nearest_entity[NUM_NEAREST_ENTITIES];
 223 float nearest_length[NUM_NEAREST_ENTITIES];
 224 entity(vector point, .string field, string value, vector axismod) findnearest =
 225 {
 226         entity localhead;
 227         float i;
 228         float j;
 229         float len;
 230         vector dist;
 231
 232         float num_nearest;
 233         num_nearest = 0;
 234
 235         localhead = find(world, field, value);
 236         while(localhead)
 237         {
 238                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 239                         dist = localhead.oldorigin;
 240                 else
 241                         dist = localhead.origin;
 242                 dist = dist - point;
 243                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 244                 len = vlen(dist);
 245
 246                 for(i = 0; i < num_nearest; ++i)
 247                 {
 248                         if(len < nearest_length[i])
 249                                 break;
 250                 }
 251
 252                 // now i tells us where to insert at
 253                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 254                 if(i < NUM_NEAREST_ENTITIES)
 255                 {
 256                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 257                         {
 258                                 nearest_length[j + 1] = nearest_length[j];
 259                                 nearest_entity[j + 1] = nearest_entity[j];
 260                         }
 261                         nearest_length[i] = len;
 262                         nearest_entity[i] = localhead;
 263                         if(num_nearest < NUM_NEAREST_ENTITIES)
 264                                 num_nearest = num_nearest + 1;
 265                 }
 266
 267                 localhead = find(localhead, field, value);
 268         }
 269
 270         // now use the first one from our list that we can see
 271         for(i = 0; i < num_nearest; ++i)
 272         {
 273                 traceline(point, nearest_entity[i].origin, TRUE, world);
 274                 if(trace_fraction == 1)
 275                 {
 276                         if(i != 0)
 277                         {
 278                                 dprint("Nearest point (");
 279                                 dprint(nearest_entity[0].netname);
 280                                 dprint(") is not visible, using a visible one.\n");
 281                         }
 282                         return nearest_entity[i];
 283                 }
 284         }
 285
 286         if(num_nearest == 0)
 287                 return world;
 288
 289         dprint("Not seeing any location point, using nearest as fallback.\n");
 290         /* DEBUGGING CODE:
 291         dprint("Candidates were: ");
 292         for(j = 0; j < num_nearest; ++j)
 293         {
 294                 if(j != 0)
 295                         dprint(", ");
 296                 dprint(nearest_entity[j].netname);
 297         }
 298         dprint("\n");
 299         */
 300
 301         return nearest_entity[0];
 302 }
 303
 304 void() spawnfunc_target_location =
 305 {
 306         self.classname = "target_location";
 307         // location name in netname
 308         // eventually support: count, teamgame selectors, line of sight?
 309 };
 310
 311 void() spawnfunc_info_location =
 312 {
 313         self.classname = "target_location";
 314         self.message = self.netname;
 315 };
 316
 317 string NearestLocation(vector p)
 318 {
 319         entity loc;
 320         string ret;
 321         ret = "somewhere";
 322         loc = findnearest(p, classname, "target_location", '1 1 1');
 323         if(loc)
 324         {
 325                 ret = loc.message;
 326         }
 327         else
 328         {
 329                 loc = findnearest(p, target, "###item###", '1 1 4');
 330                 if(loc)
 331                         ret = loc.netname;
 332         }
 333         return ret;
 334 }
 335
 336 string(string msg) formatmessage =
 337 {
 338         float p;
 339         float n;
 340         string msg_save;
 341         string escape;
 342         string replacement;
 343         msg_save = strzone(msg);
 344         p = 0;
 345         n = 7;
 346         while(1)
 347         {
 348                 if(n < 1)
 349                         break; // too many replacements
 350                 n = n - 1;
 351                 p = strstr(msg_save, "%", p); // NOTE: this destroys msg as it's a tempstring!
 352                 if(p < 0)
 353                         break;
 354                 replacement = substring(msg_save, p, 2);
 355                 escape = substring(msg_save, p + 1, 1);
 356                 if(escape == "%")
 357                         replacement = "%";
 358                 else if(escape == "a")
 359                         replacement = ftos(floor(self.armorvalue));
 360                 else if(escape == "h")
 361                         replacement = ftos(floor(self.health));
 362                 else if(escape == "l")
 363                         replacement = NearestLocation(self.origin);
 364                 else if(escape == "y")
 365                         replacement = NearestLocation(self.cursor_trace_endpos);
 366                 else if(escape == "d")
 367                         replacement = NearestLocation(self.death_origin);
 368                 else if(escape == "w")
 369                 {
 370                         float wep;
 371                         wep = self.weapon;
 372                         if(!wep)
 373                                 wep = self.switchweapon;
 374                         if(!wep)
 375                                 wep = self.cnt;
 376                         replacement = W_Name(wep);
 377                 }
 378                 else if(escape == "W")
 379                 {
 380                         if(self.items & IT_SHELLS) replacement = "shells";
 381                         else if(self.items & IT_NAILS) replacement = "bullets";
 382                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 383                         else if(self.items & IT_CELLS) replacement = "cells";
 384                         else replacement = "batteries"; // ;)
 385                 }
 386                 else if(escape == "x")
 387                 {
 388                         replacement = self.cursor_trace_ent.netname;
 389                         if(!replacement || !self.cursor_trace_ent)
 390                                 replacement = "nothing";
 391                 }
 392                 else if(escape == "p")
 393                 {
 394                         if(self.last_selected_player)
 395                                 replacement = self.last_selected_player.netname;
 396                         else
 397                                 replacement = "(nobody)";
 398                 }
 399                 msg = strcat(substring(msg_save, 0, p), replacement);
 400                 msg = strcat(msg, substring(msg_save, p+2, strlen(msg_save) - (p+2)));
 401                 strunzone(msg_save);
 402                 msg_save = strzone(msg);
 403                 p = p + 2;
 404         }
 405         msg = strcat(msg_save, "");
 406         strunzone(msg_save);
 407         return msg;
 408 }
 409
 410 /*
 411 =============
 412 GetCvars
 413 =============
 414 Called with:
 415   0:  sends the request
 416   >0: receives a cvar from name=argv(f) value=argv(f+1)
 417 */
 418 void GetCvars_handleString(float f, .string field, string name)
 419 {
 420         if(f < 0)
 421         {
 422                 if(self.field)
 423                         strunzone(self.field);
 424         }
 425         else if(f > 0)
 426         {
 427                 if(argv(f) == name)
 428                 {
 429                         if(self.field)
 430                                 strunzone(self.field);
 431                         self.field = strzone(argv(f + 1));
 432                 }
 433         }
 434         else
 435                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 436 }
 437 void GetCvars_handleFloat(float f, .float field, string name)
 438 {
 439         if(f < 0)
 440         {
 441         }
 442         else if(f > 0)
 443         {
 444                 if(argv(f) == name)
 445                         self.field = stof(argv(f + 1));
 446         }
 447         else
 448                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 449 }
 450 void GetCvars(float f)
 451 {
 452         GetCvars_handleFloat(f, autoswitch, "cl_autoswitch");
 453         GetCvars_handleFloat(f, cvar_cl_hidewaypoints, "cl_hidewaypoints");
 454         GetCvars_handleFloat(f, cvar_cl_zoomfactor, "cl_zoomfactor");
 455         GetCvars_handleFloat(f, cvar_cl_zoomspeed, "cl_zoomspeed");
 456         GetCvars_handleFloat(f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 457         GetCvars_handleFloat(f, cvar_cl_nogibs, "cl_nogibs");
 458         GetCvars_handleFloat(f, cvar_scr_centertime, "scr_centertime");
 459         GetCvars_handleFloat(f, cvar_cl_shownames, "cl_shownames");
 460         GetCvars_handleString(f, cvar_g_nexuizversion, "g_nexuizversion");
 461         GetCvars_handleFloat(f, cvar_cl_handicap, "cl_handicap");
 462 }
 463
 464 float fexists(string f)
 465 {
 466         float fh;
 467         fh = fopen(f, FILE_READ);
 468         if(fh < 0)
 469                 return FALSE;
 470         fclose(fh);
 471         return TRUE;
 472 }
 473
 474 void backtrace(string msg)
 475 {
 476         float dev;
 477         dev = cvar("developer");
 478         cvar_set("developer", "1");
 479         dprint("\n");
 480         dprint("--- CUT HERE ---\nWARNING: ");
 481         dprint(msg);
 482         dprint("\n");
 483         remove(world); // isn't there any better way to cause a backtrace?
 484         dprint("\n--- CUT UNTIL HERE ---\n");
 485         cvar_set("developer", ftos(dev));
 486 }
 487
 488 void DistributeFragsAmongTeam(entity p, float targetteam, float factor)
 489 {
 490         float nTeam;
 491         entity head;
 492         float f;
 493
 494         if(!teams_matter)
 495                 return;
 496
 497         //if(p.frags < 0)
 498         //{
 499         //      p.frags = 0; // do not harm the new team!
 500         //      return; // won't distribute negative scores
 501         //}
 502
 503         if(p.frags == -666)
 504                 return;
 505
 506         f = ceil(factor * p.frags);
 507         p.frags = p.frags - f;
 508
 509         nTeam = 0;
 510         FOR_EACH_PLAYER(head)
 511                 if(head != p)
 512                         if(head.team == targetteam)
 513                                 nTeam = nTeam + 1;
 514
 515         if(nTeam == 0)
 516                 return;
 517
 518         DistributeEvenly_Init(f, nTeam);
 519
 520         FOR_EACH_PLAYER(head)
 521                 if(head != p)
 522                         if(head.team == targetteam)
 523                                 head.frags = head.frags + DistributeEvenly_Get(1);
 524 }
 525
 526 string Team_ColorCode(float teamid)
 527 {
 528         if(teamid == COLOR_TEAM1)
 529                 return "^1";
 530         else if(teamid == COLOR_TEAM2)
 531                 return "^4";
 532         else if(teamid == COLOR_TEAM3)
 533                 return "^3";
 534         else if(teamid == COLOR_TEAM4)
 535                 return "^6";
 536         else
 537                 return "^7";
 538 }
 539 string Team_ColorName(float t)
 540 {
 541         // fixme: Search for team entities and get their .netname's!
 542         if(t == COLOR_TEAM1)
 543                 return "Red";
 544         if(t == COLOR_TEAM2)
 545                 return "Blue";
 546         if(t == COLOR_TEAM3)
 547                 return "Yellow";
 548         if(t == COLOR_TEAM4)
 549                 return "Pink";
 550         return "Neutral";
 551 }
 552 string Team_ColorNameLowerCase(float t)
 553 {
 554         // fixme: Search for team entities and get their .netname's!
 555         if(t == COLOR_TEAM1)
 556                 return "red";
 557         if(t == COLOR_TEAM2)
 558                 return "blue";
 559         if(t == COLOR_TEAM3)
 560                 return "yellow";
 561         if(t == COLOR_TEAM4)
 562                 return "pink";
 563         return "neutral";
 564 }
 565
 566 /*
 567 string decolorize(string s)
 568 {
 569         string out;
 570         out = "";
 571         while(s != "")
 572         {
 573                 float n;
 574                 string ch1, ch2;
 575                 n = 1;
 576                 ch1 = substring(s, 0, 1);
 577                 ch2 = substring(s, 1, 1);
 578                 if(ch1 == "^")
 579                 {
 580                         n = 2;
 581                         if(ch2 == "^")
 582                                 out = strcat(out, "^^");
 583                         else if(ch2 == "0")
 584                                 out = strcat1(out);
 585                         else if(ch2 == "1")
 586                                 out = strcat1(out);
 587                         else if(ch2 == "2")
 588                                 out = strcat1(out);
 589                         else if(ch2 == "3")
 590                                 out = strcat1(out);
 591                         else if(ch2 == "4")
 592                                 out = strcat1(out);
 593                         else if(ch2 == "5")
 594                                 out = strcat1(out);
 595                         else if(ch2 == "6")
 596                                 out = strcat1(out);
 597                         else if(ch2 == "7")
 598                                 out = strcat1(out);
 599                         else if(ch2 == "8")
 600                                 out = strcat1(out);
 601                         else if(ch2 == "9")
 602                                 out = strcat1(out);
 603                         else
 604                         {
 605                                 n = 1;
 606                                 out = strcat(out, "^^");
 607                         }
 608                         s = substring(s, n, strlen(s) - n);
 609                 }
 610                 else
 611                 {
 612                         s = substring(s, 1, strlen(s) - 1);
 613                         out = strcat(out, ch1);
 614                 }
 615         }
 616         return out;
 617 }
 618 #define strdecolorize(s) decolorize(s)
 619 #define strlennocol(s) strlen(decolorize(s))
 620 */
 621
 622 #define CENTERPRIO_POINT 1
 623 #define CENTERPRIO_SPAM 2
 624 #define CENTERPRIO_REBALANCE 2
 625 #define CENTERPRIO_VOTE 4
 626 #define CENTERPRIO_NORMAL 5
 627 #define CENTERPRIO_MAPVOTE 9
 628 #define CENTERPRIO_ADMIN 99
 629 .float centerprint_priority;
 630 .float centerprint_expires;
 631 void centerprint_atprio(entity e, float prio, string s)
 632 {
 633         if(intermission_running)
 634                 if(prio < CENTERPRIO_MAPVOTE)
 635                         return;
 636         if(time > e.centerprint_expires)
 637                 e.centerprint_priority = 0;
 638         if(prio >= e.centerprint_priority)
 639         {
 640                 e.centerprint_priority = prio;
 641                 if(timeoutStatus == 2)
 642                         e.centerprint_expires = time + (e.cvar_scr_centertime * TIMEOUT_SLOWMO_VALUE);
 643                 else
 644                         e.centerprint_expires = time + e.cvar_scr_centertime;
 645                 centerprint_builtin(e, s);
 646         }
 647 }
 648 void centerprint_expire(entity e, float prio)
 649 {
 650         if(prio == e.centerprint_priority)
 651         {
 652                 e.centerprint_priority = 0;
 653                 centerprint_builtin(e, "");
 654         }
 655 }
 656 void centerprint(entity e, string s)
 657 {
 658         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 659 }
 660
 661 void VoteNag();
 662
 663 // decolorizes and team colors the player name when needed
 664 string playername(entity p)
 665 {
 666         string t;
 667         if(teams_matter && !intermission_running && p.classname == "player")
 668         {
 669                 t = Team_ColorCode(p.team);
 670                 return strcat(t, strdecolorize(p.netname));
 671         }
 672         else
 673                 return p.netname;
 674 }
 675
 676 vector(vector m1, vector m2) randompos =
 677 {
 678         local vector v;
 679         m2 = m2 - m1;
 680         v_x = m2_x * random() + m1_x;
 681         v_y = m2_y * random() + m1_y;
 682         v_z = m2_z * random() + m1_z;
 683         return  v;
 684 };
 685
 686 // requires that m2>m1 in all coordinates, and that m4>m3
 687 float(vector m1, vector m2, vector m3, vector m4) boxesoverlap = {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;};
 688
 689 // requires the same, but is a stronger condition
 690 float(vector smins, vector smaxs, vector bmins, vector bmaxs) boxinsidebox = {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;};
 691
 692 float g_pickup_shells;
 693 float g_pickup_shells_max;
 694 float g_pickup_nails;
 695 float g_pickup_nails_max;
 696 float g_pickup_rockets;
 697 float g_pickup_rockets_max;
 698 float g_pickup_cells;
 699 float g_pickup_cells_max;
 700 float g_pickup_armorsmall;
 701 float g_pickup_armorsmall_max;
 702 float g_pickup_armormedium;
 703 float g_pickup_armormedium_max;
 704 float g_pickup_armorlarge;
 705 float g_pickup_armorlarge_max;
 706 float g_pickup_healthsmall;
 707 float g_pickup_healthsmall_max;
 708 float g_pickup_healthmedium;
 709 float g_pickup_healthmedium_max;
 710 float g_pickup_healthlarge;
 711 float g_pickup_healthlarge_max;
 712 float g_pickup_healthmega;
 713 float g_pickup_healthmega_max;
 714
 715 float start_items;
 716 float start_switchweapon;
 717 float start_ammo_shells;
 718 float start_ammo_nails;
 719 float start_ammo_rockets;
 720 float start_ammo_cells;
 721 float start_health;
 722 float start_armorvalue;
 723
 724 void readlevelcvars(void)
 725 {
 726         sv_cheats = cvar("sv_cheats");
 727         g_cloaked = cvar("g_cloaked");
 728         g_footsteps = cvar("g_footsteps");
 729         g_grappling_hook = cvar("g_grappling_hook");
 730         g_instagib = cvar("g_instagib");
 731         g_laserguided_missile = cvar("g_laserguided_missile");
 732         g_midair = cvar("g_midair");
 733         g_minstagib = cvar("g_minstagib");
 734         g_nixnex = cvar("g_nixnex");
 735         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
 736         g_norecoil = cvar("g_norecoil");
 737         g_rocketarena = cvar("g_rocketarena");
 738         g_vampire = cvar("g_vampire");
 739         g_tourney = cvar("g_tourney");
 740
 741         g_pickup_shells                    = cvar("g_pickup_shells");
 742         g_pickup_shells_max                = cvar("g_pickup_shells_max");
 743         g_pickup_nails                     = cvar("g_pickup_nails");
 744         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
 745         g_pickup_rockets                   = cvar("g_pickup_rockets");
 746         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
 747         g_pickup_cells                     = cvar("g_pickup_cells");
 748         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
 749         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
 750         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
 751         g_pickup_armormedium               = cvar("g_pickup_armormedium");
 752         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
 753         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
 754         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
 755         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
 756         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
 757         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
 758         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
 759         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
 760         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
 761         g_pickup_healthmega                = cvar("g_pickup_healthmega");
 762         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
 763
 764         // initialize starting values for players
 765         start_items = 0;
 766         start_switchweapon = 0;
 767         start_ammo_shells = 0;
 768         start_ammo_nails = 0;
 769         start_ammo_rockets = 0;
 770         start_ammo_cells = 0;
 771         start_health = cvar("g_balance_health_start");
 772         start_armorvalue = cvar("g_balance_armor_start");
 773
 774         if(g_instagib)
 775         {
 776                 start_items = IT_NEX;
 777                 start_switchweapon = WEP_NEX;
 778                 weapon_action(start_switchweapon, WR_PRECACHE);
 779                 start_ammo_cells = 999;
 780         }
 781         else if(g_rocketarena)
 782         {
 783                 start_items = IT_ROCKET_LAUNCHER;
 784                 start_switchweapon = WEP_ROCKET_LAUNCHER;
 785                 weapon_action(start_switchweapon, WR_PRECACHE);
 786                 start_ammo_rockets = 999;
 787         }
 788         else if(g_nixnex)
 789         {
 790                 start_items = 0;
 791                 // will be done later
 792         }
 793         else if(g_minstagib)
 794         {
 795                 start_health = 100;
 796                 start_armorvalue = 0;
 797                 start_items = IT_NEX;
 798                 start_switchweapon = WEP_NEX;
 799                 weapon_action(start_switchweapon, WR_PRECACHE);
 800                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 801                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 802         }
 803         else
 804         {
 805                 if(g_lms)
 806                 {
 807                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 808                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 809                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 810                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 811                         start_health = cvar("g_lms_start_health");
 812                         start_armorvalue = cvar("g_lms_start_armor");
 813                 }
 814                 else if(g_tourney) {
 815                         start_ammo_shells = cvar("g_tourney_start_ammo_shells");
 816                         start_ammo_nails = cvar("g_tourney_start_ammo_nails");
 817                         start_ammo_rockets = cvar("g_tourney_start_ammo_rockets");
 818                         start_ammo_cells = cvar("g_tourney_start_ammo_cells");
 819                         start_health = cvar("g_tourney_start_health");
 820                         start_armorvalue = cvar("g_tourney_start_armor");
 821                 }
 822                 else if (cvar("g_use_ammunition")) {
 823                         start_ammo_shells = cvar("g_start_ammo_shells");
 824                         start_ammo_nails = cvar("g_start_ammo_nails");
 825                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 826                         start_ammo_cells = cvar("g_start_ammo_cells");
 827                 } else {
 828                         start_ammo_shells = cvar("g_pickup_shells_max");
 829                         start_ammo_nails = cvar("g_pickup_nails_max");
 830                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 831                         start_ammo_cells = cvar("g_pickup_cells_max");
 832                 }
 833
 834                 if (cvar("g_start_weapon_laser") || g_lms)
 835                 {
 836                         start_items = start_items | IT_LASER;
 837                         start_switchweapon = WEP_LASER;
 838                         weapon_action(start_switchweapon, WR_PRECACHE);
 839                 }
 840                 if (cvar("g_start_weapon_shotgun") || g_lms)
 841                 {
 842                         start_items = start_items | IT_SHOTGUN;
 843                         start_switchweapon = WEP_SHOTGUN;
 844                         weapon_action(start_switchweapon, WR_PRECACHE);
 845                 }
 846                 if (cvar("g_start_weapon_uzi") || g_lms || g_tourney)
 847                 {
 848                         start_items = start_items | IT_UZI;
 849                         start_switchweapon = WEP_UZI;
 850                         weapon_action(start_switchweapon, WR_PRECACHE);
 851                 }
 852                 if (cvar("g_start_weapon_grenadelauncher") || g_lms || g_tourney)
 853                 {
 854                         start_items = start_items | IT_GRENADE_LAUNCHER;
 855                         start_switchweapon = WEP_GRENADE_LAUNCHER;
 856                         weapon_action(start_switchweapon, WR_PRECACHE);
 857                 }
 858                 if (cvar("g_start_weapon_electro") || g_lms || g_tourney)
 859                 {
 860                         start_items = start_items | IT_ELECTRO;
 861                         start_switchweapon = WEP_ELECTRO;
 862                         weapon_action(start_switchweapon, WR_PRECACHE);
 863                 }
 864                 if (cvar("g_start_weapon_crylink") || g_lms || g_tourney)
 865                 {
 866                         start_items = start_items | IT_CRYLINK;
 867                         start_switchweapon = WEP_CRYLINK;
 868                         weapon_action(start_switchweapon, WR_PRECACHE);
 869                 }
 870                 if (cvar("g_start_weapon_nex") || g_lms || g_tourney)
 871                 {
 872                         start_items = start_items | IT_NEX;
 873                         start_switchweapon = WEP_NEX;
 874                         weapon_action(start_switchweapon, WR_PRECACHE);
 875                 }
 876                 if (cvar("g_start_weapon_hagar") || g_lms || g_tourney)
 877                 {
 878                         start_items = start_items | IT_HAGAR;
 879                         start_switchweapon = WEP_HAGAR;
 880                         weapon_action(start_switchweapon, WR_PRECACHE);
 881                 }
 882                 if (cvar("g_start_weapon_rocketlauncher") || g_lms || g_tourney)
 883                 {
 884                         start_items = start_items | IT_ROCKET_LAUNCHER;
 885                         start_switchweapon = WEP_ROCKET_LAUNCHER;
 886                         weapon_action(start_switchweapon, WR_PRECACHE);
 887                 }
 888         }
 889 }
 890
 891 /*
 892 // TODO sound pack system
 893 string soundpack;
 894
 895 string precache_sound_builtin (string s) = #19;
 896 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
 897 string precache_sound(string s)
 898 {
 899         return precache_sound_builtin(strcat(soundpack, s));
 900 }
 901 void play2(entity e, string filename)
 902 {
 903         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
 904 }
 905 void sound(entity e, float chan, string samp, float vol, float atten)
 906 {
 907         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
 908 }
 909 */
 910
 911 string precache_sound (string s) = #19;
 912 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
 913 void play2(entity e, string filename)
 914 {
 915         stuffcmd(e, strcat("play2 ", filename, "\n"));
 916 }
 917
 918 void play2team(float t, string filename)
 919 {
 920         local entity head;
 921         FOR_EACH_REALPLAYER(head)
 922         {
 923                 if (head.team == t)
 924                         play2(head, filename);
 925         }
 926 }
 927
 928 void PrecachePlayerSounds(string f);
 929 void precache_all_models(string pattern)
 930 {
 931         float globhandle, i, n;
 932         string f;
 933
 934         globhandle = search_begin(pattern, TRUE, FALSE);
 935         if(globhandle < 0)
 936                 return;
 937         n = search_getsize(globhandle);
 938         for(i = 0; i < n; ++i)
 939         {
 940                 //print(search_getfilename(globhandle, i), "\n");
 941                 f = search_getfilename(globhandle, i);
 942                 precache_model(f);
 943                 PrecachePlayerSounds(strcat(f, ".sounds"));
 944         }
 945         search_end(globhandle);
 946 }
 947
 948 void precache()
 949 {
 950         // gamemode related things
 951         precache_model ("models/misc/chatbubble.spr");
 952         precache_model ("models/misc/teambubble.spr");
 953         if (g_runematch)
 954         {
 955                 precache_model ("models/runematch/curse.mdl");
 956                 precache_model ("models/runematch/rune.mdl");
 957         }
 958
 959         // Precache all player models if desired
 960         if (cvar("sv_precacheplayermodels"))
 961         {
 962                 PrecachePlayerSounds("sound/player/default.sounds");
 963                 precache_all_models("models/player/*.zym");
 964                 precache_all_models("models/player/*.dpm");
 965                 precache_all_models("models/player/*.md3");
 966                 precache_all_models("models/player/*.psk");
 967                 //precache_model("models/player/carni.zym");
 968                 //precache_model("models/player/crash.zym");
 969                 //precache_model("models/player/grunt.zym");
 970                 //precache_model("models/player/headhunter.zym");
 971                 //precache_model("models/player/insurrectionist.zym");
 972                 //precache_model("models/player/jeandarc.zym");
 973                 //precache_model("models/player/lurk.zym");
 974                 //precache_model("models/player/lycanthrope.zym");
 975                 //precache_model("models/player/marine.zym");
 976                 //precache_model("models/player/nexus.zym");
 977                 //precache_model("models/player/pyria.zym");
 978                 //precache_model("models/player/shock.zym");
 979                 //precache_model("models/player/skadi.zym");
 980                 //precache_model("models/player/specop.zym");
 981                 //precache_model("models/player/visitant.zym");
 982         }
 983
 984         if (g_footsteps)
 985         {
 986                 precache_sound ("misc/footstep01.wav");
 987                 precache_sound ("misc/footstep02.wav");
 988                 precache_sound ("misc/footstep03.wav");
 989                 precache_sound ("misc/footstep04.wav");
 990                 precache_sound ("misc/footstep05.wav");
 991                 precache_sound ("misc/footstep06.wav");
 992         }
 993
 994         // gore and miscellaneous sounds
 995         //precache_sound ("misc/h2ohit.wav");
 996         precache_model ("models/gibs/bloodyskull.md3");
 997         precache_model ("models/gibs/chunk.mdl");
 998         precache_model ("models/gibs/eye.md3");
 999         precache_model ("models/gibs/gib1.md3");
1000         precache_model ("models/gibs/gib2.md3");
1001         precache_model ("models/gibs/gib3.md3");
1002         precache_model ("models/gibs/gib4.md3");
1003         precache_model ("models/gibs/gib5.md3");
1004         precache_model ("models/gibs/gib6.md3");
1005         precache_model ("models/gibs/smallchest.md3");
1006         precache_model ("models/gibs/chest.md3");
1007         precache_model ("models/gibs/arm.md3");
1008         precache_model ("models/gibs/leg1.md3");
1009         precache_model ("models/gibs/leg2.md3");
1010         precache_model ("models/hook.md3");
1011         precache_sound ("misc/armorimpact.wav");
1012         precache_sound ("misc/bodyimpact1.wav");
1013         precache_sound ("misc/bodyimpact2.wav");
1014         precache_sound ("misc/gib.wav");
1015         precache_sound ("misc/gib_splat01.wav");
1016         precache_sound ("misc/gib_splat02.wav");
1017         precache_sound ("misc/gib_splat03.wav");
1018         precache_sound ("misc/gib_splat04.wav");
1019         precache_sound ("misc/hit.wav");
1020         precache_sound ("misc/hitground1.wav");
1021         precache_sound ("misc/hitground2.wav");
1022         precache_sound ("misc/hitground3.wav");
1023         precache_sound ("misc/hitground4.wav");
1024         precache_sound ("misc/null.wav");
1025         precache_sound ("misc/spawn.wav");
1026         precache_sound ("misc/talk.wav");
1027         precache_sound ("misc/teleport.wav");
1028         precache_sound ("player/lava.wav");
1029         precache_sound ("player/slime.wav");
1030
1031         // announcer sounds - male
1032         //precache_sound ("announcer/male/electrobitch.wav");
1033         precache_sound ("announcer/male/03kills.wav");
1034         precache_sound ("announcer/male/05kills.wav");
1035         precache_sound ("announcer/male/10kills.wav");
1036         precache_sound ("announcer/male/15kills.wav");
1037         precache_sound ("announcer/male/20kills.wav");
1038         precache_sound ("announcer/male/25kills.wav");
1039         precache_sound ("announcer/male/30kills.wav");
1040         precache_sound ("announcer/male/botlike.wav");
1041         precache_sound ("announcer/male/yoda.wav");
1042
1043         // announcer sounds - robotic
1044         precache_sound ("announcer/robotic/prepareforbattle.wav");
1045         precache_sound ("announcer/robotic/begin.wav");
1046         precache_sound ("announcer/robotic/timeoutcalled.wav");
1047         precache_sound ("announcer/robotic/1fragleft.wav");
1048         precache_sound ("announcer/robotic/1minuteremains.wav");
1049         precache_sound ("announcer/robotic/2fragsleft.wav");
1050         precache_sound ("announcer/robotic/3fragsleft.wav");
1051         if (g_minstagib)
1052         {
1053                 precache_sound ("announcer/robotic/lastsecond.wav");
1054                 precache_sound ("announcer/robotic/narrowly.wav");
1055         }
1056
1057         precache_model ("models/sprites/1.spr32");
1058         precache_model ("models/sprites/2.spr32");
1059         precache_model ("models/sprites/3.spr32");
1060         precache_model ("models/sprites/4.spr32");
1061         precache_model ("models/sprites/5.spr32");
1062         precache_model ("models/sprites/6.spr32");
1063         precache_model ("models/sprites/7.spr32");
1064         precache_model ("models/sprites/8.spr32");
1065         precache_model ("models/sprites/9.spr32");
1066         precache_model ("models/sprites/10.spr32");
1067         precache_sound ("announcer/robotic/1.ogg");
1068         precache_sound ("announcer/robotic/2.ogg");
1069         precache_sound ("announcer/robotic/3.ogg");
1070         precache_sound ("announcer/robotic/4.ogg");
1071         precache_sound ("announcer/robotic/5.ogg");
1072         precache_sound ("announcer/robotic/6.ogg");
1073         precache_sound ("announcer/robotic/7.ogg");
1074         precache_sound ("announcer/robotic/8.ogg");
1075         precache_sound ("announcer/robotic/9.ogg");
1076         precache_sound ("announcer/robotic/10.ogg");
1077
1078         // common weapon precaches
1079         precache_sound ("weapons/weapon_switch.wav");
1080         precache_sound ("weapons/weaponpickup.wav");
1081         if (cvar("g_grappling_hook"))
1082         {
1083                 precache_sound ("weapons/hook_fire.wav"); // hook
1084                 precache_sound ("weapons/hook_impact.wav"); // hook
1085         }
1086
1087         if (cvar("sv_precacheweapons") || g_nixnex)
1088         {
1089                 //precache weapon models/sounds
1090                 local float wep;
1091                 wep = WEP_FIRST;
1092                 while (wep <= WEP_LAST)
1093                 {
1094                         weapon_action(wep, WR_PRECACHE);
1095                         wep = wep + 1;
1096                 }
1097         }
1098
1099         // plays music for the level if there is any
1100         if (self.noise)
1101         {
1102                 precache_sound (self.noise);
1103                 ambientsound ('0 0 0', self.noise, 1.00, ATTN_NONE);
1104         }
1105 }