data/qcsrc/server/gamecommand.qc

   1 string GotoMap(string m);
   2
   3 #if 0
   4 // TODO make this algorithm work (no idea why it is failing), it would be much faster
   5 float FullTraceFraction(vector a, vector mi, vector ma, vector b)
   6 {
   7         vector c;
   8         float d;
   9         if(a_z > b_z)
  10                 return 0;
  11         tracebox(a, mi, ma, b, MOVE_WORLDONLY, world);
  12         if(trace_startsolid)
  13         {
  14                 // a leaves solid, then hits trace_endpos
  15                 // where does a leave solid?
  16                 c = trace_endpos;
  17                 tracebox(c, mi, ma, a, MOVE_WORLDONLY, world);
  18                 // a to trace_endpos is solid
  19                 // trace_endpos to c is not solid
  20                 d = trace_endpos_z - a_z;
  21                 return FullTraceFraction(c + '0 0 1', mi, ma, b) + d;
  22         }
  23         else
  24         {
  25                 // a hits trace_endpos
  26                 return FullTraceFraction(trace_endpos + '0 0 1', mi, ma, b);
  27         }
  28 }
  29
  30 float RoughMapAtPoint(float x, float y, float w, float h)
  31 {
  32         vector a, b, mi, ma;
  33         mi = '0 0 0';
  34         ma = '1 0 0' * w + '0 1 0' * h;
  35         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * world.mins_z;
  36         b = '1 0 0' * x + '0 1 0' * y + '0 0 1' * world.maxs_z;
  37         return floor(FullTraceFraction(a, mi, ma, b) / (world.maxs_z - world.mins_z) * 255);
  38 }
  39 #else
  40 float RoughMapAtPoint(float x, float y, float w, float h, float zmin, float zsize)
  41 {
  42         vector o, mi, ma;
  43         float i, r;
  44         vector dz;
  45         mi = '0 0 0';
  46         dz = (zsize / 256) * '0 0 1';
  47         ma = '1 0 0' * w + '0 1 0' * h + dz;
  48         o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
  49
  50         if(x < world.mins_x - w)
  51                 return 0;
  52         if(y < world.mins_y - h)
  53                 return 0;
  54         if(x > world.maxs_x)
  55                 return 0;
  56         if(y > world.maxs_y)
  57                 return 0;
  58
  59         r = 0;
  60         for(i = 0; i < 255; ++i)
  61         {
  62                 tracebox(o + dz * i, mi, ma, o + dz * i, MOVE_WORLDONLY, world);
  63                 if(trace_startsolid)
  64                         ++r;
  65         }
  66         return r; // 0 .. 255
  67 }
  68 #endif
  69
  70 string doublehex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F303132333435363738393A3B3C3D3E3F404142434445464748494A4B4C4D4E4F505152535455565758595A5B5C5D5E5F606162636465666768696A6B6C6D6E6F707172737475767778797A7B7C7D7E7F808182838485868788898A8B8C8D8E8F909192939495969798999A9B9C9D9E9FA0A1A2A3A4A5A6A7A8A9AAABACADAEAFB0B1B2B3B4B5B6B7B8B9BABBBCBDBEBFC0C1C2C3C4C5C6C7C8C9CACBCCCDCECFD0D1D2D3D4D5D6D7D8D9DADBDCDDDEDFE0E1E2E3E4E5E6E7E8E9EAEBECEDEEEFF0F1F2F3F4F5F6F7F8F9FAFBFCFDFEFF";
  71
  72 entity roughmapper;
  73 // rough map entity
  74 //   cnt: current line
  75 //   size: pixel width/height
  76 //   maxs: cell width/height
  77 //   frame: counter
  78 void RoughMap_Think()
  79 {
  80         float i, x, l;
  81         string si;
  82
  83         if(self.frame == 0)
  84         {
  85                 // initialize
  86                 get_mi_min_max();
  87                 self.size_x = 512;
  88                 self.size_y = 512;
  89                 self.mins = mi_picmin;
  90                 self.maxs_x = (mi_picmax_x - mi_picmin_x) / self.size_x;
  91                 self.maxs_y = (mi_picmax_y - mi_picmin_y) / self.size_y;
  92                 self.maxs_z = mi_max_z - mi_min_z;
  93                 print("Picture mins/maxs: ", ftos(self.maxs_x), " and ", ftos(self.maxs_y), " should match\n");
  94                 self.netname = strzone(strcat("gfx/", mi_shortname, "_mini.xpm"));
  95                 if(!(self.count & 1))
  96                 {
  97                         self.cnt = fopen(self.netname, FILE_READ);
  98                         if(self.cnt >= 0)
  99                         {
 100                                 print(self.netname, " already exists, aborting (you may want to specify --force)\n");
 101                                 if(self.count & 2)
 102                                 {
 103                                         if(self.count & 1)
 104                                                 localcmd("defer 1 \"sv_cmd roughmap --force --loop\"\n");
 105                                         else
 106                                                 localcmd("defer 1 \"sv_cmd roughmap --loop\"\n");
 107                                         GotoNextMap();
 108                                 }
 109                                 remove(self);
 110                                 return;
 111                         }
 112                 }
 113                 self.cnt = fopen(self.netname, FILE_WRITE);
 114                 if(self.cnt < 0)
 115                 {
 116                         print("Error writing ", self.netname, "\n");
 117                         remove(self);
 118                         roughmapper = world;
 119                         return;
 120                 }
 121                 print("Writing to ", self.netname, "...\n");
 122                 fputs(self.cnt, "/* XPM */\n");
 123                 fputs(self.cnt, "static char *RoughMap[] = {\n");
 124                 fputs(self.cnt, "/* columns rows colors chars-per-pixel */\n");
 125                 fputs(self.cnt, strcat("\"", ftos(self.size_x), " ", ftos(self.size_y), " 256 2\",\n"));
 126                 for(i = 0; i < 256; ++i)
 127                 {
 128                         si = substring(doublehex, i*2, 2);
 129                         fputs(self.cnt, strcat("\"", si, " c #", si, si, si, "\",\n"));
 130                 }
 131                 self.frame += 1;
 132                 self.nextthink = time;
 133         }
 134         else if(self.frame <= self.size_y)
 135         {
 136                 // write a pixel line
 137                 fputs(self.cnt, "\"");
 138                 for(x = 0; x < self.size_x; ++x)
 139                 {
 140                         l = RoughMapAtPoint(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z);
 141                         fputs(self.cnt, substring(doublehex, 2 * l, 2));
 142                 }
 143                 if(self.frame == self.size_y)
 144                         fputs(self.cnt, "\"\n");
 145                 else
 146                 {
 147                         fputs(self.cnt, "\",\n");
 148                         print(ftos(self.size_y - self.frame), " lines left\n");
 149                 }
 150                 self.frame += 1;
 151                 self.nextthink = time;
 152         }
 153         else
 154         {
 155                 // close the file
 156                 fputs(self.cnt, "};\n");
 157                 fclose(self.cnt);
 158                 print("Finished. Please edit data/", self.netname, " with an image editing application and place it in the TGA format in the gfx folder.\n");
 159                 if(self.count & 2)
 160                 {
 161                         if(self.count & 1)
 162                                 localcmd("defer 1 \"sv_cmd roughmap --force --loop\"\n");
 163                         else
 164                                 localcmd("defer 1 \"sv_cmd roughmap --loop\"\n");
 165                         GotoNextMap();
 166                 }
 167                 remove(self);
 168                 roughmapper = world;
 169         }
 170 }
 171
 172 void RoughMap(float argc)
 173 {
 174         if(roughmapper)
 175                 return;
 176         float i;
 177         roughmapper = spawn();
 178         roughmapper.classname = "roughmapper";
 179         roughmapper.think = RoughMap_Think;
 180         roughmapper.nextthink = time;
 181         roughmapper.count = 0;
 182
 183         for(i = 1; i < argc; ++i)
 184         {
 185                 if(argv(i) == "--force")
 186                         roughmapper.count |= 1;
 187                 if(argv(i) == "--loop")
 188                         roughmapper.count |= 2;
 189         }
 190 }
 191
 192 void EffectIndexDump()
 193 {
 194         float d;
 195         float fh;
 196         string s;
 197
 198         d = db_create();
 199
 200         print("begin of effects list\n");
 201         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
 202         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
 203         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
 204         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
 205         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
 206         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
 207         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
 208         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
 209         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
 210         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
 211         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
 212         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
 213         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
 214         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
 215         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
 216         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
 217         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
 218         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
 219         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
 220         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
 221         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
 222         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
 223         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
 224         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
 225         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
 226         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
 227         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
 228         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
 229         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
 230         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
 231         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
 232         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
 233         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
 234         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
 235         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
 236
 237         fh = fopen("effectinfo.txt", FILE_READ);
 238         while((s = fgets(fh)))
 239         {
 240                 tokenize(s);
 241                 if(argv(0) == "effect")
 242                 {
 243                         if(db_get(d, argv(1)) != "1")
 244                         {
 245                                 if(particleeffectnum(argv(1)) >= 0)
 246                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
 247                                 db_put(d, argv(1), "1");
 248                         }
 249                 }
 250         }
 251         print("end of effects list\n");
 252
 253         db_close(d);
 254 }
 255
 256 void make_mapinfo_Think()
 257 {
 258         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 1))
 259         {
 260                 print("Done rebuiling mapinfos.\n");
 261                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 262                 remove(self);
 263         }
 264         else
 265         {
 266                 self.think = make_mapinfo_Think;
 267                 self.nextthink = time;
 268         }
 269 }
 270
 271 void GameCommand(string command)
 272 {
 273         float argc;
 274         entity client;
 275         float entno;
 276         argc = tokenize(command);
 277
 278         if(argv(0) == "help" || argc == 0)
 279         {
 280                 print("Usage: sv_cmd COMMAND..., where possible commands are:\n");
 281                 print("  adminmsg clientnumber \"message\"\n");
 282                 print("  teamstatus\n");
 283                 print("  printstats\n");
 284                 print("  make_mapinfo\n");
 285                 print("  gametype dm|ctf|...\n");
 286                 print("  savedb filename\n");
 287                 print("  dumpdb filename\n");
 288                 print("  loaddb filename\n");
 289                 print("  allready\n");
 290                 print("  effectindexdump\n");
 291                 print("  roughmap\n");
 292                 GameCommand_Vote("help", world);
 293                 GameCommand_Ban("help");
 294                 GameCommand_Generic("help");
 295                 return;
 296         }
 297
 298         if(GameCommand_Vote(command, world))
 299                 return;
 300
 301         if(GameCommand_Ban(command))
 302                 return;
 303
 304         if(GameCommand_Generic(command))
 305                 return;
 306
 307         if(argv(0) == "printstats")
 308         {
 309                 DumpStats(FALSE);
 310                 return;
 311         }
 312
 313         if(argv(0) == "make_mapinfo")
 314         {
 315                 entity e;
 316                 e = spawn();
 317                 e.classname = "make_mapinfo";
 318                 e.think = make_mapinfo_Think;
 319                 e.nextthink = time;
 320                 MapInfo_Enumerate();
 321                 return;
 322         }
 323
 324         if(argv(0) == "warp") if(argc == 2) if(cvar("g_campaign"))
 325         {
 326                 CampaignLevelWarp(stof(argv(1)));
 327                 return;
 328         }
 329
 330         if(argv(0) == "gotomap") if(argc == 2)
 331         {
 332                 print(GotoMap(argv(1)), "\n");
 333                 return;
 334         }
 335
 336         if(argv(0) == "gametype") if(argc == 2)
 337         {
 338                 float t, tsave;
 339                 string s;
 340                 s = argv(1);
 341                 t = MapInfo_Type_FromString(s);
 342                 tsave = MapInfo_CurrentGametype();
 343                 if(t)
 344                 {
 345                         MapInfo_SwitchGameType(t);
 346                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 347                         if(MapInfo_count > 0)
 348                         {
 349                                 bprint("Game type successfully switched to ", s, "\n");
 350                         }
 351                         else
 352                         {
 353                                 bprint("Cannot use this game type: no map for it found\n");
 354                                 MapInfo_SwitchGameType(tsave);
 355                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 356                         }
 357                 }
 358                 else
 359                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
 360                 return;
 361         }
 362
 363         if(argv(0) == "adminmsg") if(argc == 3)
 364         {
 365                 entno = stof(argv(1));
 366                 client = world;
 367                 if(entno <= maxclients)
 368                         client = edict_num(entno);
 369                 if(client.flags & FL_CLIENT)
 370                 {
 371                         centerprint_atprio(client, CENTERPRIO_ADMIN, strcat("^3SERVER ADMIN:\n\n^7", argv(2)));
 372                         sprint(client, strcat("\{1}\{13}^3SERVER ADMIN^7: ", argv(2), "\n"));
 373                         print("Message sent to ", client.netname, "\n");
 374                 }
 375                 else
 376                         print("Client not found\n");
 377                 return;
 378         }
 379
 380         if(argv(0) == "savedb") if(argc == 2)
 381         {
 382                 db_save(ServerProgsDB, argv(1));
 383                 print("DB saved.\n");
 384                 return;
 385         }
 386
 387         if(argv(0) == "dumpdb") if(argc == 2)
 388         {
 389                 db_dump(ServerProgsDB, argv(1));
 390                 print("DB dumped.\n");
 391                 return;
 392         }
 393
 394         if(argv(0) == "loaddb") if(argc == 2)
 395         {
 396                 db_close(ServerProgsDB);
 397                 ServerProgsDB = db_load(argv(1));
 398                 print("DB loaded.\n");
 399                 return;
 400         }
 401         if (argv(0) == "nospectators")
 402         {
 403                 blockSpectators = 1;
 404                 local entity plr;
 405                 FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
 406                 {
 407                         if(plr.classname == "spectator" || plr.classname == "observer")
 408                         {
 409                                 plr.spectatortime = time;
 410                                 sprint(plr, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
 411                         }
 412                 }
 413                 bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds!\n"));
 414                 return;
 415         }
 416         if (argv(0) == "lockteams")
 417         {
 418                 if(teamplay)
 419                 {
 420                         lockteams = 1;
 421                         bprint("^1The teams are now locked.\n");
 422                 }
 423                 else
 424                         bprint("That command can only be used in a team-based gamemode.\n");
 425                 return;
 426         }
 427         if (argv(0) == "unlockteams")
 428         {
 429                 if(teamplay)
 430                 {
 431                         lockteams = 0;
 432                         bprint("^1The teams are now unlocked.\n");
 433                 }
 434                 else
 435                         bprint("That command can only be used in a team-based gamemode.\n");
 436                 return;
 437         }
 438         if (argv(0) == "movetoteam") if(argc == 3)
 439         {
 440                 entno = stof(argv(1));
 441                 client = world;
 442                 if(entno <= maxclients)
 443                         client = edict_num(entno);
 444                 if(client.flags & FL_CLIENT)
 445                 {
 446                         float lt;
 447                         lt = lockteams;
 448                         lockteams = 0;
 449
 450                         self = client;
 451                         SV_ParseClientCommand(strcat("selectteam ", argv(2)));
 452
 453                         lockteams = lt;
 454                 }
 455                 else
 456                         print("Client not found\n");
 457                 return;
 458         }
 459         if (argv(0) == "teamstatus")
 460         {
 461                 Score_NicePrint(world);
 462                 return;
 463         }
 464         if (argv(0) == "allready")
 465         {
 466                 ReadyRestart();
 467                 return;
 468         }
 469         if (argv(0) == "effectindexdump")
 470         {
 471                 EffectIndexDump();
 472                 return;
 473         }
 474         if (argv(0) == "roughmap")
 475         {
 476                 RoughMap(argc);
 477                 return;
 478         }
 479         if (argv(0) == "cvar_changes")
 480         {
 481                 print(cvar_changes);
 482                 return;
 483         }
 484
 485         print("Invalid command. For a list of supported commands, try sv_cmd help.\n");
 486 }
 487