data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 float GotoFirstMap()
 135 {
 136         if(cvar("_sv_init"))
 137         {
 138                 cvar_set("_sv_init", "0");
 139                 if(cvar("g_maplist_shuffle"))
 140                         ShuffleMaplist();
 141                 tokenizebyseparator(cvar_string("g_maplist"), " ");
 142                 {
 143                         cvar_set("nextmap", argv(0));
 144
 145                         MapInfo_Enumerate();
 146                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 0);
 147
 148                         if(!DoNextMapOverride())
 149                                 GotoNextMap();
 150
 151                         return 1;
 152                 }
 153         }
 154         return 0;
 155 }
 156
 157 void cvar_changes_init()
 158 {
 159         float h;
 160         string k, v, d;
 161         float n, i;
 162
 163         if(cvar_changes)
 164                 strunzone(cvar_changes);
 165         cvar_changes = string_null;
 166
 167         h = buf_create();
 168         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 169         n = buf_getsize(h);
 170
 171         for(i = 0; i < n; ++i)
 172         {
 173                 k = bufstr_get(h, i);
 174
 175 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 176 #define BADCVAR(p) if(k == p) continue
 177                 // internal
 178                 BADPREFIX("csqc_");
 179                 BADPREFIX("cvar_check_");
 180                 BADCVAR("gamecfg");
 181                 BADCVAR("g_configversion");
 182                 BADCVAR("g_maplist_index");
 183                 BADCVAR("halflifebsp");
 184
 185                 // client
 186                 BADPREFIX("cl_");
 187                 BADPREFIX("con_");
 188                 BADPREFIX("g_campaign");
 189                 BADPREFIX("gl_");
 190                 BADPREFIX("joy");
 191                 BADPREFIX("menu_");
 192                 BADPREFIX("net_slist_");
 193                 BADPREFIX("r_");
 194                 BADPREFIX("sbar_");
 195                 BADPREFIX("scr_");
 196                 BADPREFIX("userbind");
 197                 BADPREFIX("v_");
 198                 BADPREFIX("vid_");
 199                 BADCVAR("mod_q3bsp_lightmapmergepower");
 200                 BADCVAR("mod_q3bsp_nolightmaps");
 201
 202                 // private
 203                 BADPREFIX("g_ban_");
 204                 BADPREFIX("g_chat_flood_");
 205                 BADPREFIX("rcon_");
 206                 BADPREFIX("settemp_");
 207                 BADPREFIX("sv_allowdownloads_");
 208                 BADPREFIX("sv_autodemo");
 209                 BADPREFIX("sv_curl_");
 210                 BADPREFIX("sv_eventlog");
 211                 BADPREFIX("sv_logscores_");
 212                 BADPREFIX("sv_master");
 213                 BADCVAR("g_banned_list");
 214                 BADCVAR("log_dest_udp");
 215                 BADCVAR("log_file");
 216                 BADCVAR("net_address");
 217                 BADCVAR("port");
 218                 BADCVAR("savedgamecfg");
 219                 BADCVAR("sv_heartbeatperoid");
 220                 BADCVAR("sv_vote_master_password");
 221                 BADCVAR("sys_colortranslation");
 222                 BADCVAR("sys_specialcharactertranslation");
 223                 BADCVAR("timestamps");
 224
 225                 // mapinfo
 226                 BADCVAR("timelimit");
 227                 BADCVAR("fraglimit");
 228                 BADCVAR("g_arena");
 229                 BADCVAR("g_assault");
 230                 BADCVAR("g_ctf");
 231                 BADCVAR("g_dm");
 232                 BADCVAR("g_domination");
 233                 BADCVAR("g_keyhunt");
 234                 BADCVAR("g_keyhunt_teams");
 235                 BADCVAR("g_onslaught");
 236                 BADCVAR("g_race");
 237                 BADCVAR("g_runematch");
 238                 BADCVAR("g_tdm");
 239                 BADCVAR("teamplay");
 240
 241                 // long
 242                 BADCVAR("hostname");
 243                 BADCVAR("g_maplist");
 244                 BADCVAR("g_maplist_mostrecent");
 245                 BADCVAR("sv_motd");
 246 #undef BADPREFIX
 247 #undef BADCVAR
 248
 249                 v = cvar_string(k);
 250                 d = cvar_defstring(k);
 251                 if(v != d)
 252                 {
 253                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 254                         if(strlen(cvar_changes) > 16384)
 255                         {
 256                                 cvar_changes = "// too many settings have been changed to show them here\n";
 257                                 break;
 258                         }
 259                 }
 260         }
 261         buf_del(h);
 262         if(cvar_changes == "")
 263                 cvar_changes = "// this server runs at default settings\n";
 264         else
 265                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 266         cvar_changes = strzone(cvar_changes);
 267 }
 268
 269 void detect_maptype()
 270 {
 271 #if 0
 272         vector o, v;
 273         float i;
 274
 275         for(;;)
 276         {
 277                 o = world.mins;
 278                 o_x += random() * (world.maxs_x - world.mins_x);
 279                 o_y += random() * (world.maxs_y - world.mins_y);
 280                 o_z += random() * (world.maxs_z - world.mins_z);
 281
 282                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 283                 if(trace_fraction == 1)
 284                         continue;
 285
 286                 v = trace_endpos;
 287
 288                 for(i = 0; i < 64; i += 4)
 289                 {
 290                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 291         if(trace_fraction == 1)
 292                 continue;
 293                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 294                 }
 295
 296                 break;
 297         }
 298 #endif
 299 }
 300
 301 entity randomseed;
 302 float RandomSeed_Send(entity to, float sf)
 303 {
 304         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 305         WriteShort(MSG_ENTITY, self.cnt);
 306         return TRUE;
 307 }
 308 void RandomSeed_Think()
 309 {
 310         self.cnt = bound(0, floor(random() * 65536), 65535);
 311         self.nextthink = time + 5;
 312 }
 313 void RandomSeed_Spawn()
 314 {
 315         randomseed = spawn();
 316         randomseed.think = RandomSeed_Think;
 317         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 318
 319         entity oldself;
 320         oldself = self;
 321         self = randomseed;
 322         self.think(); // sets random seed and nextthink
 323         self = oldself;
 324 }
 325
 326 float world_already_spawned;
 327 void RegisterWeapons();
 328 void Nagger_Init();
 329 void ClientInit_Spawn();
 330 void spawnfunc_worldspawn (void)
 331 {
 332         float fd, l, i, j, n;
 333         string s, col;
 334
 335         dprint_load(); // load dprint status from cvar
 336
 337         if(world_already_spawned)
 338                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 339         world_already_spawned = TRUE;
 340
 341         remove = remove_safely; // during spawning, watch what you remove!
 342
 343         if(cvar_string("cvar_check_default") != "bypass")
 344         {
 345                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 346                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code!");
 347
 348                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 349                         error("Config file mismatch! Please update weapons.cfg and weaponsPro.cfg to match the QuakeC code!");
 350         }
 351
 352         compressShortVector_init();
 353
 354         local entity head;
 355         head = nextent(world);
 356         maxclients = 0;
 357         while(head)
 358         {
 359                 ++maxclients;
 360                 head = nextent(head);
 361         }
 362
 363         // needs to be done so early as they would still spawn
 364         RegisterWeapons();
 365
 366         if(GotoFirstMap())
 367         {
 368                 world_initialized = -1; // don't complain
 369                 return;
 370         }
 371
 372         if(sv_cheats)
 373                 ServerProgsDB = db_create();
 374         else
 375                 ServerProgsDB = db_load("server.db");
 376
 377         TemporaryDB = db_create();
 378
 379         /*
 380         TODO sound pack system
 381         // initialize sound pack system
 382         soundpack = cvar_string("g_soundpack");
 383         if(soundpack != "")
 384                 soundpack = strcat(soundpack, "/");
 385         soundpack = strzone(soundpack);
 386         */
 387
 388         // 0 normal
 389         lightstyle(0, "m");
 390
 391         // 1 FLICKER (first variety)
 392         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 393
 394         // 2 SLOW STRONG PULSE
 395         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 396
 397         // 3 CANDLE (first variety)
 398         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 399
 400         // 4 FAST STROBE
 401         lightstyle(4, "mamamamamama");
 402
 403         // 5 GENTLE PULSE 1
 404         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 405
 406         // 6 FLICKER (second variety)
 407         lightstyle(6, "nmonqnmomnmomomno");
 408
 409         // 7 CANDLE (second variety)
 410         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 411
 412         // 8 CANDLE (third variety)
 413         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 414
 415         // 9 SLOW STROBE (fourth variety)
 416         lightstyle(9, "aaaaaaaazzzzzzzz");
 417
 418         // 10 FLUORESCENT FLICKER
 419         lightstyle(10, "mmamammmmammamamaaamammma");
 420
 421         // 11 SLOW PULSE NOT FADE TO BLACK
 422         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 423
 424         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 425
 426         // 63 testing
 427         lightstyle(63, "a");
 428
 429         if(cvar("g_campaign"))
 430                 CampaignPreInit();
 431
 432         InitGameplayMode();
 433         readlevelcvars();
 434         GrappleHookInit();
 435
 436         player_count = 0;
 437         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 438         if(bot_waypoints_for_items == 1)
 439                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 440                         bot_waypoints_for_items = 0;
 441
 442         // for setting by mapinfo
 443         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 444         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 445
 446         precache();
 447
 448         WaypointSprite_Init();
 449
 450         //if (g_domination)
 451         //      dom_init();
 452
 453         GameLogInit(); // prepare everything
 454         if(cvar("sv_eventlog"))
 455         {
 456                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 457                 s = strcat(s, ftos(random()));
 458                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 459                 s = ":gameinfo:mutators:LIST";
 460                 if(cvar("g_grappling_hook"))
 461                         s = strcat(s, ":grappling_hook");
 462                 if(!cvar("g_use_ammunition"))
 463                         s = strcat(s, ":no_use_ammunition");
 464                 if(!cvar("g_pickup_items"))
 465                         s = strcat(s, ":no_pickup_items");
 466                 if(cvar("g_instagib"))
 467                         s = strcat(s, ":instagib");
 468                 if(cvar_string("g_weaponarena") != "0")
 469                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 470                 if(cvar("g_nixnex"))
 471                         s = strcat(s, ":nixnex");
 472                 if(cvar("g_vampire"))
 473                         s = strcat(s, ":vampire");
 474                 if(cvar("g_laserguided_missile"))
 475                         s = strcat(s, ":laserguided_missile");
 476                 if(cvar("g_norecoil"))
 477                         s = strcat(s, ":norecoil");
 478                 if(cvar("g_midair"))
 479                         s = strcat(s, ":midair");
 480                 if(cvar("g_minstagib"))
 481                         s = strcat(s, ":minstagib");
 482                 GameLogEcho(s);
 483                 GameLogEcho(":gameinfo:end");
 484         }
 485
 486         cvar_set("nextmap", "");
 487
 488         SetDefaultAlpha();
 489
 490         if(cvar("g_campaign"))
 491                 CampaignPostInit();
 492
 493         fteqcc_testbugs();
 494
 495         Ban_LoadBans();
 496
 497         //initialise globals related to sv_timeout
 498         sys_ticrate = cvar("sys_ticrate");
 499         orig_slowmo = cvar("slowmo");
 500
 501         MapInfo_Enumerate();
 502         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
 503
 504         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 505         {
 506                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 507                 if(fd != -1)
 508                 {
 509                         while((s = fgets(fd)))
 510                         {
 511                                 l = tokenize_sane(s);
 512                                 if(l < 2)
 513                                         continue;
 514                                 if(argv(0) == "cd")
 515                                 {
 516                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 517                                         print("  cdtrack ", argv(2), "\n");
 518                                 }
 519                                 else if(argv(0) == "fog")
 520                                 {
 521                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 522                                         print("  \"fog\" \"", s, "\"\n");
 523                                 }
 524                                 else if(argv(0) == "set")
 525                                 {
 526                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 527                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 528                                 }
 529                                 else if(argv(0) != "//")
 530                                 {
 531                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 532                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 533                                 }
 534                         }
 535                         fclose(fd);
 536                 }
 537         }
 538
 539         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 540         addstat(STAT_WEAPONS, AS_INT, weapons);
 541         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 542         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 543         Nagger_Init();
 544
 545         next_pingtime = time + 5;
 546         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 547
 548         detect_maptype();
 549
 550         lsmaps_reply = "^7Maps available: ";
 551         for(i = 0, j = 0; i < MapInfo_count; ++i)
 552         {
 553                 if(MapInfo_Get_ByID(i))
 554                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 555                         {
 556                                 if(mod(i, 2))
 557                                         col = "^2";
 558                                 else
 559                                         col = "^3";
 560                                 ++j;
 561                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 562                         }
 563         }
 564         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 565
 566         maplist_reply = "^7Maps in list: ";
 567         n = tokenize_sane(cvar_string("g_maplist"));
 568         for(i = 0, j = 0; i < n; ++i)
 569         {
 570                 if(MapInfo_CheckMap(argv(i)))
 571                 {
 572                         if(mod(j, 2))
 573                                 col = "^2";
 574                         else
 575                                 col = "^3";
 576                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 577                         ++j;
 578                 }
 579         }
 580         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 581
 582         records_reply = strzone(getrecords());
 583
 584         ClientInit_Spawn();
 585         RandomSeed_Spawn();
 586
 587         world_initialized = 1;
 588 }
 589
 590 void spawnfunc_light (void)
 591 {
 592         //makestatic (self); // Who the f___ did that?
 593         remove(self);
 594 }
 595
 596 float TryFile( string pFilename )
 597 {
 598         local float lHandle;
 599         dprint("TryFile(\"", pFilename, "\")\n");
 600         lHandle = fopen( pFilename, FILE_READ );
 601         if( lHandle != -1 ) {
 602                 fclose( lHandle );
 603                 return TRUE;
 604         } else {
 605                 return FALSE;
 606         }
 607 };
 608
 609 string GetGametype()
 610 {
 611         return GametypeNameFromType(game);
 612 }
 613
 614 string getmapname_stored;
 615 string GetMapname()
 616 {
 617         return mapname;
 618 }
 619
 620 float Map_Count, Map_Current;
 621 string Map_Current_Name;
 622
 623 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 624 float GetMaplistPosition()
 625 {
 626         float pos, idx;
 627         string map;
 628
 629         map = GetMapname();
 630         idx = cvar("g_maplist_index");
 631
 632         if(idx >= 0)
 633                 if(idx < Map_Count)
 634                         if(map == argv(idx))
 635                                 return idx;
 636
 637         for(pos = 0; pos < Map_Count; ++pos)
 638                 if(map == argv(pos))
 639                         return pos;
 640
 641         // resume normal maplist rotation if current map is not in g_maplist
 642         return idx;
 643 }
 644
 645 float MapHasRightSize(string map)
 646 {
 647         float fh;
 648         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 649         if(cvar("g_maplist_check_waypoints"))
 650         {
 651                 dprint("checkwp "); dprint(map);
 652                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 653                 if(fh < 0)
 654                 {
 655                         dprint(": no waypoints\n");
 656                         return FALSE;
 657                 }
 658                 dprint(": has waypoints\n");
 659                 fclose(fh);
 660         }
 661
 662         // open map size restriction file
 663         dprint("opensize "); dprint(map);
 664         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 665         if(fh >= 0)
 666         {
 667                 float mapmin, mapmax;
 668                 dprint(": ok, ");
 669                 mapmin = stof(fgets(fh));
 670                 mapmax = stof(fgets(fh));
 671                 fclose(fh);
 672                 if(player_count < mapmin)
 673                 {
 674                         dprint("not enough\n");
 675                         return FALSE;
 676                 }
 677                 if(player_count > mapmax)
 678                 {
 679                         dprint("too many\n");
 680                         return FALSE;
 681                 }
 682                 dprint("right size\n");
 683                 return TRUE;
 684         }
 685         dprint(": not found\n");
 686         return TRUE;
 687 }
 688
 689 string Map_Filename(float position)
 690 {
 691         return strcat("maps/", argv(position), ".bsp");
 692 }
 693
 694 string strwords(string s, float w)
 695 {
 696         float endpos;
 697         for(endpos = 0; w && endpos >= 0; --w)
 698                 endpos = strstrofs(s, " ", endpos + 1);
 699         if(endpos < 0)
 700                 return s;
 701         else
 702                 return substring(s, 0, endpos);
 703 }
 704
 705 float strhasword(string s, string w)
 706 {
 707         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 708 }
 709
 710 void Map_MarkAsRecent(string m)
 711 {
 712         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), cvar("g_maplist_mostrecent_count")));
 713 }
 714
 715 float Map_IsRecent(string m)
 716 {
 717         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 718 }
 719
 720 float Map_Check(float position, float pass)
 721 {
 722         string filename;
 723         string map_next;
 724         map_next = argv(position);
 725         if(pass <= 1)
 726         {
 727                 if(map_next == Map_Current_Name) // same map again in first pass?
 728                         return 0;
 729                 if(Map_IsRecent(map_next))
 730                         return 0;
 731         }
 732         filename = Map_Filename(position);
 733         if(MapInfo_CheckMap(map_next))
 734         {
 735                 if(pass == 2)
 736                         return 1;
 737                 if(MapHasRightSize(map_next))
 738                         return 1;
 739                 return 0;
 740         }
 741         else
 742                 dprint( "Couldn't select '", filename, "'..\n" );
 743
 744         return 0;
 745 }
 746
 747 void Map_Goto_SetStr(string nextmapname)
 748 {
 749         if(getmapname_stored != "")
 750                 strunzone(getmapname_stored);
 751         if(nextmapname == "")
 752                 getmapname_stored = "";
 753         else
 754                 getmapname_stored = strzone(nextmapname);
 755 }
 756
 757 void Map_Goto_SetFloat(float position)
 758 {
 759         cvar_set("g_maplist_index", ftos(position));
 760         Map_Goto_SetStr(argv(position));
 761 }
 762
 763 void GameResetCfg()
 764 {
 765         // settings persist, except...
 766         if(cvar("g_campaign"))
 767                 localcmd("\nexec mutator_reset.cfg\n");
 768         localcmd("\nsettemp_restore\n");
 769 };
 770
 771 void Map_Goto()
 772 {
 773         Map_MarkAsRecent(getmapname_stored);
 774         GameResetCfg();
 775         MapInfo_LoadMap(getmapname_stored);
 776 }
 777
 778 // return codes of map selectors:
 779 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 780 //   -2 = permanent failure
 781 float() MaplistMethod_Iterate = // usual method
 782 {
 783         float pass, i;
 784
 785         for(pass = 1; pass <= 2; ++pass)
 786         {
 787                 for(i = 1; i < Map_Count; ++i)
 788                 {
 789                         float mapindex;
 790                         mapindex = mod(i + Map_Current, Map_Count);
 791                         if(Map_Check(mapindex, pass))
 792                                 return mapindex;
 793                 }
 794         }
 795         return -1;
 796 }
 797
 798 float() MaplistMethod_Repeat = // fallback method
 799 {
 800         if(Map_Check(Map_Current, 2))
 801                 return Map_Current;
 802         return -2;
 803 }
 804
 805 float() MaplistMethod_Random = // random map selection
 806 {
 807         float i, imax;
 808
 809         imax = 42;
 810
 811         for(i = 0; i <= imax; ++i)
 812         {
 813                 float mapindex;
 814                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 815                 if(Map_Check(mapindex, 1))
 816                         return mapindex;
 817         }
 818         return -1;
 819 }
 820
 821 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 822 // the exponent sets a bias on the map selection:
 823 // the higher the exponent, the less likely "shortly repeated" same maps are
 824 {
 825         float i, j, imax, insertpos;
 826
 827         imax = 42;
 828
 829         for(i = 0; i <= imax; ++i)
 830         {
 831                 string newlist;
 832
 833                 // now reinsert this at another position
 834                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 835                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 836                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 837                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 838
 839                 // insert the current map there
 840                 newlist = "";
 841                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 842                         newlist = strcat(newlist, " ", argv(j));
 843                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 844                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 845                         newlist = strcat(newlist, " ", argv(j));
 846                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 847                 cvar_set("g_maplist", newlist);
 848                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 849
 850                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 851                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 852                 if(Map_Check(Map_Current, 1))
 853                         return Map_Current;
 854         }
 855         return -1;
 856 }
 857
 858 void Maplist_Init()
 859 {
 860         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 861         if(Map_Count == 0)
 862         {
 863                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 864                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 865                 if(cvar("g_maplist_shuffle"))
 866                         ShuffleMaplist();
 867                 localcmd("\nmenu_cmd sync\n");
 868                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 869         }
 870         if(Map_Count == 0)
 871                 error("empty maplist, cannot select a new map");
 872         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 873
 874         if(Map_Current_Name)
 875                 strunzone(Map_Current_Name);
 876         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 877         // this may or may not be correct, but who cares, in the worst case a map
 878         // isn't chosen in the first pass that should have been
 879 }
 880
 881 string GetNextMap()
 882 {
 883         float nextMap;
 884
 885         Maplist_Init();
 886         nextMap = -1;
 887
 888         if(nextMap == -1)
 889                 if(cvar("g_maplist_shuffle") > 0)
 890                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 891
 892         if(nextMap == -1)
 893                 if(cvar("g_maplist_selectrandom"))
 894                         nextMap = MaplistMethod_Random();
 895
 896         if(nextMap == -1)
 897                 nextMap = MaplistMethod_Iterate();
 898
 899         if(nextMap == -1)
 900                 nextMap = MaplistMethod_Repeat();
 901
 902         if(nextMap >= 0)
 903         {
 904                 Map_Goto_SetFloat(nextMap);
 905                 return getmapname_stored;
 906         }
 907
 908         return "";
 909 };
 910
 911 float DoNextMapOverride()
 912 {
 913         if(cvar("g_campaign"))
 914         {
 915                 CampaignPostIntermission();
 916                 alreadychangedlevel = TRUE;
 917                 return TRUE;
 918         }
 919         if(cvar("quit_when_empty"))
 920         {
 921                 if(player_count <= currentbots)
 922                 {
 923                         localcmd("quit\n");
 924                         alreadychangedlevel = TRUE;
 925                         return TRUE;
 926                 }
 927         }
 928         if(cvar_string("quit_and_redirect") != "")
 929         {
 930                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 931                 alreadychangedlevel = TRUE;
 932                 return TRUE;
 933         }
 934         if (cvar("samelevel")) // if samelevel is set, stay on same level
 935         {
 936                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 937                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 938                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 939                 localcmd("restart\n");
 940                 //changelevel (mapname);
 941                 alreadychangedlevel = TRUE;
 942                 return TRUE;
 943         }
 944         if(cvar_string("nextmap") != "")
 945                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 946                 {
 947                         Map_Goto_SetStr(cvar_string("nextmap"));
 948                         Map_Goto();
 949                         alreadychangedlevel = TRUE;
 950                         return TRUE;
 951                 }
 952         if(cvar("lastlevel"))
 953         {
 954                 GameResetCfg();
 955                 localcmd("set lastlevel 0\ntogglemenu\n");
 956                 alreadychangedlevel = TRUE;
 957                 return TRUE;
 958         }
 959         return FALSE;
 960 };
 961
 962 void GotoNextMap()
 963 {
 964         //local string nextmap;
 965         //local float n, nummaps;
 966         //local string s;
 967         if (alreadychangedlevel)
 968                 return;
 969         alreadychangedlevel = TRUE;
 970
 971         {
 972                 string nextMap;
 973                 float allowReset;
 974
 975                 for(allowReset = 1; allowReset >= 0; --allowReset)
 976                 {
 977                         nextMap = GetNextMap();
 978                         if(nextMap != "")
 979                                 break;
 980
 981                         if(allowReset)
 982                         {
 983                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 984                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 985                                 if(cvar("g_maplist_shuffle"))
 986                                         ShuffleMaplist();
 987                                 localcmd("\nmenu_cmd sync\n");
 988                         }
 989                         else
 990                         {
 991                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 992                         }
 993                 }
 994                 Map_Goto();
 995         }
 996 };
 997
 998
 999 /*
1000 ============
1001 IntermissionThink
1002
1003 When the player presses attack or jump, change to the next level
1004 ============
1005 */
1006 .float autoscreenshot;
1007 void() MapVote_Start;
1008 void() MapVote_Think;
1009 float mapvote_initialized;
1010 void IntermissionThink()
1011 {
1012         FixIntermissionClient(self);
1013
1014         if(cvar("sv_autoscreenshot"))
1015         if(self.autoscreenshot > 0)
1016         if(time > self.autoscreenshot)
1017         {
1018                 self.autoscreenshot = -1;
1019                 if(clienttype(self) == CLIENTTYPE_REAL)
1020                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1021                 return;
1022         }
1023
1024         if (time < intermission_exittime)
1025                 return;
1026
1027         if(!mapvote_initialized)
1028                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1029                         return;
1030
1031         MapVote_Start();
1032 };
1033
1034 /*
1035 ============
1036 FindIntermission
1037
1038 Returns the entity to view from
1039 ============
1040 */
1041 /*
1042 entity FindIntermission()
1043 {
1044         local   entity spot;
1045         local   float cyc;
1046
1047 // look for info_intermission first
1048         spot = find (world, classname, "info_intermission");
1049         if (spot)
1050         {       // pick a random one
1051                 cyc = random() * 4;
1052                 while (cyc > 1)
1053                 {
1054                         spot = find (spot, classname, "info_intermission");
1055                         if (!spot)
1056                                 spot = find (spot, classname, "info_intermission");
1057                         cyc = cyc - 1;
1058                 }
1059                 return spot;
1060         }
1061
1062 // then look for the start position
1063         spot = find (world, classname, "info_player_start");
1064         if (spot)
1065                 return spot;
1066
1067 // testinfo_player_start is only found in regioned levels
1068         spot = find (world, classname, "testplayerstart");
1069         if (spot)
1070                 return spot;
1071
1072 // then look for the start position
1073         spot = find (world, classname, "info_player_deathmatch");
1074         if (spot)
1075                 return spot;
1076
1077         //objerror ("FindIntermission: no spot");
1078         return world;
1079 };
1080 */
1081
1082 /*
1083 ===============================================================================
1084
1085 RULES
1086
1087 ===============================================================================
1088 */
1089
1090 void DumpStats(float final)
1091 {
1092         local float file;
1093         local string s;
1094         local float to_console;
1095         local float to_eventlog;
1096         local float to_file;
1097         local float i;
1098
1099         to_console = cvar("sv_logscores_console");
1100         to_eventlog = cvar("sv_eventlog");
1101         to_file = cvar("sv_logscores_file");
1102
1103         if(!final)
1104         {
1105                 to_console = TRUE; // always print printstats replies
1106                 to_eventlog = FALSE; // but never print them to the event log
1107         }
1108
1109         if(to_eventlog)
1110                 if(cvar("sv_eventlog_console"))
1111                         to_console = FALSE; // otherwise we get the output twice
1112
1113         if(final)
1114                 s = ":scores:";
1115         else
1116                 s = ":status:";
1117         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1118
1119         if(to_console)
1120                 print(s, "\n");
1121         if(to_eventlog)
1122                 GameLogEcho(s);
1123         if(to_file)
1124         {
1125                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1126                 if(file == -1)
1127                         to_file = FALSE;
1128                 else
1129                         fputs(file, strcat(s, "\n"));
1130         }
1131
1132         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1133         if(to_console)
1134                 print(s, "\n");
1135         if(to_eventlog)
1136                 GameLogEcho(s);
1137         if(to_file)
1138                 fputs(file, strcat(s, "\n"));
1139
1140         FOR_EACH_CLIENT(other)
1141         {
1142                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1143                 {
1144                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1145                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1146                         if(other.classname == "player" || g_arena || g_lms)
1147                                 s = strcat(s, ftos(other.team), ":");
1148                         else
1149                                 s = strcat(s, "spectator:");
1150
1151                         if(to_console)
1152                                 print(s, other.netname, "\n");
1153                         if(to_eventlog)
1154                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1155                         if(to_file)
1156                                 fputs(file, strcat(s, other.netname, "\n"));
1157                 }
1158         }
1159
1160         if(teamplay)
1161         {
1162                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1163                 if(to_console)
1164                         print(s, "\n");
1165                 if(to_eventlog)
1166                         GameLogEcho(s);
1167                 if(to_file)
1168                         fputs(file, strcat(s, "\n"));
1169
1170                 for(i = 1; i < 16; ++i)
1171                 {
1172                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1173                         s = strcat(s, ":", ftos(i));
1174                         if(to_console)
1175                                 print(s, "\n");
1176                         if(to_eventlog)
1177                                 GameLogEcho(s);
1178                         if(to_file)
1179                                 fputs(file, strcat(s, "\n"));
1180                 }
1181         }
1182
1183         if(to_console)
1184                 print(":end\n");
1185         if(to_eventlog)
1186                 GameLogEcho(":end");
1187         if(to_file)
1188         {
1189                 fputs(file, ":end\n");
1190                 fclose(file);
1191         }
1192 }
1193
1194 void FixIntermissionClient(entity e)
1195 {
1196         string s;
1197         if(!e.autoscreenshot) // initial call
1198         {
1199                 e.angles = e.v_angle;
1200                 e.angles_x = -e.angles_x;
1201                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1202                 e.health = -2342;
1203                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1204                 e.solid = SOLID_NOT;
1205                 e.movetype = MOVETYPE_NONE;
1206                 e.takedamage = DAMAGE_NO;
1207                 if(e.weaponentity)
1208                         e.weaponentity.effects = EF_NODRAW;
1209                 if(clienttype(e) == CLIENTTYPE_REAL)
1210                 {
1211                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1212                         s = cvar_string("sv_intermission_cdtrack");
1213                         if(s != "")
1214                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1215                         msg_entity = e;
1216                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1217                 }
1218         }
1219
1220         //e.velocity = '0 0 0';
1221         //e.fixangle = TRUE;
1222
1223         // TODO halt weapon animation
1224 }
1225
1226
1227 /*
1228 go to the next level for deathmatch
1229 only called if a time or frag limit has expired
1230 */
1231 void NextLevel()
1232 {
1233         float minTotalFrags;
1234         float maxTotalFrags;
1235         float score;
1236         float f;
1237
1238         gameover = TRUE;
1239
1240         intermission_running = 1;
1241
1242 // enforce a wait time before allowing changelevel
1243         if(player_count > 0)
1244                 intermission_exittime = time + cvar("sv_mapchange_delay");
1245         else
1246                 intermission_exittime = -1;
1247
1248         /*
1249         WriteByte (MSG_ALL, SVC_CDTRACK);
1250         WriteByte (MSG_ALL, 3);
1251         WriteByte (MSG_ALL, 3);
1252         // done in FixIntermission
1253         */
1254
1255         //pos = FindIntermission ();
1256
1257         VoteReset();
1258
1259         DumpStats(TRUE);
1260
1261         if(cvar("sv_eventlog"))
1262                 GameLogEcho(":gameover");
1263
1264         GameLogClose();
1265
1266         FOR_EACH_CLIENT(other)
1267         {
1268                 FixIntermissionClient(other);
1269
1270                 if(other.winning)
1271                         bprint(other.netname, " ^7wins.\n");
1272         }
1273
1274         minTotalFrags = 0;
1275         maxTotalFrags = 0;
1276         FOR_EACH_PLAYER(other)
1277         {
1278                 if(maxTotalFrags < other.totalfrags)
1279                         maxTotalFrags = other.totalfrags;
1280                 if(minTotalFrags > other.totalfrags)
1281                         minTotalFrags = other.totalfrags;
1282         }
1283
1284         if(!currentbots)
1285         {
1286                 FOR_EACH_PLAYER(other)
1287                 {
1288                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1289                         f = bound(0, other.play_time / max(time, 1), 1);
1290                         // store some statistics?
1291                 }
1292         }
1293
1294         if(cvar("g_campaign"))
1295                 CampaignPreIntermission();
1296
1297         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1298 };
1299
1300 /*
1301 ============
1302 CheckRules_Player
1303
1304 Exit deathmatch games upon conditions
1305 ============
1306 */
1307 void CheckRules_Player()
1308 {
1309         if (gameover)   // someone else quit the game already
1310                 return;
1311
1312         if(self.deadflag == DEAD_NO)
1313                 self.play_time += frametime;
1314
1315         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1316         //   (div0: and that in CheckRules_World please)
1317 };
1318
1319 float checkrules_oneminutewarning;
1320
1321 float checkrules_equality;
1322 float checkrules_overtimewarning;
1323 float checkrules_overtimeend;
1324
1325 void InitiateOvertime()
1326 {
1327         if(!checkrules_overtimeend)
1328                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
1329 }
1330
1331 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1332 float WINNING_YES = 1; // winner found
1333 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1334 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
1335
1336 float GetWinningCode(float fraglimitreached, float equality)
1337 {
1338         if(equality)
1339                 if(fraglimitreached)
1340                         return WINNING_STARTOVERTIME;
1341                 else
1342                         return WINNING_NEVER;
1343         else
1344                 if(fraglimitreached)
1345                         return WINNING_YES;
1346                 else
1347                         return WINNING_NO;
1348 }
1349
1350 // set the .winning flag for exactly those players with a given field value
1351 void SetWinners(.float field, float value)
1352 {
1353         entity head;
1354         FOR_EACH_PLAYER(head)
1355                 head.winning = (head.field == value);
1356 }
1357
1358 // set the .winning flag for those players with a given field value
1359 void AddWinners(.float field, float value)
1360 {
1361         entity head;
1362         FOR_EACH_PLAYER(head)
1363                 if(head.field == value)
1364                         head.winning = 1;
1365 }
1366
1367 // clear the .winning flags
1368 void ClearWinners(void)
1369 {
1370         entity head;
1371         FOR_EACH_PLAYER(head)
1372                 head.winning = 0;
1373 }
1374
1375 // Onslaught winning condition:
1376 // game terminates if only one team has a working generator (or none)
1377 float WinningCondition_Onslaught()
1378 {
1379         entity head;
1380         local float t1, t2, t3, t4;
1381
1382         WinningConditionHelper(); // set worldstatus
1383
1384         // first check if the game has ended
1385         t1 = t2 = t3 = t4 = 0;
1386         head = find(world, classname, "onslaught_generator");
1387         while (head)
1388         {
1389                 if (head.health > 0)
1390                 {
1391                         if (head.team == COLOR_TEAM1) t1 = 1;
1392                         if (head.team == COLOR_TEAM2) t2 = 1;
1393                         if (head.team == COLOR_TEAM3) t3 = 1;
1394                         if (head.team == COLOR_TEAM4) t4 = 1;
1395                 }
1396                 head = find(head, classname, "onslaught_generator");
1397         }
1398         if (t1 + t2 + t3 + t4 < 2)
1399         {
1400                 // game over, only one team remains (or none)
1401                 ClearWinners();
1402                 if (t1) SetWinners(team, COLOR_TEAM1);
1403                 if (t2) SetWinners(team, COLOR_TEAM2);
1404                 if (t3) SetWinners(team, COLOR_TEAM3);
1405                 if (t4) SetWinners(team, COLOR_TEAM4);
1406                 dprint("Have a winner, ending game.\n");
1407                 return WINNING_YES;
1408         }
1409
1410         // Two or more teams remain
1411         return WINNING_NO;
1412 }
1413
1414 float LMS_NewPlayerLives()
1415 {
1416         float fl;
1417         fl = cvar("fraglimit");
1418         if(fl == 0)
1419                 fl = 999;
1420
1421         // first player has left the game for dying too much? Nobody else can get in.
1422         if(lms_lowest_lives < 1)
1423                 return 0;
1424
1425         if(!cvar("g_lms_join_anytime"))
1426                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1427                         return 0;
1428
1429         return bound(1, lms_lowest_lives, fl);
1430 }
1431
1432 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1433 // they win. Otherwise the defending team wins once the timelimit passes.
1434 void assault_new_round();
1435 float WinningCondition_Assault()
1436 {
1437         local float status;
1438
1439         WinningConditionHelper(); // set worldstatus
1440
1441         status = WINNING_NO;
1442         // as the timelimit has not yet passed just assume the defending team will win
1443         if(assault_attacker_team == COLOR_TEAM1)
1444         {
1445                 SetWinners(team, COLOR_TEAM2);
1446         }
1447         else
1448         {
1449                 SetWinners(team, COLOR_TEAM1);
1450         }
1451
1452         local entity ent;
1453         ent = find(world, classname, "target_assault_roundend");
1454         if(ent)
1455         {
1456                 if(ent.winning) // round end has been triggered by attacking team
1457                 {
1458                         bprint("ASSAULT: round completed...\n");
1459                         SetWinners(team, assault_attacker_team);
1460
1461                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1462
1463                         if(ent.cnt == 1) // this was the second round
1464                         {
1465                                 status = WINNING_YES;
1466                         }
1467                         else
1468                         {
1469                                 local entity oldself;
1470                                 oldself = self;
1471                                 self = ent;
1472                                 assault_new_round();
1473                                 self = oldself;
1474                         }
1475                 }
1476         }
1477
1478         return status;
1479 }
1480
1481 // LMS winning condition: game terminates if and only if there's at most one
1482 // one player who's living lives. Top two scores being equal cancels the time
1483 // limit.
1484 float WinningCondition_LMS()
1485 {
1486         entity head, head2;
1487         float have_player;
1488         float have_players;
1489         float l;
1490
1491         have_player = FALSE;
1492         have_players = FALSE;
1493         l = LMS_NewPlayerLives();
1494
1495         head = find(world, classname, "player");
1496         if(head)
1497                 have_player = TRUE;
1498         head2 = find(head, classname, "player");
1499         if(head2)
1500                 have_players = TRUE;
1501
1502         if(have_player)
1503         {
1504                 // we have at least one player
1505                 if(have_players)
1506                 {
1507                         // two or more active players - continue with the game
1508                 }
1509                 else
1510                 {
1511                         // exactly one player?
1512
1513                         ClearWinners();
1514                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1515
1516                         if(l)
1517                         {
1518                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1519                                 return WINNING_NO;
1520                         }
1521                         else
1522                         {
1523                                 // a winner!
1524                                 // and assign him his first place
1525                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1526                                 return WINNING_YES;
1527                         }
1528                 }
1529         }
1530         else
1531         {
1532                 // nobody is playing at all...
1533                 if(l)
1534                 {
1535                         // wait for players...
1536                 }
1537                 else
1538                 {
1539                         // SNAFU (maybe a draw game?)
1540                         ClearWinners();
1541                         dprint("No players, ending game.\n");
1542                         return WINNING_YES;
1543                 }
1544         }
1545
1546         // When we get here, we have at least two players who are actually LIVING,
1547         // now check if the top two players have equal score.
1548         WinningConditionHelper();
1549
1550         ClearWinners();
1551         if(WinningConditionHelper_winner)
1552                 WinningConditionHelper_winner.winning = TRUE;
1553         if(WinningConditionHelper_equality)
1554                 return WINNING_NEVER;
1555
1556         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1557         return WINNING_NO;
1558 }
1559
1560 void ShuffleMaplist()
1561 {
1562         string result;
1563         float start;
1564         float litems;
1565         float selected;
1566         float i;
1567
1568         result = cvar_string("g_maplist");
1569         litems = tokenizebyseparator(result, " ");
1570
1571         for(start = 0; start < litems - 1; ++start)
1572         {
1573                 result = "";
1574
1575                 // select a random item
1576                 selected = floor(random() * (litems - start) + start);
1577
1578                 // shift this item to the place start
1579                 for(i = 0; i < start; ++i)
1580                         result = strcat(result, " ", argv(i));
1581                 result = strcat(result, " ", argv(selected));
1582                 for(i = start; i < litems; ++i)
1583                         if(i != selected)
1584                                 result = strcat(result, " ", argv(i));
1585                 result = substring(result, 1, strlen(result) - 1);
1586
1587                 litems = tokenizebyseparator(result, " ");
1588
1589                 //dprint(result, "\n");
1590         }
1591
1592         cvar_set("g_maplist", result);
1593 }
1594
1595 float leaderfrags;
1596 float WinningCondition_Scores(float limit)
1597 {
1598         // TODO make everything use THIS winning condition (except LMS)
1599         WinningConditionHelper();
1600
1601         if(teams_matter)
1602         {
1603                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1604                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1605                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1606                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1607         }
1608
1609         ClearWinners();
1610         if(WinningConditionHelper_winner)
1611                 WinningConditionHelper_winner.winning = 1;
1612         if(WinningConditionHelper_winnerteam >= 0)
1613                 SetWinners(team, WinningConditionHelper_winnerteam);
1614
1615         if(WinningConditionHelper_lowerisbetter)
1616         {
1617                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1618                 limit = -limit;
1619         }
1620
1621         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying))
1622         // these modes always score in increments of 1, thus this makes sense
1623         {
1624                 if(leaderfrags != WinningConditionHelper_topscore)
1625                 {
1626                         leaderfrags = WinningConditionHelper_topscore;
1627
1628                         if (limit)
1629                         if (leaderfrags == limit - 1)
1630                                 play2all("announcer/robotic/1fragleft.wav");
1631                         else if (leaderfrags == limit - 2)
1632                                 play2all("announcer/robotic/2fragsleft.wav");
1633                         else if (leaderfrags == limit - 3)
1634                                 play2all("announcer/robotic/3fragsleft.wav");
1635                 }
1636         }
1637
1638         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1639 }
1640
1641 float WinningCondition_Race(float fraglimit)
1642 {
1643         float wc;
1644         entity p;
1645         wc = WinningCondition_Scores(fraglimit);
1646
1647         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1648         if(wc == WINNING_YES || wc == WINNING_STARTOVERTIME)
1649         // do NOT support equality when the laps are all raced!
1650         {
1651                 FOR_EACH_PLAYER(p)
1652                         if not(p.race_completed)
1653                                 return WINNING_STARTOVERTIME;
1654                 return WINNING_YES;
1655         }
1656         return wc;
1657 }
1658
1659 void ReadyRestart();
1660 float WinningCondition_QualifyingThenRace(float limit)
1661 {
1662         float wc;
1663         wc = WinningCondition_Scores(limit);
1664
1665         // NEVER initiate overtime
1666         if(wc == WINNING_YES || wc == WINNING_STARTOVERTIME)
1667         {
1668                 return WINNING_YES;
1669         }
1670
1671         return wc;
1672 }
1673
1674 float WinningCondition_RanOutOfSpawns()
1675 {
1676         entity head;
1677
1678         if(!have_team_spawns)
1679                 return WINNING_NO;
1680
1681         if(!some_spawn_has_been_used)
1682                 return WINNING_NO;
1683
1684         team1_score = team2_score = team3_score = team4_score = 0;
1685
1686         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1687         {
1688                 if(head.team == COLOR_TEAM1)
1689                         team1_score = 1;
1690                 else if(head.team == COLOR_TEAM2)
1691                         team2_score = 1;
1692                 else if(head.team == COLOR_TEAM3)
1693                         team3_score = 1;
1694                 else if(head.team == COLOR_TEAM4)
1695                         team4_score = 1;
1696         }
1697
1698         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1699         {
1700                 if(head.team == COLOR_TEAM1)
1701                         team1_score = 1;
1702                 else if(head.team == COLOR_TEAM2)
1703                         team2_score = 1;
1704                 else if(head.team == COLOR_TEAM3)
1705                         team3_score = 1;
1706                 else if(head.team == COLOR_TEAM4)
1707                         team4_score = 1;
1708         }
1709
1710         ClearWinners();
1711         if(team1_score + team2_score + team3_score + team4_score == 0)
1712         {
1713                 checkrules_equality = TRUE;
1714                 return WINNING_YES;
1715         }
1716         else if(team1_score + team2_score + team3_score + team4_score == 1)
1717         {
1718                 float t, i;
1719                 if(team1_score) t = COLOR_TEAM1;
1720                 if(team2_score) t = COLOR_TEAM2;
1721                 if(team3_score) t = COLOR_TEAM3;
1722                 if(team4_score) t = COLOR_TEAM4;
1723                 CheckAllowedTeams(world);
1724                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1725                 {
1726                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1727                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1728                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1729                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1730                 }
1731
1732                 AddWinners(team, t);
1733                 return WINNING_YES;
1734         }
1735         else
1736                 return WINNING_NO;
1737 }
1738
1739 /*
1740 ============
1741 CheckRules_World
1742
1743 Exit deathmatch games upon conditions
1744 ============
1745 */
1746 void CheckRules_World()
1747 {
1748         local float status;
1749         local float timelimit;
1750         local float fraglimit;
1751
1752         VoteThink();
1753         MapVote_Think();
1754
1755         SetDefaultAlpha();
1756
1757         /*
1758         MapVote_Think should now do that part
1759         if (intermission_running)
1760                 if (time >= intermission_exittime + 60)
1761                 {
1762                         if(!DoNextMapOverride())
1763                                 GotoNextMap();
1764                         return;
1765                 }
1766         */
1767
1768         if (gameover)   // someone else quit the game already
1769         {
1770                 if(player_count == 0) // Nobody there? Then let's go to the next map
1771                         MapVote_Start();
1772                         // this will actually check the player count in the next frame
1773                         // again, but this shouldn't hurt
1774                 return;
1775         }
1776
1777         timelimit = cvar("timelimit") * 60;
1778         fraglimit = cvar("fraglimit");
1779
1780         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1781         {
1782                 if(timelimit > 0)
1783                         timelimit = 0; // timelimit is not made for warmup
1784                 if(fraglimit > 0)
1785                         fraglimit = 0; // no fraglimit for now
1786         }
1787
1788         if(timelimit > 0)
1789         {
1790                 timelimit += game_starttime;
1791         }
1792         else if (timelimit < 0)
1793         {
1794                 // endmatch
1795                 NextLevel();
1796                 return;
1797         }
1798
1799         if(checkrules_overtimeend)
1800         {
1801                 if(!checkrules_overtimewarning)
1802                 {
1803                         checkrules_overtimewarning = TRUE;
1804                         //announceall("announcer/robotic/1minuteremains.wav");
1805                         if(g_race && !g_race_qualifying)
1806                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1807                         else
1808                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1809                 }
1810         }
1811         else
1812         {
1813                 if (timelimit && time >= timelimit)
1814                 {
1815                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1816                         {
1817                                 float totalplayers;
1818                                 float playerswithlaps;
1819                                 float readyplayers;
1820                                 entity head;
1821                                 totalplayers = playerswithlaps = readyplayers = 0;
1822                                 FOR_EACH_PLAYER(head)
1823                                 {
1824                                         ++totalplayers;
1825                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1826                                                 ++playerswithlaps;
1827                                         if(head.ready)
1828                                                 ++readyplayers;
1829                                 }
1830
1831                                 // at least 2/3 of the players have completed a lap: start the RACE
1832                                 // otherwise, the players should end the qualifying on their own
1833                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1834                                 {
1835                                         checkrules_overtimeend = 0;
1836                                         ReadyRestart(); // go to race
1837                                 }
1838                                 else
1839                                         InitiateOvertime();
1840                         }
1841                         else
1842                                 InitiateOvertime();
1843                 }
1844         }
1845
1846         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1847         {
1848                 NextLevel();
1849                 return;
1850         }
1851
1852         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1853         {
1854                 checkrules_oneminutewarning = TRUE;
1855                 play2all("announcer/robotic/1minuteremains.wav");
1856         }
1857
1858         status = WinningCondition_RanOutOfSpawns();
1859         if(status == WINNING_YES)
1860         {
1861                 bprint("Hey! Someone ran out of spawns!\n");
1862         }
1863         else if(g_race && !g_race_qualifying && timelimit >= 0)
1864         {
1865                 status = WinningCondition_Race(fraglimit);
1866         }
1867         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1868         {
1869                 status = WinningCondition_QualifyingThenRace(fraglimit);
1870         }
1871         else if(g_assault)
1872         {
1873                 status = WinningCondition_Assault(); // TODO remove this?
1874         }
1875         else if(g_lms)
1876         {
1877                 status = WinningCondition_LMS();
1878         }
1879         else if (g_onslaught)
1880         {
1881                 status = WinningCondition_Onslaught(); // TODO remove this?
1882         }
1883         else
1884         {
1885                 status = WinningCondition_Scores(fraglimit);
1886         }
1887
1888         if(status == WINNING_STARTOVERTIME)
1889         {
1890                 status = WINNING_NEVER;
1891                 InitiateOvertime();
1892         }
1893
1894         if(status == WINNING_NEVER)
1895                 // equality cases! Nobody wins if the overtime ends in a draw.
1896                 ClearWinners();
1897
1898         if(checkrules_overtimeend)
1899                 if(status != WINNING_NEVER || time >= checkrules_overtimeend)
1900                         status = WINNING_YES;
1901
1902         if(status == WINNING_YES)
1903                 NextLevel();
1904 };
1905
1906 float mapvote_nextthink;
1907 float mapvote_initialized;
1908 float mapvote_keeptwotime;
1909 float mapvote_timeout;
1910 string mapvote_message;
1911 string mapvote_screenshot_dir;
1912
1913 float mapvote_count;
1914 float mapvote_count_real;
1915 string mapvote_maps[MAPVOTE_COUNT];
1916 float mapvote_maps_suggested[MAPVOTE_COUNT];
1917 string mapvote_suggestions[MAPVOTE_COUNT];
1918 float mapvote_suggestion_ptr;
1919 float mapvote_maxlen;
1920 float mapvote_voters;
1921 float mapvote_votes[MAPVOTE_COUNT];
1922 float mapvote_run;
1923 float mapvote_detail;
1924 float mapvote_abstain;
1925 .float mapvote;
1926
1927 void MapVote_ClearAllVotes()
1928 {
1929         FOR_EACH_CLIENT(other)
1930                 other.mapvote = 0;
1931 }
1932
1933 string MapVote_Suggest(string m)
1934 {
1935         float i;
1936         if(m == "")
1937                 return "That's not how to use this command.";
1938         if(!cvar("g_maplist_votable_suggestions"))
1939                 return "Suggestions are not accepted on this server.";
1940         if(mapvote_initialized)
1941                 return "Can't suggest - voting is already in progress!";
1942         m = MapInfo_FixName(m);
1943         if(!m)
1944                 return "The map you suggested is not available on this server.";
1945         if(!cvar("g_maplist_votable_override_mostrecent"))
1946                 if(Map_IsRecent(m))
1947                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1948
1949         if(!MapInfo_CheckMap(m))
1950                 return "The map you suggested does not support the current game mode.";
1951         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1952                 if(mapvote_suggestions[i] == m)
1953                         return "This map was already suggested.";
1954         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1955         {
1956                 i = floor(random() * mapvote_suggestion_ptr);
1957         }
1958         else
1959         {
1960                 i = mapvote_suggestion_ptr;
1961                 mapvote_suggestion_ptr += 1;
1962         }
1963         if(mapvote_suggestions[i] != "")
1964                 strunzone(mapvote_suggestions[i]);
1965         mapvote_suggestions[i] = strzone(m);
1966         if(cvar("sv_eventlog"))
1967                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
1968         return strcat("Suggestion of ", m, " accepted.");
1969 }
1970
1971 void MapVote_AddVotable(string nextMap, float isSuggestion)
1972 {
1973         float j;
1974         if(nextMap == "")
1975                 return;
1976         for(j = 0; j < mapvote_count; ++j)
1977                 if(mapvote_maps[j] == nextMap)
1978                         return;
1979         if(strlen(nextMap) > mapvote_maxlen)
1980                 mapvote_maxlen = strlen(nextMap);
1981         mapvote_maps[mapvote_count] = strzone(nextMap);
1982         mapvote_maps_suggested[mapvote_count] = isSuggestion;
1983         mapvote_count += 1;
1984 }
1985
1986 void MapVote_Spawn();
1987 void MapVote_Init()
1988 {
1989         float i;
1990         float nmax, smax;
1991
1992         MapVote_ClearAllVotes();
1993
1994         mapvote_count = 0;
1995         mapvote_detail = !cvar("g_maplist_votable_nodetail");
1996         mapvote_abstain = cvar("g_maplist_votable_abstain");
1997
1998         if(mapvote_abstain)
1999                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2000         else
2001                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2002         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2003
2004         if(mapvote_suggestion_ptr)
2005                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2006                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2007
2008         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2009                 MapVote_AddVotable(GetNextMap(), FALSE);
2010
2011         if(mapvote_count == 0)
2012         {
2013                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2014                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
2015                 if(cvar("g_maplist_shuffle"))
2016                         ShuffleMaplist();
2017                 localcmd("\nmenu_cmd sync\n");
2018                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2019                         MapVote_AddVotable(GetNextMap(), FALSE);
2020         }
2021
2022         mapvote_count_real = mapvote_count;
2023         if(mapvote_abstain)
2024                 MapVote_AddVotable("don't care", 0);
2025
2026         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2027
2028         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2029         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2030         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2031                 mapvote_keeptwotime = 0;
2032         mapvote_message = "Choose a map and press its key!";
2033
2034         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2035         if(mapvote_screenshot_dir == "")
2036                 mapvote_screenshot_dir = "maps";
2037         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2038
2039         MapVote_Spawn();
2040 }
2041
2042 void MapVote_SendPicture(float id)
2043 {
2044         msg_entity = self;
2045         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2046         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2047         WriteByte(MSG_ONE, id);
2048         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2049 }
2050
2051 float GameCommand_MapVote(string cmd)
2052 {
2053         if(!intermission_running)
2054                 return FALSE;
2055
2056         if(cmd == "mv_getpic")
2057         {
2058                 MapVote_SendPicture(stof(argv(1)));
2059                 return TRUE;
2060         }
2061
2062         return FALSE;
2063 }
2064
2065 float MapVote_GetMapMask()
2066 {
2067         float mask, i, power;
2068         mask = 0;
2069         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2070                 if(mapvote_maps[i] != "")
2071                         mask |= power;
2072         return mask;
2073 }
2074
2075 entity mapvote_ent;
2076 float MapVote_SendEntity(entity to, float sf)
2077 {
2078         string mapfile, pakfile;
2079         float i, o;
2080
2081         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2082         WriteByte(MSG_ENTITY, sf);
2083
2084         if(sf & 1)
2085         {
2086                 // flag 1 == initialization
2087                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2088                 WriteByte(MSG_ENTITY, mapvote_count);
2089                 WriteByte(MSG_ENTITY, mapvote_abstain);
2090                 WriteByte(MSG_ENTITY, mapvote_detail);
2091                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2092                 if(mapvote_count <= 8)
2093                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2094                 else
2095                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2096                 for(i = 0; i < mapvote_count; ++i)
2097                         if(mapvote_maps[i] != "")
2098                         {
2099                                 WriteString(MSG_ENTITY, mapvote_maps[i]);
2100                                 mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2101                                 pakfile = whichpack(strcat(mapfile, ".tga"));
2102                                 if(pakfile == "")
2103                                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2104                                 if(pakfile == "")
2105                                         pakfile = whichpack(strcat(mapfile, ".png"));
2106                                 print("pakfile is ", pakfile, "\n");
2107                                 for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2108                                         pakfile = substring(pakfile, o, 999);
2109                                 WriteString(MSG_ENTITY, pakfile);
2110                         }
2111         }
2112
2113         if(sf & 2)
2114         {
2115                 // flag 2 == update of mask
2116                 if(mapvote_count <= 8)
2117                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2118                 else
2119                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2120         }
2121
2122         if(sf & 4)
2123         {
2124                 if(mapvote_detail)
2125                         for(i = 0; i < mapvote_count; ++i)
2126                                 if(mapvote_maps[i] != "")
2127                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2128
2129                 WriteByte(MSG_ENTITY, to.mapvote);
2130         }
2131
2132         return TRUE;
2133 }
2134
2135 void MapVote_Spawn()
2136 {
2137         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2138 }
2139
2140 void MapVote_TouchMask()
2141 {
2142         mapvote_ent.SendFlags |= 2;
2143 }
2144
2145 void MapVote_TouchVotes(entity voter)
2146 {
2147         mapvote_ent.SendFlags |= 4;
2148 }
2149
2150 float MapVote_Finished(float mappos)
2151 {
2152         string result;
2153         float i;
2154         float didntvote;
2155
2156         if(cvar("sv_eventlog"))
2157         {
2158                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2159                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2160                 didntvote = mapvote_voters;
2161                 for(i = 0; i < mapvote_count; ++i)
2162                         if(mapvote_maps[i] != "")
2163                         {
2164                                 didntvote -= mapvote_votes[i];
2165                                 if(i != mappos)
2166                                 {
2167                                         result = strcat(result, ":", mapvote_maps[i]);
2168                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2169                                 }
2170                         }
2171                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2172
2173                 GameLogEcho(result);
2174                 if(mapvote_maps_suggested[mappos])
2175                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2176         }
2177
2178         FOR_EACH_REALCLIENT(other)
2179                 FixClientCvars(other);
2180
2181         Map_Goto_SetStr(mapvote_maps[mappos]);
2182         Map_Goto();
2183         alreadychangedlevel = TRUE;
2184         return TRUE;
2185 }
2186 void MapVote_CheckRules_1()
2187 {
2188         float i;
2189
2190         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2191         {
2192                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2193                 mapvote_votes[i] = 0;
2194         }
2195
2196         mapvote_voters = 0;
2197         FOR_EACH_REALCLIENT(other)
2198         {
2199                 ++mapvote_voters;
2200                 if(other.mapvote)
2201                 {
2202                         i = other.mapvote - 1;
2203                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2204                         mapvote_votes[i] = mapvote_votes[i] + 1;
2205                 }
2206         }
2207 }
2208
2209 float MapVote_CheckRules_2()
2210 {
2211         float i;
2212         float firstPlace, secondPlace;
2213         float firstPlaceVotes, secondPlaceVotes;
2214         float mapvote_voters_real;
2215         string result;
2216
2217         mapvote_voters_real = mapvote_voters;
2218         if(mapvote_abstain)
2219                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2220
2221         RandomSelection_Init();
2222         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2223                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2224         firstPlace = RandomSelection_chosen_float;
2225         firstPlaceVotes = RandomSelection_best_priority;
2226         //dprint("First place: ", ftos(firstPlace), "\n");
2227         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2228
2229         RandomSelection_Init();
2230         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2231                 if(i != firstPlace)
2232                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2233         secondPlace = RandomSelection_chosen_float;
2234         secondPlaceVotes = RandomSelection_best_priority;
2235         //dprint("Second place: ", ftos(secondPlace), "\n");
2236         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2237
2238         if(firstPlace == -1)
2239                 error("No first place in map vote... WTF?");
2240
2241         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2242                 return MapVote_Finished(firstPlace);
2243
2244         if(mapvote_keeptwotime)
2245                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2246                 {
2247                         float didntvote;
2248                         MapVote_TouchMask();
2249                         mapvote_message = "Now decide between the TOP TWO!";
2250                         mapvote_keeptwotime = 0;
2251                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2252                         result = strcat(result, ":", ftos(firstPlaceVotes));
2253                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2254                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2255                         didntvote = mapvote_voters;
2256                         for(i = 0; i < mapvote_count; ++i)
2257                                 if(mapvote_maps[i] != "")
2258                                 {
2259                                         didntvote -= mapvote_votes[i];
2260                                         if(i != firstPlace)
2261                                                 if(i != secondPlace)
2262                                                 {
2263                                                         result = strcat(result, ":", mapvote_maps[i]);
2264                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2265                                                         if(i < mapvote_count_real)
2266                                                         {
2267                                                                 strunzone(mapvote_maps[i]);
2268                                                                 mapvote_maps[i] = "";
2269                                                         }
2270                                                 }
2271                                 }
2272                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2273                         if(cvar("sv_eventlog"))
2274                                 GameLogEcho(result);
2275                 }
2276
2277         return FALSE;
2278 }
2279 void MapVote_Tick()
2280 {
2281         float keeptwo;
2282         float totalvotes;
2283
2284         keeptwo = mapvote_keeptwotime;
2285         MapVote_CheckRules_1(); // count
2286         if(MapVote_CheckRules_2()) // decide
2287                 return;
2288
2289         totalvotes = 0;
2290         FOR_EACH_REALCLIENT(other)
2291         {
2292                 // hide scoreboard again
2293                 if(other.health != 2342)
2294                 {
2295                         other.health = 2342;
2296                         other.impulse = 0;
2297                         if(clienttype(other) == CLIENTTYPE_REAL)
2298                         {
2299                                 msg_entity = other;
2300                                 WriteByte(MSG_ONE, SVC_FINALE);
2301                                 WriteString(MSG_ONE, "");
2302                         }
2303                 }
2304
2305                 // notify about keep-two
2306                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
2307                         play2(other, "misc/invshot.wav");
2308
2309                 // clear possibly invalid votes
2310                 if(mapvote_maps[other.mapvote - 1] == "")
2311                         other.mapvote = 0;
2312                 // use impulses as new vote
2313                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2314                         if(mapvote_maps[other.impulse - 1] != "")
2315                         {
2316                                 other.mapvote = other.impulse;
2317                                 MapVote_TouchVotes(other);
2318                         }
2319                 other.impulse = 0;
2320
2321                 if(other.mapvote)
2322                         ++totalvotes;
2323         }
2324
2325         MapVote_CheckRules_1(); // just count
2326 }
2327 void MapVote_Start()
2328 {
2329         if(mapvote_run)
2330                 return;
2331
2332         MapInfo_Enumerate();
2333         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1))
2334                 mapvote_run = TRUE;
2335 }
2336 void MapVote_Think()
2337 {
2338         if(!mapvote_run)
2339                 return;
2340
2341         if(alreadychangedlevel)
2342                 return;
2343
2344         if(time < mapvote_nextthink)
2345                 return;
2346         //dprint("tick\n");
2347
2348         mapvote_nextthink = time + 0.5;
2349
2350         if(!mapvote_initialized)
2351         {
2352                 mapvote_initialized = TRUE;
2353                 if(DoNextMapOverride())
2354                         return;
2355                 if(!cvar("g_maplist_votable") || player_count <= 0)
2356                 {
2357                         GotoNextMap();
2358                         return;
2359                 }
2360                 MapVote_Init();
2361         }
2362
2363         MapVote_Tick();
2364 };
2365
2366 string GotoMap(string m)
2367 {
2368         if(!MapInfo_CheckMap(m))
2369                 return "The map you chose is not available on this server.";
2370         cvar_set("nextmap", m);
2371         cvar_set("timelimit", "-1");
2372         if(mapvote_initialized || alreadychangedlevel)
2373         {
2374                 if(DoNextMapOverride())
2375                         return "Map switch initiated.";
2376                 else
2377                         return "Hm... no. For some reason I like THIS map more.";
2378         }
2379         else
2380                 return "Map switch will happen after scoreboard.";
2381 }
2382
2383
2384 void EndFrame()
2385 {
2386         FOR_EACH_REALCLIENT(self)
2387         {
2388                 if(self.classname == "spectator")
2389                 {
2390                         if(self.enemy.typehitsound)
2391                                 play2(self, "misc/typehit.wav");
2392                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2393                                 play2(self, "misc/hit.wav");
2394                 }
2395                 else
2396                 {
2397                         if(self.typehitsound)
2398                                 play2(self, "misc/typehit.wav");
2399                         else if(self.hitsound && self.cvar_cl_hitsound)
2400                                 play2(self, "misc/hit.wav");
2401                 }
2402         }
2403         FOR_EACH_CLIENT(self)
2404         {
2405                 self.hitsound = FALSE;
2406                 self.typehitsound = FALSE;
2407         }
2408 }
2409
2410
2411 /*
2412  * RedirectionThink:
2413  * returns TRUE if redirecting
2414  */
2415 float redirection_timeout;
2416 float redirection_nextthink;
2417 float RedirectionThink()
2418 {
2419         float clients_found;
2420
2421         if(redirection_target == "")
2422                 return FALSE;
2423
2424         if(!redirection_timeout)
2425         {
2426                 cvar_set("sv_public", "-2");
2427                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2428                 if(redirection_target == "self")
2429                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2430                 else
2431                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2432         }
2433
2434         if(time < redirection_nextthink)
2435                 return TRUE;
2436
2437         redirection_nextthink = time + 1;
2438
2439         clients_found = 0;
2440         FOR_EACH_REALCLIENT(self)
2441         {
2442                 print("Redirecting: sending connect command to ", self.netname, "\n");
2443                 if(redirection_target == "self")
2444                         stuffcmd(self, "\ndisconnect; reconnect\n");
2445                 else
2446                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2447                 ++clients_found;
2448         }
2449
2450         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2451
2452         if(time > redirection_timeout || clients_found == 0)
2453                 localcmd("\nwait; wait; wait; quit\n");
2454
2455         return TRUE;
2456 }
2457
2458 void RestoreGame()
2459 {
2460         // Loaded from a save game
2461         // some things then break, so let's work around them...
2462
2463         // Progs DB (capture records)
2464         if(sv_cheats)
2465                 ServerProgsDB = db_create();
2466         else
2467                 ServerProgsDB = db_load("server.db");
2468
2469         // Mapinfo
2470         MapInfo_Shutdown();
2471         MapInfo_Enumerate();
2472         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? MAPINFO_FLAG_HIDDEN : 0), 1);
2473 }
2474
2475 void SV_Shutdown()
2476 {
2477         if(world_initialized > 0)
2478         {
2479                 world_initialized = 0;
2480                 print("Saving persistent data...\n");
2481                 Ban_SaveBans();
2482                 if(!sv_cheats)
2483                         db_save(ServerProgsDB, "server.db");
2484                 if(cvar("developer"))
2485                         db_save(TemporaryDB, "server-temp.db");
2486                 db_close(ServerProgsDB);
2487                 db_close(TemporaryDB);
2488                 print("done!\n");
2489                 // tell the bot system the game is ending now
2490                 bot_endgame();
2491
2492                 MapInfo_Shutdown();
2493         }
2494         else if(world_initialized == 0)
2495         {
2496                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2497         }
2498 }