added command "gotomap" which does the same as chmap, but forces the
[divverent/nexuiz.git] / data / qcsrc / server / g_world.qc
1 string GetMapname();
2 void GotoNextMap();
3
4 void SetDefaultAlpha()
5 {
6         if(cvar("g_cloaked"))
7         {
8                 default_player_alpha = cvar("g_balance_cloaked_alpha");
9         }
10         else
11         {
12                 default_player_alpha = cvar("g_player_alpha");
13                 if(default_player_alpha <= 0)
14                         default_player_alpha = 1;
15         }
16 }
17
18 void GotoFirstMap()
19 {
20         if(cvar("_sv_init"))
21         {
22                 cvar_set("_sv_init", "0");
23                 tokenize(cvar_string("g_maplist"));
24                 if(argv(0) != GetMapname())
25                 {
26                         cvar_set("nextmap", argv(0));
27                         GotoNextMap();
28                 }
29         }
30 }
31
32 void worldspawn (void)
33 {
34
35         // Precache all player models
36         // Workaround for "invisible players"
37         precache_model("models/player/carni.zym");
38         precache_model("models/player/crash.zym");
39         precache_model("models/player/grunt.zym");
40         precache_model("models/player/headhunter.zym");
41         precache_model("models/player/insurrectionist.zym");
42         precache_model("models/player/jeandarc.zym");
43         precache_model("models/player/lurk.zym");
44         precache_model("models/player/lycanthrope.zym");
45         precache_model("models/player/marine.zym");
46         precache_model("models/player/nexus.zym");
47         precache_model("models/player/pyria.zym");
48         precache_model("models/player/shock.zym");
49         precache_model("models/player/skadi.zym");
50         precache_model("models/player/specop.zym");
51         precache_model("models/player/visitant.zym");
52
53         //precache_model ("progs/beam.mdl");
54         precache_model ("models/bullet.mdl");
55         precache_model ("models/casing_bronze.mdl");
56         precache_model ("models/casing_shell.mdl");
57         precache_model ("models/casing_steel.mdl");
58         precache_model ("models/ebomb.mdl");
59         precache_model ("models/elaser.mdl");
60         precache_model ("models/flash.md3");
61         precache_model ("models/gibs/bloodyskull.md3");
62         precache_model ("models/gibs/chunk.mdl");
63         precache_model ("models/gibs/eye.md3");
64         precache_model ("models/gibs/gib1.md3");
65         //precache_model ("models/gibs/gib2.md3");
66         //precache_model ("models/gibs/gib3.md3");
67         //precache_model ("models/gibs/gib4.md3");
68         precache_model ("models/gibs/gib5.md3");
69         //precache_model ("models/gibs/gib6.md3");
70         precache_model ("models/gibs/gib1.mdl");
71         precache_model ("models/gibs/gib2.mdl");
72         precache_model ("models/gibs/gib3.mdl");
73         precache_model ("models/grenademodel.md3");
74         precache_model ("models/hagarmissile.mdl");
75         precache_model ("models/items/a_bullets.mdl");
76         precache_model ("models/items/a_cells.md3");
77         precache_model ("models/items/a_rockets.md3");
78         precache_model ("models/items/a_shells.md3");
79         precache_model ("models/items/g_a1.md3");
80         precache_model ("models/items/g_a25.md3");
81         precache_model ("models/items/g_h1.md3");
82         precache_model ("models/items/g_h25.md3");
83         precache_model ("models/items/g_h100.md3");
84         precache_model ("models/items/g_invincible.md3");
85         precache_model ("models/items/g_strength.md3");
86         precache_model ("models/laser.mdl");
87         precache_model ("models/misc/chatbubble.spr");
88         precache_model ("models/misc/teambubble.spr");
89         precache_model ("models/nexflash.md3");
90         precache_model ("models/plasma.mdl");
91         precache_model ("models/plasmatrail.mdl");
92         precache_model ("models/rocket.md3");
93         //precache_model ("models/sprites/grenexpl.spr");
94         precache_model ("models/runematch/rune.mdl");
95         precache_model ("models/runematch/curse.mdl");
96         //precache_model ("models/sprites/hagar.spr");
97         //precache_model ("models/sprites/muzzleflash.spr32");
98         //precache_model ("models/sprites/electrocombo.spr32");
99         //precache_model ("models/sprites/plasmahitwall.spr32");
100         //precache_model ("models/sprites/plasmashot.spr32");
101         //precache_model ("models/sprites/rockexpl.spr");
102         precache_model ("models/tracer.mdl");
103         precache_model ("models/uziflash.md3");
104         precache_model ("models/weapons/g_crylink.md3");
105         precache_model ("models/weapons/g_electro.md3");
106         precache_model ("models/weapons/g_gl.md3");
107         precache_model ("models/weapons/g_hagar.md3");
108         precache_model ("models/weapons/g_nex.md3");
109         precache_model ("models/weapons/g_rl.md3");
110         precache_model ("models/weapons/g_shotgun.md3");
111         precache_model ("models/weapons/g_uzi.md3");
112         precache_model ("models/weapons/v_crylink.md3");
113         precache_model ("models/weapons/v_electro.md3");
114         precache_model ("models/weapons/v_gl.md3");
115         precache_model ("models/weapons/v_hagar.md3");
116         precache_model ("models/weapons/v_laser.md3");
117         precache_model ("models/weapons/v_nex.md3");
118         precache_model ("models/weapons/v_rl.md3");
119         precache_model ("models/weapons/v_shotgun.md3");
120         precache_model ("models/weapons/v_uzi.md3");
121         precache_model ("models/weapons/w_crylink.zym");
122         precache_model ("models/weapons/w_electro.zym");
123         precache_model ("models/weapons/w_gl.zym");
124         precache_model ("models/weapons/w_hagar.zym");
125         precache_model ("models/weapons/w_laser.zym");
126         precache_model ("models/weapons/w_nex.zym");
127         precache_model ("models/weapons/w_rl.zym");
128         precache_model ("models/weapons/w_shotgun.zym");
129         precache_model ("models/weapons/w_uzi.zym");
130
131         // laser for laser-guided weapons
132         precache_model ("models/laser_dot.mdl");
133
134         precache_sound ("misc/null.wav");
135         precache_sound ("misc/armor1.wav");
136         precache_sound ("misc/armor25.wav");
137         precache_sound ("misc/armorimpact.wav");
138         precache_sound ("misc/bodyimpact1.wav");
139         precache_sound ("misc/bodyimpact2.wav");
140         precache_sound ("misc/gib.wav");
141         precache_sound ("misc/gib_splat01.wav");
142         precache_sound ("misc/gib_splat02.wav");
143         precache_sound ("misc/gib_splat03.wav");
144         precache_sound ("misc/gib_splat04.wav");
145         //precache_sound ("misc/h2ohit.wav");
146         precache_sound ("misc/hit.wav");
147         precache_sound ("misc/footstep01.wav");
148         precache_sound ("misc/footstep02.wav");
149         precache_sound ("misc/footstep03.wav");
150         precache_sound ("misc/footstep04.wav");
151         precache_sound ("misc/footstep05.wav");
152         precache_sound ("misc/footstep06.wav");
153         precache_sound ("misc/hitground1.ogg");
154         precache_sound ("misc/hitground2.ogg");
155         precache_sound ("misc/hitground3.ogg");
156         precache_sound ("misc/hitground4.ogg");
157         precache_sound ("misc/itempickup.ogg");
158         precache_sound ("misc/itemrespawn.ogg");
159         precache_sound ("misc/jumppad.ogg");
160         precache_sound ("misc/mediumhealth.ogg");
161         precache_sound ("misc/megahealth.ogg");
162         precache_sound ("misc/minihealth.ogg");
163         precache_sound ("misc/powerup.ogg");
164         precache_sound ("misc/powerup_shield.ogg");
165         precache_sound ("misc/talk.wav");
166         precache_sound ("misc/teleport.ogg");
167         precache_sound ("plats/medplat1.wav");
168         precache_sound ("plats/medplat2.wav");
169         precache_sound ("player/lava.wav");
170         precache_sound ("player/slime.wav");
171         precache_sound ("weapons/crylink_fire.ogg");
172         precache_sound ("weapons/electro_bounce.ogg");
173         precache_sound ("weapons/electro_fire.ogg");
174         precache_sound ("weapons/electro_fire2.ogg");
175         precache_sound ("weapons/electro_fly.wav");
176         precache_sound ("weapons/electro_impact.ogg");
177         precache_sound ("weapons/electro_impact_combo.ogg");
178         //precache_sound ("weapons/grenade_bounce.ogg");
179         precache_sound ("weapons/grenade_bounce1.ogg");
180         precache_sound ("weapons/grenade_bounce2.ogg");
181         precache_sound ("weapons/grenade_bounce3.ogg");
182         precache_sound ("weapons/grenade_fire.ogg");
183         precache_sound ("weapons/grenade_impact.ogg");
184         precache_sound ("weapons/hagar_fire.ogg");
185         precache_sound ("weapons/hagexp1.ogg");
186         precache_sound ("weapons/hagexp2.ogg");
187         precache_sound ("weapons/hagexp3.ogg");
188         precache_sound ("weapons/hook_fire.ogg");
189         precache_sound ("weapons/hook_impact.ogg");
190         precache_sound ("weapons/lasergun_fire.ogg");
191         precache_sound ("weapons/laserimpact.ogg");
192         precache_sound ("weapons/nexfire.ogg");
193         precache_sound ("weapons/neximpact.ogg");
194         precache_sound ("weapons/ric1.ogg");
195         precache_sound ("weapons/ric2.ogg");
196         precache_sound ("weapons/ric3.ogg");
197         precache_sound ("weapons/rocket_fire.ogg");
198         precache_sound ("weapons/rocket_fly.wav");
199         precache_sound ("weapons/rocket_impact.ogg");
200         precache_sound ("weapons/rocket_det.ogg");
201         precache_sound ("weapons/shotgun_fire.ogg");
202         precache_sound ("weapons/tink1.ogg");
203         precache_sound ("weapons/uzi_fire.ogg");
204         precache_sound ("weapons/weapon_switch.ogg");
205         precache_sound ("weapons/weaponpickup.ogg");
206         precache_sound ("weapons/strength_fire.ogg");
207
208         //precache_sound ("announce/male/kill10.ogg");
209         //precache_sound ("announce/male/kill15.ogg");
210         //precache_sound ("announce/male/kill20.ogg");
211         //precache_sound ("announce/male/kill25.ogg");
212         //precache_sound ("announce/male/kill3.ogg");
213         //precache_sound ("announce/male/kill30.ogg");
214         //precache_sound ("announce/male/kill4.ogg");
215         //precache_sound ("announce/male/kill5.ogg");
216         //precache_sound ("announce/male/kill6.ogg");
217         //precache_sound ("announce/male/mapkill1.ogg");
218         //precache_sound ("announce/robotic/last_second_save.ogg");
219         //precache_sound ("announce/robotic/narrowly_averted.ogg");
220         //precache_sound ("minstagib/mockery.ogg");
221
222         // announcer sounds - male
223         precache_sound ("announcer/male/03kills.ogg");
224         precache_sound ("announcer/male/05kills.ogg");
225         precache_sound ("announcer/male/10kills.ogg");
226         precache_sound ("announcer/male/15kills.ogg");
227         precache_sound ("announcer/male/20kills.ogg");
228         precache_sound ("announcer/male/25kills.ogg");
229         precache_sound ("announcer/male/30kills.ogg");
230         precache_sound ("announcer/male/botlike.ogg");
231         precache_sound ("announcer/male/electrobitch.ogg");
232         precache_sound ("announcer/male/welcome.ogg");
233         precache_sound ("announcer/male/yoda.ogg");
234
235         // announcer sounds - robotic
236         precache_sound ("announcer/robotic/1fragleft.ogg");
237         precache_sound ("announcer/robotic/1minuteremains.ogg");
238         precache_sound ("announcer/robotic/2fragsleft.ogg");
239         precache_sound ("announcer/robotic/3fragsleft.ogg");
240         precache_sound ("announcer/robotic/lastsecond.ogg");
241         precache_sound ("announcer/robotic/narrowly.ogg");
242
243         // plays music for the level if there is any
244         if (self.noise)
245         {
246                 precache_sound (self.noise);
247                 ambientsound ('0 0 0', self.noise, 1.00, ATTN_NONE);
248         }
249
250                 // 0 normal
251         lightstyle(0, "m");
252
253         // 1 FLICKER (first variety)
254         lightstyle(1, "mmnmmommommnonmmonqnmmo");
255
256         // 2 SLOW STRONG PULSE
257         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
258
259         // 3 CANDLE (first variety)
260         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
261
262         // 4 FAST STROBE
263         lightstyle(4, "mamamamamama");
264
265         // 5 GENTLE PULSE 1
266         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
267
268         // 6 FLICKER (second variety)
269         lightstyle(6, "nmonqnmomnmomomno");
270
271         // 7 CANDLE (second variety)
272         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
273
274         // 8 CANDLE (third variety)
275         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
276
277         // 9 SLOW STROBE (fourth variety)
278         lightstyle(9, "aaaaaaaazzzzzzzz");
279
280         // 10 FLUORESCENT FLICKER
281         lightstyle(10, "mmamammmmammamamaaamammma");
282
283         // 11 SLOW PULSE NOT FADE TO BLACK
284         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
285
286         // styles 32-62 are assigned by the light program for switchable lights
287
288         // 63 testing
289         lightstyle(63, "a");
290
291         player_count = 0;
292         lms_dead_count = 0;
293         lms_lowest_lives = 0;
294         lms_next_place = 0;
295
296         GotoFirstMap();
297
298         if(cvar("g_campaign"))
299                 CampaignPreInit();
300
301         InitGameplayMode();
302         //if (cvar("g_domination"))
303         //      dom_init();
304
305         local entity head;
306         head = nextent(world);
307         maxclients = 0;
308         while(head)
309         {
310                 maxclients++;
311                 head = nextent(head);
312         }
313
314         GameLogInit(); // prepare everything
315         if(cvar("sv_eventlog"))
316         {
317                 local string s;
318                 GameLogEcho(":logversion:2", FALSE);
319                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
320                 s = strcat(s, ftos(random()));
321                 GameLogEcho(strcat(":gamestart:", GetMapname(), ":", s), FALSE);
322                 s = ":gameinfo:mutators:LIST";
323                 if(cvar("g_grappling_hook"))
324                         s = strcat(s, ":grappling_hook");
325                 if(!cvar("g_use_ammunition"))
326                         s = strcat(s, ":no_use_ammunition");
327                 if(!cvar("g_pickup_items"))
328                         s = strcat(s, ":no_pickup_items");
329                 if(cvar("g_instagib"))
330                         s = strcat(s, ":instagib");
331                 if(cvar("g_rocketarena"))
332                         s = strcat(s, ":rockerarena");
333                 if(cvar("g_nixnex"))
334                         s = strcat(s, ":nixnex");
335                 if(cvar("g_vampire"))
336                         s = strcat(s, ":vampire");
337                 if(cvar("g_laserguided_missile"))
338                         s = strcat(s, ":laserguided_missile");
339                 if(cvar("g_norecoil"))
340                         s = strcat(s, ":norecoil");
341                 if(cvar("g_midair"))
342                         s = strcat(s, ":midair");
343                 if(cvar("g_minstagib"))
344                         s = strcat(s, ":minstagib");
345                 GameLogEcho(s, FALSE);
346                 GameLogEcho(":gameinfo:end", FALSE);
347         }
348
349         cvar_set("nextmap", "");
350
351         SetDefaultAlpha();
352
353         if(cvar("g_campaign"))
354                 CampaignPostInit();
355 }
356
357 void light (void)
358 {
359         makestatic (self);
360 }
361
362 float( string pFilename ) TryFile =
363 {
364         local float lHandle;
365         dprint("TryFile(\"", pFilename, "\")\n");
366         lHandle = fopen( pFilename, FILE_READ );
367         if( lHandle != -1 ) {
368                 fclose( lHandle );
369                 return TRUE;
370         } else {
371                 return FALSE;
372         }
373 };
374
375 string GetMapname()
376 {
377         if (game == GAME_DEATHMATCH)
378                 return strcat("dm_", mapname);
379         else if (game == GAME_TEAM_DEATHMATCH)
380                 return strcat("tdm_", mapname);
381         else if (game == GAME_DOMINATION)
382                 return strcat("dom_", mapname);
383         else if (game == GAME_CTF)
384                 return strcat("ctf_", mapname);
385         else if (game == GAME_RUNEMATCH)
386                 return strcat("rune_", mapname);
387         else if (game == GAME_LMS)
388                 return strcat("lms_", mapname);
389         return strcat("dm_", mapname);
390 }
391
392 float GetMaplistPosition()
393 {
394         float pos, f;
395         string map, s;
396
397         map = strzone(GetMapname());
398         pos = 0;
399         f = tokenize(cvar_string("g_maplist"));
400
401         while(pos < f)
402         {
403                 s = strzone(argv(pos));
404                 if(s == map)
405                 {
406                         strunzone(s);
407                         strunzone(map);
408                         return pos;
409                 }
410                 strunzone(s);
411                 pos++;
412         }
413
414         strunzone(map);
415         // resume normal maplist rotation if current map is not in g_maplist
416         return cvar("g_maplist_index");
417 }
418
419 void() GotoNextMap =
420 {
421         //local string nextmap;
422         //local float n, nummaps;
423         //local string s;
424         string exit_cfg;
425         if (alreadychangedlevel)
426                 return;
427         alreadychangedlevel = TRUE;
428
429         if(cvar("g_campaign"))
430         {
431                 CampaignPostIntermission();
432                 return;
433         }
434
435         if (cvar("samelevel")) // if samelevel is set, stay on same level
436         {
437                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
438                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
439                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
440                 localcmd("restart\n");
441                 //changelevel (mapname);
442                 return;
443         }
444
445         // if an exit cfg is defined by exiting map, exec it.
446         exit_cfg = cvar_string("exit_cfg");
447         if(exit_cfg != "")
448                 localcmd(strcat("exec \"", exit_cfg, "\"\n"));
449
450         ResetGameCvars();
451
452
453         if (cvar("lastlevel"))
454         {
455                 localcmd(strcat("set lastlevel 0\n"));
456                 localcmd(strcat("togglemenu\n"));
457         }
458         else
459         {
460                 // method 0
461                 local float lCurrent;
462                 local float lSize;
463                 local float lOldCurrent;
464                 local float lBeforeCurrent;
465                 local float pass;
466
467                 if(TryFile(strcat("maps/", cvar_string("nextmap"), ".mapcfg")))
468                 {
469                         localcmd(strcat("exec \"maps/", cvar_string("nextmap"), ".mapcfg\"\n"));
470                         return;
471                 }
472
473                 pass = 0;
474                 while (pass < 2)
475                 {
476                         pass = pass + 1;
477                         local string temp;
478                         temp = cvar_string( "g_maplist" );
479                         if(temp == "")
480                         {
481                                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
482                                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
483                                 temp = cvar_string( "g_maplist" );
484                         }
485                         temp = strzone(temp);
486                         dprint("g_maplist is ", temp, "\n");
487                         lCurrent = max(0, GetMaplistPosition());
488                         lSize = tokenize( temp );
489                         lOldCurrent = lCurrent;
490                         dprint(ftos(lOldCurrent), " / ", ftos(lSize), " (start)\n");
491
492                         // if we want a random map selection...
493                         if(cvar("g_maplist_selectrandom") && lSize > 1)
494                         {
495                                 lBeforeCurrent = lCurrent - 1;
496                                 if(lBeforeCurrent < 0)
497                                         lBeforeCurrent = lSize - 1;
498                                 lCurrent = ceil(random() * (lSize - 1)) - 1; // random in 0..lsize-2
499                                 if(lCurrent >= lBeforeCurrent)
500                                         lCurrent += 1;
501                                 // choose any map except for the current one
502                         }
503
504                         while( 1 ) {
505                                 local string lFilename;
506
507                                 lCurrent = lCurrent + 1;
508                                 dprint(ftos(lCurrent), " / ", ftos(lSize), "\n");
509                                 if( lCurrent >= lSize ) {
510                                         lCurrent = 0;
511                                 }
512                                 if( lOldCurrent == lCurrent ) {
513                                         // we couldn't find a valid map at all
514                                         if (pass == 1)
515                                         {
516                                                 bprint( "Maplist is bad/messed up. Not one good mapcfg can be found in it!  Resetting it to default map list.\n" );
517                                                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
518                                                 // let the loop restart with the default list now
519                                         }
520                                         else
521                                         {
522                                                 bprint( "Both g_maplist and g_maplist_defaultlist are messed up!  Complain to developers!\n" );
523                                                 localcmd( "disconnect\n" );
524                                         }
525                                         break;
526                                 }
527
528                                 cvar_set( "g_maplist_index", ftos( lCurrent ) );
529
530                                 lFilename = strcat( "maps/", argv( lCurrent ), ".mapcfg" );
531                                 if( TryFile( lFilename ) ) {
532                                         localcmd(strcat("exec \"", lFilename ,"\"\n"));
533                                         pass = 2; // exit the outer loop
534                                         break;
535                                 } else {
536                                         dprint( "Couldn't find '", lFilename, "'..\n" );
537                                 }
538                                 //changelevel( argv( lCurrent ) );
539                         }
540                         strunzone(temp);
541                 }
542
543                 /*
544                 // method 1
545
546                 //local entity pos;
547                 local float fh;
548                 local string line;
549
550                 // restart current map if no cycle is found
551                 nextmap = strzone(mapname);
552                 fh = fopen("maplist.cfg", FILE_READ);
553                 if (fh >= 0)
554                 {
555                         while (1)
556                         {
557                                 line = fgets(fh);
558                                 if (nextmap == mapname)
559                                 {
560                                         strunzone(nextmap);
561                                         nextmap = strzone(line);
562                                 }
563                                 if (!line)
564                                         break;
565                                 if (line == mapname)
566                                 {
567                                         line = fgets(fh);
568                                         if (!line)
569                                                 break;
570                                         strunzone(nextmap);
571                                         nextmap = strzone(line);
572                                         break;
573                                 }
574                         }
575                         fclose(fh);
576                 }
577                 changelevel (nextmap);
578                 strunzone(nextmap);*/
579
580                 // method 3
581                 /*
582                 s = cvar_string("g_maplist");
583                 nummaps = tokenize(s);
584                 // if no map list, restart current one
585                 nextmap = mapname;
586                 if (nummaps >= 1)
587                 {
588                         n = 0;
589                         while (n < nummaps)
590                         {
591                                 if (argv(n) == mapname)
592                                         break;
593                                 n = n + 1;
594                         }
595                         n = n + 1;
596                         if (n >= nummaps)
597                                 n = 0;
598                         nextmap = argv(n);
599                 }
600                 changelevel (nextmap);
601                 */
602         }
603 };
604
605
606 /*
607 ============
608 IntermissionThink
609
610 When the player presses attack or jump, change to the next level
611 ============
612 */
613 void() IntermissionThink =
614 {
615         if (time < intermission_exittime)
616                 return;
617
618         if (time < intermission_exittime + 10 && !self.button0 && !self.button1 && !self.button2 && !self.button3)
619                 return;
620
621         GotoNextMap ();
622 };
623
624 /*
625 ============
626 FindIntermission
627
628 Returns the entity to view from
629 ============
630 */
631 /*
632 entity() FindIntermission =
633 {
634         local   entity spot;
635         local   float cyc;
636
637 // look for info_intermission first
638         spot = find (world, classname, "info_intermission");
639         if (spot)
640         {       // pick a random one
641                 cyc = random() * 4;
642                 while (cyc > 1)
643                 {
644                         spot = find (spot, classname, "info_intermission");
645                         if (!spot)
646                                 spot = find (spot, classname, "info_intermission");
647                         cyc = cyc - 1;
648                 }
649                 return spot;
650         }
651
652 // then look for the start position
653         spot = find (world, classname, "info_player_start");
654         if (spot)
655                 return spot;
656
657 // testinfo_player_start is only found in regioned levels
658         spot = find (world, classname, "testplayerstart");
659         if (spot)
660                 return spot;
661
662 // then look for the start position
663         spot = find (world, classname, "info_player_deathmatch");
664         if (spot)
665                 return spot;
666
667         //objerror ("FindIntermission: no spot");
668         return world;
669 };
670 */
671
672 /*
673 ===============================================================================
674
675 RULES
676
677 ===============================================================================
678 */
679
680 void() DumpStats =
681 {
682         local float file;
683         local string s;
684
685         if(cvar("_printstats"))
686                 cvar_set("_printstats", "0");
687         else if(!gameover)
688                 return;
689
690         if(gameover)
691                 s = ":scores:";
692         else
693                 s = ":status:";
694
695         s = strcat(s, GetMapname(), ":", ftos(rint(time)));
696
697         if(cvar("sv_eventlog") && gameover)
698                 GameLogEcho(s, FALSE);
699         else if(cvar("sv_logscores_console"))
700                 ServerConsoleEcho(s, FALSE);
701         if(cvar("sv_logscores_file"))
702         {
703                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
704                 fputs(file, strcat(s, "\n"));
705         }
706
707         other = findchainflags(flags, FL_CLIENT);
708         while (other)
709         {
710                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
711                 {
712                         s = strcat(":player:", ftos(other.frags), ":");
713                         s = strcat(s, ftos(other.deaths), ":");
714                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
715                         s = strcat(s, ftos(other.team), ":");
716
717                         if(cvar("sv_logscores_file"))
718                                 fputs(file, strcat(s, other.netname, "\n"));
719                         if(cvar("sv_eventlog") && gameover)
720                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname), TRUE);
721                         else if(cvar("sv_logscores_console"))
722                                 ServerConsoleEcho(strcat(s, other.netname), TRUE);
723                 }
724                 other = other.chain;
725         }
726
727         if(cvar("sv_eventlog") && gameover)
728                 GameLogEcho(":end", FALSE);
729         else if(cvar("sv_logscores_console"))
730                 ServerConsoleEcho(":end", FALSE);
731         if(cvar("sv_logscores_file"))
732         {
733                 fputs(file, ":end\n");
734                 fclose(file);
735         }
736 }
737
738
739 /*
740 go to the next level for deathmatch
741 only called if a time or frag limit has expired
742 */
743 void() NextLevel =
744 {
745         gameover = TRUE;
746
747         intermission_running = 1;
748
749 // enforce a wait time before allowing changelevel
750         if(player_count > 0)
751                 intermission_exittime = time + cvar("sv_mapchange_delay");
752         else
753                 intermission_exittime = -60;
754
755         WriteByte (MSG_ALL, SVC_CDTRACK);
756         WriteByte (MSG_ALL, 3);
757         WriteByte (MSG_ALL, 3);
758
759         //pos = FindIntermission ();
760
761         VoteReset();
762
763         DumpStats();
764
765         if(cvar("sv_eventlog"))
766                 GameLogEcho(":gameover", FALSE);
767
768         GameLogClose();
769
770         other = findchainflags(flags, FL_CLIENT);
771         while (other != world)
772         {
773                 //other.nextthink = time + 0.5;
774                 other.takedamage = DAMAGE_NO;
775                 other.solid = SOLID_NOT;
776                 other.movetype = MOVETYPE_NONE;
777                 other.angles = other.v_angle;
778                 other.angles_x = other.angles_x * -1;
779
780                 self = other;
781
782                 if(other.winning)
783                         bprint(strcat(other.netname, " ^7wins.\n"));
784
785                 /*
786                 if (pos != world);
787                 {
788                         other.modelindex = 0;
789                         other.weaponentity = world; // remove weapon model
790                         other.view_ofs = '0 0 0';
791                         other.angles = other.v_angle = pos.mangle;
792                         if (!other.angles)
793                         {
794                                 other.angles = other.v_angle = pos.angles;
795                                 other.v_angle_x = other.v_angle_x * -1;
796                         }
797                         other.fixangle = TRUE;          // turn this way immediately
798                         setorigin (other, pos.origin);
799                 }
800                 */
801                 other = other.chain;
802         }
803
804         if(cvar("g_campaign"))
805                 CampaignPreIntermission();
806
807         WriteByte (MSG_ALL, SVC_INTERMISSION);
808
809         other = findchainflags(flags, FL_CLIENT);
810         while(other)
811         {
812                 if(clienttype(other) == CLIENTTYPE_REAL)
813                 if(cvar("sv_autoscreenshot"))
814                         stuffcmd(other, "wait\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
815                 other = other.chain;
816         }
817 };
818
819 /*
820 ============
821 CheckRules_Player
822
823 Exit deathmatch games upon conditions
824 ============
825 */
826 void() CheckRules_Player =
827 {
828         if (gameover)   // someone else quit the game already
829                 return;
830
831         // fixme: don't check players; instead check dom_team and ctf_team entities
832         //   (div0: and that in CheckRules_World please)
833         centermsg_check();
834 };
835
836 float checkrules_oneminutewarning;
837 float checkrules_leaderfrags;
838 float tdm_max_score, tdm_old_score;
839
840 float checkrules_equality;
841 float checkrules_overtimewarning;
842 float checkrules_overtimeend;
843
844 void() InitiateOvertime =
845 {
846         if(!checkrules_overtimeend)
847                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
848 }
849
850 float WINNING_NO = 0; // no winner, but time limits may terminate the game
851 float WINNING_YES = 1; // winner found
852 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
853 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
854
855 float(float fraglimitreached, float equality) GetWinningCode =
856 {
857         if(equality)
858                 if(fraglimitreached)
859                         return WINNING_STARTOVERTIME;
860                 else
861                         return WINNING_NEVER;
862         else
863                 if(fraglimitreached)
864                         return WINNING_YES;
865                 else
866                         return WINNING_NO;
867 }
868
869 // set the .winning flag for exactly those players with a given field value
870 void(.float field, float value) SetWinners =
871 {
872         entity head;
873         head = findchain(classname, "player");
874         while (head)
875         {
876                 head.winning = (head.field == value);
877                 head = head.chain;
878         }
879 }
880
881 // set the .winning flag for those players with a given field value
882 void(.float field, float value) AddWinners =
883 {
884         entity head;
885         head = findchain(classname, "player");
886         while (head)
887         {
888                 if(head.field == value)
889                         head.winning = 1;
890                 head = head.chain;
891         }
892 }
893
894 // clear the .winning flags
895 void(void) ClearWinners =
896 {
897         entity head;
898         head = findchain(classname, "player");
899         while (head)
900         {
901                 head.winning = 0;
902                 head = head.chain;
903         }
904 }
905
906 // LMS winning condition: game terminates if and only if there's at most one
907 // one player who's living lives. Top two scores being equal cancels the time
908 // limit.
909 float() WinningCondition_LMS =
910 {
911         entity head;
912
913         if(lms_dead_count < 0)
914                 lms_dead_count = 0;
915
916         if(player_count > 1 && lms_dead_count >= player_count - 1)
917                 return WINNING_YES; // He's the last man standing!
918
919         if((player_count == 1 && lms_dead_count == 1))
920                 return WINNING_YES; // All dead... (n:n is handled by the test above)
921
922         // When we get here, we have at least two players who are actually LIVING,
923         // or one player who is still waiting for a victim to join the server. Now
924         // check if the top two players have equal score.
925
926         checkrules_leaderfrags = 0;
927         head = findchain(classname, "player");
928         checkrules_equality = FALSE;
929         while (head)
930         {
931                 if(head.frags > checkrules_leaderfrags)
932                 {
933                         checkrules_leaderfrags = head.frags;
934                         checkrules_equality = FALSE;
935                 }
936                 else if(head.frags > 0 && head.frags == checkrules_leaderfrags)
937                         checkrules_equality = TRUE;
938                 head = head.chain;
939         }
940
941         SetWinners(frags, checkrules_leaderfrags);
942
943         // The top two players have the same amount of lives? No timelimit then,
944         // enter overtime...
945
946         if(checkrules_equality)
947                 return WINNING_NEVER;
948
949         // Top two have different scores? Way to go for our beloved TIMELIMIT!
950         return WINNING_NO;
951 }
952
953 // DM winning condition: game terminates if a player reached the fraglimit,
954 // unless the first two players have the same score. The latter case also
955 // breaks the time limit.
956 float(float fraglimit) WinningCondition_MaxIndividualScore =
957 {
958         float checkrules_oldleaderfrags;
959         entity head;
960
961         checkrules_oldleaderfrags = checkrules_leaderfrags;
962         checkrules_leaderfrags = 0;
963         head = findchain(classname, "player");
964         checkrules_equality = FALSE;
965         while (head)
966         {
967                 if(head.frags > checkrules_leaderfrags)
968                 {
969                         checkrules_leaderfrags = head.frags;
970                         checkrules_equality = FALSE;
971                 }
972                 else if(head.frags > 0 && head.frags == checkrules_leaderfrags)
973                         checkrules_equality = TRUE;
974                 head = head.chain;
975         }
976
977         SetWinners(frags, checkrules_leaderfrags);
978
979         if (!cvar("g_runematch"))
980                 if (checkrules_leaderfrags != checkrules_oldleaderfrags)
981                 {
982                         if (checkrules_leaderfrags == fraglimit - 1)
983                                 sound(world, CHAN_AUTO, "announcer/robotic/1fragleft.ogg", 1, ATTN_NONE);
984                         else if (checkrules_leaderfrags == fraglimit - 2)
985                                 sound(world, CHAN_AUTO, "announcer/robotic/2fragsleft.ogg", 1, ATTN_NONE);
986                         else if (checkrules_leaderfrags == fraglimit - 3)
987                                 sound(world, CHAN_AUTO, "announcer/robotic/3fragsleft.ogg", 1, ATTN_NONE);
988                 }
989
990         return GetWinningCode(fraglimit && checkrules_leaderfrags >= fraglimit, checkrules_equality);
991 }
992
993 float(float fraglimit) WinningConditionBase_Teamplay =
994 {
995         tdm_old_score = tdm_max_score;
996         tdm_max_score = max(team1_score, team2_score, team3_score, team4_score);
997
998         checkrules_equality =
999         (
1000                 (tdm_max_score > 0)
1001                 &&
1002                 (
1003                           (team1_score == tdm_max_score)
1004                         + (team2_score == tdm_max_score)
1005                         + (team3_score == tdm_max_score)
1006                         + (team4_score == tdm_max_score)
1007                         >= 2));
1008
1009         ClearWinners();
1010         if(team1_score == tdm_max_score)
1011                 AddWinners(team, COLOR_TEAM1);
1012         if(team2_score == tdm_max_score)
1013                 AddWinners(team, COLOR_TEAM2);
1014         if(team3_score == tdm_max_score)
1015                 AddWinners(team, COLOR_TEAM3);
1016         if(team4_score == tdm_max_score)
1017                 AddWinners(team, COLOR_TEAM4);
1018
1019         if(!cvar("g_runematch") && !cvar("g_domination"))
1020                 if(tdm_max_score != tdm_old_score)
1021                 {
1022                         if(tdm_max_score == fraglimit - 1)
1023                                 sound(world, CHAN_AUTO, "announcer/robotic/1fragleft.ogg", 1, ATTN_NONE);
1024                         else if(tdm_max_score == fraglimit - 2)
1025                                 sound(world, CHAN_AUTO, "announcer/robotic/2fragsleft.ogg", 1, ATTN_NONE);
1026                         else if(tdm_max_score == fraglimit - 3)
1027                                 sound(world, CHAN_AUTO, "announcer/robotic/3fragsleft.ogg", 1, ATTN_NONE);
1028                 }
1029
1030         return GetWinningCode(fraglimit && tdm_max_score >= fraglimit, checkrules_equality);
1031 }
1032
1033 // TDM winning condition: game terminates if a team's score sum reached the
1034 // fraglimit, unless the first two teams have the same total score. The latter
1035 // case also breaks the time limit.
1036 float(float fraglimit) WinningCondition_MaxTeamSum =
1037 {
1038         entity head;
1039
1040         team1_score = team2_score = team3_score = team4_score = 0;
1041
1042         head = findchain(classname, "player");
1043         while (head)
1044         {
1045                 if(head.team == COLOR_TEAM1)
1046                         team1_score += head.frags;
1047                 else if(head.team == COLOR_TEAM2)
1048                         team2_score += head.frags;
1049                 else if(head.team == COLOR_TEAM3)
1050                         team3_score += head.frags;
1051                 else if(head.team == COLOR_TEAM4)
1052                         team4_score += head.frags;
1053                 head = head.chain;
1054         }
1055
1056         return WinningConditionBase_Teamplay(fraglimit);
1057 }
1058
1059 // DOM/CTF winning condition: game terminates if the max of a team's players'
1060 // score reached the fraglimit, unless the first two teams have the same
1061 // maximum score. The latter case also breaks the time limit.
1062 float(float fraglimit) WinningCondition_MaxTeamMax =
1063 {
1064         entity head;
1065
1066         team1_score = team2_score = team3_score = team4_score = 0;
1067
1068         head = findchain(classname, "player");
1069         while (head)
1070         {
1071                 if(head.team == COLOR_TEAM1)
1072                 {
1073                         if(head.frags > team1_score)
1074                                 team1_score = head.frags;
1075                 }
1076                 else if(head.team == COLOR_TEAM2)
1077                 {
1078                         if(head.frags > team2_score)
1079                                 team2_score = head.frags;
1080                 }
1081                 else if(head.team == COLOR_TEAM3)
1082                 {
1083                         if(head.frags > team3_score)
1084                                 team3_score = head.frags;
1085                 }
1086                 else if(head.team == COLOR_TEAM4)
1087                 {
1088                         if(head.frags > team4_score)
1089                                 team4_score = head.frags;
1090                 }
1091                 head = head.chain;
1092         }
1093
1094         return WinningConditionBase_Teamplay(fraglimit);
1095 }
1096
1097
1098 /*
1099 ============
1100 CheckRules_World
1101
1102 Exit deathmatch games upon conditions
1103 ============
1104 */
1105 void() CheckRules_World =
1106 {
1107         local float status;
1108         local float timelimit;
1109         local float fraglimit;
1110
1111         VoteThink();
1112
1113         SetDefaultAlpha();
1114
1115         if (intermission_running)
1116                 if (time >= intermission_exittime + 60)
1117                 {
1118                         GotoNextMap();
1119                         return;
1120                 }
1121
1122         if (gameover)   // someone else quit the game already
1123                 return;
1124
1125         DumpStats();
1126
1127         timelimit = cvar("timelimit") * 60;
1128         fraglimit = cvar("fraglimit");
1129
1130         if (timelimit && time >= timelimit)
1131                 InitiateOvertime();
1132
1133         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1134         {
1135                 NextLevel();
1136                 return;
1137         }
1138
1139         if(!checkrules_overtimewarning && checkrules_overtimeend)
1140         {
1141                 checkrules_overtimewarning = TRUE;
1142                 //sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.ogg", 1, ATTN_NONE);
1143                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1144         }
1145
1146         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1147         {
1148                 checkrules_oneminutewarning = TRUE;
1149                 sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.ogg", 1, ATTN_NONE);
1150         }
1151
1152         status = WINNING_NO;
1153         if(cvar("g_lms"))
1154         {
1155                 status = WinningCondition_LMS();
1156         }
1157         else
1158         {
1159                 if(teams_matter)
1160                 {
1161                         if(cvar("g_tdm") || cvar("g_runematch") || cvar("g_ctf") || cvar("g_domination"))
1162                                 status = WinningCondition_MaxTeamSum(fraglimit);
1163                         //else if()
1164                         //      status = WinningCondition_MaxTeamMax(fraglimit);
1165                         else
1166                         {
1167                                 dprint("div0: How can this happen?\n");
1168                                 status = WinningCondition_MaxTeamMax(fraglimit);
1169                         }
1170                 }
1171                 else
1172                         status = WinningCondition_MaxIndividualScore(fraglimit);
1173         }
1174
1175         if(status == WINNING_STARTOVERTIME)
1176         {
1177                 status = WINNING_NEVER;
1178                 InitiateOvertime();
1179         }
1180
1181         if(checkrules_overtimeend)
1182                 if(status != WINNING_NEVER)
1183                         status = WINNING_YES;
1184
1185         if(status == WINNING_YES)
1186                 NextLevel();
1187 };