data/qcsrc/server/miscfunctions.qc

   1 void() info_player_deathmatch; // needed for the other spawnpoints
   2 void() spawnpoint_use;
   3 string ColoredTeamName(float t);
   4
   5 float DistributeEvenly_amount;
   6 float DistributeEvenly_totalweight;
   7 void DistributeEvenly_Init(float amount, float totalweight)
   8 {
   9         if(DistributeEvenly_amount)
  10         {
  11                 dprint("DistributeEvenly_Init: UNFINISHED DISTRIBUTION (", ftos(DistributeEvenly_amount), " for ");
  12                 dprint(ftos(DistributeEvenly_totalweight), " left!)\n");
  13         }
  14         if(totalweight == 0)
  15                 DistributeEvenly_amount = 0;
  16         else
  17                 DistributeEvenly_amount = amount;
  18         DistributeEvenly_totalweight = totalweight;
  19 }
  20 float DistributeEvenly_Get(float weight)
  21 {
  22         float f;
  23         if(weight <= 0)
  24                 return 0;
  25         f = floor(0.5 + DistributeEvenly_amount * weight / DistributeEvenly_totalweight);
  26         DistributeEvenly_totalweight -= weight;
  27         DistributeEvenly_amount -= f;
  28         return f;
  29 }
  30
  31 void move_out_of_solid_expand(entity e, vector by)
  32 {
  33         float eps = 0.0625;
  34         tracebox(e.origin, e.mins - '1 1 1' * eps, e.maxs + '1 1 1' * eps, e.origin + by, MOVE_WORLDONLY, e);
  35         if(trace_startsolid)
  36                 return;
  37         if(trace_fraction < 1)
  38         {
  39                 // hit something
  40                 // adjust origin in the other direction...
  41                 e.origin = e.origin - by * (1 - trace_fraction);
  42         }
  43 }
  44
  45 void move_out_of_solid(entity e)
  46 {
  47         vector o, m0, m1;
  48
  49         o = e.origin;
  50         traceline(o, o, MOVE_WORLDONLY, e);
  51         if(trace_startsolid)
  52         {
  53                 dprint("origin is in solid too! (", vtos(o), ")");
  54                 return;
  55         }
  56
  57         tracebox(o, e.mins, e.maxs, o, MOVE_WORLDONLY, e);
  58         if(!trace_startsolid)
  59                 return;
  60
  61         m0 = e.mins;
  62         m1 = e.maxs;
  63         e.mins = '0 0 0';
  64         e.maxs = '0 0 0';
  65         move_out_of_solid_expand(e, '1 0 0' * m0_x); e.mins_x = m0_x;
  66         move_out_of_solid_expand(e, '1 0 0' * m1_x); e.maxs_x = m1_x;
  67         move_out_of_solid_expand(e, '0 1 0' * m0_y); e.mins_y = m0_y;
  68         move_out_of_solid_expand(e, '0 1 0' * m1_y); e.maxs_y = m1_y;
  69         move_out_of_solid_expand(e, '0 0 1' * m0_z); e.mins_z = m0_z;
  70         move_out_of_solid_expand(e, '0 0 1' * m1_z); e.maxs_z = m1_z;
  71         setorigin(e, e.origin);
  72
  73         tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_WORLDONLY, e);
  74         if(trace_startsolid)
  75         {
  76                 dprint("could not get out of solid (", vtos(o), ")\n");
  77                 return;
  78         }
  79 }
  80
  81 #define FOR_EACH_CLIENT(v) for(v = world; (v = findflags(v, flags, FL_CLIENT)) != world; )
  82 #define FOR_EACH_REALCLIENT(v) FOR_EACH_CLIENT(v) if(clienttype(v) == CLIENTTYPE_REAL)
  83 string STR_PLAYER = "player";
  84 #define FOR_EACH_PLAYER(v) for(v = world; (v = find(v, classname, STR_PLAYER)) != world; )
  85 #define FOR_EACH_REALPLAYER(v) FOR_EACH_PLAYER(v) if(clienttype(v) == CLIENTTYPE_REAL)
  86
  87 // change that to actually calling strcat when running on an engine without
  88 // unlimited tempstrings:
  89 // string strcat1(string s) = #115; // FRIK_FILE
  90 #define strcat1(s) (s)
  91
  92 float logfile_open;
  93 float logfile;
  94
  95 void(string s) bcenterprint
  96 {
  97         // TODO replace by MSG_ALL (would show it to spectators too, though)?
  98         entity head;
  99         FOR_EACH_PLAYER(head)
 100                 if(clienttype(head) == CLIENTTYPE_REAL)
 101                         centerprint(head, s);
 102 }
 103
 104 void(string s, float check_dangerous) ServerConsoleEcho =
 105 {
 106         local string ch;
 107         if (checkextension("DP_SV_PRINT"))
 108                 print(s, "\n");
 109         else
 110         {
 111                 localcmd("echo \"");
 112                 if(check_dangerous)
 113                 {
 114                         while(strlen(s))
 115                         {
 116                                 ch = substring(s, 0, 1);
 117                                 if(ch != "\"" && ch != "\r" && ch != "\n")
 118                                         localcmd(ch);
 119                                 s = substring(s, 1, strlen(s) - 1);
 120                         }
 121                 }
 122                 else
 123                 {
 124                         localcmd(s);
 125                 }
 126                 localcmd("\"\n");
 127         }
 128 }
 129
 130 void(string s, float check_dangerous) GameLogEcho =
 131 {
 132         string fn;
 133         float matches;
 134
 135         if(cvar("sv_eventlog_files"))
 136         {
 137                 if(!logfile_open)
 138                 {
 139                         logfile_open = TRUE;
 140                         matches = cvar("sv_eventlog_files_counter") + 1;
 141                         cvar_set("sv_eventlog_files_counter", ftos(matches));
 142                         fn = ftos(matches);
 143                         if(strlen(fn) < 8)
 144                                 fn = strcat(substring("00000000", 0, 8 - strlen(fn)), fn);
 145                         fn = strcat(cvar_string("sv_eventlog_files_nameprefix"), fn, cvar_string("sv_eventlog_files_namesuffix"));
 146                         logfile = fopen(fn, FILE_APPEND);
 147                 }
 148                 if(logfile >= 0)
 149                         fputs(logfile, strcat(s, "\n"));
 150         }
 151         if(cvar("sv_eventlog_console"))
 152         {
 153                 ServerConsoleEcho(s, check_dangerous);
 154         }
 155 }
 156
 157 void() GameLogInit =
 158 {
 159         logfile_open = 0;
 160         // will be opened later
 161 }
 162
 163 void() GameLogClose =
 164 {
 165         if(logfile_open && logfile >= 0)
 166         {
 167                 fclose(logfile);
 168                 logfile = -1;
 169         }
 170 }
 171
 172 void relocate_spawnpoint()
 173 {
 174         // nudge off the floor
 175         setorigin(self, self.origin + '0 0 1');
 176
 177         tracebox(self.origin, PL_MIN, PL_MAX, self.origin, TRUE, self);
 178         if (trace_startsolid)
 179         {
 180                 objerror("player spawn point in solid, mapper sucks!\n");
 181                 return;
 182         }
 183
 184         if(cvar("g_spawnpoints_autodrop"))
 185         {
 186                 setsize(self, PL_MIN, PL_MAX);
 187                 droptofloor();
 188         }
 189
 190         self.use = spawnpoint_use;
 191 }
 192
 193 #define strstr strstrofs
 194 /*
 195 // NOTE: DO NOT USE THIS FUNCTION TOO OFTEN.
 196 // IT WILL MOST PROBABLY DESTROY _ALL_ OTHER TEMP
 197 // STRINGS AND TAKE QUITE LONG. haystack and needle MUST
 198 // BE CONSTANT OR strzoneD!
 199 float(string haystack, string needle, float offset) strstr =
 200 {
 201         float len, endpos;
 202         string found;
 203         len = strlen(needle);
 204         endpos = strlen(haystack) - len;
 205         while(offset <= endpos)
 206         {
 207                 found = substring(haystack, offset, len);
 208                 if(found == needle)
 209                         return offset;
 210                 offset = offset + 1;
 211         }
 212         return -1;
 213 }
 214 */
 215
 216 float NUM_NEAREST_ENTITIES = 4;
 217 entity nearest_entity[NUM_NEAREST_ENTITIES];
 218 float nearest_length[NUM_NEAREST_ENTITIES];
 219 entity(vector point, .string field, string value, vector axismod) findnearest =
 220 {
 221         entity localhead;
 222         float i;
 223         float j;
 224         float len;
 225         vector dist;
 226
 227         float num_nearest;
 228         num_nearest = 0;
 229
 230         localhead = find(world, field, value);
 231         while(localhead)
 232         {
 233                 if((localhead.items == IT_KEY1 || localhead.items == IT_KEY2) && localhead.target == "###item###")
 234                         dist = localhead.oldorigin;
 235                 else
 236                         dist = localhead.origin;
 237                 dist = dist - point;
 238                 dist = dist_x * axismod_x * '1 0 0' + dist_y * axismod_y * '0 1 0' + dist_z * axismod_z * '0 0 1';
 239                 len = vlen(dist);
 240
 241                 for(i = 0; i < num_nearest; ++i)
 242                 {
 243                         if(len < nearest_length[i])
 244                                 break;
 245                 }
 246
 247                 // now i tells us where to insert at
 248                 //   INSERTION SORT! YOU'VE SEEN IT! RUN!
 249                 if(i < NUM_NEAREST_ENTITIES)
 250                 {
 251                         for(j = NUM_NEAREST_ENTITIES - 1; j >= i; --j)
 252                         {
 253                                 nearest_length[j + 1] = nearest_length[j];
 254                                 nearest_entity[j + 1] = nearest_entity[j];
 255                         }
 256                         nearest_length[i] = len;
 257                         nearest_entity[i] = localhead;
 258                         if(num_nearest < NUM_NEAREST_ENTITIES)
 259                                 num_nearest = num_nearest + 1;
 260                 }
 261
 262                 localhead = find(localhead, field, value);
 263         }
 264
 265         // now use the first one from our list that we can see
 266         for(i = 0; i < num_nearest; ++i)
 267         {
 268                 traceline(point, nearest_entity[i].origin, TRUE, world);
 269                 if(trace_fraction == 1)
 270                 {
 271                         if(i != 0)
 272                         {
 273                                 dprint("Nearest point (");
 274                                 dprint(nearest_entity[0].netname);
 275                                 dprint(") is not visible, using a visible one.\n");
 276                         }
 277                         return nearest_entity[i];
 278                 }
 279         }
 280
 281         if(num_nearest == 0)
 282                 return world;
 283
 284         dprint("Not seeing any location point, using nearest as fallback.\n");
 285         /* DEBUGGING CODE:
 286         dprint("Candidates were: ");
 287         for(j = 0; j < num_nearest; ++j)
 288         {
 289                 if(j != 0)
 290                         dprint(", ");
 291                 dprint(nearest_entity[j].netname);
 292         }
 293         dprint("\n");
 294         */
 295
 296         return nearest_entity[0];
 297 }
 298
 299 void() target_location =
 300 {
 301         self.classname = "target_location";
 302         // location name in netname
 303         // eventually support: count, teamgame selectors, line of sight?
 304 };
 305
 306 void() info_location =
 307 {
 308         self.classname = "target_location";
 309         self.message = self.netname;
 310 };
 311
 312 string NearestLocation(vector p)
 313 {
 314         entity loc;
 315         string ret;
 316         ret = "somewhere";
 317         loc = findnearest(p, classname, "target_location", '1 1 1');
 318         if(loc)
 319         {
 320                 ret = loc.message;
 321         }
 322         else
 323         {
 324                 loc = findnearest(p, target, "###item###", '1 1 4');
 325                 if(loc)
 326                         ret = loc.netname;
 327         }
 328         return ret;
 329 }
 330
 331 string(string msg) formatmessage =
 332 {
 333         float p;
 334         float n;
 335         string msg_save;
 336         string escape;
 337         string replacement;
 338         msg_save = strzone(msg);
 339         p = 0;
 340         n = 7;
 341         while(1)
 342         {
 343                 if(n < 1)
 344                         break; // too many replacements
 345                 n = n - 1;
 346                 p = strstr(msg_save, "%", p); // NOTE: this destroys msg as it's a tempstring!
 347                 if(p < 0)
 348                         break;
 349                 replacement = substring(msg_save, p, 2);
 350                 escape = substring(msg_save, p + 1, 1);
 351                 if(escape == "%")
 352                         replacement = "%";
 353                 else if(escape == "a")
 354                         replacement = ftos(floor(self.armorvalue));
 355                 else if(escape == "h")
 356                         replacement = ftos(floor(self.health));
 357                 else if(escape == "l")
 358                         replacement = NearestLocation(self.origin);
 359                 else if(escape == "y")
 360                         replacement = NearestLocation(self.cursor_trace_endpos);
 361                 else if(escape == "d")
 362                         replacement = NearestLocation(self.death_origin);
 363                 else if(escape == "w")
 364                 {
 365                         float wep;
 366                         wep = self.weapon;
 367                         if(!wep)
 368                                 wep = self.switchweapon;
 369                         if(!wep)
 370                                 wep = self.cnt;
 371                         replacement = W_Name(wep);
 372                 }
 373                 else if(escape == "W")
 374                 {
 375                         if(self.items & IT_SHELLS) replacement = "shells";
 376                         else if(self.items & IT_NAILS) replacement = "bullets";
 377                         else if(self.items & IT_ROCKETS) replacement = "rockets";
 378                         else if(self.items & IT_CELLS) replacement = "cells";
 379                         else replacement = "batteries"; // ;)
 380                 }
 381                 else if(escape == "x")
 382                 {
 383                         replacement = self.cursor_trace_ent.netname;
 384                         if(!replacement || !self.cursor_trace_ent)
 385                                 replacement = "nothing";
 386                 }
 387                 else if(escape == "p")
 388                 {
 389                         if(self.last_selected_player)
 390                                 replacement = self.last_selected_player.netname;
 391                         else
 392                                 replacement = "(nobody)";
 393                 }
 394                 msg = strcat(substring(msg_save, 0, p), replacement);
 395                 msg = strcat(msg, substring(msg_save, p+2, strlen(msg_save) - (p+2)));
 396                 strunzone(msg_save);
 397                 msg_save = strzone(msg);
 398                 p = p + 2;
 399         }
 400         msg = strcat(msg_save, "");
 401         strunzone(msg_save);
 402         return msg;
 403 }
 404
 405 /*
 406 =============
 407 GetCvars
 408 =============
 409 Called with:
 410   0:  sends the request
 411   >0: receives a cvar from name=argv(f) value=argv(f+1)
 412 */
 413 void GetCvars_handleString(float f, .string field, string name)
 414 {
 415         if(f < 0)
 416         {
 417                 if(self.field)
 418                         strunzone(self.field);
 419         }
 420         else if(f > 0)
 421         {
 422                 if(argv(f) == name)
 423                 {
 424                         if(self.field)
 425                                 strunzone(self.field);
 426                         self.field = strzone(argv(f + 1));
 427                 }
 428         }
 429         else
 430                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 431 }
 432 void GetCvars_handleFloat(float f, .float field, string name)
 433 {
 434         if(f < 0)
 435         {
 436         }
 437         else if(f > 0)
 438         {
 439                 if(argv(f) == name)
 440                         self.field = stof(argv(f + 1));
 441         }
 442         else
 443                 stuffcmd(self, strcat("sendcvar ", name, "\n"));
 444 }
 445 void GetCvars(float f)
 446 {
 447         GetCvars_handleFloat(f, autoswitch, "cl_autoswitch");
 448         GetCvars_handleFloat(f, cvar_cl_hidewaypoints, "cl_hidewaypoints");
 449         GetCvars_handleFloat(f, cvar_cl_zoomfactor, "cl_zoomfactor");
 450         GetCvars_handleFloat(f, cvar_cl_zoomspeed, "cl_zoomspeed");
 451         GetCvars_handleFloat(f, cvar_cl_playerdetailreduction, "cl_playerdetailreduction");
 452         GetCvars_handleFloat(f, cvar_cl_nogibs, "cl_nogibs");
 453         GetCvars_handleFloat(f, cvar_scr_centertime, "scr_centertime");
 454         GetCvars_handleFloat(f, cvar_cl_shownames, "cl_shownames");
 455         GetCvars_handleString(f, cvar_g_nexuizversion, "g_nexuizversion");
 456         GetCvars_handleFloat(f, cvar_cl_handicap, "cl_handicap");
 457 }
 458
 459 float fexists(string f)
 460 {
 461         float fh;
 462         fh = fopen(f, FILE_READ);
 463         if(fh < 0)
 464                 return FALSE;
 465         fclose(fh);
 466         return TRUE;
 467 }
 468
 469 void backtrace(string msg)
 470 {
 471         float dev;
 472         dev = cvar("developer");
 473         cvar_set("developer", "1");
 474         dprint("\n");
 475         dprint("--- CUT HERE ---\nWARNING: ");
 476         dprint(msg);
 477         dprint("\n");
 478         remove(world); // isn't there any better way to cause a backtrace?
 479         dprint("\n--- CUT UNTIL HERE ---\n");
 480         cvar_set("developer", ftos(dev));
 481 }
 482
 483 void DistributeFragsAmongTeam(entity p, float targetteam, float factor)
 484 {
 485         float nTeam;
 486         entity head;
 487         float f;
 488
 489         if(!teams_matter)
 490                 return;
 491
 492         //if(p.frags < 0)
 493         //{
 494         //      p.frags = 0; // do not harm the new team!
 495         //      return; // won't distribute negative scores
 496         //}
 497
 498         if(p.frags == -666)
 499                 return;
 500
 501         f = ceil(factor * p.frags);
 502         p.frags = p.frags - f;
 503
 504         nTeam = 0;
 505         FOR_EACH_PLAYER(head)
 506                 if(head != p)
 507                         if(head.team == targetteam)
 508                                 nTeam = nTeam + 1;
 509
 510         if(nTeam == 0)
 511                 return;
 512
 513         DistributeEvenly_Init(f, nTeam);
 514
 515         FOR_EACH_PLAYER(head)
 516                 if(head != p)
 517                         if(head.team == targetteam)
 518                                 head.frags = head.frags + DistributeEvenly_Get(1);
 519 }
 520
 521 string Team_ColorCode(float teamid)
 522 {
 523         if(teamid == COLOR_TEAM1)
 524                 return "^1";
 525         else if(teamid == COLOR_TEAM2)
 526                 return "^4";
 527         else if(teamid == COLOR_TEAM3)
 528                 return "^3";
 529         else if(teamid == COLOR_TEAM4)
 530                 return "^6";
 531         else
 532                 return "^7";
 533 }
 534 string Team_ColorName(float t)
 535 {
 536         // fixme: Search for team entities and get their .netname's!
 537         if(t == COLOR_TEAM1)
 538                 return "Red";
 539         if(t == COLOR_TEAM2)
 540                 return "Blue";
 541         if(t == COLOR_TEAM3)
 542                 return "Yellow";
 543         if(t == COLOR_TEAM4)
 544                 return "Pink";
 545         return "Neutral";
 546 }
 547 string Team_ColorNameLowerCase(float t)
 548 {
 549         // fixme: Search for team entities and get their .netname's!
 550         if(t == COLOR_TEAM1)
 551                 return "red";
 552         if(t == COLOR_TEAM2)
 553                 return "blue";
 554         if(t == COLOR_TEAM3)
 555                 return "yellow";
 556         if(t == COLOR_TEAM4)
 557                 return "pink";
 558         return "neutral";
 559 }
 560
 561 /*
 562 string decolorize(string s)
 563 {
 564         string out;
 565         out = "";
 566         while(s != "")
 567         {
 568                 float n;
 569                 string ch1, ch2;
 570                 n = 1;
 571                 ch1 = substring(s, 0, 1);
 572                 ch2 = substring(s, 1, 1);
 573                 if(ch1 == "^")
 574                 {
 575                         n = 2;
 576                         if(ch2 == "^")
 577                                 out = strcat(out, "^^");
 578                         else if(ch2 == "0")
 579                                 out = strcat1(out);
 580                         else if(ch2 == "1")
 581                                 out = strcat1(out);
 582                         else if(ch2 == "2")
 583                                 out = strcat1(out);
 584                         else if(ch2 == "3")
 585                                 out = strcat1(out);
 586                         else if(ch2 == "4")
 587                                 out = strcat1(out);
 588                         else if(ch2 == "5")
 589                                 out = strcat1(out);
 590                         else if(ch2 == "6")
 591                                 out = strcat1(out);
 592                         else if(ch2 == "7")
 593                                 out = strcat1(out);
 594                         else if(ch2 == "8")
 595                                 out = strcat1(out);
 596                         else if(ch2 == "9")
 597                                 out = strcat1(out);
 598                         else
 599                         {
 600                                 n = 1;
 601                                 out = strcat(out, "^^");
 602                         }
 603                         s = substring(s, n, strlen(s) - n);
 604                 }
 605                 else
 606                 {
 607                         s = substring(s, 1, strlen(s) - 1);
 608                         out = strcat(out, ch1);
 609                 }
 610         }
 611         return out;
 612 }
 613 #define strdecolorize(s) decolorize(s)
 614 #define strlennocol(s) strlen(decolorize(s))
 615 */
 616
 617 #define CENTERPRIO_POINT 1
 618 #define CENTERPRIO_SPAM 2
 619 #define CENTERPRIO_REBALANCE 2
 620 #define CENTERPRIO_VOTE 4
 621 #define CENTERPRIO_NORMAL 5
 622 #define CENTERPRIO_MAPVOTE 9
 623 #define CENTERPRIO_ADMIN 99
 624 .float centerprint_priority;
 625 .float centerprint_expires;
 626 void centerprint_atprio(entity e, float prio, string s)
 627 {
 628         if(intermission_running)
 629                 if(prio < CENTERPRIO_MAPVOTE)
 630                         return;
 631         if(time > e.centerprint_expires)
 632                 e.centerprint_priority = 0;
 633         if(prio >= e.centerprint_priority)
 634         {
 635                 e.centerprint_priority = prio;
 636                 e.centerprint_expires = time + e.cvar_scr_centertime;
 637                 centerprint_builtin(e, s);
 638         }
 639 }
 640 void centerprint_expire(entity e, float prio)
 641 {
 642         if(prio == e.centerprint_priority)
 643         {
 644                 e.centerprint_priority = 0;
 645                 centerprint_builtin(e, "");
 646         }
 647 }
 648 void centerprint(entity e, string s)
 649 {
 650         centerprint_atprio(e, CENTERPRIO_NORMAL, s);
 651 }
 652
 653 void VoteNag();
 654
 655 // decolorizes and team colors the player name when needed
 656 string playername(entity p)
 657 {
 658         string t;
 659         if(teams_matter && !intermission_running && p.classname == "player")
 660         {
 661                 t = Team_ColorCode(p.team);
 662                 return strcat(t, strdecolorize(p.netname));
 663         }
 664         else
 665                 return p.netname;
 666 }
 667
 668 vector(vector m1, vector m2) randompos =
 669 {
 670         local vector v;
 671         m2 = m2 - m1;
 672         v_x = m2_x * random() + m1_x;
 673         v_y = m2_y * random() + m1_y;
 674         v_z = m2_z * random() + m1_z;
 675         return  v;
 676 };
 677
 678 // requires that m2>m1 in all coordinates, and that m4>m3
 679 float(vector m1, vector m2, vector m3, vector m4) boxesoverlap = {return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z;};
 680
 681 // requires the same, but is a stronger condition
 682 float(vector smins, vector smaxs, vector bmins, vector bmaxs) boxinsidebox = {return smins_x >= bmins_x && smaxs_x <= bmaxs_x && smins_y >= bmins_y && smaxs_y <= bmaxs_y && smins_z >= bmins_z && smaxs_z <= bmaxs_z;};
 683
 684 float g_pickup_shells;
 685 float g_pickup_shells_max;
 686 float g_pickup_nails;
 687 float g_pickup_nails_max;
 688 float g_pickup_rockets;
 689 float g_pickup_rockets_max;
 690 float g_pickup_cells;
 691 float g_pickup_cells_max;
 692 float g_pickup_armorsmall;
 693 float g_pickup_armorsmall_max;
 694 float g_pickup_armormedium;
 695 float g_pickup_armormedium_max;
 696 float g_pickup_armorlarge;
 697 float g_pickup_armorlarge_max;
 698 float g_pickup_healthsmall;
 699 float g_pickup_healthsmall_max;
 700 float g_pickup_healthmedium;
 701 float g_pickup_healthmedium_max;
 702 float g_pickup_healthlarge;
 703 float g_pickup_healthlarge_max;
 704 float g_pickup_healthmega;
 705 float g_pickup_healthmega_max;
 706
 707 float start_items;
 708 float start_switchweapon;
 709 float start_ammo_shells;
 710 float start_ammo_nails;
 711 float start_ammo_rockets;
 712 float start_ammo_cells;
 713 float start_health;
 714 float start_armorvalue;
 715
 716 void readlevelcvars(void)
 717 {
 718         sv_cheats = cvar("sv_cheats");
 719         g_cloaked = cvar("g_cloaked");
 720         g_footsteps = cvar("g_footsteps");
 721         g_grappling_hook = cvar("g_grappling_hook");
 722         g_instagib = cvar("g_instagib");
 723         g_laserguided_missile = cvar("g_laserguided_missile");
 724         g_midair = cvar("g_midair");
 725         g_minstagib = cvar("g_minstagib");
 726         g_nixnex = cvar("g_nixnex");
 727         g_nixnex_with_laser = cvar("g_nixnex_with_laser");
 728         g_norecoil = cvar("g_norecoil");
 729         g_rocketarena = cvar("g_rocketarena");
 730         g_vampire = cvar("g_vampire");
 731
 732         g_pickup_shells                    = cvar("g_pickup_shells");
 733         g_pickup_shells_max                = cvar("g_pickup_shells_max");
 734         g_pickup_nails                     = cvar("g_pickup_nails");
 735         g_pickup_nails_max                 = cvar("g_pickup_nails_max");
 736         g_pickup_rockets                   = cvar("g_pickup_rockets");
 737         g_pickup_rockets_max               = cvar("g_pickup_rockets_max");
 738         g_pickup_cells                     = cvar("g_pickup_cells");
 739         g_pickup_cells_max                 = cvar("g_pickup_cells_max");
 740         g_pickup_armorsmall                = cvar("g_pickup_armorsmall");
 741         g_pickup_armorsmall_max            = cvar("g_pickup_armorsmall_max");
 742         g_pickup_armormedium               = cvar("g_pickup_armormedium");
 743         g_pickup_armormedium_max           = cvar("g_pickup_armormedium_max");
 744         g_pickup_armorlarge                = cvar("g_pickup_armorlarge");
 745         g_pickup_armorlarge_max            = cvar("g_pickup_armorlarge_max");
 746         g_pickup_healthsmall               = cvar("g_pickup_healthsmall");
 747         g_pickup_healthsmall_max           = cvar("g_pickup_healthsmall_max");
 748         g_pickup_healthmedium              = cvar("g_pickup_healthmedium");
 749         g_pickup_healthmedium_max          = cvar("g_pickup_healthmedium_max");
 750         g_pickup_healthlarge               = cvar("g_pickup_healthlarge");
 751         g_pickup_healthlarge_max           = cvar("g_pickup_healthlarge_max");
 752         g_pickup_healthmega                = cvar("g_pickup_healthmega");
 753         g_pickup_healthmega_max            = cvar("g_pickup_healthmega_max");
 754
 755         // initialize starting values for players
 756         start_items = 0;
 757         start_switchweapon = 0;
 758         start_ammo_shells = 0;
 759         start_ammo_nails = 0;
 760         start_ammo_rockets = 0;
 761         start_ammo_cells = 0;
 762         start_health = cvar("g_balance_health_start");
 763         start_armorvalue = cvar("g_balance_armor_start");
 764
 765         if(g_instagib)
 766         {
 767                 start_items = IT_NEX;
 768                 start_switchweapon = WEP_NEX;
 769                 weapon_action(start_switchweapon, WR_PRECACHE);
 770                 start_ammo_cells = 999;
 771         }
 772         else if(g_rocketarena)
 773         {
 774                 start_items = IT_ROCKET_LAUNCHER;
 775                 start_switchweapon = WEP_ROCKET_LAUNCHER;
 776                 weapon_action(start_switchweapon, WR_PRECACHE);
 777                 start_ammo_rockets = 999;
 778         }
 779         else if(g_nixnex)
 780         {
 781                 start_items = 0;
 782                 // will be done later
 783         }
 784         else if(g_minstagib)
 785         {
 786                 start_health = 100;
 787                 start_armorvalue = 0;
 788                 start_items = IT_NEX;
 789                 start_switchweapon = WEP_NEX;
 790                 weapon_action(start_switchweapon, WR_PRECACHE);
 791                 start_ammo_cells = cvar("g_minstagib_ammo_start");
 792                 g_minstagib_invis_alpha = cvar("g_minstagib_invis_alpha");
 793         }
 794         else
 795         {
 796                 if(g_lms)
 797                 {
 798                         start_ammo_shells = cvar("g_lms_start_ammo_shells");
 799                         start_ammo_nails = cvar("g_lms_start_ammo_nails");
 800                         start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 801                         start_ammo_cells = cvar("g_lms_start_ammo_cells");
 802                         start_health = cvar("g_lms_start_health");
 803                         start_armorvalue = cvar("g_lms_start_armor");
 804                 }
 805                 else if (cvar("g_use_ammunition")) {
 806                         start_ammo_shells = cvar("g_start_ammo_shells");
 807                         start_ammo_nails = cvar("g_start_ammo_nails");
 808                         start_ammo_rockets = cvar("g_start_ammo_rockets");
 809                         start_ammo_cells = cvar("g_start_ammo_cells");
 810                 } else {
 811                         start_ammo_shells = cvar("g_pickup_shells_max");
 812                         start_ammo_nails = cvar("g_pickup_nails_max");
 813                         start_ammo_rockets = cvar("g_pickup_rockets_max");
 814                         start_ammo_cells = cvar("g_pickup_cells_max");
 815                 }
 816
 817                 if (cvar("g_start_weapon_laser") || g_lms)
 818                 {
 819                         start_items = start_items | IT_LASER;
 820                         start_switchweapon = WEP_LASER;
 821                         weapon_action(start_switchweapon, WR_PRECACHE);
 822                 }
 823                 if (cvar("g_start_weapon_shotgun") || g_lms)
 824                 {
 825                         start_items = start_items | IT_SHOTGUN;
 826                         start_switchweapon = WEP_SHOTGUN;
 827                         weapon_action(start_switchweapon, WR_PRECACHE);
 828                 }
 829                 if (cvar("g_start_weapon_uzi") || g_lms)
 830                 {
 831                         start_items = start_items | IT_UZI;
 832                         start_switchweapon = WEP_UZI;
 833                         weapon_action(start_switchweapon, WR_PRECACHE);
 834                 }
 835                 if (cvar("g_start_weapon_grenadelauncher") || g_lms)
 836                 {
 837                         start_items = start_items | IT_GRENADE_LAUNCHER;
 838                         start_switchweapon = WEP_GRENADE_LAUNCHER;
 839                         weapon_action(start_switchweapon, WR_PRECACHE);
 840                 }
 841                 if (cvar("g_start_weapon_electro") || g_lms)
 842                 {
 843                         start_items = start_items | IT_ELECTRO;
 844                         start_switchweapon = WEP_ELECTRO;
 845                         weapon_action(start_switchweapon, WR_PRECACHE);
 846                 }
 847                 if (cvar("g_start_weapon_crylink") || g_lms)
 848                 {
 849                         start_items = start_items | IT_CRYLINK;
 850                         start_switchweapon = WEP_CRYLINK;
 851                         weapon_action(start_switchweapon, WR_PRECACHE);
 852                 }
 853                 if (cvar("g_start_weapon_nex") || g_lms)
 854                 {
 855                         start_items = start_items | IT_NEX;
 856                         start_switchweapon = WEP_NEX;
 857                         weapon_action(start_switchweapon, WR_PRECACHE);
 858                 }
 859                 if (cvar("g_start_weapon_hagar") || g_lms)
 860                 {
 861                         start_items = start_items | IT_HAGAR;
 862                         start_switchweapon = WEP_HAGAR;
 863                         weapon_action(start_switchweapon, WR_PRECACHE);
 864                 }
 865                 if (cvar("g_start_weapon_rocketlauncher") || g_lms)
 866                 {
 867                         start_items = start_items | IT_ROCKET_LAUNCHER;
 868                         start_switchweapon = WEP_ROCKET_LAUNCHER;
 869                         weapon_action(start_switchweapon, WR_PRECACHE);
 870                 }
 871         }
 872 }
 873
 874 /*
 875 // TODO sound pack system
 876 string soundpack;
 877
 878 string precache_sound_builtin (string s) = #19;
 879 void(entity e, float chan, string samp, float vol, float atten) sound_builtin = #8;
 880 string precache_sound(string s)
 881 {
 882         return precache_sound_builtin(strcat(soundpack, s));
 883 }
 884 void play2(entity e, string filename)
 885 {
 886         stuffcmd(e, strcat("play2 ", soundpack, filename, "\n"));
 887 }
 888 void sound(entity e, float chan, string samp, float vol, float atten)
 889 {
 890         sound_builtin(e, chan, strcat(soundpack, samp), vol, atten);
 891 }
 892 */
 893
 894 string precache_sound (string s) = #19;
 895 void(entity e, float chan, string samp, float vol, float atten) sound = #8;
 896 void play2(entity e, string filename)
 897 {
 898         stuffcmd(e, strcat("play2 ", filename, "\n"));
 899 }
 900
 901 void play2team(float t, string filename)
 902 {
 903         local entity head;
 904         FOR_EACH_REALPLAYER(head)
 905         {
 906                 if (head.team == t)
 907                         play2(head, filename);
 908         }
 909 }
 910
 911 void PrecachePlayerSounds(string f);
 912 void precache_all_models(string pattern)
 913 {
 914         float globhandle, i, n;
 915         string f;
 916
 917         globhandle = search_begin(pattern, TRUE, FALSE);
 918         if(globhandle < 0)
 919                 return;
 920         n = search_getsize(globhandle);
 921         for(i = 0; i < n; ++i)
 922         {
 923                 //print(search_getfilename(globhandle, i), "\n");
 924                 f = search_getfilename(globhandle, i);
 925                 precache_model(f);
 926                 PrecachePlayerSounds(strcat(f, ".sounds"));
 927         }
 928         search_end(globhandle);
 929 }
 930
 931 void precache()
 932 {
 933         // gamemode related things
 934         precache_model ("models/misc/chatbubble.spr");
 935         precache_model ("models/misc/teambubble.spr");
 936         if (g_runematch)
 937         {
 938                 precache_model ("models/runematch/curse.mdl");
 939                 precache_model ("models/runematch/rune.mdl");
 940         }
 941
 942         // Precache all player models if desired
 943         if (cvar("sv_precacheplayermodels"))
 944         {
 945                 PrecachePlayerSounds("sound/player/default.sounds");
 946                 precache_all_models("models/player/*.zym");
 947                 precache_all_models("models/player/*.dpm");
 948                 precache_all_models("models/player/*.md3");
 949                 precache_all_models("models/player/*.psk");
 950                 //precache_model("models/player/carni.zym");
 951                 //precache_model("models/player/crash.zym");
 952                 //precache_model("models/player/grunt.zym");
 953                 //precache_model("models/player/headhunter.zym");
 954                 //precache_model("models/player/insurrectionist.zym");
 955                 //precache_model("models/player/jeandarc.zym");
 956                 //precache_model("models/player/lurk.zym");
 957                 //precache_model("models/player/lycanthrope.zym");
 958                 //precache_model("models/player/marine.zym");
 959                 //precache_model("models/player/nexus.zym");
 960                 //precache_model("models/player/pyria.zym");
 961                 //precache_model("models/player/shock.zym");
 962                 //precache_model("models/player/skadi.zym");
 963                 //precache_model("models/player/specop.zym");
 964                 //precache_model("models/player/visitant.zym");
 965         }
 966
 967         if (g_footsteps)
 968         {
 969                 precache_sound ("misc/footstep01.wav");
 970                 precache_sound ("misc/footstep02.wav");
 971                 precache_sound ("misc/footstep03.wav");
 972                 precache_sound ("misc/footstep04.wav");
 973                 precache_sound ("misc/footstep05.wav");
 974                 precache_sound ("misc/footstep06.wav");
 975         }
 976
 977         // gore and miscellaneous sounds
 978         //precache_sound ("misc/h2ohit.wav");
 979         precache_model ("models/gibs/bloodyskull.md3");
 980         precache_model ("models/gibs/chunk.mdl");
 981         precache_model ("models/gibs/eye.md3");
 982         precache_model ("models/gibs/gib1.md3");
 983         precache_model ("models/gibs/gib1.mdl");
 984         precache_model ("models/gibs/gib2.mdl");
 985         precache_model ("models/gibs/gib3.mdl");
 986         precache_model ("models/gibs/gib5.md3");
 987         precache_model ("models/hook.md3");
 988         precache_sound ("misc/armorimpact.wav");
 989         precache_sound ("misc/bodyimpact1.wav");
 990         precache_sound ("misc/bodyimpact2.wav");
 991         precache_sound ("misc/gib.wav");
 992         precache_sound ("misc/gib_splat01.wav");
 993         precache_sound ("misc/gib_splat02.wav");
 994         precache_sound ("misc/gib_splat03.wav");
 995         precache_sound ("misc/gib_splat04.wav");
 996         precache_sound ("misc/hit.wav");
 997         precache_sound ("misc/hitground1.wav");
 998         precache_sound ("misc/hitground2.wav");
 999         precache_sound ("misc/hitground3.wav");
1000         precache_sound ("misc/hitground4.wav");
1001         precache_sound ("misc/null.wav");
1002         precache_sound ("misc/spawn.wav");
1003         precache_sound ("misc/talk.wav");
1004         precache_sound ("misc/teleport.wav");
1005         precache_sound ("player/lava.wav");
1006         precache_sound ("player/slime.wav");
1007
1008         // announcer sounds - male
1009         //precache_sound ("announcer/male/electrobitch.wav");
1010         precache_sound ("announcer/male/03kills.wav");
1011         precache_sound ("announcer/male/05kills.wav");
1012         precache_sound ("announcer/male/10kills.wav");
1013         precache_sound ("announcer/male/15kills.wav");
1014         precache_sound ("announcer/male/20kills.wav");
1015         precache_sound ("announcer/male/25kills.wav");
1016         precache_sound ("announcer/male/30kills.wav");
1017         precache_sound ("announcer/male/botlike.wav");
1018         precache_sound ("announcer/male/yoda.wav");
1019
1020         // announcer sounds - robotic
1021         precache_sound ("announcer/robotic/1fragleft.wav");
1022         precache_sound ("announcer/robotic/1minuteremains.wav");
1023         precache_sound ("announcer/robotic/2fragsleft.wav");
1024         precache_sound ("announcer/robotic/3fragsleft.wav");
1025         if (g_minstagib)
1026         {
1027                 precache_sound ("announcer/robotic/lastsecond.wav");
1028                 precache_sound ("announcer/robotic/narrowly.wav");
1029                 precache_sound ("announcer/robotic/1.wav");
1030                 precache_sound ("announcer/robotic/2.wav");
1031                 precache_sound ("announcer/robotic/3.wav");
1032                 precache_sound ("announcer/robotic/4.wav");
1033                 precache_sound ("announcer/robotic/5.wav");
1034                 precache_sound ("announcer/robotic/6.wav");
1035                 precache_sound ("announcer/robotic/7.wav");
1036                 precache_sound ("announcer/robotic/8.wav");
1037                 precache_sound ("announcer/robotic/9.wav");
1038                 precache_sound ("announcer/robotic/10.wav");
1039         }
1040
1041         // common weapon precaches
1042         precache_sound ("weapons/weapon_switch.wav");
1043         precache_sound ("weapons/weaponpickup.wav");
1044         if (cvar("g_grappling_hook"))
1045         {
1046                 precache_sound ("weapons/hook_fire.wav"); // hook
1047                 precache_sound ("weapons/hook_impact.wav"); // hook
1048         }
1049
1050         if (cvar("sv_precacheweapons") || g_nixnex)
1051         {
1052                 //precache weapon models/sounds
1053                 local float wep;
1054                 wep = WEP_FIRST;
1055                 while (wep <= WEP_LAST)
1056                 {
1057                         weapon_action(wep, WR_PRECACHE);
1058                         wep = wep + 1;
1059                 }
1060         }
1061
1062         // plays music for the level if there is any
1063         if (self.noise)
1064         {
1065                 precache_sound (self.noise);
1066                 ambientsound ('0 0 0', self.noise, 1.00, ATTN_NONE);
1067         }
1068 }