data/qcsrc/server/gamec/w_grenadelauncher.c

   1 void() glauncher_ready_01;
   2 void() glauncher_fire1_01;
   3 void() glauncher_fire2_01;
   4 void() glauncher_deselect_01;
   5 void() glauncher_select_01;
   6
   7 float() glauncher_check =
   8 {
   9         if (self.ammo_rockets >= cvar("g_balance_grenadelauncher_primary_ammo"))
  10                 return TRUE;
  11         return FALSE;
  12 };
  13
  14 float() glauncher_check2 =
  15 {
  16         if (self.ammo_rockets >= cvar("g_balance_grenadelauncher_secondary_ammo"))
  17                 return TRUE;
  18         return FALSE;
  19 };
  20
  21 void(float req) w_glauncher =
  22 {
  23         if (req == WR_IDLE)
  24                 glauncher_ready_01();
  25         else if (req == WR_FIRE1)
  26                 weapon_prepareattack(glauncher_check, glauncher_check, glauncher_fire1_01, cvar("g_balance_grenadelauncher_primary_refire"));
  27         else if (req == WR_FIRE2)
  28                 weapon_prepareattack(glauncher_check2, glauncher_check2, glauncher_fire2_01, cvar("g_balance_grenadelauncher_secondary_refire"));
  29         else if (req == WR_RAISE)
  30                 glauncher_select_01();
  31         else if (req == WR_UPDATECOUNTS)
  32                 self.currentammo = self.ammo_rockets;
  33         else if (req == WR_DROP)
  34                 glauncher_deselect_01();
  35         else if (req == WR_SETUP)
  36                 weapon_setup(WEP_GRENADE_LAUNCHER, "w_gl.zym", IT_ROCKETS);
  37         else if (req == WR_CHECKAMMO)
  38                 weapon_hasammo = glauncher_check() + glauncher_check2();
  39 };
  40
  41 void W_Grenade_Explode (void)
  42 {
  43         vector  org2;
  44         org2 = findbetterlocation (self.origin);
  45         te_explosion (org2);
  46         effect (org2, "models/sprites/grenexpl.spr", 0, 12, 35);
  47         sound (self, CHAN_BODY, "weapons/grenade_impact.ogg", 1, ATTN_NORM);
  48
  49         self.event_damage = SUB_Null;
  50         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_primary_damage"), cvar("g_balance_grenadelauncher_primary_edgedamage"), cvar("g_balance_grenadelauncher_primary_radius"), world, cvar("g_balance_grenadelauncher_primary_force"), IT_GRENADE_LAUNCHER);
  51
  52         remove (self);
  53 }
  54
  55 void W_Grenade_Explode2 (void)
  56 {
  57         vector  org2;
  58         org2 = findbetterlocation (self.origin);
  59         te_explosion (org2);
  60         effect (org2, "models/sprites/grenexpl.spr", 0, 12, 35);
  61         sound (self, CHAN_BODY, "weapons/grenade_impact.ogg", 1, ATTN_NORM);
  62
  63         self.event_damage = SUB_Null;
  64         RadiusDamage (self, self.owner, cvar("g_balance_grenadelauncher_secondary_damage"), cvar("g_balance_grenadelauncher_secondary_edgedamage"), cvar("g_balance_grenadelauncher_secondary_radius"), world, cvar("g_balance_grenadelauncher_secondary_force"), IT_GRENADE_LAUNCHER);
  65
  66         remove (self);
  67 }
  68
  69 void W_Grenade_Touch1 (void)
  70 {
  71         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  72         {
  73                 remove(self);
  74                 return;
  75         }
  76         W_Grenade_Explode ();
  77 }
  78
  79 void W_Grenade_Touch2 (void)
  80 {
  81         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  82         {
  83                 remove(self);
  84                 return;
  85         }
  86         if (other.takedamage == DAMAGE_AIM)
  87                 self.think ();
  88         else
  89         {
  90                 float r;
  91                 r = random() * 3;
  92                 if(r < 1)
  93                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce1.ogg", 1, ATTN_NORM);
  94                 else if(r < 2)
  95                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce2.ogg", 1, ATTN_NORM);
  96                 else
  97                         sound (self, CHAN_IMPACT, "weapons/grenade_bounce3.ogg", 1, ATTN_NORM);
  98         }
  99 }
 100
 101 void W_Grenade_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 102 {
 103         self.health = self.health - damage;
 104         if (self.health <= 0)
 105         {
 106                 self.owner = attacker;
 107                 self.think ();
 108         }
 109 }
 110
 111 void W_Grenade_Attack (void)
 112 {
 113         local entity gren;
 114         local vector org;
 115
 116         sound (self, CHAN_WEAPON, "weapons/grenade_fire.ogg", 1, ATTN_NORM);
 117         if (self.items & IT_STRENGTH)
 118                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
 119
 120         self.punchangle_x = -4;
 121         if (cvar("g_use_ammunition"))
 122                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_primary_ammo");
 123         org = W_MuzzleOrigin (self, '24 8 -10');
 124
 125         gren = spawn ();
 126         gren.owner = self;
 127         gren.classname = "grenade";
 128         gren.movetype = MOVETYPE_BOUNCE;
 129         gren.solid = SOLID_BBOX;
 130         gren.effects = EF_NOSHADOW;
 131         setmodel(gren, "models/grenademodel.md3");
 132         setsize(gren, '0 0 0', '0 0 0');
 133         setorigin(gren, org);
 134
 135         gren.nextthink = time + cvar("g_balance_grenadelauncher_primary_lifetime");
 136         gren.think = W_Grenade_Explode;
 137         gren.touch = W_Grenade_Touch1;
 138         gren.velocity = v_forward * cvar("g_balance_grenadelauncher_primary_speed") + v_up * cvar("g_balance_grenadelauncher_primary_speed_up");
 139         gren.avelocity_x = random () * -500 - 500;
 140
 141         gren.angles = vectoangles (gren.velocity);
 142 }
 143
 144 void W_Grenade_Attack2 (void)
 145 {
 146         local entity gren;
 147         local vector org;
 148
 149         sound (self, CHAN_WEAPON, "weapons/grenade_fire.ogg", 1, ATTN_NORM);
 150         if (self.items & IT_STRENGTH)
 151                 sound (self, CHAN_AUTO, "weapons/strength_fire.ogg", 1, ATTN_NORM);
 152
 153         self.punchangle_x = -4;
 154         if (cvar("g_use_ammunition"))
 155                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_grenadelauncher_secondary_ammo");
 156         org = W_MuzzleOrigin (self, '24 8 -10');
 157
 158         gren = spawn ();
 159         gren.owner = self;
 160         gren.classname = "grenade";
 161         gren.movetype = MOVETYPE_BOUNCE;
 162         gren.solid = SOLID_BBOX;
 163         gren.effects = EF_NOSHADOW;
 164         setmodel(gren, "models/grenademodel.md3");
 165         setsize(gren, '0 0 -3', '0 0 -3');
 166         setorigin(gren, org);
 167
 168         gren.nextthink = time + cvar("g_balance_grenadelauncher_secondary_lifetime");
 169         gren.think = W_Grenade_Explode2;
 170         gren.touch = W_Grenade_Touch2;
 171         gren.takedamage = DAMAGE_YES;
 172         gren.health = 10;
 173         gren.damageforcescale = 4;
 174         gren.event_damage = W_Grenade_Damage;
 175         gren.velocity = v_forward * cvar("g_balance_grenadelauncher_secondary_speed") + v_up * cvar("g_balance_grenadelauncher_secondary_speed_up");
 176         gren.avelocity = '100 150 100';
 177
 178         gren.angles = vectoangles (gren.velocity);
 179 }
 180
 181 // weapon frames
 182
 183 void()  glauncher_ready_01 =    {weapon_thinkf(WFRAME_IDLE, 0.1, glauncher_ready_01); self.weaponentity.state = WS_READY;};
 184 void()  glauncher_select_01 =   {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_ready); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, '0 0 0');};
 185 void()  glauncher_deselect_01 = {weapon_thinkf(-1, cvar("g_balance_weaponswitchdelay"), w_clear); weapon_boblayer1(PLAYER_WEAPONSELECTION_SPEED, PLAYER_WEAPONSELECTION_RANGE);};
 186 void()  glauncher_fire1_01 =
 187 {
 188         weapon_doattack(glauncher_check, glauncher_check, W_Grenade_Attack);
 189         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_grenadelauncher_primary_animtime"), glauncher_ready_01);
 190 };
 191 void()  glauncher_fire2_01 =
 192 {
 193         weapon_doattack(glauncher_check2, glauncher_check2, W_Grenade_Attack2);
 194         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_grenadelauncher_secondary_animtime"), glauncher_ready_01);
 195 };