data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25
  26 // kh_state
  27 //     bits 0-7: player's key status
  28 //     bits 8-15: general key status
  29 .float kh_state;
  30 .float siren_time;  //  time delay the siren
  31 //.float stuff_time;  //  time delay to stuffcmd a cvar
  32
  33 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  34 //test[0] = status of dropped keys, test[1 - 16] = player #
  35 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  36 //for(i = 0; i < maxplayers; ++i)
  37 //      test[i] = "0";
  38
  39 float kh_Team_ByID(float t)
  40 {
  41         if(t == 0) return COLOR_TEAM1;
  42         if(t == 1) return COLOR_TEAM2;
  43         if(t == 2) return COLOR_TEAM3;
  44         if(t == 3) return COLOR_TEAM4;
  45         return 0;
  46 }
  47
  48 entity kh_worldkeylist;
  49 .entity kh_worldkeynext;
  50 entity kh_controller;
  51 float kh_tracking_enabled;
  52 float kh_teams;
  53 float kh_interferemsg_time, kh_interferemsg_team;
  54 .entity kh_next, kh_prev; // linked list
  55 .float kh_droptime;
  56 .float kh_dropperteam;
  57 .entity kh_previous_owner;
  58
  59 string kh_sound_capture = "sound/kh/capture.wav";
  60 string kh_sound_destroy = "sound/kh/destroy.wav";
  61 string kh_sound_drop = "sound/kh/drop.wav";
  62 string kh_sound_collect = "sound/kh/collect.wav";
  63 string kh_sound_alarm = "sound/kh/alarm.wav";  // the new siren/alarm
  64
  65 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  66 float kh_key_dropped, kh_key_carried;
  67
  68 float kh_GetCarrierSprite(float t, float e)  // runs all the time
  69 {
  70         if(t == e)           return kh_sprite_friend;
  71         if(t == COLOR_TEAM1) return kh_sprite_red;
  72         if(t == COLOR_TEAM2) return kh_sprite_blue;
  73         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  74         if(t == COLOR_TEAM4) return kh_sprite_pink;
  75         return 0;
  76 }
  77
  78 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
  79 {
  80         kh_Controller_Thinkfunc = func;
  81         kh_controller.cnt = t;
  82         if(kh_Controller_Waitmsg != "")
  83                 strunzone(kh_Controller_Waitmsg);
  84         if(msg == "")
  85                 kh_Controller_Waitmsg = "";
  86         else
  87                 kh_Controller_Waitmsg = strzone(msg);
  88         if(t == 0)
  89                 kh_controller.nextthink = time; // force
  90 }
  91
  92 void kh_Controller_Think()  // called a lot
  93 {
  94         entity e;
  95         if(intermission_running)
  96                 return;
  97         if(self.cnt > 0)
  98         {
  99                 if(kh_Controller_Waitmsg != "")
 100                 {
 101                         string s;
 102                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
 103                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
 104                         else
 105                                 s = kh_Controller_Waitmsg;
 106
 107                         //dprint(s, "\n");
 108
 109                         FOR_EACH_PLAYER(e)
 110                                 if(clienttype(e) == CLIENTTYPE_REAL)
 111                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 112                 }
 113                 self.cnt -= 1;
 114         }
 115         else if(self.cnt == 0)
 116         {
 117                 self.cnt -= 1;
 118                 kh_Controller_Thinkfunc();
 119         }
 120         self.nextthink = time + 1;
 121 }
 122
 123 // frags f: take from cvar * f
 124 // frags 0: no frags
 125 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 126 {
 127         string s;
 128         if(intermission_running)
 129                 return;
 130         if(frags_player)
 131         {
 132                 PlayerTeamScore_AddScore(player, frags_player);
 133                 // FIXME we soon don't use .frags or UpdateFrags any more...
 134                 UpdateFrags(player, frags_player);
 135         }
 136         if(key && key.owner && frags_owner)
 137         {
 138                 PlayerTeamScore_AddScore(player, frags_player);
 139                 // FIXME we soon don't use .frags or UpdateFrags any more...
 140                 UpdateFrags(key.owner, frags_owner);
 141         }
 142         if(!cvar("sv_eventlog"))  //output extra info to the console or text file
 143                 return;
 144         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 145         s = strcat(s, ":", ftos(frags_player));
 146         if(key && key.owner)
 147                 s = strcat(s, ":", ftos(key.owner.playerid));
 148         else
 149                 s = strcat(s, ":0");
 150         s = strcat(s, ":", ftos(frags_owner), ":");
 151         if(key)
 152                 s = strcat(s, key.netname);
 153         GameLogEcho(s, FALSE);
 154 }
 155
 156 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 157 {
 158         if(e.tag_entity)
 159         {
 160                 makevectors(e.tag_entity.angles);
 161                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 162         }
 163         else
 164                 return e.origin;
 165 }
 166
 167 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 168 {
 169 #ifdef KH_PLAYER_USE_ATTACHMENT
 170         entity first;
 171         first = key.owner.kh_next;
 172         if(key == first)
 173         {
 174                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 175                 if(key.kh_next)
 176                 {
 177                         setattachment(key.kh_next, key, "");
 178                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 179                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 180                         key.kh_next.angles = '0 0 0';
 181                 }
 182                 else
 183                         setorigin(key, KH_PLAYER_ATTACHMENT);
 184                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 185         }
 186         else
 187         {
 188                 setattachment(key, key.kh_prev, "");
 189                 if(key.kh_next)
 190                         setattachment(key.kh_next, key, "");
 191                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 192                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 193                 key.angles = '0 0 0';
 194         }
 195 #else
 196         setattachment(key, key.owner, "");
 197         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 198         key.angles_y -= key.owner.angles_y;
 199 #endif
 200         key.flags = 0;
 201         key.solid = SOLID_NOT;
 202         key.movetype = MOVETYPE_NONE;
 203         key.team = key.owner.team;
 204         key.nextthink = time;
 205         key.damageforcescale = 0;
 206         key.modelindex = kh_key_carried;
 207 }
 208
 209 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 210 {
 211         float i;
 212         i = test[key.owner.playerid];
 213                 if(key.netname == "^1red key")
 214                         i -= 1;
 215                 if(key.netname == "^4blue key")
 216                         i -= 2;
 217                 if(key.netname == "^3yellow key")
 218                         i -= 4;
 219                 if(key.netname == "^6pink key")
 220                         i -= 8;
 221         test[key.owner.playerid] = i;
 222
 223         kh_show_temp();
 224         if(key.owner)
 225                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 226         //key.owner.kh_state += test[key.owner.playerid];
 227
 228 #ifdef KH_PLAYER_USE_ATTACHMENT
 229         entity first;
 230         first = key.owner.kh_next;
 231         if(key == first)
 232         {
 233                 if(key.kh_next)
 234                 {
 235                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 236                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 237                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 238                 }
 239         }
 240         else
 241         {
 242                 if(key.kh_next)
 243                         setattachment(key.kh_next, key.kh_prev, "");
 244                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 245         }
 246         // in any case:
 247         setattachment(key, world, "");
 248         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 249         key.angles = key.owner.angles;
 250 #else
 251         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 252         setattachment(key, world, "");
 253         key.angles_y += key.owner.angles_y;
 254 #endif
 255         key.aiment = world;
 256         key.flags = FL_ITEM;
 257         key.solid = SOLID_TRIGGER;
 258         key.movetype = MOVETYPE_TOSS;
 259         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 260         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 261         // let key.team stay
 262         key.modelindex = kh_key_dropped;
 263         key.kh_previous_owner = key.owner;
 264 }
 265
 266 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 267 {
 268         if(key.owner == player)
 269                 return;
 270
 271         if(key.owner)
 272         {
 273                 kh_Key_Detach(key);
 274
 275                 // remove from linked list
 276                 if(key.kh_next)
 277                         key.kh_next.kh_prev = key.kh_prev;
 278                 key.kh_prev.kh_next = key.kh_next;
 279                 key.kh_next = world;
 280                 key.kh_prev = world;
 281
 282                 if(key.owner.kh_next == world)
 283                 {
 284                         // No longer a key carrier
 285                         WaypointSprite_DetachCarrier(key.owner);
 286                 }
 287         }
 288
 289         key.owner = player;
 290
 291         if(player)
 292         {
 293                 // insert into linked list
 294                 key.kh_next = player.kh_next;
 295                 key.kh_prev = player;
 296                 player.kh_next = key;
 297                 if(key.kh_next)
 298                         key.kh_next.kh_prev = key;
 299
 300                 float i;
 301                 i = test[key.owner.playerid];
 302                         if(key.netname == "^1red key")
 303                                 i += 1;
 304                         if(key.netname == "^4blue key")
 305                                 i += 2;
 306                         if(key.netname == "^3yellow key")
 307                                 i += 4;
 308                         if(key.netname == "^6pink key")
 309                                 i += 8;
 310                 test[key.owner.playerid] = i;
 311
 312                 kh_Key_Attach(key);
 313
 314                 if(key.kh_next == world)
 315                 {
 316                         // player is now a key carrier
 317                         WaypointSprite_AttachCarrier("", player);
 318                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 319                         player.waypointsprite_attachedforcarrier.team = player.team;
 320                 }
 321         }
 322
 323         // moved that here, also update if there's no player
 324         kh_show_temp();
 325         if(key.owner)
 326                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 327
 328         key.pusher = world;
 329 }
 330
 331 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 332 {
 333         if(self.owner)
 334                 return;
 335         if(vlen(force) <= 0)
 336                 return;
 337         if(time > self.pushltime)
 338                 if(attacker.classname == "player")
 339                         self.team = attacker.team;
 340 }
 341
 342 void kh_Key_Spawn(entity initial_owner, float angle)  // runs every time a new flag is created, ie after all the keys have been collected
 343 {
 344         entity key;
 345         key = spawn();
 346         key.classname = STR_ITEM_KH_KEY;
 347         key.touch = kh_Key_Touch;
 348         key.think = kh_Key_Think;
 349         key.nextthink = time;
 350         key.items = IT_KEY1 | IT_KEY2;
 351         key.cnt = angle;
 352         key.angles = '0 360 0' * random();
 353         key.event_damage = kh_Key_Damage;
 354         key.takedamage = DAMAGE_YES;
 355         key.modelindex = kh_key_dropped;
 356         key.model = "key";
 357         key.kh_dropperteam = 0;
 358         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 359         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 360         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 361
 362         switch(initial_owner.team)
 363         {
 364                 case COLOR_TEAM1:
 365                         key.netname = "^1red key";
 366                         break;
 367                 case COLOR_TEAM2:
 368                         key.netname = "^4blue key";
 369                         break;
 370                 case COLOR_TEAM3:
 371                         key.netname = "^3yellow key";
 372                         break;
 373                 case COLOR_TEAM4:
 374                         key.netname = "^6pink key";
 375                         break;
 376                 default:
 377                         key.netname = "NETGIER key";
 378                         break;
 379         }
 380
 381         // link into key list
 382         key.kh_worldkeynext = kh_worldkeylist;
 383         kh_worldkeylist = key;
 384
 385         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 386
 387         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 388         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 389
 390         kh_Key_AssignTo(key, initial_owner);
 391 }
 392
 393 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 394 {
 395         entity o;
 396         o = key.owner;
 397         kh_Key_AssignTo(key, world);
 398         if(o) // it was attached
 399                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 400         else // it was dropped
 401                 WaypointSprite_DetachCarrier(key);
 402
 403         // remove key from key list
 404         if (kh_worldkeylist == key)
 405                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 406         else
 407         {
 408                 o = kh_worldkeylist;
 409                 while (o)
 410                 {
 411                         if (o.kh_worldkeynext == key)
 412                         {
 413                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 414                                 break;
 415                         }
 416                         o = o.kh_worldkeynext;
 417                 }
 418         }
 419
 420         remove(key);
 421 }
 422
 423 // -1 when no team completely owns all keys yet
 424 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 425 {
 426         entity key;
 427         float teem;
 428
 429         teem = -1;
 430         FOR_EACH_KH_KEY(key)
 431         {
 432                 if(!key.owner)
 433                         return -1;
 434                 if(teem == -1)
 435                         teem = key.team;
 436                 else if(teem != key.team)
 437                         return -1;
 438         }
 439         return teem;
 440 }
 441
 442 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 443 {
 444         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 445
 446         if(key.kh_dropperteam != player.team)
 447         {
 448                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 449                 PlayerScore_Add(player, SP_KH_COLLECT, 1);
 450         }
 451         key.kh_dropperteam = 0;
 452         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 453
 454         kh_Key_AssignTo(key, player); // this also updates .kh_state
 455
 456         if(kh_Key_AllOwnedByWhichTeam() != -1)
 457         {
 458                 kh_interferemsg_time = time + 0.2;
 459                 kh_interferemsg_team = player.team;
 460         }
 461 }
 462
 463 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 464 {
 465         entity key;
 466         entity mypusher;
 467         if(player.kh_next)
 468         {
 469                 mypusher = world;
 470                 if(player.pusher)
 471                         if(time < player.pushltime)
 472                                 mypusher = player.pusher;
 473                 while((key = player.kh_next))
 474                 {
 475                         kh_Scores_Event(player, key, "losekey", 0, 0);
 476                         PlayerScore_Add(player, SP_KH_LOSEKEY, 1);
 477                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 478                         kh_Key_AssignTo(key, world);
 479                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 480                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 481                         key.pusher = mypusher;
 482                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 483                         if(suicide)
 484                                 key.kh_dropperteam = player.team;
 485                 }
 486                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 487         }
 488 }
 489
 490 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 491 {
 492         if(intermission_running)
 493                 return;
 494
 495         if(self.owner) // already carried
 496                 return;
 497         if(other.classname != "player")
 498                 return;
 499         if(other.deadflag != DEAD_NO)
 500                 return;
 501         if(other == self.enemy)
 502                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 503                         return;  // you just dropped it!
 504         kh_Key_Collect(self, other);
 505 }
 506
 507 void kh_Key_Think()  // runs all the time
 508 {
 509         entity head;
 510         //entity player;  // needed by FOR_EACH_PLAYER
 511
 512         if(intermission_running)
 513                 return;
 514         /*
 515         if(time > self.stuff_time)
 516         {
 517                 FOR_EACH_PLAYER(player)
 518                         player.kh_state = test[0]*256 + (player.kh_state&255);
 519
 520                 self.stuff_time = time + 1;  // repeat in 1 second
 521         }
 522         */
 523
 524 #ifdef KH_KEY_ATTACHMENT_DEBUG
 525         if(self.kh_prev == self.owner)
 526         {
 527                 if(cvar_string("_angles") != "")
 528                 {
 529                         self.angles = stov(cvar_string("_angles"));
 530                         self.origin = stov(cvar_string("_origin"));
 531                 }
 532         }
 533 #endif
 534
 535         if(self.owner)
 536         {
 537 #ifndef KH_PLAYER_USE_ATTACHMENT
 538                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 539                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 540 #endif
 541
 542                 if(self.owner.BUTTON_USE)
 543                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 544                 {
 545                         self.owner.kh_droptime = time;
 546                         self.kh_droptime = time;  // prevent collecting this one for some time
 547                         self.enemy = self.owner;
 548                         self.pusher = world;
 549                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 550                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 551                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 552                         makevectors(self.owner.v_angle);
 553                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 554                         kh_Key_AssignTo(self, world);
 555                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 556                         self.kh_dropperteam = self.team;
 557                 }
 558         }
 559
 560         // if in nodrop or time over, end the round
 561         if(!self.owner)
 562                 if(time > self.pain_finished)
 563                         kh_LoserTeam(self.team, self);
 564
 565         if(self.owner)
 566         if(kh_Key_AllOwnedByWhichTeam() != -1)
 567         {
 568                 if(self.siren_time < time)
 569                 {
 570                         sound(world, CHAN_AUTO, kh_sound_alarm, 1, ATTN_NORM);  // play a simple alarm
 571                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 572                 }
 573
 574                 entity key;
 575                 vector p;
 576                 p = self.owner.origin;
 577                 FOR_EACH_KH_KEY(key)
 578                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 579                                 goto not_winning;
 580                 kh_WinnerTeam(self.team);
 581 :not_winning
 582         }
 583
 584         if(kh_interferemsg_time && time > kh_interferemsg_time)
 585         {
 586                 kh_interferemsg_time = 0;
 587                 FOR_EACH_PLAYER(head)
 588                 {
 589                         if(head.team == kh_interferemsg_team)
 590                                 if(head.kh_next)
 591                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 592                                 else
 593                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 594                         else
 595                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 596                 }
 597         }
 598
 599         self.nextthink = time + 0.05;
 600 }
 601
 602 void kh_WinnerTeam(float teem)  // runs when a team wins
 603 {
 604         // all key carriers get some points
 605         vector firstorigin, lastorigin, midpoint;
 606         float first;
 607         entity key;
 608         float score;
 609         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 610         DistributeEvenly_Init(score, kh_teams);
 611         // twice the score for 3 team games, three times the score for 4 team games!
 612         // note: for a win by destroying the key, this should NOT be applied
 613         FOR_EACH_KH_KEY(key)
 614         {
 615                 float f;
 616                 f = DistributeEvenly_Get(1);
 617                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 618                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 619         }
 620
 621         first = TRUE;
 622         FOR_EACH_KH_KEY(key)
 623                 if(key.owner.kh_next == key)
 624                 {
 625                         if(!first)
 626                                 bprint("^7, ");
 627                         bprint(key.owner.netname);
 628                         first = FALSE;
 629                 }
 630         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 631
 632         first = TRUE;
 633         midpoint = '0 0 0';
 634         FOR_EACH_KH_KEY(key)
 635         {
 636                 vector thisorigin;
 637
 638                 thisorigin = kh_AttachedOrigin(key);
 639                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 640                 midpoint += thisorigin;
 641
 642                 if(!first)
 643                         te_lightning2(world, lastorigin, thisorigin);
 644                 lastorigin = thisorigin;
 645                 if(first)
 646                         firstorigin = thisorigin;
 647                 first = FALSE;
 648         }
 649         if(kh_teams > 2)
 650         {
 651                 te_lightning2(world, lastorigin, firstorigin);
 652         }
 653         midpoint = midpoint * (1 / kh_teams);
 654         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 655
 656         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 657         kh_FinishRound();
 658 }
 659
 660 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 661 {
 662         entity player, key, attacker;
 663         float players;
 664         float keys;
 665         float f;
 666
 667         attacker = world;
 668         if(lostkey.pusher)
 669                 if(lostkey.pusher.team != teem)
 670                         if(lostkey.pusher.classname == "player")
 671                                 attacker = lostkey.pusher;
 672
 673         players = keys = 0;
 674
 675         if(attacker)
 676         {
 677                 if(lostkey.kh_previous_owner)
 678                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 679                         // don't actually GIVE him the -nn points, just log
 680                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 681                 PlayerScore_Add(attacker, SP_KH_PUSH, 1);
 682                 centerprint(attacker, "Your push is the best!\n\n\n");
 683                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 684         }
 685         else
 686         {
 687                 float of, fragsleft, i, j, thisteam;
 688                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 689
 690                 FOR_EACH_PLAYER(player)
 691                         if(player.team != teem)
 692                                 ++players;
 693
 694                 FOR_EACH_KH_KEY(key)
 695                         if(key.owner && key.team != teem)
 696                                 ++keys;
 697
 698                 if(lostkey.kh_previous_owner)
 699                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 700                         // don't actually GIVE him the -nn points, just log
 701
 702                 PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYED, 1);
 703
 704                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 705
 706                 FOR_EACH_KH_KEY(key)
 707                         if(key.owner && key.team != teem)
 708                         {
 709                                 f = DistributeEvenly_Get(of);
 710                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 711                         }
 712
 713                 fragsleft = DistributeEvenly_Get(players);
 714
 715                 // Now distribute these among all other teams...
 716                 j = kh_teams - 1;
 717                 for(i = 0; i < kh_teams; ++i)
 718                 {
 719                         thisteam = kh_Team_ByID(i);
 720                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 721                                 continue;
 722
 723                         players = 0;
 724                         FOR_EACH_PLAYER(player)
 725                                 if(player.team == thisteam)
 726                                         ++players;
 727
 728                         DistributeEvenly_Init(fragsleft, j);
 729                         fragsleft = DistributeEvenly_Get(j - 1);
 730                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 731
 732                         FOR_EACH_PLAYER(player)
 733                                 if(player.team == thisteam)
 734                                 {
 735                                         f = DistributeEvenly_Get(1);
 736                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 737                                 }
 738
 739                         --j;
 740                 }
 741
 742                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 743         }
 744         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 745         te_tarexplosion(lostkey.origin);
 746
 747         kh_FinishRound();
 748 }
 749
 750 void kh_FinishRound()  // runs when a team captures the keys
 751 {
 752         // prepare next round
 753         kh_interferemsg_time = 0;
 754         entity key;
 755         FOR_EACH_KH_KEY(key)
 756                 kh_Key_Remove(key);
 757
 758         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 759 }
 760
 761 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 762 {
 763         float i, players, teem;
 764         entity player;
 765         string result;
 766         result = "";
 767
 768         // find a random player per team
 769         for(i = 0; i < kh_teams; ++i)
 770         {
 771                 teem = kh_Team_ByID(i);
 772                 players = 0;
 773                 FOR_EACH_PLAYER(player)
 774                         if(player.deadflag == DEAD_NO)
 775                                 if(!player.BUTTON_CHAT)
 776                                         if(player.team == teem)
 777                                                 ++players;
 778                 if(players == 0)
 779                 {
 780                         if(result != "")
 781                                 result = strcat(result, ", ");
 782                         result = strcat(result, ColoredTeamName(teem));
 783                 }
 784         }
 785         return result;
 786 }
 787
 788 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 789 {
 790         string teams_missing;
 791         teams_missing = kh_CheckEnoughPlayers();
 792         if(teams_missing == "")
 793                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 794         else
 795                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 796 }
 797
 798 void kh_StartRound()  // runs at the start of each round
 799 {
 800         string teams_missing;
 801         float i, players, teem;
 802         entity player;
 803
 804         teams_missing = kh_CheckEnoughPlayers();
 805         if(teams_missing != "")
 806         {
 807                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 808                 return;
 809         }
 810
 811         FOR_EACH_PLAYER(player)
 812                 if(clienttype(player) == CLIENTTYPE_REAL)
 813                         centerprint_expire(player, CENTERPRIO_SPAM);
 814
 815         for(i = 0; i < kh_teams; ++i)
 816         {
 817                 teem = kh_Team_ByID(i);
 818                 players = 0;
 819                 entity my_player;
 820                 FOR_EACH_PLAYER(player)
 821                         if(player.deadflag == DEAD_NO)
 822                                 if(!player.BUTTON_CHAT)
 823                                         if(player.team == teem)
 824                                         {
 825                                                 ++players;
 826                                                 if(random() * players <= 1)
 827                                                         my_player = player;
 828                                         }
 829                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 830                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 831                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 832         }
 833
 834         kh_tracking_enabled = FALSE;
 835         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 836 }
 837
 838 void kh_setstatus()  // runs all the time
 839 {
 840         if(kh_teams)
 841         {
 842                 float kh_KEY;
 843                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST);  // the one impossible combination
 844                 if(self.kh_next)
 845                         self.items = self.items | kh_KEY;
 846                 else
 847                         self.items = self.items - (self.items & kh_KEY);
 848         }
 849 }
 850
 851 void kh_EnableTrackingDevice()  // runs after each round
 852 {
 853         entity player;
 854
 855         FOR_EACH_PLAYER(player)
 856                 if(clienttype(player) == CLIENTTYPE_REAL)
 857                         centerprint_expire(player, CENTERPRIO_SPAM);
 858
 859         kh_tracking_enabled = TRUE;
 860 }
 861
 862 float kh_Key_waypointsprite_for_player(entity e) // ??
 863 {
 864         if(!kh_tracking_enabled)
 865                 return 0;
 866         if(!self.owner)
 867                 return kh_sprite_dropped;
 868         if(!self.owner.owner)
 869                 return kh_sprite_dropped;
 870         return 0;  // draw only when key is not owned
 871 }
 872
 873 float kh_KeyCarrier_waypointsprite_for_player(entity e)  // runs all the time
 874 {
 875         if(e.classname != "player" || self.team != e.team)
 876                 if(!kh_tracking_enabled)
 877                         return 0;
 878
 879         // e is spectator? That's no team mate...
 880         if(e.classname != "player")
 881                 return kh_GetCarrierSprite(self.team, -1);
 882
 883         // e is no key carrier: simple case...
 884         if(!e.kh_next)
 885                 return kh_GetCarrierSprite(self.team, e.team);
 886
 887         // e is a key carrier: if any key is dropped or owned by another team, show
 888         // the carrier sprite; otherwise show run here
 889         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 890                 return kh_sprite_finish;
 891
 892         return kh_GetCarrierSprite(self.team, e.team);
 893 }
 894
 895 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 896 {
 897         if(attacker == targ)
 898                 return f;
 899
 900         if(targ.kh_next)
 901         {
 902                 if(attacker.team == targ.team)
 903                 {
 904                         entity k;
 905                         float nk;
 906                         nk = 0;
 907                         for(k = targ.kh_next; k != world; k = k.kh_next)
 908                                 ++nk;
 909                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 910                 }
 911                 else
 912                 {
 913                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 914                         PlayerScore_Add(attacker, SP_KH_KCFRAG, 1);
 915                         // the frag gets added later
 916                 }
 917         }
 918
 919         return f;
 920 }
 921
 922 void kh_init()  // sets up th KH environment
 923 {
 924         precache_sound(kh_sound_capture);
 925         precache_sound(kh_sound_destroy);
 926         precache_sound(kh_sound_drop);
 927         precache_sound(kh_sound_collect);
 928         precache_sound(kh_sound_alarm);  // the new siren
 929
 930         precache_model("models/sprites/key-dropped.sp2");
 931         precache_model("models/sprites/keycarrier-finish.sp2");
 932         precache_model("models/sprites/keycarrier-friend.sp2");
 933         precache_model("models/sprites/keycarrier-red.sp2");
 934         precache_model("models/sprites/keycarrier-blue.sp2");
 935         precache_model("models/sprites/keycarrier-yellow.sp2");
 936         precache_model("models/sprites/keycarrier-pink.sp2");
 937 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 938         precache_model("models/keyhunt/key-carried.md3");
 939 #endif
 940         precache_model("models/keyhunt/key.md3");
 941
 942         // setup variables
 943         kh_teams = cvar("g_keyhunt_teams_override");
 944         if(kh_teams < 2)
 945                 kh_teams = cvar("g_keyhunt_teams");
 946         kh_teams = bound(2, kh_teams, 4);
 947
 948         // make a KH entity for controlling the game
 949         kh_controller = spawn();
 950         kh_controller.think = kh_Controller_Think;
 951         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 952
 953         setmodel(kh_controller, "models/keyhunt/key.md3");
 954         kh_key_dropped = kh_controller.modelindex;
 955         /*
 956         dprint(vtos(kh_controller.mins));
 957         dprint(vtos(kh_controller.maxs));
 958         dprint("\n");
 959         */
 960 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 961         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 962         kh_key_carried = kh_controller.modelindex;
 963 #else
 964         kh_key_carried = kh_key_dropped;
 965 #endif
 966         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 967         kh_sprite_dropped = kh_controller.modelindex;
 968         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 969         kh_sprite_finish = kh_controller.modelindex;
 970         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 971         kh_sprite_friend = kh_controller.modelindex;
 972         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 973         kh_sprite_red = kh_controller.modelindex;
 974         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 975         kh_sprite_blue = kh_controller.modelindex;
 976         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 977         kh_sprite_pink = kh_controller.modelindex;
 978         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 979         kh_sprite_yellow = kh_controller.modelindex;
 980         setmodel(kh_controller, "");
 981
 982         addstat(STAT_KH_KEYS, AS_INT, kh_state);
 983
 984 #ifdef CSQCSCORES
 985         ScoreInfo_Init(kh_teams);
 986         ScoreInfo_SetLabel_TeamScore  (ST_SCORE,        "score",     SFL_SORT_PRIO_PRIMARY);
 987         ScoreInfo_SetLabel_TeamScore  (ST_KH_CAPS,      "caps",      SFL_SORT_PRIO_MED);
 988         ScoreInfo_SetLabel_PlayerScore(SP_KILLS,        "kills",     0);
 989         ScoreInfo_SetLabel_PlayerScore(SP_DEATHS,       "deaths",    SFL_DECREASING);
 990         ScoreInfo_SetLabel_PlayerScore(SP_SUICIDES,     "suicides",  SFL_DECREASING);
 991         ScoreInfo_SetLabel_PlayerScore(SP_SCORE,        "score",     SFL_SORT_PRIO_PRIMARY);
 992         ScoreInfo_SetLabel_PlayerScore(SP_KH_COLLECT,   "collect",   0);
 993         ScoreInfo_SetLabel_PlayerScore(SP_KH_LOSEKEY,   "losekey",   SFL_DECREASING);
 994         ScoreInfo_SetLabel_PlayerScore(SP_KH_CAPS,      "caps",      SFL_SORT_PRIO_HIGH);
 995         ScoreInfo_SetLabel_PlayerScore(SP_KH_PUSH,      "push",      SFL_SORT_PRIO_MED);
 996         ScoreInfo_SetLabel_PlayerScore(SP_KH_DESTROYED, "destroyed", SFL_SORT_PRIO_MED | SFL_DECREASING);
 997         ScoreInfo_SetLabel_PlayerScore(SP_KH_KCFRAG,    "kcfrag",    SFL_SORT_PRIO_MED);
 998 #endif
 999 }
1000
1001 void kh_finalize()
1002 {
1003         // to be called before intermission
1004         kh_FinishRound();
1005         remove(kh_controller);
1006         kh_controller = world;
1007 }
1008
1009 /**
1010  * kh_show_temp originally by victim.
1011  * changed it to use the kh_state stat var
1012  * Updates the general key stat bits for each player
1013  */
1014 void kh_show_temp()
1015 {
1016         entity player;
1017         float i, j;
1018
1019         j = 0;  // reset/blank j
1020         for(i=1; i<17; ++i)  // replace 17 with cvar("maxplayers"); !!!!!!!!!
1021                 j += test[i];
1022
1023         test[0] = j;
1024
1025         j *= 256;
1026         FOR_EACH_PLAYER(player)
1027                 player.kh_state = j + (player.kh_state & 255); // update the general key bits
1028 }