data/qcsrc/server/havocbot.qc

   1 .void() havocbot_role;
   2 void() havocbot_chooserole;
   3 .float havocbot_keyboardskill;
   4 .float facingwalltime, ignoregoaltime;
   5 .entity ignoregoal;
   6
   7 #ifdef DEBUG_BOT_GOALSTACK
   8 void debuggoalstack();
   9 #endif
  10
  11 vector havocbot_dodge()
  12 {
  13         // LordHavoc: disabled because this is too expensive
  14         return '0 0 0';
  15         /*
  16         local entity head;
  17         local vector dodge, v, n;
  18         local float danger, bestdanger, vl, d;
  19         dodge = '0 0 0';
  20         bestdanger = -20;
  21         // check for dangerous objects near bot or approaching bot
  22         head = findchainfloat(bot_dodge, TRUE);
  23         while(head)
  24         {
  25                 if (head.owner != self)
  26                 {
  27                         vl = vlen(head.velocity);
  28                         if (vl > sv_maxspeed * 0.3)
  29                         {
  30                                 n = normalize(head.velocity);
  31                                 v = self.origin - head.origin;
  32                                 d = v * n;
  33                                 if (d > (0 - head.bot_dodgerating))
  34                                 if (d < (vl * 0.2 + head.bot_dodgerating))
  35                                 {
  36                                         // calculate direction and distance from the flight path, by removing the forward axis
  37                                         v = v - (n * (v * n));
  38                                         danger = head.bot_dodgerating - vlen(v);
  39                                         if (bestdanger < danger)
  40                                         {
  41                                                 bestdanger = danger;
  42                                                 // dodge to the side of the object
  43                                                 dodge = normalize(v);
  44                                         }
  45                                 }
  46                         }
  47                         else
  48                         {
  49                                 danger = head.bot_dodgerating - vlen(head.origin - self.origin);
  50                                 if (bestdanger < danger)
  51                                 {
  52                                         bestdanger = danger;
  53                                         dodge = normalize(self.origin - head.origin);
  54                                 }
  55                         }
  56                 }
  57                 head = head.chain;
  58         }
  59         return dodge;
  60         */
  61 };
  62
  63 .float havocbot_keyboardtime;
  64 .float havocbot_ducktime;
  65 .vector havocbot_keyboard;
  66 void havocbot_keyboard_movement(vector destorg)
  67 {
  68         local vector keyboard;
  69         local float blend, maxspeed;
  70
  71         maxspeed = cvar("sv_maxspeed");
  72
  73         if (time < self.havocbot_keyboardtime)
  74                 return;
  75
  76         self.havocbot_keyboardtime =
  77                 max(
  78                         self.havocbot_keyboardtime
  79                                 + bound(0,0.05/(skill+self.havocbot_keyboardskill),0.05)
  80                                 +random()*bound(0,0.025/(skill+self.havocbot_keyboardskill),100)
  81                 , time);
  82         keyboard = self.movement * (1.0 / maxspeed);
  83
  84         local float trigger, trigger1;
  85         blend = bound(0,skill*0.1,1);
  86         trigger = cvar("bot_ai_keyboard_treshold");
  87         trigger1 = 0 - trigger;
  88
  89         // categorize forward movement
  90         // at skill < 1.5 only forward
  91         // at skill < 2.5 only individual directions
  92         // at skill < 4.5 only individual directions, and forward diagonals
  93         // at skill >= 4.5, all cases allowed
  94         if (keyboard_x > trigger)
  95         {
  96                 keyboard_x = 1;
  97                 if (skill < 2.5)
  98                         keyboard_y = 0;
  99         }
 100         else if (keyboard_x < trigger1 && skill > 1.5)
 101         {
 102                 keyboard_x = -1;
 103                 if (skill < 4.5)
 104                         keyboard_y = 0;
 105         }
 106         else
 107         {
 108                 keyboard_x = 0;
 109                 if (skill < 1.5)
 110                         keyboard_y = 0;
 111         }
 112         if (skill < 4.5)
 113                 keyboard_z = 0;
 114
 115         if (keyboard_y > trigger)
 116                 keyboard_y = 1;
 117         else if (keyboard_y < trigger1)
 118                 keyboard_y = -1;
 119         else
 120                 keyboard_y = 0;
 121
 122         if (keyboard_z > trigger)
 123                 keyboard_z = 1;
 124         else if (keyboard_z < trigger1)
 125                 keyboard_z = -1;
 126         else
 127                 keyboard_z = 0;
 128
 129         self.havocbot_keyboard = keyboard * maxspeed;
 130         if (self.havocbot_ducktime>time) self.BUTTON_CROUCH=TRUE;
 131
 132         keyboard = self.havocbot_keyboard;
 133         blend = bound(0,vlen(destorg-self.origin)/cvar("bot_ai_keyboard_distance"),1); // When getting close move with 360 degree
 134         //dprint("movement ", vtos(self.movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 135         self.movement = self.movement + (keyboard - self.movement) * blend;
 136 };
 137
 138 .entity bot_lastseengoal;
 139 .float bot_timelastseengoal;
 140 .float bot_canruntogoal;
 141 void havocbot_bunnyhop(vector dir)
 142 {
 143         local float distance;
 144         local vector deviation;
 145
 146         if(self.goalcurrent.classname == "player")
 147                 return;
 148
 149         if(self.aistatus & AI_STATUS_DANGER_AHEAD)
 150         {
 151                 self.aistatus &~= AI_STATUS_RUNNING;
 152                 self.BUTTON_JUMP = FALSE;
 153                 return;
 154         }
 155
 156         if(self.waterlevel > 1)
 157         {
 158                 self.aistatus &~= AI_STATUS_RUNNING;
 159                 return;
 160         }
 161
 162         if(self.bot_lastseengoal != self.goalcurrent && !(self.aistatus & AI_STATUS_RUNNING))
 163         {
 164                 self.bot_canruntogoal = 0;
 165                 self.bot_timelastseengoal = 0;
 166         }
 167
 168         distance = vlen(self.origin - self.goalcurrent.origin);
 169
 170         // Run only to visible goals
 171         traceline(self.origin + self.view_ofs , self.goalcurrent.origin, TRUE, world);
 172         if(self.flags & FL_ONGROUND)
 173         if(trace_fraction == 1)
 174         {
 175                         self.bot_lastseengoal = self.goalcurrent;
 176
 177                         // seen it before
 178                         if(self.bot_timelastseengoal)
 179                         {
 180                                 // for a period of time
 181                                 if(time - self.bot_timelastseengoal > cvar("bot_ai_bunnyhop_firstjumpdelay"))
 182                                 {
 183                                         local float checkdistance;
 184                                         checkdistance = TRUE;
 185
 186                                         // don't run if it is too close
 187                                         if(self.bot_canruntogoal==0)
 188                                         {
 189                                                 if(distance > cvar("bot_ai_bunnyhop_startdistance"))
 190                                                         self.bot_canruntogoal = 1;
 191                                                 else
 192                                                         self.bot_canruntogoal = -1;
 193                                         }
 194
 195                                         if(self.bot_canruntogoal != 1)
 196                                                 return;
 197
 198                                         if(self.aistatus & AI_STATUS_ROAMING)
 199                                         if(self.goalcurrent.classname=="waypoint")
 200                                         if(fabs(self.goalcurrent.origin_z - self.origin_z) < self.maxs_z - self.mins_z)
 201                                         if(self.goalstack01!=world)
 202                                         {
 203                                                 deviation = self.goalstack01.origin - (self.origin + self.view_ofs);
 204                                                 deviation = vectoangles(deviation) - self.v_angle;
 205                                                 while (deviation_y < -180) deviation_y = deviation_y + 360;
 206                                                 while (deviation_y > 180) deviation_y = deviation_y - 360;
 207
 208                                                 if(fabs(deviation_y) < 15)
 209                                                 if(distance < vlen(self.origin - self.goalstack01.origin))
 210                                                 if(fabs(self.goalstack01.origin_z - self.goalcurrent.origin_z) < self.maxs_z - self.mins_z)
 211                                                 {
 212                                                         traceline(self.origin + self.view_ofs , self.goalstack01.origin, TRUE, world);
 213                                                         if(trace_fraction==1)
 214                                                         {
 215                                                                 checkdistance = FALSE;
 216                                                         }
 217                                                 }
 218                                         }
 219
 220                                         if(checkdistance)
 221                                         {
 222                                                 self.aistatus &~= AI_STATUS_RUNNING;
 223                                                 if(distance > cvar("bot_ai_bunnyhop_stopdistance"))
 224                                                         self.BUTTON_JUMP = TRUE;
 225                                         }
 226                                         else
 227                                         {
 228                                                 self.aistatus |= AI_STATUS_RUNNING;
 229                                                 self.BUTTON_JUMP = TRUE;
 230                                         }
 231                                 }
 232                         }
 233                         else
 234                         {
 235                                 self.bot_timelastseengoal = time;
 236                         }
 237         }
 238         else
 239         {
 240                 self.bot_timelastseengoal = 0;
 241         }
 242
 243         // Release jump button
 244         if(self.flags & FL_ONGROUND == 0)
 245         {
 246                 if(self.velocity_z < 0)
 247                         self.BUTTON_JUMP = FALSE;
 248
 249                 // Strafe
 250                 local float maxspeed;
 251                 maxspeed = cvar("sv_maxspeed");
 252
 253                 if(self.aistatus & AI_STATUS_RUNNING)
 254                 if(vlen(self.velocity)>maxspeed)
 255                 {
 256                         deviation = vectoangles(dir) - self.v_angle;
 257                         while (deviation_y < -180) deviation_y = deviation_y + 360;
 258                         while (deviation_y > 180) deviation_y = deviation_y - 360;
 259
 260                         if ( deviation_y > 2 )
 261                                 self.movement_y = maxspeed;
 262                         if ( deviation_y < -2 )
 263                                 self.movement_y = maxspeed * -1;
 264                 }
 265         }
 266 };
 267
 268 //.float havocbotignoretime;
 269 //.vector bot_dodgevector;
 270 //.float bot_dodgevector_time;
 271 //.float bot_dodgevector_jumpbutton;
 272 void havocbot_movetogoal()
 273 {
 274         local vector destorg;
 275         local vector diff;
 276         local vector dir;
 277         local vector flatdir;
 278         local vector m1;
 279         local vector m2;
 280         local vector evadeobstacle;
 281         local vector evadelava;
 282         local float s;
 283         local float maxspeed;
 284         //local float dist;
 285         local vector dodge;
 286         //if (self.goalentity)
 287         //      te_lightning2(self, self.origin, (self.goalentity.absmin + self.goalentity.absmax) * 0.5);
 288         self.movement = '0 0 0';
 289         maxspeed = cvar("sv_maxspeed");
 290
 291         if(self.jumppadcount)
 292         {
 293                 if(self.flags & FL_ONGROUND)
 294                 {
 295                         self.jumppadcount = FALSE;
 296                         if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 297                                 self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
 298                 }
 299
 300                 // If got stuck on the jump pad try to reach the farther visible item
 301                 if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 302                 {
 303                         if(fabs(self.velocity_z)<50)
 304                         {
 305                                 local entity head, newgoal;
 306                                 local float distance, bestdistance;
 307
 308                                 for (head = findchainfloat(bot_pickup, TRUE); head; head = head.chain)
 309                                 {
 310                                         if(head.classname=="worldspawn")
 311                                                 continue;
 312
 313                                         distance = vlen(head.origin - self.origin);
 314                                         if(distance>1000)
 315                                                 continue;
 316
 317                                         traceline(self.origin + self.view_ofs , head.origin, TRUE, world);
 318
 319                                         if(trace_fraction<1)
 320                                                 continue;
 321
 322                                         if(distance>bestdistance)
 323                                         {
 324                                                 newgoal = head;
 325                                                 bestdistance = distance;
 326                                         }
 327                                 }
 328
 329                                 if(newgoal)
 330                                 {
 331                                         self.ignoregoal = self.goalcurrent;
 332                                         self.ignoregoaltime = time + cvar("bot_ai_ignoregoal_timeout");
 333                                         navigation_routetogoal(newgoal);
 334                                         self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
 335                                 }
 336                         }
 337                         else
 338                                 return;
 339                 }
 340                 else
 341                 {
 342                         if(self.velocity_z>0)
 343                         {
 344                                 local float threshold;
 345                                 threshold = maxspeed * 0.2;
 346                                 if(fabs(self.velocity_x) < threshold  &&  fabs(self.velocity_y) < threshold)
 347                                         self.aistatus |= AI_STATUS_OUT_JUMPPAD;
 348                                 return;
 349                         }
 350                 }
 351         }
 352
 353         // If we are under water with no goals, swim up
 354         if(self.waterlevel)
 355         if(self.goalcurrent==world)
 356         {
 357                 dir = '0 0 0';
 358                 if(self.waterlevel>2)
 359                         dir_z = 1;
 360                 else if(self.velocity_z >= 0 && !(self.waterlevel == 1 && self.watertype == CONTENT_WATER))
 361                         self.BUTTON_JUMP = TRUE;
 362                 else
 363                         self.BUTTON_JUMP = FALSE;
 364                 makevectors(self.v_angle_y * '0 1 0');
 365                 self.movement_x = dir * v_forward * maxspeed;
 366                 self.movement_y = dir * v_right * maxspeed;
 367                 self.movement_z = dir * v_up * maxspeed;
 368         }
 369
 370         // if there is nowhere to go, exit
 371         if (self.goalcurrent == world)
 372                 return;
 373
 374         if (self.goalcurrent)
 375                 navigation_poptouchedgoals();
 376
 377         // if ran out of goals try to use an alternative goal or get a new strategy asap
 378         if(self.goalcurrent == world)
 379         if(self.flags & FL_ONGROUND || self.aistatus & AI_STATUS_RUNNING || self.BUTTON_JUMP == TRUE)
 380         {
 381                 if(self.alternativegoal==world)
 382                 {
 383                         // ran out of goals
 384                         self.bot_strategytime = 0;
 385                         return;
 386                 }
 387
 388                 // use the alternative goal
 389                 if (bot_strategytoken == self)
 390                 if (!bot_strategytoken_taken)
 391                 {
 392                         navigation_findnearestwaypoint(self.alternativegoal, TRUE);
 393                         navigation_routetogoal(self.alternativegoal);
 394                         self.alternativegoal = world;
 395                         bot_strategytoken_taken = TRUE;
 396                 }
 397
 398                 return;
 399         }
 400
 401 #ifdef DEBUG_BOT_GOALSTACK
 402         debuggoalstack();
 403 #endif
 404
 405         m1 = self.goalcurrent.origin + self.goalcurrent.mins;
 406         m2 = self.goalcurrent.origin + self.goalcurrent.maxs;
 407         destorg = self.origin;
 408         destorg_x = bound(m1_x, destorg_x, m2_x);
 409         destorg_y = bound(m1_y, destorg_y, m2_y);
 410         destorg_z = bound(m1_z, destorg_z, m2_z);
 411         diff = destorg - self.origin;
 412         //dist = vlen(diff);
 413         dir = normalize(diff);
 414         flatdir = diff;flatdir_z = 0;
 415         flatdir = normalize(flatdir);
 416
 417         //if (self.bot_dodgevector_time < time)
 418         {
 419         //      self.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 420         //      self.bot_dodgevector_jumpbutton = 1;
 421                 evadeobstacle = '0 0 0';
 422                 evadelava = '0 0 0';
 423
 424                 if (self.waterlevel)
 425                 {
 426                         if(self.waterlevel>2)
 427                         {
 428                         //      flatdir_z = 1;
 429                                 self.aistatus |= AI_STATUS_OUT_WATER;
 430                         }
 431                         else
 432                         {
 433                                 if(self.velocity_z >= 0 && !(self.watertype == CONTENT_WATER && self.goalcurrent.origin_z < self.origin_z) &&
 434                                         ( !(self.waterlevel == 1 && self.watertype == CONTENT_WATER) || self.aistatus & AI_STATUS_OUT_WATER))
 435                                         self.BUTTON_JUMP = TRUE;
 436                                 else
 437                                         self.BUTTON_JUMP = FALSE;
 438                         }
 439                         dir = normalize(flatdir);
 440                         makevectors(self.v_angle_y * '0 1 0');
 441                 }
 442                 else
 443                 {
 444                         if(self.aistatus & AI_STATUS_OUT_WATER)
 445                                 self.aistatus &~= AI_STATUS_OUT_WATER;
 446
 447                         // jump if going toward an obstacle that doesn't look like stairs we
 448                         // can walk up directly
 449                         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.2, FALSE, self);
 450                         if (trace_fraction < 1)
 451                         if (trace_plane_normal_z < 0.7)
 452                         {
 453                                 s = trace_fraction;
 454                                 tracebox(self.origin + '0 0 16', self.mins, self.maxs, self.origin + self.velocity * 0.2 + '0 0 16', FALSE, self);
 455                                 if (trace_fraction < s + 0.01)
 456                                 if (trace_plane_normal_z < 0.7)
 457                                 {
 458                                         s = trace_fraction;
 459                                         tracebox(self.origin + '0 0 48', self.mins, self.maxs, self.origin + self.velocity * 0.2 + '0 0 48', FALSE, self);
 460                                         if (trace_fraction > s)
 461                                                 self.BUTTON_JUMP = 1;
 462                                 }
 463                         }
 464
 465                         // avoiding dangers and obstacles
 466                         local vector dst_ahead, dst_down;
 467                         dst_ahead = self.origin + self.view_ofs + (self.velocity * 0.32);
 468                         dst_down = dst_ahead + '0 0 -1500';
 469
 470                         // Look ahead
 471                         traceline(self.origin + self.view_ofs , dst_ahead, TRUE, world);
 472
 473                         // Check head-banging against walls
 474                         if(vlen(self.origin + self.view_ofs - trace_endpos) < 2 && !(self.aistatus & AI_STATUS_OUT_WATER))
 475                         {
 476                                 if(self.facingwalltime && time > self.facingwalltime)
 477                                 {
 478                                         self.ignoregoal = self.goalcurrent;
 479                                         self.ignoregoaltime = time + cvar("bot_ai_ignoregoal_timeout");
 480                                         navigation_poproute();
 481                                 }
 482                                 else
 483                                 {
 484                                         self.facingwalltime = time + 0.05;
 485                                 }
 486                         }
 487                         else
 488                         {
 489                                 self.facingwalltime = 0;
 490
 491                                 if(self.ignoregoal != world && time > self.ignoregoaltime)
 492                                 {
 493                                         self.ignoregoal = world;
 494                                         self.ignoregoaltime = 0;
 495                                 }
 496                         }
 497
 498                         // Check for water/slime/lava and dangerous edges
 499                         // (only when the bot is on the ground or jumping intentionally)
 500                         self.aistatus &~= AI_STATUS_DANGER_AHEAD;
 501
 502                         if(trace_fraction == 1)
 503                         if(self.flags & FL_ONGROUND || self.aistatus & AI_STATUS_RUNNING || self.BUTTON_JUMP == TRUE)
 504                         {
 505                                 // Look downwards
 506                                 traceline(dst_ahead , dst_down, TRUE, world);
 507                                 //      te_lightning2(world, self.origin, dst_ahead);   // Draw "ahead" look
 508                                 //      te_lightning2(world, dst_ahead, dst_down);              // Draw "downwards" look
 509                                 if(trace_endpos_z < self.origin_z + self.mins_z)
 510                                 {
 511                                         s = pointcontents(trace_endpos + '0 0 1');
 512                                         if (s != CONTENT_SOLID)
 513                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 514                                                 evadelava = normalize(self.velocity) * -1;
 515                                         else if (s == CONTENT_SKY)
 516                                                 evadeobstacle = normalize(self.velocity) * -1;
 517                                         else if (!boxesoverlap(dst_ahead - self.view_ofs + self.mins, dst_ahead - self.view_ofs + self.maxs,
 518                                                                 self.goalcurrent.absmin, self.goalcurrent.absmax))
 519                                         {
 520                                                 // if ain't a safe goal with "holes" (like the jumpad on soylent)
 521                                                 // and there is a trigger_hurt below
 522                                                 if(tracebox_hits_trigger_hurt(dst_ahead, self.mins, self.maxs, trace_endpos))
 523                                                 {
 524                                                         // Remove dangerous dynamic goals from stack
 525                                                         if (self.goalcurrent.classname == "player" || self.goalcurrent.classname == "droppedweapon")
 526                                                                 navigation_poproute();
 527                                                         // try to stop
 528                                                         flatdir = '0 0 0';
 529                                                         evadeobstacle = normalize(self.velocity) * -1;
 530                                                 }
 531                                         }
 532                                 }
 533                         }
 534
 535                         dir = flatdir;
 536                         evadeobstacle_z = 0;
 537                         evadelava_z = 0;
 538                         makevectors(self.v_angle_y * '0 1 0');
 539
 540                         if(evadeobstacle!='0 0 0'||evadelava!='0 0 0')
 541                                 self.aistatus |= AI_STATUS_DANGER_AHEAD;
 542                 }
 543
 544                 dodge = havocbot_dodge();
 545                 dodge = dodge * bound(0,3+skill*0.1,1);
 546                 evadelava = evadelava * bound(1,3-skill,3); //Noobs fear lava a lot and take more distance from it
 547                 traceline(self.origin, self.enemy.origin, TRUE, world);
 548                 if(trace_ent.classname == "player")
 549                         dir = dir * bound(0,skill/7,1);
 550
 551                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 552         //      self.bot_dodgevector = dir;
 553         //      self.bot_dodgevector_jumpbutton = self.BUTTON_JUMP;
 554         }
 555
 556         //dir = self.bot_dodgevector;
 557         //if (self.bot_dodgevector_jumpbutton)
 558         //      self.BUTTON_JUMP = 1;
 559         self.movement_x = dir * v_forward * maxspeed;
 560         self.movement_y = dir * v_right * maxspeed;
 561         self.movement_z = dir * v_up * maxspeed;
 562
 563         // Emulate keyboard interface
 564         if (skill < 10)
 565                 havocbot_keyboard_movement(destorg);
 566
 567         // Bunnyhop!
 568 //      if(self.aistatus & AI_STATUS_ROAMING)
 569         if(skill >= cvar("bot_ai_bunnyhop_skilloffset"))
 570                 havocbot_bunnyhop(dir);
 571
 572         if ((dir * v_up) >= cvar("sv_jumpvelocity")*0.5 && (self.flags & FL_ONGROUND)) self.BUTTON_JUMP=1;
 573         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill)*0.1,1)) self.BUTTON_JUMP=TRUE;
 574         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill)*0.1,1)) self.havocbot_ducktime=time+0.3/bound(0.1,skill,10);
 575 };
 576
 577 .float havocbot_chooseenemy_finished;
 578 .float havocbot_stickenemy;
 579 void havocbot_chooseenemy()
 580 {
 581         local entity head, best;
 582         local float rating, bestrating;
 583         local vector eye, v;
 584         if (cvar("bot_nofire") || IS_INDEPENDENT_PLAYER(self))
 585         {
 586                 self.enemy = world;
 587                 return;
 588         }
 589         if (self.enemy)
 590         {
 591                 if (!bot_shouldattack(self.enemy))
 592                 {
 593                         // enemy died or something, find a new target
 594                         self.enemy = world;
 595                         self.havocbot_chooseenemy_finished = time;
 596                 }
 597                 else if (self.havocbot_stickenemy)
 598                 {
 599                         // tracking last chosen enemy
 600                         // if enemy is visible
 601                         // and not really really far away
 602                         // and we're not severely injured
 603                         // then keep tracking for a half second into the future
 604                         traceline(self.origin+self.view_ofs, self.enemy.origin+self.enemy.view_ofs*0.5,FALSE,world);
 605                         if (trace_ent == self.enemy || trace_fraction == 1)
 606                         if (vlen(self.enemy.origin - self.origin) < 1000)
 607                         if (self.health > 30)
 608                         {
 609                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 610                                 self.havocbot_chooseenemy_finished = time + cvar("bot_ai_enemydetectioninterval");
 611                                 return;
 612                         }
 613                         // enemy isn't visible, or is far away, or we're injured severely
 614                         // so stop preferring this enemy
 615                         // (it will still take a half second until a new one is chosen)
 616                         self.havocbot_stickenemy = 0;
 617                 }
 618         }
 619         if (time < self.havocbot_chooseenemy_finished)
 620                 return;
 621         self.havocbot_chooseenemy_finished = time + cvar("bot_ai_enemydetectioninterval");
 622         eye = (self.origin + self.view_ofs);
 623         best = world;
 624         bestrating = 100000000;
 625         head = findchainfloat(bot_attack, TRUE);
 626         while (head)
 627         {
 628                 v = (head.absmin + head.absmax) * 0.5;
 629                 rating = vlen(v - eye);
 630                 if (bestrating > rating)
 631                 if (bot_shouldattack(head))
 632                 {
 633                         traceline(eye, v, TRUE, self);
 634                         if (trace_ent == head || trace_fraction >= 1)
 635                         {
 636                                 best = head;
 637                                 bestrating = rating;
 638                         }
 639                 }
 640                 head = head.chain;
 641         }
 642         self.enemy = best;
 643         self.havocbot_stickenemy = TRUE;
 644 };
 645
 646 .float bot_chooseweapontime;
 647 float(entity e) w_getbestweapon;
 648 void havocbot_chooseweapon()
 649 {
 650         // TODO: clean this up by moving it to weapon code
 651         if(self.enemy.classname!="player")
 652         {
 653         //      self.switchweapon = w_getbestweapon(self);
 654                 if(client_hasweapon(self, WEP_LASER, TRUE, FALSE))
 655                         self.switchweapon = WEP_LASER;
 656                 return;
 657         }
 658
 659         local float w, s;
 660         local float rocket  ; rocket   =-1000;
 661         local float nex     ; nex      =-1000;
 662         local float hagar   ; hagar    =-1000;
 663         local float grenade ; grenade  =-1000;
 664         local float electro ; electro  =-1000;
 665         local float crylink ; crylink  =-1000;
 666         local float uzi     ; uzi      =-1000;
 667         local float shotgun ; shotgun  =-1000;
 668         local float campingrifle ; campingrifle  =-1000;
 669         local float laser   ; laser    =-1000;
 670         local float minstanex ; minstanex =-1000;
 671         local float currentscore;
 672         local float bestscore; bestscore = 0;
 673         local float bestweapon; bestweapon=self.switchweapon;
 674         local float distance; distance=bound(10,vlen(self.origin-self.enemy.origin)-200,10000);
 675         local float maxdelaytime=0.5;
 676         local float spreadpenalty=10;
 677         local float distancefromfloor;
 678
 679         local float af, ct, combo_time;
 680
 681         traceline(self.enemy.origin,self.enemy.origin-'0 0 1000',TRUE,world);
 682         distancefromfloor = self.enemy.origin_z - trace_endpos_z;
 683
 684         af = ATTACK_FINISHED(self);
 685         ct = cvar("bot_ai_weapon_combo_threshold");
 686
 687         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
 688         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
 689         combo_time = time + ct + (ct * ((-0.3*skill)+3));
 690
 691         // Custom weapon list based on distance to the enemy
 692         local float i; i = 0;
 693         if(bot_custom_weapon){
 694
 695                 // Choose weapons for far distance
 696                 if ( distance > bot_distance_far ) {
 697                         for(i=0; i < WEP_COUNT && bot_weapons_far[i] != -1 ; ++i){
 698                                 w = bot_weapons_far[i];
 699                                 if ( client_hasweapon(self, w, TRUE, FALSE) ){
 700                                         if ( self.weapon == w){
 701                                                 if( cvar("bot_ai_weapon_combo") && af > combo_time)
 702                                                         continue;
 703                                         } else {
 704                                                 self.switchweapon = w;
 705                                         }
 706                                         return;
 707                                 }
 708                         }
 709                 }
 710
 711                 // Choose weapons for mid distance
 712                 if ( distance > bot_distance_close ) {
 713                         for(i= 0; i < WEP_COUNT && bot_weapons_mid[i] != -1 ; ++i){
 714                                 w = bot_weapons_mid[i];
 715                                 if ( client_hasweapon(self, w, TRUE, FALSE) ){
 716                                         if ( self.weapon == w){
 717                                                 if( cvar("bot_ai_weapon_combo") && af > combo_time)
 718                                                         continue;
 719                                         } else {
 720                                                 self.switchweapon = w;
 721                                         }
 722                                         return;
 723                                 }
 724                         }
 725                 }
 726
 727                 // Choose weapons for close distance
 728                 for(i= 0; i < WEP_COUNT && bot_weapons_close[i] != -1 ; ++i){
 729                         w = bot_weapons_close[i];
 730                         if ( client_hasweapon(self, w, TRUE, FALSE) ){
 731                                 if ( self.weapon == w){
 732                                         if( cvar("bot_ai_weapon_combo") && af > combo_time)
 733                                                 continue;
 734                                 } else {
 735                                         self.switchweapon = w;
 736                                 }
 737                                 return;
 738                         }
 739                 }
 740                 // If now weapon was chosen by this system fall back to the previous one
 741         }
 742
 743         // Formula:
 744         //      (Damage/Sec * Weapon spefic change to get that damage)
 745         //      *(Time to get to target * weapon specfic hitchange bonus) / (in a time of maxdelaytime)
 746         //      *(Spread change of hit) // if it applies
 747         //      *(Penality for target beeing in air)
 748         // %weaponaddpoint
 749         if (client_hasweapon(self, WEP_MINSTANEX, TRUE, FALSE))
 750                 minstanex = (1000/cvar("g_balance_minstanex_refire")*1.0)
 751                         * (0.5);
 752
 753         if (client_hasweapon(self, WEP_ROCKET_LAUNCHER, TRUE, FALSE)  &&
 754                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_ROCKET_LAUNCHER &&
 755                         af > combo_time
 756                 )
 757         )
 758                 rocket = (cvar("g_balance_rocketlauncher_damage")/cvar("g_balance_rocketlauncher_refire")*0.75)
 759                         * bound(0,(cvar("g_balance_rocketlauncher_speed")/distance*maxdelaytime),1)*1.5;
 760
 761         if (client_hasweapon(self, WEP_NEX, TRUE, FALSE)  &&
 762                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_NEX &&
 763                         af > combo_time
 764                 )
 765         )
 766                 nex = (cvar("g_balance_nex_damage")/cvar("g_balance_nex_refire")*1.0)
 767                         * (0.5);
 768
 769         if (client_hasweapon(self, WEP_HAGAR, TRUE, FALSE) ) // &&
 770         //      !( cvar("bot_ai_weapon_combo") && self.weapon == WEP_HAGAR &&  time < self.bot_lastshot + cvar("g_balance_hagar_primary_refire") ))
 771                 hagar = (cvar("g_balance_hagar_primary_damage")/cvar("g_balance_hagar_primary_refire")*1.0)
 772                         * bound(0,(cvar("g_balance_hagar_primary_speed")/distance*maxdelaytime),1)*0.2;
 773
 774         if (client_hasweapon(self, WEP_GRENADE_LAUNCHER, TRUE, FALSE) &&
 775                 !(
 776                         cvar("bot_ai_weapon_combo") && self.weapon == WEP_GRENADE_LAUNCHER &&
 777                         af > combo_time
 778                 )
 779         )
 780                 grenade = (cvar("g_balance_grenadelauncher_primary_damage")/cvar("g_balance_grenadelauncher_primary_refire")*1.0)
 781                         * bound(0,(cvar("g_balance_grenadelauncher_primary_speed")/distance*maxdelaytime),1)*1.1;
 782
 783         if (client_hasweapon(self, WEP_ELECTRO, TRUE, FALSE) &&
 784                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_ELECTRO &&
 785                         af > combo_time
 786                 )
 787         )
 788                 electro = (cvar("g_balance_electro_primary_damage")/cvar("g_balance_electro_primary_refire")*0.75)
 789                         * bound(0,(cvar("g_balance_electro_primary_speed")/distance*maxdelaytime),1)*1.0;
 790
 791         if (client_hasweapon(self, WEP_CRYLINK, TRUE, FALSE) ) // &&
 792         //      !( self.weapon == WEP_CRYLINK &&  time < self.bot_lastshot + cvar("g_balance_crylink_primary_refire") ))
 793                 crylink = (cvar("g_balance_crylink_primary_damage")/cvar("g_balance_crylink_primary_refire")*1.0)
 794                         * bound(0,(cvar("g_balance_crylink_primary_speed")/distance*maxdelaytime),1)*(64/(32+cvar("g_balance_crylink_primary_spread")*distance))*1.0;
 795
 796         if (client_hasweapon(self, WEP_UZI, TRUE, FALSE) ) // &&
 797         //      !( self.weapon == WEP_UZI &&  time < self.bot_lastshot + cvar("g_balance_uzi_sustained_refire") ))
 798                 uzi = (cvar("g_balance_uzi_sustained_damage")/cvar("g_balance_uzi_sustained_refire")*1.0)
 799                         * bound(0,32/(32+cvar("g_balance_uzi_sustained_spread")*distance),1);
 800
 801         if (client_hasweapon(self, WEP_SHOTGUN, TRUE, FALSE) &&
 802                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_SHOTGUN &&
 803                         af > combo_time
 804                 )
 805         )
 806                 shotgun = (cvar("g_balance_shotgun_primary_damage")*cvar("g_balance_shotgun_primary_bullets")/cvar("g_balance_shotgun_primary_refire")*1.0)
 807                         * bound(0,32/(32+cvar("g_balance_shotgun_primary_spread")*distance),1);
 808
 809         if (client_hasweapon(self, WEP_LASER, FALSE, FALSE) &&
 810                 !(      cvar("bot_ai_weapon_combo") && self.weapon == WEP_LASER &&
 811                         af > combo_time
 812                 )
 813         )
 814                 laser = (cvar("g_balance_laser_primary_damage")/cvar("g_balance_laser_primary_refire")*1.0)
 815                         * bound(0,cvar("g_balance_laser_primary_speed")/distance*maxdelaytime,1);
 816
 817         if((self.enemy.flags & FL_ONGROUND)==FALSE){
 818                 rocket = rocket   * (1.5-bound(0, distancefromfloor/cvar("g_balance_rocketlauncher_radius"         ),0.9)); //slight bigger change
 819                 grenade = grenade * (1.5-bound(0,distancefromfloor/cvar("g_balance_grenadelauncher_primary_radius"),0.95));
 820                 electro = electro * (1.5-bound(0,distancefromfloor/cvar("g_balance_electro_primary_radius"        ),0.95));
 821                 laser = laser     * (1.5-bound(0,distancefromfloor/cvar("g_balance_laser_primary_radius"                  ),0.95));
 822         }
 823         /*
 824         dprint("Floor distance: ",ftos(distancefromfloor),"\n");
 825         dprint("Rocket: " , ftos(rocket  ), "\n");
 826         dprint("Nex: "    , ftos(nex     ), "\n");
 827         dprint("Hagar: "  , ftos(hagar   ), "\n");
 828         dprint("Grenade: ", ftos(grenade ), "\n");
 829         dprint("Electro: ", ftos(electro ), "\n");
 830         dprint("Crylink: ", ftos(crylink ), "\n");
 831         dprint("Uzi: "    , ftos(uzi     ), "\n");
 832         dprint("Shotgun :", ftos(shotgun ), "\n");
 833         dprint("Laser   :", ftos(laser   ), "\n\n");
 834         */
 835         currentscore = -1;
 836         w = WEP_MINSTANEX        ;s = minstanex;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 837         w = WEP_ROCKET_LAUNCHER  ;s = rocket   ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 838         w = WEP_NEX              ;s = nex      ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 839         w = WEP_HAGAR            ;s = hagar    ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 840         w = WEP_GRENADE_LAUNCHER ;s = grenade  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 841         w = WEP_ELECTRO          ;s = electro  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 842         w = WEP_CRYLINK          ;s = crylink  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 843         w = WEP_UZI              ;s = uzi      ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 844         w = WEP_SHOTGUN          ;s = shotgun  ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 845         w = WEP_LASER            ;s = laser    ;if (s > bestscore){bestscore = s;bestweapon = w;} if (self.switchweapon == w) currentscore = s;
 846
 847         // switch if the best weapon would provide a significant damage increase
 848         if (bestscore > currentscore*1.5){
 849                 self.switchweapon = bestweapon;
 850
 851                 // buys time for detonating the rocket. not tested yet
 852                 if ( cvar("bot_ai_weapon_combo") && bestweapon == WEP_ROCKET_LAUNCHER )
 853                         self.bot_chooseweapontime += (distance  / cvar("g_balance_rocketlauncher_speed"));
 854         }
 855 };
 856
 857 .float nextaim;
 858 void havocbot_aim()
 859 {
 860         local vector selfvel, enemyvel;
 861 //      if(self.flags & FL_INWATER)
 862 //              return;
 863         if (time < self.nextaim)
 864                 return;
 865         self.nextaim = time + 0.1;
 866         selfvel = self.velocity;
 867         if (!self.waterlevel)
 868                 selfvel_z = 0;
 869         if (self.enemy)
 870         {
 871                 enemyvel = self.enemy.velocity;
 872                 if (!self.enemy.waterlevel)
 873                         enemyvel_z = 0;
 874                 lag_additem(time + self.ping, 0, 0, self.enemy, self.origin, selfvel, self.enemy.origin, enemyvel);
 875         }
 876         else
 877                 lag_additem(time + self.ping, 0, 0, world, self.origin, selfvel, self.goalcurrent.origin, '0 0 0');
 878 };
 879
 880 void havocbot_ai()
 881 {
 882         if (bot_strategytoken == self)
 883         if (!bot_strategytoken_taken)
 884         {
 885                 self.havocbot_role();
 886
 887                 // TODO: tracewalk() should take care of this job (better path finding under water)
 888                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
 889                 if(self.goalcurrent==world)
 890                 if(self.waterlevel==2 || self.aistatus & AI_STATUS_OUT_WATER)
 891                 {
 892                         // TODO: Make the bots detect and handle ladders and/or platforms
 893                         // Look for the closest waypoint out of water
 894                         local entity newgoal, head;
 895                         local float bestdistance, distance;
 896
 897                         newgoal = world;
 898                         bestdistance = 10000;
 899                         for (head = findchain(classname, "waypoint"); head; head = head.chain)
 900                         {
 901                                 distance = vlen(head.origin - self.origin);
 902                                 if(distance>10000)
 903                                         continue;
 904
 905                                 if(head.origin_z < self.origin_z)
 906                                         continue;
 907
 908                                 if(head.origin_z - self.origin_z - self.view_ofs_z > 100)
 909                                         continue;
 910
 911                                 if (pointcontents(head.origin + head.maxs + '0 0 1') != CONTENT_EMPTY)
 912                                         continue;
 913
 914                                 traceline(self.origin + self.view_ofs , head.origin, TRUE, head);
 915
 916                                 if(trace_fraction<1)
 917                                         continue;
 918
 919                                 if(distance<bestdistance)
 920                                 {
 921                                         newgoal = head;
 922                                         bestdistance = distance;
 923                                 }
 924                         }
 925
 926                         if(newgoal)
 927                         {
 928                         //      te_wizspike(newgoal.origin);
 929                                 navigation_pushroute(newgoal);
 930                         }
 931                 }
 932
 933                 // token has been used this frame
 934                 bot_strategytoken_taken = TRUE;
 935         }
 936         havocbot_chooseenemy();
 937         if (self.bot_chooseweapontime < time )
 938         {
 939                 self.bot_chooseweapontime = time + cvar("bot_ai_chooseweaponinterval");
 940                 havocbot_chooseweapon();
 941         }
 942         havocbot_aim();
 943         lag_update();
 944         if (self.bot_aimtarg)
 945         {
 946                 self.aistatus |= AI_STATUS_ATTACKING;
 947                 self.aistatus &~= AI_STATUS_ROAMING;
 948
 949                 weapon_action(self.weapon, WR_AIM);
 950                 if (cvar("bot_nofire") || IS_INDEPENDENT_PLAYER(self))
 951                 {
 952                         self.BUTTON_ATCK = FALSE;
 953                         self.BUTTON_ATCK2 = FALSE;
 954                 }
 955         }
 956         else if (self.goalcurrent)
 957         {
 958                 self.aistatus |= AI_STATUS_ROAMING;
 959                 self.aistatus &~= AI_STATUS_ATTACKING;
 960
 961                 local vector now,v,next;//,heading;
 962                 local float distance,skillblend,distanceblend,blend;
 963                 next = now = self.goalcurrent.origin - (self.origin + self.view_ofs);
 964                 distance = vlen(now);
 965                 //heading = self.velocity;
 966                 //dprint(self.goalstack01.classname,etos(self.goalstack01),"\n");
 967                 if(self.goalstack01 != self && self.goalstack01 != world && self.aistatus & AI_STATUS_RUNNING == 0)
 968                         next = self.goalstack01.origin - (self.origin + self.view_ofs);
 969                 skillblend=bound(0,(skill-2.5)*0.5,1); //lower skill player can't preturn
 970                 distanceblend=bound(0,distance/cvar("bot_ai_keyboard_distance"),1);
 971                 blend = skillblend * (1-distanceblend);
 972                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 973                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 974                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 975                 v = now + blend * (next - now);
 976                 //dprint(etos(self), " ");
 977                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 978                 //v = now * (distanceblend) + next * (1-distanceblend);
 979                 if (self.waterlevel < 2)
 980                         v_z = 0;
 981                 //dprint("walk at:", vtos(v), "\n");
 982                 //te_lightning2(world, self.origin, self.goalcurrent.origin);
 983                 bot_aimdir(v, -1);
 984         }
 985         havocbot_movetogoal();
 986 };
 987
 988 void havocbot_setupbot()
 989 {
 990         self.bot_ai = havocbot_ai;
 991         // will be updated by think code
 992         //Generate some random skill levels
 993         self.havocbot_keyboardskill=random()-0.5;
 994         havocbot_chooserole();
 995 }
 996
 997
 998 #ifdef DEBUG_BOT_GOALSTACK
 999
