data/qcsrc/server/gamec/clientcommands.c

   1 void ReadyCount();
   2 float ValidateMap(string vote);
   3
   4 void SV_ParseClientCommand(string s) {
   5         local float index;
   6
   7         tokenize(s);
   8
   9         if(argv(0) == "clogin") {
  10                 if(cvar("sv_clientcommands")) {
  11                         if(self.adminstatus < -5) {
  12                                 sprint(self, "Too many unsuccessful tries.\n");
  13                         } else if(argv(1) == cvar_string("sv_clientcommands_password")) {
  14                                 self.adminstatus = 1;
  15                                 sprint(self, "You now have remote admin status.\n");
  16                                 ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " received admin status"), TRUE);
  17                         } else {
  18                                 sprint(self, "Wrong password.\n");
  19                                 // use of -- produces compiler warning in the if() line???
  20                                 self.adminstatus = self.adminstatus - 1;
  21                                 if(self.adminstatus == 0)
  22                                 {
  23                                         sprint(self, "You lost remote admin status.\n");
  24                                         ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " lost admin status"), TRUE);
  25                                 }
  26                         }
  27                 } else {
  28                         sprint(self, "Clientside commands NOT allowed.\n");
  29                 }
  30         } else if(argv(0) == "ccmd") {
  31                 if(cvar("sv_clientcommands")) {
  32                         if(self.adminstatus > 0) {
  33                                 local string command;
  34                                 command = argv(1);
  35                                 index = 2;
  36                                 while(argv(index) != "") {
  37                                         command = strcat(command, " ", argv(index));
  38                                         index++;
  39                                 }
  40                                 ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " issued command '", command, "'"), TRUE);
  41                                 localcmd(command);
  42                         } else
  43                                 sprint(self, "You don't have remote admin status.\n");
  44                 } else {
  45                         sprint(self, "Clientside commands NOT allowed.\n");
  46                 }
  47         } else if(argv(0) == "vote") {
  48                 if(argv(1) == "help") {
  49                         local string vmasterdis;
  50                         if(!cvar("sv_vote_master")) {
  51                                 vmasterdis = " ^1(disabled)";
  52                         }
  53                         local string vcalldis;
  54                         if(!cvar("sv_vote_call")) {
  55                                 vcalldis = " ^1(disabled)";
  56                         }
  57                         sprint(self, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\".\n");
  58                         sprint(self, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\".\n");
  59                         sprint(self, "^7\"^2help^7\" shows this info.\n");
  60                         sprint(self, "^7\"^2status^7\" shows if there is a vote called and who called it.\n");
  61                         sprint(self, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7\n"));
  62                         sprint(self, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.\n");
  63                         sprint(self, strcat("^7\"^2master^7\" is used to call a vote to become a master.", vmasterdis, "^7\n"));
  64                         sprint(self, "^7\"^2do^7\" If you are a master you can execute a command without a vote. See the list of allowed commands.\n");
  65                         sprint(self, "^7\"^2yes^7\" and \"^2no^7\" to make your vote.\n");
  66                         sprint(self, "^7If more then 50% of the players vote yes the vote is accepted.\n");
  67                         sprint(self, "^7If more then 50% of the players vote no the vote is rejected.\n");
  68                         sprint(self, strcat("^7The vote will end after ", cvar_string("sv_vote_timeout"), "^7 seconds.\n"));
  69                         sprint(self, "^7You can call a vote for or execute these commands:\n");
  70                         sprint(self, strcat("^3", cvar_string("sv_vote_commands"), "^7 and maybe further ^3arguments^7\n"));
  71                 } else if(argv(1) == "status") {
  72                         if(votecalled) {
  73                                 sprint(self, strcat("^7Vote for \"^1", votecalledvote, "^7\" called by \"^7", votecaller.netname, "^7\".\n"));
  74                         } else {
  75                                 sprint(self, "^1No vote called.\n");
  76                         }
  77                 } else if(argv(1) == "call") {
  78                         if(cvar("sv_vote_call")) {
  79                                 if(votecalled) {
  80                                         sprint(self, "^1There is already a vote called.\n");
  81                                 } else {
  82                                         local string vote;
  83                                         vote = VoteParse();
  84                                         if(vote == "") {
  85                                                 sprint(self, "^1Your vote is empty. See help for more info.\n");
  86                                         } else if(time < self.vote_next) {
  87                                                 sprint(self, strcat("^1You have to wait ^2", ftos(self.vote_next - time), "^1 seconds before you can again call a vote.\n"));
  88                                         } else if(VoteAllowed(strcat(argv(2)))) { // strcat seems to be necessary
  89                                                 if(!ValidateMap(vote))
  90                                                         return;
  91                                                 votecalled = TRUE;
  92                                                 votecalledmaster = FALSE;
  93                                                 votecalledvote = strzone(vote);
  94                                                 votecaller = self; // remember who called the vote
  95                                                 votefinished = time + cvar("sv_vote_timeout");
  96                                                 votecaller.vote_vote = 1; // of course you vote yes
  97                                                 votecaller.vote_next = time + cvar("sv_vote_wait");
  98                                                 bprint(strcat("^3Vote for \"^1", votecalledvote, "^3\" called by \"^7", votecaller.netname, "^3\".\n"));
  99                                                 VoteCount(); // needed if you are the only one
 100                                         } else {
 101                                                 sprint(self, "^1This vote is not ok. See help for more info.\n");
 102                                         }
 103                                 }
 104                         } else {
 105                                 sprint(self, "^1Vote calling is NOT allowed.\n");
 106                         }
 107                 } else if(argv(1) == "stop") {
 108                         if(!votecalled) {
 109                                 sprint(self, "^1No vote called.\n");
 110                         } else if(self == votecaller
 111                                   || self.adminstatus > 0) { // the votecaller and admins can stop a vote
 112                                 VoteStop(self);
 113                         } else {
 114                                 sprint(self, "^1You are not allowed to stop that Vote.\n");
 115                         }
 116                 } else if(argv(1) == "master") {
 117                         if(cvar("sv_vote_master")) {
 118                                 if(votecalled) {
 119                                         sprint(self, "^1There is already a vote called.\n");
 120                                 } else {
 121                                         votecalled = TRUE;
 122                                         votecalledmaster = TRUE;
 123                                         votecalledvote = strzone("^3master");
 124                                         votecaller = self; // remember who called the vote
 125                                         votefinished = time + cvar("sv_vote_timeout");
 126                                         votecaller.vote_vote = 1; // of course you vote yes
 127                                         votecaller.vote_next = time + cvar("sv_vote_wait");
 128                                         bprint(strcat("\"^3", votecaller.netname, "^3\" called a vote to become ^3master^3.\n"));
 129                                         VoteCount(); // needed if you are the only one
 130                                 }
 131                         } else {
 132                                 sprint(self, "^1Vote to become master is NOT allowed.\n");
 133                         }
 134                 } else if(argv(1) == "do") {
 135                         if(self.vote_master) {
 136                                 local string dovote;
 137                                 dovote = VoteParse();
 138                                 if(dovote == "") {
 139                                         sprint(self, "^1Your command was empty. See help for more info.\n");
 140                                 } else if(VoteAllowed(strcat(argv(2)))) { // strcat seems to be necessary
 141                                         bprint("\"^7", strcat(self.netname, "^2 used his ^3master^2 status to do \"^2", dovote, "^2\".\n"));
 142                                         localcmd(dovote);
 143                                 } else {
 144                                         sprint(self, "^1This command is not ok. See help for more info.\n");
 145                                 }
 146                         } else {
 147                                 sprint(self, "^1You are NOT a master.\n");
 148                         }
 149                 } else if(argv(1) == "yes") {
 150                         if(!votecalled) {
 151                                 sprint(self, "^1No vote called.\n");
 152                         } else if(self.vote_vote == 0
 153                                   || cvar("sv_vote_change")) {
 154                                 sprint(self, "^1You accepted the vote.\n");
 155                                 self.vote_vote = 1;
 156                                 if(!cvar("sv_vote_singlecount")) {
 157                                         VoteCount();
 158                                 }
 159                         } else {
 160                                 sprint(self, "^1You have already voted.\n");
 161                         }
 162                 } else if(argv(1) == "no") {
 163                         if(!votecalled) {
 164                                 sprint(self, "^1No vote called.\n");
 165                         } else if(self.vote_vote == 0
 166                                   || cvar("sv_vote_change")) {
 167                                 sprint(self, "^1You rejected the vote.\n");
 168                                 self.vote_vote = -1;
 169                                 if(!cvar("sv_vote_singlecount")) {
 170                                         VoteCount();
 171                                 }
 172                         } else {
 173                                 sprint(self, "^1You have already voted.\n");
 174                         }
 175                 } else {
 176                         // ignore this?
 177                         sprint(self, "^1Unknown vote command.\n");
 178                 }
 179         } else if(argv(0) == "autoswitch") {
 180                 // be backwards compatible with older clients (enabled)
 181                 self.autoswitch = ("0" != argv(1));
 182                 local string autoswitchmsg;
 183                 if (self.autoswitch) {
 184                         autoswitchmsg = "on";
 185                 } else {
 186                         autoswitchmsg = "off";
 187                 }
 188                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 189         } else if(argv(0) == "clientversion") {
 190                 if (argv(1) == "$gameversion") {
 191                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 192                         // either that or someone wants to be funny
 193                         self.version = 1;
 194                 } else {
 195                         self.version = stof(argv(1));
 196                 }
 197                 if(self.version != cvar("gameversion"))
 198                 {
 199                         self.classname = "observer";
 200                         self.frags = -2;
 201                         PutClientInServer();
 202                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 203                         self.classname = "observer";
 204                         stuffcmd(self,"menu_showteamselect\n");
 205                 }
 206         } else if(argv(0) == "spectate") {
 207                 if(cvar("g_lms") || cvar("g_arena"))
 208                         return; // don't allow spectating in lms, unless player runs out of lives
 209                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 210                         self.classname = "observer";
 211                         PutClientInServer();
 212                 }
 213         } else if(argv(0) == "join") {
 214                 if(!cvar("g_arena"))
 215                 if (self.classname != "player")
 216                 {
 217                         self.classname = "player";
 218                         self.frags = 0;
 219                         bprint (strcat("^4", self.netname, "^4 is playing now\n"));
 220                         PutClientInServer();
 221                 }
 222         } else if( argv(0) == "selectteam" ) {
 223                 if( !cvar("teamplay") ) {
 224                         sprint( self, "selecteam can only be used in teamgames\n");
 225                 } else if( argv(1) == "none" ) {
 226                         SV_ChangeTeam( 0 );
 227                 } else if( argv(1) == "red" ) {
 228                         SV_ChangeTeam( COLOR_TEAM1 - 1 );
 229                 } else if( argv(1) == "blue" ) {
 230                         SV_ChangeTeam( COLOR_TEAM2 - 1 );
 231                 } else if( argv(1) == "pink" ) {
 232                         SV_ChangeTeam( COLOR_TEAM3 - 1 );
 233                 } else if( argv(1) == "yellow" ) {
 234                         SV_ChangeTeam( COLOR_TEAM4 - 1 );
 235                 } else if( argv(1) == "auto" ) {
 236                         JoinBestTeam( self, 0 );
 237                 } else {
 238                         sprint( self, strcat( "selectteam none/red/blue/pink/yellow/auto - \"", argv(1), "\" not recognised\n" ) );
 239                 }
 240         } else if(argv(0) == "ready") {
 241                 if(cvar("sv_ready_restart"))
 242                 {
 243                         self.ready = TRUE;
 244                         bprint(self.netname, "^2 is ready\n");
 245                         ReadyCount();
 246                 }
 247         } else if(argv(0) == "say") {
 248                 clientcommand(self, formatmessage(s));
 249         } else if(argv(0) == "say_team") {
 250                 clientcommand(self, formatmessage(s));
 251         } else {
 252                 clientcommand(self,s);
 253         }
 254 }
 255
 256 float ValidateMap(string vote)
 257 {
 258         string ext;
 259
 260         tokenize(vote);
 261         if(argv(0) == "map" || argv(0) == "changelevel")
 262                 ext = ".bsp";
 263         else if(argv(0) == "chmap")
 264                 ext = ".mapcfg";
 265         else
 266                 return TRUE;
 267
 268         if(!TryFile(strcat("maps/", argv(1), ext)))
 269         {
 270                 sprint(self, strcat("^1Invalid mapname, \"^3", argv(1), "^1\" does not exist on this server.\n"));
 271                 return FALSE;
 272         }
 273         return TRUE;
 274 }
 275
 276
 277 void VoteThink() {
 278         if(votefinished > 0 // a vote was called
 279             && time > votefinished) // time is up
 280         {
 281                 VoteCount();
 282         }
 283 }
 284
 285 string VoteParse() {
 286         local float index;
 287         index = 3;
 288         local string vote;
 289         vote = argv(2);
 290         while(argv(index) != "") {
 291                 vote = strcat(vote, " ", argv(index));
 292                 index++;
 293         }
 294
 295         // necessary for some of the string operations
 296         vote = strzone(vote);
 297
 298         // now we remove some things that could be misused
 299         index = 0;
 300         local float found;
 301         found = FALSE;
 302         local float votelength;
 303         votelength = strlen(vote);
 304         while(!found && index < votelength)
 305         {
 306                 local string badchar;
 307                 badchar = substring(vote, index, 1);
 308                 if(badchar == ";"
 309                    || badchar == "\r"
 310                    || badchar == "\n")
 311                 {
 312                         found = TRUE;
 313                 } else {
 314                         index++;
 315                 }
 316         }
 317         return substring(vote, 0, index);
 318 }
 319
 320 float VoteAllowed(string votecommand) {
 321         tokenize(cvar_string("sv_vote_commands"));
 322         local float index;
 323         index = 0;
 324         while(argv(index) != "") {
 325                 local string allowed;
 326                 allowed = argv(index);
 327                 if(votecommand == allowed) {
 328                         return TRUE;
 329                 }
 330                 index++;
 331         }
 332         return FALSE;
 333 }
 334
 335 void VoteReset() {
 336         local string searchclass;
 337         searchclass = "player";
 338
 339         while (TRUE)
 340         {
 341                 local entity player;
 342                 player = find(player, classname, searchclass);
 343                 while(player)
 344                 {
 345                         player.vote_vote = 0;
 346                         player = find(player, classname, searchclass);
 347                 }
 348
 349                 if("player" == searchclass) {
 350                         searchclass = "observer";
 351                 } else if("observer" == searchclass) {
 352                         searchclass = "spectator";
 353                 } else {
 354                         break;
 355                 }
 356         }
 357
 358         votecalled = FALSE;
 359         votecalledmaster = FALSE;
 360         votefinished = 0;
 361 }
 362
 363 void VoteAccept() {
 364         bprint(strcat("^2The vote for \"^1", votecalledvote, "^2\" from \"^7", votecaller.netname, "^2\" was accepted.\n"));
 365         if(votecalledmaster)
 366         {
 367                 votecaller.vote_master = 1;
 368         } else {
 369                 localcmd(votecalledvote);
 370         }
 371         votecaller.vote_next = 0; // people like your votes, no wait for next vote
 372         VoteReset();
 373 }
 374
 375 void VoteReject() {
 376         bprint(strcat("^2The vote for \"^1", votecalledvote, "^2\" from \"^7", votecaller.netname, "^2\" was rejected.\n"));
 377         VoteReset();
 378 }
 379
 380 void VoteTimeout() {
 381         bprint(strcat("^5The vote for \"^1", votecalledvote, "^5\" from \"^7", votecaller.netname, "^5\" did timeout.\n"));
 382         VoteReset();
 383 }
 384
 385 void VoteStop(entity stopper) {
 386         bprint(strcat("^5The vote for \"^1", votecalledvote, "^5\" from \"^7", votecaller.netname, "^5\" was stopped by \"^5", stopper.netname, "^5\".\n"));
 387         if(stopper == votecaller) {
 388                 // no wait for next vote so you can correct your vote
 389                 votecaller.vote_next = 0;
 390         }
 391         VoteReset();
 392 }
 393
 394 void VoteCount() {
 395         local float playercount;
 396         playercount = 0;
 397         local float yescount;
 398         yescount = 0;
 399         local float nocount;
 400         nocount = 0;
 401         local string searchclass;
 402         searchclass = "player";
 403
 404         while (TRUE)
 405         {
 406                 local entity player;
 407                 player = find(player, classname, searchclass);
 408
 409                 while(player)
 410                 {
 411                         if(clienttype(player) != CLIENTTYPE_BOT) {
 412                                 if(player.vote_vote < 0) {
 413                                         nocount++;
 414                                 } else if(player.vote_vote > 0) {
 415                                         yescount++;
 416                                 }
 417                                 playercount++;
 418                         }
 419                         player = find(player, classname, searchclass);
 420                 }
 421
 422                 if("player" == searchclass) {
 423                         searchclass = "observer";
 424                 } else if("observer" == searchclass) {
 425                         searchclass = "specator";
 426                 } else {
 427                         break;
 428                 }
 429         }
 430
 431         if((playercount == 1) && votecalledmaster) {
 432                 // if only one player is on the server becoming vote
 433                 // master is not allowed.  This could be used for
 434                 // trolling or worse. 'self' is the user who has
 435                 // called the vote because this function is called
 436                 // by SV_ParseClientCommand. Maybe all voting should
 437                 // be disabled for a single player?
 438                 sprint(self, "^1You are the only player on this server so you can not become vote master.\n");
 439                 votecaller.vote_next = 0;
 440                 VoteReset();
 441         } else if((playercount / 2) < yescount) { // vote accepted
 442                 VoteAccept();
 443         } else if((playercount / 2) < nocount) { // vote rejected
 444                 VoteReject();
 445         } else if(time > votefinished) { // vote timedout
 446                 VoteTimeout();
 447         } // else still running
 448 }
 449
 450
 451 void ReadyCount()
 452 {
 453         local entity e;
 454         local float r, p;
 455
 456         e = find(world, classname, "player");
 457
 458         while(e)
 459         {
 460                 if(clienttype(e) == CLIENTTYPE_REAL)
 461                 {
 462                         p += 1;
 463                         if(e.ready) r += 1;
 464                 }
 465                 e = find(e, classname, "player");
 466         }
 467
 468         if(p && r == p)
 469         {
 470                 bprint("^1Server is restarting...\n");
 471                 localcmd("restart\n");
 472         }
 473 }