data/qcsrc/server/gamec/clientcommands.c

   1 void ReadyCount();
   2 float ValidateMap(string vote);
   3
   4 void SV_ParseClientCommand(string s) {
   5         local float index;
   6
   7         tokenize(s);
   8
   9         if(argv(0) == "clogin") {
  10                 if(cvar("sv_clientcommands")) {
  11                         if(self.adminstatus < -5) {
  12                                 sprint(self, "Too many unsuccessful tries.\n");
  13                         } else if(argv(1) == cvar_string("sv_clientcommands_password")) {
  14                                 self.adminstatus = 1;
  15                                 sprint(self, "You now have remote admin status.\n");
  16                                 ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " received admin status"), TRUE);
  17                         } else {
  18                                 sprint(self, "Wrong password.\n");
  19                                 // use of -- produces compiler warning in the if() line???
  20                                 self.adminstatus = self.adminstatus - 1;
  21                                 if(self.adminstatus == 0)
  22                                 {
  23                                         sprint(self, "You lost remote admin status.\n");
  24                                         ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " lost admin status"), TRUE);
  25                                 }
  26                         }
  27                 } else {
  28                         sprint(self, "Clientside commands NOT allowed.\n");
  29                 }
  30         } else if(argv(0) == "ccmd") {
  31                 if(cvar("sv_clientcommands")) {
  32                         if(self.adminstatus > 0) {
  33                                 local string command;
  34                                 command = argv(1);
  35                                 index = 2;
  36                                 while(argv(index) != "") {
  37                                         command = strcat(command, " ", argv(index));
  38                                         index++;
  39                                 }
  40                                 ServerConsoleEcho(strcat("ClientCommands: ", self.netname, " issued command '", command, "'"), TRUE);
  41                                 localcmd(command);
  42                         } else
  43                                 sprint(self, "You don't have remote admin status.\n");
  44                 } else {
  45                         sprint(self, "Clientside commands NOT allowed.\n");
  46                 }
  47         } else if(argv(0) == "vote") {
  48                 if(argv(1) == "help") {
  49                         local string vmasterdis;
  50                         if(!cvar("sv_vote_master")) {
  51                                 vmasterdis = " ^1(disabled)";
  52                         }
  53                         local string vcalldis;
  54                         if(!cvar("sv_vote_call")) {
  55                                 vcalldis = " ^1(disabled)";
  56                         }
  57                         sprint(self, "^7You can use voting with \"^2cmd vote help^7\" \"^2cmd vote status^7\" \"^2cmd vote call ^3COMMAND ARGUMENTS^7\" \"^2cmd vote stop^7\" \"^2cmd vote master^7\" \"^2cmd vote do ^3COMMAND ARGUMENTS^7\" \"^2cmd vote yes^7\" \"^2cmd vote no^7\".\n");
  58                         sprint(self, "^7Or if your version is up to date you can use these aliases \"^2vhelp^7\" \"^2vstatus^7\" \"^2vcall ^3COMMAND ARGUMENTS^7\" \"^2vstop^7\" \"^2vmaster^7\" \"^2vdo ^3COMMAND ARGUMENTS^7\" \"^2vyes^7\" \"^2vno^7\".\n");
  59                         sprint(self, "^7\"^2help^7\" shows this info.\n");
  60                         sprint(self, "^7\"^2status^7\" shows if there is a vote called and who called it.\n");
  61                         sprint(self, strcat("^7\"^2call^7\" is used to call a vote. See the list of allowed commands.", vcalldis, "^7\n"));
  62                         sprint(self, "^7\"^2stop^7\" can be used by the vote caller or an admin to stop a vote and maybe correct it.\n");
  63                         sprint(self, strcat("^7\"^2master^7\" is used to call a vote to become a master.", vmasterdis, "^7\n"));
  64                         sprint(self, "^7\"^2do^7\" If you are a master you can execute a command without a vote. See the list of allowed commands.\n");
  65                         sprint(self, "^7\"^2yes^7\" and \"^2no^7\" to make your vote.\n");
  66                         sprint(self, "^7If more then 50% of the players vote yes the vote is accepted.\n");
  67                         sprint(self, "^7If more then 50% of the players vote no the vote is rejected.\n");
  68                         sprint(self, strcat("^7The vote will end after ", cvar_string("sv_vote_timeout"), "^7 seconds.\n"));
  69                         sprint(self, "^7You can call a vote for or execute these commands:\n");
  70                         sprint(self, strcat("^3", cvar_string("sv_vote_commands"), "^7 and maybe further ^3arguments^7\n"));
  71                 } else if(argv(1) == "status") {
  72                         if(votecalled) {
  73                                 sprint(self, strcat("^7Vote for \"^1", votecalledvote, "^7\" called by \"^7", votecaller.netname, "^7\".\n"));
  74                         } else {
  75                                 sprint(self, "^1No vote called.\n");
  76                         }
  77                 } else if(argv(1) == "call") {
  78                         if(cvar("sv_vote_call")) {
  79                                 if(votecalled) {
  80                                         sprint(self, "^1There is already a vote called.\n");
  81                                 } else {
  82                                         local string vote;
  83                                         vote = VoteParse();
  84                                         if(vote == "") {
  85                                                 sprint(self, "^1Your vote is empty. See help for more info.\n");
  86                                         } else if(time < self.vote_next) {
  87                                                 sprint(self, strcat("^1You have to wait ^2", ftos(self.vote_next - time), "^1 seconds before you can again call a vote.\n"));
  88                                         } else if(VoteAllowed(strcat(argv(2)))) { // strcat seems to be necessary
  89                                                 if(!ValidateMap(vote))
  90                                                         return;
  91                                                 votecalled = TRUE;
  92                                                 votecalledmaster = FALSE;
  93                                                 votecalledvote = strzone(vote);
  94                                                 votecaller = self; // remember who called the vote
  95                                                 votefinished = time + cvar("sv_vote_timeout");
  96                                                 votecaller.vote_vote = 1; // of course you vote yes
  97                                                 votecaller.vote_next = time + cvar("sv_vote_wait");
  98                                                 bprint(strcat("^3Vote for \"^1", votecalledvote, "^3\" called by \"^7", votecaller.netname, "^3\".\n"));
  99                                                 VoteCount(); // needed if you are the only one
 100                                         } else {
 101                                                 sprint(self, "^1This vote is not ok. See help for more info.\n");
 102                                         }
 103                                 }
 104                         } else {
 105                                 sprint(self, "^1Vote calling is NOT allowed.\n");
 106                         }
 107                 } else if(argv(1) == "stop") {
 108                         if(!votecalled) {
 109                                 sprint(self, "^1No vote called.\n");
 110                         } else if(self == votecaller
 111                                   || self.adminstatus > 0) { // the votecaller and admins can stop a vote
 112                                 VoteStop(self);
 113                         } else {
 114                                 sprint(self, "^1You are not allowed to stop that Vote.\n");
 115                         }
 116                 } else if(argv(1) == "master") {
 117                         if(cvar("sv_vote_master")) {
 118                                 if(votecalled) {
 119                                         sprint(self, "^1There is already a vote called.\n");
 120                                 } else {
 121                                         votecalled = TRUE;
 122                                         votecalledmaster = TRUE;
 123                                         votecalledvote = strzone("^3master");
 124                                         votecaller = self; // remember who called the vote
 125                                         votefinished = time + cvar("sv_vote_timeout");
 126                                         votecaller.vote_vote = 1; // of course you vote yes
 127                                         votecaller.vote_next = time + cvar("sv_vote_wait");
 128                                         bprint(strcat("\"^3", votecaller.netname, "^3\" called a vote to become ^3master^3.\n"));
 129                                         VoteCount(); // needed if you are the only one
 130                                 }
 131                         } else {
 132                                 sprint(self, "^1Vote to become master is NOT allowed.\n");
 133                         }
 134                 } else if(argv(1) == "do") {
 135                         if(self.vote_master) {
 136                                 local string dovote;
 137                                 dovote = VoteParse();
 138                                 if(dovote == "") {
 139                                         sprint(self, "^1Your command was empty. See help for more info.\n");
 140                                 } else if(VoteAllowed(strcat(argv(2)))) { // strcat seems to be necessary
 141                                         bprint("\"^7", strcat(self.netname, "^2 used his ^3master^2 status to do \"^2", dovote, "^2\".\n"));
 142                                         localcmd(dovote);
 143                                 } else {
 144                                         sprint(self, "^1This command is not ok. See help for more info.\n");
 145                                 }
 146                         } else {
 147                                 sprint(self, "^1You are NOT a master.\n");
 148                         }
 149                 } else if(argv(1) == "yes") {
 150                         if(!votecalled) {
 151                                 sprint(self, "^1No vote called.\n");
 152                         } else if(self.vote_vote == 0
 153                                   || cvar("sv_vote_change")) {
 154                                 sprint(self, "^1You accepted the vote.\n");
 155                                 self.vote_vote = 1;
 156                                 if(!cvar("sv_vote_singlecount")) {
 157                                         VoteCount();
 158                                 }
 159                         } else {
 160                                 sprint(self, "^1You have already voted.\n");
 161                         }
 162                 } else if(argv(1) == "no") {
 163                         if(!votecalled) {
 164                                 sprint(self, "^1No vote called.\n");
 165                         } else if(self.vote_vote == 0
 166                                   || cvar("sv_vote_change")) {
 167                                 sprint(self, "^1You rejected the vote.\n");
 168                                 self.vote_vote = -1;
 169                                 if(!cvar("sv_vote_singlecount")) {
 170                                         VoteCount();
 171                                 }
 172                         } else {
 173                                 sprint(self, "^1You have already voted.\n");
 174                         }
 175                 } else {
 176                         // ignore this?
 177                         sprint(self, "^1Unknown vote command.\n");
 178                 }
 179         } else if(argv(0) == "autoswitch") {
 180                 // be backwards compatible with older clients (enabled)
 181                 self.autoswitch = ("0" != argv(1));
 182                 local string autoswitchmsg;
 183                 if (self.autoswitch) {
 184                         autoswitchmsg = "on";
 185                 } else {
 186                         autoswitchmsg = "off";
 187                 }
 188                 sprint(self, strcat("^1autoswitch turned ", autoswitchmsg, "\n"));
 189         } else if(argv(0) == "clientversion") {
 190                 if (argv(1) == "$gameversion") {
 191                         //versionmsg = "^1client is too old to get versioninfo.\nUPDATE!!! (http://www.nexuiz.com)^8";
 192                         // either that or someone wants to be funny
 193                         self.version = 1;
 194                 } else {
 195                         self.version = stof(argv(1));
 196                 }
 197                 if(self.version != cvar("gameversion"))
 198                 {
 199                         self.classname = "observer";
 200                         self.frags = -2;
 201                         PutClientInServer();
 202                 } else if(cvar("teamplay") && !cvar("sv_spectate")) {
 203                         self.classname = "observer";
 204                         stuffcmd(self,"menu_showteamselect\n");
 205                 }
 206         } else if(argv(0) == "spectate") {
 207                 if(cvar("g_lms"))
 208                         return; // don't allow spectating in lms, unless player runs out of lives
 209                 if(self.classname == "player" && cvar("sv_spectate") == 1) {
 210                         self.classname = "observer";
 211                         PutClientInServer();
 212                 }
 213         } else if(argv(0) == "join") {
 214                 if (self.classname != "player")
 215                 {
 216                         self.classname = "player";
 217                         self.frags = 0;
 218                         bprint (strcat("^4", self.netname, "^4 is playing now\n"));
 219                         PutClientInServer();
 220                 }
 221         } else if( argv(0) == "selectteam" ) {
 222                 if( !cvar("teamplay") ) {
 223                         sprint( self, "selecteam can only be used in teamgames\n");
 224                 } else if( argv(1) == "none" ) {
 225                         SV_ChangeTeam( 0 );
 226                 } else if( argv(1) == "red" ) {
 227                         SV_ChangeTeam( COLOR_TEAM1 - 1 );
 228                 } else if( argv(1) == "blue" ) {
 229                         SV_ChangeTeam( COLOR_TEAM2 - 1 );
 230                 } else if( argv(1) == "pink" ) {
 231                         SV_ChangeTeam( COLOR_TEAM3 - 1 );
 232                 } else if( argv(1) == "yellow" ) {
 233                         SV_ChangeTeam( COLOR_TEAM4 - 1 );
 234                 } else if( argv(1) == "auto" ) {
 235                         JoinBestTeam( self, 0 );
 236                 } else {
 237                         sprint( self, strcat( "selectteam none/red/blue/pink/yellow/auto - \"", argv(1), "\" not recognised\n" ) );
 238                 }
 239         } else if(argv(0) == "ready") {
 240                 if(cvar("sv_ready_restart"))
 241                 {
 242                         self.ready = TRUE;
 243                         bprint(self.netname, "^2 is ready\n");
 244                         ReadyCount();
 245                 }
 246         } else {
 247                 clientcommand(self,s);
 248         }
 249 }
 250
 251 float ValidateMap(string vote)
 252 {
 253         string ext;
 254
 255         tokenize(vote);
 256         if(argv(0) == "map" || argv(0) == "changelevel")
 257                 ext = ".bsp";
 258         else if(argv(0) == "chmap")
 259                 ext = ".mapcfg";
 260         else
 261                 return TRUE;
 262
 263         if(!TryFile(strcat("maps/", argv(1), ext)))
 264         {
 265                 sprint(self, strcat("^1Invalid mapname, \"^3", argv(1), "^1\" does not exist on this server.\n"));
 266                 return FALSE;
 267         }
 268         return TRUE;
 269 }
 270
 271
 272 void VoteThink() {
 273         if(votefinished > 0 // a vote was called
 274             && time > votefinished) // time is up
 275         {
 276                 VoteCount();
 277         }
 278 }
 279
 280 string VoteParse() {
 281         local float index;
 282         index = 3;
 283         local string vote;
 284         vote = argv(2);
 285         while(argv(index) != "") {
 286                 vote = strcat(vote, " ", argv(index));
 287                 index++;
 288         }
 289
 290         // necessary for some of the string operations
 291         vote = strzone(vote);
 292
 293         // now we remove some things that could be misused
 294         index = 0;
 295         local float found;
 296         found = FALSE;
 297         local float votelength;
 298         votelength = strlen(vote);
 299         while(!found && index < votelength)
 300         {
 301                 local string badchar;
 302                 badchar = substring(vote, index, 1);
 303                 if(badchar == ";"
 304                    || badchar == "\r"
 305                    || badchar == "\n")
 306                 {
 307                         found = TRUE;
 308                 } else {
 309                         index++;
 310                 }
 311         }
 312         return substring(vote, 0, index);
 313 }
 314
 315 float VoteAllowed(string votecommand) {
 316         tokenize(cvar_string("sv_vote_commands"));
 317         local float index;
 318         index = 0;
 319         while(argv(index) != "") {
 320                 local string allowed;
 321                 allowed = argv(index);
 322                 if(votecommand == allowed) {
 323                         return TRUE;
 324                 }
 325                 index++;
 326         }
 327         return FALSE;
 328 }
 329
 330 void VoteReset() {
 331         local string searchclass;
 332         searchclass = "player";
 333
 334         while (TRUE)
 335         {
 336                 local entity player;
 337                 player = find(player, classname, searchclass);
 338                 while(player)
 339                 {
 340                         player.vote_vote = 0;
 341                         player = find(player, classname, searchclass);
 342                 }
 343
 344                 if("player" == searchclass) {
 345                         searchclass = "observer";
 346                 } else if("observer" == searchclass) {
 347                         searchclass = "spectator";
 348                 } else {
 349                         break;
 350                 }
 351         }
 352
 353         votecalled = FALSE;
 354         votecalledmaster = FALSE;
 355         votefinished = 0;
 356 }
 357
 358 void VoteAccept() {
 359         bprint(strcat("^2The vote for \"^1", votecalledvote, "^2\" from \"^7", votecaller.netname, "^2\" was accepted.\n"));
 360         if(votecalledmaster)
 361         {
 362                 votecaller.vote_master = 1;
 363         } else {
 364                 localcmd(votecalledvote);
 365         }
 366         votecaller.vote_next = 0; // people like your votes, no wait for next vote
 367         VoteReset();
 368 }
 369
 370 void VoteReject() {
 371         bprint(strcat("^2The vote for \"^1", votecalledvote, "^2\" from \"^7", votecaller.netname, "^2\" was rejected.\n"));
 372         VoteReset();
 373 }
 374
 375 void VoteTimeout() {
 376         bprint(strcat("^5The vote for \"^1", votecalledvote, "^5\" from \"^7", votecaller.netname, "^5\" did timeout.\n"));
 377         VoteReset();
 378 }
 379
 380 void VoteStop(entity stopper) {
 381         bprint(strcat("^5The vote for \"^1", votecalledvote, "^5\" from \"^7", votecaller.netname, "^5\" was stopped by \"^5", stopper.netname, "^5\".\n"));
 382         if(stopper == votecaller) {
 383                 // no wait for next vote so you can correct your vote
 384                 votecaller.vote_next = 0;
 385         }
 386         VoteReset();
 387 }
 388
 389 void VoteCount() {
 390         local float playercount;
 391         playercount = 0;
 392         local float yescount;
 393         yescount = 0;
 394         local float nocount;
 395         nocount = 0;
 396         local string searchclass;
 397         searchclass = "player";
 398
 399         while (TRUE)
 400         {
 401                 local entity player;
 402                 player = find(player, classname, searchclass);
 403
 404                 while(player)
 405                 {
 406                         if(clienttype(player) != CLIENTTYPE_BOT) {
 407                                 if(player.vote_vote < 0) {
 408                                         nocount++;
 409                                 } else if(player.vote_vote > 0) {
 410                                         yescount++;
 411                                 }
 412                                 playercount++;
 413                         }
 414                         player = find(player, classname, searchclass);
 415                 }
 416
 417                 if("player" == searchclass) {
 418                         searchclass = "observer";
 419                 } else if("observer" == searchclass) {
 420                         searchclass = "specator";
 421                 } else {
 422                         break;
 423                 }
 424         }
 425
 426         if((playercount == 1) && votecalledmaster) {
 427                 // if only one player is on the server becoming vote
 428                 // master is not allowed.  This could be used for
 429                 // trolling or worse. 'self' is the user who has
 430                 // called the vote because this function is called
 431                 // by SV_ParseClientCommand. Maybe all voting should
 432                 // be disabled for a single player?
 433                 sprint(self, "^1You are the only player on this server so you can not become vote master.\n");
 434                 votecaller.vote_next = 0;
 435                 VoteReset();
 436         } else if((playercount / 2) < yescount) { // vote accepted
 437                 VoteAccept();
 438         } else if((playercount / 2) < nocount) { // vote rejected
 439                 VoteReject();
 440         } else if(time > votefinished) { // vote timedout
 441                 VoteTimeout();
 442         } // else still running
 443 }
 444
 445
 446 void ReadyCount()
 447 {
 448         local entity e;
 449         local float r, p;
 450
 451         e = find(world, classname, "player");
 452
 453         while(e)
 454         {
 455                 if(clienttype(e) == CLIENTTYPE_REAL)
 456                 {
 457                         p += 1;
 458                         if(e.ready) r += 1;
 459                 }
 460                 e = find(e, classname, "player");
 461         }
 462
 463         if(p && r == p)
 464         {
 465                 bprint("^1Server is restarting...\n");
 466                 localcmd("restart\n");
 467         }
 468 }