1000 .float goalcounter;
1001 .vector lastposition;
1002
1003 // Debug the goal stack visually
1004 void debuggoalstack()
1005 {
1006         local entity target;
1007         local vector org;
1008
1009         if(self.goalcounter==0)target=self.goalcurrent;
1010         else if(self.goalcounter==1)target=self.goalstack01;
1011         else if(self.goalcounter==2)target=self.goalstack02;
1012         else if(self.goalcounter==3)target=self.goalstack03;
1013         else if(self.goalcounter==4)target=self.goalstack04;
1014         else if(self.goalcounter==5)target=self.goalstack05;
1015         else if(self.goalcounter==6)target=self.goalstack06;
1016         else if(self.goalcounter==7)target=self.goalstack07;
1017         else if(self.goalcounter==8)target=self.goalstack08;
1018         else if(self.goalcounter==9)target=self.goalstack09;
1019         else if(self.goalcounter==10)target=self.goalstack10;
1020         else if(self.goalcounter==11)target=self.goalstack11;
1021         else if(self.goalcounter==12)target=self.goalstack12;
1022         else if(self.goalcounter==13)target=self.goalstack13;
1023         else if(self.goalcounter==14)target=self.goalstack14;
1024         else if(self.goalcounter==15)target=self.goalstack15;
1025         else if(self.goalcounter==16)target=self.goalstack16;
1026         else if(self.goalcounter==17)target=self.goalstack17;
1027         else if(self.goalcounter==18)target=self.goalstack18;
1028         else if(self.goalcounter==19)target=self.goalstack19;
1029         else if(self.goalcounter==20)target=self.goalstack20;
1030         else if(self.goalcounter==21)target=self.goalstack21;
1031         else if(self.goalcounter==22)target=self.goalstack22;
1032         else if(self.goalcounter==23)target=self.goalstack23;
1033         else if(self.goalcounter==24)target=self.goalstack24;
1034         else if(self.goalcounter==25)target=self.goalstack25;
1035         else if(self.goalcounter==26)target=self.goalstack26;
1036         else if(self.goalcounter==27)target=self.goalstack27;
1037         else if(self.goalcounter==28)target=self.goalstack28;
1038         else if(self.goalcounter==29)target=self.goalstack29;
1039         else if(self.goalcounter==30)target=self.goalstack30;
1040         else if(self.goalcounter==31)target=self.goalstack31;
1041
1042         if(target==world)
1043         {
1044                 self.goalcounter = 0;
1045                 self.lastposition='0 0 0';
1046                 return;
1047         }
1048
1049         if(self.lastposition=='0 0 0')
1050                 org = self.origin;
1051         else
1052                 org = self.lastposition;
1053
1054
1055         te_lightning2(world, org, target.origin);
1056         self.lastposition = target.origin;
1057
1058         self.goalcounter++;
1059 }
1060
1061 #endif