data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 // #define KH_PLAYER_USE_ATTACHMENT
   5 // #define KH_PLAYER_USE_CARRIEDMODEL
   6 // #define KH_KEY_ATTACHMENT_DEBUG
   7
   8 #ifdef KH_PLAYER_USE_ATTACHMENT
   9 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  10 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  11 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  12 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  13 string KH_PLAYER_ATTACHMENT_BONE = "";
  14 #else
  15 float KH_KEY_ZSHIFT = 22;
  16 float KH_KEY_XYDIST = 24;
  17 float KH_KEY_XYSPEED = 45;
  18 #endif
  19 float KH_KEY_WP_ZSHIFT = 20;
  20
  21 vector KH_KEY_MIN = '-10 -10 -46';
  22 vector KH_KEY_MAX = '10 10 3';
  23 float KH_KEY_BRIGHTNESS = 4;
  24
  25 typedef void(void) kh_Think_t;
  26 var kh_Think_t kh_Controller_Thinkfunc;
  27 string kh_Controller_Waitmsg;
  28
  29 float kh_Team_ByID(float t)
  30 {
  31         if(t == 0) return COLOR_TEAM1;
  32         if(t == 1) return COLOR_TEAM2;
  33         if(t == 2) return COLOR_TEAM3;
  34         if(t == 3) return COLOR_TEAM4;
  35         return 0;
  36 }
  37
  38 entity kh_controller;
  39 float kh_tracking_enabled;
  40 float kh_teams;
  41 float kh_interferemsg_time, kh_interferemsg_team;
  42 .entity kh_next, kh_prev; // linked list
  43 .float kh_droptime;
  44 .float kh_dropperteam;
  45
  46 string kh_sound_capture = "sound/ctf/capture.wav";
  47 string kh_sound_destroy = "sound/ctf/return.wav";
  48 string kh_sound_drop = "sound/misc/mouseclick.wav";
  49 string kh_sound_collect = "sound/ctf/take.wav";
  50
  51 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  52 float kh_key_dropped, kh_key_carried;
  53
  54 float kh_GetCarrierSprite(float t, float e)
  55 {
  56         if(t == e)           return kh_sprite_friend;
  57         if(t == COLOR_TEAM1) return kh_sprite_red;
  58         if(t == COLOR_TEAM2) return kh_sprite_blue;
  59         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  60         if(t == COLOR_TEAM4) return kh_sprite_pink;
  61         return 0;
  62 }
  63
  64 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  65 {
  66         kh_Controller_Thinkfunc = func;
  67         kh_controller.cnt = t;
  68         if(kh_Controller_Waitmsg != "")
  69                 strunzone(kh_Controller_Waitmsg);
  70         if(msg == "")
  71                 kh_Controller_Waitmsg = "";
  72         else
  73                 kh_Controller_Waitmsg = strzone(msg);
  74         if(t == 0)
  75                 kh_controller.nextthink = time; // force
  76 }
  77
  78 void kh_Controller_Think()
  79 {
  80         entity e;
  81         if(intermission_running)
  82                 return;
  83         if(self.cnt > 0)
  84         {
  85                 if(kh_Controller_Waitmsg != "")
  86                 {
  87                         string s;
  88                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  89                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  90                         else
  91                                 s = kh_Controller_Waitmsg;
  92
  93                         //dprint(s, "\n");
  94
  95                         FOR_EACH_PLAYER(e)
  96                                 if(clienttype(e) == CLIENTTYPE_REAL)
  97                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  98                 }
  99                 self.cnt -= 1;
 100         }
 101         else if(self.cnt == 0)
 102         {
 103                 self.cnt -= 1;
 104                 kh_Controller_Thinkfunc();
 105         }
 106         self.nextthink = time + 1;
 107 }
 108
 109 // frags f: take from cvar * f
 110 // frags 0: no frags
 111 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 112 {
 113         string s;
 114         if(intermission_running)
 115                 return;
 116         if(frags_player)
 117                 player.frags = player.frags + floor(0.5 + frags_player);
 118         if(frags_owner)
 119                 key.owner.frags = key.owner.frags + floor(0.5 + frags_owner);
 120         if(!cvar("sv_eventlog"))
 121                 return;
 122         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 123         s = strcat(s, ":", ftos(frags_player));
 124         if(key && key.owner)
 125                 s = strcat(s, ":", ftos(key.owner.playerid));
 126         else
 127                 s = strcat(s, ":0");
 128         s = strcat(s, ":", ftos(frags_owner), ":");
 129         if(key)
 130                 s = strcat(s, key.netname);
 131         GameLogEcho(s, FALSE);
 132 }
 133
 134 vector kh_AttachedOrigin(entity e)
 135 {
 136         if(e.tag_entity)
 137         {
 138                 makevectors(e.tag_entity.angles);
 139                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 140         }
 141         else
 142                 return e.origin;
 143 }
 144
 145 void kh_Key_Attach(entity key)
 146 {
 147 #ifdef KH_PLAYER_USE_ATTACHMENT
 148         entity first;
 149         first = key.owner.kh_next;
 150         if(key == first)
 151         {
 152                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 153                 if(key.kh_next)
 154                 {
 155                         setattachment(key.kh_next, key, "");
 156                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 157                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 158                         key.kh_next.angles = '0 0 0';
 159                 }
 160                 else
 161                         setorigin(key, KH_PLAYER_ATTACHMENT);
 162                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 163         }
 164         else
 165         {
 166                 setattachment(key, key.kh_prev, "");
 167                 if(key.kh_next)
 168                         setattachment(key.kh_next, key, "");
 169                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 170                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 171                 key.angles = '0 0 0';
 172         }
 173 #else
 174         setattachment(key, key.owner, "");
 175         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT); // fixing x, y in think
 176         key.angles_y -= key.owner.angles_y;
 177 #endif
 178         key.flags = 0;
 179         key.solid = SOLID_NOT;
 180         key.movetype = MOVETYPE_NONE;
 181         key.team = key.owner.team;
 182         key.nextthink = time;
 183         key.damageforcescale = 0;
 184         key.modelindex = kh_key_carried;
 185 }
 186
 187 void kh_Key_Detach(entity key)
 188 {
 189 #ifdef KH_PLAYER_USE_ATTACHMENT
 190         entity first;
 191         first = key.owner.kh_next;
 192         if(key == first)
 193         {
 194                 if(key.kh_next)
 195                 {
 196                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 197                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 198                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 199                 }
 200         }
 201         else
 202         {
 203                 if(key.kh_next)
 204                         setattachment(key.kh_next, key.kh_prev, "");
 205                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 206         }
 207         // in any case:
 208         setattachment(key, world, "");
 209         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 210         key.angles = key.owner.angles;
 211 #else
 212         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 213         setattachment(key, world, "");
 214         key.angles_y += key.owner.angles_y;
 215 #endif
 216         key.aiment = world;
 217         key.flags = FL_ITEM;
 218         key.solid = SOLID_TRIGGER;
 219         key.movetype = MOVETYPE_TOSS;
 220         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 221         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 222         // let key.team stay
 223         key.modelindex = kh_key_dropped;
 224 }
 225
 226 void kh_Key_AssignTo(entity key, entity player)
 227 {
 228         if(key.owner == player)
 229                 return;
 230
 231         if(key.owner)
 232         {
 233                 kh_Key_Detach(key);
 234
 235                 // remove from linked list
 236                 if(key.kh_next)
 237                         key.kh_next.kh_prev = key.kh_prev;
 238                 key.kh_prev.kh_next = key.kh_next;
 239                 key.kh_next = world;
 240                 key.kh_prev = world;
 241
 242                 if(key.owner.kh_next == world)
 243                 {
 244                         // No longer a key carrier
 245                         WaypointSprite_DetachCarrier(key.owner);
 246                 }
 247         }
 248
 249         key.owner = player;
 250
 251         if(player)
 252         {
 253                 // insert into linked list
 254                 key.kh_next = player.kh_next;
 255                 key.kh_prev = player;
 256                 player.kh_next = key;
 257                 if(key.kh_next)
 258                         key.kh_next.kh_prev = key;
 259
 260                 kh_Key_Attach(key);
 261
 262                 if(key.kh_next == world)
 263                 {
 264                         // player is now a key carrier
 265                         WaypointSprite_AttachCarrier("", player);
 266                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 267                         player.waypointsprite_attachedforcarrier.team = player.team;
 268                 }
 269         }
 270
 271         key.pusher = world;
 272 }
 273
 274 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 275 {
 276         if(self.owner)
 277                 return;
 278         if(vlen(force) <= 0)
 279                 return;
 280         if(time > self.pushltime)
 281                 if(attacker.classname == "player")
 282                         self.team = attacker.team;
 283 }
 284
 285 vector kh_TeamColor(float teem)
 286 {
 287         switch(teem)
 288         {
 289                 case COLOR_TEAM1:
 290                         //return '103 0 0' / 255.0;
 291                         return '0.4039 0.0000 0.0000';
 292                 case COLOR_TEAM2:
 293                         //return '35 35 191' / 255.0;
 294                         return '0.1373 0.1373 0.7490';
 295                 case COLOR_TEAM3:
 296                         //return '187 167 15' / 255.0;
 297                         return '0.7333 0.6549 0.0588';
 298                 case COLOR_TEAM4:
 299                         //return '139 79 107' / 255.0;
 300                         return '0.5451 0.3099 0.4196';
 301                 default:
 302                         return '1 1 1';
 303         }
 304 }
 305
 306 void kh_Key_Spawn(entity initial_owner, float angle)
 307 {
 308         entity key;
 309         key = spawn();
 310         key.classname = STR_ITEM_KH_KEY;
 311         key.touch = kh_Key_Touch;
 312         key.think = kh_Key_Think;
 313         key.nextthink = time;
 314         key.items = IT_KEY1 | IT_KEY2;
 315         key.cnt = angle;
 316         key.angles = '0 360 0' * random();
 317         key.event_damage = kh_Key_Damage;
 318         key.modelindex = kh_key_dropped;
 319         key.model = "key";
 320         key.kh_dropperteam = 0;
 321         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 322         key.colormod = kh_TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 323
 324         switch(initial_owner.team)
 325         {
 326                 case COLOR_TEAM1:
 327                         key.netname = "^1red key";
 328                         break;
 329                 case COLOR_TEAM2:
 330                         key.netname = "^4blue key";
 331                         break;
 332                 case COLOR_TEAM3:
 333                         key.netname = "^3yellow key";
 334                         break;
 335                 case COLOR_TEAM4:
 336                         key.netname = "^6pink key";
 337                         break;
 338                 default:
 339                         key.netname = "NETGIER key";
 340                         break;
 341         }
 342
 343         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 344
 345         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 346         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 347
 348         kh_Key_AssignTo(key, initial_owner);
 349 }
 350
 351 void kh_Key_Remove(entity key)
 352 {
 353         entity o;
 354         o = key.owner;
 355         kh_Key_AssignTo(key, world);
 356         if(o) // it was attached
 357                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 358         else // it was dropped
 359                 WaypointSprite_DetachCarrier(key);
 360
 361         remove(key);
 362 }
 363
 364 // -1 when no team completely owns all keys yet
 365 float kh_Key_AllOwnedByWhichTeam()
 366 {
 367         entity key;
 368         float teem;
 369
 370         teem = -1;
 371         FOR_EACH_KH_KEY(key)
 372         {
 373                 if(!key.owner)
 374                         return -1;
 375                 if(teem == -1)
 376                         teem = key.team;
 377                 else if(teem != key.team)
 378                         return -1;
 379         }
 380         return teem;
 381 }
 382
 383 void kh_Key_Collect(entity key, entity player)
 384 {
 385         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 386
 387         if(key.kh_dropperteam != player.team)
 388                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 389         key.kh_dropperteam = 0;
 390         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 391         kh_Key_AssignTo(key, player);
 392
 393         if(kh_Key_AllOwnedByWhichTeam() != -1)
 394         {
 395                 kh_interferemsg_time = time + 0.2;
 396                 kh_interferemsg_team = player.team;
 397         }
 398 }
 399
 400 void kh_Key_DropAll(entity player, float suicide)
 401 {
 402         entity key;
 403         entity mypusher;
 404         if(player.kh_next)
 405         {
 406                 mypusher = world;
 407                 if(player.pusher)
 408                         if(time < player.pushltime)
 409                                 mypusher = player.pusher;
 410                 while((key = player.kh_next))
 411                 {
 412                         kh_Scores_Event(player, key, "losekey", 0, 0);
 413                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 414                         kh_Key_AssignTo(key, world);
 415                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 416                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 417                         key.pusher = mypusher;
 418                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 419                         if(suicide)
 420                                 key.kh_dropperteam = player.team;
 421                 }
 422                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 423         }
 424 }
 425
 426 void kh_Key_Touch()
 427 {
 428         if(intermission_running)
 429                 return;
 430
 431         if(self.owner) // already carried
 432                 return;
 433         if(other.classname != "player")
 434                 return;
 435         if(other.deadflag != DEAD_NO)
 436                 return;
 437         if(other == self.enemy)
 438                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 439                         return; // you just dropped it!
 440         kh_Key_Collect(self, other);
 441 }
 442
 443 void kh_Key_Think()
 444 {
 445         entity head;
 446
 447         if(intermission_running)
 448                 return;
 449
 450 #ifdef KH_KEY_ATTACHMENT_DEBUG
 451         if(self.kh_prev == self.owner)
 452         {
 453                 if(cvar_string("_angles") != "")
 454                 {
 455                         self.angles = stov(cvar_string("_angles"));
 456                         self.origin = stov(cvar_string("_origin"));
 457                 }
 458         }
 459 #endif
 460
 461         if(self.owner)
 462         {
 463 #ifndef KH_PLAYER_USE_ATTACHMENT
 464                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * KH_KEY_XYSPEED));
 465                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 466 #endif
 467
 468                 if(self.owner.buttonuse)
 469                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 470                 {
 471                         self.owner.kh_droptime = time;
 472                         self.kh_droptime = time; // prevent collecting this one for some time
 473                         self.enemy = self.owner;
 474                         self.pusher = world;
 475                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 476                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 477                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 478                         makevectors(self.owner.v_angle);
 479                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 480                         kh_Key_AssignTo(self, world);
 481                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 482                         self.kh_dropperteam = self.team;
 483                 }
 484         }
 485
 486         // if in nodrop or time over, end the round
 487         if(!self.owner)
 488                 if(time > self.pain_finished)
 489                         kh_LoserTeam(self.team, self);
 490
 491         if(self.owner)
 492         if(kh_Key_AllOwnedByWhichTeam() != -1)
 493         {
 494                 entity key;
 495                 vector p;
 496                 p = self.owner.origin;
 497                 FOR_EACH_KH_KEY(key)
 498                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 499                                 goto not_winning;
 500                 kh_WinnerTeam(self.team);
 501 :not_winning
 502         }
 503
 504         if(kh_interferemsg_time && time > kh_interferemsg_time)
 505         {
 506                 kh_interferemsg_time = 0;
 507                 FOR_EACH_PLAYER(head)
 508                 {
 509                         if(head.team == kh_interferemsg_team)
 510                                 if(head.kh_next)
 511                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 512                                 else
 513                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 514                         else
 515                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 516                 }
 517         }
 518
 519         self.nextthink = time + 0.05;
 520 }
 521
 522 void kh_WinnerTeam(float teem)
 523 {
 524         // all key carriers get some points
 525         vector firstorigin, lastorigin, midpoint;
 526         float first;
 527         entity key;
 528         float score;
 529         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 530         DistributeEvenly_Init(score, kh_teams);
 531         // twice the score for 3 team games, three times the score for 4 team games!
 532         // note: for a win by destroying the key, this should NOT be applied
 533         FOR_EACH_KH_KEY(key)
 534                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 535
 536         first = TRUE;
 537         FOR_EACH_KH_KEY(key)
 538                 if(key.owner.kh_next == key)
 539                 {
 540                         if(!first)
 541                                 bprint("^7, ");
 542                         bprint(key.owner.netname);
 543                         first = FALSE;
 544                 }
 545         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 546
 547         first = TRUE;
 548         midpoint = '0 0 0';
 549         FOR_EACH_KH_KEY(key)
 550         {
 551                 vector thisorigin;
 552
 553                 thisorigin = kh_AttachedOrigin(key);
 554                 dprint("Key origin: ", vtos(thisorigin), "\n");
 555                 midpoint += thisorigin;
 556
 557                 if(!first)
 558                         te_lightning2(world, lastorigin, thisorigin);
 559                 lastorigin = thisorigin;
 560                 if(first)
 561                         firstorigin = thisorigin;
 562                 first = FALSE;
 563         }
 564         if(kh_teams > 2)
 565         {
 566                 te_lightning2(world, lastorigin, firstorigin);
 567         }
 568         midpoint = midpoint * (1 / kh_teams);
 569         te_customflash(midpoint, 1000, 1, kh_TeamColor(teem));
 570
 571         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 572         kh_FinishRound();
 573 }
 574
 575 void kh_LoserTeam(float teem, entity lostkey)
 576 {
 577         entity player, key, attacker;
 578         float players;
 579         float keys;
 580
 581         attacker = world;
 582         if(lostkey.pusher)
 583                 if(lostkey.pusher.team != teem)
 584                         if(lostkey.pusher.classname == "player")
 585                                 attacker = lostkey.pusher;
 586
 587         players = keys = 0;
 588
 589         if(attacker)
 590         {
 591                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 592                 centerprint(attacker, "Your push is the best!\n\n\n");
 593                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 594         }
 595         else
 596         {
 597                 float of, fragsleft, i, j, thisteam;
 598                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 599
 600                 FOR_EACH_PLAYER(player)
 601                         if(player.team != teem)
 602                                 ++players;
 603
 604                 FOR_EACH_KH_KEY(key)
 605                         if(key.owner && key.team != teem)
 606                                 ++keys;
 607
 608                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 609
 610                 FOR_EACH_KH_KEY(key)
 611                         if(key.owner && key.team != teem)
 612                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 613
 614                 fragsleft = DistributeEvenly_Get(players);
 615
 616                 // Now distribute these among all other teams...
 617                 j = kh_teams - 1;
 618                 for(i = 0; i < kh_teams; ++i)
 619                 {
 620                         thisteam = kh_Team_ByID(i);
 621                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 622                                 continue;
 623
 624                         players = 0;
 625                         FOR_EACH_PLAYER(player)
 626                                 if(player.team == thisteam)
 627                                         ++players;
 628
 629                         DistributeEvenly_Init(fragsleft, j);
 630                         fragsleft = DistributeEvenly_Get(j - 1);
 631                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 632
 633                         FOR_EACH_PLAYER(player)
 634                                 if(player.team == thisteam)
 635                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 636
 637                         --j;
 638                 }
 639
 640                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 641         }
 642         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 643         te_tarexplosion(lostkey.origin);
 644
 645         kh_FinishRound();
 646 }
 647
 648 void kh_FinishRound()
 649 {
 650         // prepare next round
 651         kh_interferemsg_time = 0;
 652         entity key;
 653         FOR_EACH_KH_KEY(key)
 654                 kh_Key_Remove(key);
 655
 656         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 657 }
 658
 659 string kh_CheckEnoughPlayers()
 660 {
 661         float i, players, teem;
 662         entity player;
 663         string result;
 664         result = "";
 665
 666         // find a random player per team
 667         for(i = 0; i < kh_teams; ++i)
 668         {
 669                 teem = kh_Team_ByID(i);
 670                 players = 0;
 671                 FOR_EACH_PLAYER(player)
 672                         if(player.deadflag == DEAD_NO)
 673                                 if(!player.buttonchat)
 674                                         if(player.team == teem)
 675                                                 ++players;
 676                 if(players == 0)
 677                 {
 678                         if(result != "")
 679                                 result = strcat(result, ", ");
 680                         result = strcat(result, ColoredTeamName(teem));
 681                 }
 682         }
 683         return result;
 684 }
 685
 686 void kh_WaitForPlayers()
 687 {
 688         string teams_missing;
 689         teams_missing = kh_CheckEnoughPlayers();
 690         if(teams_missing == "")
 691                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 692         else
 693                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 694 }
 695
 696 void kh_StartRound()
 697 {
 698         string teams_missing;
 699         float i, players, teem;
 700         entity player;
 701
 702         teams_missing = kh_CheckEnoughPlayers();
 703         if(teams_missing != "")
 704         {
 705                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 706                 return;
 707         }
 708
 709         FOR_EACH_PLAYER(player)
 710                 if(clienttype(player) == CLIENTTYPE_REAL)
 711                         centerprint_expire(player, CENTERPRIO_SPAM);
 712
 713         for(i = 0; i < kh_teams; ++i)
 714         {
 715                 teem = kh_Team_ByID(i);
 716                 players = 0;
 717                 entity my_player;
 718                 FOR_EACH_PLAYER(player)
 719                         if(player.deadflag == DEAD_NO)
 720                                 if(!player.buttonchat)
 721                                         if(player.team == teem)
 722                                         {
 723                                                 ++players;
 724                                                 if(random() * players <= 1)
 725                                                         my_player = player;
 726                                         }
 727                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 728                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 729                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 730         }
 731
 732         kh_tracking_enabled = FALSE;
 733         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 734 }
 735
 736 void kh_setstatus()
 737 {
 738         if(kh_teams)
 739         {
 740                 float kh_KEY;
 741                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 742                 if(self.kh_next)
 743                         self.items = self.items | kh_KEY;
 744                 else
 745                         self.items = self.items - (self.items & kh_KEY);
 746         }
 747 }
 748
 749 void kh_EnableTrackingDevice()
 750 {
 751         entity player;
 752
 753         FOR_EACH_PLAYER(player)
 754                 if(clienttype(player) == CLIENTTYPE_REAL)
 755                         centerprint_expire(player, CENTERPRIO_SPAM);
 756
 757         kh_tracking_enabled = TRUE;
 758 }
 759
 760 float kh_Key_waypointsprite_for_player(entity e)
 761 {
 762         if(!kh_tracking_enabled)
 763                 return 0;
 764         if(!self.owner)
 765                 return kh_sprite_dropped;
 766         if(!self.owner.owner)
 767                 return kh_sprite_dropped;
 768         return 0; // draw only when key is not owned
 769 }
 770
 771 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 772 {
 773         if(e.classname != "player" || self.team != e.team)
 774                 if(!kh_tracking_enabled)
 775                         return 0;
 776
 777         // e is spectator? That's no team mate...
 778         if(e.classname != "player")
 779                 return kh_GetCarrierSprite(self.team, -1);
 780
 781         // e is no key carrier: simple case...
 782         if(!e.kh_next)
 783                 return kh_GetCarrierSprite(self.team, e.team);
 784
 785         // e is a key carrier: if any key is dropped or owned by another team, show
 786         // the carrier sprite; otherwise show run here
 787         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 788                 return kh_sprite_finish;
 789
 790         return kh_GetCarrierSprite(self.team, e.team);
 791 }
 792
 793 float kh_HandleFrags(entity attacker, entity targ, float f)
 794 {
 795         if(attacker == targ)
 796                 return f;
 797
 798         if(targ.kh_next)
 799         {
 800                 if(attacker.team == targ.team)
 801                 {
 802                         entity k;
 803                         float nk;
 804                         nk = 0;
 805                         for(k = targ.kh_next; k != world; k = k.kh_next)
 806                                 ++nk;
 807                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 808                 }
 809                 else
 810                 {
 811                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 812                 }
 813         }
 814
 815         return f;
 816 }
 817
 818 void kh_init()
 819 {
 820         precache_sound(kh_sound_capture);
 821         precache_sound(kh_sound_destroy);
 822         precache_sound(kh_sound_drop);
 823         precache_sound(kh_sound_collect);
 824
 825         precache_model("models/sprites/key-dropped.sp2");
 826         precache_model("models/sprites/keycarrier-finish.sp2");
 827         precache_model("models/sprites/keycarrier-friend.sp2");
 828         precache_model("models/sprites/keycarrier-red.sp2");
 829         precache_model("models/sprites/keycarrier-blue.sp2");
 830         precache_model("models/sprites/keycarrier-yellow.sp2");
 831         precache_model("models/sprites/keycarrier-pink.sp2");
 832 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 833         precache_model("models/keyhunt/key-carried.md3");
 834 #endif
 835         precache_model("models/keyhunt/key.md3");
 836
 837         // setup variables
 838         kh_teams = cvar("g_keyhunt_teams_override");
 839         if(kh_teams < 2)
 840                 kh_teams = cvar("g_keyhunt_teams");
 841         kh_teams = bound(2, kh_teams, 4);
 842
 843         // make a KH entity for controlling the game
 844         kh_controller = spawn();
 845         kh_controller.think = kh_Controller_Think;
 846         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 847
 848         setmodel(kh_controller, "models/keyhunt/key.md3");
 849         kh_key_dropped = kh_controller.modelindex;
 850         /*
 851         dprint(vtos(kh_controller.mins));
 852         dprint(vtos(kh_controller.maxs));
 853         dprint("\n");
 854         */
 855 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 856         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 857         kh_key_carried = kh_controller.modelindex;
 858 #else
 859         kh_key_carried = kh_key_dropped;
 860 #endif
 861         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 862         kh_sprite_dropped = kh_controller.modelindex;
 863         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 864         kh_sprite_finish = kh_controller.modelindex;
 865         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 866         kh_sprite_friend = kh_controller.modelindex;
 867         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 868         kh_sprite_red = kh_controller.modelindex;
 869         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 870         kh_sprite_blue = kh_controller.modelindex;
 871         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 872         kh_sprite_pink = kh_controller.modelindex;
 873         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 874         kh_sprite_yellow = kh_controller.modelindex;
 875         setmodel(kh_controller, "");
 876 }
 877
 878 void kh_finalize()
 879 {
 880         // to be called before intermission
 881         kh_FinishRound();
 882         remove(kh_controller);
 883         kh_controller = world;
 884 }