data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 typedef void(void) kh_Think_t;
   5 var kh_Think_t kh_Controller_Thinkfunc;
   6 string kh_Controller_Waitmsg;
   7
   8 float kh_Team_ByID(float t)
   9 {
  10         if(t == 0) return COLOR_TEAM1;
  11         if(t == 1) return COLOR_TEAM2;
  12         if(t == 2) return COLOR_TEAM3;
  13         if(t == 3) return COLOR_TEAM4;
  14         return 0;
  15 }
  16
  17 entity kh_controller;
  18 float kh_tracking_enabled;
  19 float kh_teams;
  20 float kh_interferemsg_time, kh_interferemsg_team;
  21 .entity kh_next, kh_prev; // linked list
  22 .float kh_droptime;
  23
  24 string kh_sound_capture = "sound/ctf/capture.wav";
  25 string kh_sound_destroy = "sound/ctf/return.wav";
  26 string kh_sound_drop = "sound/misc/mouseclick.wav";
  27 string kh_sound_collect = "sound/ctf/take.wav";
  28
  29 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  30
  31 float kh_GetCarrierSprite(float t, float e)
  32 {
  33         if(t == e)           return kh_sprite_friend;
  34         if(t == COLOR_TEAM1) return kh_sprite_red;
  35         if(t == COLOR_TEAM2) return kh_sprite_blue;
  36         if(t == COLOR_TEAM3) return kh_sprite_pink;
  37         if(t == COLOR_TEAM4) return kh_sprite_yellow;
  38         return 0;
  39 }
  40
  41 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  42 {
  43         kh_Controller_Thinkfunc = func;
  44         kh_controller.cnt = t;
  45         if(kh_Controller_Waitmsg != "")
  46                 strunzone(kh_Controller_Waitmsg);
  47         if(msg == "")
  48                 kh_Controller_Waitmsg = "";
  49         else
  50                 kh_Controller_Waitmsg = strzone(msg);
  51         if(t == 0)
  52                 kh_controller.nextthink = time; // force
  53 }
  54
  55 void kh_Controller_Think()
  56 {
  57         entity e;
  58         if(self.cnt > 0)
  59         {
  60                 if(kh_Controller_Waitmsg != "")
  61                 {
  62                         string s;
  63                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  64                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  65                         else
  66                                 s = kh_Controller_Waitmsg;
  67
  68                         dprint(s, "\n");
  69
  70                         FOR_EACH_PLAYER(e)
  71                                 if(clienttype(e) == CLIENTTYPE_REAL)
  72                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  73                 }
  74                 self.cnt -= 1;
  75         }
  76         else if(self.cnt == 0)
  77         {
  78                 FOR_EACH_PLAYER(e)
  79                         if(clienttype(e) == CLIENTTYPE_REAL)
  80                                 centerprint_expire(e, CENTERPRIO_SPAM);
  81                 self.cnt -= 1;
  82                 kh_Controller_Thinkfunc();
  83         }
  84         self.nextthink = time + 1;
  85 }
  86
  87 void kh_Log()
  88 {
  89         string s;
  90         if(!cvar("sv_eventlog"))
  91                 return;
  92         // TODO ...
  93         GameLogEcho(s, FALSE);
  94 }
  95
  96 // frags f: take from cvar * f
  97 // frags 0: no frags
  98 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
  99 {
 100         float basefrags;
 101         basefrags = cvar(strcat("g_balance_keyhunt_score_", what));
 102
 103         if(frags_player)
 104                 player.frags = player.frags + floor(0.5 + basefrags * frags_player);
 105         if(frags_owner)
 106                 key.owner.frags = key.owner.frags + floor(0.5 + basefrags * frags_owner);
 107 }
 108
 109 void kh_Key_Attach(entity key, float wpchange)
 110 {
 111         setattachment(key, key.owner, "");
 112         setorigin(key, '0 0 0'); // fixed later in think
 113         key.angles = key.angles - '0 1 0' * key.owner.angles_y;
 114         key.flags = 0;
 115         key.solid = SOLID_NOT;
 116         key.movetype = MOVETYPE_NONE;
 117         key.team = key.owner.team;
 118         key.nextthink = time;
 119 }
 120
 121 vector kh_AttachedOrigin(entity e)
 122 {
 123         if(e.tag_entity)
 124         {
 125                 makevectors(e.tag_entity.angles);
 126                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 127         }
 128         else
 129                 return e.origin;
 130 }
 131
 132 void kh_Key_Detach(entity key, float wpchange)
 133 {
 134         setorigin(key, kh_AttachedOrigin(key));
 135         setattachment(key, world, "");
 136         key.angles_y = key.owner.angles_y;
 137         key.aiment = world;
 138         key.flags = FL_ITEM;
 139         key.solid = SOLID_TRIGGER;
 140         key.movetype = MOVETYPE_TOSS;
 141         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 142         // let key.team stay
 143 }
 144
 145 void kh_Key_AssignTo(entity key, entity player, float wpchange)
 146 {
 147         if(key.owner == player)
 148                 return;
 149
 150         if(key.owner)
 151         {
 152                 kh_Key_Detach(key, wpchange);
 153
 154                 // remove from linked list
 155                 if(key.kh_next)
 156                         key.kh_next.kh_prev = key.kh_prev;
 157                 key.kh_prev.kh_next = key.kh_next;
 158                 key.kh_next = world;
 159                 key.kh_prev = world;
 160
 161                 if(key.owner.kh_next == world)
 162                 {
 163                         // No longer a key carrier
 164                         if(wpchange)
 165                                 WaypointSprite_Kill(key.owner.waypointsprite_attachedforcarrier);
 166                         else
 167                                 WaypointSprite_DetachCarrier(key.owner);
 168                 }
 169         }
 170
 171         key.owner = player;
 172
 173         if(player)
 174         {
 175                 // insert into linked list
 176                 key.kh_next = player.kh_next;
 177                 key.kh_prev = player;
 178                 player.kh_next = key;
 179                 if(key.kh_next)
 180                         key.kh_next.kh_prev = key;
 181
 182                 kh_Key_Attach(key, wpchange);
 183
 184                 if(key.kh_next == world)
 185                 {
 186                         // player is now a key carrier
 187                         WaypointSprite_AttachCarrier("", player);
 188                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 189                         player.waypointsprite_attachedforcarrier.team = player.team;
 190                 }
 191         }
 192
 193         key.pusher = world;
 194 }
 195
 196 void kh_Key_Spawn(entity initial_owner, float angle)
 197 {
 198         entity key;
 199         key = spawn();
 200         key.classname = STR_ITEM_KH_KEY;
 201         key.touch = kh_Key_Touch;
 202         key.think = kh_Key_Think;
 203         key.nextthink = time;
 204         key.items = IT_KEY1 | IT_KEY2;
 205         key.cnt = angle;
 206         key.angles = '0 360 0' * random();
 207         setmodel(key, "models/keyhunt/key3.md3");
 208         setsize(key, '0 0 -24', '0 0 25');
 209
 210         switch(initial_owner.team)
 211         {
 212                 case COLOR_TEAM1:
 213                         key.netname = "^1red key";
 214                         key.colormod = '1.73 0.10 0.10';
 215                         break;
 216                 case COLOR_TEAM2:
 217                         key.netname = "^4blue key";
 218                         key.colormod = '0.10 0.10 1.73';
 219                         break;
 220                 case COLOR_TEAM3:
 221                         key.netname = "^6pink key";
 222                         key.colormod = '1.22 0.10 1.22';
 223                         break;
 224                 case COLOR_TEAM4:
 225                         key.netname = "^3yellow key";
 226                         key.colormod = '1.22 1.22 0.10';
 227                         break;
 228                 default:
 229                         key.netname = "NETGIER key";
 230                         key.colormod = '1.00 1.00 1.00';
 231                         break;
 232         }
 233
 234         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 235
 236         WaypointSprite_AttachCarrier("", key);
 237         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 238
 239         kh_Key_AssignTo(key, initial_owner, TRUE);
 240 }
 241
 242 void kh_Key_Remove(entity key)
 243 {
 244         entity o;
 245         o = key.owner;
 246         kh_Key_AssignTo(key, world, FALSE);
 247         if(o) // it was attached
 248                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 249         else // it was dropped
 250                 WaypointSprite_DetachCarrier(key);
 251
 252         remove(key);
 253 }
 254
 255 // -1 when no team completely owns all keys yet
 256 float kh_Key_AllOwnedByWhichTeam()
 257 {
 258         entity key;
 259         float teem;
 260
 261         teem = -1;
 262         FOR_EACH_KH_KEY(key)
 263         {
 264                 if(!key.owner)
 265                         return -1;
 266                 if(teem == -1)
 267                         teem = key.team;
 268                 else if(teem != key.team)
 269                         return -1;
 270         }
 271         return teem;
 272 }
 273
 274 void kh_Key_Collect(entity key, entity player)
 275 {
 276         sound(key, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 277
 278         kh_Scores_Event(player, key, "collect", 1, 0);
 279         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 280         kh_Key_AssignTo(key, player, TRUE);
 281
 282         if(kh_Key_AllOwnedByWhichTeam() != -1)
 283         {
 284                 kh_interferemsg_time = time + 0.2;
 285                 kh_interferemsg_team = player.team;
 286         }
 287 }
 288
 289 void kh_Key_DropAll(entity player)
 290 {
 291         entity key;
 292         entity mypusher;
 293         if(player.kh_next)
 294         {
 295                 mypusher = world;
 296                 if(player.pusher)
 297                         if(time < player.pushltime)
 298                                 mypusher = player.pusher;
 299                 while((key = player.kh_next))
 300                 {
 301                         kh_Scores_Event(player, key, "losekey", 0, 0);
 302                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 303                         kh_Key_AssignTo(key, world, TRUE);
 304                         key.pusher = mypusher;
 305                 }
 306                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 307         }
 308 }
 309
 310 void kh_Key_Touch()
 311 {
 312         if(self.owner) // already carried
 313                 return;
 314         if(other.classname != "player")
 315                 return;
 316         if(other.deadflag != DEAD_NO)
 317                 return;
 318         if(other == self.enemy)
 319                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 320                         return; // you just dropped it!
 321         kh_Key_Collect(self, other);
 322 }
 323
 324 void kh_Key_Think()
 325 {
 326         entity head;
 327
 328         self.angles_y = math_mod(self.angles_y + 0.05 * 135, 360);
 329
 330         if(self.owner)
 331         {
 332                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * 45));
 333                 setorigin(self, v_forward * 16);
 334
 335                 if(self.owner.buttonuse)
 336                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 337                 {
 338                         self.owner.kh_droptime = time;
 339                         self.kh_droptime = time; // prevent collecting this one for some time
 340                         self.enemy = self.owner;
 341                         self.pusher = world;
 342                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 343                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 344                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 345                         kh_Key_AssignTo(self, world, TRUE);
 346                 }
 347         }
 348
 349         // if in nodrop or time over, end the round
 350         if(!self.owner)
 351                 if(time > self.pain_finished)
 352                         kh_LoserTeam(self.team, self);
 353
 354         if(self.owner)
 355         if(kh_Key_AllOwnedByWhichTeam() != -1)
 356         {
 357                 entity key;
 358                 vector p;
 359                 p = self.owner.origin;
 360                 FOR_EACH_KH_KEY(key)
 361                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 362                                 goto not_winning;
 363                 kh_WinnerTeam(self.team);
 364 :not_winning
 365         }
 366
 367         if(kh_interferemsg_time && time > kh_interferemsg_time)
 368         {
 369                 kh_interferemsg_time = 0;
 370                 FOR_EACH_PLAYER(head)
 371                 {
 372                         if(head.team == kh_interferemsg_team)
 373                                 if(head.kh_next)
 374                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 375                                 else
 376                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 377                         else
 378                                 centerprint(head, "All keys are in the enemy's hands!\n\nInterfere ^1NOW^7!\n");
 379                 }
 380         }
 381
 382         self.nextthink = time + 0.05;
 383 }
 384
 385 void kh_WinnerTeam(float teem)
 386 {
 387         // all key carriers get some points
 388         vector firstorigin, lastorigin;
 389         float first;
 390         entity key;
 391         float score;
 392         score = (kh_teams - 1) / kh_teams;
 393         // twice the score for 3 team games, three times the score for 4 team games!
 394         // note: for a win by destroying the key, this should NOT be applied
 395         first = TRUE;
 396         FOR_EACH_KH_KEY(key)
 397         {
 398                 kh_Scores_Event(key.owner, key, "capture", score, 0);
 399                 if(key.owner.kh_next == key)
 400                 {
 401                         if(!first)
 402                                 bprint("^7, ");
 403                         bprint(key.owner.netname);
 404                         first = FALSE;
 405                 }
 406         }
 407
 408         first = TRUE;
 409         FOR_EACH_KH_KEY(key)
 410         {
 411                 vector thisorigin;
 412
 413                 thisorigin = kh_AttachedOrigin(key);
 414
 415                 if(!first)
 416                         te_lightning2(world, lastorigin, thisorigin);
 417                 lastorigin = thisorigin;
 418                 if(first)
 419                         firstorigin = thisorigin;
 420                 first = FALSE;
 421         }
 422         if(kh_teams > 2)
 423         {
 424                 te_lightning2(world, lastorigin, firstorigin);
 425         }
 426
 427         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 428         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 429         kh_FinishRound();
 430 }
 431
 432 void kh_LoserTeam(float teem, entity lostkey)
 433 {
 434         entity player, key, attacker;
 435         float players;
 436         float keys;
 437         float score;
 438
 439         attacker = world;
 440         if(lostkey.pusher)
 441                 if(lostkey.pusher.team != teem)
 442                         if(lostkey.pusher.classname == "player")
 443                                 attacker = lostkey.pusher;
 444
 445         players = keys = 0;
 446
 447         if(attacker)
 448         {
 449                 kh_Scores_Event(attacker, world, "push", 1, 0);
 450                 centerprint(attacker, "Your push is the best!\n\n\n");
 451                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 452         }
 453         else
 454         {
 455                 FOR_EACH_PLAYER(player)
 456                         if(player.team != teem)
 457                                 ++players;
 458
 459                 FOR_EACH_KH_KEY(key)
 460                         if(key.owner && key.team != teem)
 461                                 ++keys;
 462
 463                 score = 1.0 / max(1, keys * cvar("g_balance_keyhunt_score_destroyed_ownfactor") + players);
 464
 465                 FOR_EACH_PLAYER(player)
 466                         if(player.team != teem)
 467                                 kh_Scores_Event(player, world, "destroyed", score, 0);
 468
 469                 FOR_EACH_KH_KEY(key)
 470                         if(key.owner && key.team != teem)
 471                                 kh_Scores_Event(key.owner, world, "destroyed", score * cvar("g_balance_keyhunt_score_destroyed_ownfactor"), 0);
 472
 473                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 474         }
 475         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 476
 477         kh_FinishRound();
 478 }
 479
 480 void kh_FinishRound()
 481 {
 482         // prepare next round
 483         kh_interferemsg_time = 0;
 484         entity key;
 485         FOR_EACH_KH_KEY(key)
 486                 kh_Key_Remove(key);
 487
 488         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 489 }
 490
 491 float kh_EnoughPlayers()
 492 {
 493         float i, players, teem;
 494         entity player;
 495
 496         // find a random player per team
 497         for(i = 0; i < kh_teams; ++i)
 498         {
 499                 teem = kh_Team_ByID(i);
 500                 players = 0;
 501                 FOR_EACH_PLAYER(player)
 502                         if(player.deadflag == DEAD_NO)
 503                                 if(player.team == teem)
 504                                         ++players;
 505                 if(players == 0)
 506                         return FALSE;
 507         }
 508         return TRUE;
 509 }
 510
 511 void kh_WaitForPlayers()
 512 {
 513         if(kh_EnoughPlayers())
 514                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 515         else
 516                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 517 }
 518
 519 void kh_StartRound()
 520 {
 521         float i, players, teem;
 522         entity player;
 523
 524         if(!kh_EnoughPlayers())
 525         {
 526                 kh_Controller_SetThink(1, "Waiting for players to join...", kh_WaitForPlayers);
 527                 return;
 528         }
 529
 530         for(i = 0; i < kh_teams; ++i)
 531         {
 532                 teem = kh_Team_ByID(i);
 533                 players = 0;
 534                 entity my_player;
 535                 FOR_EACH_PLAYER(player)
 536                         if(player.deadflag == DEAD_NO)
 537                                 if(player.team == teem)
 538                                 {
 539                                         ++players;
 540                                         if(random() * players <= 1)
 541                                                 my_player = player;
 542                                 }
 543                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 544         }
 545
 546         kh_tracking_enabled = FALSE;
 547         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 548 }
 549
 550 void kh_setstatus()
 551 {
 552         if(kh_teams)
 553         {
 554                 float kh_KEY;
 555                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 556                 if(self.kh_next)
 557                         self.items = self.items | kh_KEY;
 558                 else
 559                         self.items = self.items - (self.items & kh_KEY);
 560         }
 561 }
 562
 563 void kh_EnableTrackingDevice()
 564 {
 565         kh_tracking_enabled = TRUE;
 566 }
 567
 568 float kh_Key_waypointsprite_for_player(entity e)
 569 {
 570         if(!kh_tracking_enabled)
 571                 return 0;
 572         if(!self.owner)
 573                 return kh_sprite_dropped;
 574         if(!self.owner.owner)
 575                 return kh_sprite_dropped;
 576         return 0; // draw only when key is not owned
 577 }
 578
 579 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 580 {
 581         if(e.classname != "player" || self.team != e.team)
 582                 if(!kh_tracking_enabled)
 583                         return 0;
 584
 585         // e is spectator? That's no team mate...
 586         if(e.classname != "player")
 587                 return kh_GetCarrierSprite(self.team, -1);
 588
 589         // e is no key carrier: simple case...
 590         if(!e.kh_next)
 591                 return kh_GetCarrierSprite(self.team, e.team);
 592
 593         // e is a key carrier: if any key is dropped or owned by another team, show
 594         // the carrier sprite; otherwise show run here
 595         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 596                 return kh_sprite_finish;
 597
 598         return kh_GetCarrierSprite(self.team, e.team);
 599 }
 600
 601 float kh_HandleFrags(entity attacker, entity targ, float f)
 602 {
 603         float newfrags;
 604
 605         if(f <= 0)
 606                 return f;
 607         if(attacker == targ)
 608                 return f;
 609
 610         if(targ.kh_next)
 611                 f = f - 1 + cvar("g_balance_keyhunt_score_carrierfrag");
 612
 613         if(newfrags)
 614                 f = f - 1 + newfrags;
 615         return f;
 616 }
 617
 618 void kh_init()
 619 {
 620         precache_sound(kh_sound_capture);
 621         precache_sound(kh_sound_destroy);
 622         precache_sound(kh_sound_drop);
 623         precache_sound(kh_sound_collect);
 624
 625         precache_model("models/sprites/key-dropped.sp2");
 626         precache_model("models/sprites/keycarrier-finish.sp2");
 627         precache_model("models/sprites/keycarrier-friend.sp2");
 628         precache_model("models/sprites/keycarrier-red.sp2");
 629         precache_model("models/sprites/keycarrier-blue.sp2");
 630         precache_model("models/sprites/keycarrier-pink.sp2");
 631         precache_model("models/sprites/keycarrier-yellow.sp2");
 632         precache_model("models/keyhunt/key3.md3");
 633
 634         // setup variables
 635         kh_teams = cvar("g_keyhunt_teams_override");
 636         if(kh_teams < 2)
 637                 kh_teams = cvar("g_keyhunt_teams");
 638         if(kh_teams < 2)
 639                 kh_teams = 2;
 640
 641         // make a KH entity for controlling the game
 642         kh_controller = spawn();
 643         kh_controller.think = kh_Controller_Think;
 644         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 645
 646         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 647         kh_sprite_dropped = kh_controller.modelindex;
 648         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 649         kh_sprite_finish = kh_controller.modelindex;
 650         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 651         kh_sprite_friend = kh_controller.modelindex;
 652         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 653         kh_sprite_red = kh_controller.modelindex;
 654         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 655         kh_sprite_blue = kh_controller.modelindex;
 656         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 657         kh_sprite_pink = kh_controller.modelindex;
 658         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 659         kh_sprite_yellow = kh_controller.modelindex;
 660         setmodel(kh_controller, "");
 661 }
 662
 663 void kh_finalize()
 664 {
 665         // to be called before intermission
 666         kh_FinishRound();
 667         remove(kh_controller);
 668         kh_controller = world;
 669 }