data/qcsrc/server/gamec/cl_client.c

   1 void info_player_start (void)
   2 {
   3         self.classname = "info_player_deathmatch";
   4 }
   5
   6 void info_player_deathmatch (void)
   7 {
   8 }
   9
  10 entity Spawn_FilterOutBadSpots(entity firstspot, entity playerlist, float mindist, float teamcheck)
  11 {
  12         local entity spot, player, nextspot, previousspot, newfirstspot;
  13         local float pcount;
  14         spot = firstspot;
  15         newfirstspot = world;
  16         previousspot = world;
  17         while (spot)
  18         {
  19                 nextspot = spot.chain;
  20                 // count team mismatches as bad spots
  21                 if (spot.team == teamcheck)
  22                 {
  23                         pcount = 0;
  24                         player = playerlist;
  25                         while (player)
  26                         {
  27                                 if (player != self)
  28                                 if (vlen(player.origin - spot.origin) < mindist)
  29                                         pcount = pcount + 1;
  30                                 player = player.chain;
  31                         }
  32                         if (!pcount)
  33                         {
  34                                 if (newfirstspot)
  35                                         previousspot.chain = spot;
  36                                 else
  37                                         newfirstspot = spot;
  38                                 previousspot = spot;
  39                                 spot.chain = world;
  40                         }
  41                 }
  42                 spot = nextspot;
  43         }
  44         // if we couldn't find ANY good points, return the original list
  45         if (!newfirstspot)
  46                 newfirstspot = firstspot;
  47         return newfirstspot;
  48 }
  49
  50 entity Spawn_RandomPoint(entity firstspot)
  51 {
  52         local entity spot;
  53         local float numspots;
  54         // count number of spots
  55         numspots = 0;
  56         spot = firstspot;
  57         while (spot)
  58         {
  59                 numspots = numspots + 1;
  60                 spot = spot.chain;
  61         }
  62         // pick a random one
  63         numspots = numspots * random();
  64         spot = firstspot;
  65         while (spot.chain && numspots >= 1)
  66         {
  67                 numspots = numspots - 1;
  68                 spot = spot.chain;
  69         }
  70         return spot;
  71 }
  72
  73 entity Spawn_FurthestPoint(entity firstspot, entity playerlist)
  74 {
  75         local entity best, spot, player;
  76         local float bestrating, rating;
  77         best = world;
  78         bestrating = -1000000;
  79         spot = firstspot;
  80         while (spot)
  81         {
  82                 rating = 1000000000;
  83                 player = playerlist;
  84                 while (player)
  85                 {
  86                         if (player != self)
  87                                 rating = min(rating, vlen(player.origin - spot.origin));
  88                         player = player.chain;
  89                 }
  90                 rating = rating + random() * 16;
  91                 if (bestrating < rating)
  92                 {
  93                         best = spot;
  94                         bestrating = rating;
  95                 }
  96                 spot = spot.chain;
  97         }
  98         return best;
  99 }
 100
 101 /*
 102 =============
 103 SelectSpawnPoint
 104
 105 Finds a point to respawn
 106 =============
 107 */
 108 entity SelectSpawnPoint (float anypoint)
 109 {
 110         local float teamcheck;
 111         local entity spot, firstspot, playerlist;
 112         string spotname;
 113
 114         spot = find (world, classname, "testplayerstart");
 115         if (spot)
 116                 return spot;
 117
 118         spotname = "info_player_deathmatch";
 119         teamcheck = 0;
 120
 121         if(!anypoint && cvar("g_ctf") )
 122                 teamcheck = self.team;
 123
 124         // get the list of players
 125         playerlist = findchain(classname, "player");
 126         // get the entire list of spots
 127         firstspot = findchain(classname, "info_player_deathmatch");
 128         // filter out the bad ones
 129         // (note this returns the original list if none survived)
 130         firstspot = Spawn_FilterOutBadSpots(firstspot, playerlist, 100, teamcheck);
 131
 132         // there is 50/50 chance of choosing a random spot or the furthest spot
 133         // (this means that roughly every other spawn will be furthest, so you
 134         // usually won't get fragged at spawn twice in a row)
 135         if (random() > 0.5)
 136                 spot = Spawn_RandomPoint(firstspot);
 137         else
 138                 spot = Spawn_FurthestPoint(firstspot, playerlist);
 139
 140         if (!spot)
 141                 error ("PutClientInServer: no start points on level");
 142
 143         return spot;
 144 }
 145
 146 /*
 147 =============
 148 CheckPlayerModel
 149
 150 Checks if the argument string can be a valid playermodel.
 151 Returns a valid one in doubt.
 152 =============
 153 */
 154 string CheckPlayerModel(string plyermodel) {
 155         if( substring(plyermodel,0,14) != "models/player/") plyermodel = "models/player/marine.zym";
 156
 157         /* Possible Fixme: Check if server can open the model?
 158            This would kill custom models, however. */
 159
 160         return plyermodel;
 161 }
 162
 163 /*
 164 =============
 165 PutObserverInServer
 166
 167 putting a client as observer in the server
 168 =============
 169 */
 170 void PutObserverInServer (void)
 171 {
 172         entity  spot;
 173         spot = SelectSpawnPoint (FALSE);
 174         RemoveGrapplingHook(self); // Wazat's Grappling Hook
 175
 176         if(self.frags == 0 && cvar("g_lms") && self.killcount != -666)
 177                 bprint (strcat("^4", self.netname, "^4 has no more lives left\n"));
 178         else if(self.killcount != -666)
 179                 bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 180
 181         self.classname = "observer";
 182         self.health = -666;
 183         self.takedamage = DAMAGE_NO;
 184         self.solid = SOLID_NOT;
 185         self.movetype = MOVETYPE_NOCLIP;
 186         self.flags = FL_CLIENT | FL_NOTARGET;
 187         self.armorvalue = 666;
 188         self.effects = 0;
 189         self.armorvalue = cvar("g_balance_armor_start");
 190         self.pauserotarmor_finished = 0;
 191         self.pauserothealth_finished = 0;
 192         self.pauseregen_finished = 0;
 193         self.damageforcescale = 0;
 194         self.death_time = 0;
 195         self.dead_time = 0;
 196         self.dead_frame = 0;
 197         self.die_frame = 0;
 198         self.alpha = 0;
 199         self.scale = 0;
 200         self.fade_time = 0;
 201         self.pain_frame = 0;
 202         self.pain_finished = 0;
 203         self.strength_finished = 0;
 204         self.invincible_finished = 0;
 205         self.pushltime = 0;
 206         self.think = SUB_Null;
 207         self.nextthink = 0;
 208         self.hook_time = 0;
 209         self.runes = 0;
 210         self.deadflag = DEAD_NO;
 211         self.angles = spot.angles;
 212         self.angles_z = 0;
 213         self.fixangle = TRUE;
 214         self.crouch = FALSE;
 215         self.view_ofs = PL_VIEW_OFS;
 216         setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 14));
 217         self.oldorigin = self.origin;
 218         self.items = 0;
 219         self.model = "";
 220         self.modelindex = 0;
 221         self.weapon = 0;
 222         self.weaponmodel = "";
 223         self.weaponframe = 0;
 224         self.weaponentity = world;
 225         self.killcount = -666;
 226         if(!cvar("g_lms"))
 227                 self.frags = -666;
 228         //stuffcmd(self, "set viewsize 120 \n");
 229 //      bprint (strcat("^4", self.netname, "^4 is spectating now\n"));
 230 }
 231
 232
 233 /*
 234 =============
 235 PutClientInServer
 236
 237 Called when a client spawns in the server
 238 =============
 239 */
 240 void PutClientInServer (void)
 241 {
 242         if(clienttype(self) ==  CLIENTTYPE_BOT)
 243         {
 244                 self.classname = "player";
 245         }
 246
 247         // player is dead and becomes observer
 248         if(cvar("g_lms") && self.frags < 1)
 249                 self.classname = "observer";
 250
 251         if(self.classname == "player") {
 252                 entity  spot;
 253
 254                 spot = SelectSpawnPoint (FALSE);
 255
 256                 RemoveGrapplingHook(self); // Wazat's Grappling Hook
 257
 258                 self.classname = "player";
 259                 self.iscreature = TRUE;
 260                 self.movetype = MOVETYPE_WALK;
 261                 self.solid = SOLID_SLIDEBOX;
 262                 self.flags = FL_CLIENT;
 263                 self.takedamage = DAMAGE_AIM;
 264                 self.effects = 0;
 265                 self.health = cvar("g_balance_health_start");
 266                 self.armorvalue = cvar("g_balance_armor_start");
 267                 self.spawnshieldtime = time + cvar("g_spawnshieldtime");
 268                 self.pauserotarmor_finished = time + 10;
 269                 self.pauserothealth_finished = time + 10;
 270                 self.pauseregen_finished = 0;
 271                 self.damageforcescale = 2;
 272                 self.death_time = 0;
 273                 self.dead_time = 0;
 274                 self.dead_frame = 0;
 275                 self.die_frame = 0;
 276                 self.alpha = 0;
 277                 self.scale = 0;
 278                 self.fade_time = 0;
 279                 self.pain_frame = 0;
 280                 self.pain_finished = 0;
 281                 self.strength_finished = 0;
 282                 self.invincible_finished = 0;
 283                 self.pushltime = 0;
 284                 //self.speed_finished = 0;
 285                 //self.slowmo_finished = 0;
 286                 // players have no think function
 287                 self.think = SUB_Null;
 288                 self.nextthink = 0;
 289
 290                 self.hook_time = 0;
 291
 292                 self.runes = 0;
 293
 294                 self.deadflag = DEAD_NO;
 295
 296                 self.angles = spot.angles;
 297
 298                 self.angles_z = 0; // never spawn tilted even if the spot says to
 299                 self.fixangle = TRUE; // turn this way immediately
 300                 self.velocity = '0 0 0';
 301                 self.avelocity = '0 0 0';
 302                 self.punchangle = '0 0 0';
 303                 self.punchvector = '0 0 0';
 304                 self.oldvelocity = self.velocity;
 305
 306                 self.viewzoom = 0.6;
 307
 308                 if(cvar("sv_defaultcharacter") == 1) {
 309                         local string defaultmodel;
 310                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
 311
 312                         precache_model (defaultmodel);
 313                         setmodel (self, defaultmodel);
 314                         self.skin = stof(cvar_string("sv_defaultplayerskin"));
 315                 } else {
 316                         self.playermodel = CheckPlayerModel(self.playermodel);
 317
 318                         precache_model (self.playermodel);
 319                         setmodel (self, self.playermodel);
 320                         self.skin = stof(self.playerskin);
 321
 322                 }
 323
 324                 self.crouch = FALSE;
 325                 self.view_ofs = PL_VIEW_OFS;
 326                 setsize (self, PL_MIN, PL_MAX);
 327                 setorigin (self, spot.origin + '0 0 1' * (1 - self.mins_z - 24));
 328                 // don't reset back to last position, even if new position is stuck in solid
 329                 self.oldorigin = self.origin;
 330
 331                 if(cvar("g_lms"))
 332                 {
 333                         self.ammo_shells = cvar("g_lms_start_ammo_shells");
 334                         self.ammo_nails = cvar("g_lms_start_ammo_nails");
 335                         self.ammo_rockets = cvar("g_lms_start_ammo_rockets");
 336                         self.ammo_cells = cvar("g_lms_start_ammo_cells");
 337                         self.health = cvar("g_lms_start_health");
 338                         self.armorvalue = cvar("g_lms_start_armor");
 339                 }
 340                 else if (cvar("g_use_ammunition")) {
 341                         self.ammo_shells = cvar("g_start_ammo_shells");
 342                         self.ammo_nails = cvar("g_start_ammo_nails");
 343                         self.ammo_rockets = cvar("g_start_ammo_rockets");
 344                         self.ammo_cells = cvar("g_start_ammo_cells");
 345                 } else {
 346                         self.ammo_shells = 999;
 347                         self.ammo_nails = 999;
 348                         self.ammo_rockets = 999;
 349                         self.ammo_cells = 999;
 350                 }
 351
 352                 self.items = 0;
 353                 if (cvar("g_start_weapon_laser") || cvar("g_lms"))
 354                 {
 355                         self.items = self.items | IT_LASER;
 356                         self.switchweapon = WEP_LASER;
 357                 }
 358                 if (cvar("g_start_weapon_shotgun") || cvar("g_lms"))
 359                 {
 360                         self.items = self.items | IT_SHOTGUN;
 361                         self.switchweapon = WEP_SHOTGUN;
 362                 }
 363                 if (cvar("g_start_weapon_uzi") || cvar("g_lms"))
 364                 {
 365                         self.items = self.items | IT_UZI;
 366                         self.switchweapon = WEP_UZI;
 367                 }
 368                 if (cvar("g_start_weapon_grenadelauncher") || cvar("g_lms"))
 369                 {
 370                         self.items = self.items | IT_GRENADE_LAUNCHER;
 371                         self.switchweapon = WEP_GRENADE_LAUNCHER;
 372                 }
 373                 if (cvar("g_start_weapon_electro") || cvar("g_lms"))
 374                 {
 375                         self.items = self.items | IT_ELECTRO;
 376                         self.switchweapon = WEP_ELECTRO;
 377                 }
 378                 if (cvar("g_start_weapon_crylink") || cvar("g_lms"))
 379                 {
 380                         self.items = self.items | IT_CRYLINK;
 381                         self.switchweapon = WEP_CRYLINK;
 382                 }
 383                 if (cvar("g_start_weapon_nex") || cvar("g_lms"))
 384                 {
 385                         self.items = self.items | IT_NEX;
 386                         self.switchweapon = WEP_NEX;
 387                 }
 388                 if (cvar("g_start_weapon_hagar") || cvar("g_lms"))
 389                 {
 390                         self.items = self.items | IT_HAGAR;
 391                         self.switchweapon = WEP_HAGAR;
 392                 }
 393                 if (cvar("g_start_weapon_rocketlauncher") || cvar("g_lms"))
 394                 {
 395                         self.items = self.items | IT_ROCKET_LAUNCHER;
 396                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 397                 }
 398
 399                 if(cvar("g_instagib"))
 400                 {
 401                         self.items = IT_NEX;
 402                         self.switchweapon = WEP_NEX;
 403                         self.ammo_cells = 999;
 404                 }
 405
 406                 if(cvar("g_rocketarena"))
 407                 {
 408                         self.items = IT_ROCKET_LAUNCHER;
 409                         self.switchweapon = WEP_ROCKET_LAUNCHER;
 410                         self.ammo_rockets = 999;
 411                 }
 412
 413                 if(cvar("g_minstagib"))
 414                 {
 415                         self.health = 100;
 416                         self.armorvalue = 0;
 417                         self.items = IT_NEX;
 418                         self.switchweapon = WEP_NEX;
 419                         self.ammo_cells = cvar("g_minstagib_ammo_start");
 420                         self.extralives = 0;
 421                         self.jump_interval = time;
 422                 }
 423
 424                 self.event_damage = PlayerDamage;
 425
 426                 self.statdraintime = time + 5;
 427                 self.button0 = self.button1 = self.button2 = self.button3 = 0;
 428
 429                 if(self.killcount == -666) {
 430                         self.killcount = 0;
 431                         self.frags = 0;
 432                 }
 433
 434                 self.cnt = WEP_LASER;
 435
 436                 /*
 437                 W_UpdateWeapon();
 438                 W_UpdateAmmo();
 439                 */
 440                 CL_SpawnWeaponentity();
 441                 self.alpha = 1;
 442                 self.exteriorweaponentity.alpha = 1;
 443
 444                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
 445                 self.lms_traveled_distance = 0;
 446
 447                 //stuffcmd(self, "chase_active 0");
 448                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
 449         } else if(self.classname == "observer") {
 450                 PutObserverInServer ();
 451         }
 452 }
 453
 454 /*
 455 =============
 456 SetNewParms
 457 =============
 458 */
 459 void SetNewParms (void)
 460 {
 461
 462 }
 463
 464 /*
 465 =============
 466 SetChangeParms
 467 =============
 468 */
 469 void SetChangeParms (void)
 470 {
 471
 472 }
 473
 474 /*
 475 =============
 476 ClientKill
 477
 478 Called when a client types 'kill' in the console
 479 =============
 480 */
 481 void ClientKill (void)
 482 {
 483         Damage(self, self, self, 100000, DEATH_KILL, self.origin, '0 0 0');
 484 }
 485
 486 /*
 487 =============
 488 ClientConnect
 489
 490 Called when a client connects to the server
 491 =============
 492 */
 493 string ColoredTeamName(float t);
 494 //void dom_player_join_team(entity pl);
 495 void ClientConnect (void)
 496 {
 497         self.classname = "player_joining";
 498
 499         if(player_count<0) player_count = 0;
 500
 501         //if(cvar("g_domination"))
 502         //      dom_player_join_team(self);
 503
 504         //JoinBestTeam(self, FALSE);
 505         if(cvar("teamplay") && self.version == cvar("g_nexuizversion_major")) stuffcmd(self,"menu_showteamselect\n");
 506
 507
 508         if(cvar("sv_spectate") == 1 && !cvar("g_lms")) {
 509                 self.classname = "observer";
 510         } else {
 511                 self.classname = "player";
 512         }
 513
 514         //stuffcmd(self, "set tmpviewsize $viewsize \n");
 515
 516         bprint ("^4",self.netname);
 517         bprint ("^4 connected");
 518
 519         if(cvar("g_domination") || cvar("g_ctf"))
 520         {
 521                 bprint(" and joined the ");
 522                 bprint(ColoredTeamName(self.team));
 523         }
 524
 525         bprint("\n");
 526
 527         self.welcomemessage_time = time + cvar("welcome_message_time");
 528         self.welcomemessage_time2 = 0;
 529
 530         stuffcmd(self, strcat("exec maps/", mapname, ".cfg\n"));
 531         // send prediction settings to the client
 532         stuffcmd(self, strcat("cl_movement_maxspeed ", ftos(cvar("sv_maxspeed")), "\n"));
 533         stuffcmd(self, strcat("cl_movement_maxairspeed ", ftos(cvar("sv_maxairspeed")), "\n"));
 534         stuffcmd(self, strcat("cl_movement_accelerate ", ftos(cvar("sv_accelerate")), "\n"));
 535         stuffcmd(self, strcat("cl_movement_friction ", ftos(cvar("sv_friction")), "\n"));
 536         stuffcmd(self, strcat("cl_movement_stopspeed ", ftos(cvar("sv_stopspeed")), "\n"));
 537         stuffcmd(self, strcat("cl_movement_jumpvelocity ", ftos(cvar("g_balance_jumpheight")), "\n"));
 538         stuffcmd(self, strcat("cl_movement_stepheight ", ftos(cvar("sv_stepheight")), "\n"));
 539         stuffcmd(self, strcat("cl_movement_edgefriction 0\n"));
 540         // Wazat's grappling hook
 541         SetGrappleHookBindings();
 542
 543         // get autoswitch state from player
 544         stuffcmd(self, "alias autoswitch \"set cl_autoswitch $1; cmd autoswitch $1\"\n");
 545         stuffcmd(self, "cmd autoswitch $cl_autoswitch\n");
 546
 547         // get version info from player
 548         stuffcmd(self, "cmd clientversion $g_nexuizversion_major\n");
 549
 550         // set cvar for team scoreboard
 551         stuffcmd(self, strcat("set teamplay ", ftos(teams_matter), "\n"));
 552
 553         if(cvar("g_lms"))
 554         {
 555                 self.frags = cvar("fraglimit");
 556                 // no fraglimit was set, so player gets 999 lives
 557                 if(self.frags < 1)
 558                         self.frags = 999;
 559
 560                 // disallow player to join after the worst player has lost g_lms_last_join lives
 561                 // if "g_lms_join_anytime" new players spawn with same amount of lives as the worst active player
 562                 if(((cvar("fraglimit") - cvar("g_lms_last_join")) > lms_lowest_lives && !cvar("g_lms_join_anytime")) || lms_lowest_lives < 1)
 563                 {
 564                         self.frags = -1;
 565                         lms_dead_count += 1;
 566                 }
 567                 else if(cvar("fraglimit") > lms_lowest_lives)
 568                 {
 569                         self.frags = lms_lowest_lives;
 570                 }
 571         }
 572
 573         player_count += 1;
 574         self.jointime = time;
 575 }
 576
 577 /*
 578 =============
 579 ClientDisconnect
 580
 581 Called when a client disconnects from the server
 582 =============
 583 */
 584 .entity chatbubbleentity;
 585 .entity teambubbleentity;
 586 void ClientDisconnect (void)
 587 {
 588         bprint ("^4",self.netname);
 589         bprint ("^4 disconnected\n");
 590
 591         if (self.chatbubbleentity)
 592         {
 593                 remove (self.chatbubbleentity);
 594                 self.chatbubbleentity = world;
 595         }
 596
 597         if (self.teambubbleentity)
 598         {
 599                 remove (self.teambubbleentity);
 600                 self.teambubbleentity = world;
 601         }
 602
 603         DropAllRunes(self);
 604         // decrease player count for lms
 605         player_count -= 1;
 606         // player was dead, decrease dead count
 607         if(cvar("g_lms") && self.frags < 1)
 608                 lms_dead_count -= 1;
 609         //stuffcmd(self, "set viewsize $tmpviewsize \n");
 610 }
 611
 612 .float buttonchat;
 613 void() ChatBubbleThink =
 614 {
 615         self.nextthink = time;
 616         if (!self.owner.modelindex || self.owner.chatbubbleentity != self)
 617         {
 618                 remove(self);
 619                 return;
 620         }
 621         setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');
 622         if (self.owner.buttonchat && !self.owner.deadflag)
 623                 self.model = self.mdl;
 624         else
 625                 self.model = "";
 626 };
 627
 628 void() UpdateChatBubble =
 629 {
 630         if (!self.modelindex)
 631                 return;
 632         // spawn a chatbubble entity if needed
 633         if (!self.chatbubbleentity)
 634         {
 635                 self.chatbubbleentity = spawn();
 636                 self.chatbubbleentity.owner = self;
 637                 self.chatbubbleentity.exteriormodeltoclient = self;
 638                 self.chatbubbleentity.think = ChatBubbleThink;
 639                 self.chatbubbleentity.nextthink = time;
 640                 setmodel(self.chatbubbleentity, "models/misc/chatbubble.spr");
 641                 setorigin(self.chatbubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 642                 self.chatbubbleentity.mdl = self.chatbubbleentity.model;
 643                 self.chatbubbleentity.model = "";
 644         }
 645 }
 646
 647
 648 void() TeamBubbleThink =
 649 {
 650         self.nextthink = time;
 651         if (!self.owner.modelindex || self.owner.teambubbleentity != self)
 652         {
 653                 remove(self);
 654                 return;
 655         }
 656 //      setorigin(self, self.owner.origin + '0 0 15' + self.owner.maxs_z * '0 0 1');  // bandwidth hog. setattachment does this now
 657         if (self.owner.buttonchat || self.owner.deadflag)
 658                 self.model = "";
 659         else
 660                 self.model = self.mdl;
 661
 662 };
 663
 664 .float() customizeentityforclient;
 665 float() ChatBubble_customizeentityforclient = {return (self.owner.team == other.team && other.killcount > -666);};
 666
 667 void() UpdateTeamBubble =
 668 {
 669         if (!self.modelindex || !cvar("teamplay"))
 670                 return;
 671         // spawn a teambubble entity if needed
 672         if (!self.teambubbleentity && cvar("teamplay"))
 673         {
 674                 self.teambubbleentity = spawn();
 675                 self.teambubbleentity.owner = self;
 676                 self.teambubbleentity.exteriormodeltoclient = self;
 677                 self.teambubbleentity.think = TeamBubbleThink;
 678                 self.teambubbleentity.nextthink = time;
 679                 setmodel(self.teambubbleentity, "models/misc/teambubble.spr");
 680 //              setorigin(self.teambubbleentity, self.origin + '0 0 15' + self.maxs_z * '0 0 1');
 681                 setorigin(self.teambubbleentity, self.teambubbleentity.origin + '0 0 15' + self.maxs_z * '0 0 1');
 682                 setattachment(self.teambubbleentity, self, "");  // sticks to moving player better, also conserves bandwidth
 683                 self.teambubbleentity.mdl = self.teambubbleentity.model;
 684                 self.teambubbleentity.model = self.teambubbleentity.mdl;
 685                 self.teambubbleentity.customizeentityforclient = ChatBubble_customizeentityforclient;
 686         }
 687 }
 688
 689 // LordHavoc: this hack will be removed when proper _pants/_shirt layers are
 690 // added to the model skins
 691 /*void() UpdateColorModHack =
 692 {
 693         local float c;
 694         c = self.clientcolors & 15;
 695         // LordHavoc: only bothering to support white, green, red, yellow, blue
 696              if (teamplay == 0) self.colormod = '0 0 0';
 697         else if (c ==  0) self.colormod = '1.00 1.00 1.00';
 698         else if (c ==  3) self.colormod = '0.10 1.73 0.10';
 699         else if (c ==  4) self.colormod = '1.73 0.10 0.10';
 700         else if (c == 12) self.colormod = '1.22 1.22 0.10';
 701         else if (c == 13) self.colormod = '0.10 0.10 1.73';
 702         else self.colormod = '1 1 1';
 703 };*/
 704
 705 void UpdatePlayerColors () {
 706         if(self.weaponentity) {
 707                 self.weaponentity.colormap = self.colormap;
 708                 self.exteriorweaponentity.colormap = self.colormap;
 709         }
 710 }
 711 /*
 712 =============
 713 PlayerJump
 714
 715 When you press the jump key
 716 =============
 717 */
 718 void PlayerJump (void)
 719 {
 720         float mjumpheight;
 721
 722         mjumpheight = cvar("g_balance_jumpheight");
 723         if (self.waterlevel >= 2)
 724         {
 725                 if (self.watertype == CONTENT_WATER)
 726                         self.velocity_z = 200;
 727                 else if (self.watertype == CONTENT_SLIME)
 728                         self.velocity_z = 80;
 729                 else
 730                         self.velocity_z = 50;
 731
 732                 return;
 733         }
 734
 735
 736         if (!(self.flags & FL_ONGROUND))
 737                 return;
 738
 739         if (!(self.flags & FL_JUMPRELEASED))
 740                 return;
 741
 742         if(cvar("g_runematch"))
 743         {
 744                 if(self.runes & RUNE_SPEED)
 745                 {
 746                         if(self.runes & CURSE_SLOW)
 747                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_combo_jumpheight");
 748                         else
 749                                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 750                 }
 751                 else if(self.runes & CURSE_SLOW)
 752                 {
 753                         mjumpheight = mjumpheight * cvar("g_balance_curse_slow_jumpheight");
 754                 }
 755         }
 756
 757         if(cvar("g_minstagib") && (self.items & IT_INVINCIBLE))
 758         {
 759                 mjumpheight = mjumpheight * cvar("g_balance_rune_speed_jumpheight");
 760         }
 761
 762         self.velocity_z = self.velocity_z + mjumpheight;
 763         self.oldvelocity_z = self.velocity_z;
 764
 765         self.flags = self.flags - FL_ONGROUND;
 766         self.flags = self.flags - FL_JUMPRELEASED;
 767 }
 768
 769 void() CheckWaterJump =
 770 {
 771         local vector start, end;
 772
 773 // check for a jump-out-of-water
 774         makevectors (self.angles);
 775         start = self.origin;
 776         start_z = start_z + 8;
 777         v_forward_z = 0;
 778         normalize(v_forward);
 779         end = start + v_forward*24;
 780         traceline (start, end, TRUE, self);
 781         if (trace_fraction < 1)
 782         {       // solid at waist
 783                 start_z = start_z + self.maxs_z - 8;
 784                 end = start + v_forward*24;
 785                 self.movedir = trace_plane_normal * -50;
 786                 traceline (start, end, TRUE, self);
 787                 if (trace_fraction == 1)
 788                 {       // open at eye level
 789                         self.flags = self.flags | FL_WATERJUMP;
 790                         self.velocity_z = 225;
 791                         self.flags = self.flags - (self.flags & FL_JUMPRELEASED);
 792                         self.teleport_time = time + 2;  // safety net
 793                         return;
 794                 }
 795         }
 796 };
 797
 798
 799 void respawn(void)
 800 {
 801         CopyBody(1);
 802         PutClientInServer();
 803 }
 804
 805 void player_powerups (void)
 806 {
 807         if (cvar("g_minstagib"))
 808         {
 809                 self.effects = EF_FULLBRIGHT;
 810                 if (self.items & IT_STRENGTH)
 811                 {
 812                         if (time > self.strength_finished)
 813                         {
 814                                 self.alpha = 1;
 815                                 self.exteriorweaponentity.alpha = 1;
 816                                 self.items = self.items - (self.items & IT_STRENGTH);
 817                                 sprint(self, "^3Invisibility has worn off\n");
 818                         }
 819                 }
 820                 else
 821                 {
 822                         if (time < self.strength_finished)
 823                         {
 824                                 self.alpha = cvar("g_minstagib_invis_alpha");
 825                                 self.exteriorweaponentity.alpha = cvar("g_minstagib_invis_alpha");
 826                                 self.items = self.items | IT_STRENGTH;
 827                                 sprint(self, "^3You are invisible\n");
 828                         }
 829                 }
 830
 831                 if (self.items & IT_INVINCIBLE)
 832                 {
 833                         if (time > self.invincible_finished)
 834                         {
 835                                 self.items = self.items - (self.items & IT_INVINCIBLE);
 836                                 sprint(self, "^3Speed has worn off\n");
 837                         }
 838                 }
 839                 else
 840                 {
 841                         if (time < self.invincible_finished)
 842                         {
 843                                 self.items = self.items | IT_INVINCIBLE;
 844                                 sprint(self, "^3You are on speed\n");
 845                         }
 846                 }
 847                 return;
 848         }
 849
 850         self.effects = self.effects - (self.effects & (EF_RED | EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT));
 851         if (self.items & IT_STRENGTH)
 852         {
 853                 self.effects = self.effects | (EF_BLUE | EF_ADDITIVE | EF_FULLBRIGHT);
 854                 if (time > self.strength_finished)
 855                 {
 856                         self.items = self.items - (self.items & IT_STRENGTH);
 857                         sprint(self, "^3Strength has worn off\n");
 858                 }
 859         }
 860         else
 861         {
 862                 if (time < self.strength_finished)
 863                 {
 864                         self.items = self.items | IT_STRENGTH;
 865                         sprint(self, "^3Strength infuses your weapons with devestating power\n");
 866                 }
 867         }
 868         if (self.items & IT_INVINCIBLE)
 869         {
 870                 self.effects = self.effects | (EF_RED | EF_ADDITIVE | EF_FULLBRIGHT);
 871                 if (time > self.invincible_finished)
 872                 {
 873                         self.items = self.items - (self.items & IT_INVINCIBLE);
 874                         sprint(self, "^3Shield has worn off\n");
 875                 }
 876         }
 877         else
 878         {
 879                 if (time < self.invincible_finished)
 880                 {
 881                         self.items = self.items | IT_INVINCIBLE;
 882                         sprint(self, "^3Shield surrounds you\n");
 883                 }
 884         }
 885
 886         if (cvar("g_fullbrightplayers"))
 887                 self.effects = self.effects | EF_FULLBRIGHT;
 888
 889         // midair gamemode: damage only while in the air
 890         // if in midair mode, being on ground grants temporary invulnerability
 891         // (this is so that multishot weapon don't clear the ground flag on the
 892         // first damage in the frame, leaving the player vulnerable to the
 893         // remaining hits in the same frame)
 894         if (self.flags & FL_ONGROUND)
 895         if (cvar("g_midair"))
 896                 self.spawnshieldtime = max(self.spawnshieldtime, time + cvar("g_midair_shieldtime"));
 897
 898         if (time < self.spawnshieldtime)
 899                 self.effects = self.effects | (EF_ADDITIVE | EF_FULLBRIGHT);
 900 }
 901
 902 void player_regen (void)
 903 {
 904         float maxh, maxa, max_mod, regen_mod, rot_mod;
 905         maxh = cvar("g_balance_health_stable");
 906         maxa = cvar("g_balance_armor_stable");
 907
 908         if (cvar("g_minstagib") || (cvar("g_lms") && !cvar("g_lms_regenerate")))
 909                 return;
 910
 911         if(cvar("g_runematch"))
 912         {
 913                 max_mod = regen_mod = rot_mod = 1;
 914                 if (self.runes & RUNE_REGEN)
 915                 {
 916                         if (self.runes & CURSE_VENOM) // do we have both rune/curse?
 917                         {
 918                                 regen_mod = cvar("g_balance_rune_regen_combo_regenrate");
 919                                 max_mod = cvar("g_balance_rune_regen_combo_hpmod");
 920                         }
 921                         else
 922                         {
 923                                 regen_mod = cvar("g_balance_rune_regen_regenrate");
 924                                 max_mod = cvar("g_balance_rune_regen_hpmod");
 925                         }
 926                 }
 927                 else if (self.runes & CURSE_VENOM)
 928                 {
 929                         max_mod = cvar("g_balance_curse_venom_hpmod");
 930                         if (self.runes & RUNE_REGEN) // do we have both rune/curse?
 931                                 rot_mod = cvar("g_balance_rune_regen_combo_rotrate");
 932                         else
 933                                 rot_mod = cvar("g_balance_curse_venom_rotrate");
 934                         //if (!self.runes & RUNE_REGEN)
 935                         //      rot_mod = cvar("g_balance_curse_venom_rotrate");
 936                 }
 937                 maxh = maxh * max_mod;
 938                 //maxa = maxa * max_mod;
 939
 940                 if (time > self.pauserotarmor_finished)
 941                 {
 942                         if (self.armorvalue > maxa)
 943                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 944                 }
 945                 if (time > self.pauserothealth_finished)
 946                 {
 947                         if (self.health > maxh)
 948                                 self.health = bound(0, self.health + (maxh - self.health) * rot_mod*cvar("g_balance_health_rot") * frametime, 1000);
 949                 }
 950                 if (time > self.pauseregen_finished)
 951                 {
 952                         if (self.health < maxh)
 953                                 self.health = bound(0, self.health + (maxh- self.health) * regen_mod*cvar("g_balance_health_regen") * frametime, 1000);
 954                         if (self.armorvalue < maxa)
 955                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
 956                 }
 957         }
 958         else
 959         {
 960                 if (time > self.pauserothealth_finished)
 961                 if (self.health > maxh)
 962                         self.health = bound(0, self.health + (maxh - self.health) * cvar("g_balance_health_rot") * frametime, 1000);
 963                 if (time > self.pauserotarmor_finished)
 964                 if (self.armorvalue > maxa)
 965                         self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_rot") * frametime, 1000);
 966                 if (time > self.pauseregen_finished)
 967                 {
 968                         if (self.health < maxh)
 969                                 self.health = bound(0, self.health + (maxh- self.health) * cvar("g_balance_health_regen") * frametime, 1000);
 970                         if (self.armorvalue < maxa)
 971                                 self.armorvalue = bound(0, self.armorvalue + (maxa - self.armorvalue) * cvar("g_balance_armor_regen") * frametime, 1000);
 972                 }
 973         }
 974 }
 975
 976 /*
 977 ======================
 978 spectate mode routines
 979 ======================
 980 */
 981 void SpectateCopy(entity spectatee) {
 982         self.armortype = spectatee.armortype;
 983         self.armorvalue = spectatee.armorvalue;
 984         self.currentammo = spectatee.currentammo;
 985         self.effects = spectatee.effects;
 986         self.health = spectatee.health;
 987         self.impulse = 0;
 988         self.items = spectatee.items;
 989         self.punchangle = spectatee.punchangle;
 990         self.view_ofs = spectatee.view_ofs;
 991         self.v_angle = spectatee.v_angle;
 992         self.viewzoom = spectatee.viewzoom;
 993         setorigin(self, spectatee.origin);
 994         setsize(self, spectatee.mins, spectatee.maxs);
 995 }
 996
 997 void SpectateUpdate() {
 998         if (self != self.enemy) {
 999                 SpectateCopy(self.enemy);
1000                 msg_entity = self;
1001                 WriteByte(MSG_ONE, SVC_SETANGLE);
1002                 WriteAngle(MSG_ONE, self.enemy.v_angle_x);
1003                 WriteAngle(MSG_ONE, self.enemy.v_angle_y);
1004                 WriteAngle(MSG_ONE, self.enemy.v_angle_z);
1005         }
1006 }
1007
1008 float SpectateNext() {
1009         other = find(self.enemy, classname, "player");
1010         if (!other) {
1011                 other = find(other, classname, "player");
1012         }
1013         if (other) {
1014                 self.enemy = other;
1015         }
1016         if(self.enemy.classname == "player") {
1017                 msg_entity = self;
1018                 WriteByte(MSG_ONE, SVC_SETVIEW);
1019                 WriteEntity(MSG_ONE, self.enemy);
1020                 //stuffcmd(self, "set viewsize $tmpviewsize \n");
1021                 SpectateUpdate();
1022                 return 1;
1023         } else {
1024                 return 0;
1025         }
1026 }
1027
1028 /*
1029 =============
1030 PlayerPreThink
1031
1032 Called every frame for each client before the physics are run
1033 =============
1034 */
1035 void PlayerPreThink (void)
1036 {
1037         if(self.classname == "player") {
1038                 local vector m1, m2;
1039
1040 //              MauveBot_AI();
1041
1042 //              if(self.netname == "Wazat")
1043 //                      bprint(strcat(self.classname, "\n"));
1044
1045                 CheckRules_Player();
1046
1047                 if (intermission_running)
1048                 {
1049                         IntermissionThink ();   // otherwise a button could be missed between
1050                         return;                                 // the think tics
1051                 }
1052
1053                 if (self.deadflag != DEAD_NO)
1054                 {
1055                         player_anim();
1056                         weapon_freeze();
1057                         if (self.deadflag == DEAD_DYING)
1058                         {
1059                                 if (time > self.dead_time)
1060                                         self.deadflag = DEAD_DEAD;
1061                         }
1062                         else if (self.deadflag == DEAD_DEAD)
1063                         {
1064                                 if (!self.button0 && !self.button2 && !self.button3)
1065                                         self.deadflag = DEAD_RESPAWNABLE;
1066                         }
1067                         else if (self.deadflag == DEAD_RESPAWNABLE)
1068                         {
1069                                 if (self.button0  ||
1070                                     self.button2  ||
1071                                     self.button3  ||
1072                                     self.button4  ||
1073                                     cvar("g_lms") ||
1074                                     cvar("g_forced_respawn"))
1075                                         respawn();
1076                         }
1077                         return;
1078                 }
1079
1080                 if(cvar("g_lms") && !self.deadflag && cvar("g_lms_campcheck_interval"))
1081                 {
1082                         vector dist;
1083
1084                         // calculate player movement (in 2 dimensions only, so jumping on one spot doesn't count as movement)
1085                         dist = self.oldorigin - self.origin;
1086                         dist_z = 0;
1087                         self.lms_traveled_distance += fabs(vlen(dist));
1088
1089                         if(time > self.lms_nextcheck)
1090                         {
1091                                 //sprint(self, "distance: ", ftos(self.lms_traveled_distance), "\n");
1092                                 if(self.lms_traveled_distance < cvar("g_lms_campcheck_distance"))
1093                                 {
1094                                         centerprint(self, cvar_string("g_lms_campcheck_message"));
1095                                         Damage(self, self, self, cvar("g_lms_campcheck_damage"), DEATH_CAMP, self.origin, '0 0 0');
1096                                 }
1097                                 self.lms_nextcheck = time + cvar("g_lms_campcheck_interval");
1098                                 self.lms_traveled_distance = 0;
1099                         }
1100                 }
1101
1102                 if (self.button5)
1103                 {
1104                         if (!self.crouch)
1105                         {
1106                                 self.crouch = TRUE;
1107                                 self.view_ofs = PL_CROUCH_VIEW_OFS;
1108                                 setsize (self, PL_CROUCH_MIN, PL_CROUCH_MAX);
1109                         }
1110                 }
1111                 else
1112                 {
1113                         if (self.crouch)
1114                         {
1115                                 tracebox(self.origin, PL_MIN, PL_MAX, self.origin, FALSE, self);
1116                                 if (!trace_startsolid)
1117                                 {
1118                                         self.crouch = FALSE;
1119                                         self.view_ofs = PL_VIEW_OFS;
1120                                         setsize (self, PL_MIN, PL_MAX);
1121                                 }
1122                         }
1123                 }
1124
1125                 if(cvar("sv_defaultcharacter") == 1) {
1126                         local string defaultmodel;
1127                         defaultmodel = CheckPlayerModel(cvar_string("sv_defaultplayermodel"));
1128
1129                         if (defaultmodel != self.model)
1130                         {
1131                                 m1 = self.mins;
1132                                 m2 = self.maxs;
1133                                 precache_model (defaultmodel);
1134                                 setmodel (self, defaultmodel);
1135                                 setsize (self, m1, m2);
1136                         }
1137
1138                         if (self.skin != stof(cvar_string("sv_defaultplayerskin")))
1139                                 self.skin = stof(cvar_string("sv_defaultplayerskin"));
1140                 } else {
1141                         if (self.playermodel != self.model)
1142                         {
1143                                 self.playermodel = CheckPlayerModel(self.playermodel);
1144                                 m1 = self.mins;
1145                                 m2 = self.maxs;
1146                                 precache_model (self.playermodel);
1147                                 setmodel (self, self.playermodel);
1148                                 setsize (self, m1, m2);
1149                         }
1150
1151                         if (self.skin != stof(self.playerskin))
1152                                 self.skin = stof(self.playerskin);
1153                 }
1154                 // Savage: Check for nameless players
1155                 if (strlen(self.netname) < 1) {
1156                         self.netname = "Player";
1157                         stuffcmd(self, "name Player\n");
1158                 }
1159
1160                 GrapplingHookFrame();
1161
1162                 W_WeaponFrame();
1163
1164                 if (self.button4 || (self.weapon == WEP_NEX && self.button3))
1165                 {
1166                         if (cvar("g_minstagib") && self.button3)
1167                         {
1168                                 if (self.jump_interval <= (time + 0.1))
1169                                 {
1170                                         self.jump_interval = time + 1;
1171                                         weapon_doattack(laser_check, laser_check, W_Laser_Attack);
1172                                 }
1173                         }
1174                         else if (self.viewzoom > 0.4)
1175                                 self.viewzoom = max (0.4, self.viewzoom - frametime * 2);
1176                 }
1177                 else if (self.viewzoom < 1.0)
1178                         self.viewzoom = min (1.0, self.viewzoom + frametime);
1179
1180
1181                 if (self.button2)
1182                         PlayerJump ();
1183                 else
1184                         self.flags = self.flags | FL_JUMPRELEASED;
1185
1186                 player_powerups();
1187                 player_regen();
1188                 player_anim();
1189
1190                 //self.angles_y=self.v_angle_y + 90;   // temp
1191
1192                 if (self.waterlevel == 2)
1193                         CheckWaterJump ();
1194
1195                 //if (TetrisPreFrame()) return;
1196         } else if(gameover) {
1197                 if (intermission_running)
1198                         IntermissionThink ();   // otherwise a button could be missed between
1199                 return;
1200         } else if(self.classname == "observer") {
1201
1202                 if (self.flags & FL_JUMPRELEASED) {
1203                         if (self.button2 && self.version == cvar("g_nexuizversion_major")) {
1204                                 if(!cvar("teamplay")) {
1205                                         self.flags = self.flags & !FL_JUMPRELEASED;
1206                                         self.classname = "player";
1207                                         if(!cvar("g_lms"))
1208                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1209                                         PutClientInServer();
1210                                         centerprint(self,"");
1211                                         return;
1212                                 } else {
1213                                         self.flags = self.flags & !FL_JUMPRELEASED;
1214                                         stuffcmd(self,"menu_showteamselect\n");
1215                                         return;
1216                                 }
1217                         } else if(self.button0 && self.version == cvar("g_nexuizversion_major")) {
1218                                 self.flags = self.flags & !FL_JUMPRELEASED;
1219                                 if(SpectateNext() == 1) {
1220                                         self.classname = "spectator";
1221                                 }
1222                         }
1223                 } else {
1224                         if (!(self.button0 || self.button2)) {
1225                                 self.flags = self.flags | FL_JUMPRELEASED;
1226                         }
1227                 }
1228                 if(cvar("g_lms") && self.frags == 0)
1229                         centerprint(self, "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n^1You have no more lives left\nwait for next round\n\n\n^7press attack to spectate other players");
1230                 else if(cvar("g_lms") && self.frags == -1)
1231                         centerprint(self, "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n^1Match has already begun\nwait for next round\n\n\n^7press attack to spectate other players");
1232                 else
1233                         PrintWelcomeMessage(self);
1234                         //centerprint(self, "\n\n\npress jump to play\npress attack to spectate other players");
1235         } else if(self.classname == "spectator") {
1236
1237                 if (self.flags & FL_JUMPRELEASED) {
1238                         if (self.button2 && self.version == cvar("g_nexuizversion_major")) {
1239                                 if(!cvar("teamplay")) {
1240                                         self.flags = self.flags & !FL_JUMPRELEASED;
1241                                         self.classname = "player";
1242                                         if(!cvar("g_lms"))
1243                                                 bprint (strcat("^4", self.netname, "^4 is playing now\n"));
1244
1245                                         msg_entity = self;
1246                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1247                                         WriteEntity(MSG_ONE, self);
1248                                         PutClientInServer();
1249                                         centerprint(self,"");
1250                                         return;
1251                                 } else {
1252                                         self.flags = self.flags & !FL_JUMPRELEASED;
1253                                         stuffcmd(self,"menu_showteamselect\n");
1254                                         return;
1255                                 }
1256                         } else if(self.button0) {
1257                                 self.flags = self.flags & !FL_JUMPRELEASED;
1258                                 if(SpectateNext() == 1) {
1259                                         self.classname = "spectator";
1260                                 } else {
1261                                         self.classname = "observer";
1262                                         msg_entity = self;
1263                                         WriteByte(MSG_ONE, SVC_SETVIEW);
1264                                         WriteEntity(MSG_ONE, self);
1265                                         PutClientInServer();
1266                                 }
1267                         } else if (self.button3) {
1268                                 self.flags = self.flags & !FL_JUMPRELEASED;
1269                                 self.classname = "observer";
1270                                 msg_entity = self;
1271                                 WriteByte(MSG_ONE, SVC_SETVIEW);
1272                                 WriteEntity(MSG_ONE, self);
1273                                 PutClientInServer();
1274                         } else {
1275                                 SpectateUpdate();
1276                         }
1277         } else {
1278                 if (!(self.button0 || self.button3)) {
1279                         self.flags = self.flags | FL_JUMPRELEASED;
1280                 }
1281                 }
1282                 if (cvar("g_lms") && self.frags < 1)
1283                         centerprint(self, strcat("\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\nspectating ", self.enemy.netname, "\n\n\n^7press attack for next player\npress attack2 for free fly mode"));
1284                 else
1285                         centerprint(self, strcat("\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\nspectating ", self.enemy.netname, "\n\n\n^7press jump to play\n^7press attack for next player\npress attack2 for free fly mode"));
1286
1287         }
1288 }
1289
1290 /*
1291 =============
1292 PlayerPostThink
1293
1294 Called every frame for each client after the physics are run
1295 =============
1296 */
1297 void PlayerPostThink (void)
1298 {
1299         if(self.classname == "player") {
1300                 CheckRules_Player();
1301                 UpdateChatBubble();
1302                 UpdateTeamBubble();
1303                 UpdatePlayerColors();
1304                 if (self.deadflag == DEAD_NO)
1305                 if (self.impulse)
1306                         ImpulseCommands ();
1307                 if (intermission_running)
1308                         return;         // intermission or finale
1309
1310                 //PrintWelcomeMessage(self);
1311                 //if (TetrisPostFrame()) return;
1312         } else if (self.classname == "observer") {
1313                 //do nothing
1314         } else if (self.classname == "spectator") {
1315                 //do nothing
1316         }
1317 }