entities.def update; new cvar checksums
[divverent/nexuiz.git] / data / qcsrc / server / gamecommand.qc
1 string GotoMap(string m);
2
3 float FullTraceFraction(vector a, vector mi, vector ma, vector b)
4 {
5         vector c;
6         float white, black;
7
8         white = 0.001;
9         black = 0.001;
10
11         c = a;
12
13         float n, m;
14         n = m = 0;
15
16         while(vlen(c - b) > 1)
17         {
18                 ++m;
19
20                 tracebox(c, mi, ma, b, MOVE_WORLDONLY, world);
21                 ++n;
22
23                 if(!trace_startsolid)
24                 {
25                         black += vlen(trace_endpos - c);
26                         c = trace_endpos;
27                 }
28
29                 n += tracebox_inverted(c, mi, ma, b, MOVE_WORLDONLY, world);
30
31                 white += vlen(trace_endpos - c);
32                 c = trace_endpos;
33         }
34
35         if(n > 200)
36                 dprint("HOLY SHIT! FullTraceFraction: ", ftos(n), " total traces, ", ftos(m), " iterations\n");
37
38         return white / (black + white);
39 }
40
41 float RadarMapAtPoint_Trace(float x, float y, float w, float h, float zmin, float zsize, float q)
42 {
43         vector a, b, mi, ma;
44
45         mi = '0 0 0';
46         ma = '1 0 0' * w + '0 1 0' * h;
47         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
48         b = '1 0 0' * x + '0 1 0' * y + '0 0 1' * (zsize + zmin);
49
50         return FullTraceFraction(a, mi, ma, b);
51 }
52 float RadarMapAtPoint_Block(float x, float y, float w, float h, float zmin, float zsize, float q)
53 {
54         vector o, mi, ma;
55         float i, r;
56         vector dz;
57
58         q = 256 * q - 1;
59         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
60
61         mi = '0 0 0';
62         dz = (zsize / q) * '0 0 1';
63         ma = '1 0 0' * w + '0 1 0' * h + dz;
64         o = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
65
66         if(x < world.absmin_x - w)
67                 return 0;
68         if(y < world.absmin_y - h)
69                 return 0;
70         if(x > world.absmax_x)
71                 return 0;
72         if(y > world.absmax_y)
73                 return 0;
74         
75         r = 0;
76         for(i = 0; i < q; ++i)
77         {
78                 tracebox(o + dz * i, mi, ma, o + dz * i, MOVE_WORLDONLY, world);
79                 if(trace_startsolid)
80                         ++r;
81         }
82         return r / q;
83 }
84 float RadarMapAtPoint_Sample(float x, float y, float w, float h, float zmin, float zsize, float q)
85 {
86         vector a, b, mi, ma;
87
88         q *= 4; // choose q so it matches the regular algorithm in speed
89
90         q = 256 * q - 1;
91         // 256q-1 is the ideal sample count to map equal amount of sample values to one pixel value
92
93         mi = '0 0 0';
94         ma = '1 0 0' * w + '0 1 0' * h;
95         a = '1 0 0' * x + '0 1 0' * y + '0 0 1' * zmin;
96         b = '1 0 0' * w + '0 1 0' * h + '0 0 1' * zsize;
97         
98         float c, i;
99         c = 0;
100
101         for(i = 0; i < q; ++i)
102         {
103                 vector v;
104                 v_x = a_x + random() * b_x;
105                 v_y = a_y + random() * b_y;
106                 v_z = a_z + random() * b_z;
107                 traceline(v, v, MOVE_WORLDONLY, world);
108                 if(trace_startsolid)
109                         ++c;
110         }
111
112         return c / q;
113 }
114
115 // FF is contained twice, to map 256 to FF too
116 // removes the need to bound()
117 string doublehex = "000102030405060708090A0B0C0D0E0F101112131415161718191A1B1C1D1E1F202122232425262728292A2B2C2D2E2F303132333435363738393A3B3C3D3E3F404142434445464748494A4B4C4D4E4F505152535455565758595A5B5C5D5E5F606162636465666768696A6B6C6D6E6F707172737475767778797A7B7C7D7E7F808182838485868788898A8B8C8D8E8F909192939495969798999A9B9C9D9E9FA0A1A2A3A4A5A6A7A8A9AAABACADAEAFB0B1B2B3B4B5B6B7B8B9BABBBCBDBEBFC0C1C2C3C4C5C6C7C8C9CACBCCCDCECFD0D1D2D3D4D5D6D7D8D9DADBDCDDDEDFE0E1E2E3E4E5E6E7E8E9EAEBECEDEEEFF0F1F2F3F4F5F6F7F8F9FAFBFCFDFEFFFF";
118
119 float RADAR_WIDTH_MAX = 2048;
120 float RADAR_HEIGHT_MAX = 2048;
121 float sharpen_buffer[RADAR_WIDTH_MAX * 3];
122
123 void sharpen_set(float x, float v)
124 {
125         sharpen_buffer[x + 2 * RADAR_WIDTH_MAX] = v;
126 }
127
128 float sharpen_getpixel(float x, float y)
129 {
130         if(x < 0)
131                 return 0;
132         if(x >= RADAR_WIDTH_MAX)
133                 return 0;
134         if(y < 0)
135                 return 0;
136         if(y > 2)
137                 return 0;
138         return sharpen_buffer[x + y * RADAR_WIDTH_MAX];
139 }
140
141 float sharpen_get(float x, float a)
142 {
143         float sum;
144         sum = sharpen_getpixel(x, 1);
145         if(a == 0)
146                 return sum;
147         sum *= (8 + 1/a);
148         sum -= sharpen_getpixel(x - 1, 0);
149         sum -= sharpen_getpixel(x - 1, 1);
150         sum -= sharpen_getpixel(x - 1, 2);
151         sum -= sharpen_getpixel(x + 1, 0);
152         sum -= sharpen_getpixel(x + 1, 1);
153         sum -= sharpen_getpixel(x + 1, 2);
154         sum -= sharpen_getpixel(x, 0);
155         sum -= sharpen_getpixel(x, 2);
156         return bound(0, sum * a, 1);
157 }
158
159 void sharpen_shift(float w)
160 {
161         float i;
162         for(i = 0; i < w; ++i)
163         {
164                 sharpen_buffer[i] = sharpen_buffer[i + RADAR_WIDTH_MAX];
165                 sharpen_buffer[i + RADAR_WIDTH_MAX] = sharpen_buffer[i + 2 * RADAR_WIDTH_MAX];
166                 sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
167         }
168 }
169
170 void sharpen_init(float w)
171 {
172         float i;
173         for(i = 0; i < w; ++i)
174         {
175                 sharpen_buffer[i] = 0;
176                 sharpen_buffer[i + RADAR_WIDTH_MAX] = 0;
177                 sharpen_buffer[i + 2 * RADAR_WIDTH_MAX] = 0;
178         }
179 }
180
181 entity radarmapper;
182 void RadarMap_Next()
183 {
184         if(radarmapper.count & 4)
185         {
186                 localcmd("quit\n");
187         }
188         else if(radarmapper.count & 2)
189         {
190                 localcmd(strcat("defer 1 \"sv_cmd radarmap --flags ", ftos(radarmapper.count), strcat(" --res ", ftos(radarmapper.size_x), " ", ftos(radarmapper.size_y), " --sharpen ", ftos(radarmapper.ltime), " --qual ", ftos(radarmapper.size_z)), "\"\n"));
191                 GotoNextMap();
192         }
193         remove(radarmapper);
194         radarmapper = world;
195 }
196
197 // rough map entity
198 //   cnt: current line
199 //   size: pixel width/height
200 //   maxs: cell width/height
201 //   frame: counter
202 void RadarMap_Think()
203 {
204         float i, x, l;
205         string si;
206
207         if(self.frame == 0)
208         {
209                 // initialize
210                 get_mi_min_max_texcoords(1);
211                 self.mins = mi_picmin;
212                 self.maxs_x = (mi_picmax_x - mi_picmin_x) / self.size_x;
213                 self.maxs_y = (mi_picmax_y - mi_picmin_y) / self.size_y;
214                 self.maxs_z = mi_max_z - mi_min_z;
215                 print("Picture mins/maxs: ", ftos(self.maxs_x), " and ", ftos(self.maxs_y), " should match\n");
216                 self.netname = strzone(strcat("gfx/", mi_shortname, "_radar.xpm"));
217                 if(!(self.count & 1))
218                 {
219                         self.cnt = fopen(self.netname, FILE_READ);
220                         if(self.cnt < 0)
221                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.tga"), FILE_READ);
222                         if(self.cnt < 0)
223                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.png"), FILE_READ);
224                         if(self.cnt < 0)
225                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_radar.jpg"), FILE_READ);
226                         if(self.cnt < 0)
227                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.tga"), FILE_READ);
228                         if(self.cnt < 0)
229                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.png"), FILE_READ);
230                         if(self.cnt < 0)
231                                 self.cnt = fopen(strcat("gfx/", mi_shortname, "_mini.jpg"), FILE_READ);
232                         if(self.cnt >= 0)
233                         {
234                                 fclose(self.cnt);
235
236                                 print(self.netname, " already exists, aborting (you may want to specify --force)\n");
237                                 RadarMap_Next();
238                                 return;
239                         }
240                 }
241                 self.cnt = fopen(self.netname, FILE_WRITE);
242                 if(self.cnt < 0)
243                 {
244                         print("Error writing ", self.netname, "\n");
245                         remove(self);
246                         radarmapper = world;
247                         return;
248                 }
249                 print("Writing to ", self.netname, "...\n");
250                 fputs(self.cnt, "/* XPM */\n");
251                 fputs(self.cnt, "static char *RadarMap[] = {\n");
252                 fputs(self.cnt, "/* columns rows colors chars-per-pixel */\n");
253                 fputs(self.cnt, strcat("\"", ftos(self.size_x), " ", ftos(self.size_y), " 256 2\",\n"));
254                 for(i = 0; i < 256; ++i)
255                 {
256                         si = substring(doublehex, i*2, 2);
257                         fputs(self.cnt, strcat("\"", si, " c #", si, si, si, "\",\n"));
258                 }
259                 self.frame += 1;
260                 self.nextthink = time;
261                 sharpen_init(self.size_x);
262         }
263         else if(self.frame <= self.size_y)
264         {
265                 // fill the sharpen buffer with this line
266                 sharpen_shift(self.size_x);
267                 i = self.count & 24;
268
269                 switch(i)
270                 {
271                         case 0:
272                         default:
273                                 for(x = 0; x < self.size_x; ++x)
274                                 {
275                                         l = RadarMapAtPoint_Block(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
276                                         sharpen_set(x, l);
277                                 }
278                                 break;
279                         case 8:
280                                 for(x = 0; x < self.size_x; ++x)
281                                 {
282                                         l = RadarMapAtPoint_Trace(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
283                                         sharpen_set(x, l);
284                                 }
285                                 break;
286                         case 16:
287                                 for(x = 0; x < self.size_x; ++x)
288                                 {
289                                         l = RadarMapAtPoint_Sample(self.mins_x + x * self.maxs_x, self.mins_y + (self.size_y - self.frame) * self.maxs_y, self.maxs_x, self.maxs_y, self.mins_z, self.maxs_z, self.size_z);
290                                         sharpen_set(x, l);
291                                 }
292                                 break;
293                 }
294
295                 // do we have enough lines?
296                 if(self.frame >= 2)
297                 {
298                         // write a pixel line
299                         fputs(self.cnt, "\"");
300                         for(x = 0; x < self.size_x; ++x)
301                         {
302                                 l = sharpen_get(x, self.ltime);
303                                 fputs(self.cnt, substring(doublehex, 2 * floor(l * 256.0), 2));
304                         }
305                         if(self.frame == self.size_y)
306                                 fputs(self.cnt, "\"\n");
307                         else
308                         {
309                                 fputs(self.cnt, "\",\n");
310                                 print(ftos(self.size_y - self.frame), " lines left\n");
311                         }
312                 }
313
314                 // is this the last line? then write back the missing line
315                 if(self.frame == self.size_y)
316                 {
317                         sharpen_shift(self.size_x);
318                         // write a pixel line
319                         fputs(self.cnt, "\"");
320                         for(x = 0; x < self.size_x; ++x)
321                         {
322                                 l = sharpen_get(x, self.ltime);
323                                 fputs(self.cnt, substring(doublehex, 2 * floor(l * 256.0), 2));
324                         }
325                         if(self.frame == self.size_y)
326                                 fputs(self.cnt, "\"\n");
327                         else
328                         {
329                                 fputs(self.cnt, "\",\n");
330                                 print(ftos(self.size_y - self.frame), " lines left\n");
331                         }
332                 }
333
334                 self.frame += 1;
335                 self.nextthink = time;
336         }
337         else
338         {
339                 // close the file
340                 fputs(self.cnt, "};\n");
341                 fclose(self.cnt);
342                 print("Finished. Please edit data/", self.netname, " with an image editing application and place it in the TGA format in the gfx folder.\n");
343                 RadarMap_Next();
344         }
345 }
346
347 void RadarMap(float argc)
348 {
349         if(radarmapper)
350                 return;
351         float i;
352         radarmapper = spawn();
353         radarmapper.classname = "radarmapper";
354         radarmapper.think = RadarMap_Think;
355         radarmapper.nextthink = time;
356         radarmapper.count = 8; // default to the --trace method, as it is faster now
357         radarmapper.ltime = 1;
358         radarmapper.size_x = 512;
359         radarmapper.size_y = 512;
360         radarmapper.size_z = 1;
361
362         for(i = 1; i < argc; ++i)
363         {
364                 if(argv(i) == "--force")
365                         radarmapper.count |= 1;
366                 else if(argv(i) == "--loop")
367                         radarmapper.count |= 2;
368                 else if(argv(i) == "--quit")
369                         radarmapper.count |= 4;
370                 else if(argv(i) == "--block")
371                 {
372                         radarmapper.count &~= 24;
373                 }
374                 else if(argv(i) == "--trace")
375                 {
376                         radarmapper.count &~= 24;
377                         radarmapper.count |= 8;
378                 }
379                 else if(argv(i) == "--sample")
380                 {
381                         radarmapper.count &~= 24;
382                         radarmapper.count |= 16;
383                 }
384                 else if(argv(i) == "--flags") // for the recursive call
385                 {
386                         ++i;
387                         radarmapper.count = stof(argv(i));
388                 }
389                 else if(argv(i) == "--sharpen") // for the recursive call
390                 {
391                         ++i;
392                         radarmapper.ltime = stof(argv(i));
393                 }
394                 else if(argv(i) == "--res") // resolution
395                 {
396                         ++i;
397                         radarmapper.size_x = stof(argv(i));
398                         ++i;
399                         radarmapper.size_y = stof(argv(i));
400                 }
401                 else if(argv(i) == "--qual") // quality multiplier
402                 {
403                         ++i;
404                         radarmapper.size_z = stof(argv(i));
405                 }
406                 else
407                 {
408                         remove(radarmapper);
409                         radarmapper = world;
410                         print("Usage: sv_cmd radarmap [--force] [--loop] [--quit] [--block | --trace | --sample] [--sharpen N] [--res W H] [--qual Q]\n");
411                         print("The quality factor Q is roughly proportional to the time taken.\n");
412                         print("--trace supports no quality factor; its result should look like --block with infinite quality factor.\n");
413                         print("--block \n");
414                         return;
415                 }
416         }
417
418         print("Radarmap entity spawned.\n");
419 }
420
421 void BBox()
422 {
423         print("Original size: ", ftos(world.absmin_x), " ", ftos(world.absmin_y), " ", ftos(world.absmin_z));
424         print(" ", ftos(world.absmax_x), " ", ftos(world.absmax_y), " ", ftos(world.absmax_z), "\n");
425         print("Currently set size: ", ftos(world.mins_x), " ", ftos(world.mins_y), " ", ftos(world.mins_z));
426         print(" ", ftos(world.maxs_x), " ", ftos(world.maxs_y), " ", ftos(world.maxs_z), "\n");
427         print("Solid bounding box size:");
428
429         tracebox('1 0 0' * world.absmin_x,
430                  '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
431                  '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
432                  '1 0 0' * world.absmax_x,
433                          MOVE_WORLDONLY,
434                          world);
435         if(trace_startsolid)
436                 print(" ", ftos(world.absmin_x));
437         else
438                 print(" ", ftos(trace_endpos_x));
439
440         tracebox('0 1 0' * world.absmin_y,
441                  '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
442                  '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
443                  '0 1 0' * world.absmax_y,
444                          MOVE_WORLDONLY,
445                          world);
446         if(trace_startsolid)
447                 print(" ", ftos(world.absmin_y));
448         else
449                 print(" ", ftos(trace_endpos_y));
450
451         tracebox('0 0 1' * world.absmin_z,
452                  '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
453                  '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
454                  '0 0 1' * world.absmax_z,
455                          MOVE_WORLDONLY,
456                          world);
457         if(trace_startsolid)
458                 print(" ", ftos(world.absmin_z));
459         else
460                 print(" ", ftos(trace_endpos_z));
461
462         tracebox('1 0 0' * world.absmax_x,
463                  '0 1 0' * world.absmin_y + '0 0 1' * world.absmin_z,
464                  '0 1 0' * world.absmax_y + '0 0 1' * world.absmax_z,
465                  '1 0 0' * world.absmin_x,
466                          MOVE_WORLDONLY,
467                          world);
468         if(trace_startsolid)
469                 print(" ", ftos(world.absmax_x));
470         else
471                 print(" ", ftos(trace_endpos_x));
472
473         tracebox('0 1 0' * world.absmax_y,
474                  '1 0 0' * world.absmin_x + '0 0 1' * world.absmin_z,
475                  '1 0 0' * world.absmax_x + '0 0 1' * world.absmax_z,
476                  '0 1 0' * world.absmin_y,
477                          MOVE_WORLDONLY,
478                          world);
479         if(trace_startsolid)
480                 print(" ", ftos(world.absmax_y));
481         else
482                 print(" ", ftos(trace_endpos_y));
483
484         tracebox('0 0 1' * world.absmax_z,
485                  '1 0 0' * world.absmin_x + '0 1 0' * world.absmin_y,
486                  '1 0 0' * world.absmax_x + '0 1 0' * world.absmax_y,
487                  '0 0 1' * world.absmin_z,
488                          MOVE_WORLDONLY,
489                          world);
490         if(trace_startsolid)
491                 print(" ", ftos(world.absmax_z));
492         else
493                 print(" ", ftos(trace_endpos_z));
494
495         print("\n");
496 }
497
498 void EffectIndexDump()
499 {
500         float d;
501         float fh;
502         string s;
503
504         d = db_create();
505
506         print("begin of effects list\n");
507         db_put(d, "TE_GUNSHOT", "1"); print("effect TE_GUNSHOT is ", ftos(particleeffectnum("TE_GUNSHOT")), "\n");
508         db_put(d, "TE_GUNSHOTQUAD", "1"); print("effect TE_GUNSHOTQUAD is ", ftos(particleeffectnum("TE_GUNSHOTQUAD")), "\n");
509         db_put(d, "TE_SPIKE", "1"); print("effect TE_SPIKE is ", ftos(particleeffectnum("TE_SPIKE")), "\n");
510         db_put(d, "TE_SPIKEQUAD", "1"); print("effect TE_SPIKEQUAD is ", ftos(particleeffectnum("TE_SPIKEQUAD")), "\n");
511         db_put(d, "TE_SUPERSPIKE", "1"); print("effect TE_SUPERSPIKE is ", ftos(particleeffectnum("TE_SUPERSPIKE")), "\n");
512         db_put(d, "TE_SUPERSPIKEQUAD", "1"); print("effect TE_SUPERSPIKEQUAD is ", ftos(particleeffectnum("TE_SUPERSPIKEQUAD")), "\n");
513         db_put(d, "TE_WIZSPIKE", "1"); print("effect TE_WIZSPIKE is ", ftos(particleeffectnum("TE_WIZSPIKE")), "\n");
514         db_put(d, "TE_KNIGHTSPIKE", "1"); print("effect TE_KNIGHTSPIKE is ", ftos(particleeffectnum("TE_KNIGHTSPIKE")), "\n");
515         db_put(d, "TE_EXPLOSION", "1"); print("effect TE_EXPLOSION is ", ftos(particleeffectnum("TE_EXPLOSION")), "\n");
516         db_put(d, "TE_EXPLOSIONQUAD", "1"); print("effect TE_EXPLOSIONQUAD is ", ftos(particleeffectnum("TE_EXPLOSIONQUAD")), "\n");
517         db_put(d, "TE_TAREXPLOSION", "1"); print("effect TE_TAREXPLOSION is ", ftos(particleeffectnum("TE_TAREXPLOSION")), "\n");
518         db_put(d, "TE_TELEPORT", "1"); print("effect TE_TELEPORT is ", ftos(particleeffectnum("TE_TELEPORT")), "\n");
519         db_put(d, "TE_LAVASPLASH", "1"); print("effect TE_LAVASPLASH is ", ftos(particleeffectnum("TE_LAVASPLASH")), "\n");
520         db_put(d, "TE_SMALLFLASH", "1"); print("effect TE_SMALLFLASH is ", ftos(particleeffectnum("TE_SMALLFLASH")), "\n");
521         db_put(d, "TE_FLAMEJET", "1"); print("effect TE_FLAMEJET is ", ftos(particleeffectnum("TE_FLAMEJET")), "\n");
522         db_put(d, "EF_FLAME", "1"); print("effect EF_FLAME is ", ftos(particleeffectnum("EF_FLAME")), "\n");
523         db_put(d, "TE_BLOOD", "1"); print("effect TE_BLOOD is ", ftos(particleeffectnum("TE_BLOOD")), "\n");
524         db_put(d, "TE_SPARK", "1"); print("effect TE_SPARK is ", ftos(particleeffectnum("TE_SPARK")), "\n");
525         db_put(d, "TE_PLASMABURN", "1"); print("effect TE_PLASMABURN is ", ftos(particleeffectnum("TE_PLASMABURN")), "\n");
526         db_put(d, "TE_TEI_G3", "1"); print("effect TE_TEI_G3 is ", ftos(particleeffectnum("TE_TEI_G3")), "\n");
527         db_put(d, "TE_TEI_SMOKE", "1"); print("effect TE_TEI_SMOKE is ", ftos(particleeffectnum("TE_TEI_SMOKE")), "\n");
528         db_put(d, "TE_TEI_BIGEXPLOSION", "1"); print("effect TE_TEI_BIGEXPLOSION is ", ftos(particleeffectnum("TE_TEI_BIGEXPLOSION")), "\n");
529         db_put(d, "TE_TEI_PLASMAHIT", "1"); print("effect TE_TEI_PLASMAHIT is ", ftos(particleeffectnum("TE_TEI_PLASMAHIT")), "\n");
530         db_put(d, "EF_STARDUST", "1"); print("effect EF_STARDUST is ", ftos(particleeffectnum("EF_STARDUST")), "\n");
531         db_put(d, "TR_ROCKET", "1"); print("effect TR_ROCKET is ", ftos(particleeffectnum("TR_ROCKET")), "\n");
532         db_put(d, "TR_GRENADE", "1"); print("effect TR_GRENADE is ", ftos(particleeffectnum("TR_GRENADE")), "\n");
533         db_put(d, "TR_BLOOD", "1"); print("effect TR_BLOOD is ", ftos(particleeffectnum("TR_BLOOD")), "\n");
534         db_put(d, "TR_WIZSPIKE", "1"); print("effect TR_WIZSPIKE is ", ftos(particleeffectnum("TR_WIZSPIKE")), "\n");
535         db_put(d, "TR_SLIGHTBLOOD", "1"); print("effect TR_SLIGHTBLOOD is ", ftos(particleeffectnum("TR_SLIGHTBLOOD")), "\n");
536         db_put(d, "TR_KNIGHTSPIKE", "1"); print("effect TR_KNIGHTSPIKE is ", ftos(particleeffectnum("TR_KNIGHTSPIKE")), "\n");
537         db_put(d, "TR_VORESPIKE", "1"); print("effect TR_VORESPIKE is ", ftos(particleeffectnum("TR_VORESPIKE")), "\n");
538         db_put(d, "TR_NEHAHRASMOKE", "1"); print("effect TR_NEHAHRASMOKE is ", ftos(particleeffectnum("TR_NEHAHRASMOKE")), "\n");
539         db_put(d, "TR_NEXUIZPLASMA", "1"); print("effect TR_NEXUIZPLASMA is ", ftos(particleeffectnum("TR_NEXUIZPLASMA")), "\n");
540         db_put(d, "TR_GLOWTRAIL", "1"); print("effect TR_GLOWTRAIL is ", ftos(particleeffectnum("TR_GLOWTRAIL")), "\n");
541         db_put(d, "SVC_PARTICLE", "1"); print("effect SVC_PARTICLE is ", ftos(particleeffectnum("SVC_PARTICLE")), "\n");
542
543         fh = fopen("effectinfo.txt", FILE_READ);
544         while((s = fgets(fh)))
545         {
546                 tokenize_insane(s); // tokenize_sane would hit the loop counter :(
547                 if(argv(0) == "effect")
548                 {
549                         if(db_get(d, argv(1)) != "1")
550                         {
551                                 if(particleeffectnum(argv(1)) >= 0)
552                                         print("effect ", argv(1), " is ", ftos(particleeffectnum(argv(1))), "\n");
553                                 db_put(d, argv(1), "1");
554                         }
555                 }
556         }
557         print("end of effects list\n");
558
559         db_close(d);
560 }
561
562 void make_mapinfo_Think()
563 {
564         if(MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, 0, 1))
565         {
566                 print("Done rebuiling mapinfos.\n");
567                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0) | MAPINFO_FLAG_FORBIDDEN, 0);
568                 remove(self);
569         }
570         else
571         {
572                 self.think = make_mapinfo_Think;
573                 self.nextthink = time;
574         }
575 }
576
577 void GameCommand(string command)
578 {
579         float argc;
580         entity client, e;
581         vector v;
582         float entno, i;
583         argc = tokenize_sane(command);
584
585         if(argv(0) == "help" || argc == 0)
586         {
587                 print("Usage: sv_cmd COMMAND..., where possible commands are:\n");
588                 print("  adminmsg clientnumber \"message\"\n");
589                 print("  teamstatus\n");
590                 print("  printstats\n");
591                 print("  make_mapinfo\n");
592                 print("  gametype dm|ctf|...\n");
593                 print("  savedb filename\n");
594                 print("  dumpdb filename\n");
595                 print("  loaddb filename\n");
596                 print("  allready\n");
597                 print("  effectindexdump\n");
598                 print("  radarmap [--force] [--quit | --loop] [sharpness]\n");
599                 print("  bbox\n");
600                 print("  cvar_changes\n");
601                 print("  find classname\n");
602                 GameCommand_Vote("help", world);
603                 GameCommand_Ban("help");
604                 GameCommand_Generic("help");
605                 return;
606         }
607
608         if(GameCommand_Vote(command, world))
609                 return;
610
611         if(GameCommand_Ban(command))
612                 return;
613
614         if(GameCommand_Generic(command))
615                 return;
616
617         if(argv(0) == "printstats")
618         {
619                 DumpStats(FALSE);
620                 return;
621         }
622
623         if(argv(0) == "make_mapinfo")
624         {
625                 e = spawn();
626                 e.classname = "make_mapinfo";
627                 e.think = make_mapinfo_Think;
628                 e.nextthink = time;
629                 MapInfo_Enumerate();
630                 return;
631         }
632
633         if(argv(0) == "warp") if(argc == 2) if(cvar("g_campaign"))
634         {
635                 CampaignLevelWarp(stof(argv(1)));
636                 return;
637         }
638
639         if(argv(0) == "gotomap") if(argc == 2)
640         {
641                 print(GotoMap(argv(1)), "\n");
642                 return;
643         }
644
645         if(argv(0) == "gametype") if(argc == 2)
646         {
647                 float t, tsave;
648                 string s;
649                 s = argv(1);
650                 t = MapInfo_Type_FromString(s);
651                 tsave = MapInfo_CurrentGametype();
652                 if(t)
653                 {
654                         MapInfo_SwitchGameType(t);
655                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN, 0);
656                         if(MapInfo_count > 0)
657                         {
658                                 bprint("Game type successfully switched to ", s, "\n");
659                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0) | MAPINFO_FLAG_FORBIDDEN, 0);
660                         }
661                         else
662                         {
663                                 bprint("Cannot use this game type: no map for it found\n");
664                                 MapInfo_SwitchGameType(tsave);
665                                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0) | MAPINFO_FLAG_FORBIDDEN, 0);
666                         }
667                 }
668                 else
669                         bprint("Game type switch to ", s, " failed: this type does not exist!\n");
670                 return;
671         }
672
673         if(argv(0) == "adminmsg") if(argc == 3)
674         {
675                 entno = stof(argv(1));
676                 client = world;
677                 if(entno <= maxclients)
678                         client = edict_num(entno);
679                 if(client.flags & FL_CLIENT)
680                 {
681                         centerprint_atprio(client, CENTERPRIO_ADMIN, strcat("^3SERVER ADMIN:\n\n^7", argv(2)));
682                         sprint(client, strcat("\{1}\{13}^3SERVER ADMIN^7: ", argv(2), "\n"));
683                         print("Message sent to ", client.netname, "\n");
684                 }
685                 else
686                         print("Client not found\n");
687                 return;
688         }
689
690         if(argv(0) == "savedb") if(argc == 2)
691         {
692                 db_save(ServerProgsDB, argv(1));
693                 print("DB saved.\n");
694                 return;
695         }
696
697         if(argv(0) == "dumpdb") if(argc == 2)
698         {
699                 db_dump(ServerProgsDB, argv(1));
700                 print("DB dumped.\n");
701                 return;
702         }
703
704         if(argv(0) == "loaddb") if(argc == 2)
705         {
706                 db_close(ServerProgsDB);
707                 ServerProgsDB = db_load(argv(1));
708                 print("DB loaded.\n");
709                 return;
710         }
711         if (argv(0) == "nospectators")
712         {
713                 blockSpectators = 1;
714                 local entity plr;
715                 FOR_EACH_CLIENT(plr) //give every spectator <g_maxplayers_spectator_blocktime> seconds time to become a player
716                 {
717                         if(plr.classname == "spectator" || plr.classname == "observer")
718                         {
719                                 plr.spectatortime = time;
720                                 sprint(plr, strcat("^7You have to become a player within the next ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds, otherwise you will be kicked, because spectators aren't allowed at this time!\n"));
721                         }
722                 }
723                 bprint(strcat("^7All spectators will be automatically kicked when not joining the game after ", ftos(cvar("g_maxplayers_spectator_blocktime")), " seconds!\n"));
724                 return;
725         }
726         if (argv(0) == "lockteams")
727         {
728                 if(teams_matter)
729                 {
730                         lockteams = 1;
731                         bprint("^1The teams are now locked.\n");
732                 }
733                 else
734                         bprint("That command can only be used in a team-based gamemode.\n");
735                 return;
736         }
737         if (argv(0) == "unlockteams")
738         {
739                 if(teams_matter)
740                 {
741                         lockteams = 0;
742                         bprint("^1The teams are now unlocked.\n");
743                 }
744                 else
745                         bprint("That command can only be used in a team-based gamemode.\n");
746                 return;
747         }
748         if (argv(0) == "movetoteam") if(argc == 3)
749         {
750                 entno = stof(argv(1));
751                 client = world;
752                 if(entno <= maxclients)
753                         client = edict_num(entno);
754                 if(client.flags & FL_CLIENT)
755                 {
756                         float lt;
757                         lt = lockteams;
758                         lockteams = 0;
759
760                         self = client;
761                         SV_ParseClientCommand(strcat("selectteam ", argv(2)));
762
763                         lockteams = lt;
764                 }
765                 else
766                         print("Client not found\n");
767                 return;
768         }
769         if (argv(0) == "teamstatus")
770         {
771                 Score_NicePrint(world);
772                 return;
773         }
774         if (argv(0) == "allready")
775         {
776                 ReadyRestart();
777                 return;
778         }
779         if (argv(0) == "effectindexdump")
780         {
781                 EffectIndexDump();
782                 return;
783         }
784         if (argv(0) == "radarmap")
785         {
786                 RadarMap(argc);
787                 return;
788         }
789         if (argv(0) == "bbox")
790         {
791                 BBox();
792                 return;
793         }
794         if (argv(0) == "cvar_changes")
795         {
796                 print(cvar_changes);
797                 return;
798         }
799         if (argv(0) == "find") if(argc == 2)
800         {
801                 for(client = world; (client = find(client, classname, argv(1))); )
802                         print(etos(client), "\n");
803                 return;
804         }
805         if (argv(0) == "records")
806         {
807                 strunzone(records_reply);
808                 records_reply = strzone(getrecords());
809                 print(records_reply);
810                 return;
811         }
812
813         if(argv(0) == "cointoss")
814         {
815                 bprint("^3Throwing coin... Result: ");
816                 if (random() > 0.5)
817                         bprint("^1heads ^3!\n");
818                 else
819                         bprint("^1tails ^3!\n");
820                 return;
821         }
822
823         if(argv(0) == "__FORCE_READY_RESTART")
824         {
825                 reset_map(FALSE);
826                 return;
827         }
828
829         if(argv(0) == "debug_shotorg")
830         {
831                 debug_shotorg = stov(argv(1));
832                 return;
833         }
834
835         if(argv(0) == "gettaginfo") if(argc >= 4)
836         {
837                 e = spawn();
838                 if(argv(1) == "w")
839                         setmodel(e, (nextent(world)).weaponentity.model);
840                 else
841                         setmodel(e, argv(1));
842                 e.frame = stof(argv(2));
843                 i = gettagindex(e, argv(3));
844                 if(i)
845                 {
846                         v = gettaginfo(e, i);
847                         print("model ", e.model, " frame ", ftos(e.frame), " tag ", argv(3));
848                         print(" index = ", ftos(i));
849                         print(" vector = ", ftos(v_x), " ", ftos(v_y), " ", ftos(v_z), "\n");
850                         if(argc >= 6)
851                         {
852                                 v_y = -v_y;
853                                 localcmd(strcat(argv(4), vtos(v), argv(5), "\n"));
854                         }
855                 }
856                 else
857                         print("bone not found\n");
858                 remove(e);
859                 return;
860         }
861
862         if(argv(0) == "time")
863         {
864                 print("time = ", ftos(time), "\n");
865                 print("frame start = ", ftos(gettime(GETTIME_FRAMESTART)), "\n");
866                 print("realtime = ", ftos(gettime(GETTIME_REALTIME)), "\n");
867                 print("hires = ", ftos(gettime(GETTIME_HIRES)), "\n");
868                 print("uptime = ", ftos(gettime(GETTIME_UPTIME)), "\n");
869                 print("localtime = ", strftime(TRUE, "%a %b %e %H:%M:%S %Z %Y"), "\n");
870                 print("gmtime = ", strftime(FALSE, "%a %b %e %H:%M:%S %Z %Y"), "\n");
871                 return;
872         }
873
874         if(argv(0) == "tracebug")
875         {
876                 print("TEST CASE. If this returns the runaway loop counter error, possibly everything is oaky.\n");
877                 for(;;)
878                 {
879                         vector org, delta, start, end, p;
880
881                         org = world.mins;
882                         delta = world.maxs - world.mins;
883
884                         start_x = org_x + random() * delta_x;
885                         start_y = org_y + random() * delta_y;
886                         start_z = org_z + random() * delta_z;
887
888                         end_x = org_x + random() * delta_x;
889                         end_y = org_y + random() * delta_y;
890                         end_z = org_z + random() * delta_z;
891
892                         start = stov(vtos(start));
893                         end = stov(vtos(end));
894
895                         tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
896                         if(!trace_startsolid)
897                         {
898                                 p = trace_endpos;
899                                 tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
900                                 if(trace_startsolid)
901                                 {
902                                         rint(42); // do an engine breakpoint on VM_rint so you can get the trace that errnoeously returns startsolid
903                                         tracebox(start, PL_MIN, PL_MAX, end, MOVE_NOMONSTERS, world);
904                                         tracebox(p, PL_MIN, PL_MAX, p, MOVE_NOMONSTERS, world);
905
906                                         tracebox(p, PL_MIN + '0.1 0.1 0.1', PL_MAX - '0.1 0.1 0.1', p, MOVE_NOMONSTERS, world);
907                                         if(trace_startsolid)
908                                                 error(strcat("trace_endpos much in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(trace_endpos), "\n"));
909                                         else
910                                                 error(strcat("trace_endpos just in solid when tracing from ", vtos(start), " to ", vtos(end), " endpos ", vtos(trace_endpos), "\n"));
911                                 }
912                         }
913                 }
914         }
915
916         print("Invalid command. For a list of supported commands, try sv_cmd help.\n");
917 }
918