data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25 float kh_no_radar_circles;
  26
  27 // kh_state
  28 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  29 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  30 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  31 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  32 .float kh_state;
  33 .float siren_time;  //  time delay the siren
  34 //.float stuff_time;  //  time delay to stuffcmd a cvar
  35
  36 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  37 //test[0] = status of dropped keys, test[1 - 16] = player #
  38 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  39 //for(i = 0; i < maxplayers; ++i)
  40 //      test[i] = "0";
  41
  42 float kh_Team_ByID(float t)
  43 {
  44         if(t == 0) return COLOR_TEAM1;
  45         if(t == 1) return COLOR_TEAM2;
  46         if(t == 2) return COLOR_TEAM3;
  47         if(t == 3) return COLOR_TEAM4;
  48         return 0;
  49 }
  50
  51 entity kh_worldkeylist;
  52 .entity kh_worldkeynext;
  53 entity kh_controller;
  54 float kh_tracking_enabled;
  55 float kh_teams;
  56 float kh_interferemsg_time, kh_interferemsg_team;
  57 .entity kh_next, kh_prev; // linked list
  58 .float kh_droptime;
  59 .float kh_dropperteam;
  60 .entity kh_previous_owner;
  61 .float kh_previous_owner_playerid;
  62
  63 string kh_sound_capture = "kh/capture.wav";
  64 string kh_sound_destroy = "kh/destroy.wav";
  65 string kh_sound_drop = "kh/drop.wav";
  66 string kh_sound_collect = "kh/collect.wav";
  67 string kh_sound_alarm = "kh/alarm.wav";  // the new siren/alarm
  68
  69 float kh_key_dropped, kh_key_carried;
  70
  71 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
  72 {
  73         kh_Controller_Thinkfunc = func;
  74         kh_controller.cnt = ceil(t);
  75         if(kh_Controller_Waitmsg != "")
  76                 strunzone(kh_Controller_Waitmsg);
  77         if(msg == "")
  78                 kh_Controller_Waitmsg = "";
  79         else
  80                 kh_Controller_Waitmsg = strzone(msg);
  81         if(t == 0)
  82                 kh_controller.nextthink = time; // force
  83 }
  84
  85 void kh_Controller_Think()  // called a lot
  86 {
  87         entity e;
  88         if(intermission_running)
  89                 return;
  90         if(self.cnt > 0)
  91         {
  92                 if(kh_Controller_Waitmsg != "")
  93                 {
  94                         string s;
  95                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  96                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  97                         else
  98                                 s = kh_Controller_Waitmsg;
  99
 100                         //dprint(s, "\n");
 101
 102                         FOR_EACH_PLAYER(e)
 103                                 if(clienttype(e) == CLIENTTYPE_REAL)
 104                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 105                 }
 106                 self.cnt -= 1;
 107         }
 108         else if(self.cnt == 0)
 109         {
 110                 self.cnt -= 1;
 111                 kh_Controller_Thinkfunc();
 112         }
 113         self.nextthink = time + 1;
 114 }
 115
 116 // frags f: take from cvar * f
 117 // frags 0: no frags
 118 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 119 {
 120         string s;
 121         if(intermission_running)
 122                 return;
 123         if(frags_player)
 124                 UpdateFrags(player, frags_player);
 125         if(key && key.owner && frags_owner)
 126                 UpdateFrags(key.owner, frags_owner);
 127         if(!cvar("sv_eventlog"))  //output extra info to the console or text file
 128                 return;
 129         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 130         s = strcat(s, ":", ftos(frags_player));
 131         if(key && key.owner)
 132                 s = strcat(s, ":", ftos(key.owner.playerid));
 133         else
 134                 s = strcat(s, ":0");
 135         s = strcat(s, ":", ftos(frags_owner), ":");
 136         if(key)
 137                 s = strcat(s, key.netname);
 138         GameLogEcho(s);
 139 }
 140
 141 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 142 {
 143         if(e.tag_entity)
 144         {
 145                 makevectors(e.tag_entity.angles);
 146                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 147         }
 148         else
 149                 return e.origin;
 150 }
 151
 152 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 153 {
 154 #ifdef KH_PLAYER_USE_ATTACHMENT
 155         entity first;
 156         first = key.owner.kh_next;
 157         if(key == first)
 158         {
 159                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 160                 if(key.kh_next)
 161                 {
 162                         setattachment(key.kh_next, key, "");
 163                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 164                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 165                         key.kh_next.angles = '0 0 0';
 166                 }
 167                 else
 168                         setorigin(key, KH_PLAYER_ATTACHMENT);
 169                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 170         }
 171         else
 172         {
 173                 setattachment(key, key.kh_prev, "");
 174                 if(key.kh_next)
 175                         setattachment(key.kh_next, key, "");
 176                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 177                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 178                 key.angles = '0 0 0';
 179         }
 180 #else
 181         setattachment(key, key.owner, "");
 182         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 183         key.angles_y -= key.owner.angles_y;
 184 #endif
 185         key.flags = 0;
 186         key.solid = SOLID_NOT;
 187         key.movetype = MOVETYPE_NONE;
 188         key.team = key.owner.team;
 189         key.nextthink = time;
 190         key.damageforcescale = 0;
 191         key.takedamage = DAMAGE_NO;
 192         key.modelindex = kh_key_carried;
 193 }
 194
 195 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 196 {
 197 #ifdef KH_PLAYER_USE_ATTACHMENT
 198         entity first;
 199         first = key.owner.kh_next;
 200         if(key == first)
 201         {
 202                 if(key.kh_next)
 203                 {
 204                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 205                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 206                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 207                 }
 208         }
 209         else
 210         {
 211                 if(key.kh_next)
 212                         setattachment(key.kh_next, key.kh_prev, "");
 213                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 214         }
 215         // in any case:
 216         setattachment(key, world, "");
 217         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 218         key.angles = key.owner.angles;
 219 #else
 220         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 221         setattachment(key, world, "");
 222         key.angles_y += key.owner.angles_y;
 223 #endif
 224         key.flags = FL_ITEM;
 225         key.solid = SOLID_TRIGGER;
 226         key.movetype = MOVETYPE_TOSS;
 227         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 228         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 229         key.takedamage = DAMAGE_YES;
 230         // let key.team stay
 231         key.modelindex = kh_key_dropped;
 232         key.kh_previous_owner = key.owner;
 233         key.kh_previous_owner_playerid = key.owner.playerid;
 234 }
 235
 236 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 237 {
 238         entity k;
 239         float ownerteam0, ownerteam;
 240         if(key.owner == player)
 241                 return;
 242
 243         ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 244
 245         if(key.owner)
 246         {
 247                 kh_Key_Detach(key);
 248
 249                 // remove from linked list
 250                 if(key.kh_next)
 251                         key.kh_next.kh_prev = key.kh_prev;
 252                 key.kh_prev.kh_next = key.kh_next;
 253                 key.kh_next = world;
 254                 key.kh_prev = world;
 255
 256                 if(key.owner.kh_next == world)
 257                 {
 258                         // No longer a key carrier
 259                         if(!kh_no_radar_circles)
 260                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 261                         WaypointSprite_DetachCarrier(key.owner);
 262                 }
 263         }
 264
 265         key.owner = player;
 266
 267         if(player)
 268         {
 269                 // insert into linked list
 270                 key.kh_next = player.kh_next;
 271                 key.kh_prev = player;
 272                 player.kh_next = key;
 273                 if(key.kh_next)
 274                         key.kh_next.kh_prev = key;
 275
 276                 float i;
 277                 i = test[key.owner.playerid];
 278                         if(key.netname == "^1red key")
 279                                 i += 1;
 280                         if(key.netname == "^4blue key")
 281                                 i += 2;
 282                         if(key.netname == "^3yellow key")
 283                                 i += 4;
 284                         if(key.netname == "^6pink key")
 285                                 i += 8;
 286                 test[key.owner.playerid] = i;
 287
 288                 kh_Key_Attach(key);
 289
 290                 if(key.kh_next == world)
 291                 {
 292                         // player is now a key carrier
 293                         WaypointSprite_AttachCarrier("", player);
 294                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 295                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 296                         if(player.team == COLOR_TEAM1)
 297                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-red", "keycarrier-friend", "keycarrier-red");
 298                         else if(player.team == COLOR_TEAM2)
 299                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-blue", "keycarrier-friend", "keycarrier-blue");
 300                         else if(player.team == COLOR_TEAM3)
 301                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-yellow", "keycarrier-friend", "keycarrier-yellow");
 302                         else if(player.team == COLOR_TEAM4)
 303                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, "keycarrier-pink", "keycarrier-friend", "keycarrier-pink");
 304                         WaypointSprite_UpdateTeamRadar(player.waypointsprite_attachedforcarrier, RADARICON_FLAGCARRIER, colormapPaletteColor(player.team - 1, 0));
 305                         if(!kh_no_radar_circles)
 306                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 307                 }
 308         }
 309
 310         // moved that here, also update if there's no player
 311         kh_update_state();
 312
 313         key.pusher = world;
 314
 315         ownerteam = kh_Key_AllOwnedByWhichTeam();
 316         if(ownerteam != ownerteam0)
 317         {
 318                 if(ownerteam != -1)
 319                 {
 320                         kh_interferemsg_time = time + 0.2;
 321                         kh_interferemsg_team = player.team;
 322
 323                         // audit all key carrier sprites, update them to RUN HERE
 324                         FOR_EACH_KH_KEY(k)
 325                         {
 326                                 if(k.owner)
 327                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-finish", k.owner.waypointsprite_attachedforcarrier.model3);
 328                         }
 329                 }
 330                 else
 331                 {
 332                         kh_interferemsg_time = 0;
 333
 334                         // audit all key carrier sprites, update them to RUN HERE
 335                         FOR_EACH_KH_KEY(k)
 336                         {
 337                                 if(k.owner)
 338                                         WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, k.owner.waypointsprite_attachedforcarrier.model1, "keycarrier-friend", k.owner.waypointsprite_attachedforcarrier.model3);
 339                         }
 340                 }
 341         }
 342 }
 343
 344 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 345 {
 346         if(self.owner)
 347                 return;
 348         if(vlen(force) <= 0)
 349                 return;
 350         if(time > self.pushltime)
 351                 if(attacker.classname == "player")
 352                         self.team = attacker.team;
 353 }
 354
 355 void key_reset()
 356 {
 357         kh_Key_AssignTo(self, world);
 358         kh_Key_Remove(self);
 359 }
 360
 361 void kh_Key_Spawn(entity initial_owner, float angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 362 {
 363         entity key;
 364         key = spawn();
 365         key.count = i;
 366         key.classname = STR_ITEM_KH_KEY;
 367         key.touch = kh_Key_Touch;
 368         key.think = kh_Key_Think;
 369         key.nextthink = time;
 370         key.items = IT_KEY1 | IT_KEY2;
 371         key.cnt = angle;
 372         key.angles = '0 360 0' * random();
 373         key.event_damage = kh_Key_Damage;
 374         key.takedamage = DAMAGE_YES;
 375         key.modelindex = kh_key_dropped;
 376         key.model = "key";
 377         key.kh_dropperteam = 0;
 378         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 379         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 380         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 381         key.reset = key_reset;
 382
 383         switch(initial_owner.team)
 384         {
 385                 case COLOR_TEAM1:
 386                         key.netname = "^1red key";
 387                         break;
 388                 case COLOR_TEAM2:
 389                         key.netname = "^4blue key";
 390                         break;
 391                 case COLOR_TEAM3:
 392                         key.netname = "^3yellow key";
 393                         break;
 394                 case COLOR_TEAM4:
 395                         key.netname = "^6pink key";
 396                         break;
 397                 default:
 398                         key.netname = "NETGIER key";
 399                         break;
 400         }
 401
 402         // link into key list
 403         key.kh_worldkeynext = kh_worldkeylist;
 404         kh_worldkeylist = key;
 405
 406         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 407
 408         WaypointSprite_Spawn("key-dropped", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 409         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 410         WaypointSprite_UpdateTeamRadar(key.waypointsprite_attachedforcarrier, RADARICON_FLAG, '0 1 1');
 411
 412         kh_Key_AssignTo(key, initial_owner);
 413 }
 414
 415 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 416 {
 417         entity o;
 418         o = key.owner;
 419         kh_Key_AssignTo(key, world);
 420         if(o) // it was attached
 421                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 422         else // it was dropped
 423                 WaypointSprite_DetachCarrier(key);
 424
 425         // remove key from key list
 426         if (kh_worldkeylist == key)
 427                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 428         else
 429         {
 430                 o = kh_worldkeylist;
 431                 while (o)
 432                 {
 433                         if (o.kh_worldkeynext == key)
 434                         {
 435                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 436                                 break;
 437                         }
 438                         o = o.kh_worldkeynext;
 439                 }
 440         }
 441
 442         remove(key);
 443
 444         kh_update_state();
 445 }
 446
 447 // -1 when no team completely owns all keys yet
 448 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 449 {
 450         entity key;
 451         float teem;
 452         float keys;
 453
 454         teem = -1;
 455         keys = kh_teams;
 456         FOR_EACH_KH_KEY(key)
 457         {
 458                 if(!key.owner)
 459                         return -1;
 460                 if(teem == -1)
 461                         teem = key.team;
 462                 else if(teem != key.team)
 463                         return -1;
 464                 --keys;
 465         }
 466         if(keys != 0)
 467                 return -1;
 468         return teem;
 469 }
 470
 471 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 472 {
 473         sound(player, CHAN_AUTO, kh_sound_collect, VOL_BASE, ATTN_NORM);
 474
 475         if(key.kh_dropperteam != player.team)
 476         {
 477                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 478                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 479         }
 480         key.kh_dropperteam = 0;
 481         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 482
 483         kh_Key_AssignTo(key, player); // this also updates .kh_state
 484 }
 485
 486 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 487 {
 488         entity key;
 489         entity mypusher;
 490         if(player.kh_next)
 491         {
 492                 mypusher = world;
 493                 if(player.pusher)
 494                         if(time < player.pushltime)
 495                                 mypusher = player.pusher;
 496                 while((key = player.kh_next))
 497                 {
 498                         kh_Scores_Event(player, key, "losekey", 0, 0);
 499                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 500                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 501                         kh_Key_AssignTo(key, world);
 502                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 503                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 504                         key.pusher = mypusher;
 505                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 506                         if(suicide)
 507                                 key.kh_dropperteam = player.team;
 508                 }
 509                 sound(player, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 510         }
 511 }
 512
 513 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 514 {
 515         if(intermission_running)
 516                 return;
 517
 518         if(self.owner) // already carried
 519                 return;
 520         if(other.classname != "player")
 521                 return;
 522         if(other.deadflag != DEAD_NO)
 523                 return;
 524         if(other == self.enemy)
 525                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 526                         return;  // you just dropped it!
 527         kh_Key_Collect(self, other);
 528 }
 529
 530 void kh_Key_Think()  // runs all the time
 531 {
 532         entity head;
 533         //entity player;  // needed by FOR_EACH_PLAYER
 534
 535         if(intermission_running)
 536                 return;
 537
 538 #ifdef KH_KEY_ATTACHMENT_DEBUG
 539         if(self.kh_prev == self.owner)
 540         {
 541                 if(cvar_string("_angles") != "")
 542                 {
 543                         self.angles = stov(cvar_string("_angles"));
 544                         setorigin(self, stov(cvar_string("_origin")));
 545                 }
 546         }
 547 #endif
 548
 549         if(self.owner)
 550         {
 551 #ifndef KH_PLAYER_USE_ATTACHMENT
 552                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 553                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 554 #endif
 555
 556                 if(self.owner.BUTTON_USE)
 557                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 558                 {
 559                         self.owner.kh_droptime = time;
 560                         self.kh_droptime = time;  // prevent collecting this one for some time
 561                         self.enemy = self.owner;
 562                         self.pusher = world;
 563                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 564                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 565                         sound(self.owner, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 566                         makevectors(self.owner.v_angle);
 567                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 568                         kh_Key_AssignTo(self, world);
 569                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 570                         self.kh_dropperteam = self.team;
 571                 }
 572         }
 573
 574         // if in nodrop or time over, end the round
 575         if(!self.owner)
 576                 if(time > self.pain_finished)
 577                         kh_LoserTeam(self.team, self);
 578
 579         if(self.owner)
 580         if(kh_Key_AllOwnedByWhichTeam() != -1)
 581         {
 582                 if(self.siren_time < time)
 583                 {
 584                         sound(self.owner, CHAN_AUTO, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 585                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 586                 }
 587
 588                 entity key;
 589                 vector p;
 590                 p = self.owner.origin;
 591                 FOR_EACH_KH_KEY(key)
 592                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 593                                 goto not_winning;
 594                 kh_WinnerTeam(self.team);
 595 :not_winning
 596         }
 597
 598         if(kh_interferemsg_time && time > kh_interferemsg_time)
 599         {
 600                 kh_interferemsg_time = 0;
 601                 FOR_EACH_PLAYER(head)
 602                 {
 603                         if(head.team == kh_interferemsg_team)
 604                                 if(head.kh_next)
 605                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!");
 606                                 else
 607                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!");
 608                         else
 609                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!"));
 610                 }
 611         }
 612
 613         self.nextthink = time + 0.05;
 614 }
 615
 616 void kh_WinnerTeam(float teem)  // runs when a team wins
 617 {
 618         // all key carriers get some points
 619         vector firstorigin, lastorigin, midpoint;
 620         float first;
 621         entity key;
 622         float score;
 623         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 624         DistributeEvenly_Init(score, kh_teams);
 625         // twice the score for 3 team games, three times the score for 4 team games!
 626         // note: for a win by destroying the key, this should NOT be applied
 627         FOR_EACH_KH_KEY(key)
 628         {
 629                 float f;
 630                 f = DistributeEvenly_Get(1);
 631                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 632                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 633         }
 634
 635         first = TRUE;
 636         FOR_EACH_KH_KEY(key)
 637                 if(key.owner.kh_next == key)
 638                 {
 639                         if(!first)
 640                                 bprint("^7, ");
 641                         bprint(key.owner.netname);
 642                         first = FALSE;
 643                 }
 644         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 645
 646         first = TRUE;
 647         midpoint = '0 0 0';
 648         FOR_EACH_KH_KEY(key)
 649         {
 650                 vector thisorigin;
 651
 652                 thisorigin = kh_AttachedOrigin(key);
 653                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 654                 midpoint += thisorigin;
 655
 656                 if(!first)
 657                         te_lightning2(world, lastorigin, thisorigin);
 658                 lastorigin = thisorigin;
 659                 if(first)
 660                         firstorigin = thisorigin;
 661                 first = FALSE;
 662         }
 663         if(kh_teams > 2)
 664         {
 665                 te_lightning2(world, lastorigin, firstorigin);
 666         }
 667         midpoint = midpoint * (1 / kh_teams);
 668         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 669
 670         play2all(kh_sound_capture);
 671         kh_FinishRound();
 672 }
 673
 674 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 675 {
 676         entity player, key, attacker;
 677         float players;
 678         float keys;
 679         float f;
 680
 681         attacker = world;
 682         if(lostkey.pusher)
 683                 if(lostkey.pusher.team != teem)
 684                         if(lostkey.pusher.classname == "player")
 685                                 attacker = lostkey.pusher;
 686
 687         players = keys = 0;
 688
 689         if(attacker)
 690         {
 691                 if(lostkey.kh_previous_owner)
 692                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 693                         // don't actually GIVE him the -nn points, just log
 694                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 695                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 696                 centerprint(attacker, "Your push is the best!");
 697                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 698         }
 699         else
 700         {
 701                 float of, fragsleft, i, j, thisteam;
 702                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 703
 704                 FOR_EACH_PLAYER(player)
 705                         if(player.team != teem)
 706                                 ++players;
 707
 708                 FOR_EACH_KH_KEY(key)
 709                         if(key.owner && key.team != teem)
 710                                 ++keys;
 711
 712                 if(lostkey.kh_previous_owner)
 713                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 714                         // don't actually GIVE him the -nn points, just log
 715
 716                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 717                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 718
 719                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 720
 721                 FOR_EACH_KH_KEY(key)
 722                         if(key.owner && key.team != teem)
 723                         {
 724                                 f = DistributeEvenly_Get(of);
 725                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 726                         }
 727
 728                 fragsleft = DistributeEvenly_Get(players);
 729
 730                 // Now distribute these among all other teams...
 731                 j = kh_teams - 1;
 732                 for(i = 0; i < kh_teams; ++i)
 733                 {
 734                         thisteam = kh_Team_ByID(i);
 735                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 736                                 continue;
 737
 738                         players = 0;
 739                         FOR_EACH_PLAYER(player)
 740                                 if(player.team == thisteam)
 741                                         ++players;
 742
 743                         DistributeEvenly_Init(fragsleft, j);
 744                         fragsleft = DistributeEvenly_Get(j - 1);
 745                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 746
 747                         FOR_EACH_PLAYER(player)
 748                                 if(player.team == thisteam)
 749                                 {
 750                                         f = DistributeEvenly_Get(1);
 751                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 752                                 }
 753
 754                         --j;
 755                 }
 756
 757                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 758         }
 759         play2all(kh_sound_destroy);
 760         te_tarexplosion(lostkey.origin);
 761
 762         kh_FinishRound();
 763 }
 764
 765 void kh_FinishRound()  // runs when a team captures the keys
 766 {
 767         // prepare next round
 768         kh_interferemsg_time = 0;
 769         entity key;
 770
 771         kh_no_radar_circles = TRUE;
 772         FOR_EACH_KH_KEY(key)
 773                 kh_Key_Remove(key);
 774         kh_no_radar_circles = FALSE;
 775
 776         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 777 }
 778
 779 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 780 {
 781         float i, players, teem;
 782         entity player;
 783         string result;
 784         result = "";
 785
 786         // find a random player per team
 787         for(i = 0; i < kh_teams; ++i)
 788         {
 789                 teem = kh_Team_ByID(i);
 790                 players = 0;
 791                 FOR_EACH_PLAYER(player)
 792                         if(player.deadflag == DEAD_NO)
 793                                 if(!player.BUTTON_CHAT)
 794                                         if(player.team == teem)
 795                                                 ++players;
 796                 if(players == 0)
 797                 {
 798                         if(result != "")
 799                                 result = strcat(result, ", ");
 800                         result = strcat(result, ColoredTeamName(teem));
 801                 }
 802         }
 803         return result;
 804 }
 805
 806 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 807 {
 808         string teams_missing;
 809
 810         if(time < game_starttime)
 811         {
 812                 kh_Controller_SetThink(game_starttime - time + 0.1, "", kh_WaitForPlayers);
 813                 return;
 814         }
 815
 816         teams_missing = kh_CheckEnoughPlayers();
 817         if(teams_missing == "")
 818                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 819         else
 820                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 821 }
 822
 823 void kh_StartRound()  // runs at the start of each round
 824 {
 825         string teams_missing;
 826         float i, players, teem;
 827         entity player;
 828
 829         if(time < game_starttime)
 830         {
 831                 kh_Controller_SetThink(game_starttime - time + 0.1, "", kh_WaitForPlayers);
 832                 return;
 833         }
 834
 835         teams_missing = kh_CheckEnoughPlayers();
 836         if(teams_missing != "")
 837         {
 838                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 839                 return;
 840         }
 841
 842         FOR_EACH_PLAYER(player)
 843                 if(clienttype(player) == CLIENTTYPE_REAL)
 844                         centerprint_expire(player, CENTERPRIO_SPAM);
 845
 846         for(i = 0; i < kh_teams; ++i)
 847         {
 848                 teem = kh_Team_ByID(i);
 849                 players = 0;
 850                 entity my_player;
 851                 FOR_EACH_PLAYER(player)
 852                         if(player.deadflag == DEAD_NO)
 853                                 if(!player.BUTTON_CHAT)
 854                                         if(player.team == teem)
 855                                         {
 856                                                 ++players;
 857                                                 if(random() * players <= 1)
 858                                                         my_player = player;
 859                                         }
 860                 kh_Key_Spawn(my_player, 360 * i / kh_teams, i);
 861         }
 862
 863         kh_tracking_enabled = FALSE;
 864         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 865 }
 866
 867 void kh_EnableTrackingDevice()  // runs after each round
 868 {
 869         entity player;
 870
 871         FOR_EACH_PLAYER(player)
 872                 if(clienttype(player) == CLIENTTYPE_REAL)
 873                         centerprint_expire(player, CENTERPRIO_SPAM);
 874
 875         kh_tracking_enabled = TRUE;
 876 }
 877
 878 float kh_Key_waypointsprite_visible_for_player(entity e) // ??
 879 {
 880         if(!kh_tracking_enabled)
 881                 return FALSE;
 882         if(!self.owner)
 883                 return TRUE;
 884         if(!self.owner.owner)
 885                 return TRUE;
 886         return FALSE;  // draw only when key is not owned
 887 }
 888
 889 float kh_KeyCarrier_waypointsprite_visible_for_player(entity e)  // runs all the time
 890 {
 891         if(e.classname != "player" || self.team != e.team)
 892                 if(!kh_tracking_enabled)
 893                         return FALSE;
 894
 895         return TRUE;
 896 }
 897
 898 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 899 {
 900         if(attacker == targ)
 901                 return f;
 902
 903         if(targ.kh_next)
 904         {
 905                 if(attacker.team == targ.team)
 906                 {
 907                         entity k;
 908                         float nk;
 909                         nk = 0;
 910                         for(k = targ.kh_next; k != world; k = k.kh_next)
 911                                 ++nk;
 912                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 913                 }
 914                 else
 915                 {
 916                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 917                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 918                         // the frag gets added later
 919                 }
 920         }
 921
 922         return f;
 923 }
 924
 925 void kh_init()  // sets up th KH environment
 926 {
 927         precache_sound(kh_sound_capture);
 928         precache_sound(kh_sound_destroy);
 929         precache_sound(kh_sound_drop);
 930         precache_sound(kh_sound_collect);
 931         precache_sound(kh_sound_alarm);  // the new siren
 932
 933 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 934         precache_model("models/keyhunt/key-carried.md3");
 935 #endif
 936         precache_model("models/keyhunt/key.md3");
 937
 938         // setup variables
 939         kh_teams = cvar("g_keyhunt_teams_override");
 940         if(kh_teams < 2)
 941                 kh_teams = cvar("g_keyhunt_teams");
 942         kh_teams = bound(2, kh_teams, 4);
 943
 944         // make a KH entity for controlling the game
 945         kh_controller = spawn();
 946         kh_controller.think = kh_Controller_Think;
 947         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 948
 949         setmodel(kh_controller, "models/keyhunt/key.md3");
 950         kh_key_dropped = kh_controller.modelindex;
 951         /*
 952         dprint(vtos(kh_controller.mins));
 953         dprint(vtos(kh_controller.maxs));
 954         dprint("\n");
 955         */
 956 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 957         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 958         kh_key_carried = kh_controller.modelindex;
 959 #else
 960         kh_key_carried = kh_key_dropped;
 961 #endif
 962
 963         kh_controller.model = "";
 964         kh_controller.modelindex = 0;
 965
 966         addstat(STAT_KH_KEYS, AS_INT, kh_state);
 967
 968         ScoreRules_kh(kh_teams);
 969 }
 970
 971 void kh_finalize()
 972 {
 973         // to be called before intermission
 974         kh_FinishRound();
 975         remove(kh_controller);
 976         kh_controller = world;
 977 }
 978
 979 void kh_update_state()
 980 {
 981         entity player;
 982         entity key;
 983         float s;
 984         float f;
 985
 986         s = 0;
 987         FOR_EACH_KH_KEY(key)
 988         {
 989                 if(key.owner)
 990                         f = key.team;
 991                 else
 992                         f = 30;
 993                 s |= pow(32, key.count) * f;
 994         }
 995
 996         FOR_EACH_CLIENT(player)
 997         {
 998                 player.kh_state = s;
 999         }
1000
1001         FOR_EACH_KH_KEY(key)
1002         {
1003                 if(key.owner)
1004                         key.owner.kh_state |= pow(32, key.count) * 31;
1005         }
1006         //print(ftos((nextent(world)).kh_state), "\n");
1007 }