data/qcsrc/server/gamec/t_items.c

   1 void Item_ClearRespawnEffect (void) {
   2         self.effects = self.effects - (self.effects & EF_STARDUST);
   3 }
   4
   5 void Item_Respawn (void)
   6 {
   7         self.model = self.mdl;          // restore original model
   8         self.solid = SOLID_TRIGGER;     // allow it to be touched again
   9         sound (self, CHAN_VOICE, "misc/itemrespawn.ogg", 1, ATTN_NORM); // play respawn sound
  10         setorigin (self, self.origin);
  11
  12         // Savage: Add simple Respawn effect and make sure it gets removed
  13         self.effects = self.effects | EF_STARDUST;
  14         self.think = Item_ClearRespawnEffect;
  15         self.nextthink = time + 0.1;
  16 }
  17
  18 void Item_Touch (void)
  19 {
  20         local entity oldself;
  21         local float _switchweapon;
  22
  23         // remove the item if it's currnetly in a NODROP brush or hits a NOIMPACT surface (such as sky)
  24         if (((trace_dpstartcontents | trace_dphitcontents) & DPCONTENTS_NODROP) || (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
  25         {
  26                 remove(self);
  27                 return;
  28         }
  29         if (other.classname != "player")
  30                 return;
  31         if (other.deadflag)
  32                 return;
  33         if (self.solid != SOLID_TRIGGER)
  34                 return;
  35         if (self.health && other.health >= other.max_health)
  36                 return;
  37         if (self.owner == other)
  38                 return;
  39         // Savage: Remove the respawn effect if still present
  40         self.effects = self.effects - (self.effects & EF_STARDUST);
  41
  42         sound (self, CHAN_BODY, self.noise, 1, ATTN_NORM);
  43
  44         // in case the player has autoswitch enabled do the following:
  45         // if the player is using their best weapon before items are given, they
  46         // probably want to switch to an even better weapon after items are given
  47         _switchweapon = (other.autoswitch && (other.switchweapon == w_getbestweapon(other)) || cvar("g_minstagib"));
  48
  49         if (cvar("g_minstagib"))
  50         {
  51                 if (self.ammo_cells)
  52                 {
  53                         // play some cool sounds ;)
  54                         centerprint(other, "\n");
  55                         if(other.health <= 5)
  56                                 stuffcmd(other, "play2 announcer/robotic/lastsecond.ogg\n");
  57                         else if(other.health < 50)
  58                                 stuffcmd(other, "play2 announcer/robotic/narrowly.ogg\n");
  59                         // sound not available
  60                         // else if(self.items == IT_CELLS)
  61                         //      stuffcmd(other, "play2 announce/robotic/ammo.ogg\n");
  62
  63                         if (self.items & IT_NEX)
  64                                 W_GiveWeapon (other, IT_NEX, "Nex");
  65                         if (self.ammo_cells)
  66                                 other.ammo_cells = min (other.ammo_cells + cvar("g_minstagib_ammo_drop"), 999);
  67                         other.health = 100;
  68                 }
  69
  70                 // extralife powerup
  71                 if (self.max_health)
  72                 {
  73                         // sound not available
  74                         // stuffcmd(other, "play2 announce/robotic/extra.ogg\nplay2 announce/robotic/_lives.ogg\n");
  75                         other.extralives = other.extralives + cvar("g_minstagib_extralives");
  76                         other.armorvalue = other.extralives;
  77                         sprint(other, "^3You picked up some extra lives\n");
  78                 }
  79
  80                 // invis powerup
  81                 if (self.strength_finished)
  82                 {
  83                         // sound not available
  84                         // stuffcmd(other, "play2 announce/robotic/invisible.ogg\n");
  85                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
  86                 }
  87
  88                 // speed powerup
  89                 if (self.invincible_finished)
  90                 {
  91                         // sound not available
  92                         // stuffcmd(other, "play2 announce/robotic/speed.ogg\n");
  93                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_strength_time");
  94                 }
  95         }
  96         else
  97         {
  98                 if (cvar("deathmatch") == 2 && self.flags & FL_WEAPON && other.items & self.items && self.classname != "droppedweapon")
  99                         return;
 100
 101                 if (self.ammo_shells)
 102                         other.ammo_shells = min (other.ammo_shells + self.ammo_shells, 999);
 103                 if (self.ammo_nails)
 104                         other.ammo_nails = min (other.ammo_nails + self.ammo_nails, 999);
 105                 if (self.ammo_rockets)
 106                         other.ammo_rockets = min (other.ammo_rockets + self.ammo_rockets, 999);
 107                 if (self.ammo_cells)
 108                         other.ammo_cells = min (other.ammo_cells + self.ammo_cells, 999);
 109
 110                 if (self.items & IT_UZI)                W_GiveWeapon (other, IT_UZI, self.netname);
 111                 if (self.items & IT_SHOTGUN)            W_GiveWeapon (other, IT_SHOTGUN, self.netname);
 112                 if (self.items & IT_GRENADE_LAUNCHER)   W_GiveWeapon (other, IT_GRENADE_LAUNCHER, self.netname);
 113                 if (self.items & IT_ELECTRO)            W_GiveWeapon (other, IT_ELECTRO, self.netname);
 114                 if (self.items & IT_NEX)                W_GiveWeapon (other, IT_NEX, self.netname);
 115                 if (self.items & IT_HAGAR)              W_GiveWeapon (other, IT_HAGAR, self.netname);
 116                 if (self.items & IT_ROCKET_LAUNCHER)    W_GiveWeapon (other, IT_ROCKET_LAUNCHER, self.netname);
 117                 if (self.items & IT_CRYLINK)            W_GiveWeapon (other, IT_CRYLINK, self.netname);
 118
 119                 if (self.strength_finished)
 120                         other.strength_finished = max(other.strength_finished, time) + cvar("g_balance_powerup_strength_time");
 121                 if (self.invincible_finished)
 122                         other.invincible_finished = max(other.invincible_finished, time) + cvar("g_balance_powerup_invincible_time");
 123                 //if (self.speed_finished)
 124                 //      other.speed_finished = max(other.speed_finished, time) + cvar("g_balance_powerup_speed_time");
 125                 //if (self.slowmo_finished)
 126                 //      other.slowmo_finished = max(other.slowmo_finished, time) + (cvar("g_balance_powerup_slowmo_time") * cvar("g_balance_powerup_slowmo_speed"));
 127
 128                 if (self.max_health)
 129                 {
 130                         other.health = other.health + self.max_health;
 131                         other.pauserothealth_finished = max(other.pauserothealth_finished, time + cvar("g_balance_pause_health_rot"));
 132                 }
 133                 if (self.health && other.health < other.max_health)
 134                         other.health = min(other.health + self.health, other.max_health);
 135                 if (self.armorvalue)
 136                 {
 137                         other.armorvalue = other.armorvalue + self.armorvalue;
 138                         other.pauserotarmor_finished = max(other.pauserotarmor_finished, time + cvar("g_balance_pause_armor_rot"));
 139                 }
 140         }
 141
 142         sound (other, CHAN_AUTO, self.item_pickupsound, 1, ATTN_NORM);
 143
 144         oldself = self;
 145         self = other;
 146
 147         if (_switchweapon)
 148                 self.switchweapon = w_getbestweapon(self);
 149         if (self.switchweapon != self.weapon)
 150                 self.cnt = self.weapon;
 151
 152         //w_updateweapon ();
 153         //w_updateammo ();
 154         weapon_action(self.weapon, WR_UPDATECOUNTS);
 155
 156         self = oldself;
 157
 158         if (self.classname == "droppedweapon")
 159                 remove (self);
 160         else
 161         {
 162                 self.solid = SOLID_NOT;
 163                 self.model = string_null;
 164                 self.nextthink = time + self.respawntime;
 165                 self.think = Item_Respawn;
 166                 setorigin (self, self.origin);
 167         }
 168 }
 169
 170 // Savage: used for item garbage-collection
 171 // TODO: perhaps nice special effect?
 172 void RemoveItem(void) = {
 173         remove(self);
 174 }
 175
 176 void StartItem (string itemmodel, string pickupsound, float defaultrespawntime, string itemname, float itemid, float itemflags)
 177 {
 178         vector org;
 179         org = self.origin;
 180
 181         if (!(cvar("g_pickup_items") && !cvar("g_nixnex")) && !cvar("g_minstagib") &&
 182                         itemid != IT_STRENGTH && itemid != IT_INVINCIBLE && itemname != "100 Health")
 183         {
 184                 remove (self);
 185                 return;
 186         }
 187
 188         if (cvar("g_minstagib"))
 189         {
 190                 // don't remove dropped items and powerups
 191                 if (self.classname != "droppedweapon" &&
 192                     self.classname != "minstagib")
 193                 {
 194                         remove (self);
 195                         return;
 196                 }
 197         }
 198
 199         if(cvar("g_lms") && (self.classname != "droppedweapon"))
 200         {
 201                 remove(self);
 202                 return;
 203         }
 204
 205         if(cvar("g_instagib") || cvar("g_rocketarena"))
 206         {
 207                 remove(self);
 208                 return;
 209         }
 210
 211         if (self.classname == "droppedweapon")
 212         {
 213                 // don't drop if in a NODROP zone (such as lava)
 214                 traceline(self.origin, self.origin, MOVE_NORMAL, self);
 215                 if (trace_dpstartcontents & DPCONTENTS_NODROP)
 216                 {
 217                         remove(self);
 218                         return;
 219                 }
 220         }
 221
 222         self.mdl = itemmodel;
 223         //self.noise = pickupsound;
 224         self.item_pickupsound = pickupsound;
 225         // let mappers override respawntime
 226         if (!self.respawntime)
 227                 self.respawntime = defaultrespawntime;
 228         self.netname = itemname;
 229         self.items = itemid;
 230         self.flags = FL_ITEM | itemflags;
 231         setmodel (self, self.mdl);
 232         if (itemflags & FL_WEAPON)
 233         {
 234                 setorigin (self, self.origin + '0 0 23');
 235                 setsize (self, '-12 -12 -12', '12 12 12');
 236
 237                 // neutral team color for pickup weapons
 238                 self.colormap = 160 * 1024 + 160;
 239         }
 240         else
 241         {
 242                 setorigin (self, self.origin + '0 0 25');
 243         //      setsize (self, '-8 -8 -5', '8 8 8');
 244         }
 245         self.movetype = MOVETYPE_TOSS;
 246         self.solid = SOLID_TRIGGER;
 247         self.touch = Item_Touch;
 248
 249         // Savage: remove thrown items after a certain period of time ("garbage collection")
 250         if (self.classname == "droppedweapon")
 251         {
 252                 self.think = RemoveItem;
 253                 self.nextthink = time + 60;
 254         }
 255         else if (!self.noalign)
 256         {
 257                 vector z_offset;
 258
 259                 z_offset = '0 0 1';
 260
 261                 if (itemid == IT_SHELLS)
 262                         z_offset = '0 0 1' * 4;
 263                 else if (itemid == IT_ROCKETS)
 264                         z_offset = '0 0 1' * 4;
 265                 else if (itemid == IT_NAILS)
 266                         z_offset = '0 0 0';
 267                 else if (self.max_health == 25)
 268                         z_offset = '0 0 1' * 5;
 269                 else if (self.armorvalue == 100)
 270                         z_offset = '0 0 1' * 3;
 271
 272                 self.movetype = MOVETYPE_NONE;
 273                 setorigin(self, find_floor(org) + z_offset);
 274         }
 275         else
 276         {
 277                 self.movetype = MOVETYPE_NONE;
 278                 setorigin(self, org);
 279         }
 280
 281         if (cvar("g_fullbrightitems"))
 282                 self.effects = self.effects | EF_FULLBRIGHT;
 283
 284 }
 285
 286 /* replace items in minstagib
 287  * IT_STRENGTH   = invisibility
 288  * IT_NAILS      = extra lives
 289  * IT_INVINCIBLE = speed
 290  */
 291 void minstagib_items (float itemid)
 292 {
 293         // we don't want to replace dropped weapons ;)
 294         if (self.classname == "droppedweapon")
 295         {
 296                 self.ammo_cells = 25;
 297                 StartItem ("models/weapons/g_nex.md3",
 298                         "weapons/weaponpickup.ogg", 15,
 299                         "Nex Gun", IT_NEX, FL_WEAPON);
 300                 return;
 301         }
 302
 303         local float rnd;
 304         self.classname = "minstagib";
 305
 306         // replace rocket launchers and nex guns with ammo cells
 307         if (itemid == IT_CELLS)
 308         {
 309                 self.ammo_cells = 1;
 310                 StartItem ("models/items/a_cells.md3",
 311                         "misc/itempickup.ogg", 45,
 312                         "Nex Ammo", IT_CELLS, 0);
 313                 return;
 314         }
 315
 316         // randomize
 317         rnd = random() * 3;
 318         if (rnd <= 1)
 319                 itemid = IT_STRENGTH;
 320         else if (rnd <= 2)
 321                 itemid = IT_NAILS;
 322         else
 323                 itemid = IT_INVINCIBLE;
 324
 325         // replace with invis
 326         if (itemid == IT_STRENGTH)
 327         {
 328                 self.effects = EF_ADDITIVE;
 329                 self.strength_finished = 30;
 330                 StartItem ("models/items/g_strength.md3",
 331                         "misc/powerup.ogg", 120,
 332                         "Invisibility", IT_STRENGTH, FL_POWERUP);
 333         }
 334         // replace with extra lives
 335         if (itemid == IT_NAILS)
 336         {
 337                 self.max_health = 1;
 338                 StartItem ("models/items/g_h100.md3",
 339                         "misc/megahealth.ogg", 120,
 340                         "Extralife", IT_NAILS, FL_POWERUP);
 341
 342         }
 343         // replace with ammo
 344         if (itemid == IT_INVINCIBLE)
 345         {
 346                 self.effects = EF_ADDITIVE;
 347                 self.invincible_finished = 30;
 348                 StartItem ("models/items/g_invincible.md3",
 349                         "misc/powerup_shield.ogg", 120,
 350                         "Speed", IT_INVINCIBLE, FL_POWERUP);
 351         }
 352
 353 }
 354
 355 void weapon_uzi (void) {
 356         self.ammo_nails = 120;
 357         StartItem ("models/weapons/g_uzi.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_UZI), IT_UZI, FL_WEAPON);
 358 }
 359
 360 void weapon_shotgun (void) {
 361         self.ammo_shells = 15;
 362         StartItem ("models/weapons/g_shotgun.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_SHOTGUN), IT_SHOTGUN, FL_WEAPON);
 363 }
 364
 365 void weapon_grenadelauncher (void) {
 366         self.ammo_rockets = 15;
 367         StartItem ("models/weapons/g_gl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_GRENADE_LAUNCHER), IT_GRENADE_LAUNCHER, FL_WEAPON);
 368 }
 369
 370 void weapon_electro (void) {
 371         self.ammo_cells = 25;
 372         StartItem ("models/weapons/g_electro.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ELECTRO), IT_ELECTRO, FL_WEAPON);
 373 }
 374
 375 void weapon_crylink (void) {
 376         self.ammo_cells = 25;
 377         StartItem ("models/weapons/g_crylink.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_CRYLINK), IT_CRYLINK, FL_WEAPON);
 378 }
 379
 380 void weapon_nex (void) {
 381         if (cvar("g_minstagib")) {
 382                 minstagib_items(IT_CELLS);
 383         } else {
 384                 self.ammo_cells = 25;
 385                 StartItem ("models/weapons/g_nex.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_NEX), IT_NEX, FL_WEAPON);
 386         }
 387 }
 388
 389 void weapon_hagar (void) {
 390         self.ammo_rockets = 15;
 391         StartItem ("models/weapons/g_hagar.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_HAGAR), IT_HAGAR, FL_WEAPON);
 392 }
 393
 394 void weapon_rocketlauncher (void) {
 395         if (cvar("g_minstagib")) {
 396                 minstagib_items(IT_CELLS);
 397         } else {
 398                 self.ammo_rockets = 15;
 399                 StartItem ("models/weapons/g_rl.md3", "weapons/weaponpickup.ogg", 15, W_Name(WEP_ROCKET_LAUNCHER), IT_ROCKET_LAUNCHER, FL_WEAPON);
 400         }
 401 }
 402
 403 void item_rockets (void) {
 404         self.ammo_rockets = 15;
 405         StartItem ("models/items/a_rockets.md3", "misc/itempickup.ogg", 15, "rockets", IT_ROCKETS, 0);
 406 }
 407
 408 void item_bullets (void) {
 409         self.ammo_nails = 120;
 410         StartItem ("models/items/a_bullets.mdl", "misc/itempickup.ogg", 15, "bullets", IT_NAILS, 0);
 411 }
 412
 413 void item_cells (void) {
 414         self.ammo_cells = 25;
 415         StartItem ("models/items/a_cells.md3", "misc/itempickup.ogg", 15, "cells", IT_CELLS, 0);
 416 }
 417
 418 void item_shells (void) {
 419         self.ammo_shells = 15;
 420         StartItem ("models/items/a_shells.md3", "misc/itempickup.ogg", 15, "shells", IT_SHELLS, 0);
 421 }
 422
 423 void item_armor1 (void) {
 424         self.armorvalue = 5;
 425         StartItem ("models/items/g_a1.md3", "misc/armor1.wav", 15, "Armor Shard", 0, 0);
 426 }
 427
 428 void item_armor25 (void) {
 429         self.armorvalue = 100;
 430         StartItem ("models/items/g_a25.md3", "misc/armor25.wav", 30, "Armor", 0, 0);
 431 }
 432
 433 void item_health1 (void) {
 434         self.max_health = 5;
 435         StartItem ("models/items/g_h1.md3", "misc/minihealth.ogg", 15, "5 Health", 0, 0);
 436 }
 437
 438 void item_health25 (void) {
 439         self.max_health = 25;
 440         StartItem ("models/items/g_h25.md3", "misc/mediumhealth.ogg", 15, "25 Health", 0, 0);
 441 }
 442
 443 void item_health100 (void) {
 444         if(!cvar("g_powerup_superhealth"))
 445                 return;
 446
 447         if(cvar("g_minstagib")) {
 448                 minstagib_items(IT_NAILS);
 449         } else {
 450                 self.max_health = 100;
 451                 StartItem ("models/items/g_h100.md3", "misc/megahealth.ogg", 30, "100 Health", 0, 0);
 452         }
 453 }
 454
 455 void item_strength (void) {
 456         if(!cvar("g_powerup_strength"))
 457                 return;
 458
 459         if(cvar("g_minstagib")) {
 460                 minstagib_items(IT_STRENGTH);
 461         } else {
 462                 self.strength_finished = 30;
 463                 self.effects = EF_ADDITIVE;StartItem ("models/items/g_strength.md3", "misc/powerup.ogg", 120, "Strength Powerup", IT_STRENGTH, FL_POWERUP);
 464         }
 465 }
 466
 467 void item_invincible (void) {
 468         if(!cvar("g_powerup_shield"))
 469                 return;
 470
 471         if(cvar("g_minstagib")) {
 472                 minstagib_items(IT_INVINCIBLE);
 473         } else {
 474                 self.invincible_finished = 30;
 475                 self.effects = EF_ADDITIVE;
 476                 StartItem ("models/items/g_invincible.md3", "misc/powerup_shield.ogg", 120, "Invulnerability", IT_INVINCIBLE, FL_POWERUP);
 477         }
 478 }
 479 //void item_speed (void) {self.speed_finished = 30;StartItem ("models/items/g_speed.md3", "misc/powerup.wav", 120, "Speed Powerup", IT_SPEED, FL_POWERUP);}
 480 //void item_slowmo (void) {self.slowmo_finished = 30;StartItem ("models/items/g_slowmo.md3", "misc/powerup.wav", 120, "Slow Motion", IT_SLOWMO, FL_POWERUP);}
 481
 482 void misc_models (void)
 483 {
 484         precache_model (self.model);
 485         setmodel (self, self.model);
 486         setsize (self, self.mins, self.maxs);
 487 }
 488
 489