data/qcsrc/server/keyhunt.qc

   1 #define FOR_EACH_KH_KEY(v) for(v = world; (v = find(v, classname, STR_ITEM_KH_KEY)); )
   2
   3 // #define KH_PLAYER_USE_ATTACHMENT
   4 // #define KH_PLAYER_USE_CARRIEDMODEL
   5 // #define KH_KEY_ATTACHMENT_DEBUG
   6
   7 #ifdef KH_PLAYER_USE_ATTACHMENT
   8 vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
   9 vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  10 vector KH_PLAYER_ATTACHMENT = '0 0 0';
  11 vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  12 string KH_PLAYER_ATTACHMENT_BONE = "";
  13 #else
  14 float KH_KEY_ZSHIFT = 22;
  15 float KH_KEY_XYDIST = 24;
  16 float KH_KEY_XYSPEED = 45;
  17 #endif
  18 float KH_KEY_WP_ZSHIFT = 20;
  19
  20 vector KH_KEY_MIN = '-10 -10 -46';
  21 vector KH_KEY_MAX = '10 10 3';
  22 float KH_KEY_BRIGHTNESS = 2;
  23
  24 string kh_Controller_Waitmsg;
  25
  26 float kh_Team_ByID(float t)
  27 {
  28         if(t == 0) return COLOR_TEAM1;
  29         if(t == 1) return COLOR_TEAM2;
  30         if(t == 2) return COLOR_TEAM3;
  31         if(t == 3) return COLOR_TEAM4;
  32         return 0;
  33 }
  34
  35 entity kh_controller;
  36 float kh_tracking_enabled;
  37 float kh_teams;
  38 float kh_interferemsg_time, kh_interferemsg_team;
  39 .entity kh_next, kh_prev; // linked list
  40 .float kh_droptime;
  41 .float kh_dropperteam;
  42 .entity kh_previous_owner;
  43
  44 string kh_sound_capture = "sound/kh/capture.wav";
  45 string kh_sound_destroy = "sound/kh/destroy.wav";
  46 string kh_sound_drop = "sound/kh/drop.wav";
  47 string kh_sound_collect = "sound/kh/collect.wav";
  48
  49 float kh_sprite_dropped, kh_sprite_finish, kh_sprite_red, kh_sprite_blue, kh_sprite_pink, kh_sprite_yellow, kh_sprite_friend;
  50 float kh_key_dropped, kh_key_carried;
  51
  52 float kh_GetCarrierSprite(float t, float e)
  53 {
  54         if(t == e)           return kh_sprite_friend;
  55         if(t == COLOR_TEAM1) return kh_sprite_red;
  56         if(t == COLOR_TEAM2) return kh_sprite_blue;
  57         if(t == COLOR_TEAM3) return kh_sprite_yellow;
  58         if(t == COLOR_TEAM4) return kh_sprite_pink;
  59         return 0;
  60 }
  61
  62 void kh_Controller_SetThink(float t, string msg, kh_Think_t func)
  63 {
  64         kh_Controller_Thinkfunc = func;
  65         kh_controller.cnt = t;
  66         if(kh_Controller_Waitmsg != "")
  67                 strunzone(kh_Controller_Waitmsg);
  68         if(msg == "")
  69                 kh_Controller_Waitmsg = "";
  70         else
  71                 kh_Controller_Waitmsg = strzone(msg);
  72         if(t == 0)
  73                 kh_controller.nextthink = time; // force
  74 }
  75
  76 void kh_Controller_Think()
  77 {
  78         entity e;
  79         if(intermission_running)
  80                 return;
  81         if(self.cnt > 0)
  82         {
  83                 if(kh_Controller_Waitmsg != "")
  84                 {
  85                         string s;
  86                         if(substring(kh_Controller_Waitmsg, strlen(kh_Controller_Waitmsg)-1, 1) == " ")
  87                                 s = strcat(kh_Controller_Waitmsg, ftos(self.cnt));
  88                         else
  89                                 s = kh_Controller_Waitmsg;
  90
  91                         //dprint(s, "\n");
  92
  93                         FOR_EACH_PLAYER(e)
  94                                 if(clienttype(e) == CLIENTTYPE_REAL)
  95                                         centerprint_atprio(e, CENTERPRIO_SPAM, s);
  96                 }
  97                 self.cnt -= 1;
  98         }
  99         else if(self.cnt == 0)
 100         {
 101                 self.cnt -= 1;
 102                 kh_Controller_Thinkfunc();
 103         }
 104         self.nextthink = time + 1;
 105 }
 106
 107 // frags f: take from cvar * f
 108 // frags 0: no frags
 109 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)
 110 {
 111         string s;
 112         if(intermission_running)
 113                 return;
 114         if(frags_player)
 115                 UpdateFrags(player, frags_player);
 116         if(key && key.owner && frags_owner)
 117                 UpdateFrags(key.owner, frags_owner);
 118         if(!cvar("sv_eventlog"))
 119                 return;
 120         s = strcat(":keyhunt:", what, ":", ftos(player.playerid));
 121         s = strcat(s, ":", ftos(frags_player));
 122         if(key && key.owner)
 123                 s = strcat(s, ":", ftos(key.owner.playerid));
 124         else
 125                 s = strcat(s, ":0");
 126         s = strcat(s, ":", ftos(frags_owner), ":");
 127         if(key)
 128                 s = strcat(s, key.netname);
 129         GameLogEcho(s, FALSE);
 130 }
 131
 132 vector kh_AttachedOrigin(entity e)
 133 {
 134         if(e.tag_entity)
 135         {
 136                 makevectors(e.tag_entity.angles);
 137                 return e.tag_entity.origin + e.origin_x * v_forward - e.origin_y * v_right + e.origin_z * v_up;
 138         }
 139         else
 140                 return e.origin;
 141 }
 142
 143 void kh_Key_Attach(entity key)
 144 {
 145 #ifdef KH_PLAYER_USE_ATTACHMENT
 146         entity first;
 147         first = key.owner.kh_next;
 148         if(key == first)
 149         {
 150                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 151                 if(key.kh_next)
 152                 {
 153                         setattachment(key.kh_next, key, "");
 154                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 155                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 156                         key.kh_next.angles = '0 0 0';
 157                 }
 158                 else
 159                         setorigin(key, KH_PLAYER_ATTACHMENT);
 160                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 161         }
 162         else
 163         {
 164                 setattachment(key, key.kh_prev, "");
 165                 if(key.kh_next)
 166                         setattachment(key.kh_next, key, "");
 167                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 168                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 169                 key.angles = '0 0 0';
 170         }
 171 #else
 172         setattachment(key, key.owner, "");
 173         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT); // fixing x, y in think
 174         key.angles_y -= key.owner.angles_y;
 175 #endif
 176         key.flags = 0;
 177         key.solid = SOLID_NOT;
 178         key.movetype = MOVETYPE_NONE;
 179         key.team = key.owner.team;
 180         key.nextthink = time;
 181         key.damageforcescale = 0;
 182         key.modelindex = kh_key_carried;
 183 }
 184
 185 void kh_Key_Detach(entity key)
 186 {
 187 #ifdef KH_PLAYER_USE_ATTACHMENT
 188         entity first;
 189         first = key.owner.kh_next;
 190         if(key == first)
 191         {
 192                 if(key.kh_next)
 193                 {
 194                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 195                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 196                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 197                 }
 198         }
 199         else
 200         {
 201                 if(key.kh_next)
 202                         setattachment(key.kh_next, key.kh_prev, "");
 203                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 204         }
 205         // in any case:
 206         setattachment(key, world, "");
 207         setorigin(key, key.owner.origin + '0 0 1' * (PL_MIN_z - KH_KEY_MIN_z));
 208         key.angles = key.owner.angles;
 209 #else
 210         setorigin(key, key.owner.origin + key.origin_z * '0 0 1');
 211         setattachment(key, world, "");
 212         key.angles_y += key.owner.angles_y;
 213 #endif
 214         key.aiment = world;
 215         key.flags = FL_ITEM;
 216         key.solid = SOLID_TRIGGER;
 217         key.movetype = MOVETYPE_TOSS;
 218         key.pain_finished = time + cvar("g_balance_keyhunt_delay_return");
 219         key.damageforcescale = cvar("g_balance_keyhunt_damageforcescale");
 220         // let key.team stay
 221         key.modelindex = kh_key_dropped;
 222         key.kh_previous_owner = key.owner;
 223 }
 224
 225 void kh_Key_AssignTo(entity key, entity player)
 226 {
 227         if(key.owner == player)
 228                 return;
 229
 230         if(key.owner)
 231         {
 232                 kh_Key_Detach(key);
 233
 234                 // remove from linked list
 235                 if(key.kh_next)
 236                         key.kh_next.kh_prev = key.kh_prev;
 237                 key.kh_prev.kh_next = key.kh_next;
 238                 key.kh_next = world;
 239                 key.kh_prev = world;
 240
 241                 if(key.owner.kh_next == world)
 242                 {
 243                         // No longer a key carrier
 244                         WaypointSprite_DetachCarrier(key.owner);
 245                 }
 246         }
 247
 248         key.owner = player;
 249
 250         if(player)
 251         {
 252                 // insert into linked list
 253                 key.kh_next = player.kh_next;
 254                 key.kh_prev = player;
 255                 player.kh_next = key;
 256                 if(key.kh_next)
 257                         key.kh_next.kh_prev = key;
 258
 259                 kh_Key_Attach(key);
 260
 261                 if(key.kh_next == world)
 262                 {
 263                         // player is now a key carrier
 264                         WaypointSprite_AttachCarrier("", player);
 265                         player.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_KeyCarrier_waypointsprite_for_player;
 266                         player.waypointsprite_attachedforcarrier.team = player.team;
 267                 }
 268         }
 269
 270         key.pusher = world;
 271 }
 272
 273 void kh_Key_Damage(entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 274 {
 275         if(self.owner)
 276                 return;
 277         if(vlen(force) <= 0)
 278                 return;
 279         if(time > self.pushltime)
 280                 if(attacker.classname == "player")
 281                         self.team = attacker.team;
 282 }
 283
 284 vector kh_TeamColor(float teem)
 285 {
 286         switch(teem)
 287         {
 288                 case COLOR_TEAM1:
 289                         return '1 0.0625 0.0625';
 290                 case COLOR_TEAM2:
 291                         return '0.0625 0.0625 1';
 292                 case COLOR_TEAM3:
 293                         return '1 1 0.0625';
 294                 case COLOR_TEAM4:
 295                         return '1 0.0625 1';
 296                 default:
 297                         return '1 1 1';
 298         }
 299 }
 300
 301 void kh_Key_Spawn(entity initial_owner, float angle)
 302 {
 303         entity key;
 304         key = spawn();
 305         key.classname = STR_ITEM_KH_KEY;
 306         key.touch = kh_Key_Touch;
 307         key.think = kh_Key_Think;
 308         key.nextthink = time;
 309         key.items = IT_KEY1 | IT_KEY2;
 310         key.cnt = angle;
 311         key.angles = '0 360 0' * random();
 312         key.event_damage = kh_Key_Damage;
 313         key.takedamage = DAMAGE_YES;
 314         key.modelindex = kh_key_dropped;
 315         key.model = "key";
 316         key.kh_dropperteam = 0;
 317         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 318         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 319         key.colormod = kh_TeamColor(initial_owner.team) * KH_KEY_BRIGHTNESS;
 320
 321         switch(initial_owner.team)
 322         {
 323                 case COLOR_TEAM1:
 324                         key.netname = "^1red key";
 325                         break;
 326                 case COLOR_TEAM2:
 327                         key.netname = "^4blue key";
 328                         break;
 329                 case COLOR_TEAM3:
 330                         key.netname = "^3yellow key";
 331                         break;
 332                 case COLOR_TEAM4:
 333                         key.netname = "^6pink key";
 334                         break;
 335                 default:
 336                         key.netname = "NETGIER key";
 337                         break;
 338         }
 339
 340         sprint(initial_owner, strcat("You got the ^2", key.netname, "\n"));
 341
 342         WaypointSprite_Spawn("", 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, world, key.team, key, waypointsprite_attachedforcarrier, FALSE);
 343         key.waypointsprite_attachedforcarrier.waypointsprite_for_player = kh_Key_waypointsprite_for_player;
 344
 345         kh_Key_AssignTo(key, initial_owner);
 346 }
 347
 348 void kh_Key_Remove(entity key)
 349 {
 350         entity o;
 351         o = key.owner;
 352         kh_Key_AssignTo(key, world);
 353         if(o) // it was attached
 354                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 355         else // it was dropped
 356                 WaypointSprite_DetachCarrier(key);
 357
 358         remove(key);
 359 }
 360
 361 // -1 when no team completely owns all keys yet
 362 float kh_Key_AllOwnedByWhichTeam()
 363 {
 364         entity key;
 365         float teem;
 366
 367         teem = -1;
 368         FOR_EACH_KH_KEY(key)
 369         {
 370                 if(!key.owner)
 371                         return -1;
 372                 if(teem == -1)
 373                         teem = key.team;
 374                 else if(teem != key.team)
 375                         return -1;
 376         }
 377         return teem;
 378 }
 379
 380 void kh_Key_Collect(entity key, entity player)
 381 {
 382         sound(player, CHAN_AUTO, kh_sound_collect, 1, ATTN_NORM);
 383
 384         if(key.kh_dropperteam != player.team)
 385                 kh_Scores_Event(player, key, "collect", cvar("g_balance_keyhunt_score_collect"), 0);
 386         key.kh_dropperteam = 0;
 387         bprint(player.netname, "^7 collected the ", key.netname, "\n");
 388         kh_Key_AssignTo(key, player);
 389
 390         if(kh_Key_AllOwnedByWhichTeam() != -1)
 391         {
 392                 kh_interferemsg_time = time + 0.2;
 393                 kh_interferemsg_team = player.team;
 394         }
 395 }
 396
 397 void kh_Key_DropAll(entity player, float suicide)
 398 {
 399         entity key;
 400         entity mypusher;
 401         if(player.kh_next)
 402         {
 403                 mypusher = world;
 404                 if(player.pusher)
 405                         if(time < player.pushltime)
 406                                 mypusher = player.pusher;
 407                 while((key = player.kh_next))
 408                 {
 409                         kh_Scores_Event(player, key, "losekey", 0, 0);
 410                         bprint(player.netname, "^7 lost the ", key.netname, "\n");
 411                         kh_Key_AssignTo(key, world);
 412                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 413                         key.velocity = W_CalculateProjectileVelocity(player.velocity, cvar("g_balance_keyhunt_dropvelocity") * v_forward);
 414                         key.pusher = mypusher;
 415                         key.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 416                         if(suicide)
 417                                 key.kh_dropperteam = player.team;
 418                 }
 419                 sound(player, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 420         }
 421 }
 422
 423 void kh_Key_Touch()
 424 {
 425         if(intermission_running)
 426                 return;
 427
 428         if(self.owner) // already carried
 429                 return;
 430         if(other.classname != "player")
 431                 return;
 432         if(other.deadflag != DEAD_NO)
 433                 return;
 434         if(other == self.enemy)
 435                 if(time < self.kh_droptime + cvar("g_balance_keyhunt_delay_collect"))
 436                         return; // you just dropped it!
 437         kh_Key_Collect(self, other);
 438 }
 439
 440 void kh_Key_Think()
 441 {
 442         entity head;
 443
 444         if(intermission_running)
 445                 return;
 446
 447 #ifdef KH_KEY_ATTACHMENT_DEBUG
 448         if(self.kh_prev == self.owner)
 449         {
 450                 if(cvar_string("_angles") != "")
 451                 {
 452                         self.angles = stov(cvar_string("_angles"));
 453                         self.origin = stov(cvar_string("_origin"));
 454                 }
 455         }
 456 #endif
 457
 458         if(self.owner)
 459         {
 460 #ifndef KH_PLAYER_USE_ATTACHMENT
 461                 makevectors('0 1 0' * (self.cnt + mod(time, 360) * KH_KEY_XYSPEED));
 462                 setorigin(self, v_forward * KH_KEY_XYDIST + '0 0 1' * self.origin_z);
 463 #endif
 464
 465                 if(self.owner.buttonuse)
 466                 if(time >= self.owner.kh_droptime + cvar("g_balance_keyhunt_delay_drop"))
 467                 {
 468                         self.owner.kh_droptime = time;
 469                         self.kh_droptime = time; // prevent collecting this one for some time
 470                         self.enemy = self.owner;
 471                         self.pusher = world;
 472                         kh_Scores_Event(self.owner, self, "dropkey", 0, 0);
 473                         bprint(self.owner.netname, "^7 dropped the ", self.netname, "\n");
 474                         sound(self.owner, CHAN_AUTO, kh_sound_drop, 1, ATTN_NORM);
 475                         makevectors(self.owner.v_angle);
 476                         self.velocity = W_CalculateProjectileVelocity(self.owner.velocity, cvar("g_balance_keyhunt_throwvelocity") * v_forward);
 477                         kh_Key_AssignTo(self, world);
 478                         self.pushltime = time + cvar("g_balance_keyhunt_protecttime");
 479                         self.kh_dropperteam = self.team;
 480                 }
 481         }
 482
 483         // if in nodrop or time over, end the round
 484         if(!self.owner)
 485                 if(time > self.pain_finished)
 486                         kh_LoserTeam(self.team, self);
 487
 488         if(self.owner)
 489         if(kh_Key_AllOwnedByWhichTeam() != -1)
 490         {
 491                 entity key;
 492                 vector p;
 493                 p = self.owner.origin;
 494                 FOR_EACH_KH_KEY(key)
 495                         if(vlen(key.owner.origin - p) > cvar("g_balance_keyhunt_maxdist"))
 496                                 goto not_winning;
 497                 kh_WinnerTeam(self.team);
 498 :not_winning
 499         }
 500
 501         if(kh_interferemsg_time && time > kh_interferemsg_time)
 502         {
 503                 kh_interferemsg_time = 0;
 504                 FOR_EACH_PLAYER(head)
 505                 {
 506                         if(head.team == kh_interferemsg_team)
 507                                 if(head.kh_next)
 508                                         centerprint(head, "All keys are in your team's hands!\n\nMeet the other key carriers ^1NOW^7!\n");
 509                                 else
 510                                         centerprint(head, "All keys are in your team's hands!\n\nHelp the key carriers to meet!\n");
 511                         else
 512                                 centerprint(head, strcat("All keys are in the ", ColoredTeamName(kh_interferemsg_team), "^7's hands!\n\nInterfere ^1NOW^7!\n"));
 513                 }
 514         }
 515
 516         self.nextthink = time + 0.05;
 517 }
 518
 519 void kh_WinnerTeam(float teem)
 520 {
 521         // all key carriers get some points
 522         vector firstorigin, lastorigin, midpoint;
 523         float first;
 524         entity key;
 525         float score;
 526         score = (kh_teams - 1) * cvar("g_balance_keyhunt_score_capture");
 527         DistributeEvenly_Init(score, kh_teams);
 528         // twice the score for 3 team games, three times the score for 4 team games!
 529         // note: for a win by destroying the key, this should NOT be applied
 530         FOR_EACH_KH_KEY(key)
 531                 kh_Scores_Event(key.owner, key, "capture", DistributeEvenly_Get(1), 0);
 532
 533         first = TRUE;
 534         FOR_EACH_KH_KEY(key)
 535                 if(key.owner.kh_next == key)
 536                 {
 537                         if(!first)
 538                                 bprint("^7, ");
 539                         bprint(key.owner.netname);
 540                         first = FALSE;
 541                 }
 542         bprint("^7 captured the keys for the ", ColoredTeamName(teem), "\n");
 543
 544         first = TRUE;
 545         midpoint = '0 0 0';
 546         FOR_EACH_KH_KEY(key)
 547         {
 548                 vector thisorigin;
 549
 550                 thisorigin = kh_AttachedOrigin(key);
 551                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 552                 midpoint += thisorigin;
 553
 554                 if(!first)
 555                         te_lightning2(world, lastorigin, thisorigin);
 556                 lastorigin = thisorigin;
 557                 if(first)
 558                         firstorigin = thisorigin;
 559                 first = FALSE;
 560         }
 561         if(kh_teams > 2)
 562         {
 563                 te_lightning2(world, lastorigin, firstorigin);
 564         }
 565         midpoint = midpoint * (1 / kh_teams);
 566         te_customflash(midpoint, 1000, 1, kh_TeamColor(teem) * 0.5 + '0.5 0.5 0.5'); // make the color >=0.5 in each component
 567
 568         sound(world, CHAN_AUTO, kh_sound_capture, 1, ATTN_NONE);
 569         kh_FinishRound();
 570 }
 571
 572 void kh_LoserTeam(float teem, entity lostkey)
 573 {
 574         entity player, key, attacker;
 575         float players;
 576         float keys;
 577
 578         attacker = world;
 579         if(lostkey.pusher)
 580                 if(lostkey.pusher.team != teem)
 581                         if(lostkey.pusher.classname == "player")
 582                                 attacker = lostkey.pusher;
 583
 584         players = keys = 0;
 585
 586         if(attacker)
 587         {
 588                 if(lostkey.kh_previous_owner)
 589                         kh_Scores_Event(lostkey.kh_previous_owner, world, "pushed", 0, -cvar("g_balance_keyhunt_score_push"));
 590                         // don't actually GIVE him the -nn points, just log
 591                 kh_Scores_Event(attacker, world, "push", cvar("g_balance_keyhunt_score_push"), 0);
 592                 centerprint(attacker, "Your push is the best!\n\n\n");
 593                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "^7 when ", attacker.netname, "^7 came\n");
 594         }
 595         else
 596         {
 597                 float of, fragsleft, i, j, thisteam;
 598                 of = cvar("g_balance_keyhunt_score_destroyed_ownfactor");
 599
 600                 FOR_EACH_PLAYER(player)
 601                         if(player.team != teem)
 602                                 ++players;
 603
 604                 FOR_EACH_KH_KEY(key)
 605                         if(key.owner && key.team != teem)
 606                                 ++keys;
 607
 608                 if(lostkey.kh_previous_owner)
 609                         kh_Scores_Event(lostkey.kh_previous_owner, world, "destroyed", 0, -cvar("g_balance_keyhunt_score_destroyed"));
 610                         // don't actually GIVE him the -nn points, just log
 611
 612                 DistributeEvenly_Init(cvar("g_balance_keyhunt_score_destroyed"), keys * of + players);
 613
 614                 FOR_EACH_KH_KEY(key)
 615                         if(key.owner && key.team != teem)
 616                                 kh_Scores_Event(key.owner, world, "destroyed_holdingkey", DistributeEvenly_Get(of), 0);
 617
 618                 fragsleft = DistributeEvenly_Get(players);
 619
 620                 // Now distribute these among all other teams...
 621                 j = kh_teams - 1;
 622                 for(i = 0; i < kh_teams; ++i)
 623                 {
 624                         thisteam = kh_Team_ByID(i);
 625                         if(thisteam == teem) // bad boy, no cookie - this WILL happen
 626                                 continue;
 627
 628                         players = 0;
 629                         FOR_EACH_PLAYER(player)
 630                                 if(player.team == thisteam)
 631                                         ++players;
 632
 633                         DistributeEvenly_Init(fragsleft, j);
 634                         fragsleft = DistributeEvenly_Get(j - 1);
 635                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 636
 637                         FOR_EACH_PLAYER(player)
 638                                 if(player.team == thisteam)
 639                                         kh_Scores_Event(player, world, "destroyed", DistributeEvenly_Get(1), 0);
 640
 641                         --j;
 642                 }
 643
 644                 bprint("The ", ColoredTeamName(teem), "^7 could not take care of the ", lostkey.netname, "\n");
 645         }
 646         sound(world, CHAN_AUTO, kh_sound_destroy, 1, ATTN_NONE);
 647         te_tarexplosion(lostkey.origin);
 648
 649         kh_FinishRound();
 650 }
 651
 652 void kh_FinishRound()
 653 {
 654         // prepare next round
 655         kh_interferemsg_time = 0;
 656         entity key;
 657         FOR_EACH_KH_KEY(key)
 658                 kh_Key_Remove(key);
 659
 660         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 661 }
 662
 663 string kh_CheckEnoughPlayers()
 664 {
 665         float i, players, teem;
 666         entity player;
 667         string result;
 668         result = "";
 669
 670         // find a random player per team
 671         for(i = 0; i < kh_teams; ++i)
 672         {
 673                 teem = kh_Team_ByID(i);
 674                 players = 0;
 675                 FOR_EACH_PLAYER(player)
 676                         if(player.deadflag == DEAD_NO)
 677                                 if(!player.buttonchat)
 678                                         if(player.team == teem)
 679                                                 ++players;
 680                 if(players == 0)
 681                 {
 682                         if(result != "")
 683                                 result = strcat(result, ", ");
 684                         result = strcat(result, ColoredTeamName(teem));
 685                 }
 686         }
 687         return result;
 688 }
 689
 690 void kh_WaitForPlayers()
 691 {
 692         string teams_missing;
 693         teams_missing = kh_CheckEnoughPlayers();
 694         if(teams_missing == "")
 695                 kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_round"), "Round starts in ", kh_StartRound);
 696         else
 697                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 698 }
 699
 700 void kh_StartRound()
 701 {
 702         string teams_missing;
 703         float i, players, teem;
 704         entity player;
 705
 706         teams_missing = kh_CheckEnoughPlayers();
 707         if(teams_missing != "")
 708         {
 709                 kh_Controller_SetThink(1, strcat("Waiting for players to join...\n\nNeed active players for: ", teams_missing), kh_WaitForPlayers);
 710                 return;
 711         }
 712
 713         FOR_EACH_PLAYER(player)
 714                 if(clienttype(player) == CLIENTTYPE_REAL)
 715                         centerprint_expire(player, CENTERPRIO_SPAM);
 716
 717         for(i = 0; i < kh_teams; ++i)
 718         {
 719                 teem = kh_Team_ByID(i);
 720                 players = 0;
 721                 entity my_player;
 722                 FOR_EACH_PLAYER(player)
 723                         if(player.deadflag == DEAD_NO)
 724                                 if(!player.buttonchat)
 725                                         if(player.team == teem)
 726                                         {
 727                                                 ++players;
 728                                                 if(random() * players <= 1)
 729                                                         my_player = player;
 730                                         }
 731                 kh_Key_Spawn(my_player, 360 * i / kh_teams);
 732                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 733                 //kh_Key_Spawn(my_player, 360 * i / kh_teams);
 734         }
 735
 736         kh_tracking_enabled = FALSE;
 737         kh_Controller_SetThink(cvar("g_balance_keyhunt_delay_tracking"), "Scanning frequency range...", kh_EnableTrackingDevice);
 738 }
 739
 740 void kh_setstatus()
 741 {
 742         if(kh_teams)
 743         {
 744                 float kh_KEY;
 745                 kh_KEY = (IT_RED_FLAG_TAKEN | IT_RED_FLAG_LOST | IT_BLUE_FLAG_TAKEN | IT_BLUE_FLAG_LOST); // the one impossible combination
 746                 if(self.kh_next)
 747                         self.items = self.items | kh_KEY;
 748                 else
 749                         self.items = self.items - (self.items & kh_KEY);
 750         }
 751 }
 752
 753 void kh_EnableTrackingDevice()
 754 {
 755         entity player;
 756
 757         FOR_EACH_PLAYER(player)
 758                 if(clienttype(player) == CLIENTTYPE_REAL)
 759                         centerprint_expire(player, CENTERPRIO_SPAM);
 760
 761         kh_tracking_enabled = TRUE;
 762 }
 763
 764 float kh_Key_waypointsprite_for_player(entity e)
 765 {
 766         if(!kh_tracking_enabled)
 767                 return 0;
 768         if(!self.owner)
 769                 return kh_sprite_dropped;
 770         if(!self.owner.owner)
 771                 return kh_sprite_dropped;
 772         return 0; // draw only when key is not owned
 773 }
 774
 775 float kh_KeyCarrier_waypointsprite_for_player(entity e)
 776 {
 777         if(e.classname != "player" || self.team != e.team)
 778                 if(!kh_tracking_enabled)
 779                         return 0;
 780
 781         // e is spectator? That's no team mate...
 782         if(e.classname != "player")
 783                 return kh_GetCarrierSprite(self.team, -1);
 784
 785         // e is no key carrier: simple case...
 786         if(!e.kh_next)
 787                 return kh_GetCarrierSprite(self.team, e.team);
 788
 789         // e is a key carrier: if any key is dropped or owned by another team, show
 790         // the carrier sprite; otherwise show run here
 791         if(kh_Key_AllOwnedByWhichTeam() == e.team)
 792                 return kh_sprite_finish;
 793
 794         return kh_GetCarrierSprite(self.team, e.team);
 795 }
 796
 797 float kh_HandleFrags(entity attacker, entity targ, float f)
 798 {
 799         if(attacker == targ)
 800                 return f;
 801
 802         if(targ.kh_next)
 803         {
 804                 if(attacker.team == targ.team)
 805                 {
 806                         entity k;
 807                         float nk;
 808                         nk = 0;
 809                         for(k = targ.kh_next; k != world; k = k.kh_next)
 810                                 ++nk;
 811                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * cvar("g_balance_keyhunt_score_collect"), 0);
 812                 }
 813                 else
 814                 {
 815                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", cvar("g_balance_keyhunt_score_carrierfrag")-1, 0);
 816                 }
 817         }
 818
 819         return f;
 820 }
 821
 822 void kh_init()
 823 {
 824         precache_sound(kh_sound_capture);
 825         precache_sound(kh_sound_destroy);
 826         precache_sound(kh_sound_drop);
 827         precache_sound(kh_sound_collect);
 828
 829         precache_model("models/sprites/key-dropped.sp2");
 830         precache_model("models/sprites/keycarrier-finish.sp2");
 831         precache_model("models/sprites/keycarrier-friend.sp2");
 832         precache_model("models/sprites/keycarrier-red.sp2");
 833         precache_model("models/sprites/keycarrier-blue.sp2");
 834         precache_model("models/sprites/keycarrier-yellow.sp2");
 835         precache_model("models/sprites/keycarrier-pink.sp2");
 836 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 837         precache_model("models/keyhunt/key-carried.md3");
 838 #endif
 839         precache_model("models/keyhunt/key.md3");
 840
 841         // setup variables
 842         kh_teams = cvar("g_keyhunt_teams_override");
 843         if(kh_teams < 2)
 844                 kh_teams = cvar("g_keyhunt_teams");
 845         kh_teams = bound(2, kh_teams, 4);
 846
 847         // make a KH entity for controlling the game
 848         kh_controller = spawn();
 849         kh_controller.think = kh_Controller_Think;
 850         kh_Controller_SetThink(0, "", kh_WaitForPlayers);
 851
 852         setmodel(kh_controller, "models/keyhunt/key.md3");
 853         kh_key_dropped = kh_controller.modelindex;
 854         /*
 855         dprint(vtos(kh_controller.mins));
 856         dprint(vtos(kh_controller.maxs));
 857         dprint("\n");
 858         */
 859 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 860         setmodel(kh_controller, "models/keyhunt/key-carried.md3");
 861         kh_key_carried = kh_controller.modelindex;
 862 #else
 863         kh_key_carried = kh_key_dropped;
 864 #endif
 865         setmodel(kh_controller, "models/sprites/key-dropped.sp2");
 866         kh_sprite_dropped = kh_controller.modelindex;
 867         setmodel(kh_controller, "models/sprites/keycarrier-finish.sp2");
 868         kh_sprite_finish = kh_controller.modelindex;
 869         setmodel(kh_controller, "models/sprites/keycarrier-friend.sp2");
 870         kh_sprite_friend = kh_controller.modelindex;
 871         setmodel(kh_controller, "models/sprites/keycarrier-red.sp2");
 872         kh_sprite_red = kh_controller.modelindex;
 873         setmodel(kh_controller, "models/sprites/keycarrier-blue.sp2");
 874         kh_sprite_blue = kh_controller.modelindex;
 875         setmodel(kh_controller, "models/sprites/keycarrier-pink.sp2");
 876         kh_sprite_pink = kh_controller.modelindex;
 877         setmodel(kh_controller, "models/sprites/keycarrier-yellow.sp2");
 878         kh_sprite_yellow = kh_controller.modelindex;
 879         setmodel(kh_controller, "");
 880 }
 881
 882 void kh_finalize()
 883 {
 884         // to be called before intermission
 885         kh_FinishRound();
 886         remove(kh_controller);
 887         kh_controller = world;
 888 }