data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 .string fog;
  12
  13 void SetDefaultAlpha()
  14 {
  15         if(cvar("g_running_guns"))
  16         {
  17                 default_player_alpha = -1;
  18                 default_weapon_alpha = +1;
  19         }
  20         else if(g_cloaked)
  21         {
  22                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  23                 default_weapon_alpha = default_player_alpha;
  24         }
  25         else
  26         {
  27                 default_player_alpha = cvar("g_player_alpha");
  28                 if(default_player_alpha <= 0)
  29                         default_player_alpha = 1;
  30                 default_weapon_alpha = default_player_alpha;
  31         }
  32 }
  33
  34 void fteqcc_testbugs()
  35 {
  36         float a, b;
  37
  38         if(!cvar("developer_fteqccbugs"))
  39                 return;
  40
  41         dprint("*** fteqcc test: checking for bugs...\n");
  42
  43         a = 1;
  44         b = 5;
  45         if(sqrt(a) - sqrt(b - a) == 0)
  46                 dprint("*** fteqcc test: found same-function-twice bug\n");
  47         else
  48                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  49
  50         world.cnt = -10;
  51         world.enemy = world;
  52         world.enemy.cnt += 10;
  53         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  54                 dprint("*** fteqcc test: found += bug\n");
  55         else
  56                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  57         world.cnt = 0;
  58 }
  59
  60 /**
  61  * Takes care of pausing and unpausing the game.
  62  * Centerprints the information about an upcoming or active timeout to all active
  63  * players. Also plays reminder sounds.
  64  */
  65 void timeoutHandler_Think() {
  66         local string timeStr;
  67         local entity plr;
  68         if (timeoutStatus == 1) {
  69                 if (remainingLeadTime > 0) {
  70                         //centerprint the information to every player
  71                         timeStr = getTimeoutText(0);
  72                         FOR_EACH_REALCLIENT(plr) {
  73                                 if(plr.classname == "player") {
  74                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  75                                 }
  76                         }
  77                         remainingLeadTime -= 1;
  78                         //think again in 1 second:
  79                         self.nextthink = time + 1;
  80                 }
  81                 else {
  82                         //now pause the game:
  83                         timeoutStatus = 2;
  84                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  85                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  86                         FOR_EACH_REALPLAYER(plr) {
  87                                 plr.lastV_angle = plr.v_angle;
  88                         }
  89                         self.nextthink = time;
  90                 }
  91         }
  92         else if (timeoutStatus == 2) {
  93                 if (remainingTimeoutTime > 0) {
  94                         timeStr = getTimeoutText(0);
  95                         FOR_EACH_REALCLIENT(plr) {
  96                                 if(plr.classname == "player") {
  97                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  98                                 }
  99                         }
 100                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 101                                 sound(world, CHAN_AUTO, "announcer/robotic/prepareforbattle.wav", VOL_BASE, ATTN_NONE);
 102                         }
 103                         remainingTimeoutTime -= 1;
 104                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 105                 }
 106                 else {
 107                         //unpause the game again
 108                         remainingTimeoutTime = timeoutStatus = 0;
 109                         cvar_set("slowmo", ftos(orig_slowmo));
 110                         //and unlock the fixed view again once there is no timeout active anymore
 111                         FOR_EACH_REALPLAYER(plr) {
 112                                 plr.fixangle = FALSE;
 113                         }
 114                         //get rid of the countdown message
 115                         FOR_EACH_REALCLIENT(plr) {
 116                                 if(plr.classname == "player") {
 117                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 118                                 }
 119                         }
 120                         remove(self);
 121                         return;
 122                 }
 123
 124         }
 125         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 126                 FOR_EACH_REALCLIENT(plr) {
 127                         if(plr.classname == "player") {
 128                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 129                         }
 130                 }
 131                 remove(self);
 132                 return;
 133         }
 134 }
 135
 136 float GotoFirstMap()
 137 {
 138         if(cvar("_sv_init"))
 139         {
 140                 cvar_set("_sv_init", "0");
 141                 if(cvar("g_maplist_shuffle"))
 142                         ShuffleMaplist();
 143 #ifdef MAPINFO
 144                 tokenizebyseparator(cvar_string("g_maplist"), " ");
 145 #else
 146                 tokenize(cvar_string("g_maplist"));
 147                 if(argv(0) != GetMapname())
 148 #endif
 149                 {
 150                         cvar_set("nextmap", argv(0));
 151
 152 #ifdef MAPINFO
 153                         MapInfo_Enumerate();
 154                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0);
 155 #endif
 156
 157                         if(!DoNextMapOverride())
 158                                 GotoNextMap();
 159
 160                         return 1;
 161                 }
 162         }
 163         return 0;
 164 }
 165
 166 float world_already_spawned;
 167 void spawnfunc_worldspawn (void)
 168 {
 169         float fd, l;
 170         string s;
 171
 172         dprint_load(); // load dprint status from cvar
 173
 174         if(world_already_spawned)
 175                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 176         world_already_spawned = TRUE;
 177
 178         local entity head;
 179         head = nextent(world);
 180         maxclients = 0;
 181         while(head)
 182         {
 183                 ++maxclients;
 184                 head = nextent(head);
 185         }
 186
 187         if(GotoFirstMap())
 188                 return;
 189
 190 #ifdef MAPINFO
 191         MapInfo_LoadMapSettings(mapname);
 192 #endif
 193
 194         if(sv_cheats)
 195                 ServerProgsDB = db_create();
 196         else
 197                 ServerProgsDB = db_load("server.db");
 198
 199         /*
 200         TODO sound pack system
 201         // initialize sound pack system
 202         soundpack = cvar_string("g_soundpack");
 203         if(soundpack != "")
 204                 soundpack = strcat(soundpack, "/");
 205         soundpack = strzone(soundpack);
 206         */
 207
 208         // 0 normal
 209         lightstyle(0, "m");
 210
 211         // 1 FLICKER (first variety)
 212         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 213
 214         // 2 SLOW STRONG PULSE
 215         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 216
 217         // 3 CANDLE (first variety)
 218         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 219
 220         // 4 FAST STROBE
 221         lightstyle(4, "mamamamamama");
 222
 223         // 5 GENTLE PULSE 1
 224         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 225
 226         // 6 FLICKER (second variety)
 227         lightstyle(6, "nmonqnmomnmomomno");
 228
 229         // 7 CANDLE (second variety)
 230         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 231
 232         // 8 CANDLE (third variety)
 233         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 234
 235         // 9 SLOW STROBE (fourth variety)
 236         lightstyle(9, "aaaaaaaazzzzzzzz");
 237
 238         // 10 FLUORESCENT FLICKER
 239         lightstyle(10, "mmamammmmammamamaaamammma");
 240
 241         // 11 SLOW PULSE NOT FADE TO BLACK
 242         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 243
 244         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 245
 246         // 63 testing
 247         lightstyle(63, "a");
 248
 249         // for setting by mapinfo
 250         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 251         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 252
 253         player_count = 0;
 254         lms_lowest_lives = 0;
 255         lms_next_place = 0;
 256
 257         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 258         if(bot_waypoints_for_items == 1)
 259                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 260                         bot_waypoints_for_items = 0;
 261
 262         if(cvar("g_campaign"))
 263                 CampaignPreInit();
 264
 265         InitGameplayMode();
 266         readlevelcvars();
 267         precache();
 268
 269         WaypointSprite_Init();
 270
 271         //if (g_domination)
 272         //      dom_init();
 273
 274         GameLogInit(); // prepare everything
 275         if(cvar("sv_eventlog"))
 276         {
 277                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 278                 s = strcat(s, ftos(random()));
 279 #ifdef MAPINFO
 280                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s), FALSE);
 281 #else
 282                 GameLogEcho(strcat(":gamestart:", GetMapname(), ":", s), FALSE);
 283 #endif
 284                 s = ":gameinfo:mutators:LIST";
 285                 if(cvar("g_grappling_hook"))
 286                         s = strcat(s, ":grappling_hook");
 287                 if(!cvar("g_use_ammunition"))
 288                         s = strcat(s, ":no_use_ammunition");
 289                 if(!cvar("g_pickup_items"))
 290                         s = strcat(s, ":no_pickup_items");
 291                 if(cvar("g_instagib"))
 292                         s = strcat(s, ":instagib");
 293                 if(cvar("g_rocketarena"))
 294                         s = strcat(s, ":rockerarena");
 295                 if(cvar("g_nixnex"))
 296                         s = strcat(s, ":nixnex");
 297                 if(cvar("g_vampire"))
 298                         s = strcat(s, ":vampire");
 299                 if(cvar("g_laserguided_missile"))
 300                         s = strcat(s, ":laserguided_missile");
 301                 if(cvar("g_norecoil"))
 302                         s = strcat(s, ":norecoil");
 303                 if(cvar("g_midair"))
 304                         s = strcat(s, ":midair");
 305                 if(cvar("g_minstagib"))
 306                         s = strcat(s, ":minstagib");
 307                 GameLogEcho(s, FALSE);
 308                 GameLogEcho(":gameinfo:end", FALSE);
 309         }
 310
 311         cvar_set("nextmap", "");
 312
 313         SetDefaultAlpha();
 314
 315         if(cvar("g_campaign"))
 316                 CampaignPostInit();
 317
 318         fteqcc_testbugs();
 319
 320         Ban_LoadBans();
 321
 322         //initialise globals related to sv_timeout
 323         sys_ticrate = cvar("sys_ticrate");
 324         orig_slowmo = cvar("slowmo");
 325
 326 #ifdef MAPINFO
 327         MapInfo_Enumerate();
 328         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 1);
 329 #endif
 330
 331         //if tourney is used map starts in warmup mode. if this mode shall stay unlimited, reset timelimit, but save the original one
 332         if(g_tourney && cvar("g_tourney_warmup_unlimited_time")) {
 333                 timelimit_orig = cvar("timelimit");
 334                 cvar_set("timelimit", "0");
 335         }
 336
 337         fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 338         if(fd != -1)
 339         {
 340                 while((s = fgets(fd)))
 341                 {
 342                         l = tokenize(s);
 343                         if(l < 2)
 344                                 continue;
 345                         if(argv(0) != "fog")
 346                                 continue;
 347                         s = "";
 348                         while(l >= 2)
 349                         {
 350                                 --l;
 351                                 s = strcat(argv(l), " ", s);
 352                         }
 353                         s = substring(s, 0, strlen(s) - 1);
 354                         print("Found ^1DEPRECATED^7 fog command in .cfg file: ", s, "\n");
 355                         world.fog = strzone(s);
 356                 }
 357                 fclose(fd);
 358         }
 359
 360         next_pingtime = time + 5;
 361         world_initialized = 1;
 362 }
 363
 364 void spawnfunc_light (void)
 365 {
 366         //makestatic (self); // Who the f___ did that?
 367         remove(self);
 368 }
 369
 370 float TryFile( string pFilename )
 371 {
 372         local float lHandle;
 373         dprint("TryFile(\"", pFilename, "\")\n");
 374         lHandle = fopen( pFilename, FILE_READ );
 375         if( lHandle != -1 ) {
 376                 fclose( lHandle );
 377                 return TRUE;
 378         } else {
 379                 return FALSE;
 380         }
 381 };
 382
 383 string GetGametype()
 384 {
 385         return GametypeNameFromType(game);
 386 }
 387
 388 float IsSameGametype(string mapcfgname)
 389 {
 390 #ifdef MAPINFO
 391         return TRUE; // can't change game type by map name here
 392 #else
 393         string gt;
 394         gt = GetGametype();
 395         if(substring(mapcfgname, 0, strlen(gt) + 1) == strcat(gt, "_"))
 396                 return TRUE;
 397         return FALSE;
 398 #endif
 399 }
 400
 401 string getmapname_stored;
 402 string GetMapname()
 403 {
 404 #ifdef MAPINFO
 405         return mapname;
 406 #else
 407         if(getmapname_stored == "")
 408                 getmapname_stored = strzone(strcat(GetGametype(), "_", mapname));
 409         return getmapname_stored;
 410 #endif
 411 }
 412
 413 float Map_Count, Map_Current;
 414 string Map_Current_Name;
 415
 416 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 417 float GetMaplistPosition()
 418 {
 419         float pos, idx;
 420         string map;
 421
 422         map = GetMapname();
 423         idx = cvar("g_maplist_index");
 424
 425         if(idx >= 0)
 426                 if(idx < Map_Count)
 427                         if(map == argv(idx))
 428                                 return idx;
 429
 430         for(pos = 0; pos < Map_Count; ++pos)
 431                 if(map == argv(pos))
 432                         return pos;
 433
 434         // resume normal maplist rotation if current map is not in g_maplist
 435         return idx;
 436 }
 437
 438 float MapHasRightSize(string map)
 439 {
 440         float fh;
 441         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 442         if(cvar("g_maplist_check_waypoints"))
 443         {
 444                 dprint("checkwp "); dprint(map);
 445                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 446                 if(fh < 0)
 447                 {
 448                         dprint(": no waypoints\n");
 449                         return FALSE;
 450                 }
 451                 dprint(": has waypoints\n");
 452                 fclose(fh);
 453         }
 454
 455         // open map size restriction file
 456         dprint("opensize "); dprint(map);
 457         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 458         if(fh >= 0)
 459         {
 460                 float mapmin, mapmax;
 461                 dprint(": ok, ");
 462                 mapmin = stof(fgets(fh));
 463                 mapmax = stof(fgets(fh));
 464                 fclose(fh);
 465                 if(player_count < mapmin)
 466                 {
 467                         dprint("not enough\n");
 468                         return FALSE;
 469                 }
 470                 if(player_count > mapmax)
 471                 {
 472                         dprint("too many\n");
 473                         return FALSE;
 474                 }
 475                 dprint("right size\n");
 476                 return TRUE;
 477         }
 478         dprint(": not found\n");
 479         return TRUE;
 480 }
 481
 482 string Map_Filename(float position)
 483 {
 484 #ifdef MAPINFO
 485         return strcat("maps/", argv(position), ".bsp");
 486 #else
 487         return strcat("maps/", argv(position), ".mapcfg");
 488 #endif
 489 }
 490
 491 string strwords(string s, float w)
 492 {
 493         float endpos;
 494         for(endpos = 0; w && endpos >= 0; --w)
 495                 endpos = strstrofs(s, " ", endpos + 1);
 496         if(endpos < 0)
 497                 return s;
 498         else
 499                 return substring(s, 0, endpos);
 500 }
 501
 502 float strhasword(string s, string w)
 503 {
 504         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 505 }
 506
 507 void Map_MarkAsRecent(string m)
 508 {
 509         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), cvar("g_maplist_mostrecent_count")));
 510 }
 511
 512 float Map_IsRecent(string m)
 513 {
 514         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 515 }
 516
 517 float Map_Check(float position, float pass)
 518 {
 519         string filename;
 520         string map_next;
 521         map_next = argv(position);
 522         if(pass <= 1)
 523         {
 524                 if(map_next == Map_Current_Name) // same map again in first pass?
 525                         return 0;
 526                 if(Map_IsRecent(map_next))
 527                         return 0;
 528         }
 529         filename = Map_Filename(position);
 530 #ifdef MAPINFO
 531         if(MapInfo_CheckMap(map_next))
 532 #else
 533         if(TryFile(filename))
 534 #endif
 535         {
 536                 if(pass == 2)
 537                         return 1;
 538                 if(MapHasRightSize(map_next))
 539                         return 1;
 540                 return 0;
 541         }
 542         else
 543                 dprint( "Couldn't select '", filename, "'..\n" );
 544
 545         return 0;
 546 }
 547
 548 void Map_Goto_SetStr(string nextmapname)
 549 {
 550         if(getmapname_stored != "")
 551                 strunzone(getmapname_stored);
 552         if(nextmapname == "")
 553                 getmapname_stored = "";
 554         else
 555                 getmapname_stored = strzone(nextmapname);
 556 }
 557
 558 void Map_Goto_SetFloat(float position)
 559 {
 560         cvar_set("g_maplist_index", ftos(position));
 561         Map_Goto_SetStr(argv(position));
 562 }
 563
 564 void GameResetCfg()
 565 {
 566 #ifdef MAPINFO
 567         // settings persist, except...
 568         if(cvar("g_campaign"))
 569                 localcmd("\nexec mutator_reset.cfg\n");
 570         localcmd("\nsettemp_restore\n");
 571 #else
 572         // if an exit cfg is defined by exiting map, exec it.
 573         string exit_cfg;
 574         exit_cfg = cvar_string("exit_cfg");
 575         if(exit_cfg != "")
 576                 localcmd(strcat("exec \"", exit_cfg, "\"\n"));
 577
 578         localcmd("exec game_reset.cfg\n");
 579 #endif
 580 };
 581
 582 void Map_Goto()
 583 {
 584         Map_MarkAsRecent(getmapname_stored);
 585         GameResetCfg();
 586 #ifdef MAPINFO
 587         MapInfo_LoadMap(getmapname_stored);
 588 #else
 589         localcmd(strcat("exec \"maps/", getmapname_stored ,".mapcfg\"\n"));
 590 #endif
 591 }
 592
 593 // return codes of map selectors:
 594 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 595 //   -2 = permanent failure
 596 float() MaplistMethod_Iterate = // usual method
 597 {
 598         float pass, i;
 599
 600         for(pass = 1; pass <= 2; ++pass)
 601         {
 602                 for(i = 1; i < Map_Count; ++i)
 603                 {
 604                         float mapindex;
 605                         mapindex = mod(i + Map_Current, Map_Count);
 606                         if(Map_Check(mapindex, pass))
 607                                 return mapindex;
 608                 }
 609         }
 610         return -1;
 611 }
 612
 613 float() MaplistMethod_Repeat = // fallback method
 614 {
 615         if(Map_Check(Map_Current, 2))
 616                 return Map_Current;
 617         return -2;
 618 }
 619
 620 float() MaplistMethod_Random = // random map selection
 621 {
 622         float i, imax;
 623
 624         imax = 42;
 625
 626         for(i = 0; i <= imax; ++i)
 627         {
 628                 float mapindex;
 629                 mapindex = mod(Map_Current + ceil(random() * (Map_Count - 1)), Map_Count); // any OTHER map
 630                 if(Map_Check(mapindex, 1))
 631                         return mapindex;
 632         }
 633         return -1;
 634 }
 635
 636 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 637 // the exponent sets a bias on the map selection:
 638 // the higher the exponent, the less likely "shortly repeated" same maps are
 639 {
 640         float i, j, imax, insertpos;
 641
 642         imax = 42;
 643
 644         for(i = 0; i <= imax; ++i)
 645         {
 646                 string newlist;
 647
 648                 // now reinsert this at another position
 649                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 650                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 651                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 652                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 653
 654                 // insert the current map there
 655                 newlist = "";
 656 #ifdef MAPINFO
 657                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 658                         newlist = strcat(newlist, " ", argv(j));
 659                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 660                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 661                         newlist = strcat(newlist, " ", argv(j));
 662                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 663 #else
 664                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 665                         newlist = strcat(newlist, "'", argv(j), "'");
 666                 newlist = strcat(newlist, "'", argv(0), "'");  // now insert the just selected map
 667                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 668                         newlist = strcat(newlist, "'", argv(j), "'");
 669 #endif
 670                 cvar_set("g_maplist", newlist);
 671 #ifdef MAPINFO
 672                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 673 #else
 674                 Map_Count = tokenize(newlist);
 675 #endif
 676
 677                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 678                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 679                 if(Map_Check(Map_Current, 1))
 680                         return Map_Current;
 681         }
 682         return -1;
 683 }
 684
 685 void Maplist_Init()
 686 {
 687         string temp;
 688         temp = cvar_string("g_maplist");
 689 #ifdef MAPINFO
 690         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 691 #else
 692         Map_Count = tokenize(temp);
 693 #endif
 694         if(Map_Count == 0)
 695         {
 696                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 697 #ifdef MAPINFO
 698                 cvar_set("g_maplist", temp = MapInfo_ListAllowedMaps());
 699                 localcmd("\nmenu_cmd sync\n");
 700                 Map_Count = tokenizebyseparator(temp, " ");
 701 #else
 702                 cvar_set("g_maplist", temp = cvar_string("g_maplist_defaultlist"));
 703                 Map_Count = tokenize(temp);
 704 #endif
 705         }
 706         if(Map_Count == 0)
 707                 error("empty maplist, cannot select a new map");
 708         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 709
 710         if(Map_Current_Name)
 711                 strunzone(Map_Current_Name);
 712         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 713         // this may or may not be correct, but who cares, in the worst case a map
 714         // isn't chosen in the first pass that should have been
 715 }
 716
 717 string GetNextMap()
 718 {
 719         float nextMap;
 720
 721         Maplist_Init();
 722         nextMap = -1;
 723
 724         if(nextMap == -1)
 725                 if(cvar("g_maplist_shuffle") > 0)
 726                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 727
 728         if(nextMap == -1)
 729                 if(cvar("g_maplist_selectrandom"))
 730                         nextMap = MaplistMethod_Random();
 731
 732         if(nextMap == -1)
 733                 nextMap = MaplistMethod_Iterate();
 734
 735         if(nextMap == -1)
 736                 nextMap = MaplistMethod_Repeat();
 737
 738         if(nextMap >= 0)
 739         {
 740                 Map_Goto_SetFloat(nextMap);
 741                 return getmapname_stored;
 742         }
 743
 744         return "";
 745 };
 746
 747 float DoNextMapOverride()
 748 {
 749         if(cvar("g_campaign"))
 750         {
 751                 CampaignPostIntermission();
 752                 alreadychangedlevel = TRUE;
 753                 return TRUE;
 754         }
 755         if(cvar("quit_when_empty"))
 756         {
 757                 if(player_count <= currentbots)
 758                 {
 759                         localcmd("quit\n");
 760                         alreadychangedlevel = TRUE;
 761                         return TRUE;
 762                 }
 763         }
 764         if(cvar_string("quit_and_redirect") != "")
 765         {
 766                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 767                 alreadychangedlevel = TRUE;
 768                 return TRUE;
 769         }
 770         if (cvar("samelevel")) // if samelevel is set, stay on same level
 771         {
 772                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 773                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 774                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 775                 localcmd("restart\n");
 776                 //changelevel (mapname);
 777                 alreadychangedlevel = TRUE;
 778                 return TRUE;
 779         }
 780         if(cvar_string("nextmap") != "")
 781 #ifdef MAPINFO
 782                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 783 #else
 784                 if(TryFile(strcat("maps/", cvar_string("nextmap"), ".mapcfg")))
 785 #endif
 786                 {
 787                         Map_Goto_SetStr(cvar_string("nextmap"));
 788                         Map_Goto();
 789                         alreadychangedlevel = TRUE;
 790                         return TRUE;
 791                 }
 792         if(cvar("lastlevel"))
 793         {
 794                 GameResetCfg();
 795                 localcmd("set lastlevel 0\ntogglemenu\n");
 796                 alreadychangedlevel = TRUE;
 797                 return TRUE;
 798         }
 799         return FALSE;
 800 };
 801
 802 void GotoNextMap()
 803 {
 804         //local string nextmap;
 805         //local float n, nummaps;
 806         //local string s;
 807         if (alreadychangedlevel)
 808                 return;
 809         alreadychangedlevel = TRUE;
 810
 811         {
 812                 string nextMap;
 813                 float allowReset;
 814
 815                 for(allowReset = 1; allowReset >= 0; --allowReset)
 816                 {
 817                         nextMap = GetNextMap();
 818                         if(nextMap != "")
 819                                 break;
 820
 821                         if(allowReset)
 822                         {
 823                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
 824 #ifdef MAPINFO
 825                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps());
 826                                 localcmd("\nmenu_cmd sync\n");
 827 #else
 828                                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
 829 #endif
 830                         }
 831                         else
 832                         {
 833                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
 834                         }
 835                 }
 836                 Map_Goto();
 837         }
 838 };
 839
 840
 841 /*
 842 ============
 843 IntermissionThink
 844
 845 When the player presses attack or jump, change to the next level
 846 ============
 847 */
 848 .float autoscreenshot;
 849 void() MapVote_Start;
 850 void() MapVote_Think;
 851 float mapvote_initialized;
 852 void IntermissionThink()
 853 {
 854         FixIntermissionClient(self);
 855
 856         if(cvar("sv_autoscreenshot"))
 857         if(self.autoscreenshot > 0)
 858         if(time > self.autoscreenshot)
 859         {
 860                 self.autoscreenshot = -1;
 861                 if(clienttype(self) == CLIENTTYPE_REAL)
 862                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
 863                 return;
 864         }
 865
 866         if (time < intermission_exittime)
 867                 return;
 868
 869         if(!mapvote_initialized)
 870                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
 871                         return;
 872
 873         MapVote_Start();
 874 };
 875
 876 /*
 877 ============
 878 FindIntermission
 879
 880 Returns the entity to view from
 881 ============
 882 */
 883 /*
 884 entity FindIntermission()
 885 {
 886         local   entity spot;
 887         local   float cyc;
 888
 889 // look for info_intermission first
 890         spot = find (world, classname, "info_intermission");
 891         if (spot)
 892         {       // pick a random one
 893                 cyc = random() * 4;
 894                 while (cyc > 1)
 895                 {
 896                         spot = find (spot, classname, "info_intermission");
 897                         if (!spot)
 898                                 spot = find (spot, classname, "info_intermission");
 899                         cyc = cyc - 1;
 900                 }
 901                 return spot;
 902         }
 903
 904 // then look for the start position
 905         spot = find (world, classname, "info_player_start");
 906         if (spot)
 907                 return spot;
 908
 909 // testinfo_player_start is only found in regioned levels
 910         spot = find (world, classname, "testplayerstart");
 911         if (spot)
 912                 return spot;
 913
 914 // then look for the start position
 915         spot = find (world, classname, "info_player_deathmatch");
 916         if (spot)
 917                 return spot;
 918
 919         //objerror ("FindIntermission: no spot");
 920         return world;
 921 };
 922 */
 923
 924 /*
 925 ===============================================================================
 926
 927 RULES
 928
 929 ===============================================================================
 930 */
 931
 932 void DumpStats(float final)
 933 {
 934         local float file;
 935         local string s;
 936         local float to_console;
 937         local float to_eventlog;
 938         local float to_file;
 939         local float i;
 940
 941         to_console = cvar("sv_logscores_console");
 942         to_eventlog = cvar("sv_eventlog");
 943         to_file = cvar("sv_logscores_file");
 944
 945         if(!final)
 946         {
 947                 to_console = TRUE; // always print printstats replies
 948                 to_eventlog = FALSE; // but never print them to the event log
 949         }
 950
 951         if(to_eventlog)
 952                 if(cvar("sv_eventlog_console"))
 953                         to_console = FALSE; // otherwise we get the output twice
 954
 955         if(final)
 956                 s = ":scores:";
 957         else
 958                 s = ":status:";
 959 #ifdef MAPINFO
 960         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
 961 #else
 962         s = strcat(s, GetMapname(), ":", ftos(rint(time)));
 963 #endif
 964
 965         if(to_console)
 966                 ServerConsoleEcho(s, FALSE);
 967         if(to_eventlog)
 968                 GameLogEcho(s, FALSE);
 969         if(to_file)
 970         {
 971                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
 972                 if(file == -1)
 973                         to_file = FALSE;
 974                 else
 975                         fputs(file, strcat(s, "\n"));
 976         }
 977
 978         s = strcat(":labels:player:", GetPlayerScoreString(world));
 979         if(to_console)
 980                 ServerConsoleEcho(s, TRUE);
 981         if(to_eventlog)
 982                 GameLogEcho(s, TRUE);
 983         if(to_file)
 984                 fputs(file, strcat(s, "\n"));
 985
 986         FOR_EACH_CLIENT(other)
 987         {
 988                 // FIXME make this use the new score system
 989                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
 990                 {
 991                         s = strcat(":player:see-labels:", GetPlayerScoreString(other), ":");
 992                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
 993                         if(other.classname == "player")
 994                                 s = strcat(s, ftos(other.team), ":");
 995                         else
 996                                 s = strcat(s, "spectator:");
 997
 998                         if(to_console)
 999                                 ServerConsoleEcho(strcat(s, other.netname), TRUE);
1000                         if(to_eventlog)
1001                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname), TRUE);
1002                         if(to_file)
1003                                 fputs(file, strcat(s, other.netname, "\n"));
1004                 }
1005         }
1006
1007         if(teamplay)
1008         {
1009                 s = strcat(":labels:teamscores:", GetTeamScoreString(0));
1010                 if(to_console)
1011                         ServerConsoleEcho(s, TRUE);
1012                 if(to_eventlog)
1013                         GameLogEcho(s, TRUE);
1014                 if(to_file)
1015                         fputs(file, strcat(s, "\n"));
1016
1017                 for(i = 1; i < 16; ++i)
1018                 {
1019                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i));
1020                         s = strcat(s, ":", ftos(i));
1021                         if(to_console)
1022                                 ServerConsoleEcho(s, TRUE);
1023                         if(to_eventlog)
1024                                 GameLogEcho(s, TRUE);
1025                         if(to_file)
1026                                 fputs(file, strcat(s, "\n"));
1027                 }
1028         }
1029
1030         if(to_console)
1031                 ServerConsoleEcho(":end", FALSE);
1032         if(to_eventlog)
1033                 GameLogEcho(":end", FALSE);
1034         if(to_file)
1035         {
1036                 fputs(file, ":end\n");
1037                 fclose(file);
1038         }
1039 }
1040
1041 void FixIntermissionClient(entity e)
1042 {
1043         string s;
1044         if(!e.autoscreenshot) // initial call
1045         {
1046                 e.angles = e.v_angle;
1047                 e.angles_x = -e.angles_x;
1048                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1049                 e.health = -2342;
1050                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1051                 e.solid = SOLID_NOT;
1052                 e.movetype = MOVETYPE_NONE;
1053                 e.takedamage = DAMAGE_NO;
1054                 if(e.weaponentity)
1055                         e.weaponentity.effects = EF_NODRAW;
1056                 if(clienttype(e) == CLIENTTYPE_REAL)
1057                 {
1058                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1059                         s = cvar_string("sv_intermission_cdtrack");
1060                         if(s != "")
1061                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1062                         msg_entity = e;
1063                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1064                 }
1065         }
1066
1067         //e.velocity = '0 0 0';
1068         //e.fixangle = TRUE;
1069
1070         // TODO halt weapon animation
1071 }
1072
1073
1074 /*
1075 go to the next level for deathmatch
1076 only called if a time or frag limit has expired
1077 */
1078 void NextLevel()
1079 {
1080         float minTotalFrags;
1081         float maxTotalFrags;
1082         float score;
1083         float f;
1084
1085         gameover = TRUE;
1086
1087         intermission_running = 1;
1088
1089 // enforce a wait time before allowing changelevel
1090         if(player_count > 0)
1091                 intermission_exittime = time + cvar("sv_mapchange_delay");
1092         else
1093                 intermission_exittime = -1;
1094
1095         /*
1096         WriteByte (MSG_ALL, SVC_CDTRACK);
1097         WriteByte (MSG_ALL, 3);
1098         WriteByte (MSG_ALL, 3);
1099         // done in FixIntermission
1100         */
1101
1102         //pos = FindIntermission ();
1103
1104         VoteReset();
1105
1106         DumpStats(TRUE);
1107
1108         if(cvar("sv_eventlog"))
1109                 GameLogEcho(":gameover", FALSE);
1110
1111         GameLogClose();
1112
1113         FOR_EACH_CLIENT(other)
1114         {
1115                 FixIntermissionClient(other);
1116
1117                 if(other.winning)
1118                         bprint(other.netname, " ^7wins.\n");
1119         }
1120
1121         minTotalFrags = 0;
1122         maxTotalFrags = 0;
1123         FOR_EACH_PLAYER(other)
1124         {
1125                 if(maxTotalFrags < other.totalfrags)
1126                         maxTotalFrags = other.totalfrags;
1127                 if(minTotalFrags > other.totalfrags)
1128                         minTotalFrags = other.totalfrags;
1129         }
1130
1131         if(!currentbots)
1132         {
1133                 FOR_EACH_PLAYER(other)
1134                 {
1135                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1136                         f = bound(0, other.play_time / max(time, 1), 1);
1137                         // store some statistics?
1138                 }
1139         }
1140
1141         if(cvar("g_campaign"))
1142                 CampaignPreIntermission();
1143
1144         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1145 };
1146
1147 /*
1148 ============
1149 CheckRules_Player
1150
1151 Exit deathmatch games upon conditions
1152 ============
1153 */
1154 .float fogtime;
1155 void CheckRules_Player()
1156 {
1157         if (gameover)   // someone else quit the game already
1158                 return;
1159
1160         if(self.deadflag == DEAD_NO)
1161                 self.play_time += frametime;
1162
1163         if(sv_foginterval)
1164         if(world.fog)
1165         if(time > self.fogtime)
1166         {
1167                 stuffcmd(self, strcat("\nfog ", world.fog, "\nr_fog_exp2 0\nr_drawfog 1\n"));
1168                 self.fogtime = time + sv_foginterval;
1169         }
1170
1171         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1172         //   (div0: and that in CheckRules_World please)
1173 };
1174
1175 float checkrules_oneminutewarning;
1176 float checkrules_leaderfrags;
1177 float tdm_max_score, tdm_old_score;
1178
1179 float checkrules_equality;
1180 float checkrules_overtimewarning;
1181 float checkrules_overtimeend;
1182
1183 void InitiateOvertime()
1184 {
1185         if(!checkrules_overtimeend)
1186                 checkrules_overtimeend = time + 60 * cvar("timelimit_maxovertime");
1187 }
1188
1189 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1190 float WINNING_YES = 1; // winner found
1191 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1192 float WINNING_STARTOVERTIME = 3; // no winner, enter overtime NOW
1193
1194 float GetWinningCode(float fraglimitreached, float equality)
1195 {
1196         if(equality)
1197                 if(fraglimitreached)
1198                         return WINNING_STARTOVERTIME;
1199                 else
1200                         return WINNING_NEVER;
1201         else
1202                 if(fraglimitreached)
1203                         return WINNING_YES;
1204                 else
1205                         return WINNING_NO;
1206 }
1207
1208 // set the .winning flag for exactly those players with a given field value
1209 void SetWinners(.float field, float value)
1210 {
1211         entity head;
1212         FOR_EACH_PLAYER(head)
1213                 head.winning = (head.field == value);
1214 }
1215
1216 // set the .winning flag for those players with a given field value
1217 void AddWinners(.float field, float value)
1218 {
1219         entity head;
1220         FOR_EACH_PLAYER(head)
1221                 if(head.field == value)
1222                         head.winning = 1;
1223 }
1224
1225 // clear the .winning flags
1226 void ClearWinners(void)
1227 {
1228         entity head;
1229         FOR_EACH_PLAYER(head)
1230                 head.winning = 0;
1231 }
1232
1233 // Onslaught winning condition:
1234 // game terminates if only one team has a working generator (or none)
1235 float WinningCondition_Onslaught()
1236 {
1237         entity head;
1238         local float t1, t2, t3, t4;
1239         // first check if the game has ended
1240         t1 = t2 = t3 = t4 = 0;
1241         head = find(world, classname, "onslaught_generator");
1242         while (head)
1243         {
1244                 if (head.health > 0)
1245                 {
1246                         if (head.team == COLOR_TEAM1) t1 = 1;
1247                         if (head.team == COLOR_TEAM2) t2 = 1;
1248                         if (head.team == COLOR_TEAM3) t3 = 1;
1249                         if (head.team == COLOR_TEAM4) t4 = 1;
1250                 }
1251                 head = find(head, classname, "onslaught_generator");
1252         }
1253         if (t1 + t2 + t3 + t4 < 2)
1254         {
1255                 // game over, only one team remains (or none)
1256                 ClearWinners();
1257                 if (t1) SetWinners(team, COLOR_TEAM1);
1258                 if (t2) SetWinners(team, COLOR_TEAM2);
1259                 if (t3) SetWinners(team, COLOR_TEAM3);
1260                 if (t4) SetWinners(team, COLOR_TEAM4);
1261                 dprint("Have a winner, ending game.\n");
1262                 return WINNING_YES;
1263         }
1264
1265         // Two or more teams remain
1266         return WINNING_NO;
1267 }
1268
1269 float LMS_NewPlayerLives()
1270 {
1271         float fl;
1272         fl = cvar("fraglimit");
1273         if(fl == 0)
1274                 fl = 999;
1275
1276         // first player has left the game for dying too much? Nobody else can get in.
1277         if(lms_lowest_lives < 1)
1278                 return 0;
1279
1280         if(!cvar("g_lms_join_anytime"))
1281                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1282                         return 0;
1283
1284         return bound(1, lms_lowest_lives, fl);
1285 }
1286
1287 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1288 // they win. Otherwise the defending team wins once the timelimit passes.
1289 void assault_new_round();
1290 float WinningCondition_Assault()
1291 {
1292         local float status;
1293         status = WINNING_NO;
1294
1295         // as the timelimit has not yet passed just assume the defending team will win
1296         if(assault_attacker_team == COLOR_TEAM1)
1297         {
1298                 SetWinners(team, COLOR_TEAM2);
1299         }
1300         else
1301         {
1302                 SetWinners(team, COLOR_TEAM1);
1303         }
1304
1305         local entity ent;
1306         ent = find(world, classname, "target_assault_roundend");
1307         if(ent)
1308         {
1309                 if(ent.winning) // round end has been triggered by attacking team
1310                 {
1311                         SetWinners(team, assault_attacker_team);
1312                         if(assault_attacker_team == COLOR_TEAM1)
1313                         {
1314                                 team1_score = team1_score + 50;
1315                         }
1316                         else
1317                         {
1318                                 team2_score = team2_score + 50;
1319                         }
1320
1321                         if(ent.cnt == 1) // this was the second round
1322                         {
1323                                 status = WINNING_YES;
1324                         }
1325                         else
1326                         {
1327                                 local entity oldself;
1328                                 oldself = self;
1329                                 self = ent;
1330                                 cvar_set("timelimit", ftos((2*time)/60));
1331                                 assault_new_round();
1332                                 self = oldself;
1333                         }
1334                 }
1335         }
1336
1337         return status;
1338
1339 }
1340
1341 // LMS winning condition: game terminates if and only if there's at most one
1342 // one player who's living lives. Top two scores being equal cancels the time
1343 // limit.
1344 float WinningCondition_LMS()
1345 {
1346         entity head, head2;
1347         float have_player;
1348         float have_players;
1349         float l;
1350
1351         have_player = FALSE;
1352         have_players = FALSE;
1353         l = LMS_NewPlayerLives();
1354
1355         head = find(world, classname, "player");
1356         if(head)
1357                 have_player = TRUE;
1358         head2 = find(head, classname, "player");
1359         if(head2)
1360                 have_players = TRUE;
1361
1362         if(have_player)
1363         {
1364                 // we have at least one player
1365                 if(have_players)
1366                 {
1367                         // two or more active players - continue with the game
1368                 }
1369                 else
1370                 {
1371                         // exactly one player?
1372
1373                         ClearWinners();
1374                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1375
1376                         if(l)
1377                         {
1378                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1379                                 return WINNING_NO;
1380                         }
1381                         else
1382                         {
1383                                 // a winner!
1384                                 // and assign him his first place
1385                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1386                                 return WINNING_YES;
1387                         }
1388                 }
1389         }
1390         else
1391         {
1392                 // nobody is playing at all...
1393                 if(l)
1394                 {
1395                         // wait for players...
1396                 }
1397                 else
1398                 {
1399                         // SNAFU (maybe a draw game?)
1400                         ClearWinners();
1401                         dprint("No players, ending game.\n");
1402                         return WINNING_YES;
1403                 }
1404         }
1405
1406         // When we get here, we have at least two players who are actually LIVING,
1407         // now check if the top two players have equal score.
1408         WinningConditionHelper();
1409
1410         ClearWinners();
1411         if(WinningConditionHelper_winner)
1412                 WinningConditionHelper_winner.winning = TRUE;
1413         if(WinningConditionHelper_equality)
1414                 return WINNING_NEVER;
1415
1416         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1417         return WINNING_NO;
1418 }
1419
1420 void print_to(entity e, string s)
1421 {
1422         if(e)
1423                 sprint(e, strcat(s, "\n"));
1424         else
1425                 ServerConsoleEcho(s, TRUE);
1426 }
1427
1428 void ShuffleMaplist()
1429 {
1430         string result;
1431         float start;
1432         float litems;
1433         float selected;
1434         float i;
1435
1436         result = cvar_string("g_maplist");
1437 #ifdef MAPINFO
1438         litems = tokenizebyseparator(result, " ");
1439 #else
1440         litems = tokenize(result);
1441 #endif
1442
1443         for(start = 0; start < litems - 1; ++start)
1444         {
1445                 result = "";
1446
1447                 // select a random item
1448                 selected = ceil(random() * (litems - start) + start) - 1;
1449
1450                 // shift this item to the place start
1451 #ifdef MAPINFO
1452                 for(i = 0; i < start; ++i)
1453                         result = strcat(result, " ", argv(i));
1454                 result = strcat(result, " ", argv(selected));
1455                 for(i = start; i < litems; ++i)
1456                         if(i != selected)
1457                                 result = strcat(result, " ", argv(i));
1458                 result = substring(result, 1, strlen(result) - 1);
1459
1460                 litems = tokenizebyseparator(result, " ");
1461 #else
1462                 for(i = 0; i < start; ++i)
1463                         result = strcat(result, "'", argv(i), "'");
1464                 result = strcat(result, "'", argv(selected), "'");
1465                 for(i = start; i < litems; ++i)
1466                         if(i != selected)
1467                                 result = strcat(result, "'", argv(i), "'");
1468
1469                 litems = tokenize(result);
1470 #endif
1471
1472                 //dprint(result, "\n");
1473         }
1474
1475         cvar_set("g_maplist", result);
1476 }
1477
1478 float WinningCondition_Scores(float limit)
1479 {
1480         // TODO make everything use THIS winning condition (except LMS)
1481         WinningConditionHelper();
1482
1483         ClearWinners();
1484         if(WinningConditionHelper_winner)
1485                 WinningConditionHelper_winner.winning = 1;
1486         if(WinningConditionHelper_winnerteam >= 0)
1487                 SetWinners(team, WinningConditionHelper_winnerteam);
1488
1489         if(WinningConditionHelper_topscore == 0)
1490                 WinningConditionHelper_equality = 0;
1491
1492         return GetWinningCode(limit && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1493 }
1494
1495 float WinningCondition_RanOutOfSpawns()
1496 {
1497         entity head;
1498
1499         if(!have_team_spawns)
1500                 return WINNING_NO;
1501
1502         if(!some_spawn_has_been_used)
1503                 return WINNING_NO;
1504
1505         team1_score = team2_score = team3_score = team4_score = 0;
1506
1507         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1508         {
1509                 if(head.team == COLOR_TEAM1)
1510                         team1_score = 1;
1511                 else if(head.team == COLOR_TEAM2)
1512                         team2_score = 1;
1513                 else if(head.team == COLOR_TEAM3)
1514                         team3_score = 1;
1515                 else if(head.team == COLOR_TEAM4)
1516                         team4_score = 1;
1517         }
1518
1519         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1520         {
1521                 if(head.team == COLOR_TEAM1)
1522                         team1_score = 1;
1523                 else if(head.team == COLOR_TEAM2)
1524                         team2_score = 1;
1525                 else if(head.team == COLOR_TEAM3)
1526                         team3_score = 1;
1527                 else if(head.team == COLOR_TEAM4)
1528                         team4_score = 1;
1529         }
1530
1531         ClearWinners();
1532         if(team1_score + team2_score + team3_score + team4_score == 0)
1533         {
1534                 checkrules_equality = TRUE;
1535                 return WINNING_YES;
1536         }
1537         else if(team1_score + team2_score + team3_score + team4_score == 1)
1538         {
1539                 float t, i;
1540                 if(team1_score) t = COLOR_TEAM1;
1541                 if(team2_score) t = COLOR_TEAM2;
1542                 if(team3_score) t = COLOR_TEAM3;
1543                 if(team4_score) t = COLOR_TEAM4;
1544                 CheckAllowedTeams(world);
1545                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1546                 {
1547                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1548                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1549                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1550                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1551                 }
1552
1553                 AddWinners(team, t);
1554                 return WINNING_YES;
1555         }
1556         else
1557                 return WINNING_NO;
1558 }
1559
1560 /*
1561 ============
1562 CheckRules_World
1563
1564 Exit deathmatch games upon conditions
1565 ============
1566 */
1567 void CheckRules_World()
1568 {
1569         local float status;
1570         local float timelimit;
1571         local float fraglimit;
1572
1573         VoteThink();
1574         MapVote_Think();
1575
1576         SetDefaultAlpha();
1577
1578         /*
1579         MapVote_Think should now do that part
1580         if (intermission_running)
1581                 if (time >= intermission_exittime + 60)
1582                 {
1583                         if(!DoNextMapOverride())
1584                                 GotoNextMap();
1585                         return;
1586                 }
1587         */
1588
1589         if (gameover)   // someone else quit the game already
1590         {
1591                 if(player_count == 0) // Nobody there? Then let's go to the next map
1592                         MapVote_Start();
1593                         // this will actually check the player count in the next frame
1594                         // again, but this shouldn't hurt
1595                 return;
1596         }
1597
1598         timelimit = cvar("timelimit") * 60;
1599         fraglimit = cvar("fraglimit");
1600
1601         if(checkrules_overtimeend)
1602         {
1603                 if(!checkrules_overtimewarning)
1604                 {
1605                         checkrules_overtimewarning = TRUE;
1606                         //sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.wav", VOL_BASE, ATTN_NONE);
1607                         bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1608                 }
1609         }
1610         else
1611         {
1612                 if (timelimit && time >= timelimit)
1613                         InitiateOvertime();
1614         }
1615
1616         if (checkrules_overtimeend && time >= checkrules_overtimeend)
1617         {
1618                 NextLevel();
1619                 return;
1620         }
1621
1622         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1623         {
1624                 checkrules_oneminutewarning = TRUE;
1625                 sound(world, CHAN_AUTO, "announcer/robotic/1minuteremains.wav", VOL_BASE, ATTN_NONE);
1626         }
1627
1628         status = WinningCondition_RanOutOfSpawns();
1629         if(status == WINNING_YES)
1630         {
1631                 bprint("Hey! Someone ran out of spawns!\n");
1632         }
1633         else if(g_assault)
1634         {
1635                 status = WinningCondition_Assault(); // TODO remove this?
1636         }
1637         else if(g_lms)
1638         {
1639                 status = WinningCondition_LMS();
1640         }
1641         else if (g_onslaught)
1642         {
1643                 status = WinningCondition_Onslaught(); // TODO remove this?
1644         }
1645         else
1646         {
1647                 status = WinningCondition_Scores(fraglimit);
1648         }
1649
1650         if(status == WINNING_STARTOVERTIME)
1651         {
1652                 status = WINNING_NEVER;
1653                 InitiateOvertime();
1654         }
1655
1656         if(status == WINNING_NEVER)
1657                 // equality cases! Nobody wins if the overtime ends in a draw.
1658                 ClearWinners();
1659
1660         if(checkrules_overtimeend)
1661                 if(status != WINNING_NEVER || time >= checkrules_overtimeend)
1662                         status = WINNING_YES;
1663
1664         if(status == WINNING_YES)
1665                 NextLevel();
1666 };
1667
1668 float mapvote_nextthink;
1669 float mapvote_initialized;
1670 float mapvote_keeptwotime;
1671 float mapvote_timeout;
1672 string mapvote_message;
1673 string mapvote_screenshot_dir;
1674
1675 float mapvote_count;
1676 float mapvote_count_real;
1677 string mapvote_maps[MAPVOTE_COUNT];
1678 float mapvote_maps_suggested[MAPVOTE_COUNT];
1679 string mapvote_suggestions[MAPVOTE_COUNT];
1680 float mapvote_suggestion_ptr;
1681 float mapvote_maxlen;
1682 float mapvote_voters;
1683 float mapvote_votes[MAPVOTE_COUNT];
1684 float mapvote_run;
1685 float mapvote_detail;
1686 float mapvote_abstain;
1687 float mapvote_dirty;
1688 .float mapvote;
1689
1690 void MapVote_ClearAllVotes()
1691 {
1692         FOR_EACH_CLIENT(other)
1693                 other.mapvote = 0;
1694 }
1695
1696 string MapVote_Suggest(string m)
1697 {
1698         float i;
1699         if(m == "")
1700                 return "That's not how to use this command.";
1701         if(!cvar("g_maplist_votable_suggestions"))
1702                 return "Suggestions are not accepted on this server.";
1703         if(mapvote_initialized)
1704                 return "Can't suggest - voting is already in progress!";
1705 #ifdef MAPINFO
1706         m = MapInfo_FixName(m);
1707         if(!m)
1708                 return "The map you suggested is not available on this server.";
1709 #else
1710         if(!cvar("g_maplist_votable_suggestions_change_gametype"))
1711                 if(!IsSameGametype(m))
1712                         return "This server does not allow changing the game type by map suggestions.";
1713 #endif
1714         if(!cvar("g_maplist_votable_override_mostrecent"))
1715                 if(Map_IsRecent(m))
1716                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1717
1718 #ifdef MAPINFO
1719         if(!MapInfo_CheckMap(m))
1720                 return "The map you suggested does not support the current game mode.";
1721 #else
1722         if(!TryFile(strcat("maps/", m, ".mapcfg")))
1723                 return "The map you suggested is not available on this server.";
1724 #endif
1725         for(i = 0; i < mapvote_suggestion_ptr; ++i)
1726                 if(mapvote_suggestions[i] == m)
1727                         return "This map was already suggested.";
1728         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
1729         {
1730                 i = ceil(random() * mapvote_suggestion_ptr) - 1;
1731         }
1732         else
1733         {
1734                 i = mapvote_suggestion_ptr;
1735                 mapvote_suggestion_ptr += 1;
1736         }
1737         if(mapvote_suggestions[i] != "")
1738                 strunzone(mapvote_suggestions[i]);
1739         mapvote_suggestions[i] = strzone(m);
1740         if(cvar("sv_eventlog"))
1741                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)), TRUE);
1742         return strcat("Suggestion of ", m, " accepted.");
1743 }
1744
1745 void MapVote_AddVotable(string nextMap, float isSuggestion)
1746 {
1747         float j;
1748         if(nextMap == "")
1749                 return;
1750         for(j = 0; j < mapvote_count; ++j)
1751                 if(mapvote_maps[j] == nextMap)
1752                         return;
1753         if(strlen(nextMap) > mapvote_maxlen)
1754                 mapvote_maxlen = strlen(nextMap);
1755         mapvote_maps[mapvote_count] = strzone(nextMap);
1756         mapvote_maps_suggested[mapvote_count] = isSuggestion;
1757         mapvote_count += 1;
1758 }
1759
1760 void MapVote_SendData(float target);
1761 void MapVote_Init()
1762 {
1763         float i;
1764         float nmax, smax;
1765
1766         MapVote_ClearAllVotes();
1767
1768         mapvote_count = 0;
1769         mapvote_detail = !cvar("g_maplist_votable_nodetail");
1770         mapvote_abstain = cvar("g_maplist_votable_abstain");
1771
1772         if(mapvote_abstain)
1773                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
1774         else
1775                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
1776         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
1777
1778         if(mapvote_suggestion_ptr)
1779                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
1780                         MapVote_AddVotable(mapvote_suggestions[ceil(random() * mapvote_suggestion_ptr) - 1], TRUE);
1781
1782         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1783                 MapVote_AddVotable(GetNextMap(), FALSE);
1784
1785         if(mapvote_count == 0)
1786         {
1787                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1788 #ifdef MAPINFO
1789                 cvar_set("g_maplist", MapInfo_ListAllowedMaps());
1790                 localcmd("\nmenu_cmd sync\n");
1791 #else
1792                 cvar_set("g_maplist", cvar_string("g_maplist_defaultlist"));
1793 #endif
1794                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
1795                         MapVote_AddVotable(GetNextMap(), FALSE);
1796         }
1797
1798         mapvote_count_real = mapvote_count;
1799         if(mapvote_abstain)
1800                 MapVote_AddVotable("don't care", 0);
1801
1802         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
1803
1804         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
1805         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
1806         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
1807                 mapvote_keeptwotime = 0;
1808         mapvote_message = "Choose a map and press its key!";
1809
1810         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
1811         if(mapvote_screenshot_dir == "")
1812                 mapvote_screenshot_dir = "maps";
1813         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
1814
1815         if(!cvar("g_maplist_textonly"))
1816                 MapVote_SendData(MSG_ALL);
1817 }
1818
1819 void MapVote_SendPicture(float id)
1820 {
1821         msg_entity = self;
1822         WriteByte(MSG_ONE, SVC_TEMPENTITY);
1823         WriteByte(MSG_ONE, TE_CSQC_MAPVOTE);
1824         WriteByte(MSG_ONE, MAPVOTE_NET_PIC);
1825         WriteByte(MSG_ONE, id);
1826         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
1827 }
1828
1829 float GameCommand_MapVote(string cmd)
1830 {
1831         if(!intermission_running)
1832                 return FALSE;
1833         if(!cvar("g_maplist_textonly"))
1834         {
1835                 if(cmd == "mv_getpic")
1836                 {
1837                         MapVote_SendPicture(stof(argv(1)));
1838                         return TRUE;
1839                 }
1840         }
1841
1842         return FALSE;
1843 }
1844
1845 float MapVote_GetMapMask()
1846 {
1847         float mask, i, power;
1848         mask = 0;
1849         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
1850                 if(mapvote_maps[i] != "")
1851                         mask |= power;
1852         return mask;
1853 }
1854
1855 void MapVote_SendData(float targ)
1856 {
1857         string mapfile, pakfile;
1858         float i, o;
1859         WriteByte(targ, SVC_TEMPENTITY);
1860         WriteByte(targ, TE_CSQC_CONFIG);
1861         WriteString(targ, "mv_screenshot_dir");
1862         WriteString(targ, mapvote_screenshot_dir);
1863
1864         WriteByte(targ, SVC_TEMPENTITY);
1865         WriteByte(targ, TE_CSQC_MAPVOTE);
1866         WriteByte(targ, MAPVOTE_NET_INIT);
1867
1868         WriteByte(targ, mapvote_count);
1869         WriteByte(targ, mapvote_abstain);
1870         WriteByte(targ, mapvote_detail);
1871         WriteCoord(targ, mapvote_timeout);
1872         if(mapvote_count <= 8)
1873                 WriteByte(targ, MapVote_GetMapMask());
1874         else
1875                 WriteShort(targ, MapVote_GetMapMask());
1876         for(i = 0; i < mapvote_count; ++i)
1877                 if(mapvote_maps[i] != "")
1878                 {
1879                         WriteString(targ, mapvote_maps[i]);
1880                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
1881                         pakfile = whichpack(strcat(mapfile, ".tga"));
1882                         if(pakfile == "")
1883                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
1884                         if(pakfile == "")
1885                                 pakfile = whichpack(strcat(mapfile, ".png"));
1886                         print("pakfile is ", pakfile, "\n");
1887                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
1888                                 pakfile = substring(pakfile, o, 999);
1889                         WriteString(targ, pakfile);
1890                 }
1891 }
1892
1893 void MapVote_UpdateData(float targ)
1894 {
1895         float i;
1896         WriteByte(targ, SVC_TEMPENTITY);
1897         WriteByte(targ, TE_CSQC_MAPVOTE);
1898         WriteByte(targ, MAPVOTE_NET_UPDATE);
1899         if(mapvote_count <= 8)
1900                 WriteByte(targ, MapVote_GetMapMask());
1901         else
1902                 WriteShort(targ, MapVote_GetMapMask());
1903         if(mapvote_detail)
1904                 for(i = 0; i < mapvote_count; ++i)
1905                         if(mapvote_maps[i] != "")
1906                                 WriteByte(targ, mapvote_votes[i]);
1907 }
1908
1909 void MapVote_TellVote(float targ, float vote)
1910 {
1911         WriteByte(targ, SVC_TEMPENTITY);
1912         WriteByte(targ, TE_CSQC_MAPVOTE);
1913         WriteByte(targ, MAPVOTE_NET_OWNVOTE);
1914         WriteByte(targ, vote);
1915 }
1916
1917 float MapVote_Finished(float mappos)
1918 {
1919         string result;
1920         float i;
1921         float didntvote;
1922
1923         if(cvar("sv_eventlog"))
1924         {
1925                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
1926                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
1927                 didntvote = mapvote_voters;
1928                 for(i = 0; i < mapvote_count; ++i)
1929                         if(mapvote_maps[i] != "")
1930                         {
1931                                 didntvote -= mapvote_votes[i];
1932                                 if(i != mappos)
1933                                 {
1934                                         result = strcat(result, ":", mapvote_maps[i]);
1935                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
1936                                 }
1937                         }
1938                 result = strcat(result, ":didn't vote:", ftos(didntvote));
1939
1940                 GameLogEcho(result, FALSE);
1941                 if(mapvote_maps_suggested[mappos])
1942                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]), FALSE);
1943         }
1944
1945         FOR_EACH_REALCLIENT(other)
1946                 FixClientCvars(other);
1947
1948         Map_Goto_SetStr(mapvote_maps[mappos]);
1949         Map_Goto();
1950         alreadychangedlevel = TRUE;
1951         return TRUE;
1952 }
1953 void MapVote_CheckRules_1()
1954 {
1955         float i;
1956
1957         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
1958         {
1959                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
1960                 mapvote_votes[i] = 0;
1961         }
1962
1963         mapvote_voters = 0;
1964         FOR_EACH_REALCLIENT(other)
1965         {
1966                 ++mapvote_voters;
1967                 if(other.mapvote)
1968                 {
1969                         i = other.mapvote - 1;
1970                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
1971                         mapvote_votes[i] = mapvote_votes[i] + 1;
1972                 }
1973         }
1974 }
1975
1976 float MapVote_CheckRules_2()
1977 {
1978         float i;
1979         float firstPlace, secondPlace;
1980         float firstPlaceVotes, secondPlaceVotes;
1981         float mapvote_voters_real;
1982         string result;
1983
1984         mapvote_voters_real = mapvote_voters;
1985         if(mapvote_abstain)
1986                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
1987
1988         RandomSelection_Init();
1989         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
1990                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
1991         firstPlace = RandomSelection_chosen_float;
1992         firstPlaceVotes = RandomSelection_best_priority;
1993         //dprint("First place: ", ftos(firstPlace), "\n");
1994         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
1995
1996         RandomSelection_Init();
1997         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
1998                 if(i != firstPlace)
1999                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2000         secondPlace = RandomSelection_chosen_float;
2001         secondPlaceVotes = RandomSelection_best_priority;
2002         //dprint("Second place: ", ftos(secondPlace), "\n");
2003         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2004
2005         if(firstPlace == -1)
2006                 error("No first place in map vote... WTF?");
2007
2008         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2009                 return MapVote_Finished(firstPlace);
2010
2011         if(mapvote_keeptwotime)
2012                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2013                 {
2014                         float didntvote;
2015                         mapvote_dirty = TRUE;
2016                         mapvote_message = "Now decide between the TOP TWO!";
2017                         mapvote_keeptwotime = 0;
2018                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2019                         result = strcat(result, ":", ftos(firstPlaceVotes));
2020                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2021                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2022                         didntvote = mapvote_voters;
2023                         for(i = 0; i < mapvote_count; ++i)
2024                                 if(mapvote_maps[i] != "")
2025                                 {
2026                                         didntvote -= mapvote_votes[i];
2027                                         if(i != firstPlace)
2028                                                 if(i != secondPlace)
2029                                                 {
2030                                                         result = strcat(result, ":", mapvote_maps[i]);
2031                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2032                                                         if(i < mapvote_count_real)
2033                                                         {
2034                                                                 strunzone(mapvote_maps[i]);
2035                                                                 mapvote_maps[i] = "";
2036                                                         }
2037                                                 }
2038                                 }
2039                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2040                         if(cvar("sv_eventlog"))
2041                                 GameLogEcho(result, FALSE);
2042                 }
2043
2044         return FALSE;
2045 }
2046 void MapVote_Tick()
2047 {
2048         string msgstr;
2049         string tmp;
2050         float i;
2051         float keeptwo;
2052         float totalvotes;
2053
2054         keeptwo = mapvote_keeptwotime;
2055         MapVote_CheckRules_1(); // count
2056         if(MapVote_CheckRules_2()) // decide
2057                 return;
2058
2059         totalvotes = 0;
2060         FOR_EACH_REALCLIENT(other)
2061         {
2062                 // hide scoreboard again
2063                 if(other.health != 2342)
2064                 {
2065                         other.health = 2342;
2066                         other.impulse = 0;
2067                         if(clienttype(other) == CLIENTTYPE_REAL)
2068                         {
2069                                 if(cvar("g_maplist_textonly"))
2070                                         stuffcmd(other, "\nin_bind 7 1 \"impulse 1\"; in_bind 7 2 \"impulse 2\"; in_bind 7 3 \"impulse 3\"; in_bind 7 4 \"impulse 4\"; in_bind 7 5 \"impulse 5\"; in_bind 7 6 \"impulse 6\"; in_bind 7 7 \"impulse 7\"; in_bind 7 8 \"impulse 8\"; in_bind 7 9 \"impulse 9\"; in_bind 7 0 \"impulse 10\"; in_bind 7 KP_1 \"impulse 1\"; in_bind 7 KP_2 \"impulse 2\"; in_bind 7 KP_3 \"impulse 3\"; in_bind 7 KP_4 \"impulse 4\"; in_bind 7 KP_5 \"impulse 5\"; in_bind 7 KP_6 \"impulse 6\"; in_bind 7 KP_7 \"impulse 7\"; in_bind 7 KP_8 \"impulse 8\"; in_bind 7 KP_9 \"impulse 9\"; in_bind 7 KP_0 \"impulse 10\"; in_bindmap 7 0\n");
2071
2072                                 msg_entity = other;
2073                                 WriteByte(MSG_ONE, SVC_FINALE);
2074                                 WriteString(MSG_ONE, "");
2075                         }
2076                 }
2077
2078                 // notify about keep-two
2079                 if(keeptwo != 0 && mapvote_keeptwotime == 0)
2080                         play2(other, "misc/invshot.wav");
2081
2082                 // clear possibly invalid votes
2083                 if(mapvote_maps[other.mapvote - 1] == "")
2084                         other.mapvote = 0;
2085                 // use impulses as new vote
2086                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2087                         if(mapvote_maps[other.impulse - 1] != "")
2088                         {
2089                                 other.mapvote = other.impulse;
2090                                 if(mapvote_detail)
2091                                         mapvote_dirty = TRUE;
2092
2093                                 msg_entity = other;
2094                                 MapVote_TellVote(MSG_ONE, other.mapvote);
2095                         }
2096                 other.impulse = 0;
2097
2098                 if(other.mapvote)
2099                         ++totalvotes;
2100         }
2101
2102         MapVote_CheckRules_1(); // just count
2103
2104         if(!cvar("g_maplist_textonly"))
2105         if(mapvote_dirty) // 1 if "keeptwo" or "impulse" happened before
2106         {
2107                 MapVote_UpdateData(MSG_BROADCAST);
2108                 mapvote_dirty = FALSE;
2109         }
2110
2111         if(cvar("g_maplist_textonly"))
2112         {
2113                 FOR_EACH_REALCLIENT(other)
2114                 {
2115                         // display voting screen
2116                         msgstr = "\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n\n";
2117                         msgstr = substring(msgstr, 0, strlen(msgstr) - mapvote_count);
2118                         if(mapvote_abstain)
2119                                 msgstr = substring(msgstr, 1, strlen(msgstr) - 1);
2120                         msgstr = strcat(msgstr, mapvote_message);
2121                         msgstr = strcat(msgstr, "\n\n");
2122                         for(i = 0; i < mapvote_count; ++i)
2123                                 if(mapvote_maps[i] == "")
2124                                         msgstr = strcat(msgstr, "\n");
2125                                 else
2126                                 {
2127                                         tmp = mapvote_maps[i];
2128                                         tmp = strpad(mapvote_maxlen, tmp);
2129                                         tmp = strcat(ftos(mod(i + 1, 10)), ": ", tmp);
2130                                         if(mapvote_detail)
2131                                         {
2132                                                 tmp = strcat(tmp, " ^2(", ftos(mapvote_votes[i]), " vote");
2133                                                 if(mapvote_votes[i] != 1)
2134                                                         tmp = strcat(tmp, "s");
2135                                                 tmp = strcat(tmp, ")");
2136                                                 tmp = strpad(mapvote_maxlen + 15, tmp);
2137                                         }
2138                                         if(mapvote_abstain)
2139                                                 if(i == mapvote_count - 1)
2140                                                         msgstr = strcat(msgstr, "\n");
2141                                         if(other.mapvote == i + 1)
2142                                                 msgstr = strcat(msgstr, "^3> ", tmp, "\n");
2143                                         else
2144                                                 msgstr = strcat(msgstr, "^7  ", tmp, "\n");
2145                                 }
2146
2147                         msgstr = strcat(msgstr, "\n\n^2", ftos(totalvotes), " vote");
2148                         if(totalvotes != 1)
2149                                 msgstr = strcat(msgstr, "s");
2150                         msgstr = strcat(msgstr, " cast");
2151                         i = ceil(mapvote_timeout - time);
2152                         msgstr = strcat(msgstr, "\n", ftos(i), " second");
2153                         if(i != 1)
2154                                 msgstr = strcat(msgstr, "s");
2155                         msgstr = strcat(msgstr, " left");
2156
2157                         centerprint_atprio(other, CENTERPRIO_MAPVOTE, msgstr);
2158                 }
2159         }
2160 }
2161 void MapVote_Start()
2162 {
2163         if(mapvote_run)
2164                 return;
2165
2166 #ifdef MAPINFO
2167         MapInfo_Enumerate();
2168         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 1))
2169 #endif
2170                 mapvote_run = TRUE;
2171 }
2172 void MapVote_Think()
2173 {
2174         if(!mapvote_run)
2175                 return;
2176
2177         if(alreadychangedlevel)
2178                 return;
2179
2180         if(time < mapvote_nextthink)
2181                 return;
2182         //dprint("tick\n");
2183
2184         mapvote_nextthink = time + 0.5;
2185
2186         if(!mapvote_initialized)
2187         {
2188                 mapvote_initialized = TRUE;
2189                 if(DoNextMapOverride())
2190                         return;
2191                 if(!cvar("g_maplist_votable") || player_count <= 0)
2192                 {
2193                         GotoNextMap();
2194                         return;
2195                 }
2196                 MapVote_Init();
2197         }
2198
2199         MapVote_Tick();
2200 };
2201
2202 string GotoMap(string m)
2203 {
2204 #ifdef MAPINFO
2205         if(!MapInfo_CheckMap(m))
2206 #else
2207         if(!TryFile(strcat("maps/", m, ".mapcfg")))
2208 #endif
2209                 return "The map you chose is not available on this server.";
2210         cvar_set("nextmap", m);
2211         cvar_set("timelimit", "-1");
2212         if(mapvote_initialized || alreadychangedlevel)
2213         {
2214                 if(DoNextMapOverride())
2215                         return "Map switch initiated.";
2216                 else
2217                         return "Hm... no. For some reason I like THIS map more.";
2218         }
2219         else
2220                 return "Map switch will happen after scoreboard.";
2221 }
2222
2223
2224 void EndFrame()
2225 {
2226         FOR_EACH_REALCLIENT(self)
2227         {
2228                 if(self.classname == "spectator")
2229                 {
2230                         if(self.enemy.hitsound)
2231                                 play2(self, "misc/hit.wav");
2232                 }
2233                 else
2234                 {
2235                         if(self.hitsound)
2236                                 play2(self, "misc/hit.wav");
2237                 }
2238         }
2239         FOR_EACH_CLIENT(self)
2240                 self.hitsound = FALSE;
2241 }
2242
2243
2244 /*
2245  * RedirectionThink:
2246  * returns TRUE if redirecting
2247  */
2248 float redirection_timeout;
2249 float redirection_nextthink;
2250 float RedirectionThink()
2251 {
2252         float clients_found;
2253
2254         if(redirection_target == "")
2255                 return FALSE;
2256
2257         if(!redirection_timeout)
2258         {
2259                 cvar_set("sv_public", "-2");
2260                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2261                 if(redirection_target == "self")
2262                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2263                 else
2264                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2265         }
2266
2267         if(time < redirection_nextthink)
2268                 return TRUE;
2269
2270         redirection_nextthink = time + 1;
2271
2272         clients_found = 0;
2273         FOR_EACH_REALCLIENT(self)
2274         {
2275                 ServerConsoleEcho(strcat("Redirecting: sending connect command to ", self.netname), FALSE);
2276                 if(redirection_target == "self")
2277                         stuffcmd(self, "\ndisconnect; reconnect\n");
2278                 else
2279                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2280                 ++clients_found;
2281         }
2282
2283         ServerConsoleEcho(strcat("Redirecting: ", ftos(clients_found), " clients left."), FALSE);
2284
2285         if(time > redirection_timeout || clients_found == 0)
2286                 localcmd("\nwait; wait; wait; quit\n");
2287
2288         return TRUE;
2289 }
2290
2291 void RestoreGame()
2292 {
2293         // Loaded from a save game
2294         // some things then break, so let's work around them...
2295
2296         // Progs DB (capture records)
2297         if(sv_cheats)
2298                 ServerProgsDB = db_create();
2299         else
2300                 ServerProgsDB = db_load("server.db");
2301
2302         // Mapinfo
2303 #ifdef MAPINFO
2304         MapInfo_Shutdown();
2305         MapInfo_Enumerate();
2306         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 1);
2307 #endif
2308 }
2309
2310 void SV_Shutdown()
2311 {
2312         if(world_initialized)
2313         {
2314                 world_initialized = 0;
2315                 print("Saving persistent data...\n");
2316                 Ban_SaveBans();
2317                 if(!sv_cheats)
2318                         db_save(ServerProgsDB, "server.db");
2319                 db_close(ServerProgsDB);
2320                 print("done!\n");
2321                 // tell the bot system the game is ending now
2322                 bot_endgame();
2323
2324                 MapInfo_Shutdown();
2325         }
2326         else
2327         {
2328                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2329         }
2330 }