data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = kh_worldkeylist; v; v = v.kh_worldkeynext )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25
  26 // kh_state
  27 //     bits 0-7: player's key status
  28 //     bits 8-15: general key status
  29 .float kh_state;
  30 .float siren_time;  //  time delay the siren
  31 //.float stuff_time;  //  time delay to stuffcmd a cvar
  32
  33 float test[17] = {0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0};
  34 //test[0] = status of dropped keys, test[1 - 16] = player #
  35 //replace 17 with cvar("maxplayers") or similar !!!!!!!!!
  36 //for(i = 0; i < maxplayers; ++i)
  37 //      test[i] = "0";
  38
  39 float kh_Team_ByID(float t)
  40 {
  41         if(t == 0) return COLOR_TEAM1;
  42         if(t == 1) return COLOR_TEAM2;
  43         if(t == 2) return COLOR_TEAM3;
  44         if(t == 3) return COLOR_TEAM4;
  45         return 0;
  46 }
  47
  48 entity kh_worldkeylist;
  49 .entity kh_worldkeynext;
  50 entity kh_controller;
  51 float kh_tracking_enabled;
  52 float kh_teams;
  53 float kh_interferemsg_time, kh_interferemsg_team;
  54 .entity kh_next, kh_prev; // linked list
  55 .float kh_droptime;
  56 .float kh_dropperteam;
  57 .entity kh_previous_owner;
  58 .float kh_previous_owner_playerid;
  59
  60 string kh_sound_capture = "sound/kh/capture.wav";
  61 string kh_sound_destroy = "sound/kh/destroy.wav";
  62 string kh_sound_drop = "sound/kh/drop.wav";
  63 string kh_sound_collect = "sound/kh/collect.wav";
  64 string kh_sound_alarm = "sound/kh/alarm.wav";  // the new siren/alarm
  65
  66 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  67 float kh_key_dropped, kh_key_carried;
  68
  69 float kh_GetCarrierSprite(float t, float e)  // runs all the time
  70 {
  71         if(t == e)           return kh_sprite_friend;
  72         if(t == COLOR_TEAM1) return kh_sprite_red;
  73         if(t == COLOR_TEAM2) return kh_sprite_blue;
  74         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  75         if(t == COLOR_TEAM4) return kh_sprite_pink;
  76         return 0;
  77 }
  78
  79 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)  // runs occasionaly
  80 {
  81         kh_Controller_Thinkfunc = func;
  82         kh_controller.cnt = t;
  83         if(kh_Controller_Waitmsg != "")
  84                 strunzone(kh_Controller_Waitmsg);
  85         if(msg == "")
  86                 kh_Controller_Waitmsg = "";
  87         else
  88                 kh_Controller_Waitmsg = strzone(msg);
  89         if(t == 0)
  90                 kh_controller.nextthink = time; // force
  91 }
  92
  93 void kh_Controller_Think()  // called a lot
  94 {
  95         entity e;
  96         if(intermission_running)
  97                 return;
  98         if(self.cnt > 0)
  99         {
 100                 if(kh_Controller_Waitmsg != "")
 101                 {
 102                         string s;
 103                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
 104                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
 105                         else
 106                                 s = kh_Controller_Waitmsg;
 107
 108                         //dprint(s, "\n");
 109
 110                         FOR_EACH_PLAYER(e)
 111                                 if(clienttype(e) == CLIENTTYPE_REAL)
 112                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
 113                 }
 114                 self.cnt -= 1;
 115         }
 116         else if(self.cnt == 0)
 117         {
 118                 self.cnt -= 1;
 119                 kh_Controller_Thinkfunc();
 120         }
 121         self.nextthink = time + 1;
 122 }
 123
 124 // frags f: take from cvar * f
 125 // frags 0: no frags
 126 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 127 {
 128         string s;
 129         if(intermission_running)
 130                 return;
 131         if(frags_player)
 132                 UpdateFrags(player, frags_player);
 133         if(key && key.owner && frags_owner)
 134                 UpdateFrags(key.owner, frags_owner);
 135         if(!cvar("sv_eventlog"))  //output extra info to the console or text file
 136                 return;
 137         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 138         s = strcat(s, ":", ftos(frags_player));
 139         if(key && key.owner)
 140                 s = strcat(s, ":", ftos(key.owner.playerid));
 141         else
 142                 s = strcat(s, ":0");
 143         s = strcat(s, ":", ftos(frags_owner), ":");
 144         if(key)
 145                 s = strcat(s, key.netname);
 146         GameLogEcho(s);
 147 }
 148
 149 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 150 {
 151         if(e.tag_entity)
 152         {
 153                 makevectors(e.tag_entity.angles);
 154                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 155         }
 156         else
 157                 return e.origin;
 158 }
 159
 160 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 161 {
 162 #ifdef KH_PLAYER_USE_ATTACHMENT
 163         entity first;
 164         first = key.owner.kh_next;
 165         if(key == first)
 166         {
 167                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 168                 if(key.kh_next)
 169                 {
 170                         setattachment(key.kh_next, key, "");
 171                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 172                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 173                         key.kh_next.angles = '0 0 0';
 174                 }
 175                 else
 176                         setorigin(key, KH_PLAYER_ATTACHMENT);
 177                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 178         }
 179         else
 180         {
 181                 setattachment(key, key.kh_prev, "");
 182                 if(key.kh_next)
 183                         setattachment(key.kh_next, key, "");
 184                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 185                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 186                 key.angles = '0 0 0';
 187         }
 188 #else
 189         setattachment(key, key.owner, "");
 190         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 191         key.angles_y -= key.owner.angles_y;
 192 #endif
 193         key.flags = 0;
 194         key.solid = SOLID_NOT;
 195         key.movetype = MOVETYPE_NONE;
 196         key.team = key.owner.team;
 197         key.nextthink = time;
 198         key.damageforcescale = 0;
 199         key.modelindex = kh_key_carried;
 200 }
 201
 202 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 203 {
 204         float i;
 205         i = test[key.owner.playerid];
 206                 if(key.netname == "^1red key")
 207                         i -= 1;
 208                 if(key.netname == "^4blue key")
 209                         i -= 2;
 210                 if(key.netname == "^3yellow key")
 211                         i -= 4;
 212                 if(key.netname == "^6pink key")
 213                         i -= 8;
 214         test[key.owner.playerid] = i;
 215
 216         kh_show_temp();
 217         if(key.owner)
 218                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 219         //key.owner.kh_state += test[key.owner.playerid];
 220
 221 #ifdef KH_PLAYER_USE_ATTACHMENT
 222         entity first;
 223         first = key.owner.kh_next;
 224         if(key == first)
 225         {
 226                 if(key.kh_next)
 227                 {
 228                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 229                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 230                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 231                 }
 232         }
 233         else
 234         {
 235                 if(key.kh_next)
 236                         setattachment(key.kh_next, key.kh_prev, "");
 237                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 238         }
 239         // in any case:
 240         setattachment(key, world, "");
 241         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 242         key.angles = key.owner.angles;
 243 #else
 244         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 245         setattachment(key, world, "");
 246         key.angles_y += key.owner.angles_y;
 247 #endif
 248         key.flags = FL_ITEM;
 249         key.solid = SOLID_TRIGGER;
 250         key.movetype = MOVETYPE_TOSS;
 251         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 252         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 253         // let key.team stay
 254         key.modelindex = kh_key_dropped;
 255         key.kh_previous_owner = key.owner;
 256         key.kh_previous_owner_playerid = key.owner.playerid;
 257 }
 258
 259 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 260 {
 261         if(key.owner == player)
 262                 return;
 263
 264         if(key.owner)
 265         {
 266                 kh_Key_Detach(key);
 267
 268                 // remove from linked list
 269                 if(key.kh_next)
 270                         key.kh_next.kh_prev = key.kh_prev;
 271                 key.kh_prev.kh_next = key.kh_next;
 272                 key.kh_next = world;
 273                 key.kh_prev = world;
 274
 275                 if(key.owner.kh_next == world)
 276                 {
 277                         // No longer a key carrier
 278                         WaypointSprite_DetachCarrier(key.owner);
 279                 }
 280         }
 281
 282         key.owner = player;
 283
 284         if(player)
 285         {
 286                 // insert into linked list
 287                 key.kh_next = player.kh_next;
 288                 key.kh_prev = player;
 289                 player.kh_next = key;
 290                 if(key.kh_next)
 291                         key.kh_next.kh_prev = key;
 292
 293                 float i;
 294                 i = test[key.owner.playerid];
 295                         if(key.netname == "^1red key")
 296                                 i += 1;
 297                         if(key.netname == "^4blue key")
 298                                 i += 2;
 299                         if(key.netname == "^3yellow key")
 300                                 i += 4;
 301                         if(key.netname == "^6pink key")
 302                                 i += 8;
 303                 test[key.owner.playerid] = i;
 304
 305                 kh_Key_Attach(key);
 306
 307                 if(key.kh_next == world)
 308                 {
 309                         // player is now a key carrier
 310                         WaypointSprite_AttachCarrier("", player);
 311                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 312                         player.waypointsprite_attachedforcarrier.team = player.team;
 313                 }
 314         }
 315
 316         // moved that here, also update if there's no player
 317         kh_show_temp();
 318         if(key.owner)
 319                 key.owner.kh_state = (key.owner.kh_state | 255) - 255 + test[key.owner.playerid];
 320
 321         key.pusher = world;
 322 }
 323
 324 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 325 {
 326         if(self.owner)
 327                 return;
 328         if(vlen(force) <= 0)
 329                 return;
 330         if(time > self.pushltime)
 331                 if(attacker.classname == "player")
 332                         self.team = attacker.team;
 333 }
 334
 335 void kh_Key_Spawn(entity initial_owner, float angle)  // runs every time a new flag is created, ie after all the keys have been collected
 336 {
 337         entity key;
 338         key = spawn();
 339         key.classname = STR_ITEM_KH_KEY;
 340         key.touch = kh_Key_Touch;
 341         key.think = kh_Key_Think;
 342         key.nextthink = time;
 343         key.items = IT_KEY1 | IT_KEY2;
 344         key.cnt = angle;
 345         key.angles = '0 360 0' * random();
 346         key.event_damage = kh_Key_Damage;
 347         key.takedamage = DAMAGE_YES;
 348         key.modelindex = kh_key_dropped;
 349         key.model = "key";
 350         key.kh_dropperteam = 0;
 351         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 352         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 353         key.colormod = TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 354
 355         switch(initial_owner.team)
 356         {
 357                 case COLOR_TEAM1:
 358                         key.netname = "^1red key";
 359                         break;
 360                 case COLOR_TEAM2:
 361                         key.netname = "^4blue key";
 362                         break;
 363                 case COLOR_TEAM3:
 364                         key.netname = "^3yellow key";
 365                         break;
 366                 case COLOR_TEAM4:
 367                         key.netname = "^6pink key";
 368                         break;
 369                 default:
 370                         key.netname = "NETGIER key";
 371                         break;
 372         }
 373
 374         // link into key list
 375         key.kh_worldkeynext = kh_worldkeylist;
 376         kh_worldkeylist = key;
 377
 378         centerprint(initial_owner, strcat("You are starting with the ", key.netname, "\n"));  // message to player at start of round
 379
 380         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 381         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 382
 383         kh_Key_AssignTo(key, initial_owner);
 384 }
 385
 386 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 387 {
 388         entity o;
 389         o = key.owner;
 390         kh_Key_AssignTo(key, world);
 391         if(o) // it was attached
 392                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 393         else // it was dropped
 394                 WaypointSprite_DetachCarrier(key);
 395
 396         // remove key from key list
 397         if (kh_worldkeylist == key)
 398                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 399         else
 400         {
 401                 o = kh_worldkeylist;
 402                 while (o)
 403                 {
 404                         if (o.kh_worldkeynext == key)
 405                         {
 406                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 407                                 break;
 408                         }
 409                         o = o.kh_worldkeynext;
 410                 }
 411         }
 412
 413         remove(key);
 414 }
 415
 416 // -1 when no team completely owns all keys yet
 417 float kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 418 {
 419         entity key;
 420         float teem;
 421
 422         teem = -1;
 423         FOR_EACH_KH_KEY(key)
 424         {
 425                 if(!key.owner)
 426                         return -1;
 427                 if(teem == -1)
 428                         teem = key.team;
 429                 else if(teem != key.team)
 430                         return -1;
 431         }
 432         return teem;
 433 }
 434
 435 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 436 {
 437         sound(player, CHAN_AUTO, kh_sound_collect, VOL_BASE, ATTN_NORM);
 438
 439         if(key.kh_dropperteam != player.team)
 440         {
 441                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 442                 PlayerScore_Add(player, SP_KH_PICKUPS, 1);
 443         }
 444         key.kh_dropperteam = 0;
 445         bprint(player.netname, "^7 picked up the ", key.netname, "\n");
 446
 447         kh_Key_AssignTo(key, player); // this also updates .kh_state
 448
 449         if(kh_Key_AllOwnedByWhichTeam() != -1)
 450         {
 451                 kh_interferemsg_time = time + 0.2;
 452                 kh_interferemsg_team = player.team;
 453         }
 454 }
 455
 456 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 457 {
 458         entity key;
 459         entity mypusher;
 460         if(player.kh_next)
 461         {
 462                 mypusher = world;
 463                 if(player.pusher)
 464                         if(time < player.pushltime)
 465                                 mypusher = player.pusher;
 466                 while((key = player.kh_next))
 467                 {
 468                         kh_Scores_Event(player, key, "losekey", 0, 0);
 469                         PlayerScore_Add(player, SP_KH_LOSSES, 1);
 470                         bprint(player.netname, "^7 died and lost the ", key.netname, "\n");
 471                         kh_Key_AssignTo(key, world);
 472                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 473                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 474                         key.pusher = mypusher;
 475                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 476                         if(suicide)
 477                                 key.kh_dropperteam = player.team;
 478                 }
 479                 sound(player, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 480         }
 481 }
 482
 483 void kh_Key_Touch()  // runs many, many times when a key has been dropped and can be picked up
 484 {
 485         if(intermission_running)
 486                 return;
 487
 488         if(self.owner) // already carried
 489                 return;
 490         if(other.classname != "player")
 491                 return;
 492         if(other.deadflag != DEAD_NO)
 493                 return;
 494         if(other == self.enemy)
 495                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 496                         return;  // you just dropped it!
 497         kh_Key_Collect(self, other);
 498 }
 499
 500 void kh_Key_Think()  // runs all the time
 501 {
 502         entity head;
 503         //entity player;  // needed by FOR_EACH_PLAYER
 504
 505         if(intermission_running)
 506                 return;
 507         /*
 508         if(time > self.stuff_time)
 509         {
 510                 FOR_EACH_PLAYER(player)
 511                         player.kh_state = test[0]*256 + (player.kh_state&255);
 512
 513                 self.stuff_time = time + 1;  // repeat in 1 second
 514         }
 515         */
 516
 517 #ifdef KH_KEY_ATTACHMENT_DEBUG
 518         if(self.kh_prev == self.owner)
 519         {
 520                 if(cvar_string("_angles") != "")
 521                 {
 522                         self.angles = stov(cvar_string("_angles"));
 523                         self.origin = stov(cvar_string("_origin"));
 524                 }
 525         }
 526 #endif
 527
 528         if(self.owner)
 529         {
 530 #ifndef KH_PLAYER_USE_ATTACHMENT
 531                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 532                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 533 #endif
 534
 535                 if(self.owner.BUTTON_USE)
 536                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 537                 {
 538                         self.owner.kh_droptime = time;
 539                         self.kh_droptime = time;  // prevent collecting this one for some time
 540                         self.enemy = self.owner;
 541                         self.pusher = world;
 542                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 543                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 544                         sound(self.owner, CHAN_AUTO, kh_sound_drop, VOL_BASE, ATTN_NORM);
 545                         makevectors(self.owner.v_angle);
 546                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 547                         kh_Key_AssignTo(self, world);
 548                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 549                         self.kh_dropperteam = self.team;
 550                 }
 551         }
 552
 553         // if in nodrop or time over, end the round
 554         if(!self.owner)
 555                 if(time > self.pain_finished)
 556                         kh_LoserTeam(self.team, self);
 557
 558         if(self.owner)
 559         if(kh_Key_AllOwnedByWhichTeam() != -1)
 560         {
 561                 if(self.siren_time < time)
 562                 {
 563                         sound(self.owner, CHAN_AUTO, kh_sound_alarm, VOL_BASE, ATTN_NORM);  // play a simple alarm
 564                         self.siren_time = time + 2.5;  // repeat every 2.5 seconds
 565                 }
 566
 567                 entity key;
 568                 vector p;
 569                 p = self.owner.origin;
 570                 FOR_EACH_KH_KEY(key)
 571                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 572                                 goto not_winning;
 573                 kh_WinnerTeam(self.team);
 574 :not_winning
 575         }
 576
 577         if(kh_interferemsg_time && time > kh_interferemsg_time)
 578         {
 579                 kh_interferemsg_time = 0;
 580                 FOR_EACH_PLAYER(head)
 581                 {
 582                         if(head.team == kh_interferemsg_team)
 583                                 if(head.kh_next)
 584                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 585                                 else
 586                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 587                         else
 588                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 589                 }
 590         }
 591
 592         self.nextthink = time + 0.05;
 593 }
 594
 595 void kh_WinnerTeam(float teem)  // runs when a team wins
 596 {
 597         // all key carriers get some points
 598         vector firstorigin, lastorigin, midpoint;
 599         float first;
 600         entity key;
 601         float score;
 602         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 603         DistributeEvenly_Init(score, kh_teams);
 604         // twice the score for 3 team games, three times the score for 4 team games!
 605         // note: for a win by destroying the key, this should NOT be applied
 606         FOR_EACH_KH_KEY(key)
 607         {
 608                 float f;
 609                 f = DistributeEvenly_Get(1);
 610                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 611                 PlayerTeamScore_Add(key.owner, SP_KH_CAPS, ST_KH_CAPS, 1);
 612         }
 613
 614         first = TRUE;
 615         FOR_EACH_KH_KEY(key)
 616                 if(key.owner.kh_next == key)
 617                 {
 618                         if(!first)
 619                                 bprint("^7, ");
 620                         bprint(key.owner.netname);
 621                         first = FALSE;
 622                 }
 623         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 624
 625         first = TRUE;
 626         midpoint = '0 0 0';
 627         FOR_EACH_KH_KEY(key)
 628         {
 629                 vector thisorigin;
 630
 631                 thisorigin = kh_AttachedOrigin(key);
 632                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 633                 midpoint += thisorigin;
 634
 635                 if(!first)
 636                         te_lightning2(world, lastorigin, thisorigin);
 637                 lastorigin = thisorigin;
 638                 if(first)
 639                         firstorigin = thisorigin;
 640                 first = FALSE;
 641         }
 642         if(kh_teams > 2)
 643         {
 644                 te_lightning2(world, lastorigin, firstorigin);
 645         }
 646         midpoint = midpoint * (1 / kh_teams);
 647         te_customflash(midpoint, 1000, 1, TeamColor(teem) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 648
 649         play2all(kh_sound_capture);
 650         kh_FinishRound();
 651 }
 652
 653 void kh_LoserTeam(float teem, entity lostkey)  // runs when a player pushes a flag carrier off the map
 654 {
 655         entity player, key, attacker;
 656         float players;
 657         float keys;
 658         float f;
 659
 660         attacker = world;
 661         if(lostkey.pusher)
 662                 if(lostkey.pusher.team != teem)
 663                         if(lostkey.pusher.classname == "player")
 664                                 attacker = lostkey.pusher;
 665
 666         players = keys = 0;
 667
 668         if(attacker)
 669         {
 670                 if(lostkey.kh_previous_owner)
 671                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 672                         // don't actually GIVE him the -nn points, just log
 673                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 674                 PlayerScore_Add(attacker, SP_KH_PUSHES, 1);
 675                 centerprint(attacker, "Your push is the best!\n\n\n");
 676                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 677         }
 678         else
 679         {
 680                 float of, fragsleft, i, j, thisteam;
 681                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 682
 683                 FOR_EACH_PLAYER(player)
 684                         if(player.team != teem)
 685                                 ++players;
 686
 687                 FOR_EACH_KH_KEY(key)
 688                         if(key.owner && key.team != teem)
 689                                 ++keys;
 690
 691                 if(lostkey.kh_previous_owner)
 692                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 693                         // don't actually GIVE him the -nn points, just log
 694
 695                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 696                         PlayerScore_Add(lostkey.kh_previous_owner, SP_KH_DESTROYS, 1);
 697
 698                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 699
 700                 FOR_EACH_KH_KEY(key)
 701                         if(key.owner && key.team != teem)
 702                         {
 703                                 f = DistributeEvenly_Get(of);
 704                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", f, 0);
 705                         }
 706
 707                 fragsleft = DistributeEvenly_Get(players);
 708
 709                 // Now distribute these among all other teams...
 710                 j = kh_teams - 1;
 711                 for(i = 0; i < kh_teams; ++i)
 712                 {
 713                         thisteam = kh_Team_ByID(i);
 714                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 715                                 continue;
 716
 717                         players = 0;
 718                         FOR_EACH_PLAYER(player)
 719                                 if(player.team == thisteam)
 720                                         ++players;
 721
 722                         DistributeEvenly_Init(fragsleft, j);
 723                         fragsleft = DistributeEvenly_Get(j - 1);
 724                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 725
 726                         FOR_EACH_PLAYER(player)
 727                                 if(player.team == thisteam)
 728                                 {
 729                                         f = DistributeEvenly_Get(1);
 730                                         kh_Scores_Event(player, world, "destroyed", f, 0);
 731                                 }
 732
 733                         --j;
 734                 }
 735
 736                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 737         }
 738         play2all(kh_sound_destroy);
 739         te_tarexplosion(lostkey.origin);
 740
 741         kh_FinishRound();
 742 }
 743
 744 void kh_FinishRound()  // runs when a team captures the keys
 745 {
 746         // prepare next round
 747         kh_interferemsg_time = 0;
 748         entity key;
 749         FOR_EACH_KH_KEY(key)
 750                 kh_Key_Remove(key);
 751
 752         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 753 }
 754
 755 string kh_CheckEnoughPlayers()  // checks enough player are present, runs after every completed round
 756 {
 757         float i, players, teem;
 758         entity player;
 759         string result;
 760         result = "";
 761
 762         // find a random player per team
 763         for(i = 0; i < kh_teams; ++i)
 764         {
 765                 teem = kh_Team_ByID(i);
 766                 players = 0;
 767                 FOR_EACH_PLAYER(player)
 768                         if(player.deadflag == DEAD_NO)
 769                                 if(!player.BUTTON_CHAT)
 770                                         if(player.team == teem)
 771                                                 ++players;
 772                 if(players == 0)
 773                 {
 774                         if(result != "")
 775                                 result = strcat(result, ", ");
 776                         result = strcat(result, ColoredTeamName(teem));
 777                 }
 778         }
 779         return result;
 780 }
 781
 782 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 783 {
 784         string teams_missing;
 785         teams_missing = kh_CheckEnoughPlayers();
 786         if(teams_missing == "")
 787                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 788         else
 789                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 790 }
 791
 792 void kh_StartRound()  // runs at the start of each round
 793 {
 794         string teams_missing;
 795         float i, players, teem;
 796         entity player;
 797
 798         teams_missing = kh_CheckEnoughPlayers();
 799         if(teams_missing != "")
 800         {
 801                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 802                 return;
 803         }
 804
 805         FOR_EACH_PLAYER(player)
 806                 if(clienttype(player) == CLIENTTYPE_REAL)
 807                         centerprint_expire(player, CENTERPRIO_SPAM);
 808
 809         for(i = 0; i < kh_teams; ++i)
 810         {
 811                 teem = kh_Team_ByID(i);
 812                 players = 0;
 813                 entity my_player;
 814                 FOR_EACH_PLAYER(player)
 815                         if(player.deadflag == DEAD_NO)
 816                                 if(!player.BUTTON_CHAT)
 817                                         if(player.team == teem)
 818                                         {
 819                                                 ++players;
 820                                                 if(random() * players <= 1)
 821                                                         my_player = player;
 822                                         }
 823                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 824                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 825                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 826         }
 827
 828         kh_tracking_enabled = FALSE;
 829         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 830 }
 831
 832 void kh_setstatus()  // runs all the time
 833 {
 834         if(kh_teams)
 835         {
 836                 float kh_KEY;
 837                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST);  // the one impossible combination
 838                 if(self.kh_next)
 839                         self.items = self.items | kh_KEY;
 840                 else
 841                         self.items = self.items - (self.items & kh_KEY);
 842         }
 843 }
 844
 845 void kh_EnableTrackingDevice()  // runs after each round
 846 {
 847         entity player;
 848
 849         FOR_EACH_PLAYER(player)
 850                 if(clienttype(player) == CLIENTTYPE_REAL)
 851                         centerprint_expire(player, CENTERPRIO_SPAM);
 852
 853         kh_tracking_enabled = TRUE;
 854 }
 855
 856 float kh_Key_waypointsprite_for_player(entity e) // ??
 857 {
 858         if(!kh_tracking_enabled)
 859                 return 0;
 860         if(!self.owner)
 861                 return kh_sprite_dropped;
 862         if(!self.owner.owner)
 863                 return kh_sprite_dropped;
 864         return 0;  // draw only when key is not owned
 865 }
 866
 867 float kh_KeyCarrier_waypointsprite_for_player(entity e)  // runs all the time
 868 {
 869         if(e.classname != "player" || self.team != e.team)
 870                 if(!kh_tracking_enabled)
 871                         return 0;
 872
 873         // e is spectator? That's no team mate...
 874         if(e.classname != "player")
 875                 return kh_GetCarrierSprite(self.team, -1);
 876
 877         // e is no key carrier: simple case...
 878         if(!e.kh_next)
 879                 return kh_GetCarrierSprite(self.team, e.team);
 880
 881         // e is a key carrier: if any key is dropped or owned by another team, show
 882         // the carrier sprite; otherwise show run here
 883         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 884                 return kh_sprite_finish;
 885
 886         return kh_GetCarrierSprite(self.team, e.team);
 887 }
 888
 889 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 890 {
 891         if(attacker == targ)
 892                 return f;
 893
 894         if(targ.kh_next)
 895         {
 896                 if(attacker.team == targ.team)
 897                 {
 898                         entity k;
 899                         float nk;
 900                         nk = 0;
 901                         for(k = targ.kh_next; k != world; k = k.kh_next)
 902                                 ++nk;
 903                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 904                 }
 905                 else
 906                 {
 907                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 908                         PlayerScore_Add(attacker, SP_KH_KCKILLS, 1);
 909                         // the frag gets added later
 910                 }
 911         }
 912
 913         return f;
 914 }
 915
 916 void kh_init()  // sets up th KH environment
 917 {
 918         precache_sound(kh_sound_capture);
 919         precache_sound(kh_sound_destroy);
 920         precache_sound(kh_sound_drop);
 921         precache_sound(kh_sound_collect);
 922         precache_sound(kh_sound_alarm);  // the new siren
 923
 924         precache_model("models/sprites/key-dropped.sp2");
 925         precache_model("models/sprites/keycarrier-finish.sp2");
 926         precache_model("models/sprites/keycarrier-friend.sp2");
 927         precache_model("models/sprites/keycarrier-red.sp2");
 928         precache_model("models/sprites/keycarrier-blue.sp2");
 929         precache_model("models/sprites/keycarrier-yellow.sp2");
 930         precache_model("models/sprites/keycarrier-pink.sp2");
 931 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 932         precache_model("models/keyhunt/key-carried.md3");
 933 #endif
 934         precache_model("models/keyhunt/key.md3");
 935
 936         // setup variables
 937         kh_teams = cvar("g_keyhunt_teams_override");
 938         if(kh_teams < 2)
 939                 kh_teams = cvar("g_keyhunt_teams");
 940         kh_teams = bound(2, kh_teams, 4);
 941
 942         // make a KH entity for controlling the game
 943         kh_controller = spawn();
 944         kh_controller.think = kh_Controller_Think;
 945         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 946
 947         setmodel(kh_controller, "models/keyhunt/key.md3");
 948         kh_key_dropped = kh_controller.modelindex;
 949         /*
 950         dprint(vtos(kh_controller.mins));
 951         dprint(vtos(kh_controller.maxs));
 952         dprint("\n");
 953         */
 954 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 955         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 956         kh_key_carried = kh_controller.modelindex;
 957 #else
 958         kh_key_carried = kh_key_dropped;
 959 #endif
 960         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 961         kh_sprite_dropped = kh_controller.modelindex;
 962         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 963         kh_sprite_finish = kh_controller.modelindex;
 964         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 965         kh_sprite_friend = kh_controller.modelindex;
 966         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 967         kh_sprite_red = kh_controller.modelindex;
 968         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 969         kh_sprite_blue = kh_controller.modelindex;
 970         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 971         kh_sprite_pink = kh_controller.modelindex;
 972         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 973         kh_sprite_yellow = kh_controller.modelindex;
 974         setmodel(kh_controller, "");
 975
 976         addstat(STAT_KH_KEYS, AS_INT, kh_state);
 977
 978         ScoreRules_kh(kh_teams);
 979 }
 980
 981 void kh_finalize()
 982 {
 983         // to be called before intermission
 984         kh_FinishRound();
 985         remove(kh_controller);
 986         kh_controller = world;
 987 }
 988
 989 /**
 990  * kh_show_temp originally by victim.
 991  * changed it to use the kh_state stat var
 992  * Updates the general key stat bits for each player
 993  */
 994 void kh_show_temp()
 995 {
 996         entity player;
 997         float i, j;
 998
 999         j = 0;  // reset/blank j
1000         for(i=1; i<17; ++i)  // replace 17 with cvar("maxplayers"); !!!!!!!!!
1001                 j += test[i];
1002
1003         test[0] = j;
1004
1005         j *= 256;
1006         FOR_EACH_PLAYER(player)
1007                 player.kh_state = j + (player.kh_state & 255); // update the general key bits
1008 }