data/qcsrc/server/keyhunt.qc

   1 string STR_ITEM_KH_KEY = "item_kh_key";
   2 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   3
   4 // #define KH_PLAYER_USE_ATTACHMENT
   5 // #define KH_PLAYER_USE_CARRIEDMODEL
   6 // #define KH_KEY_ATTACHMENT_DEBUG
   7
   8 #ifdef KH_PLAYER_USE_ATTACHMENT
   9 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  10 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  11 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  12 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  13 string KH_PLAYER_ATTACHMENT_BONE = "";
  14 #else
  15 float KH_KEY_ZSHIFT = 22;
  16 float KH_KEY_XYDIST = 24;
  17 float KH_KEY_XYSPEED = 45;
  18 #endif
  19 float KH_KEY_WP_ZSHIFT = 20;
  20
  21 vector KH_KEY_MIN = '-10 -10 -46';
  22 vector KH_KEY_MAX = '10 10 3';
  23 float KH_KEY_BRIGHTNESS = 2;
  24
  25 typedef void(void) kh_Think_t;
  26 var kh_Think_t kh_Controller_Thinkfunc;
  27 string kh_Controller_Waitmsg;
  28
  29 float kh_Team_ByID(float t)
  30 {
  31         if(t == 0) return COLOR_TEAM1;
  32         if(t == 1) return COLOR_TEAM2;
  33         if(t == 2) return COLOR_TEAM3;
  34         if(t == 3) return COLOR_TEAM4;
  35         return 0;
  36 }
  37
  38 entity kh_controller;
  39 float kh_tracking_enabled;
  40 float kh_teams;
  41 float kh_interferemsg_time, kh_interferemsg_team;
  42 .entity kh_next, kh_prev; // linked list
  43 .float kh_droptime;
  44 .float kh_dropperteam;
  45 .entity kh_previous_owner;
  46
  47 string kh_sound_capture = "sound/kh/capture.wav";
  48 string kh_sound_destroy = "sound/kh/destroy.wav";
  49 string kh_sound_drop = "sound/kh/drop.wav";
  50 string kh_sound_collect = "sound/kh/collect.wav";
  51
  52 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  53 float kh_key_dropped, kh_key_carried;
  54
  55 float kh_GetCarrierSprite(float t, float e)
  56 {
  57         if(t == e)           return kh_sprite_friend;
  58         if(t == COLOR_TEAM1) return kh_sprite_red;
  59         if(t == COLOR_TEAM2) return kh_sprite_blue;
  60         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  61         if(t == COLOR_TEAM4) return kh_sprite_pink;
  62         return 0;
  63 }
  64
  65 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  66 {
  67         kh_Controller_Thinkfunc = func;
  68         kh_controller.cnt = t;
  69         if(kh_Controller_Waitmsg != "")
  70                 strunzone(kh_Controller_Waitmsg);
  71         if(msg == "")
  72                 kh_Controller_Waitmsg = "";
  73         else
  74                 kh_Controller_Waitmsg = strzone(msg);
  75         if(t == 0)
  76                 kh_controller.nextthink = time; // force
  77 }
  78
  79 void kh_Controller_Think()
  80 {
  81         entity e;
  82         if(intermission_running)
  83                 return;
  84         if(self.cnt > 0)
  85         {
  86                 if(kh_Controller_Waitmsg != "")
  87                 {
  88                         string s;
  89                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  90                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  91                         else
  92                                 s = kh_Controller_Waitmsg;
  93
  94                         //dprint(s, "\n");
  95
  96                         FOR_EACH_PLAYER(e)
  97                                 if(clienttype(e) == CLIENTTYPE_REAL)
  98                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  99                 }
 100                 self.cnt -= 1;
 101         }
 102         else if(self.cnt == 0)
 103         {
 104                 self.cnt -= 1;
 105                 kh_Controller_Thinkfunc();
 106         }
 107         self.nextthink = time + 1;
 108 }
 109
 110 // frags f: take from cvar * f
 111 // frags 0: no frags
 112 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 113 {
 114         string s;
 115         if(intermission_running)
 116                 return;
 117         if(frags_player)
 118                 UpdateFrags(player, frags_player);
 119         if(key && key.owner && frags_owner)
 120                 UpdateFrags(key.owner, frags_owner);
 121         if(!cvar("sv_eventlog"))
 122                 return;
 123         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 124         s = strcat(s, ":", ftos(frags_player));
 125         if(key && key.owner)
 126                 s = strcat(s, ":", ftos(key.owner.playerid));
 127         else
 128                 s = strcat(s, ":0");
 129         s = strcat(s, ":", ftos(frags_owner), ":");
 130         if(key)
 131                 s = strcat(s, key.netname);
 132         GameLogEcho(s, FALSE);
 133 }
 134
 135 vector kh_AttachedOrigin(entity e)
 136 {
 137         if(e.tag_entity)
 138         {
 139                 makevectors(e.tag_entity.angles);
 140                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 141         }
 142         else
 143                 return e.origin;
 144 }
 145
 146 void kh_Key_Attach(entity key)
 147 {
 148 #ifdef KH_PLAYER_USE_ATTACHMENT
 149         entity first;
 150         first = key.owner.kh_next;
 151         if(key == first)
 152         {
 153                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 154                 if(key.kh_next)
 155                 {
 156                         setattachment(key.kh_next, key, "");
 157                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 158                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 159                         key.kh_next.angles = '0 0 0';
 160                 }
 161                 else
 162                         setorigin(key, KH_PLAYER_ATTACHMENT);
 163                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 164         }
 165         else
 166         {
 167                 setattachment(key, key.kh_prev, "");
 168                 if(key.kh_next)
 169                         setattachment(key.kh_next, key, "");
 170                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 171                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 172                 key.angles = '0 0 0';
 173         }
 174 #else
 175         setattachment(key, key.owner, "");
 176         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT); // fixing x, y in think
 177         key.angles_y -= key.owner.angles_y;
 178 #endif
 179         key.flags = 0;
 180         key.solid = SOLID_NOT;
 181         key.movetype = MOVETYPE_NONE;
 182         key.team = key.owner.team;
 183         key.nextthink = time;
 184         key.damageforcescale = 0;
 185         key.modelindex = kh_key_carried;
 186 }
 187
 188 void kh_Key_Detach(entity key)
 189 {
 190 #ifdef KH_PLAYER_USE_ATTACHMENT
 191         entity first;
 192         first = key.owner.kh_next;
 193         if(key == first)
 194         {
 195                 if(key.kh_next)
 196                 {
 197                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 198                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 199                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 200                 }
 201         }
 202         else
 203         {
 204                 if(key.kh_next)
 205                         setattachment(key.kh_next, key.kh_prev, "");
 206                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 207         }
 208         // in any case:
 209         setattachment(key, world, "");
 210         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 211         key.angles = key.owner.angles;
 212 #else
 213         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 214         setattachment(key, world, "");
 215         key.angles_y += key.owner.angles_y;
 216 #endif
 217         key.aiment = world;
 218         key.flags = FL_ITEM;
 219         key.solid = SOLID_TRIGGER;
 220         key.movetype = MOVETYPE_TOSS;
 221         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 222         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 223         // let key.team stay
 224         key.modelindex = kh_key_dropped;
 225         key.kh_previous_owner = key.owner;
 226 }
 227
 228 void kh_Key_AssignTo(entity key, entity player)
 229 {
 230         if(key.owner == player)
 231                 return;
 232
 233         if(key.owner)
 234         {
 235                 kh_Key_Detach(key);
 236
 237                 // remove from linked list
 238                 if(key.kh_next)
 239                         key.kh_next.kh_prev = key.kh_prev;
 240                 key.kh_prev.kh_next = key.kh_next;
 241                 key.kh_next = world;
 242                 key.kh_prev = world;
 243
 244                 if(key.owner.kh_next == world)
 245                 {
 246                         // No longer a key carrier
 247                         WaypointSprite_DetachCarrier(key.owner);
 248                 }
 249         }
 250
 251         key.owner = player;
 252
 253         if(player)
 254         {
 255                 // insert into linked list
 256                 key.kh_next = player.kh_next;
 257                 key.kh_prev = player;
 258                 player.kh_next = key;
 259                 if(key.kh_next)
 260                         key.kh_next.kh_prev = key;
 261
 262                 kh_Key_Attach(key);
 263
 264                 if(key.kh_next == world)
 265                 {
 266                         // player is now a key carrier
 267                         WaypointSprite_AttachCarrier("", player);
 268                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 269                         player.waypointsprite_attachedforcarrier.team = player.team;
 270                 }
 271         }
 272
 273         key.pusher = world;
 274 }
 275
 276 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 277 {
 278         if(self.owner)
 279                 return;
 280         if(vlen(force) <= 0)
 281                 return;
 282         if(time > self.pushltime)
 283                 if(attacker.classname == "player")
 284                         self.team = attacker.team;
 285 }
 286
 287 vector kh_TeamColor(float teem)
 288 {
 289         switch(teem)
 290         {
 291                 case COLOR_TEAM1:
 292                         return '1 0.0625 0.0625';
 293                 case COLOR_TEAM2:
 294                         return '0.0625 0.0625 1';
 295                 case COLOR_TEAM3:
 296                         return '1 1 0.0625';
 297                 case COLOR_TEAM4:
 298                         return '1 0.0625 1';
 299                 default:
 300                         return '1 1 1';
 301         }
 302 }
 303
 304 void kh_Key_Spawn(entity initial_owner, float angle)
 305 {
 306         entity key;
 307         key = spawn();
 308         key.classname = STR_ITEM_KH_KEY;
 309         key.touch = kh_Key_Touch;
 310         key.think = kh_Key_Think;
 311         key.nextthink = time;
 312         key.items = IT_KEY1 | IT_KEY2;
 313         key.cnt = angle;
 314         key.angles = '0 360 0' * random();
 315         key.event_damage = kh_Key_Damage;
 316         key.takedamage = DAMAGE_YES;
 317         key.modelindex = kh_key_dropped;
 318         key.model = "key";
 319         key.kh_dropperteam = 0;
 320         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 321         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 322         key.colormod = kh_TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 323
 324         switch(initial_owner.team)
 325         {
 326                 case COLOR_TEAM1:
 327                         key.netname = "^1red key";
 328                         break;
 329                 case COLOR_TEAM2:
 330                         key.netname = "^4blue key";
 331                         break;
 332                 case COLOR_TEAM3:
 333                         key.netname = "^3yellow key";
 334                         break;
 335                 case COLOR_TEAM4:
 336                         key.netname = "^6pink key";
 337                         break;
 338                 default:
 339                         key.netname = "NETGIER key";
 340                         break;
 341         }
 342
 343         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 344
 345         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 346         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 347
 348         kh_Key_AssignTo(key, initial_owner);
 349 }
 350
 351 void kh_Key_Remove(entity key)
 352 {
 353         entity o;
 354         o = key.owner;
 355         kh_Key_AssignTo(key, world);
 356         if(o) // it was attached
 357                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 358         else // it was dropped
 359                 WaypointSprite_DetachCarrier(key);
 360
 361         remove(key);
 362 }
 363
 364 // -1 when no team completely owns all keys yet
 365 float kh_Key_AllOwnedByWhichTeam()
 366 {
 367         entity key;
 368         float teem;
 369
 370         teem = -1;
 371         FOR_EACH_KH_KEY(key)
 372         {
 373                 if(!key.owner)
 374                         return -1;
 375                 if(teem == -1)
 376                         teem = key.team;
 377                 else if(teem != key.team)
 378                         return -1;
 379         }
 380         return teem;
 381 }
 382
 383 void kh_Key_Collect(entity key, entity player)
 384 {
 385         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 386
 387         if(key.kh_dropperteam != player.team)
 388                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 389         key.kh_dropperteam = 0;
 390         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 391         kh_Key_AssignTo(key, player);
 392
 393         if(kh_Key_AllOwnedByWhichTeam() != -1)
 394         {
 395                 kh_interferemsg_time = time + 0.2;
 396                 kh_interferemsg_team = player.team;
 397         }
 398 }
 399
 400 void kh_Key_DropAll(entity player, float suicide)
 401 {
 402         entity key;
 403         entity mypusher;
 404         if(player.kh_next)
 405         {
 406                 mypusher = world;
 407                 if(player.pusher)
 408                         if(time < player.pushltime)
 409                                 mypusher = player.pusher;
 410                 while((key = player.kh_next))
 411                 {
 412                         kh_Scores_Event(player, key, "losekey", 0, 0);
 413                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 414                         kh_Key_AssignTo(key, world);
 415                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 416                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 417                         key.pusher = mypusher;
 418                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 419                         if(suicide)
 420                                 key.kh_dropperteam = player.team;
 421                 }
 422                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 423         }
 424 }
 425
 426 void kh_Key_Touch()
 427 {
 428         if(intermission_running)
 429                 return;
 430
 431         if(self.owner) // already carried
 432                 return;
 433         if(other.classname != "player")
 434                 return;
 435         if(other.deadflag != DEAD_NO)
 436                 return;
 437         if(other == self.enemy)
 438                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 439                         return; // you just dropped it!
 440         kh_Key_Collect(self, other);
 441 }
 442
 443 void kh_Key_Think()
 444 {
 445         entity head;
 446
 447         if(intermission_running)
 448                 return;
 449
 450 #ifdef KH_KEY_ATTACHMENT_DEBUG
 451         if(self.kh_prev == self.owner)
 452         {
 453                 if(cvar_string("_angles") != "")
 454                 {
 455                         self.angles = stov(cvar_string("_angles"));
 456                         self.origin = stov(cvar_string("_origin"));
 457                 }
 458         }
 459 #endif
 460
 461         if(self.owner)
 462         {
 463 #ifndef KH_PLAYER_USE_ATTACHMENT
 464                 makevectors('0 1 0' * (self.cnt + math_mod(time, 360) * KH_KEY_XYSPEED));
 465                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 466 #endif
 467
 468                 if(self.owner.buttonuse)
 469                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 470                 {
 471                         self.owner.kh_droptime = time;
 472                         self.kh_droptime = time; // prevent collecting this one for some time
 473                         self.enemy = self.owner;
 474                         self.pusher = world;
 475                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 476                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 477                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 478                         makevectors(self.owner.v_angle);
 479                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 480                         kh_Key_AssignTo(self, world);
 481                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 482                         self.kh_dropperteam = self.team;
 483                 }
 484         }
 485
 486         // if in nodrop or time over, end the round
 487         if(!self.owner)
 488                 if(time > self.pain_finished)
 489                         kh_LoserTeam(self.team, self);
 490
 491         if(self.owner)
 492         if(kh_Key_AllOwnedByWhichTeam() != -1)
 493         {
 494                 entity key;
 495                 vector p;
 496                 p = self.owner.origin;
 497                 FOR_EACH_KH_KEY(key)
 498                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 499                                 goto not_winning;
 500                 kh_WinnerTeam(self.team);
 501 :not_winning
 502         }
 503
 504         if(kh_interferemsg_time && time > kh_interferemsg_time)
 505         {
 506                 kh_interferemsg_time = 0;
 507                 FOR_EACH_PLAYER(head)
 508                 {
 509                         if(head.team == kh_interferemsg_team)
 510                                 if(head.kh_next)
 511                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 512                                 else
 513                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 514                         else
 515                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 516                 }
 517         }
 518
 519         self.nextthink = time + 0.05;
 520 }
 521
 522 void kh_WinnerTeam(float teem)
 523 {
 524         // all key carriers get some points
 525         vector firstorigin, lastorigin, midpoint;
 526         float first;
 527         entity key;
 528         float score;
 529         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 530         DistributeEvenly_Init(score, kh_teams);
 531         // twice the score for 3 team games, three times the score for 4 team games!
 532         // note: for a win by destroying the key, this should NOT be applied
 533         FOR_EACH_KH_KEY(key)
 534                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 535
 536         first = TRUE;
 537         FOR_EACH_KH_KEY(key)
 538                 if(key.owner.kh_next == key)
 539                 {
 540                         if(!first)
 541                                 bprint("^7, ");
 542                         bprint(key.owner.netname);
 543                         first = FALSE;
 544                 }
 545         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 546
 547         first = TRUE;
 548         midpoint = '0 0 0';
 549         FOR_EACH_KH_KEY(key)
 550         {
 551                 vector thisorigin;
 552
 553                 thisorigin = kh_AttachedOrigin(key);
 554                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 555                 midpoint += thisorigin;
 556
 557                 if(!first)
 558                         te_lightning2(world, lastorigin, thisorigin);
 559                 lastorigin = thisorigin;
 560                 if(first)
 561                         firstorigin = thisorigin;
 562                 first = FALSE;
 563         }
 564         if(kh_teams > 2)
 565         {
 566                 te_lightning2(world, lastorigin, firstorigin);
 567         }
 568         midpoint = midpoint * (1 / kh_teams);
 569         te_customflash(midpoint, 1000, 1, kh_TeamColor(teem) * 0.5 + '0.5 0.5 0.5'); // make the color >=0.5 in each component
 570
 571         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 572         kh_FinishRound();
 573 }
 574
 575 void kh_LoserTeam(float teem, entity lostkey)
 576 {
 577         entity player, key, attacker;
 578         float players;
 579         float keys;
 580
 581         attacker = world;
 582         if(lostkey.pusher)
 583                 if(lostkey.pusher.team != teem)
 584                         if(lostkey.pusher.classname == "player")
 585                                 attacker = lostkey.pusher;
 586
 587         players = keys = 0;
 588
 589         if(attacker)
 590         {
 591                 if(lostkey.kh_previous_owner)
 592                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 593                         // don't actually GIVE him the -nn points, just log
 594                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 595                 centerprint(attacker, "Your push is the best!\n\n\n");
 596                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 597         }
 598         else
 599         {
 600                 float of, fragsleft, i, j, thisteam;
 601                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 602
 603                 FOR_EACH_PLAYER(player)
 604                         if(player.team != teem)
 605                                 ++players;
 606
 607                 FOR_EACH_KH_KEY(key)
 608                         if(key.owner && key.team != teem)
 609                                 ++keys;
 610
 611                 if(lostkey.kh_previous_owner)
 612                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 613                         // don't actually GIVE him the -nn points, just log
 614
 615                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 616
 617                 FOR_EACH_KH_KEY(key)
 618                         if(key.owner && key.team != teem)
 619                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 620
 621                 fragsleft = DistributeEvenly_Get(players);
 622
 623                 // Now distribute these among all other teams...
 624                 j = kh_teams - 1;
 625                 for(i = 0; i < kh_teams; ++i)
 626                 {
 627                         thisteam = kh_Team_ByID(i);
 628                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 629                                 continue;
 630
 631                         players = 0;
 632                         FOR_EACH_PLAYER(player)
 633                                 if(player.team == thisteam)
 634                                         ++players;
 635
 636                         DistributeEvenly_Init(fragsleft, j);
 637                         fragsleft = DistributeEvenly_Get(j - 1);
 638                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 639
 640                         FOR_EACH_PLAYER(player)
 641                                 if(player.team == thisteam)
 642                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 643
 644                         --j;
 645                 }
 646
 647                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 648         }
 649         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 650         te_tarexplosion(lostkey.origin);
 651
 652         kh_FinishRound();
 653 }
 654
 655 void kh_FinishRound()
 656 {
 657         // prepare next round
 658         kh_interferemsg_time = 0;
 659         entity key;
 660         FOR_EACH_KH_KEY(key)
 661                 kh_Key_Remove(key);
 662
 663         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 664 }
 665
 666 string kh_CheckEnoughPlayers()
 667 {
 668         float i, players, teem;
 669         entity player;
 670         string result;
 671         result = "";
 672
 673         // find a random player per team
 674         for(i = 0; i < kh_teams; ++i)
 675         {
 676                 teem = kh_Team_ByID(i);
 677                 players = 0;
 678                 FOR_EACH_PLAYER(player)
 679                         if(player.deadflag == DEAD_NO)
 680                                 if(!player.buttonchat)
 681                                         if(player.team == teem)
 682                                                 ++players;
 683                 if(players == 0)
 684                 {
 685                         if(result != "")
 686                                 result = strcat(result, ", ");
 687                         result = strcat(result, ColoredTeamName(teem));
 688                 }
 689         }
 690         return result;
 691 }
 692
 693 void kh_WaitForPlayers()
 694 {
 695         string teams_missing;
 696         teams_missing = kh_CheckEnoughPlayers();
 697         if(teams_missing == "")
 698                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 699         else
 700                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 701 }
 702
 703 void kh_StartRound()
 704 {
 705         string teams_missing;
 706         float i, players, teem;
 707         entity player;
 708
 709         teams_missing = kh_CheckEnoughPlayers();
 710         if(teams_missing != "")
 711         {
 712                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 713                 return;
 714         }
 715
 716         FOR_EACH_PLAYER(player)
 717                 if(clienttype(player) == CLIENTTYPE_REAL)
 718                         centerprint_expire(player, CENTERPRIO_SPAM);
 719
 720         for(i = 0; i < kh_teams; ++i)
 721         {
 722                 teem = kh_Team_ByID(i);
 723                 players = 0;
 724                 entity my_player;
 725                 FOR_EACH_PLAYER(player)
 726                         if(player.deadflag == DEAD_NO)
 727                                 if(!player.buttonchat)
 728                                         if(player.team == teem)
 729                                         {
 730                                                 ++players;
 731                                                 if(random() * players <= 1)
 732                                                         my_player = player;
 733                                         }
 734                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 735                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 736                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 737         }
 738
 739         kh_tracking_enabled = FALSE;
 740         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 741 }
 742
 743 void kh_setstatus()
 744 {
 745         if(kh_teams)
 746         {
 747                 float kh_KEY;
 748                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 749                 if(self.kh_next)
 750                         self.items = self.items | kh_KEY;
 751                 else
 752                         self.items = self.items - (self.items & kh_KEY);
 753         }
 754 }
 755
 756 void kh_EnableTrackingDevice()
 757 {
 758         entity player;
 759
 760         FOR_EACH_PLAYER(player)
 761                 if(clienttype(player) == CLIENTTYPE_REAL)
 762                         centerprint_expire(player, CENTERPRIO_SPAM);
 763
 764         kh_tracking_enabled = TRUE;
 765 }
 766
 767 float kh_Key_waypointsprite_for_player(entity e)
 768 {
 769         if(!kh_tracking_enabled)
 770                 return 0;
 771         if(!self.owner)
 772                 return kh_sprite_dropped;
 773         if(!self.owner.owner)
 774                 return kh_sprite_dropped;
 775         return 0; // draw only when key is not owned
 776 }
 777
 778 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 779 {
 780         if(e.classname != "player" || self.team != e.team)
 781                 if(!kh_tracking_enabled)
 782                         return 0;
 783
 784         // e is spectator? That's no team mate...
 785         if(e.classname != "player")
 786                 return kh_GetCarrierSprite(self.team, -1);
 787
 788         // e is no key carrier: simple case...
 789         if(!e.kh_next)
 790                 return kh_GetCarrierSprite(self.team, e.team);
 791
 792         // e is a key carrier: if any key is dropped or owned by another team, show
 793         // the carrier sprite; otherwise show run here
 794         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 795                 return kh_sprite_finish;
 796
 797         return kh_GetCarrierSprite(self.team, e.team);
 798 }
 799
 800 float kh_HandleFrags(entity attacker, entity targ, float f)
 801 {
 802         if(attacker == targ)
 803                 return f;
 804
 805         if(targ.kh_next)
 806         {
 807                 if(attacker.team == targ.team)
 808                 {
 809                         entity k;
 810                         float nk;
 811                         nk = 0;
 812                         for(k = targ.kh_next; k != world; k = k.kh_next)
 813                                 ++nk;
 814                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 815                 }
 816                 else
 817                 {
 818                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 819                 }
 820         }
 821
 822         return f;
 823 }
 824
 825 void kh_init()
 826 {
 827         precache_sound(kh_sound_capture);
 828         precache_sound(kh_sound_destroy);
 829         precache_sound(kh_sound_drop);
 830         precache_sound(kh_sound_collect);
 831
 832         precache_model("models/sprites/key-dropped.sp2");
 833         precache_model("models/sprites/keycarrier-finish.sp2");
 834         precache_model("models/sprites/keycarrier-friend.sp2");
 835         precache_model("models/sprites/keycarrier-red.sp2");
 836         precache_model("models/sprites/keycarrier-blue.sp2");
 837         precache_model("models/sprites/keycarrier-yellow.sp2");
 838         precache_model("models/sprites/keycarrier-pink.sp2");
 839 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 840         precache_model("models/keyhunt/key-carried.md3");
 841 #endif
 842         precache_model("models/keyhunt/key.md3");
 843
 844         // setup variables
 845         kh_teams = cvar("g_keyhunt_teams_override");
 846         if(kh_teams < 2)
 847                 kh_teams = cvar("g_keyhunt_teams");
 848         kh_teams = bound(2, kh_teams, 4);
 849
 850         // make a KH entity for controlling the game
 851         kh_controller = spawn();
 852         kh_controller.think = kh_Controller_Think;
 853         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 854
 855         setmodel(kh_controller, "models/keyhunt/key.md3");
 856         kh_key_dropped = kh_controller.modelindex;
 857         /*
 858         dprint(vtos(kh_controller.mins));
 859         dprint(vtos(kh_controller.maxs));
 860         dprint("\n");
 861         */
 862 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 863         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 864         kh_key_carried = kh_controller.modelindex;
 865 #else
 866         kh_key_carried = kh_key_dropped;
 867 #endif
 868         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 869         kh_sprite_dropped = kh_controller.modelindex;
 870         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 871         kh_sprite_finish = kh_controller.modelindex;
 872         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 873         kh_sprite_friend = kh_controller.modelindex;
 874         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 875         kh_sprite_red = kh_controller.modelindex;
 876         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 877         kh_sprite_blue = kh_controller.modelindex;
 878         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 879         kh_sprite_pink = kh_controller.modelindex;
 880         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 881         kh_sprite_yellow = kh_controller.modelindex;
 882         setmodel(kh_controller, "");
 883 }
 884
 885 void kh_finalize()
 886 {
 887         // to be called before intermission
 888         kh_FinishRound();
 889         remove(kh_controller);
 890         kh_controller = world;
 891 }