data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha <= 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 float GotoFirstMap()
 135 {
 136         if(cvar("_sv_init"))
 137         {
 138                 cvar_set("_sv_init", "0");
 139                 if(cvar("g_maplist_shuffle"))
 140                         ShuffleMaplist();
 141                 tokenizebyseparator(cvar_string("g_maplist"), " ");
 142                 {
 143                         cvar_set("nextmap", argv(0));
 144
 145                         MapInfo_Enumerate();
 146                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 147
 148                         if(!DoNextMapOverride())
 149                                 GotoNextMap();
 150
 151                         return 1;
 152                 }
 153         }
 154         return 0;
 155 }
 156
 157 void cvar_changes_init()
 158 {
 159         float fh;
 160         string s, k, v, d;
 161         float n;
 162
 163         if(cvar_changes)
 164                 strunzone(cvar_changes);
 165         cvar_changes = string_null;
 166         fh = fopen("cvars.txt", FILE_READ);
 167         if(fh < 0)
 168                 return;
 169         while((s = fgets(fh)))
 170         {
 171                 n = tokenize_sane(s);
 172                 if(n < 1)
 173                         continue;
 174                 if(argv(0) == "//")
 175                         continue;
 176                 k = argv(0);
 177                 v = cvar_string(k);
 178                 d = cvar_defstring(k);
 179                 if(v != d)
 180                 {
 181                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 182                         if(strlen(cvar_changes) > 16384)
 183                         {
 184                                 cvar_changes = "// too many settings have been changed to show them here\n";
 185                                 break;
 186                         }
 187                 }
 188         }
 189         fclose(fh);
 190         if(cvar_changes == "")
 191                 cvar_changes = "// this server runs at default settings\n";
 192         else
 193                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 194         cvar_changes = strzone(cvar_changes);
 195 }
 196
 197 void detect_maptype()
 198 {
 199 #if 0
 200         vector o, v;
 201         float i;
 202
 203         for(;;)
 204         {
 205                 o = world.mins;
 206                 o_x += random() * (world.maxs_x - world.mins_x);
 207                 o_y += random() * (world.maxs_y - world.mins_y);
 208                 o_z += random() * (world.maxs_z - world.mins_z);
 209
 210                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 211                 if(trace_fraction == 1)
 212                         continue;
 213
 214                 v = trace_endpos;
 215
 216                 for(i = 0; i < 64; i += 4)
 217                 {
 218                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 219         if(trace_fraction == 1)
 220                 continue;
 221                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 222                 }
 223
 224                 break;
 225         }
 226 #endif
 227 }
 228
 229 float world_already_spawned;
 230 void RegisterWeapons();
 231 void Nagger_Init();
 232 void spawnfunc_worldspawn (void)
 233 {
 234         float fd, l, i, j, n;
 235         string s, col;
 236
 237         dprint_load(); // load dprint status from cvar
 238
 239         if(world_already_spawned)
 240                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 241         world_already_spawned = TRUE;
 242
 243         remove = remove_safely; // during spawning, watch what you remove!
 244
 245         if(cvar_string("cvar_check_default") != "bypass")
 246         {
 247                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 248                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code!");
 249
 250                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 251                         error("Config file mismatch! Please update weapons.cfg and weaponsPro.cfg to match the QuakeC code!");
 252         }
 253
 254         compressShortVector_init();
 255
 256         local entity head;
 257         head = nextent(world);
 258         maxclients = 0;
 259         while(head)
 260         {
 261                 ++maxclients;
 262                 head = nextent(head);
 263         }
 264
 265         // needs to be done so early as they would still spawn
 266         RegisterWeapons();
 267
 268         if(GotoFirstMap())
 269         {
 270                 world_initialized = -1; // don't complain
 271                 return;
 272         }
 273
 274         if(sv_cheats)
 275                 ServerProgsDB = db_create();
 276         else
 277                 ServerProgsDB = db_load("server.db");
 278
 279         TemporaryDB = db_create();
 280
 281         /*
 282         TODO sound pack system
 283         // initialize sound pack system
 284         soundpack = cvar_string("g_soundpack");
 285         if(soundpack != "")
 286                 soundpack = strcat(soundpack, "/");
 287         soundpack = strzone(soundpack);
 288         */
 289
 290         // 0 normal
 291         lightstyle(0, "m");
 292
 293         // 1 FLICKER (first variety)
 294         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 295
 296         // 2 SLOW STRONG PULSE
 297         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 298
 299         // 3 CANDLE (first variety)
 300         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 301
 302         // 4 FAST STROBE
 303         lightstyle(4, "mamamamamama");
 304
 305         // 5 GENTLE PULSE 1
 306         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 307
 308         // 6 FLICKER (second variety)
 309         lightstyle(6, "nmonqnmomnmomomno");
 310
 311         // 7 CANDLE (second variety)
 312         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 313
 314         // 8 CANDLE (third variety)
 315         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 316
 317         // 9 SLOW STROBE (fourth variety)
 318         lightstyle(9, "aaaaaaaazzzzzzzz");
 319
 320         // 10 FLUORESCENT FLICKER
 321         lightstyle(10, "mmamammmmammamamaaamammma");
 322
 323         // 11 SLOW PULSE NOT FADE TO BLACK
 324         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 325
 326         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 327
 328         // 63 testing
 329         lightstyle(63, "a");
 330
 331         if(cvar("g_campaign"))
 332                 CampaignPreInit();
 333
 334         InitGameplayMode();
 335         readlevelcvars();
 336         GrappleHookInit();
 337
 338         player_count = 0;
 339         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 340         if(bot_waypoints_for_items == 1)
 341                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 342                         bot_waypoints_for_items = 0;
 343
 344         // for setting by mapinfo
 345         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 346         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 347
 348         precache();
 349
 350         WaypointSprite_Init();
 351
 352         //if (g_domination)
 353         //      dom_init();
 354
 355         GameLogInit(); // prepare everything
 356         if(cvar("sv_eventlog"))
 357         {
 358                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 359                 s = strcat(s, ftos(random()));
 360                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 361                 s = ":gameinfo:mutators:LIST";
 362                 if(cvar("g_grappling_hook"))
 363                         s = strcat(s, ":grappling_hook");
 364                 if(!cvar("g_use_ammunition"))
 365                         s = strcat(s, ":no_use_ammunition");
 366                 if(!cvar("g_pickup_items"))
 367                         s = strcat(s, ":no_pickup_items");
 368                 if(cvar("g_instagib"))
 369                         s = strcat(s, ":instagib");
 370                 if(cvar_string("g_weaponarena") != "0")
 371                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 372                 if(cvar("g_nixnex"))
 373                         s = strcat(s, ":nixnex");
 374                 if(cvar("g_vampire"))
 375                         s = strcat(s, ":vampire");
 376                 if(cvar("g_laserguided_missile"))
 377                         s = strcat(s, ":laserguided_missile");
 378                 if(cvar("g_norecoil"))
 379                         s = strcat(s, ":norecoil");
 380                 if(cvar("g_midair"))
 381                         s = strcat(s, ":midair");
 382                 if(cvar("g_minstagib"))
 383                         s = strcat(s, ":minstagib");
 384                 GameLogEcho(s);
 385                 GameLogEcho(":gameinfo:end");
 386         }
 387
 388         cvar_set("nextmap", "");
 389
 390         SetDefaultAlpha();
 391
 392         if(cvar("g_campaign"))
 393                 CampaignPostInit();
 394
 395         fteqcc_testbugs();
 396
 397         Ban_LoadBans();
 398
 399         //initialise globals related to sv_timeout
 400         sys_ticrate = cvar("sys_ticrate");
 401         orig_slowmo = cvar("slowmo");
 402
 403         MapInfo_Enumerate();
 404         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
 405
 406         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 407         {
 408                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 409                 if(fd != -1)
 410                 {
 411                         while((s = fgets(fd)))
 412                         {
 413                                 l = tokenize_sane(s);
 414                                 if(l < 2)
 415                                         continue;
 416                                 if(argv(0) == "cd")
 417                                 {
 418                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 419                                         print("  cdtrack ", argv(2), "\n");
 420                                 }
 421                                 else if(argv(0) == "fog")
 422                                 {
 423                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 424                                         print("  \"fog\" \"", s, "\"\n");
 425                                 }
 426                                 else if(argv(0) == "set")
 427                                 {
 428                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 429                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 430                                 }
 431                                 else if(argv(0) != "//")
 432                                 {
 433                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 434                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 435                                 }
 436                         }
 437                         fclose(fd);
 438                 }
 439         }
 440
 441         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 442         addstat(STAT_WEAPONS, AS_INT, weapons);
 443         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 444         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 445         Nagger_Init();
 446
 447         next_pingtime = time + 5;
 448         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 449
 450         detect_maptype();
 451
 452         lsmaps_reply = "^7Maps available: ";
 453         for(i = 0, j = 0; i < MapInfo_count; ++i)
 454         {
 455                 if(MapInfo_Get_ByID(i))
 456                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 457                         {
 458                                 if(mod(i, 2))
 459                                         col = "^2";
 460                                 else
 461                                         col = "^3";
 462                                 ++j;
 463                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 464                         }
 465         }
 466         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 467
 468         maplist_reply = "^7Maps in list: ";
 469         n = tokenize_sane(cvar_string("g_maplist"));
 470         for(i = 0, j = 0; i < n; ++i)
 471         {
 472                 if(MapInfo_CheckMap(argv(i)))
 473                 {
 474                         if(mod(j, 2))
 475                                 col = "^2";
 476                         else
 477                                 col = "^3";
 478                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 479                         ++j;
 480                 }
 481         }
 482         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 483
 484         records_reply = strzone(getrecords());
 485
 486         world_initialized = 1;
 487 }
 488
 489 void spawnfunc_light (void)
 490 {
 491         //makestatic (self); // Who the f___ did that?
 492         remove(self);
 493 }
 494
 495 float TryFile( string pFilename )
 496 {
 497         local float lHandle;
 498         dprint("TryFile(\"", pFilename, "\")\n");
 499         lHandle = fopen( pFilename, FILE_READ );
 500         if( lHandle != -1 ) {
 501                 fclose( lHandle );
 502                 return TRUE;
 503         } else {
 504                 return FALSE;
 505         }
 506 };
 507
 508 string GetGametype()
 509 {
 510         return GametypeNameFromType(game);
 511 }
 512
 513 string getmapname_stored;
 514 string GetMapname()
 515 {
 516         return mapname;
 517 }
 518
 519 float Map_Count, Map_Current;
 520 string Map_Current_Name;
 521
 522 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 523 float GetMaplistPosition()
 524 {
 525         float pos, idx;
 526         string map;
 527
 528         map = GetMapname();
 529         idx = cvar("g_maplist_index");
 530
 531         if(idx >= 0)
 532                 if(idx < Map_Count)
 533                         if(map == argv(idx))
 534                                 return idx;
 535
 536         for(pos = 0; pos < Map_Count; ++pos)
 537                 if(map == argv(pos))
 538                         return pos;
 539
 540         // resume normal maplist rotation if current map is not in g_maplist
 541         return idx;
 542 }
 543
 544 float MapHasRightSize(string map)
 545 {
 546         float fh;
 547         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 548         if(cvar("g_maplist_check_waypoints"))
 549         {
 550                 dprint("checkwp "); dprint(map);
 551                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 552                 if(fh < 0)
 553                 {
 554                         dprint(": no waypoints\n");
 555                         return FALSE;
 556                 }
 557                 dprint(": has waypoints\n");
 558                 fclose(fh);
 559         }
 560
 561         // open map size restriction file
 562         dprint("opensize "); dprint(map);
 563         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 564         if(fh >= 0)
 565         {
 566                 float mapmin, mapmax;
 567                 dprint(": ok, ");
 568                 mapmin = stof(fgets(fh));
 569                 mapmax = stof(fgets(fh));
 570                 fclose(fh);
 571                 if(player_count < mapmin)
 572                 {
 573                         dprint("not enough\n");
 574                         return FALSE;
 575                 }
 576                 if(player_count > mapmax)
 577                 {
 578                         dprint("too many\n");
 579                         return FALSE;
 580                 }
 581                 dprint("right size\n");
 582                 return TRUE;
 583         }
 584         dprint(": not found\n");
 585         return TRUE;
 586 }
 587
 588 string Map_Filename(float position)
 589 {
 590         return strcat("maps/", argv(position), ".bsp");
 591 }
 592
 593 string strwords(string s, float w)
 594 {
 595         float endpos;
 596         for(endpos = 0; w && endpos >= 0; --w)
 597                 endpos = strstrofs(s, " ", endpos + 1);
 598         if(endpos < 0)
 599                 return s;
 600         else
 601                 return substring(s, 0, endpos);
 602 }
 603
 604 float strhasword(string s, string w)
 605 {
 606         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 607 }
 608
 609 void Map_MarkAsRecent(string m)
 610 {
 611         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), cvar("g_maplist_mostrecent_count")));
 612 }
 613
 614 float Map_IsRecent(string m)
 615 {
 616         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 617 }
 618
 619 float Map_Check(float position, float pass)
 620 {
 621         string filename;
 622         string map_next;
 623         map_next = argv(position);
 624         if(pass <= 1)
 625         {
 626                 if(map_next == Map_Current_Name) // same map again in first pass?
 627                         return 0;
 628                 if(Map_IsRecent(map_next))
 629                         return 0;
 630         }
 631         filename = Map_Filename(position);
 632         if(MapInfo_CheckMap(map_next))
 633         {
 634                 if(pass == 2)
 635                         return 1;
 636                 if(MapHasRightSize(map_next))
 637                         return 1;
 638                 return 0;
 639         }
 640         else
 641                 dprint( "Couldn't select '", filename, "'..\n" );
 642
 643         return 0;
 644 }
 645
 646 void Map_Goto_SetStr(string nextmapname)
 647 {
 648         if(getmapname_stored != "")
 649                 strunzone(getmapname_stored);
 650         if(nextmapname == "")
 651                 getmapname_stored = "";
 652         else
 653                 getmapname_stored = strzone(nextmapname);
 654 }
 655
 656 void Map_Goto_SetFloat(float position)
 657 {
 658         cvar_set("g_maplist_index", ftos(position));
 659         Map_Goto_SetStr(argv(position));
 660 }
 661
 662 void GameResetCfg()
 663 {
 664         // settings persist, except...
 665         if(cvar("g_campaign"))
 666                 localcmd("\nexec mutator_reset.cfg\n");
 667         localcmd("\nsettemp_restore\n");
 668 };
 669
 670 void Map_Goto()
 671 {
 672         Map_MarkAsRecent(getmapname_stored);
 673         GameResetCfg();
 674         MapInfo_LoadMap(getmapname_stored);
 675 }
 676
 677 // return codes of map selectors:
 678 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 679 //   -2 = permanent failure
 680 float() MaplistMethod_Iterate = // usual method
 681 {
 682         float pass, i;
 683
 684         for(pass = 1; pass <= 2; ++pass)
 685         {
 686                 for(i = 1; i < Map_Count; ++i)
 687                 {
 688                         float mapindex;
 689                         mapindex = mod(i + Map_Current, Map_Count);
 690                         if(Map_Check(mapindex, pass))
 691                                 return mapindex;
 692                 }
 693         }
 694         return -1;
 695 }
 696
 697 float() MaplistMethod_Repeat = // fallback method
 698 {
 699         if(Map_Check(Map_Current, 2))
 700                 return Map_Current;
 701         return -2;
 702 }
 703
 704 float() MaplistMethod_Random = // random map selection
 705 {
 706         float i, imax;
 707
 708         imax = 42;
 709
 710         for(i = 0; i <= imax; ++i)
 711         {
 712                 float mapindex;
 713                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 714                 if(Map_Check(mapindex, 1))
 715                         return mapindex;
 716         }
 717         return -1;
 718 }
 719
 720 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 721 // the exponent sets a bias on the map selection:
 722 // the higher the exponent, the less likely "shortly repeated" same maps are
 723 {
 724         float i, j, imax, insertpos;
 725
 726         imax = 42;
 727
 728         for(i = 0; i <= imax; ++i)
 729         {
 730                 string newlist;
 731
 732                 // now reinsert this at another position
 733                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 734                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 735                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 736                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 737
 738                 // insert the current map there
 739                 newlist = "";
 740                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 741                         newlist = strcat(newlist, " ", argv(j));
 742                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 743                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 744                         newlist = strcat(newlist, " ", argv(j));
 745                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 746                 cvar_set("g_maplist", newlist);
 747                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 748
 749                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 750                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 751                 if(Map_Check(Map_Current, 1))
 752                         return Map_Current;
 753         }
 754         return -1;
 755 }
 756
 757 void Maplist_Init()
 758 {
 759         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 760         if(Map_Count == 0)
 761         {
 762                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 763                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 764                 ShuffleMaplist();
 765                 localcmd("\nmenu_cmd sync\n");
 766                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 767         }
 768         if(Map_Count == 0)
 769                 error("empty maplist, cannot select a new map");
 770         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 771
 772         if(Map_Current_Name)
 773                 strunzone(Map_Current_Name);
 774         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 775         // this may or may not be correct, but who cares, in the worst case a map
 776         // isn't chosen in the first pass that should have been
 777 }
 778
 779 string GetNextMap()
 780 {
 781         float nextMap;
 782
 783         Maplist_Init();
 784         nextMap = -1;
 785
 786         if(nextMap == -1)
 787                 if(cvar("g_maplist_shuffle") > 0)
 788                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 789
 790         if(nextMap == -1)
 791                 if(cvar("g_maplist_selectrandom"))
 792                         nextMap = MaplistMethod_Random();
 793
 794         if(nextMap == -1)
 795                 nextMap = MaplistMethod_Iterate();
 796
 797         if(nextMap == -1)
 798                 nextMap = MaplistMethod_Repeat();
 799
 800         if(nextMap >= 0)
 801         {
 802                 Map_Goto_SetFloat(nextMap);
 803                 return getmapname_stored;
 804         }
 805
 806         return "";
 807 };
 808
 809 float DoNextMapOverride()
 810 {
 811         if(cvar("g_campaign"))
 812         {
 813                 CampaignPostIntermission();
 814                 alreadychangedlevel = TRUE;
 815                 return TRUE;
 816         }
 817         if(cvar("quit_when_empty"))
 818         {
 819                 if(player_count <= currentbots)
 820                 {
 821                         localcmd("quit\n");
 822                         alreadychangedlevel = TRUE;
 823                         return TRUE;
 824                 }
 825         }
 826         if(cvar_string("quit_and_redirect") != "")
 827         {
 828                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 829                 alreadychangedlevel = TRUE;
 830                 return TRUE;
 831         }
 832         if (cvar("samelevel")) // if samelevel is set, stay on same level
 833         {
 834                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 835                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 836                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 837                 localcmd("restart\n");
 838                 //changelevel (mapname);
 839                 alreadychangedlevel = TRUE;
 840                 return TRUE;
 841         }
 842         if(cvar_string("nextmap") != "")
 843                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 844                 {
 845                         Map_Goto_SetStr(cvar_string("nextmap"));
 846                         Map_Goto();
 847                         alreadychangedlevel = TRUE;
 848                         return TRUE;
 849                 }
 850         if(cvar("lastlevel"))
 851         {
 852                 GameResetCfg();
 853                 localcmd("set lastlevel 0\ntogglemenu\n");
 854                 alreadychangedlevel = TRUE;
 855                 return TRUE;
 856         }
 857         return FALSE;
 858 };
 859
 860 void GotoNextMap()
 861 {
 862         //local string nextmap;
 863         //local float n, nummaps;
 864         //local string s;
 865         if (alreadychangedlevel)
 866                 return;
 867         alreadychangedlevel = TRUE;
 868
 869         {
 870                 string nextMap;
 871                 float allowReset;
 872
 873                 for(allowReset = 1; allowReset >= 0; --allowReset)
 874                 {
 875                         nextMap = GetNextMap();
 876                         if(nextMap != "")
 877                                 break;
 878
 879                         if(allowReset)
 880                         {
 881                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 882                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 883                                 ShuffleMaplist();
 884                                 localcmd("\nmenu_cmd sync\n");
 885                         }
 886                         else
 887                         {
 888                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 889                         }
 890                 }
 891                 Map_Goto();
 892         }
 893 };
 894
 895
 896 /*
 897 ============
 898 IntermissionThink
 899
 900 When the player presses attack or jump, change to the next level
 901 ============
 902 */
 903 .float autoscreenshot;
 904 void() MapVote_Start;
 905 void() MapVote_Think;
 906 float mapvote_initialized;
 907 void IntermissionThink()
 908 {
 909         FixIntermissionClient(self);
 910
 911         if(cvar("sv_autoscreenshot"))
 912         if(self.autoscreenshot > 0)
 913         if(time > self.autoscreenshot)
 914         {
 915                 self.autoscreenshot = -1;
 916                 if(clienttype(self) == CLIENTTYPE_REAL)
 917                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
 918                 return;
 919         }
 920
 921         if (time < intermission_exittime)
 922                 return;
 923
 924         if(!mapvote_initialized)
 925                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
 926                         return;
 927
 928         MapVote_Start();
 929 };
 930
 931 /*
 932 ============
 933 FindIntermission
 934
 935 Returns the entity to view from
 936 ============
 937 */
 938 /*
 939 entity FindIntermission()
 940 {
 941         local   entity spot;
 942         local   float cyc;
 943
 944 // look for info_intermission first
 945         spot = find (world, classname, "info_intermission");
 946         if (spot)
 947         {       // pick a random one
 948                 cyc = random() * 4;
 949                 while (cyc > 1)
 950                 {
 951                         spot = find (spot, classname, "info_intermission");
 952                         if (!spot)
 953                                 spot = find (spot, classname, "info_intermission");
 954                         cyc = cyc - 1;
 955                 }
 956                 return spot;
 957         }
 958
 959 // then look for the start position
 960         spot = find (world, classname, "info_player_start");
 961         if (spot)
 962                 return spot;
 963
 964 // testinfo_player_start is only found in regioned levels
 965         spot = find (world, classname, "testplayerstart");
 966         if (spot)
 967                 return spot;
 968
 969 // then look for the start position
 970         spot = find (world, classname, "info_player_deathmatch");
 971         if (spot)
 972                 return spot;
 973
 974         //objerror ("FindIntermission: no spot");
 975         return world;
 976 };
 977 */
 978
 979 /*
 980 ===============================================================================
 981
 982 RULES
 983
 984 ===============================================================================
 985 */
 986
 987 void DumpStats(float final)
 988 {
 989         local float file;
 990         local string s;
 991         local float to_console;
 992         local float to_eventlog;
 993         local float to_file;
 994         local float i;
 995
 996         to_console = cvar("sv_logscores_console");
 997         to_eventlog = cvar("sv_eventlog");
 998         to_file = cvar("sv_logscores_file");
 999
1000         if(!final)
1001         {
1002                 to_console = TRUE; // always print printstats replies
1003                 to_eventlog = FALSE; // but never print them to the event log
1004         }
1005
1006         if(to_eventlog)
1007                 if(cvar("sv_eventlog_console"))
1008                         to_console = FALSE; // otherwise we get the output twice
1009
1010         if(final)
1011                 s = ":scores:";
1012         else
1013                 s = ":status:";
1014         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1015
1016         if(to_console)
1017                 print(s, "\n");
1018         if(to_eventlog)
1019                 GameLogEcho(s);
1020         if(to_file)
1021         {
1022                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1023                 if(file == -1)
1024                         to_file = FALSE;
1025                 else
1026                         fputs(file, strcat(s, "\n"));
1027         }
1028
1029         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1030         if(to_console)
1031                 print(s, "\n");
1032         if(to_eventlog)
1033                 GameLogEcho(s);
1034         if(to_file)
1035                 fputs(file, strcat(s, "\n"));
1036
1037         FOR_EACH_CLIENT(other)
1038         {
1039                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1040                 {
1041                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1042                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1043                         if(other.classname == "player" || g_arena || g_lms)
1044                                 s = strcat(s, ftos(other.team), ":");
1045                         else
1046                                 s = strcat(s, "spectator:");
1047
1048                         if(to_console)
1049                                 print(s, other.netname, "\n");
1050                         if(to_eventlog)
1051                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1052                         if(to_file)
1053                                 fputs(file, strcat(s, other.netname, "\n"));
1054                 }
1055         }
1056
1057         if(teamplay)
1058         {
1059                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1060                 if(to_console)
1061                         print(s, "\n");
1062                 if(to_eventlog)
1063                         GameLogEcho(s);
1064                 if(to_file)
1065                         fputs(file, strcat(s, "\n"));
1066
1067                 for(i = 1; i < 16; ++i)
1068                 {
1069                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1070                         s = strcat(s, ":", ftos(i));
1071                         if(to_console)
1072                                 print(s, "\n");
1073                         if(to_eventlog)
1074                                 GameLogEcho(s);
1075                         if(to_file)
1076                                 fputs(file, strcat(s, "\n"));
1077                 }
1078         }
1079
1080         if(to_console)
1081                 print(":end\n");
1082         if(to_eventlog)
1083                 GameLogEcho(":end");
1084         if(to_file)
1085         {
1086                 fputs(file, ":end\n");
1087                 fclose(file);
1088         }
1089 }
1090
1091 void FixIntermissionClient(entity e)
1092 {
1093         string s;
1094         if(!e.autoscreenshot) // initial call
1095         {
1096                 e.angles = e.v_angle;
1097                 e.angles_x = -e.angles_x;
1098                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1099                 e.health = -2342;
1100                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1101                 e.solid = SOLID_NOT;
1102                 e.movetype = MOVETYPE_NONE;
1103                 e.takedamage = DAMAGE_NO;
1104                 if(e.weaponentity)
1105                         e.weaponentity.effects = EF_NODRAW;
1106                 if(clienttype(e) == CLIENTTYPE_REAL)
1107                 {
1108                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1109                         s = cvar_string("sv_intermission_cdtrack");
1110                         if(s != "")
1111                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1112                         msg_entity = e;
1113                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1114                 }
1115         }
1116
1117         //e.velocity = '0 0 0';
1118         //e.fixangle = TRUE;
1119
1120         // TODO halt weapon animation
1121 }
1122
1123
1124 /*
1125 go to the next level for deathmatch
1126 only called if a time or frag limit has expired
1127 */
1128 void NextLevel()
1129 {
1130         float minTotalFrags;
1131         float maxTotalFrags;
1132         float score;
1133         float f;
1134
1135         gameover = TRUE;
1136
1137         intermission_running = 1;
1138
1139 // enforce a wait time before allowing changelevel
1140         if(player_count > 0)
1141                 intermission_exittime = time + cvar("sv_mapchange_delay");
1142         else
1143                 intermission_exittime = -1;
1144
1145         /*
1146         WriteByte (MSG_ALL, SVC_CDTRACK);
1147         WriteByte (MSG_ALL, 3);
1148         WriteByte (MSG_ALL, 3);
1149         // done in FixIntermission
1150         */
1151
1152         //pos = FindIntermission ();
1153
1154         VoteReset();
1155
1156         DumpStats(TRUE);
1157
1158         if(cvar("sv_eventlog"))
1159                 GameLogEcho(":gameover");
1160
1161         GameLogClose();
1162
1163         FOR_EACH_CLIENT(other)
1164         {
1165                 FixIntermissionClient(other);
1166
1167                 if(other.winning)
1168                         bprint(other.netname, " ^7wins.\n");
1169         }
1170
1171         minTotalFrags = 0;
1172         maxTotalFrags = 0;
1173         FOR_EACH_PLAYER(other)
1174         {
1175                 if(maxTotalFrags < other.totalfrags)
1176                         maxTotalFrags = other.totalfrags;
1177                 if(minTotalFrags > other.totalfrags)
1178                         minTotalFrags = other.totalfrags;
1179         }
1180
1181         if(!currentbots)
1182         {
1183                 FOR_EACH_PLAYER(other)
1184                 {
1185                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1186                         f = bound(0, other.play_time / max(time, 1), 1);
1187                         // store some statistics?
1188                 }
1189         }
1190
1191         if(cvar("g_campaign"))
1192                 CampaignPreIntermission();
1193
1194         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1195 };
1196
1197 /*
1198 ============
1199 CheckRules_Player
1200
1201 Exit deathmatch games upon conditions
1202 ============
1203 */
1204 void CheckRules_Player()
1205 {
1206         if (gameover)   // someone else quit the game already
1207                 return;
1208
1209         if(self.deadflag == DEAD_NO)
1210                 self.play_time += frametime;
1211
1212         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1213         //   (div0: and that in CheckRules_World please)
1214 };
1215
1216 float checkrules_oneminutewarning;
1217
1218 float checkrules_equality;
1219 float checkrules_overtimewarning;
1220 float checkrules_overtimeend;
1221
1222 void InitiateOvertime()
1223 {
1224         if(!checkrules_overtimeend)
1225                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
1226 }
1227
1228 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1229 float WINNING_YES = 1; // winner found
1230 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1231 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
1232
1233 float GetWinningCode(float fraglimitreached, float equality)
1234 {
1235         if(equality)
1236                 if(fraglimitreached)
1237                         return WINNING_STARTOVERTIME;
1238                 else
1239                         return WINNING_NEVER;
1240         else
1241                 if(fraglimitreached)
1242                         return WINNING_YES;
1243                 else
1244                         return WINNING_NO;
1245 }
1246
1247 // set the .winning flag for exactly those players with a given field value
1248 void SetWinners(.float field, float value)
1249 {
1250         entity head;
1251         FOR_EACH_PLAYER(head)
1252                 head.winning = (head.field == value);
1253 }
1254
1255 // set the .winning flag for those players with a given field value
1256 void AddWinners(.float field, float value)
1257 {
1258         entity head;
1259         FOR_EACH_PLAYER(head)
1260                 if(head.field == value)
1261                         head.winning = 1;
1262 }
1263
1264 // clear the .winning flags
1265 void ClearWinners(void)
1266 {
1267         entity head;
1268         FOR_EACH_PLAYER(head)
1269                 head.winning = 0;
1270 }
1271
1272 // Onslaught winning condition:
1273 // game terminates if only one team has a working generator (or none)
1274 float WinningCondition_Onslaught()
1275 {
1276         entity head;
1277         local float t1, t2, t3, t4;
1278
1279         WinningConditionHelper(); // set worldstatus
1280
1281         // first check if the game has ended
1282         t1 = t2 = t3 = t4 = 0;
1283         head = find(world, classname, "onslaught_generator");
1284         while (head)
1285         {
1286                 if (head.health > 0)
1287                 {
1288                         if (head.team == COLOR_TEAM1) t1 = 1;
1289                         if (head.team == COLOR_TEAM2) t2 = 1;
1290                         if (head.team == COLOR_TEAM3) t3 = 1;
1291                         if (head.team == COLOR_TEAM4) t4 = 1;
1292                 }
1293                 head = find(head, classname, "onslaught_generator");
1294         }
1295         if (t1 + t2 + t3 + t4 < 2)
1296         {
1297                 // game over, only one team remains (or none)
1298                 ClearWinners();
1299                 if (t1) SetWinners(team, COLOR_TEAM1);
1300                 if (t2) SetWinners(team, COLOR_TEAM2);
1301                 if (t3) SetWinners(team, COLOR_TEAM3);
1302                 if (t4) SetWinners(team, COLOR_TEAM4);
1303                 dprint("Have a winner, ending game.\n");
1304                 return WINNING_YES;
1305         }
1306
1307         // Two or more teams remain
1308         return WINNING_NO;
1309 }
1310
1311 float LMS_NewPlayerLives()
1312 {
1313         float fl;
1314         fl = cvar("fraglimit");
1315         if(fl == 0)
1316                 fl = 999;
1317
1318         // first player has left the game for dying too much? Nobody else can get in.
1319         if(lms_lowest_lives < 1)
1320                 return 0;
1321
1322         if(!cvar("g_lms_join_anytime"))
1323                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1324                         return 0;
1325
1326         return bound(1, lms_lowest_lives, fl);
1327 }
1328
1329 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1330 // they win. Otherwise the defending team wins once the timelimit passes.
1331 void assault_new_round();
1332 float WinningCondition_Assault()
1333 {
1334         local float status;
1335
1336         WinningConditionHelper(); // set worldstatus
1337
1338         status = WINNING_NO;
1339         // as the timelimit has not yet passed just assume the defending team will win
1340         if(assault_attacker_team == COLOR_TEAM1)
1341         {
1342                 SetWinners(team, COLOR_TEAM2);
1343         }
1344         else
1345         {
1346                 SetWinners(team, COLOR_TEAM1);
1347         }
1348
1349         local entity ent;
1350         ent = find(world, classname, "target_assault_roundend");
1351         if(ent)
1352         {
1353                 if(ent.winning) // round end has been triggered by attacking team
1354                 {
1355                         bprint("ASSAULT: round completed...\n");
1356                         SetWinners(team, assault_attacker_team);
1357
1358                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1359
1360                         if(ent.cnt == 1) // this was the second round
1361                         {
1362                                 status = WINNING_YES;
1363                         }
1364                         else
1365                         {
1366                                 local entity oldself;
1367                                 oldself = self;
1368                                 self = ent;
1369                                 assault_new_round();
1370                                 self = oldself;
1371                         }
1372                 }
1373         }
1374
1375         return status;
1376 }
1377
1378 // LMS winning condition: game terminates if and only if there's at most one
1379 // one player who's living lives. Top two scores being equal cancels the time
1380 // limit.
1381 float WinningCondition_LMS()
1382 {
1383         entity head, head2;
1384         float have_player;
1385         float have_players;
1386         float l;
1387
1388         have_player = FALSE;
1389         have_players = FALSE;
1390         l = LMS_NewPlayerLives();
1391
1392         head = find(world, classname, "player");
1393         if(head)
1394                 have_player = TRUE;
1395         head2 = find(head, classname, "player");
1396         if(head2)
1397                 have_players = TRUE;
1398
1399         if(have_player)
1400         {
1401                 // we have at least one player
1402                 if(have_players)
1403                 {
1404                         // two or more active players - continue with the game
1405                 }
1406                 else
1407                 {
1408                         // exactly one player?
1409
1410                         ClearWinners();
1411                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1412
1413                         if(l)
1414                         {
1415                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1416                                 return WINNING_NO;
1417                         }
1418                         else
1419                         {
1420                                 // a winner!
1421                                 // and assign him his first place
1422                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1423                                 return WINNING_YES;
1424                         }
1425                 }
1426         }
1427         else
1428         {
1429                 // nobody is playing at all...
1430                 if(l)
1431                 {
1432                         // wait for players...
1433                 }
1434                 else
1435                 {
1436                         // SNAFU (maybe a draw game?)
1437                         ClearWinners();
1438                         dprint("No players, ending game.\n");
1439                         return WINNING_YES;
1440                 }
1441         }
1442
1443         // When we get here, we have at least two players who are actually LIVING,
1444         // now check if the top two players have equal score.
1445         WinningConditionHelper();
1446
1447         ClearWinners();
1448         if(WinningConditionHelper_winner)
1449                 WinningConditionHelper_winner.winning = TRUE;
1450         if(WinningConditionHelper_equality)
1451                 return WINNING_NEVER;
1452
1453         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1454         return WINNING_NO;
1455 }
1456
1457 void ShuffleMaplist()
1458 {
1459         string result;
1460         float start;
1461         float litems;
1462         float selected;
1463         float i;
1464
1465         result = cvar_string("g_maplist");
1466         litems = tokenizebyseparator(result, " ");
1467
1468         for(start = 0; start < litems - 1; ++start)
1469         {
1470                 result = "";
1471
1472                 // select a random item
1473                 selected = floor(random() * (litems - start) + start);
1474
1475                 // shift this item to the place start
1476                 for(i = 0; i < start; ++i)
1477                         result = strcat(result, " ", argv(i));
1478                 result = strcat(result, " ", argv(selected));
1479                 for(i = start; i < litems; ++i)
1480                         if(i != selected)
1481                                 result = strcat(result, " ", argv(i));
1482                 result = substring(result, 1, strlen(result) - 1);
1483
1484                 litems = tokenizebyseparator(result, " ");
1485
1486                 //dprint(result, "\n");
1487         }
1488
1489         cvar_set("g_maplist", result);
1490 }
1491
1492 float leaderfrags;
1493 float WinningCondition_Scores(float limit)
1494 {
1495         // TODO make everything use THIS winning condition (except LMS)
1496         WinningConditionHelper();
1497
1498         if(teams_matter)
1499         {
1500                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1501                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1502                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1503                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1504         }
1505
1506         ClearWinners();
1507         if(WinningConditionHelper_winner)
1508                 WinningConditionHelper_winner.winning = 1;
1509         if(WinningConditionHelper_winnerteam >= 0)
1510                 SetWinners(team, WinningConditionHelper_winnerteam);
1511
1512         if(WinningConditionHelper_lowerisbetter)
1513         {
1514                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1515                 limit = -limit;
1516         }
1517
1518         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying))
1519         // these modes always score in increments of 1, thus this makes sense
1520         {
1521                 if(leaderfrags != WinningConditionHelper_topscore)
1522                 {
1523                         leaderfrags = WinningConditionHelper_topscore;
1524
1525                         if (limit)
1526                         if (leaderfrags == limit - 1)
1527                                 play2all("announcer/robotic/1fragleft.wav");
1528                         else if (leaderfrags == limit - 2)
1529                                 play2all("announcer/robotic/2fragsleft.wav");
1530                         else if (leaderfrags == limit - 3)
1531                                 play2all("announcer/robotic/3fragsleft.wav");
1532                 }
1533         }
1534
1535         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1536 }
1537
1538 float WinningCondition_Race(float fraglimit)
1539 {
1540         float wc;
1541         entity p;
1542         wc = WinningCondition_Scores(fraglimit);
1543
1544         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1545         if(wc == WINNING_YES || wc == WINNING_STARTOVERTIME)
1546         // do NOT support equality when the laps are all raced!
1547         {
1548                 FOR_EACH_PLAYER(p)
1549                         if not(p.race_completed)
1550                                 return WINNING_STARTOVERTIME;
1551                 return WINNING_YES;
1552         }
1553         return wc;
1554 }
1555
1556 void ReadyRestart();
1557 float WinningCondition_QualifyingThenRace(float limit)
1558 {
1559         float wc;
1560         wc = WinningCondition_Scores(limit);
1561
1562         // NEVER initiate overtime
1563         if(wc == WINNING_YES || wc == WINNING_STARTOVERTIME)
1564         {
1565                 return WINNING_YES;
1566         }
1567
1568         return wc;
1569 }
1570
1571 float WinningCondition_RanOutOfSpawns()
1572 {
1573         entity head;
1574
1575         if(!have_team_spawns)
1576                 return WINNING_NO;
1577
1578         if(!some_spawn_has_been_used)
1579                 return WINNING_NO;
1580
1581         team1_score = team2_score = team3_score = team4_score = 0;
1582
1583         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1584         {
1585                 if(head.team == COLOR_TEAM1)
1586                         team1_score = 1;
1587                 else if(head.team == COLOR_TEAM2)
1588                         team2_score = 1;
1589                 else if(head.team == COLOR_TEAM3)
1590                         team3_score = 1;
1591                 else if(head.team == COLOR_TEAM4)
1592                         team4_score = 1;
1593         }
1594
1595         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1596         {
1597                 if(head.team == COLOR_TEAM1)
1598                         team1_score = 1;
1599                 else if(head.team == COLOR_TEAM2)
1600                         team2_score = 1;
1601                 else if(head.team == COLOR_TEAM3)
1602                         team3_score = 1;
1603                 else if(head.team == COLOR_TEAM4)
1604                         team4_score = 1;
1605         }
1606
1607         ClearWinners();
1608         if(team1_score + team2_score + team3_score + team4_score == 0)
1609         {
1610                 checkrules_equality = TRUE;
1611                 return WINNING_YES;
1612         }
1613         else if(team1_score + team2_score + team3_score + team4_score == 1)
1614         {
1615                 float t, i;
1616                 if(team1_score) t = COLOR_TEAM1;
1617                 if(team2_score) t = COLOR_TEAM2;
1618                 if(team3_score) t = COLOR_TEAM3;
1619                 if(team4_score) t = COLOR_TEAM4;
1620                 CheckAllowedTeams(world);
1621                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1622                 {
1623                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1624                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1625                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1626                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1627                 }
1628
1629                 AddWinners(team, t);
1630                 return WINNING_YES;
1631         }
1632         else
1633                 return WINNING_NO;
1634 }
1635
1636 /*
1637 ============
1638 CheckRules_World
1639
1640 Exit deathmatch games upon conditions
1641 ============
1642 */
1643 void CheckRules_World()
1644 {
1645         local float status;
1646         local float timelimit;
1647         local float fraglimit;
1648
1649         VoteThink();
1650         MapVote_Think();
1651
1652         SetDefaultAlpha();
1653
1654         /*
1655         MapVote_Think should now do that part
1656         if (intermission_running)
1657                 if (time >= intermission_exittime + 60)
1658                 {
1659                         if(!DoNextMapOverride())
1660                                 GotoNextMap();
1661                         return;
1662                 }
1663         */
1664
1665         if (gameover)   // someone else quit the game already
1666         {
1667                 if(player_count == 0) // Nobody there? Then let's go to the next map
1668                         MapVote_Start();
1669                         // this will actually check the player count in the next frame
1670                         // again, but this shouldn't hurt
1671                 return;
1672         }
1673
1674         timelimit = cvar("timelimit") * 60;
1675         fraglimit = cvar("fraglimit");
1676
1677         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1678         {
1679                 if(timelimit > 0)
1680                         timelimit = 0; // timelimit is not made for warmup
1681                 if(fraglimit > 0)
1682                         fraglimit = 0; // no fraglimit for now
1683         }
1684
1685         if(timelimit > 0)
1686                 timelimit += game_starttime;
1687
1688         if(checkrules_overtimeend)
1689         {
1690                 if(!checkrules_overtimewarning)
1691                 {
1692                         checkrules_overtimewarning = TRUE;
1693                         //announceall("announcer/robotic/1minuteremains.wav");
1694                         if(g_race && !g_race_qualifying)
1695                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1696                         else
1697                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1698                 }
1699         }
1700         else
1701         {
1702                 if (timelimit && time >= timelimit)
1703                 {
1704                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1705                         {
1706                                 float totalplayers;
1707                                 float playerswithlaps;
1708                                 float readyplayers;
1709                                 entity head;
1710                                 totalplayers = playerswithlaps = readyplayers = 0;
1711                                 FOR_EACH_PLAYER(head)
1712                                 {
1713                                         ++totalplayers;
1714                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1715                                                 ++playerswithlaps;
1716                                         if(head.ready)
1717                                                 ++readyplayers;
1718                                 }
1719
1720                                 // at least 2/3 of the players have completed a lap: start the RACE
1721                                 // otherwise, the players should end the qualifying on their own
1722                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1723                                 {
1724                                         checkrules_overtimeend = 0;
1725                                         ReadyRestart(); // go to race
1726                                 }
1727                                 else
1728                                         InitiateOvertime();
1729                         }
1730                         else
1731                                 InitiateOvertime();
1732                 }
1733         }
1734
1735         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1736         {
1737                 NextLevel();
1738                 return;
1739         }
1740
1741         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1742         {
1743                 checkrules_oneminutewarning = TRUE;
1744                 play2all("announcer/robotic/1minuteremains.wav");
1745         }
1746
1747         status = WinningCondition_RanOutOfSpawns();
1748         if(status == WINNING_YES)
1749         {
1750                 bprint("Hey! Someone ran out of spawns!\n");
1751         }
1752         else if(g_race && !g_race_qualifying && timelimit >= 0)
1753         {
1754                 status = WinningCondition_Race(fraglimit);
1755         }
1756         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1757         {
1758                 status = WinningCondition_QualifyingThenRace(fraglimit);
1759         }
1760         else if(g_assault)
1761         {
1762                 status = WinningCondition_Assault(); // TODO remove this?
1763         }
1764         else if(g_lms)
1765         {
1766                 status = WinningCondition_LMS();
1767         }
1768         else if (g_onslaught)
1769         {
1770                 status = WinningCondition_Onslaught(); // TODO remove this?
1771         }
1772         else
1773         {
1774                 status = WinningCondition_Scores(fraglimit);
1775         }
1776
1777         if(status == WINNING_STARTOVERTIME)
1778         {
1779                 status = WINNING_NEVER;
1780                 InitiateOvertime();
1781         }
1782
1783         if(status == WINNING_NEVER)
1784                 // equality cases! Nobody wins if the overtime ends in a draw.
1785                 ClearWinners();
1786
1787         if(checkrules_overtimeend)
1788                 if(status != WINNING_NEVER || time >= checkrules_overtimeend)
1789                         status = WINNING_YES;
1790
1791         if(status == WINNING_YES)
1792                 NextLevel();
1793 };
1794
1795 float mapvote_nextthink;
1796 float mapvote_initialized;
1797 float mapvote_keeptwotime;
1798 float mapvote_timeout;
1799 string mapvote_message;
1800 string mapvote_screenshot_dir;
1801
1802 float mapvote_count;
1803 float mapvote_count_real;
1804 string mapvote_maps[MAPVOTE_COUNT];
1805 float mapvote_maps_suggested[MAPVOTE_COUNT];
1806 string mapvote_suggestions[MAPVOTE_COUNT];
1807 float mapvote_suggestion_ptr;
1808 float mapvote_maxlen;
1809 float mapvote_voters;
1810 float mapvote_votes[MAPVOTE_COUNT];
1811 float mapvote_run;
1812 float mapvote_detail;
1813 float mapvote_abstain;
1814 float mapvote_dirty;
1815 .float mapvote;
1816
1817 void MapVote_ClearAllVotes()
1818 {
1819         FOR_EACH_CLIENT(other)
1820                 other.mapvote = 0;
1821 }
1822
1823 string MapVote_Suggest(string m)
1824 {
1825         float i;
1826         if(m == "")
1827                 return "That's not how to use this command.";
1828         if(!cvar("g_maplist_votable_suggestions"))
1829                 return "Suggestions are not accepted on this server.";
1830         if(mapvote_initialized)
1831                 return "Can't suggest - voting is already in progress!";
1832         m = MapInfo_FixName(m);
1833         if(!m)
1834                 return "The map you suggested is not available on this server.";
1835         if(!cvar("g_maplist_votable_override_mostrecent"))
1836                 if(Map_IsRecent(m))
1837                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1838
1839         if(!MapInfo_CheckMap(m))
1840                 return "The map you suggested does not support the current game mode.";
1841         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1842                 if(mapvote_suggestions[i] == m)
1843                         return "This map was already suggested.";
1844         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1845         {
1846                 i = floor(random() * mapvote_suggestion_ptr);
1847         }
1848         else
1849         {
1850                 i = mapvote_suggestion_ptr;
1851                 mapvote_suggestion_ptr += 1;
1852         }
1853         if(mapvote_suggestions[i] != "")
1854                 strunzone(mapvote_suggestions[i]);
1855         mapvote_suggestions[i] = strzone(m);
1856         if(cvar("sv_eventlog"))
1857                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
1858         return strcat("Suggestion of ", m, " accepted.");
1859 }
1860
1861 void MapVote_AddVotable(string nextMap, float isSuggestion)
1862 {
1863         float j;
1864         if(nextMap == "")
1865                 return;
1866         for(j = 0; j < mapvote_count; ++j)
1867                 if(mapvote_maps[j] == nextMap)
1868                         return;
1869         if(strlen(nextMap) > mapvote_maxlen)
1870                 mapvote_maxlen = strlen(nextMap);
1871         mapvote_maps[mapvote_count] = strzone(nextMap);
1872         mapvote_maps_suggested[mapvote_count] = isSuggestion;
1873         mapvote_count += 1;
1874 }
1875
1876 void MapVote_SendData(float target);
1877 void MapVote_Init()
1878 {
1879         float i;
1880         float nmax, smax;
1881
1882         MapVote_ClearAllVotes();
1883
1884         mapvote_count = 0;
1885         mapvote_detail = !cvar("g_maplist_votable_nodetail");
1886         mapvote_abstain = cvar("g_maplist_votable_abstain");
1887
1888         if(mapvote_abstain)
1889                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
1890         else
1891                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
1892         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
1893
1894         if(mapvote_suggestion_ptr)
1895                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
1896                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
1897
1898         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1899                 MapVote_AddVotable(GetNextMap(), FALSE);
1900
1901         if(mapvote_count == 0)
1902         {
1903                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1904                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
1905                 ShuffleMaplist();
1906                 localcmd("\nmenu_cmd sync\n");
1907                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1908                         MapVote_AddVotable(GetNextMap(), FALSE);
1909         }
1910
1911         mapvote_count_real = mapvote_count;
1912         if(mapvote_abstain)
1913                 MapVote_AddVotable("don't care", 0);
1914
1915         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
1916
1917         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
1918         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
1919         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
1920                 mapvote_keeptwotime = 0;
1921         mapvote_message = "Choose a map and press its key!";
1922
1923         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
1924         if(mapvote_screenshot_dir == "")
1925                 mapvote_screenshot_dir = "maps";
1926         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
1927
1928         if(!cvar("g_maplist_textonly"))
1929                 MapVote_SendData(MSG_ALL);
1930 }
1931
1932 void MapVote_SendPicture(float id)
1933 {
1934         msg_entity = self;
1935         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1936         WriteByte(MSG_ONE, TE_CSQC_MAPVOTE);
1937         WriteByte(MSG_ONE, MAPVOTE_NET_PIC);
1938         WriteByte(MSG_ONE, id);
1939         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
1940 }
1941
1942 float GameCommand_MapVote(string cmd)
1943 {
1944         if(!intermission_running)
1945                 return FALSE;
1946         if(!cvar("g_maplist_textonly"))
1947         {
1948                 if(cmd == "mv_getpic")
1949                 {
1950                         MapVote_SendPicture(stof(argv(1)));
1951                         return TRUE;
1952                 }
1953         }
1954
1955         return FALSE;
1956 }
1957
1958 float MapVote_GetMapMask()
1959 {
1960         float mask, i, power;
1961         mask = 0;
1962         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
1963                 if(mapvote_maps[i] != "")
1964                         mask |= power;
1965         return mask;
1966 }
1967
1968 void MapVote_SendData(float targ)
1969 {
1970         string mapfile, pakfile;
1971         float i, o;
1972         WriteByte(targ, SVC_TEMPENTITY);
1973         WriteByte(targ, TE_CSQC_CONFIG);
1974         WriteString(targ, "mv_screenshot_dir");
1975         WriteString(targ, mapvote_screenshot_dir);
1976
1977         WriteByte(targ, SVC_TEMPENTITY);
1978         WriteByte(targ, TE_CSQC_MAPVOTE);
1979         WriteByte(targ, MAPVOTE_NET_INIT);
1980
1981         WriteByte(targ, mapvote_count);
1982         WriteByte(targ, mapvote_abstain);
1983         WriteByte(targ, mapvote_detail);
1984         WriteCoord(targ, mapvote_timeout);
1985         if(mapvote_count <= 8)
1986                 WriteByte(targ, MapVote_GetMapMask());
1987         else
1988                 WriteShort(targ, MapVote_GetMapMask());
1989         for(i = 0; i < mapvote_count; ++i)
1990                 if(mapvote_maps[i] != "")
1991                 {
1992                         WriteString(targ, mapvote_maps[i]);
1993                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
1994                         pakfile = whichpack(strcat(mapfile, ".tga"));
1995                         if(pakfile == "")
1996                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
1997                         if(pakfile == "")
1998                                 pakfile = whichpack(strcat(mapfile, ".png"));
1999                         print("pakfile is ", pakfile, "\n");
2000                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2001                                 pakfile = substring(pakfile, o, 999);
2002                         WriteString(targ, pakfile);
2003                 }
2004 }
2005
2006 void MapVote_UpdateData(float targ)
2007 {
2008         float i;
2009         WriteByte(targ, SVC_TEMPENTITY);
2010         WriteByte(targ, TE_CSQC_MAPVOTE);
2011         WriteByte(targ, MAPVOTE_NET_UPDATE);
2012         if(mapvote_count <= 8)
2013                 WriteByte(targ, MapVote_GetMapMask());
2014         else
2015                 WriteShort(targ, MapVote_GetMapMask());
2016         if(mapvote_detail)
2017                 for(i = 0; i < mapvote_count; ++i)
2018                         if(mapvote_maps[i] != "")
2019                                 WriteByte(targ, mapvote_votes[i]);
2020 }
2021
2022 void MapVote_TellVote(float targ, float vote)
2023 {
2024         WriteByte(targ, SVC_TEMPENTITY);
2025         WriteByte(targ, TE_CSQC_MAPVOTE);
2026         WriteByte(targ, MAPVOTE_NET_OWNVOTE);
2027         WriteByte(targ, vote);
2028 }
2029
2030 float MapVote_Finished(float mappos)
2031 {
2032         string result;
2033         float i;
2034         float didntvote;
2035
2036         if(cvar("sv_eventlog"))
2037         {
2038                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2039                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2040                 didntvote = mapvote_voters;
2041                 for(i = 0; i < mapvote_count; ++i)
2042                         if(mapvote_maps[i] != "")
2043                         {
2044                                 didntvote -= mapvote_votes[i];
2045                                 if(i != mappos)
2046                                 {
2047                                         result = strcat(result, ":", mapvote_maps[i]);
2048                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2049                                 }
2050                         }
2051                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2052
2053                 GameLogEcho(result);
2054                 if(mapvote_maps_suggested[mappos])
2055                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2056         }
2057
2058         FOR_EACH_REALCLIENT(other)
2059                 FixClientCvars(other);
2060
2061         Map_Goto_SetStr(mapvote_maps[mappos]);
2062         Map_Goto();
2063         alreadychangedlevel = TRUE;
2064         return TRUE;
2065 }
2066 void MapVote_CheckRules_1()
2067 {
2068         float i;
2069
2070         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2071         {
2072                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2073                 mapvote_votes[i] = 0;
2074         }
2075
2076         mapvote_voters = 0;
2077         FOR_EACH_REALCLIENT(other)
2078         {
2079                 ++mapvote_voters;
2080                 if(other.mapvote)
2081                 {
2082                         i = other.mapvote - 1;
2083                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2084                         mapvote_votes[i] = mapvote_votes[i] + 1;
2085                 }
2086         }
2087 }
2088
2089 float MapVote_CheckRules_2()
2090 {
2091         float i;
2092         float firstPlace, secondPlace;
2093         float firstPlaceVotes, secondPlaceVotes;
2094         float mapvote_voters_real;
2095         string result;
2096
2097         mapvote_voters_real = mapvote_voters;
2098         if(mapvote_abstain)
2099                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2100
2101         RandomSelection_Init();
2102         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2103                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2104         firstPlace = RandomSelection_chosen_float;
2105         firstPlaceVotes = RandomSelection_best_priority;
2106         //dprint("First place: ", ftos(firstPlace), "\n");
2107         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2108
2109         RandomSelection_Init();
2110         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2111                 if(i != firstPlace)
2112                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2113         secondPlace = RandomSelection_chosen_float;
2114         secondPlaceVotes = RandomSelection_best_priority;
2115         //dprint("Second place: ", ftos(secondPlace), "\n");
2116         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2117
2118         if(firstPlace == -1)
2119                 error("No first place in map vote... WTF?");
2120
2121         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2122                 return MapVote_Finished(firstPlace);
2123
2124         if(mapvote_keeptwotime)
2125                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2126                 {
2127                         float didntvote;
2128                         mapvote_dirty = TRUE;
2129                         mapvote_message = "Now decide between the TOP TWO!";
2130                         mapvote_keeptwotime = 0;
2131                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2132                         result = strcat(result, ":", ftos(firstPlaceVotes));
2133                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2134                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2135                         didntvote = mapvote_voters;
2136                         for(i = 0; i < mapvote_count; ++i)
2137                                 if(mapvote_maps[i] != "")
2138                                 {
2139                                         didntvote -= mapvote_votes[i];
2140                                         if(i != firstPlace)
2141                                                 if(i != secondPlace)
2142                                                 {
2143                                                         result = strcat(result, ":", mapvote_maps[i]);
2144                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2145                                                         if(i < mapvote_count_real)
2146                                                         {
2147                                                                 strunzone(mapvote_maps[i]);
2148                                                                 mapvote_maps[i] = "";
2149                                                         }
2150                                                 }
2151                                 }
2152                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2153                         if(cvar("sv_eventlog"))
2154                                 GameLogEcho(result);
2155                 }
2156
2157         return FALSE;
2158 }
2159 void MapVote_Tick()
2160 {
2161         string msgstr;
2162         string tmp;
2163         float i;
2164         float keeptwo;
2165         float totalvotes;
2166
2167         keeptwo = mapvote_keeptwotime;
2168         MapVote_CheckRules_1(); // count
2169         if(MapVote_CheckRules_2()) // decide
2170                 return;
2171
2172         totalvotes = 0;
2173         FOR_EACH_REALCLIENT(other)
2174         {
2175                 // hide scoreboard again
2176                 if(other.health != 2342)
2177                 {
2178                         other.health = 2342;
2179                         other.impulse = 0;
2180                         if(clienttype(other) == CLIENTTYPE_REAL)
2181                         {
2182                                 if(cvar("g_maplist_textonly"))
2183                                         stuffcmd(other, "\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
2184
2185                                 msg_entity = other;
2186                                 WriteByte(MSG_ONE, SVC_FINALE);
2187                                 WriteString(MSG_ONE, "");
2188                         }
2189                 }
2190
2191                 // notify about keep-two
2192                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
2193                         play2(other, "misc/invshot.wav");
2194
2195                 // clear possibly invalid votes
2196                 if(mapvote_maps[other.mapvote - 1] == "")
2197                         other.mapvote = 0;
2198                 // use impulses as new vote
2199                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2200                         if(mapvote_maps[other.impulse - 1] != "")
2201                         {
2202                                 other.mapvote = other.impulse;
2203                                 if(mapvote_detail)
2204                                         mapvote_dirty = TRUE;
2205
2206                                 msg_entity = other;
2207                                 MapVote_TellVote(MSG_ONE, other.mapvote);
2208                         }
2209                 other.impulse = 0;
2210
2211                 if(other.mapvote)
2212                         ++totalvotes;
2213         }
2214
2215         MapVote_CheckRules_1(); // just count
2216
2217         if(!cvar("g_maplist_textonly"))
2218         if(mapvote_dirty) // 1 if "keeptwo" or "impulse" happened before
2219         {
2220                 MapVote_UpdateData(MSG_BROADCAST);
2221                 mapvote_dirty = FALSE;
2222         }
2223
2224         if(cvar("g_maplist_textonly"))
2225         {
2226                 FOR_EACH_REALCLIENT(other)
2227                 {
2228                         // display voting screen
2229                         msgstr = "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n";
2230                         msgstr = substring(msgstr, 0, strlen(msgstr) - mapvote_count);
2231                         if(mapvote_abstain)
2232                                 msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2233                         msgstr = strcat(msgstr, mapvote_message);
2234                         msgstr = strcat(msgstr, "\n\n");
2235                         for(i = 0; i < mapvote_count; ++i)
2236                                 if(mapvote_maps[i] == "")
2237                                         msgstr = strcat(msgstr, "\n");
2238                                 else
2239                                 {
2240                                         tmp = mapvote_maps[i];
2241                                         tmp = strpad(mapvote_maxlen, tmp);
2242                                         tmp = strcat(ftos(mod(i + 1, 10)), ": ", tmp);
2243                                         if(mapvote_detail)
2244                                         {
2245                                                 tmp = strcat(tmp, " ^2(", ftos(mapvote_votes[i]), " vote");
2246                                                 if(mapvote_votes[i] != 1)
2247                                                         tmp = strcat(tmp, "s");
2248                                                 tmp = strcat(tmp, ")");
2249                                                 tmp = strpad(mapvote_maxlen + 15, tmp);
2250                                         }
2251                                         if(mapvote_abstain)
2252                                                 if(i == mapvote_count - 1)
2253                                                         msgstr = strcat(msgstr, "\n");
2254                                         if(other.mapvote == i + 1)
2255                                                 msgstr = strcat(msgstr, "^3> ", tmp, "\n");
2256                                         else
2257                                                 msgstr = strcat(msgstr, "^7  ", tmp, "\n");
2258                                 }
2259
2260                         msgstr = strcat(msgstr, "\n\n^2", ftos(totalvotes), " vote");
2261                         if(totalvotes != 1)
2262                                 msgstr = strcat(msgstr, "s");
2263                         msgstr = strcat(msgstr, " cast");
2264                         i = ceil(mapvote_timeout - time);
2265                         msgstr = strcat(msgstr, "\n", ftos(i), " second");
2266                         if(i != 1)
2267                                 msgstr = strcat(msgstr, "s");
2268                         msgstr = strcat(msgstr, " left");
2269
2270                         centerprint_atprio(other, CENTERPRIO_MAPVOTE, msgstr);
2271                 }
2272         }
2273 }
2274 void MapVote_Start()
2275 {
2276         if(mapvote_run)
2277                 return;
2278
2279         MapInfo_Enumerate();
2280         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1))
2281                 mapvote_run = TRUE;
2282 }
2283 void MapVote_Think()
2284 {
2285         if(!mapvote_run)
2286                 return;
2287
2288         if(alreadychangedlevel)
2289                 return;
2290
2291         if(time < mapvote_nextthink)
2292                 return;
2293         //dprint("tick\n");
2294
2295         mapvote_nextthink = time + 0.5;
2296
2297         if(!mapvote_initialized)
2298         {
2299                 mapvote_initialized = TRUE;
2300                 if(DoNextMapOverride())
2301                         return;
2302                 if(!cvar("g_maplist_votable") || player_count <= 0)
2303                 {
2304                         GotoNextMap();
2305                         return;
2306                 }
2307                 MapVote_Init();
2308         }
2309
2310         MapVote_Tick();
2311 };
2312
2313 string GotoMap(string m)
2314 {
2315         if(!MapInfo_CheckMap(m))
2316                 return "The map you chose is not available on this server.";
2317         cvar_set("nextmap", m);
2318         cvar_set("timelimit", "-1");
2319         if(mapvote_initialized || alreadychangedlevel)
2320         {
2321                 if(DoNextMapOverride())
2322                         return "Map switch initiated.";
2323                 else
2324                         return "Hm... no. For some reason I like THIS map more.";
2325         }
2326         else
2327                 return "Map switch will happen after scoreboard.";
2328 }
2329
2330
2331 void EndFrame()
2332 {
2333         FOR_EACH_REALCLIENT(self)
2334         {
2335                 if(self.classname == "spectator")
2336                 {
2337                         if(self.enemy.typehitsound)
2338                                 play2(self, "misc/typehit.wav");
2339                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2340                                 play2(self, "misc/hit.wav");
2341                 }
2342                 else
2343                 {
2344                         if(self.typehitsound)
2345                                 play2(self, "misc/typehit.wav");
2346                         else if(self.hitsound && self.cvar_cl_hitsound)
2347                                 play2(self, "misc/hit.wav");
2348                 }
2349         }
2350         FOR_EACH_CLIENT(self)
2351         {
2352                 self.hitsound = FALSE;
2353                 self.typehitsound = FALSE;
2354         }
2355 }
2356
2357
2358 /*
2359  * RedirectionThink:
2360  * returns TRUE if redirecting
2361  */
2362 float redirection_timeout;
2363 float redirection_nextthink;
2364 float RedirectionThink()
2365 {
2366         float clients_found;
2367
2368         if(redirection_target == "")
2369                 return FALSE;
2370
2371         if(!redirection_timeout)
2372         {
2373                 cvar_set("sv_public", "-2");
2374                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2375                 if(redirection_target == "self")
2376                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2377                 else
2378                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2379         }
2380
2381         if(time < redirection_nextthink)
2382                 return TRUE;
2383
2384         redirection_nextthink = time + 1;
2385
2386         clients_found = 0;
2387         FOR_EACH_REALCLIENT(self)
2388         {
2389                 print("Redirecting: sending connect command to ", self.netname, "\n");
2390                 if(redirection_target == "self")
2391                         stuffcmd(self, "\ndisconnect; reconnect\n");
2392                 else
2393                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2394                 ++clients_found;
2395         }
2396
2397         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2398
2399         if(time > redirection_timeout || clients_found == 0)
2400                 localcmd("\nwait; wait; wait; quit\n");
2401
2402         return TRUE;
2403 }
2404
2405 void RestoreGame()
2406 {
2407         // Loaded from a save game
2408         // some things then break, so let's work around them...
2409
2410         // Progs DB (capture records)
2411         if(sv_cheats)
2412                 ServerProgsDB = db_create();
2413         else
2414                 ServerProgsDB = db_load("server.db");
2415
2416         // Mapinfo
2417         MapInfo_Shutdown();
2418         MapInfo_Enumerate();
2419         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
2420 }
2421
2422 void SV_Shutdown()
2423 {
2424         if(world_initialized > 0)
2425         {
2426                 world_initialized = 0;
2427                 print("Saving persistent data...\n");
2428                 Ban_SaveBans();
2429                 if(!sv_cheats)
2430                         db_save(ServerProgsDB, "server.db");
2431                 if(cvar("developer"))
2432                         db_save(TemporaryDB, "server-temp.db");
2433                 db_close(ServerProgsDB);
2434                 db_close(TemporaryDB);
2435                 print("done!\n");
2436                 // tell the bot system the game is ending now
2437                 bot_endgame();
2438
2439                 MapInfo_Shutdown();
2440         }
2441         else if(world_initialized == 0)
2442         {
2443                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2444         }
2445 }