data/qcsrc/server/gamec/cl_physics.c

   1 float sv_accelerate;
   2 float sv_maxairspeed;
   3 float sv_friction;
   4 float sv_maxspeed;
   5 float sv_stopspeed;
   6 float sv_gravity;
   7 .float ladder_time;
   8 .entity ladder_entity;
   9 .float gravity;
  10 .float swamp_slowdown;
  11 .float lastflags;
  12
  13 void Nixnex_GiveCurrentWeapon();
  14 void SV_PlayerPhysics()
  15 {
  16         local vector wishvel, wishdir, v;
  17         local float wishspeed, f, maxspd_mod, spd, maxairspd, airaccel, swampspd_mod;
  18         string temps;
  19
  20         Nixnex_GiveCurrentWeapon();
  21
  22         // MauveBot_AI();
  23         if (clienttype(self) == CLIENTTYPE_BOT)
  24         {
  25                 if (self.bot_type == BOT_TYPE_MAUVEBOT || self.bot_type == BOT_TYPE_AUTOMAUVE)
  26                         MauveBot_AI();
  27                 else if (self.bot_type == BOT_TYPE_URREBOT || self.bot_type == BOT_TYPE_AUTOURRE)
  28                         UrreBotThink();
  29         }
  30
  31         if (self.movetype == MOVETYPE_NONE)
  32                 return;
  33
  34         if (self.punchangle != '0 0 0')
  35         {
  36                 f = vlen(self.punchangle) - 10 * frametime;
  37                 if (f > 0)
  38                         self.punchangle = normalize(self.punchangle) * f;
  39                 else
  40                         self.punchangle = '0 0 0';
  41         }
  42
  43         if (self.punchvector != '0 0 0')
  44         {
  45                 f = vlen(self.punchvector) - 30 * frametime;
  46                 if (f > 0)
  47                         self.punchvector = normalize(self.punchvector) * f;
  48                 else
  49                         self.punchvector = '0 0 0';
  50         }
  51
  52         maxspd_mod = 1;
  53
  54         if(cvar("g_runematch"))
  55         {
  56                 if(self.runes & RUNE_SPEED)
  57                 {
  58                         if(self.runes & CURSE_SLOW)
  59                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_combo_moverate");
  60                         else
  61                                 maxspd_mod = maxspd_mod * cvar("g_balance_rune_speed_moverate");
  62                 }
  63                 else if(self.runes & CURSE_SLOW)
  64                 {
  65                         maxspd_mod = maxspd_mod * cvar("g_balance_curse_slow_moverate");
  66                 }
  67         }
  68
  69         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
  70         {
  71                 maxspd_mod = cvar("g_balance_rune_speed_moverate");
  72         }
  73
  74         swampspd_mod = 1;
  75         if(self.in_swamp) {
  76                 swampspd_mod = self.swamp_slowdown; //cvar("g_balance_swamp_moverate");
  77         }
  78
  79
  80         spd = sv_maxspeed * maxspd_mod * swampspd_mod;
  81
  82         if(self.speed != spd)
  83         {
  84                 self.speed = spd;
  85                 temps = ftos(spd);
  86                 stuffcmd(self, strcat("cl_forwardspeed ", temps, "\n"));
  87                 stuffcmd(self, strcat("cl_backspeed ", temps, "\n"));
  88                 stuffcmd(self, strcat("cl_sidespeed ", temps, "\n"));
  89                 stuffcmd(self, strcat("cl_upspeed ", temps, "\n"));
  90
  91                 temps = ftos(sv_accelerate * maxspd_mod);
  92                 stuffcmd(self, strcat("cl_movement_accelerate ", temps, "\n"));
  93         }
  94
  95         // if dead, behave differently
  96         if (self.deadflag)
  97                 return;
  98
  99         if (!self.fixangle)
 100         {
 101                 self.angles_x = 0;
 102                 self.angles_y = self.v_angle_y;
 103                 self.angles_z = 0;
 104         }
 105
 106         if (self.flags & FL_WATERJUMP )
 107         {
 108                 self.velocity_x = self.movedir_x;
 109                 self.velocity_y = self.movedir_y;
 110                 if (time > self.teleport_time || self.waterlevel == 0)
 111                 {
 112                         self.flags = self.flags - (self.flags & FL_WATERJUMP);
 113                         self.teleport_time = 0;
 114                 }
 115         }
 116         else if (self.movetype == MOVETYPE_NOCLIP || self.movetype == MOVETYPE_FLY)
 117         {
 118                 // noclipping or flying
 119                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 120
 121                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 122                 makevectors(self.v_angle);
 123                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 124                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 125                 // acceleration
 126                 wishdir = normalize(wishvel);
 127                 wishspeed = vlen(wishvel);
 128                 if (wishspeed > sv_maxspeed*maxspd_mod)
 129                         wishspeed = sv_maxspeed*maxspd_mod;
 130                 if (time >= self.teleport_time)
 131                 {
 132                         f = wishspeed - (self.velocity * wishdir);
 133                         if (f > 0)
 134                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 135                 }
 136         }
 137         else if (self.waterlevel >= 2)
 138         {
 139                 // swimming
 140                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 141
 142                 makevectors(self.v_angle);
 143                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 144                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 145                 if (wishvel == '0 0 0')
 146                         wishvel = '0 0 -60'; // drift towards bottom
 147
 148                 wishdir = normalize(wishvel);
 149                 wishspeed = vlen(wishvel);
 150                 if (wishspeed > sv_maxspeed*maxspd_mod)
 151                         wishspeed = sv_maxspeed*maxspd_mod;
 152                 wishspeed = wishspeed * 0.7;
 153
 154                 // water friction
 155                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 156
 157                 // water acceleration
 158                 f = wishspeed - (self.velocity * wishdir);
 159                 if (f > 0)
 160                         self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 161         }
 162         else if (time < self.ladder_time)
 163         {
 164                 // on a func_ladder or swimming in func_water
 165                 self.flags = self.flags - (self.flags & FL_ONGROUND);
 166
 167                 self.velocity = self.velocity * (1 - frametime * sv_friction);
 168                 makevectors(self.v_angle);
 169                 //wishvel = v_forward * self.movement_x + v_right * self.movement_y + v_up * self.movement_z;
 170                 wishvel = v_forward * self.movement_x + v_right * self.movement_y + '0 0 1' * self.movement_z;
 171                 if (self.gravity)
 172                         self.velocity_z = self.velocity_z + self.gravity * sv_gravity * frametime;
 173                 else
 174                         self.velocity_z = self.velocity_z + sv_gravity * frametime;
 175                 if (self.ladder_entity.classname == "func_water")
 176                 {
 177                         f = vlen(wishvel);
 178                         if (f > self.ladder_entity.speed)
 179                                 wishvel = wishvel * (self.ladder_entity.speed / f);
 180
 181                         self.watertype = self.ladder_entity.skin;
 182                         f = self.ladder_entity.origin_z + self.ladder_entity.maxs_z;
 183                         if ((self.origin_z + self.view_ofs_z) < f)
 184                                 self.waterlevel = 3;
 185                         else if ((self.origin_z + (self.mins_z + self.maxs_z) * 0.5) < f)
 186                                 self.waterlevel = 2;
 187                         else if ((self.origin_z + self.mins_z + 1) < f)
 188                                 self.waterlevel = 1;
 189                         else
 190                         {
 191                                 self.waterlevel = 0;
 192                                 self.watertype = CONTENT_EMPTY;
 193                         }
 194                 }
 195                 // acceleration
 196                 wishdir = normalize(wishvel);
 197                 wishspeed = vlen(wishvel);
 198                 if (wishspeed > sv_maxspeed)
 199                         wishspeed = sv_maxspeed;
 200                 if (time >= self.teleport_time)
 201                 {
 202                         f = wishspeed - (self.velocity * wishdir);
 203                         if (f > 0)
 204                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 205                 }
 206         }
 207         else if (self.flags & FL_ONGROUND)
 208         {
 209                 // walking
 210                 makevectors(self.v_angle_y * '0 1 0');
 211                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 212
 213                 if(!(self.lastflags & FL_ONGROUND))
 214                 {
 215                         dprint(strcat("landing velocity: ", vtos(self.velocity), " (abs: ", ftos(vlen(self.velocity)), ")\n"));
 216                         self.velocity = self.velocity * (1 - cvar("sv_friction_on_land"));
 217                 }
 218
 219                 if (self.velocity_x || self.velocity_y)
 220                 if (!(self.flags & FL_JUMPRELEASED) || !self.button2)
 221                 {
 222                         v = self.velocity;
 223                         v_z = 0;
 224                         f = vlen(v);
 225                         if (f < sv_stopspeed)
 226                                 f = 1 - frametime * (sv_stopspeed / f) * sv_friction;
 227                         else
 228                                 f = 1 - frametime * sv_friction;
 229                         if (f > 0)
 230                                 self.velocity = self.velocity * f;
 231                         else
 232                                 self.velocity = '0 0 0';
 233                 }
 234                 // acceleration
 235                 wishdir = normalize(wishvel);
 236                 wishspeed = vlen(wishvel);
 237                 if (wishspeed > sv_maxspeed*maxspd_mod)
 238                         wishspeed = sv_maxspeed*maxspd_mod;
 239                 if (self.crouch)
 240                         wishspeed = wishspeed * 0.5;
 241                 if (time >= self.teleport_time)
 242                 {
 243                         f = wishspeed - (self.velocity * wishdir);
 244                         if (f > 0)
 245                                 self.velocity = self.velocity + wishdir * min(f, sv_accelerate*maxspd_mod * frametime * wishspeed);
 246                 }
 247         }
 248         else
 249         {
 250                 if(maxspd_mod < 1)
 251                 {
 252                         maxairspd = sv_maxairspeed*maxspd_mod;
 253                         airaccel = sv_accelerate*maxspd_mod;
 254                 }
 255                 else
 256                 {
 257                         maxairspd = sv_maxairspeed;
 258                         airaccel = sv_accelerate;
 259                 }
 260                 // airborn
 261                 makevectors(self.v_angle_y * '0 1 0');
 262                 wishvel = v_forward * self.movement_x + v_right * self.movement_y;
 263                 // acceleration
 264                 wishdir = normalize(wishvel);
 265                 wishspeed = vlen(wishvel);
 266                 if (wishspeed > maxairspd)
 267                         wishspeed = maxairspd;
 268                 if (self.crouch)
 269                         wishspeed = wishspeed * 0.5;
 270                 if (time >= self.teleport_time)
 271                 {
 272                         f = wishspeed;// - (self.velocity * wishdir);
 273                         if (f > 0)
 274                                 self.velocity = self.velocity + wishdir * min(f, airaccel * frametime * wishspeed);
 275                 }
 276         }
 277         self.lastflags = self.flags;
 278 };