data/qcsrc/server/gamecommand.qc

   1 string GotoMap(string m);
   2
   3 float FullTraceFraction(vector a, vector mi, vector ma, vector b)
   4 {
   5         vector c;
   6         float white, black;
   7
   8         white = 0.001;
   9         black = 0.001;
  10
  11         c = a;
  12
  13         while(vlen(c - b) > 1)
  14         {
  15                 tracebox(c, mi, ma, b, MOVE_WORLDONLY, world);
  16                 if(!trace_startsolid)
  17                 {
  18                         black += vlen(trace_endpos - c);
  19                         c = trace_endpos;
  20                 }
  21                 tracebox_inverted(c, mi, ma, b, MOVE_WORLDONLY, world);
  22                 white += vlen(trace_endpos - c);
  23                 c = trace_endpos;
  24         }
  25
  26         return white / (black + white);
  27 }
  28
  29 float RadarMapAtPoint_Trace(float x, float y, float w, float h, float zmin, float zsize, float q)
  30 {
  31         vector a, b, mi, ma;
  32
  33         mi = '0 0 0';
  34         ma = '1 0 0' * w + '0 1 0' * h;
  35         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  36         b = '1 0 0' * x + '0 1 0' * y + '0 0 1' * (zsize + zmin);
  37
  38         return FullTraceFraction(a, mi, ma, b);
  39 }
  40 float RadarMapAtPoint_Block(float x, float y, float w, float h, float zmin, float zsize, float q)
  41 {
  42         vector o, mi, ma;
  43         float i, r;
  44         vector dz;
  45
  46         q = 256 * q - 1;
  47         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
  48
  49         mi = '0 0 0';
  50         dz = (zsize / q) * '0 0 1';
  51         ma = '1 0 0' * w + '0 1 0' * h + dz;
  52         o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  53
  54         if(x < world.absmin_x - w)
  55                 return 0;
  56         if(y < world.absmin_y - h)
  57                 return 0;
  58         if(x > world.absmax_x)
  59                 return 0;
  60         if(y > world.absmax_y)
  61                 return 0;
  62
  63         r = 0;
  64         for(i = 0; i < q; ++i)
  65         {
  66                 tracebox(o + dz * i, mi, ma, o + dz * i, MOVE_WORLDONLY, world);
  67                 if(trace_startsolid)
  68                         ++r;
  69         }
  70         return r / q;
  71 }
  72 float RadarMapAtPoint_Sample(float x, float y, float w, float h, float zmin, float zsize, float q)
  73 {
  74         vector a, b, mi, ma;
  75
  76         q *= 4; // choose q so it matches the regular algorithm in speed
  77
  78         q = 256 * q - 1;
  79         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
  80
  81         mi = '0 0 0';
  82         ma = '1 0 0' * w + '0 1 0' * h;
  83         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  84         b = '1 0 0' * w + '0 1 0' * h + '0 0 1' * zsize;
  85
  86         float c, i;
  87         c = 0;
  88
  89         for(i = 0; i < q; ++i)
  90         {
  91                 vector v;
  92                 v_x = a_x + random() * b_x;
  93                 v_y = a_y + random() * b_y;
  94                 v_z = a_z + random() * b_z;
  95                 traceline(v, v, MOVE_WORLDONLY, world);
  96                 if(trace_startsolid)
  97                         ++c;
  98         }
  99
 100         return c / q;
 101 }
 102
 103 // FF is contained twice, to map 256 to FF too
 104 // removes the need to bound()
 105 string doublehex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F303132333435363738393A3B3C3D3E3F404142434445464748494A4B4C4D4E4F505152535455565758595A5B5C5D5E5F606162636465666768696A6B6C6D6E6F707172737475767778797A7B7C7D7E7F808182838485868788898A8B8C8D8E8F909192939495969798999A9B9C9D9E9FA0A1A2A3A4A5A6A7A8A9AAABACADAEAFB0B1B2B3B4B5B6B7B8B9BABBBCBDBEBFC0C1C2C3C4C5C6C7C8C9CACBCCCDCECFD0D1D2D3D4D5D6D7D8D9DADBDCDDDEDFE0E1E2E3E4E5E6E7E8E9EAEBECEDEEEFF0F1F2F3F4F5F6F7F8F9FAFBFCFDFEFFFF";
 106
 107 float RADAR_WIDTH_MAX = 2048;
 108 float RADAR_HEIGHT_MAX = 2048;
 109 float sharpen_buffer[RADAR_WIDTH_MAX * 3];
 110
 111 void sharpen_set(float x, float v)
 112 {
 113         sharpen_buffer[x + 2 * RADAR_WIDTH_MAX] = v;
 114 }
 115
 116 float sharpen_getpixel(float x, float y)
 117 {
 118         if(x < 0)
 119                 return 0;
 120         if(x >= RADAR_WIDTH_MAX)
 121                 return 0;
 122         if(y < 0)
 123                 return 0;
 124         if(y > 2)
 125                 return 0;
 126         return sharpen_buffer[x + y * RADAR_WIDTH_MAX];
 127 }
 128
 129 float sharpen_get(float x, float a)
 130 {
 131         float sum;
 132         sum = sharpen_getpixel(x, 1);
 133         if(a == 0)
 134                 return sum;
 135         sum *= (8 + 1/a);
 136         sum -= sharpen_getpixel(x - 1, 0);
 137         sum -= sharpen_getpixel(x - 1, 1);
 138         sum -= sharpen_getpixel(x - 1, 2);
 139         sum -= sharpen_getpixel(x + 1, 0);
 140         sum -= sharpen_getpixel(x + 1, 1);
 141         sum -= sharpen_getpixel(x + 1, 2);
 142         sum -= sharpen_getpixel(x, 0);
 143         sum -= sharpen_getpixel(x, 2);
 144         return bound(0, sum * a, 1);
 145 }
 146
 147 void sharpen_shift(float w)
 148 {
 149         float i;
 150         for(i = 0; i < w; ++i)
 151         {
 152                 sharpen_buffer[i] = sharpen_buffer[i + RADAR_WIDTH_MAX];
 153                 sharpen_buffer[i + RADAR_WIDTH_MAX] = sharpen_buffer[i + 2 * RADAR_WIDTH_MAX];
 154                 sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
 155         }
 156 }
 157
 158 void sharpen_init(float w)
 159 {
 160         float i;
 161         for(i = 0; i < w; ++i)
 162         {
 163                 sharpen_buffer[i] = 0;
 164                 sharpen_buffer[i + RADAR_WIDTH_MAX] = 0;
 165                 sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
 166         }
 167 }
 168
 169 entity radarmapper;
 170 void RadarMap_Next()
 171 {
 172         if(radarmapper.count & 4)
 173         {
 174                 localcmd("quit\n");
 175         }
 176         else if(radarmapper.count & 2)
 177         {
 178                 localcmd(strcat("defer 1 \"sv_cmd radarmap --flags ", ftos(radarmapper.count), strcat(" --res ", ftos(radarmapper.size_x), " ", ftos(radarmapper.size_y), " --sharpen ", ftos(radarmapper.ltime), " --qual ", ftos(radarmapper.size_z)), "\"\n"));
 179                 GotoNextMap();
 180         }
 181         remove(radarmapper);
 182         radarmapper = world;
 183 }
 184
 185 // rough map entity
 186 //   cnt: current line
 187 //   size: pixel width/height
 188 //   maxs: cell width/height
 189 //   frame: counter
 190 void RadarMap_Think()
 191 {
 192         float i, x, l;
 193         string si;
 194
 195         if(self.frame == 0)
 196         {
 197                 // initialize
 198                 get_mi_min_max_texcoords(1);
 199                 self.mins = mi_picmin;
 200                 self.maxs_x = (mi_picmax_x - mi_picmin_x) / self.size_x;
 201                 self.maxs_y = (mi_picmax_y - mi_picmin_y) / self.size_y;
 202                 self.maxs_z = mi_max_z - mi_min_z;
 203                 print("Picture mins/maxs: ", ftos(self.maxs_x), " and ", ftos(self.maxs_y), " should match\n");
 204                 self.netname = strzone(strcat("gfx/", mi_shortname, "_radar.xpm"));
 205                 if(!(self.count & 1))
 206                 {
 207                         self.cnt = fopen(self.netname, FILE_READ);
 208                         if(self.cnt < 0)
 209                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.tga"), FILE_READ);
 210                         if(self.cnt < 0)
 211                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.png"), FILE_READ);
 212                         if(self.cnt < 0)
 213                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.jpg"), FILE_READ);
 214                         if(self.cnt >= 0)
 215                         {
 216                                 print(self.netname, " already exists, aborting (you may want to specify --force)\n");
 217                                 RadarMap_Next();
 218                                 return;
 219                         }
 220                         fclose(self.cnt);
 221                 }
 222                 self.cnt = fopen(self.netname, FILE_WRITE);
 223                 if(self.cnt < 0)
 224                 {
 225                         print("Error writing ", self.netname, "\n");
 226                         remove(self);
 227                         radarmapper = world;
 228                         return;
 229                 }
 230                 print("Writing to ", self.netname, "...\n");
 231                 fputs(self.cnt, "/* XPM */\n");
 232                 fputs(self.cnt, "static char *RadarMap[] = {\n");
 233                 fputs(self.cnt, "/* columns rows colors chars-per-pixel */\n");
 234                 fputs(self.cnt, strcat("\"", ftos(self.size_x), " ", ftos(self.size_y), " 256 2\",\n"));
 235                 for(i = 0; i < 256; ++i)
 236                 {
 237                         si = substring(doublehex, i*2, 2);
 238                         fputs(self.cnt, strcat("\"", si, " c #", si, si, si, "\",\n"));
 239                 }
 240                 self.frame += 1;
 241                 self.nextthink = time;
 242                 sharpen_init(self.size_x);
 243         }
 244         else if(self.frame <= self.size_y)
 245         {
 246                 // fill the sharpen buffer with this line
 247                 sharpen_shift(self.size_x);
 248                 i = self.count & 24;
 249
 250                 switch(i)
 251                 {
 252                         case 0:
 253                         default:
 254                                 for(x = 0; x < self.size_x; ++x)
 255                                 {
 256                                         l = RadarMapAtPoint_Block(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 257                                         sharpen_set(x, l);
 258                                 }
 259                                 break;
 260                         case 8:
 261                                 for(x = 0; x < self.size_x; ++x)
 262                                 {
 263                                         l = RadarMapAtPoint_Trace(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 264                                         sharpen_set(x, l);
 265                                 }
 266                                 break;
 267                         case 16:
 268                                 for(x = 0; x < self.size_x; ++x)
 269                                 {
 270                                         l = RadarMapAtPoint_Sample(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
 271                                         sharpen_set(x, l);
 272                                 }
 273                                 break;
 274                 }
 275
 276                 // do we have enough lines?
 277                 if(self.frame >= 2)
 278                 {
 279                         // write a pixel line
 280                         fputs(self.cnt, "\"");
 281                         for(x = 0; x < self.size_x; ++x)
 282                         {
 283                                 l = sharpen_get(x, self.ltime);
 284                                 fputs(self.cnt, substring(doublehex, 2 * floor(l * 256.0), 2));
 285                         }
 286                         if(self.frame == self.size_y)
 287                                 fputs(self.cnt, "\"\n");
 288                         else
 289                         {
 290                                 fputs(self.cnt, "\",\n");
 291                                 print(ftos(self.size_y - self.frame), " lines left\n");
 292                         }
 293                 }
 294
 295                 // is this the last line? then write back the missing line
 296                 if(self.frame == self.size_y)
 297                 {
 298                         sharpen_shift(self.size_x);
 299                         // write a pixel line
 300                         fputs(self.cnt, "\"");
 301                         for(x = 0; x < self.size_x; ++x)
 302                         {
 303                                 l = sharpen_get(x, self.ltime);
 304                                 fputs(self.cnt, substring(doublehex, 2 * floor(l * 256.0), 2));
 305                         }
 306                         if(self.frame == self.size_y)
 307                                 fputs(self.cnt, "\"\n");
 308                         else
 309                         {
 310                                 fputs(self.cnt, "\",\n");
 311                                 print(ftos(self.size_y - self.frame), " lines left\n");
 312                         }
 313                 }
 314
 315                 self.frame += 1;
 316                 self.nextthink = time;
 317         }
 318         else
 319         {
 320                 // close the file
 321                 fputs(self.cnt, "};\n");
 322                 fclose(self.cnt);
 323                 print("Finished. Please edit data/", self.netname, " with an image editing application and place it in the TGA format in the gfx folder.\n");
 324                 RadarMap_Next();
 325         }
 326 }
 327
 328 void RadarMap(float argc)
 329 {
 330         if(radarmapper)
 331                 return;
 332         float i;
 333         radarmapper = spawn();
 334         radarmapper.classname = "radarmapper";
 335         radarmapper.think = RadarMap_Think;
 336         radarmapper.nextthink = time;
 337         radarmapper.count = 0;
 338         radarmapper.ltime = 1;
 339         radarmapper.size_x = 512;
 340         radarmapper.size_y = 512;
 341         radarmapper.size_z = 1;
 342
 343         for(i = 1; i < argc; ++i)
 344         {
 345                 if(argv(i) == "--force")
 346                         radarmapper.count |= 1;
 347                 else if(argv(i) == "--loop")
 348                         radarmapper.count |= 2;
 349                 else if(argv(i) == "--quit")
 350                         radarmapper.count |= 4;
 351                 else if(argv(i) == "--block")
 352                 {
 353                         radarmapper.count &~= 24;
 354                 }
 355                 else if(argv(i) == "--trace")
 356                 {
 357                         radarmapper.count &~= 24;
 358                         radarmapper.count |= 8;
 359                 }
 360                 else if(argv(i) == "--sample")
 361                 {
 362                         radarmapper.count &~= 24;
 363                         radarmapper.count |= 16;
 364                 }
 365                 else if(argv(i) == "--flags") // for the recursive call
 366                 {
 367                         ++i;
 368                         radarmapper.count = stof(argv(i));
 369                 }
 370                 else if(argv(i) == "--sharpen") // for the recursive call
 371                 {
 372                         ++i;
 373                         radarmapper.ltime = stof(argv(i));
 374                 }
 375                 else if(argv(i) == "--res") // resolution
 376                 {
 377                         ++i;
 378                         radarmapper.size_x = stof(argv(i));
 379                         ++i;
 380                         radarmapper.size_y = stof(argv(i));
 381                 }
 382                 else if(argv(i) == "--qual") // quality multiplier
 383                 {
 384                         ++i;
 385                         radarmapper.size_z = stof(argv(i));
 386                 }
 387                 else
 388                 {
 389                         remove(radarmapper);
 390                         radarmapper = world;
 391                         print("Usage: sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample] [--sharpen N] [--res W H] [--qual Q]\n");
 392                         print("The quality factor Q is roughly proportional to the time taken.\n");
 393                         print("--trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
 394                         print("--block \n");
 395                         return;
 396                 }
 397         }
 398
 399         print("Radarmap entity spawned.\n");
 400 }
 401
 402 void BBox()
 403 {
 404         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
 405         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
 406         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
 407         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
 408         print("Solid bounding box size:");
 409
 410         tracebox('1 0 0' * world.absmin_x,
 411                  '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 412                  '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 413                  '1 0 0' * world.absmax_x,
 414                          MOVE_WORLDONLY,
 415                          world);
 416         if(trace_startsolid)
 417                 print(" ", ftos(world.absmin_x));
 418         else
 419                 print(" ", ftos(trace_endpos_x));
 420
 421         tracebox('0 1 0' * world.absmin_y,
 422                  '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 423                  '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 424                  '0 1 0' * world.absmax_y,
 425                          MOVE_WORLDONLY,
 426                          world);
 427         if(trace_startsolid)
 428                 print(" ", ftos(world.absmin_y));
 429         else
 430                 print(" ", ftos(trace_endpos_y));
 431
 432         tracebox('0 0 1' * world.absmin_z,
 433                  '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 434                  '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 435                  '0 0 1' * world.absmax_z,
 436                          MOVE_WORLDONLY,
 437                          world);
 438         if(trace_startsolid)
 439                 print(" ", ftos(world.absmin_z));
 440         else
 441                 print(" ", ftos(trace_endpos_z));
 442
 443         tracebox('1 0 0' * world.absmax_x,
 444                  '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
 445                  '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
 446                  '1 0 0' * world.absmin_x,
 447                          MOVE_WORLDONLY,
 448                          world);
 449         if(trace_startsolid)
 450                 print(" ", ftos(world.absmax_x));
 451         else
 452                 print(" ", ftos(trace_endpos_x));
 453
 454         tracebox('0 1 0' * world.absmax_y,
 455                  '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
 456                  '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
 457                  '0 1 0' * world.absmin_y,
 458                          MOVE_WORLDONLY,
 459                          world);
 460         if(trace_startsolid)
 461                 print(" ", ftos(world.absmax_y));
 462         else
 463                 print(" ", ftos(trace_endpos_y));
 464
 465         tracebox('0 0 1' * world.absmax_z,
 466                  '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
 467                  '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
 468                  '0 0 1' * world.absmin_z,
 469                          MOVE_WORLDONLY,
 470                          world);
 471         if(trace_startsolid)
 472                 print(" ", ftos(world.absmax_z));
 473         else
 474                 print(" ", ftos(trace_endpos_z));
 475
 476         print("\n");
 477 }
 478
 479 void EffectIndexDump()
 480 {
 481         float d;
 482         float fh;
 483         string s;
 484
 485         d = db_create();
 486
 487         print("begin of effects list\n");
 488         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 489         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 490         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 491         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 492         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 493         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 494         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 495         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 496         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 497         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 498         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 499         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 500         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 501         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 502         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 503         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 504         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 505         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 506         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 507         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 508         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 509         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 510         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 511         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 512         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 513         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 514         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 515         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 516         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 517         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 518         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 519         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 520         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 521         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 522         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 523
 524         fh = fopen("effectinfo.txt", FILE_READ);
 525         while((s = fgets(fh)))
 526         {
 527                 tokenize_insane(s); // tokenize_sane would hit the loop counter :(
 528                 if(argv(0) == "effect")
 529                 {
 530                         if(db_get(d, argv(1)) != "1")
 531                         {
 532                                 if(particleeffectnum(argv(1)) >= 0)
 533                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 534                                 db_put(d, argv(1), "1");
 535                         }
 536                 }
 537         }
 538         print("end of effects list\n");
 539
 540         db_close(d);
 541 }
 542
 543 void make_mapinfo_Think()
 544 {
 545         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
 546         {
 547                 print("Done rebuiling mapinfos.\n");
 548                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 549                 remove(self);
 550         }
 551         else
 552         {
 553                 self.think = make_mapinfo_Think;
 554                 self.nextthink = time;
 555         }
 556 }
 557
 558 void GameCommand(string command)
 559 {
 560         float argc;
 561         entity client;
 562         float entno;
 563         argc = tokenize_sane(command);
 564
 565         if(argv(0) == "help" || argc == 0)
 566         {
 567                 print("Usage: sv_cmd COMMAND..., where possible commands are:\n");
 568                 print("  adminmsg clientnumber \"message\"\n");
 569                 print("  teamstatus\n");
 570                 print("  printstats\n");
 571                 print("  make_mapinfo\n");
 572                 print("  gametype dm|ctf|...\n");
 573                 print("  savedb filename\n");
 574                 print("  dumpdb filename\n");
 575                 print("  loaddb filename\n");
 576                 print("  allready\n");
 577                 print("  effectindexdump\n");
 578                 print("  radarmap [--force] [--quit | --loop] [sharpness]\n");
 579                 print("  bbox\n");
 580                 print("  cvar_changes\n");
 581                 print("  find classname\n");
 582                 GameCommand_Vote("help", world);
 583                 GameCommand_Ban("help");
 584                 GameCommand_Generic("help");
 585                 return;
 586         }
 587
 588         if(GameCommand_Vote(command, world))
 589                 return;
 590
 591         if(GameCommand_Ban(command))
 592                 return;
 593
 594         if(GameCommand_Generic(command))
 595                 return;
 596
 597         if(argv(0) == "printstats")
 598         {
 599                 DumpStats(FALSE);
 600                 return;
 601         }
 602
 603         if(argv(0) == "make_mapinfo")
 604         {
 605                 entity e;
 606                 e = spawn();
 607                 e.classname = "make_mapinfo";
 608                 e.think = make_mapinfo_Think;
 609                 e.nextthink = time;
 610                 MapInfo_Enumerate();
 611                 return;
 612         }
 613
 614         if(argv(0) == "warp") if(argc == 2) if(cvar("g_campaign"))
 615         {
 616                 CampaignLevelWarp(stof(argv(1)));
 617                 return;
 618         }
 619
 620         if(argv(0) == "gotomap") if(argc == 2)
 621         {
 622                 print(GotoMap(argv(1)), "\n");
 623                 return;
 624         }
 625
 626         if(argv(0) == "gametype") if(argc == 2)
 627         {
 628                 float t, tsave;
 629                 string s;
 630                 s = argv(1);
 631                 t = MapInfo_Type_FromString(s);
 632                 tsave = MapInfo_CurrentGametype();
 633                 if(t)
 634                 {
 635                         MapInfo_SwitchGameType(t);
 636                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, MAPINFO_FLAG_HIDDEN, 0);
 637                         if(MapInfo_count > 0)
 638                         {
 639                                 bprint("Game type successfully switched to ", s, "\n");
 640                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 641                         }
 642                         else
 643                         {
 644                                 bprint("Cannot use this game type: no map for it found\n");
 645                                 MapInfo_SwitchGameType(tsave);
 646                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 647                         }
 648                 }
 649                 else
 650                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 651                 return;
 652         }
 653
 654         if(argv(0) == "adminmsg") if(argc == 3)
 655         {
 656                 entno = stof(argv(1));
 657                 client = world;
 658                 if(entno <= maxclients)
 659                         client = edict_num(entno);
 660                 if(client.flags & FL_CLIENT)
 661                 {
 662                         centerprint_atprio(client, CENTERPRIO_ADMIN, strcat("^3SERVER ADMIN:\n\n^7", argv(2)));
 663                         sprint(client, strcat("\{1}\{13}^3SERVER ADMIN^7: ", argv(2), "\n"));
 664                         print("Message sent to ", client.netname, "\n");
 665                 }
 666                 else
 667                         print("Client not found\n");
 668                 return;
 669         }
 670
 671         if(argv(0) == "savedb") if(argc == 2)
 672         {
 673                 db_save(ServerProgsDB, argv(1));
 674                 print("DB saved.\n");
 675                 return;
 676         }
 677
 678         if(argv(0) == "dumpdb") if(argc == 2)
 679         {
 680                 db_dump(ServerProgsDB, argv(1));
 681                 print("DB dumped.\n");
 682                 return;
 683         }
 684
 685         if(argv(0) == "loaddb") if(argc == 2)
 686         {
 687                 db_close(ServerProgsDB);
 688                 ServerProgsDB = db_load(argv(1));
 689                 print("DB loaded.\n");
 690                 return;
 691         }
 692         if (argv(0) == "nospectators")
 693         {
 694                 blockSpectators = 1;
 695                 local entity plr;
 696                 FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
 697                 {
 698                         if(plr.classname == "spectator" || plr.classname == "observer")
 699                         {
 700                                 plr.spectatortime = time;
 701                                 sprint(plr, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 702                         }
 703                 }
 704                 bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds!\n"));
 705                 return;
 706         }
 707         if (argv(0) == "lockteams")
 708         {
 709                 if(teamplay)
 710                 {
 711                         lockteams = 1;
 712                         bprint("^1The teams are now locked.\n");
 713                 }
 714                 else
 715                         bprint("That command can only be used in a team-based gamemode.\n");
 716                 return;
 717         }
 718         if (argv(0) == "unlockteams")
 719         {
 720                 if(teamplay)
 721                 {
 722                         lockteams = 0;
 723                         bprint("^1The teams are now unlocked.\n");
 724                 }
 725                 else
 726                         bprint("That command can only be used in a team-based gamemode.\n");
 727                 return;
 728         }
 729         if (argv(0) == "movetoteam") if(argc == 3)
 730         {
 731                 entno = stof(argv(1));
 732                 client = world;
 733                 if(entno <= maxclients)
 734                         client = edict_num(entno);
 735                 if(client.flags & FL_CLIENT)
 736                 {
 737                         float lt;
 738                         lt = lockteams;
 739                         lockteams = 0;
 740
 741                         self = client;
 742                         SV_ParseClientCommand(strcat("selectteam ", argv(2)));
 743
 744                         lockteams = lt;
 745                 }
 746                 else
 747                         print("Client not found\n");
 748                 return;
 749         }
 750         if (argv(0) == "teamstatus")
 751         {
 752                 Score_NicePrint(world);
 753                 return;
 754         }
 755         if (argv(0) == "allready")
 756         {
 757                 ReadyRestart();
 758                 return;
 759         }
 760         if (argv(0) == "effectindexdump")
 761         {
 762                 EffectIndexDump();
 763                 return;
 764         }
 765         if (argv(0) == "radarmap")
 766         {
 767                 RadarMap(argc);
 768                 return;
 769         }
 770         if (argv(0) == "bbox")
 771         {
 772                 BBox();
 773                 return;
 774         }
 775         if (argv(0) == "cvar_changes")
 776         {
 777                 print(cvar_changes);
 778                 return;
 779         }
 780         if (argv(0) == "find") if(argc == 2)
 781         {
 782                 for(client = world; (client = find(client, classname, argv(1))); )
 783                         print(etos(client), "\n");
 784                 return;
 785         }
 786         if (argv(0) == "records")
 787         {
 788                 strunzone(records_reply);
 789                 records_reply = strzone(getrecords());
 790                 print(records_reply);
 791                 return;
 792         }
 793
 794         print("Invalid command. For a list of supported commands, try sv_cmd help.\n");
 795 }
 796