data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_keylist; v; v = v.enemy )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25
  26 float kh_Team_ByID(float t)
  27 {
  28         if(t == 0) return COLOR_TEAM1;
  29         if(t == 1) return COLOR_TEAM2;
  30         if(t == 2) return COLOR_TEAM3;
  31         if(t == 3) return COLOR_TEAM4;
  32         return 0;
  33 }
  34
  35 entity kh_keylist;
  36 entity kh_controller;
  37 float kh_tracking_enabled;
  38 float kh_teams;
  39 float kh_interferemsg_time, kh_interferemsg_team;
  40 .entity kh_next, kh_prev; // linked list
  41 .float kh_droptime;
  42 .float kh_dropperteam;
  43 .entity kh_previous_owner;
  44
  45 string kh_sound_capture = "sound/kh/capture.wav";
  46 string kh_sound_destroy = "sound/kh/destroy.wav";
  47 string kh_sound_drop = "sound/kh/drop.wav";
  48 string kh_sound_collect = "sound/kh/collect.wav";
  49
  50 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  51 float kh_key_dropped, kh_key_carried;
  52
  53 float kh_GetCarrierSprite(float t, float e)
  54 {
  55         if(t == e)           return kh_sprite_friend;
  56         if(t == COLOR_TEAM1) return kh_sprite_red;
  57         if(t == COLOR_TEAM2) return kh_sprite_blue;
  58         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  59         if(t == COLOR_TEAM4) return kh_sprite_pink;
  60         return 0;
  61 }
  62
  63 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  64 {
  65         kh_Controller_Thinkfunc = func;
  66         kh_controller.cnt = t;
  67         if(kh_Controller_Waitmsg != "")
  68                 strunzone(kh_Controller_Waitmsg);
  69         if(msg == "")
  70                 kh_Controller_Waitmsg = "";
  71         else
  72                 kh_Controller_Waitmsg = strzone(msg);
  73         if(t == 0)
  74                 kh_controller.nextthink = time; // force
  75 }
  76
  77 void kh_Controller_Think()
  78 {
  79         entity e;
  80         if(intermission_running)
  81                 return;
  82         if(self.cnt > 0)
  83         {
  84                 if(kh_Controller_Waitmsg != "")
  85                 {
  86                         string s;
  87                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  88                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  89                         else
  90                                 s = kh_Controller_Waitmsg;
  91
  92                         //dprint(s, "\n");
  93
  94                         FOR_EACH_PLAYER(e)
  95                                 if(clienttype(e) == CLIENTTYPE_REAL)
  96                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  97                 }
  98                 self.cnt -= 1;
  99         }
 100         else if(self.cnt == 0)
 101         {
 102                 self.cnt -= 1;
 103                 kh_Controller_Thinkfunc();
 104         }
 105         self.nextthink = time + 1;
 106 }
 107
 108 // frags f: take from cvar * f
 109 // frags 0: no frags
 110 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 111 {
 112         string s;
 113         if(intermission_running)
 114                 return;
 115         if(frags_player)
 116                 UpdateFrags(player, frags_player);
 117         if(key && key.owner && frags_owner)
 118                 UpdateFrags(key.owner, frags_owner);
 119         if(!cvar("sv_eventlog"))
 120                 return;
 121         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 122         s = strcat(s, ":", ftos(frags_player));
 123         if(key && key.owner)
 124                 s = strcat(s, ":", ftos(key.owner.playerid));
 125         else
 126                 s = strcat(s, ":0");
 127         s = strcat(s, ":", ftos(frags_owner), ":");
 128         if(key)
 129                 s = strcat(s, key.netname);
 130         GameLogEcho(s, FALSE);
 131 }
 132
 133 vector kh_AttachedOrigin(entity e)
 134 {
 135         if(e.tag_entity)
 136         {
 137                 makevectors(e.tag_entity.angles);
 138                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 139         }
 140         else
 141                 return e.origin;
 142 }
 143
 144 void kh_Key_Attach(entity key)
 145 {
 146 #ifdef KH_PLAYER_USE_ATTACHMENT
 147         entity first;
 148         first = key.owner.kh_next;
 149         if(key == first)
 150         {
 151                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 152                 if(key.kh_next)
 153                 {
 154                         setattachment(key.kh_next, key, "");
 155                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 156                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 157                         key.kh_next.angles = '0 0 0';
 158                 }
 159                 else
 160                         setorigin(key, KH_PLAYER_ATTACHMENT);
 161                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 162         }
 163         else
 164         {
 165                 setattachment(key, key.kh_prev, "");
 166                 if(key.kh_next)
 167                         setattachment(key.kh_next, key, "");
 168                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 169                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 170                 key.angles = '0 0 0';
 171         }
 172 #else
 173         setattachment(key, key.owner, "");
 174         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT); // fixing x, y in think
 175         key.angles_y -= key.owner.angles_y;
 176 #endif
 177         key.flags = 0;
 178         key.solid = SOLID_NOT;
 179         key.movetype = MOVETYPE_NONE;
 180         key.team = key.owner.team;
 181         key.nextthink = time;
 182         key.damageforcescale = 0;
 183         key.modelindex = kh_key_carried;
 184 }
 185
 186 void kh_Key_Detach(entity key)
 187 {
 188 #ifdef KH_PLAYER_USE_ATTACHMENT
 189         entity first;
 190         first = key.owner.kh_next;
 191         if(key == first)
 192         {
 193                 if(key.kh_next)
 194                 {
 195                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 196                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 197                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 198                 }
 199         }
 200         else
 201         {
 202                 if(key.kh_next)
 203                         setattachment(key.kh_next, key.kh_prev, "");
 204                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 205         }
 206         // in any case:
 207         setattachment(key, world, "");
 208         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 209         key.angles = key.owner.angles;
 210 #else
 211         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 212         setattachment(key, world, "");
 213         key.angles_y += key.owner.angles_y;
 214 #endif
 215         key.aiment = world;
 216         key.flags = FL_ITEM;
 217         key.solid = SOLID_TRIGGER;
 218         key.movetype = MOVETYPE_TOSS;
 219         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 220         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 221         // let key.team stay
 222         key.modelindex = kh_key_dropped;
 223         key.kh_previous_owner = key.owner;
 224 }
 225
 226 void kh_Key_AssignTo(entity key, entity player)
 227 {
 228         if(key.owner == player)
 229                 return;
 230
 231         if(key.owner)
 232         {
 233                 kh_Key_Detach(key);
 234
 235                 // remove from linked list
 236                 if(key.kh_next)
 237                         key.kh_next.kh_prev = key.kh_prev;
 238                 key.kh_prev.kh_next = key.kh_next;
 239                 key.kh_next = world;
 240                 key.kh_prev = world;
 241
 242                 if(key.owner.kh_next == world)
 243                 {
 244                         // No longer a key carrier
 245                         WaypointSprite_DetachCarrier(key.owner);
 246                 }
 247         }
 248
 249         key.owner = player;
 250
 251         if(player)
 252         {
 253                 // insert into linked list
 254                 key.kh_next = player.kh_next;
 255                 key.kh_prev = player;
 256                 player.kh_next = key;
 257                 if(key.kh_next)
 258                         key.kh_next.kh_prev = key;
 259
 260                 kh_Key_Attach(key);
 261
 262                 if(key.kh_next == world)
 263                 {
 264                         // player is now a key carrier
 265                         WaypointSprite_AttachCarrier("", player);
 266                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 267                         player.waypointsprite_attachedforcarrier.team = player.team;
 268                 }
 269         }
 270
 271         key.pusher = world;
 272 }
 273
 274 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 275 {
 276         if(self.owner)
 277                 return;
 278         if(vlen(force) <= 0)
 279                 return;
 280         if(time > self.pushltime)
 281                 if(attacker.classname == "player")
 282                         self.team = attacker.team;
 283 }
 284
 285 void kh_Key_Spawn(entity initial_owner, float angle)
 286 {
 287         entity key;
 288         key = spawn();
 289         key.classname = STR_ITEM_KH_KEY;
 290         key.touch = kh_Key_Touch;
 291         key.think = kh_Key_Think;
 292         key.nextthink = time;
 293         key.items = IT_KEY1 | IT_KEY2;
 294         key.cnt = angle;
 295         key.angles = '0 360 0' * random();
 296         key.event_damage = kh_Key_Damage;
 297         key.takedamage = DAMAGE_YES;
 298         key.modelindex = kh_key_dropped;
 299         key.model = "key";
 300         key.kh_dropperteam = 0;
 301         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 302         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 303         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 304
 305         switch(initial_owner.team)
 306         {
 307                 case COLOR_TEAM1:
 308                         key.netname = "^1red key";
 309                         break;
 310                 case COLOR_TEAM2:
 311                         key.netname = "^4blue key";
 312                         break;
 313                 case COLOR_TEAM3:
 314                         key.netname = "^3yellow key";
 315                         break;
 316                 case COLOR_TEAM4:
 317                         key.netname = "^6pink key";
 318                         break;
 319                 default:
 320                         key.netname = "NETGIER key";
 321                         break;
 322         }
 323
 324         // link into key list
 325         key.enemy = kh_keylist;
 326         kh_keylist = key;
 327
 328         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 329
 330         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 331         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 332
 333         kh_Key_AssignTo(key, initial_owner);
 334 }
 335
 336 void kh_Key_Remove(entity key)
 337 {
 338         entity o;
 339         o = key.owner;
 340         kh_Key_AssignTo(key, world);
 341         if(o) // it was attached
 342                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 343         else // it was dropped
 344                 WaypointSprite_DetachCarrier(key);
 345
 346         // remove key from key list
 347         if (kh_keylist == key)
 348                 kh_keylist = kh_keylist.enemy;
 349         else
 350         {
 351                 o = kh_keylist;
 352                 while (o)
 353                 {
 354                         if (o.enemy == key)
 355                         {
 356                                 o.enemy = o.enemy.enemy;
 357                                 break;
 358                         }
 359                         o = o.enemy;
 360                 }
 361         }
 362
 363         remove(key);
 364 }
 365
 366 // -1 when no team completely owns all keys yet
 367 float kh_Key_AllOwnedByWhichTeam()
 368 {
 369         entity key;
 370         float teem;
 371
 372         teem = -1;
 373         FOR_EACH_KH_KEY(key)
 374         {
 375                 if(!key.owner)
 376                         return -1;
 377                 if(teem == -1)
 378                         teem = key.team;
 379                 else if(teem != key.team)
 380                         return -1;
 381         }
 382         return teem;
 383 }
 384
 385 void kh_Key_Collect(entity key, entity player)
 386 {
 387         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 388
 389         if(key.kh_dropperteam != player.team)
 390                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 391         key.kh_dropperteam = 0;
 392         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 393         kh_Key_AssignTo(key, player);
 394
 395         if(kh_Key_AllOwnedByWhichTeam() != -1)
 396         {
 397                 kh_interferemsg_time = time + 0.2;
 398                 kh_interferemsg_team = player.team;
 399         }
 400 }
 401
 402 void kh_Key_DropAll(entity player, float suicide)
 403 {
 404         entity key;
 405         entity mypusher;
 406         if(player.kh_next)
 407         {
 408                 mypusher = world;
 409                 if(player.pusher)
 410                         if(time < player.pushltime)
 411                                 mypusher = player.pusher;
 412                 while((key = player.kh_next))
 413                 {
 414                         kh_Scores_Event(player, key, "losekey", 0, 0);
 415                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 416                         kh_Key_AssignTo(key, world);
 417                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 418                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 419                         key.pusher = mypusher;
 420                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 421                         if(suicide)
 422                                 key.kh_dropperteam = player.team;
 423                 }
 424                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 425         }
 426 }
 427
 428 void kh_Key_Touch()
 429 {
 430         if(intermission_running)
 431                 return;
 432
 433         if(self.owner) // already carried
 434                 return;
 435         if(other.classname != "player")
 436                 return;
 437         if(other.deadflag != DEAD_NO)
 438                 return;
 439         if(other == self.enemy)
 440                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 441                         return; // you just dropped it!
 442         kh_Key_Collect(self, other);
 443 }
 444
 445 void kh_Key_Think()
 446 {
 447         entity head;
 448
 449         if(intermission_running)
 450                 return;
 451
 452 #ifdef KH_KEY_ATTACHMENT_DEBUG
 453         if(self.kh_prev == self.owner)
 454         {
 455                 if(cvar_string("_angles") != "")
 456                 {
 457                         self.angles = stov(cvar_string("_angles"));
 458                         self.origin = stov(cvar_string("_origin"));
 459                 }
 460         }
 461 #endif
 462
 463         if(self.owner)
 464         {
 465 #ifndef KH_PLAYER_USE_ATTACHMENT
 466                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 467                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 468 #endif
 469
 470                 if(self.owner.buttonuse)
 471                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 472                 {
 473                         self.owner.kh_droptime = time;
 474                         self.kh_droptime = time; // prevent collecting this one for some time
 475                         self.enemy = self.owner;
 476                         self.pusher = world;
 477                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 478                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 479                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 480                         makevectors(self.owner.v_angle);
 481                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 482                         kh_Key_AssignTo(self, world);
 483                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 484                         self.kh_dropperteam = self.team;
 485                 }
 486         }
 487
 488         // if in nodrop or time over, end the round
 489         if(!self.owner)
 490                 if(time > self.pain_finished)
 491                         kh_LoserTeam(self.team, self);
 492
 493         if(self.owner)
 494         if(kh_Key_AllOwnedByWhichTeam() != -1)
 495         {
 496                 entity key;
 497                 vector p;
 498                 p = self.owner.origin;
 499                 FOR_EACH_KH_KEY(key)
 500                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 501                                 goto not_winning;
 502                 kh_WinnerTeam(self.team);
 503 :not_winning
 504         }
 505
 506         if(kh_interferemsg_time && time > kh_interferemsg_time)
 507         {
 508                 kh_interferemsg_time = 0;
 509                 FOR_EACH_PLAYER(head)
 510                 {
 511                         if(head.team == kh_interferemsg_team)
 512                                 if(head.kh_next)
 513                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 514                                 else
 515                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 516                         else
 517                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 518                 }
 519         }
 520
 521         self.nextthink = time + 0.05;
 522 }
 523
 524 void kh_WinnerTeam(float teem)
 525 {
 526         // all key carriers get some points
 527         vector firstorigin, lastorigin, midpoint;
 528         float first;
 529         entity key;
 530         float score;
 531         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 532         DistributeEvenly_Init(score, kh_teams);
 533         // twice the score for 3 team games, three times the score for 4 team games!
 534         // note: for a win by destroying the key, this should NOT be applied
 535         FOR_EACH_KH_KEY(key)
 536                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 537
 538         first = TRUE;
 539         FOR_EACH_KH_KEY(key)
 540                 if(key.owner.kh_next == key)
 541                 {
 542                         if(!first)
 543                                 bprint("^7, ");
 544                         bprint(key.owner.netname);
 545                         first = FALSE;
 546                 }
 547         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 548
 549         first = TRUE;
 550         midpoint = '0 0 0';
 551         FOR_EACH_KH_KEY(key)
 552         {
 553                 vector thisorigin;
 554
 555                 thisorigin = kh_AttachedOrigin(key);
 556                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 557                 midpoint += thisorigin;
 558
 559                 if(!first)
 560                         te_lightning2(world, lastorigin, thisorigin);
 561                 lastorigin = thisorigin;
 562                 if(first)
 563                         firstorigin = thisorigin;
 564                 first = FALSE;
 565         }
 566         if(kh_teams > 2)
 567         {
 568                 te_lightning2(world, lastorigin, firstorigin);
 569         }
 570         midpoint = midpoint * (1 / kh_teams);
 571         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5'); // make the color >=0.5 in each component
 572
 573         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 574         kh_FinishRound();
 575 }
 576
 577 void kh_LoserTeam(float teem, entity lostkey)
 578 {
 579         entity player, key, attacker;
 580         float players;
 581         float keys;
 582
 583         attacker = world;
 584         if(lostkey.pusher)
 585                 if(lostkey.pusher.team != teem)
 586                         if(lostkey.pusher.classname == "player")
 587                                 attacker = lostkey.pusher;
 588
 589         players = keys = 0;
 590
 591         if(attacker)
 592         {
 593                 if(lostkey.kh_previous_owner)
 594                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 595                         // don't actually GIVE him the -nn points, just log
 596                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 597                 centerprint(attacker, "Your push is the best!\n\n\n");
 598                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 599         }
 600         else
 601         {
 602                 float of, fragsleft, i, j, thisteam;
 603                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 604
 605                 FOR_EACH_PLAYER(player)
 606                         if(player.team != teem)
 607                                 ++players;
 608
 609                 FOR_EACH_KH_KEY(key)
 610                         if(key.owner && key.team != teem)
 611                                 ++keys;
 612
 613                 if(lostkey.kh_previous_owner)
 614                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 615                         // don't actually GIVE him the -nn points, just log
 616
 617                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 618
 619                 FOR_EACH_KH_KEY(key)
 620                         if(key.owner && key.team != teem)
 621                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 622
 623                 fragsleft = DistributeEvenly_Get(players);
 624
 625                 // Now distribute these among all other teams...
 626                 j = kh_teams - 1;
 627                 for(i = 0; i < kh_teams; ++i)
 628                 {
 629                         thisteam = kh_Team_ByID(i);
 630                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 631                                 continue;
 632
 633                         players = 0;
 634                         FOR_EACH_PLAYER(player)
 635                                 if(player.team == thisteam)
 636                                         ++players;
 637
 638                         DistributeEvenly_Init(fragsleft, j);
 639                         fragsleft = DistributeEvenly_Get(j - 1);
 640                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 641
 642                         FOR_EACH_PLAYER(player)
 643                                 if(player.team == thisteam)
 644                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 645
 646                         --j;
 647                 }
 648
 649                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 650         }
 651         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 652         te_tarexplosion(lostkey.origin);
 653
 654         kh_FinishRound();
 655 }
 656
 657 void kh_FinishRound()
 658 {
 659         // prepare next round
 660         kh_interferemsg_time = 0;
 661         entity key;
 662         FOR_EACH_KH_KEY(key)
 663                 kh_Key_Remove(key);
 664
 665         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 666 }
 667
 668 string kh_CheckEnoughPlayers()
 669 {
 670         float i, players, teem;
 671         entity player;
 672         string result;
 673         result = "";
 674
 675         // find a random player per team
 676         for(i = 0; i < kh_teams; ++i)
 677         {
 678                 teem = kh_Team_ByID(i);
 679                 players = 0;
 680                 FOR_EACH_PLAYER(player)
 681                         if(player.deadflag == DEAD_NO)
 682                                 if(!player.buttonchat)
 683                                         if(player.team == teem)
 684                                                 ++players;
 685                 if(players == 0)
 686                 {
 687                         if(result != "")
 688                                 result = strcat(result, ", ");
 689                         result = strcat(result, ColoredTeamName(teem));
 690                 }
 691         }
 692         return result;
 693 }
 694
 695 void kh_WaitForPlayers()
 696 {
 697         string teams_missing;
 698         teams_missing = kh_CheckEnoughPlayers();
 699         if(teams_missing == "")
 700                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 701         else
 702                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 703 }
 704
 705 void kh_StartRound()
 706 {
 707         string teams_missing;
 708         float i, players, teem;
 709         entity player;
 710
 711         teams_missing = kh_CheckEnoughPlayers();
 712         if(teams_missing != "")
 713         {
 714                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 715                 return;
 716         }
 717
 718         FOR_EACH_PLAYER(player)
 719                 if(clienttype(player) == CLIENTTYPE_REAL)
 720                         centerprint_expire(player, CENTERPRIO_SPAM);
 721
 722         for(i = 0; i < kh_teams; ++i)
 723         {
 724                 teem = kh_Team_ByID(i);
 725                 players = 0;
 726                 entity my_player;
 727                 FOR_EACH_PLAYER(player)
 728                         if(player.deadflag == DEAD_NO)
 729                                 if(!player.buttonchat)
 730                                         if(player.team == teem)
 731                                         {
 732                                                 ++players;
 733                                                 if(random() * players <= 1)
 734                                                         my_player = player;
 735                                         }
 736                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 737                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 738                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 739         }
 740
 741         kh_tracking_enabled = FALSE;
 742         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 743 }
 744
 745 void kh_setstatus()
 746 {
 747         if(kh_teams)
 748         {
 749                 float kh_KEY;
 750                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 751                 if(self.kh_next)
 752                         self.items = self.items | kh_KEY;
 753                 else
 754                         self.items = self.items - (self.items & kh_KEY);
 755         }
 756 }
 757
 758 void kh_EnableTrackingDevice()
 759 {
 760         entity player;
 761
 762         FOR_EACH_PLAYER(player)
 763                 if(clienttype(player) == CLIENTTYPE_REAL)
 764                         centerprint_expire(player, CENTERPRIO_SPAM);
 765
 766         kh_tracking_enabled = TRUE;
 767 }
 768
 769 float kh_Key_waypointsprite_for_player(entity e)
 770 {
 771         if(!kh_tracking_enabled)
 772                 return 0;
 773         if(!self.owner)
 774                 return kh_sprite_dropped;
 775         if(!self.owner.owner)
 776                 return kh_sprite_dropped;
 777         return 0; // draw only when key is not owned
 778 }
 779
 780 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 781 {
 782         if(e.classname != "player" || self.team != e.team)
 783                 if(!kh_tracking_enabled)
 784                         return 0;
 785
 786         // e is spectator? That's no team mate...
 787         if(e.classname != "player")
 788                 return kh_GetCarrierSprite(self.team, -1);
 789
 790         // e is no key carrier: simple case...
 791         if(!e.kh_next)
 792                 return kh_GetCarrierSprite(self.team, e.team);
 793
 794         // e is a key carrier: if any key is dropped or owned by another team, show
 795         // the carrier sprite; otherwise show run here
 796         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 797                 return kh_sprite_finish;
 798
 799         return kh_GetCarrierSprite(self.team, e.team);
 800 }
 801
 802 float kh_HandleFrags(entity attacker, entity targ, float f)
 803 {
 804         if(attacker == targ)
 805                 return f;
 806
 807         if(targ.kh_next)
 808         {
 809                 if(attacker.team == targ.team)
 810                 {
 811                         entity k;
 812                         float nk;
 813                         nk = 0;
 814                         for(k = targ.kh_next; k != world; k = k.kh_next)
 815                                 ++nk;
 816                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 817                 }
 818                 else
 819                 {
 820                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 821                 }
 822         }
 823
 824         return f;
 825 }
 826
 827 void kh_init()
 828 {
 829         precache_sound(kh_sound_capture);
 830         precache_sound(kh_sound_destroy);
 831         precache_sound(kh_sound_drop);
 832         precache_sound(kh_sound_collect);
 833
 834         precache_model("models/sprites/key-dropped.sp2");
 835         precache_model("models/sprites/keycarrier-finish.sp2");
 836         precache_model("models/sprites/keycarrier-friend.sp2");
 837         precache_model("models/sprites/keycarrier-red.sp2");
 838         precache_model("models/sprites/keycarrier-blue.sp2");
 839         precache_model("models/sprites/keycarrier-yellow.sp2");
 840         precache_model("models/sprites/keycarrier-pink.sp2");
 841 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 842         precache_model("models/keyhunt/key-carried.md3");
 843 #endif
 844         precache_model("models/keyhunt/key.md3");
 845
 846         // setup variables
 847         kh_teams = cvar("g_keyhunt_teams_override");
 848         if(kh_teams < 2)
 849                 kh_teams = cvar("g_keyhunt_teams");
 850         kh_teams = bound(2, kh_teams, 4);
 851
 852         // make a KH entity for controlling the game
 853         kh_controller = spawn();
 854         kh_controller.think = kh_Controller_Think;
 855         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 856
 857         setmodel(kh_controller, "models/keyhunt/key.md3");
 858         kh_key_dropped = kh_controller.modelindex;
 859         /*
 860         dprint(vtos(kh_controller.mins));
 861         dprint(vtos(kh_controller.maxs));
 862         dprint("\n");
 863         */
 864 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 865         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 866         kh_key_carried = kh_controller.modelindex;
 867 #else
 868         kh_key_carried = kh_key_dropped;
 869 #endif
 870         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 871         kh_sprite_dropped = kh_controller.modelindex;
 872         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 873         kh_sprite_finish = kh_controller.modelindex;
 874         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 875         kh_sprite_friend = kh_controller.modelindex;
 876         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 877         kh_sprite_red = kh_controller.modelindex;
 878         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 879         kh_sprite_blue = kh_controller.modelindex;
 880         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 881         kh_sprite_pink = kh_controller.modelindex;
 882         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 883         kh_sprite_yellow = kh_controller.modelindex;
 884         setmodel(kh_controller, "");
 885 }
 886
 887 void kh_finalize()
 888 {
 889         // to be called before intermission
 890         kh_FinishRound();
 891         remove(kh_controller);
 892         kh_controller = world;
 893 }