data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         //reset all the flood variables
  83                         FOR_EACH_CLIENT(plr) {
  84                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
  85                         }
  86                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  87                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  88                         FOR_EACH_REALPLAYER(plr) {
  89                                 plr.lastV_angle = plr.v_angle;
  90                         }
  91                         self.nextthink = time;
  92                 }
  93         }
  94         else if (timeoutStatus == 2) {
  95                 if (remainingTimeoutTime > 0) {
  96                         timeStr = getTimeoutText(0);
  97                         FOR_EACH_REALCLIENT(plr) {
  98                                 if(plr.classname == "player") {
  99                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 100                                 }
 101                         }
 102                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 103                                 play2all("announcer/robotic/prepareforbattle.wav");
 104                         }
 105                         remainingTimeoutTime -= 1;
 106                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 107                 }
 108                 else {
 109                         //unpause the game again
 110                         remainingTimeoutTime = timeoutStatus = 0;
 111                         cvar_set("slowmo", ftos(orig_slowmo));
 112                         //and unlock the fixed view again once there is no timeout active anymore
 113                         FOR_EACH_REALPLAYER(plr) {
 114                                 plr.fixangle = FALSE;
 115                         }
 116                         //get rid of the countdown message
 117                         FOR_EACH_REALCLIENT(plr) {
 118                                 if(plr.classname == "player") {
 119                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 120                                 }
 121                         }
 122                         remove(self);
 123                         return;
 124                 }
 125
 126         }
 127         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 128                 FOR_EACH_REALCLIENT(plr) {
 129                         if(plr.classname == "player") {
 130                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 131                         }
 132                 }
 133                 remove(self);
 134                 return;
 135         }
 136 }
 137
 138 void GotoFirstMap()
 139 {
 140         float n;
 141         if(cvar("_sv_init"))
 142         {
 143                 // cvar_set("_sv_init", "0");
 144                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 145                 // to this "init" map on a dedicated server will cause no permanent
 146                 // harm
 147                 if(cvar("g_maplist_shuffle"))
 148                         ShuffleMaplist();
 149                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 150                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 151
 152                 MapInfo_Enumerate();
 153                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 154
 155                 if(!DoNextMapOverride())
 156                         GotoNextMap();
 157
 158                 return;
 159         }
 160
 161         if(time < 5)
 162         {
 163                 self.nextthink = time;
 164         }
 165         else
 166         {
 167                 self.nextthink = time + 1;
 168                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 169         }
 170 }
 171
 172 void cvar_changes_init()
 173 {
 174         float h;
 175         string k, v, d;
 176         float n, i;
 177
 178         if(cvar_changes)
 179                 strunzone(cvar_changes);
 180         cvar_changes = string_null;
 181
 182         h = buf_create();
 183         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 184         n = buf_getsize(h);
 185
 186         for(i = 0; i < n; ++i)
 187         {
 188                 k = bufstr_get(h, i);
 189
 190 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 191 #define BADCVAR(p) if(k == p) continue
 192                 // internal
 193                 BADPREFIX("csqc_");
 194                 BADPREFIX("cvar_check_");
 195                 BADCVAR("gamecfg");
 196                 BADCVAR("g_configversion");
 197                 BADCVAR("g_maplist_index");
 198                 BADCVAR("halflifebsp");
 199
 200                 // client
 201                 BADPREFIX("cl_");
 202                 BADPREFIX("con_");
 203                 BADPREFIX("g_campaign");
 204                 BADPREFIX("gl_");
 205                 BADPREFIX("joy");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("userbind");
 212                 BADPREFIX("v_");
 213                 BADPREFIX("vid_");
 214                 BADPREFIX("crosshair");
 215                 BADCVAR("mod_q3bsp_lightmapmergepower");
 216                 BADCVAR("mod_q3bsp_nolightmaps");
 217
 218                 // private
 219                 BADPREFIX("g_ban_");
 220                 BADPREFIX("g_chat_flood_");
 221                 BADPREFIX("g_voice_flood_");
 222                 BADPREFIX("rcon_");
 223                 BADPREFIX("settemp_");
 224                 BADPREFIX("sv_allowdownloads_");
 225                 BADPREFIX("sv_autodemo");
 226                 BADPREFIX("sv_curl_");
 227                 BADPREFIX("sv_eventlog");
 228                 BADPREFIX("sv_logscores_");
 229                 BADPREFIX("sv_master");
 230                 BADCVAR("g_banned_list");
 231                 BADCVAR("log_dest_udp");
 232                 BADCVAR("log_file");
 233                 BADCVAR("net_address");
 234                 BADCVAR("port");
 235                 BADCVAR("savedgamecfg");
 236                 BADCVAR("sv_heartbeatperoid");
 237                 BADCVAR("sv_vote_master_password");
 238                 BADCVAR("sys_colortranslation");
 239                 BADCVAR("sys_specialcharactertranslation");
 240                 BADCVAR("timestamps");
 241
 242                 // mapinfo
 243                 BADCVAR("timelimit");
 244                 BADCVAR("fraglimit");
 245                 BADCVAR("g_arena");
 246                 BADCVAR("g_assault");
 247                 BADCVAR("g_ctf");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_keyhunt");
 251                 BADCVAR("g_keyhunt_teams");
 252                 BADCVAR("g_onslaught");
 253                 BADCVAR("g_race");
 254                 BADCVAR("g_runematch");
 255                 BADCVAR("g_tdm");
 256                 BADCVAR("teamplay");
 257
 258                 // long
 259                 BADCVAR("hostname");
 260                 BADCVAR("g_maplist");
 261                 BADCVAR("g_maplist_mostrecent");
 262                 BADCVAR("sv_motd");
 263 #undef BADPREFIX
 264 #undef BADCVAR
 265
 266                 v = cvar_string(k);
 267                 d = cvar_defstring(k);
 268                 if(v != d)
 269                 {
 270                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 271                         if(strlen(cvar_changes) > 16384)
 272                         {
 273                                 cvar_changes = "// too many settings have been changed to show them here\n";
 274                                 break;
 275                         }
 276                 }
 277         }
 278         buf_del(h);
 279         if(cvar_changes == "")
 280                 cvar_changes = "// this server runs at default settings\n";
 281         else
 282                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 283         cvar_changes = strzone(cvar_changes);
 284 }
 285
 286 void detect_maptype()
 287 {
 288 #if 0
 289         vector o, v;
 290         float i;
 291
 292         for(;;)
 293         {
 294                 o = world.mins;
 295                 o_x += random() * (world.maxs_x - world.mins_x);
 296                 o_y += random() * (world.maxs_y - world.mins_y);
 297                 o_z += random() * (world.maxs_z - world.mins_z);
 298
 299                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 300                 if(trace_fraction == 1)
 301                         continue;
 302
 303                 v = trace_endpos;
 304
 305                 for(i = 0; i < 64; i += 4)
 306                 {
 307                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 308         if(trace_fraction == 1)
 309                 continue;
 310                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 311                 }
 312
 313                 break;
 314         }
 315 #endif
 316 }
 317
 318 entity randomseed;
 319 float RandomSeed_Send(entity to, float sf)
 320 {
 321         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 322         WriteShort(MSG_ENTITY, self.cnt);
 323         return TRUE;
 324 }
 325 void RandomSeed_Think()
 326 {
 327         self.cnt = bound(0, floor(random() * 65536), 65535);
 328         self.nextthink = time + 5;
 329
 330         self.SendFlags |= 1;
 331 }
 332 void RandomSeed_Spawn()
 333 {
 334         randomseed = spawn();
 335         randomseed.think = RandomSeed_Think;
 336         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 337
 338         entity oldself;
 339         oldself = self;
 340         self = randomseed;
 341         self.think(); // sets random seed and nextthink
 342         self = oldself;
 343 }
 344
 345 void spawnfunc___init_dedicated_server(void)
 346 {
 347         // handler for _init/_init map (only for dedicated server initialization)
 348
 349         world_initialized = -1; // don't complain
 350         cvar = cvar_builtin;
 351         cvar_string = cvar_string_builtin;
 352         cvar_set = cvar_set_builtin;
 353         dprint_load(); // load dprint status from cvar
 354
 355         remove = remove_unsafely;
 356
 357         entity e;
 358         e = spawn();
 359         e.think = GotoFirstMap;
 360         e.nextthink = time; // this is usually 1 at this point
 361
 362         e = spawn();
 363         e.classname = "info_player_deathmatch"; // safeguard against player joining
 364
 365         self.classname = "worldspawn"; // safeguard against various stuff ;)
 366
 367         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 368         MapInfo_Enumerate();
 369         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 370 }
 371
 372 void Map_MarkAsRecent(string m);
 373 float world_already_spawned;
 374 void RegisterWeapons();
 375 void Nagger_Init();
 376 void ClientInit_Spawn();
 377 void spawnfunc_worldspawn (void)
 378 {
 379         float fd, l, i, j, n;
 380         string s, col;
 381
 382         cvar = cvar_builtin;
 383         cvar_string = cvar_string_builtin;
 384         cvar_set = cvar_set_builtin;
 385         dprint_load(); // load dprint status from cvar
 386
 387         if(world_already_spawned)
 388                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 389         world_already_spawned = TRUE;
 390
 391         remove = remove_safely; // during spawning, watch what you remove!
 392
 393         check_unacceptable_compiler_bugs();
 394
 395         if(cvar_string("cvar_check_default") != "bypass")
 396         {
 397                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 398                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 399
 400                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 401                         error("Config file mismatch! Please update weapons.cfg and weaponsHavoc.cfg to match the QuakeC code, and restart the engine!");
 402         }
 403
 404         compressShortVector_init();
 405
 406         local entity head;
 407         head = nextent(world);
 408         maxclients = 0;
 409         while(head)
 410         {
 411                 ++maxclients;
 412                 head = nextent(head);
 413         }
 414
 415         // needs to be done so early as they would still spawn
 416         RegisterWeapons();
 417
 418         if(sv_cheats)
 419                 ServerProgsDB = db_create();
 420         else
 421                 ServerProgsDB = db_load("server.db");
 422
 423         TemporaryDB = db_create();
 424
 425         /*
 426         TODO sound pack system
 427         // initialize sound pack system
 428         soundpack = cvar_string("g_soundpack");
 429         if(soundpack != "")
 430                 soundpack = strcat(soundpack, "/");
 431         soundpack = strzone(soundpack);
 432         */
 433
 434         // 0 normal
 435         lightstyle(0, "m");
 436
 437         // 1 FLICKER (first variety)
 438         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 439
 440         // 2 SLOW STRONG PULSE
 441         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 442
 443         // 3 CANDLE (first variety)
 444         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 445
 446         // 4 FAST STROBE
 447         lightstyle(4, "mamamamamama");
 448
 449         // 5 GENTLE PULSE 1
 450         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 451
 452         // 6 FLICKER (second variety)
 453         lightstyle(6, "nmonqnmomnmomomno");
 454
 455         // 7 CANDLE (second variety)
 456         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 457
 458         // 8 CANDLE (third variety)
 459         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 460
 461         // 9 SLOW STROBE (fourth variety)
 462         lightstyle(9, "aaaaaaaazzzzzzzz");
 463
 464         // 10 FLUORESCENT FLICKER
 465         lightstyle(10, "mmamammmmammamamaaamammma");
 466
 467         // 11 SLOW PULSE NOT FADE TO BLACK
 468         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 469
 470         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 471
 472         // 63 testing
 473         lightstyle(63, "a");
 474
 475         if(cvar("g_campaign"))
 476                 CampaignPreInit();
 477
 478         Map_MarkAsRecent(mapname);
 479
 480         precache_model ("null"); // we need this one before InitGameplayMode
 481         InitGameplayMode();
 482         readlevelcvars();
 483         GrappleHookInit();
 484
 485         player_count = 0;
 486         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 487         if(bot_waypoints_for_items == 1)
 488                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 489                         bot_waypoints_for_items = 0;
 490
 491         // for setting by mapinfo
 492         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 493         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 494
 495         precache();
 496
 497         WaypointSprite_Init();
 498
 499         //if (g_domination)
 500         //      dom_init();
 501
 502         GameLogInit(); // prepare everything
 503         if(cvar("sv_eventlog"))
 504         {
 505                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 506                 s = strcat(s, ftos(random()));
 507                 matchid = strzone(s);
 508
 509                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 510                 s = ":gameinfo:mutators:LIST";
 511                 if(cvar("g_grappling_hook"))
 512                         s = strcat(s, ":grappling_hook");
 513                 if(!cvar("g_use_ammunition"))
 514                         s = strcat(s, ":no_use_ammunition");
 515                 if(!cvar("g_pickup_items"))
 516                         s = strcat(s, ":no_pickup_items");
 517                 if(cvar("g_instagib"))
 518                         s = strcat(s, ":instagib");
 519                 if(cvar_string("g_weaponarena") != "0")
 520                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 521                 if(cvar("g_nixnex"))
 522                         s = strcat(s, ":nixnex");
 523                 if(cvar("g_vampire"))
 524                         s = strcat(s, ":vampire");
 525                 if(cvar("g_laserguided_missile"))
 526                         s = strcat(s, ":laserguided_missile");
 527                 if(cvar("g_norecoil"))
 528                         s = strcat(s, ":norecoil");
 529                 if(cvar("g_midair"))
 530                         s = strcat(s, ":midair");
 531                 if(cvar("g_minstagib"))
 532                         s = strcat(s, ":minstagib");
 533                 GameLogEcho(s);
 534                 GameLogEcho(":gameinfo:end");
 535         }
 536         else
 537                 matchid = strzone(ftos(random()));
 538
 539         cvar_set("nextmap", "");
 540
 541         SetDefaultAlpha();
 542
 543         if(cvar("g_campaign"))
 544                 CampaignPostInit();
 545
 546         fteqcc_testbugs();
 547
 548         Ban_LoadBans();
 549
 550         //initialise globals related to sv_timeout
 551         sys_ticrate = cvar("sys_ticrate");
 552         orig_slowmo = cvar("slowmo");
 553
 554         MapInfo_Enumerate();
 555         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
 556
 557         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 558         {
 559                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 560                 if(fd != -1)
 561                 {
 562                         while((s = fgets(fd)))
 563                         {
 564                                 l = tokenize_console(s);
 565                                 if(l < 2)
 566                                         continue;
 567                                 if(argv(0) == "cd")
 568                                 {
 569                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 570                                         print("  cdtrack ", argv(2), "\n");
 571                                 }
 572                                 else if(argv(0) == "fog")
 573                                 {
 574                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 575                                         print("  \"fog\" \"", s, "\"\n");
 576                                 }
 577                                 else if(argv(0) == "set")
 578                                 {
 579                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 580                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 581                                 }
 582                                 else if(argv(0) != "//")
 583                                 {
 584                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 585                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 586                                 }
 587                         }
 588                         fclose(fd);
 589                 }
 590         }
 591
 592         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 593         addstat(STAT_WEAPONS, AS_INT, weapons);
 594         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 595         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 596         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 597         Nagger_Init();
 598
 599         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 600         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 601         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 602         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 603         addstat(STAT_DAMAGE_HITS, AS_INT, damage_hits);
 604         addstat(STAT_DAMAGE_FIRED, AS_INT, maxdamage_fired);
 605         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 606
 607         next_pingtime = time + 5;
 608         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 609
 610         detect_maptype();
 611
 612         lsmaps_reply = "^7Maps available: ";
 613         for(i = 0, j = 0; i < MapInfo_count; ++i)
 614         {
 615                 if(MapInfo_Get_ByID(i))
 616                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 617                         {
 618                                 if(mod(i, 2))
 619                                         col = "^2";
 620                                 else
 621                                         col = "^3";
 622                                 ++j;
 623                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 624                         }
 625         }
 626         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 627
 628         maplist_reply = "^7Maps in list: ";
 629         n = tokenize_console(cvar_string("g_maplist"));
 630         for(i = 0, j = 0; i < n; ++i)
 631         {
 632                 if(MapInfo_CheckMap(argv(i)))
 633                 {
 634                         if(mod(j, 2))
 635                                 col = "^2";
 636                         else
 637                                 col = "^3";
 638                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 639                         ++j;
 640                 }
 641         }
 642         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 643         MapInfo_ClearTemps();
 644
 645         records_reply = strzone(getrecords());
 646
 647         ClientInit_Spawn();
 648         RandomSeed_Spawn();
 649
 650         world_initialized = 1;
 651 }
 652
 653 void spawnfunc_light (void)
 654 {
 655         //makestatic (self); // Who the f___ did that?
 656         remove(self);
 657 }
 658
 659 float TryFile( string pFilename )
 660 {
 661         local float lHandle;
 662         dprint("TryFile(\"", pFilename, "\")\n");
 663         lHandle = fopen( pFilename, FILE_READ );
 664         if( lHandle != -1 ) {
 665                 fclose( lHandle );
 666                 return TRUE;
 667         } else {
 668                 return FALSE;
 669         }
 670 };
 671
 672 string GetGametype()
 673 {
 674         return GametypeNameFromType(game);
 675 }
 676
 677 string getmapname_stored;
 678 string GetMapname()
 679 {
 680         return mapname;
 681 }
 682
 683 float Map_Count, Map_Current;
 684 string Map_Current_Name;
 685
 686 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 687 float GetMaplistPosition()
 688 {
 689         float pos, idx;
 690         string map;
 691
 692         map = GetMapname();
 693         idx = cvar("g_maplist_index");
 694
 695         if(idx >= 0)
 696                 if(idx < Map_Count)
 697                         if(map == argv(idx))
 698                                 return idx;
 699
 700         for(pos = 0; pos < Map_Count; ++pos)
 701                 if(map == argv(pos))
 702                         return pos;
 703
 704         // resume normal maplist rotation if current map is not in g_maplist
 705         return idx;
 706 }
 707
 708 float MapHasRightSize(string map)
 709 {
 710         float fh;
 711         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 712         if(cvar("g_maplist_check_waypoints"))
 713         {
 714                 dprint("checkwp "); dprint(map);
 715                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 716                 if(fh < 0)
 717                 {
 718                         dprint(": no waypoints\n");
 719                         return FALSE;
 720                 }
 721                 dprint(": has waypoints\n");
 722                 fclose(fh);
 723         }
 724
 725         // open map size restriction file
 726         dprint("opensize "); dprint(map);
 727         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 728         if(fh >= 0)
 729         {
 730                 float mapmin, mapmax;
 731                 dprint(": ok, ");
 732                 mapmin = stof(fgets(fh));
 733                 mapmax = stof(fgets(fh));
 734                 fclose(fh);
 735                 if(player_count < mapmin)
 736                 {
 737                         dprint("not enough\n");
 738                         return FALSE;
 739                 }
 740                 if(player_count > mapmax)
 741                 {
 742                         dprint("too many\n");
 743                         return FALSE;
 744                 }
 745                 dprint("right size\n");
 746                 return TRUE;
 747         }
 748         dprint(": not found\n");
 749         return TRUE;
 750 }
 751
 752 string Map_Filename(float position)
 753 {
 754         return strcat("maps/", argv(position), ".bsp");
 755 }
 756
 757 string strwords(string s, float w)
 758 {
 759         float endpos;
 760         for(endpos = 0; w && endpos >= 0; --w)
 761                 endpos = strstrofs(s, " ", endpos + 1);
 762         if(endpos < 0)
 763                 return s;
 764         else
 765                 return substring(s, 0, endpos);
 766 }
 767
 768 float strhasword(string s, string w)
 769 {
 770         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 771 }
 772
 773 void Map_MarkAsRecent(string m)
 774 {
 775         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 776 }
 777
 778 float Map_IsRecent(string m)
 779 {
 780         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 781 }
 782
 783 float Map_Check(float position, float pass)
 784 {
 785         string filename;
 786         string map_next;
 787         map_next = argv(position);
 788         if(pass <= 1)
 789         {
 790                 if(Map_IsRecent(map_next))
 791                         return 0;
 792         }
 793         filename = Map_Filename(position);
 794         if(MapInfo_CheckMap(map_next))
 795         {
 796                 if(pass == 2)
 797                         return 1;
 798                 if(MapHasRightSize(map_next))
 799                         return 1;
 800                 return 0;
 801         }
 802         else
 803                 dprint( "Couldn't select '", filename, "'..\n" );
 804
 805         return 0;
 806 }
 807
 808 void Map_Goto_SetStr(string nextmapname)
 809 {
 810         if(getmapname_stored != "")
 811                 strunzone(getmapname_stored);
 812         if(nextmapname == "")
 813                 getmapname_stored = "";
 814         else
 815                 getmapname_stored = strzone(nextmapname);
 816 }
 817
 818 void Map_Goto_SetFloat(float position)
 819 {
 820         cvar_set("g_maplist_index", ftos(position));
 821         Map_Goto_SetStr(argv(position));
 822 }
 823
 824 void GameResetCfg()
 825 {
 826         // settings persist, except...
 827         localcmd("\nsettemp_restore\n");
 828 };
 829
 830 void Map_Goto()
 831 {
 832         GameResetCfg();
 833         MapInfo_LoadMap(getmapname_stored);
 834 }
 835
 836 // return codes of map selectors:
 837 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 838 //   -2 = permanent failure
 839 float() MaplistMethod_Iterate = // usual method
 840 {
 841         float pass, i;
 842
 843         for(pass = 1; pass <= 2; ++pass)
 844         {
 845                 for(i = 1; i < Map_Count; ++i)
 846                 {
 847                         float mapindex;
 848                         mapindex = mod(i + Map_Current, Map_Count);
 849                         if(Map_Check(mapindex, pass))
 850                                 return mapindex;
 851                 }
 852         }
 853         return -1;
 854 }
 855
 856 float() MaplistMethod_Repeat = // fallback method
 857 {
 858         if(Map_Check(Map_Current, 2))
 859                 return Map_Current;
 860         return -2;
 861 }
 862
 863 float() MaplistMethod_Random = // random map selection
 864 {
 865         float i, imax;
 866
 867         imax = 42;
 868
 869         for(i = 0; i <= imax; ++i)
 870         {
 871                 float mapindex;
 872                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 873                 if(Map_Check(mapindex, 1))
 874                         return mapindex;
 875         }
 876         return -1;
 877 }
 878
 879 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 880 // the exponent sets a bias on the map selection:
 881 // the higher the exponent, the less likely "shortly repeated" same maps are
 882 {
 883         float i, j, imax, insertpos;
 884
 885         imax = 42;
 886
 887         for(i = 0; i <= imax; ++i)
 888         {
 889                 string newlist;
 890
 891                 // now reinsert this at another position
 892                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 893                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 894                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 895                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 896
 897                 // insert the current map there
 898                 newlist = "";
 899                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 900                         newlist = strcat(newlist, " ", argv(j));
 901                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 902                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 903                         newlist = strcat(newlist, " ", argv(j));
 904                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 905                 cvar_set("g_maplist", newlist);
 906                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 907
 908                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 909                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 910                 if(Map_Check(Map_Current, 1))
 911                         return Map_Current;
 912         }
 913         return -1;
 914 }
 915
 916 void Maplist_Init()
 917 {
 918         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 919         if(Map_Count == 0)
 920         {
 921                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 922                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
 923                 if(cvar("g_maplist_shuffle"))
 924                         ShuffleMaplist();
 925                 localcmd("\nmenu_cmd sync\n");
 926                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 927         }
 928         if(Map_Count == 0)
 929                 error("empty maplist, cannot select a new map");
 930         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 931
 932         if(Map_Current_Name)
 933                 strunzone(Map_Current_Name);
 934         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 935         // this may or may not be correct, but who cares, in the worst case a map
 936         // isn't chosen in the first pass that should have been
 937 }
 938
 939 string GetNextMap()
 940 {
 941         float nextMap;
 942
 943         Maplist_Init();
 944         nextMap = -1;
 945
 946         if(nextMap == -1)
 947                 if(cvar("g_maplist_shuffle") > 0)
 948                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 949
 950         if(nextMap == -1)
 951                 if(cvar("g_maplist_selectrandom"))
 952                         nextMap = MaplistMethod_Random();
 953
 954         if(nextMap == -1)
 955                 nextMap = MaplistMethod_Iterate();
 956
 957         if(nextMap == -1)
 958                 nextMap = MaplistMethod_Repeat();
 959
 960         if(nextMap >= 0)
 961         {
 962                 Map_Goto_SetFloat(nextMap);
 963                 return getmapname_stored;
 964         }
 965
 966         return "";
 967 };
 968
 969 float DoNextMapOverride()
 970 {
 971         if(cvar("g_campaign"))
 972         {
 973                 CampaignPostIntermission();
 974                 alreadychangedlevel = TRUE;
 975                 return TRUE;
 976         }
 977         if(cvar("quit_when_empty"))
 978         {
 979                 if(player_count <= currentbots)
 980                 {
 981                         localcmd("quit\n");
 982                         alreadychangedlevel = TRUE;
 983                         return TRUE;
 984                 }
 985         }
 986         if(cvar_string("quit_and_redirect") != "")
 987         {
 988                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 989                 alreadychangedlevel = TRUE;
 990                 return TRUE;
 991         }
 992         if (cvar("samelevel")) // if samelevel is set, stay on same level
 993         {
 994                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 995                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 996                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 997                 localcmd("restart\n");
 998                 //changelevel (mapname);
 999                 alreadychangedlevel = TRUE;
1000                 return TRUE;
1001         }
1002         if(cvar_string("nextmap") != "")
1003                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1004                 {
1005                         Map_Goto_SetStr(cvar_string("nextmap"));
1006                         Map_Goto();
1007                         alreadychangedlevel = TRUE;
1008                         return TRUE;
1009                 }
1010         if(cvar("lastlevel"))
1011         {
1012                 GameResetCfg();
1013                 localcmd("set lastlevel 0\ntogglemenu\n");
1014                 alreadychangedlevel = TRUE;
1015                 return TRUE;
1016         }
1017         return FALSE;
1018 };
1019
1020 void GotoNextMap()
1021 {
1022         //local string nextmap;
1023         //local float n, nummaps;
1024         //local string s;
1025         if (alreadychangedlevel)
1026                 return;
1027         alreadychangedlevel = TRUE;
1028
1029         {
1030                 string nextMap;
1031                 float allowReset;
1032
1033                 for(allowReset = 1; allowReset >= 0; --allowReset)
1034                 {
1035                         nextMap = GetNextMap();
1036                         if(nextMap != "")
1037                                 break;
1038
1039                         if(allowReset)
1040                         {
1041                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1042                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
1043                                 if(cvar("g_maplist_shuffle"))
1044                                         ShuffleMaplist();
1045                                 localcmd("\nmenu_cmd sync\n");
1046                         }
1047                         else
1048                         {
1049                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1050                         }
1051                 }
1052                 Map_Goto();
1053         }
1054 };
1055
1056
1057 /*
1058 ============
1059 IntermissionThink
1060
1061 When the player presses attack or jump, change to the next level
1062 ============
1063 */
1064 .float autoscreenshot;
1065 void() MapVote_Start;
1066 void() MapVote_Think;
1067 float mapvote_initialized;
1068 void IntermissionThink()
1069 {
1070         FixIntermissionClient(self);
1071
1072         if(cvar("sv_autoscreenshot"))
1073         if(self.autoscreenshot > 0)
1074         if(time > self.autoscreenshot)
1075         {
1076                 self.autoscreenshot = -1;
1077                 if(clienttype(self) == CLIENTTYPE_REAL)
1078                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1079                 return;
1080         }
1081
1082         if (time < intermission_exittime)
1083                 return;
1084
1085         if(!mapvote_initialized)
1086                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1087                         return;
1088
1089         MapVote_Start();
1090 };
1091
1092 /*
1093 ============
1094 FindIntermission
1095
1096 Returns the entity to view from
1097 ============
1098 */
1099 /*
1100 entity FindIntermission()
1101 {
1102         local   entity spot;
1103         local   float cyc;
1104
1105 // look for info_intermission first
1106         spot = find (world, classname, "info_intermission");
1107         if (spot)
1108         {       // pick a random one
1109                 cyc = random() * 4;
1110                 while (cyc > 1)
1111                 {
1112                         spot = find (spot, classname, "info_intermission");
1113                         if (!spot)
1114                                 spot = find (spot, classname, "info_intermission");
1115                         cyc = cyc - 1;
1116                 }
1117                 return spot;
1118         }
1119
1120 // then look for the start position
1121         spot = find (world, classname, "info_player_start");
1122         if (spot)
1123                 return spot;
1124
1125 // testinfo_player_start is only found in regioned levels
1126         spot = find (world, classname, "testplayerstart");
1127         if (spot)
1128                 return spot;
1129
1130 // then look for the start position
1131         spot = find (world, classname, "info_player_deathmatch");
1132         if (spot)
1133                 return spot;
1134
1135         //objerror ("FindIntermission: no spot");
1136         return world;
1137 };
1138 */
1139
1140 /*
1141 ===============================================================================
1142
1143 RULES
1144
1145 ===============================================================================
1146 */
1147
1148 void DumpStats(float final)
1149 {
1150         local float file;
1151         local string s;
1152         local float to_console;
1153         local float to_eventlog;
1154         local float to_file;
1155         local float i;
1156
1157         to_console = cvar("sv_logscores_console");
1158         to_eventlog = cvar("sv_eventlog");
1159         to_file = cvar("sv_logscores_file");
1160
1161         if(!final)
1162         {
1163                 to_console = TRUE; // always print printstats replies
1164                 to_eventlog = FALSE; // but never print them to the event log
1165         }
1166
1167         if(to_eventlog)
1168                 if(cvar("sv_eventlog_console"))
1169                         to_console = FALSE; // otherwise we get the output twice
1170
1171         if(final)
1172                 s = ":scores:";
1173         else
1174                 s = ":status:";
1175         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1176
1177         if(to_console)
1178                 print(s, "\n");
1179         if(to_eventlog)
1180                 GameLogEcho(s);
1181         if(to_file)
1182         {
1183                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1184                 if(file == -1)
1185                         to_file = FALSE;
1186                 else
1187                         fputs(file, strcat(s, "\n"));
1188         }
1189
1190         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1191         if(to_console)
1192                 print(s, "\n");
1193         if(to_eventlog)
1194                 GameLogEcho(s);
1195         if(to_file)
1196                 fputs(file, strcat(s, "\n"));
1197
1198         FOR_EACH_CLIENT(other)
1199         {
1200                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1201                 {
1202                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1203                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1204                         if(other.classname == "player" || g_arena || g_lms)
1205                                 s = strcat(s, ftos(other.team), ":");
1206                         else
1207                                 s = strcat(s, "spectator:");
1208
1209                         if(to_console)
1210                                 print(s, other.netname, "\n");
1211                         if(to_eventlog)
1212                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1213                         if(to_file)
1214                                 fputs(file, strcat(s, other.netname, "\n"));
1215                 }
1216         }
1217
1218         if(teams_matter)
1219         {
1220                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1221                 if(to_console)
1222                         print(s, "\n");
1223                 if(to_eventlog)
1224                         GameLogEcho(s);
1225                 if(to_file)
1226                         fputs(file, strcat(s, "\n"));
1227
1228                 for(i = 1; i < 16; ++i)
1229                 {
1230                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1231                         s = strcat(s, ":", ftos(i));
1232                         if(to_console)
1233                                 print(s, "\n");
1234                         if(to_eventlog)
1235                                 GameLogEcho(s);
1236                         if(to_file)
1237                                 fputs(file, strcat(s, "\n"));
1238                 }
1239         }
1240
1241         if(to_console)
1242                 print(":end\n");
1243         if(to_eventlog)
1244                 GameLogEcho(":end");
1245         if(to_file)
1246         {
1247                 fputs(file, ":end\n");
1248                 fclose(file);
1249         }
1250 }
1251
1252 void FixIntermissionClient(entity e)
1253 {
1254         string s;
1255         if(!e.autoscreenshot) // initial call
1256         {
1257                 e.angles = e.v_angle;
1258                 e.angles_x = -e.angles_x;
1259                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1260                 e.health = -2342;
1261                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1262                 e.solid = SOLID_NOT;
1263                 e.movetype = MOVETYPE_NONE;
1264                 e.takedamage = DAMAGE_NO;
1265                 if(e.weaponentity)
1266                 {
1267                         e.weaponentity.effects = EF_NODRAW;
1268                         if (e.weaponentity.weaponentity)
1269                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1270                 }
1271                 if(clienttype(e) == CLIENTTYPE_REAL)
1272                 {
1273                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1274                         s = cvar_string("sv_intermission_cdtrack");
1275                         if(s != "")
1276                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1277                         msg_entity = e;
1278                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1279                 }
1280         }
1281
1282         //e.velocity = '0 0 0';
1283         //e.fixangle = TRUE;
1284
1285         // TODO halt weapon animation
1286 }
1287
1288
1289 /*
1290 go to the next level for deathmatch
1291 only called if a time or frag limit has expired
1292 */
1293 void NextLevel()
1294 {
1295         float minTotalFrags;
1296         float maxTotalFrags;
1297         float score;
1298         float f;
1299
1300         gameover = TRUE;
1301
1302         intermission_running = 1;
1303
1304 // enforce a wait time before allowing changelevel
1305         if(player_count > 0)
1306                 intermission_exittime = time + cvar("sv_mapchange_delay");
1307         else
1308                 intermission_exittime = -1;
1309
1310         /*
1311         WriteByte (MSG_ALL, SVC_CDTRACK);
1312         WriteByte (MSG_ALL, 3);
1313         WriteByte (MSG_ALL, 3);
1314         // done in FixIntermission
1315         */
1316
1317         //pos = FindIntermission ();
1318
1319         VoteReset();
1320
1321         DumpStats(TRUE);
1322
1323         if(cvar("sv_eventlog"))
1324                 GameLogEcho(":gameover");
1325
1326         GameLogClose();
1327
1328         FOR_EACH_CLIENT(other)
1329         {
1330                 FixIntermissionClient(other);
1331
1332                 if(other.winning)
1333                         bprint(other.netname, " ^7wins.\n");
1334         }
1335
1336         minTotalFrags = 0;
1337         maxTotalFrags = 0;
1338         FOR_EACH_PLAYER(other)
1339         {
1340                 if(maxTotalFrags < other.totalfrags)
1341                         maxTotalFrags = other.totalfrags;
1342                 if(minTotalFrags > other.totalfrags)
1343                         minTotalFrags = other.totalfrags;
1344         }
1345
1346         if(!currentbots)
1347         {
1348                 FOR_EACH_PLAYER(other)
1349                 {
1350                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1351                         f = bound(0, other.play_time / max(time, 1), 1);
1352                         // store some statistics?
1353                 }
1354         }
1355
1356         if(cvar("g_campaign"))
1357                 CampaignPreIntermission();
1358
1359         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1360 };
1361
1362 /*
1363 ============
1364 CheckRules_Player
1365
1366 Exit deathmatch games upon conditions
1367 ============
1368 */
1369 void CheckRules_Player()
1370 {
1371         if (gameover)   // someone else quit the game already
1372                 return;
1373
1374         if(self.deadflag == DEAD_NO)
1375                 self.play_time += frametime;
1376
1377         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1378         //   (div0: and that in CheckRules_World please)
1379 };
1380
1381 float checkrules_equality;
1382 float checkrules_suddendeathwarning;
1383 float checkrules_suddendeathend;
1384 float checkrules_overtimesadded; //how many overtimes have been already added
1385 float checkrules_status;
1386
1387 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1388 float WINNING_YES = 1; // winner found
1389 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1390 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1391
1392 void InitiateOvertime()
1393 {
1394         // Check first whether normal overtimes could be added before initiating suddendeath mode
1395         // - for this timelimit_overtime needs to be >0 of course
1396         // - also check the winning condition calculated in the previous frame and only add normal overtime
1397         //   again, if at the point at which timelimit would be extended again, still no winner was found
1398         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1399         {
1400                 ++checkrules_overtimesadded;
1401                 //add one more overtime by simply extending the timelimit
1402                 float tl;
1403                 tl = cvar("timelimit");
1404                 tl += cvar("timelimit_overtime");
1405                 cvar_set("timelimit", ftos(tl));
1406                 string minutesPlural;
1407                 if (cvar("timelimit_overtime") == 1)
1408                         minutesPlural = " ^3minute";
1409                 else
1410                         minutesPlural = " ^3minutes";
1411
1412                 bcenterprint(
1413                         strcat(
1414                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1415                                 ftos(cvar("timelimit_overtime")),
1416                                 minutesPlural,
1417                                 " to the game!"
1418                         )
1419                 );
1420         }
1421         else
1422         {
1423                 if(!checkrules_suddendeathend)
1424                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1425         }
1426 }
1427
1428 float GetWinningCode(float fraglimitreached, float equality)
1429 {
1430         if(equality)
1431                 if(fraglimitreached)
1432                         return WINNING_STARTSUDDENDEATHOVERTIME;
1433                 else
1434                         return WINNING_NEVER;
1435         else
1436                 if(fraglimitreached)
1437                         return WINNING_YES;
1438                 else
1439                         return WINNING_NO;
1440 }
1441
1442 // set the .winning flag for exactly those players with a given field value
1443 void SetWinners(.float field, float value)
1444 {
1445         entity head;
1446         FOR_EACH_PLAYER(head)
1447                 head.winning = (head.field == value);
1448 }
1449
1450 // set the .winning flag for those players with a given field value
1451 void AddWinners(.float field, float value)
1452 {
1453         entity head;
1454         FOR_EACH_PLAYER(head)
1455                 if(head.field == value)
1456                         head.winning = 1;
1457 }
1458
1459 // clear the .winning flags
1460 void ClearWinners(void)
1461 {
1462         entity head;
1463         FOR_EACH_PLAYER(head)
1464                 head.winning = 0;
1465 }
1466
1467 // Onslaught winning condition:
1468 // game terminates if only one team has a working generator (or none)
1469 float WinningCondition_Onslaught()
1470 {
1471         entity head;
1472         local float t1, t2, t3, t4;
1473
1474         WinningConditionHelper(); // set worldstatus
1475
1476         // first check if the game has ended
1477         t1 = t2 = t3 = t4 = 0;
1478         head = find(world, classname, "onslaught_generator");
1479         while (head)
1480         {
1481                 if (head.health > 0)
1482                 {
1483                         if (head.team == COLOR_TEAM1) t1 = 1;
1484                         if (head.team == COLOR_TEAM2) t2 = 1;
1485                         if (head.team == COLOR_TEAM3) t3 = 1;
1486                         if (head.team == COLOR_TEAM4) t4 = 1;
1487                 }
1488                 head = find(head, classname, "onslaught_generator");
1489         }
1490         if (t1 + t2 + t3 + t4 < 2)
1491         {
1492                 // game over, only one team remains (or none)
1493                 ClearWinners();
1494                 if (t1) SetWinners(team, COLOR_TEAM1);
1495                 if (t2) SetWinners(team, COLOR_TEAM2);
1496                 if (t3) SetWinners(team, COLOR_TEAM3);
1497                 if (t4) SetWinners(team, COLOR_TEAM4);
1498                 dprint("Have a winner, ending game.\n");
1499                 return WINNING_YES;
1500         }
1501
1502         // Two or more teams remain
1503         return WINNING_NO;
1504 }
1505
1506 float LMS_NewPlayerLives()
1507 {
1508         float fl;
1509         fl = cvar("fraglimit");
1510         if(fl == 0)
1511                 fl = 999;
1512
1513         // first player has left the game for dying too much? Nobody else can get in.
1514         if(lms_lowest_lives < 1)
1515                 return 0;
1516
1517         if(!cvar("g_lms_join_anytime"))
1518                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1519                         return 0;
1520
1521         return bound(1, lms_lowest_lives, fl);
1522 }
1523
1524 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1525 // they win. Otherwise the defending team wins once the timelimit passes.
1526 void assault_new_round();
1527 float WinningCondition_Assault()
1528 {
1529         local float status;
1530
1531         WinningConditionHelper(); // set worldstatus
1532
1533         status = WINNING_NO;
1534         // as the timelimit has not yet passed just assume the defending team will win
1535         if(assault_attacker_team == COLOR_TEAM1)
1536         {
1537                 SetWinners(team, COLOR_TEAM2);
1538         }
1539         else
1540         {
1541                 SetWinners(team, COLOR_TEAM1);
1542         }
1543
1544         local entity ent;
1545         ent = find(world, classname, "target_assault_roundend");
1546         if(ent)
1547         {
1548                 if(ent.winning) // round end has been triggered by attacking team
1549                 {
1550                         bprint("ASSAULT: round completed...\n");
1551                         SetWinners(team, assault_attacker_team);
1552
1553                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1554
1555                         if(ent.cnt == 1) // this was the second round
1556                         {
1557                                 status = WINNING_YES;
1558                         }
1559                         else
1560                         {
1561                                 local entity oldself;
1562                                 oldself = self;
1563                                 self = ent;
1564                                 assault_new_round();
1565                                 self = oldself;
1566                         }
1567                 }
1568         }
1569
1570         return status;
1571 }
1572
1573 // LMS winning condition: game terminates if and only if there's at most one
1574 // one player who's living lives. Top two scores being equal cancels the time
1575 // limit.
1576 float WinningCondition_LMS()
1577 {
1578         entity head, head2;
1579         float have_player;
1580         float have_players;
1581         float l;
1582
1583         have_player = FALSE;
1584         have_players = FALSE;
1585         l = LMS_NewPlayerLives();
1586
1587         head = find(world, classname, "player");
1588         if(head)
1589                 have_player = TRUE;
1590         head2 = find(head, classname, "player");
1591         if(head2)
1592                 have_players = TRUE;
1593
1594         if(have_player)
1595         {
1596                 // we have at least one player
1597                 if(have_players)
1598                 {
1599                         // two or more active players - continue with the game
1600                 }
1601                 else
1602                 {
1603                         // exactly one player?
1604
1605                         ClearWinners();
1606                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1607
1608                         if(l)
1609                         {
1610                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1611                                 return WINNING_NO;
1612                         }
1613                         else
1614                         {
1615                                 // a winner!
1616                                 // and assign him his first place
1617                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1618                                 return WINNING_YES;
1619                         }
1620                 }
1621         }
1622         else
1623         {
1624                 // nobody is playing at all...
1625                 if(l)
1626                 {
1627                         // wait for players...
1628                 }
1629                 else
1630                 {
1631                         // SNAFU (maybe a draw game?)
1632                         ClearWinners();
1633                         dprint("No players, ending game.\n");
1634                         return WINNING_YES;
1635                 }
1636         }
1637
1638         // When we get here, we have at least two players who are actually LIVING,
1639         // now check if the top two players have equal score.
1640         WinningConditionHelper();
1641
1642         ClearWinners();
1643         if(WinningConditionHelper_winner)
1644                 WinningConditionHelper_winner.winning = TRUE;
1645         if(WinningConditionHelper_equality)
1646                 return WINNING_NEVER;
1647
1648         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1649         return WINNING_NO;
1650 }
1651
1652 void ShuffleMaplist()
1653 {
1654         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1655 }
1656
1657 float leaderfrags;
1658 float WinningCondition_Scores(float limit)
1659 {
1660         // TODO make everything use THIS winning condition (except LMS)
1661         WinningConditionHelper();
1662
1663         if(teams_matter)
1664         {
1665                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1666                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1667                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1668                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1669         }
1670
1671         ClearWinners();
1672         if(WinningConditionHelper_winner)
1673                 WinningConditionHelper_winner.winning = 1;
1674         if(WinningConditionHelper_winnerteam >= 0)
1675                 SetWinners(team, WinningConditionHelper_winnerteam);
1676
1677         if(WinningConditionHelper_lowerisbetter)
1678         {
1679                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1680                 limit = -limit;
1681         }
1682
1683         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying) || g_nexball)
1684         // these modes always score in increments of 1, thus this makes sense
1685         {
1686                 if(leaderfrags != WinningConditionHelper_topscore)
1687                 {
1688                         leaderfrags = WinningConditionHelper_topscore;
1689
1690                         if (limit)
1691                         if (leaderfrags == limit - 1)
1692                                 play2all("announcer/robotic/1fragleft.wav");
1693                         else if (leaderfrags == limit - 2)
1694                                 play2all("announcer/robotic/2fragsleft.wav");
1695                         else if (leaderfrags == limit - 3)
1696                                 play2all("announcer/robotic/3fragsleft.wav");
1697                 }
1698         }
1699
1700         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1701 }
1702
1703 float WinningCondition_Race(float fraglimit)
1704 {
1705         float wc;
1706         entity p;
1707         wc = WinningCondition_Scores(fraglimit);
1708
1709         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1710         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1711         // do NOT support equality when the laps are all raced!
1712         {
1713                 FOR_EACH_PLAYER(p)
1714                         if not(p.race_completed)
1715                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1716                 return WINNING_YES;
1717         }
1718         return wc;
1719 }
1720
1721 void ReadyRestart();
1722 float WinningCondition_QualifyingThenRace(float limit)
1723 {
1724         float wc;
1725         wc = WinningCondition_Scores(limit);
1726
1727         // NEVER initiate overtime
1728         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1729         {
1730                 return WINNING_YES;
1731         }
1732
1733         return wc;
1734 }
1735
1736 float WinningCondition_RanOutOfSpawns()
1737 {
1738         entity head;
1739
1740         if(!have_team_spawns)
1741                 return WINNING_NO;
1742
1743         if(!some_spawn_has_been_used)
1744                 return WINNING_NO;
1745
1746         team1_score = team2_score = team3_score = team4_score = 0;
1747
1748         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1749         {
1750                 if(head.team == COLOR_TEAM1)
1751                         team1_score = 1;
1752                 else if(head.team == COLOR_TEAM2)
1753                         team2_score = 1;
1754                 else if(head.team == COLOR_TEAM3)
1755                         team3_score = 1;
1756                 else if(head.team == COLOR_TEAM4)
1757                         team4_score = 1;
1758         }
1759
1760         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1761         {
1762                 if(head.team == COLOR_TEAM1)
1763                         team1_score = 1;
1764                 else if(head.team == COLOR_TEAM2)
1765                         team2_score = 1;
1766                 else if(head.team == COLOR_TEAM3)
1767                         team3_score = 1;
1768                 else if(head.team == COLOR_TEAM4)
1769                         team4_score = 1;
1770         }
1771
1772         ClearWinners();
1773         if(team1_score + team2_score + team3_score + team4_score == 0)
1774         {
1775                 checkrules_equality = TRUE;
1776                 return WINNING_YES;
1777         }
1778         else if(team1_score + team2_score + team3_score + team4_score == 1)
1779         {
1780                 float t, i;
1781                 if(team1_score) t = COLOR_TEAM1;
1782                 if(team2_score) t = COLOR_TEAM2;
1783                 if(team3_score) t = COLOR_TEAM3;
1784                 if(team4_score) t = COLOR_TEAM4;
1785                 CheckAllowedTeams(world);
1786                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1787                 {
1788                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1789                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1790                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1791                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1792                 }
1793
1794                 AddWinners(team, t);
1795                 return WINNING_YES;
1796         }
1797         else
1798                 return WINNING_NO;
1799 }
1800
1801 /*
1802 ============
1803 CheckRules_World
1804
1805 Exit deathmatch games upon conditions
1806 ============
1807 */
1808 void CheckRules_World()
1809 {
1810         local float timelimit;
1811         local float fraglimit;
1812
1813         VoteThink();
1814         MapVote_Think();
1815
1816         SetDefaultAlpha();
1817
1818         /*
1819         MapVote_Think should now do that part
1820         if (intermission_running)
1821                 if (time >= intermission_exittime + 60)
1822                 {
1823                         if(!DoNextMapOverride())
1824                                 GotoNextMap();
1825                         return;
1826                 }
1827         */
1828
1829         if (gameover)   // someone else quit the game already
1830         {
1831                 if(player_count == 0) // Nobody there? Then let's go to the next map
1832                         MapVote_Start();
1833                         // this will actually check the player count in the next frame
1834                         // again, but this shouldn't hurt
1835                 return;
1836         }
1837
1838         timelimit = cvar("timelimit") * 60;
1839         fraglimit = cvar("fraglimit");
1840
1841         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1842         {
1843                 if(timelimit > 0)
1844                         timelimit = 0; // timelimit is not made for warmup
1845                 if(fraglimit > 0)
1846                         fraglimit = 0; // no fraglimit for now
1847         }
1848
1849         if(timelimit > 0)
1850         {
1851                 timelimit += game_starttime;
1852         }
1853         else if (timelimit < 0)
1854         {
1855                 // endmatch
1856                 NextLevel();
1857                 return;
1858         }
1859
1860         if(checkrules_suddendeathend)
1861         {
1862                 if(!checkrules_suddendeathwarning)
1863                 {
1864                         checkrules_suddendeathwarning = TRUE;
1865                         if(g_race && !g_race_qualifying)
1866                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1867                         else
1868                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1869                 }
1870         }
1871         else
1872         {
1873                 if (timelimit && time >= timelimit)
1874                 {
1875                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1876                         {
1877                                 float totalplayers;
1878                                 float playerswithlaps;
1879                                 float readyplayers;
1880                                 entity head;
1881                                 totalplayers = playerswithlaps = readyplayers = 0;
1882                                 FOR_EACH_PLAYER(head)
1883                                 {
1884                                         ++totalplayers;
1885                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1886                                                 ++playerswithlaps;
1887                                         if(head.ready)
1888                                                 ++readyplayers;
1889                                 }
1890
1891                                 // at least 2/3 of the players have completed a lap: start the RACE
1892                                 // otherwise, the players should end the qualifying on their own
1893                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1894                                 {
1895                                         checkrules_suddendeathend = 0;
1896                                         ReadyRestart(); // go to race
1897                                 }
1898                                 else
1899                                         InitiateOvertime();
1900                         }
1901                         else
1902                                 InitiateOvertime();
1903                 }
1904         }
1905
1906         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1907         {
1908                 NextLevel();
1909                 return;
1910         }
1911
1912         checkrules_status = WinningCondition_RanOutOfSpawns();
1913         if(checkrules_status == WINNING_YES)
1914         {
1915                 bprint("Hey! Someone ran out of spawns!\n");
1916         }
1917         else if(g_race && !g_race_qualifying && timelimit >= 0)
1918         {
1919                 checkrules_status = WinningCondition_Race(fraglimit);
1920         }
1921         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1922         {
1923                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1924         }
1925         else if(g_assault)
1926         {
1927                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1928         }
1929         else if(g_lms)
1930         {
1931                 checkrules_status = WinningCondition_LMS();
1932         }
1933         else if (g_onslaught)
1934         {
1935                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1936         }
1937         else
1938         {
1939                 checkrules_status = WinningCondition_Scores(fraglimit);
1940         }
1941
1942         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1943         {
1944                 checkrules_status = WINNING_NEVER;
1945                 InitiateOvertime();
1946         }
1947
1948         if(checkrules_status == WINNING_NEVER)
1949                 // equality cases! Nobody wins if the overtime ends in a draw.
1950                 ClearWinners();
1951
1952         if(checkrules_suddendeathend)
1953                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1954                         checkrules_status = WINNING_YES;
1955
1956         if(checkrules_status == WINNING_YES)
1957                 NextLevel();
1958 };
1959
1960 float mapvote_nextthink;
1961 float mapvote_initialized;
1962 float mapvote_keeptwotime;
1963 float mapvote_timeout;
1964 string mapvote_message;
1965 string mapvote_screenshot_dir;
1966
1967 float mapvote_count;
1968 float mapvote_count_real;
1969 string mapvote_maps[MAPVOTE_COUNT];
1970 float mapvote_maps_suggested[MAPVOTE_COUNT];
1971 string mapvote_suggestions[MAPVOTE_COUNT];
1972 float mapvote_suggestion_ptr;
1973 float mapvote_maxlen;
1974 float mapvote_voters;
1975 float mapvote_votes[MAPVOTE_COUNT];
1976 float mapvote_run;
1977 float mapvote_detail;
1978 float mapvote_abstain;
1979 .float mapvote;
1980
1981 void MapVote_ClearAllVotes()
1982 {
1983         FOR_EACH_CLIENT(other)
1984                 other.mapvote = 0;
1985 }
1986
1987 string MapVote_Suggest(string m)
1988 {
1989         float i;
1990         if(m == "")
1991                 return "That's not how to use this command.";
1992         if(!cvar("g_maplist_votable_suggestions"))
1993                 return "Suggestions are not accepted on this server.";
1994         if(mapvote_initialized)
1995                 return "Can't suggest - voting is already in progress!";
1996         m = MapInfo_FixName(m);
1997         if(!m)
1998                 return "The map you suggested is not available on this server.";
1999         if(!cvar("g_maplist_votable_override_mostrecent"))
2000                 if(Map_IsRecent(m))
2001                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2002
2003         if(!MapInfo_CheckMap(m))
2004                 return "The map you suggested does not support the current game mode.";
2005         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2006                 if(mapvote_suggestions[i] == m)
2007                         return "This map was already suggested.";
2008         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2009         {
2010                 i = floor(random() * mapvote_suggestion_ptr);
2011         }
2012         else
2013         {
2014                 i = mapvote_suggestion_ptr;
2015                 mapvote_suggestion_ptr += 1;
2016         }
2017         if(mapvote_suggestions[i] != "")
2018                 strunzone(mapvote_suggestions[i]);
2019         mapvote_suggestions[i] = strzone(m);
2020         if(cvar("sv_eventlog"))
2021                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2022         return strcat("Suggestion of ", m, " accepted.");
2023 }
2024
2025 void MapVote_AddVotable(string nextMap, float isSuggestion)
2026 {
2027         float j;
2028         if(nextMap == "")
2029                 return;
2030         for(j = 0; j < mapvote_count; ++j)
2031                 if(mapvote_maps[j] == nextMap)
2032                         return;
2033         if(strlen(nextMap) > mapvote_maxlen)
2034                 mapvote_maxlen = strlen(nextMap);
2035         mapvote_maps[mapvote_count] = strzone(nextMap);
2036         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2037         mapvote_count += 1;
2038 }
2039
2040 void MapVote_Spawn();
2041 void MapVote_Init()
2042 {
2043         float i;
2044         float nmax, smax;
2045
2046         MapVote_ClearAllVotes();
2047
2048         mapvote_count = 0;
2049         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2050         mapvote_abstain = cvar("g_maplist_votable_abstain");
2051
2052         if(mapvote_abstain)
2053                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2054         else
2055                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2056         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2057
2058         if(mapvote_suggestion_ptr)
2059                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2060                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2061
2062         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2063                 MapVote_AddVotable(GetNextMap(), FALSE);
2064
2065         if(mapvote_count == 0)
2066         {
2067                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2068                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
2069                 if(cvar("g_maplist_shuffle"))
2070                         ShuffleMaplist();
2071                 localcmd("\nmenu_cmd sync\n");
2072                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2073                         MapVote_AddVotable(GetNextMap(), FALSE);
2074         }
2075
2076         mapvote_count_real = mapvote_count;
2077         if(mapvote_abstain)
2078                 MapVote_AddVotable("don't care", 0);
2079
2080         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2081
2082         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2083         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2084         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2085                 mapvote_keeptwotime = 0;
2086         mapvote_message = "Choose a map and press its key!";
2087
2088         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2089         if(mapvote_screenshot_dir == "")
2090                 mapvote_screenshot_dir = "maps";
2091         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2092
2093         MapVote_Spawn();
2094 }
2095
2096 void MapVote_SendPicture(float id)
2097 {
2098         msg_entity = self;
2099         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2100         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2101         WriteByte(MSG_ONE, id);
2102         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2103 }
2104
2105 float GameCommand_MapVote(string cmd)
2106 {
2107         if(!intermission_running)
2108                 return FALSE;
2109
2110         if(cmd == "mv_getpic")
2111         {
2112                 MapVote_SendPicture(stof(argv(1)));
2113                 return TRUE;
2114         }
2115
2116         return FALSE;
2117 }
2118
2119 float MapVote_GetMapMask()
2120 {
2121         float mask, i, power;
2122         mask = 0;
2123         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2124                 if(mapvote_maps[i] != "")
2125                         mask |= power;
2126         return mask;
2127 }
2128
2129 entity mapvote_ent;
2130 float MapVote_SendEntity(entity to, float sf)
2131 {
2132         string mapfile, pakfile;
2133         float i, o;
2134
2135         if(sf & 1)
2136                 sf &~= 2; // if we send 1, we don't need to also send 2
2137
2138         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2139         WriteByte(MSG_ENTITY, sf);
2140
2141         if(sf & 1)
2142         {
2143                 // flag 1 == initialization
2144                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2145                 WriteByte(MSG_ENTITY, mapvote_count);
2146                 WriteByte(MSG_ENTITY, mapvote_abstain);
2147                 WriteByte(MSG_ENTITY, mapvote_detail);
2148                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2149                 if(mapvote_count <= 8)
2150                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2151                 else
2152                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2153                 for(i = 0; i < mapvote_count; ++i)
2154                         if(mapvote_maps[i] != "")
2155                         {
2156                                 if(mapvote_abstain && i == mapvote_count - 1)
2157                                 {
2158                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2159                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2160                                 }
2161                                 else
2162                                 {
2163                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2164                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2165                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2166                                         if(pakfile == "")
2167                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2168                                         if(pakfile == "")
2169                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2170                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2171                                                 pakfile = substring(pakfile, o, 999);
2172                                         WriteString(MSG_ENTITY, pakfile);
2173                                 }
2174                         }
2175         }
2176
2177         if(sf & 2)
2178         {
2179                 // flag 2 == update of mask
2180                 if(mapvote_count <= 8)
2181                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2182                 else
2183                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2184         }
2185
2186         if(sf & 4)
2187         {
2188                 if(mapvote_detail)
2189                         for(i = 0; i < mapvote_count; ++i)
2190                                 if(mapvote_maps[i] != "")
2191                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2192
2193                 WriteByte(MSG_ENTITY, to.mapvote);
2194         }
2195
2196         return TRUE;
2197 }
2198
2199 void MapVote_Spawn()
2200 {
2201         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2202 }
2203
2204 void MapVote_TouchMask()
2205 {
2206         mapvote_ent.SendFlags |= 2;
2207 }
2208
2209 void MapVote_TouchVotes(entity voter)
2210 {
2211         mapvote_ent.SendFlags |= 4;
2212 }
2213
2214 float MapVote_Finished(float mappos)
2215 {
2216         string result;
2217         float i;
2218         float didntvote;
2219
2220         if(cvar("sv_eventlog"))
2221         {
2222                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2223                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2224                 didntvote = mapvote_voters;
2225                 for(i = 0; i < mapvote_count; ++i)
2226                         if(mapvote_maps[i] != "")
2227                         {
2228                                 didntvote -= mapvote_votes[i];
2229                                 if(i != mappos)
2230                                 {
2231                                         result = strcat(result, ":", mapvote_maps[i]);
2232                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2233                                 }
2234                         }
2235                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2236
2237                 GameLogEcho(result);
2238                 if(mapvote_maps_suggested[mappos])
2239                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2240         }
2241
2242         FOR_EACH_REALCLIENT(other)
2243                 FixClientCvars(other);
2244
2245         Map_Goto_SetStr(mapvote_maps[mappos]);
2246         Map_Goto();
2247         alreadychangedlevel = TRUE;
2248         return TRUE;
2249 }
2250 void MapVote_CheckRules_1()
2251 {
2252         float i;
2253
2254         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2255         {
2256                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2257                 mapvote_votes[i] = 0;
2258         }
2259
2260         mapvote_voters = 0;
2261         FOR_EACH_REALCLIENT(other)
2262         {
2263                 ++mapvote_voters;
2264                 if(other.mapvote)
2265                 {
2266                         i = other.mapvote - 1;
2267                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2268                         mapvote_votes[i] = mapvote_votes[i] + 1;
2269                 }
2270         }
2271 }
2272
2273 float MapVote_CheckRules_2()
2274 {
2275         float i;
2276         float firstPlace, secondPlace;
2277         float firstPlaceVotes, secondPlaceVotes;
2278         float mapvote_voters_real;
2279         string result;
2280
2281         if(mapvote_count_real == 1)
2282                 return MapVote_Finished(0);
2283
2284         mapvote_voters_real = mapvote_voters;
2285         if(mapvote_abstain)
2286                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2287
2288         RandomSelection_Init();
2289         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2290                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2291         firstPlace = RandomSelection_chosen_float;
2292         firstPlaceVotes = RandomSelection_best_priority;
2293         //dprint("First place: ", ftos(firstPlace), "\n");
2294         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2295
2296         RandomSelection_Init();
2297         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2298                 if(i != firstPlace)
2299                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2300         secondPlace = RandomSelection_chosen_float;
2301         secondPlaceVotes = RandomSelection_best_priority;
2302         //dprint("Second place: ", ftos(secondPlace), "\n");
2303         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2304
2305         if(firstPlace == -1)
2306                 error("No first place in map vote... WTF?");
2307
2308         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2309                 return MapVote_Finished(firstPlace);
2310
2311         if(mapvote_keeptwotime)
2312                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2313                 {
2314                         float didntvote;
2315                         MapVote_TouchMask();
2316                         mapvote_message = "Now decide between the TOP TWO!";
2317                         mapvote_keeptwotime = 0;
2318                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2319                         result = strcat(result, ":", ftos(firstPlaceVotes));
2320                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2321                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2322                         didntvote = mapvote_voters;
2323                         for(i = 0; i < mapvote_count; ++i)
2324                                 if(mapvote_maps[i] != "")
2325                                 {
2326                                         didntvote -= mapvote_votes[i];
2327                                         if(i != firstPlace)
2328                                                 if(i != secondPlace)
2329                                                 {
2330                                                         result = strcat(result, ":", mapvote_maps[i]);
2331                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2332                                                         if(i < mapvote_count_real)
2333                                                         {
2334                                                                 strunzone(mapvote_maps[i]);
2335                                                                 mapvote_maps[i] = "";
2336                                                         }
2337                                                 }
2338                                 }
2339                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2340                         if(cvar("sv_eventlog"))
2341                                 GameLogEcho(result);
2342                 }
2343
2344         return FALSE;
2345 }
2346 void MapVote_Tick()
2347 {
2348         float keeptwo;
2349         float totalvotes;
2350
2351         keeptwo = mapvote_keeptwotime;
2352         MapVote_CheckRules_1(); // count
2353         if(MapVote_CheckRules_2()) // decide
2354                 return;
2355
2356         totalvotes = 0;
2357         FOR_EACH_REALCLIENT(other)
2358         {
2359                 // hide scoreboard again
2360                 if(other.health != 2342)
2361                 {
2362                         other.health = 2342;
2363                         other.impulse = 0;
2364                         if(clienttype(other) == CLIENTTYPE_REAL)
2365                         {
2366                                 msg_entity = other;
2367                                 WriteByte(MSG_ONE, SVC_FINALE);
2368                                 WriteString(MSG_ONE, "");
2369                         }
2370                 }
2371
2372                 // clear possibly invalid votes
2373                 if(mapvote_maps[other.mapvote - 1] == "")
2374                         other.mapvote = 0;
2375                 // use impulses as new vote
2376                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2377                         if(mapvote_maps[other.impulse - 1] != "")
2378                         {
2379                                 other.mapvote = other.impulse;
2380                                 MapVote_TouchVotes(other);
2381                         }
2382                 other.impulse = 0;
2383
2384                 if(other.mapvote)
2385                         ++totalvotes;
2386         }
2387
2388         MapVote_CheckRules_1(); // just count
2389 }
2390 void MapVote_Start()
2391 {
2392         if(mapvote_run)
2393                 return;
2394
2395         MapInfo_Enumerate();
2396         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1))
2397                 mapvote_run = TRUE;
2398 }
2399 void MapVote_Think()
2400 {
2401         if(!mapvote_run)
2402                 return;
2403
2404         if(alreadychangedlevel)
2405                 return;
2406
2407         if(time < mapvote_nextthink)
2408                 return;
2409         //dprint("tick\n");
2410
2411         mapvote_nextthink = time + 0.5;
2412
2413         if(!mapvote_initialized)
2414         {
2415                 mapvote_initialized = TRUE;
2416                 if(DoNextMapOverride())
2417                         return;
2418                 if(!cvar("g_maplist_votable") || player_count <= 0)
2419                 {
2420                         GotoNextMap();
2421                         return;
2422                 }
2423                 MapVote_Init();
2424         }
2425
2426         MapVote_Tick();
2427 };
2428
2429 string GotoMap(string m)
2430 {
2431         if(!MapInfo_CheckMap(m))
2432                 return "The map you chose is not available on this server.";
2433         cvar_set("nextmap", m);
2434         cvar_set("timelimit", "-1");
2435         if(mapvote_initialized || alreadychangedlevel)
2436         {
2437                 if(DoNextMapOverride())
2438                         return "Map switch initiated.";
2439                 else
2440                         return "Hm... no. For some reason I like THIS map more.";
2441         }
2442         else
2443                 return "Map switch will happen after scoreboard.";
2444 }
2445
2446
2447 void EndFrame()
2448 {
2449         FOR_EACH_REALCLIENT(self)
2450         {
2451                 if(self.classname == "spectator")
2452                 {
2453                         if(self.enemy.typehitsound)
2454                                 play2(self, "misc/typehit.wav");
2455                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2456                                 play2(self, "misc/hit.wav");
2457                 }
2458                 else
2459                 {
2460                         if(self.typehitsound)
2461                                 play2(self, "misc/typehit.wav");
2462                         else if(self.hitsound && self.cvar_cl_hitsound)
2463                                 play2(self, "misc/hit.wav");
2464                 }
2465         }
2466         FOR_EACH_CLIENT(self)
2467         {
2468                 self.hitsound = FALSE;
2469                 self.typehitsound = FALSE;
2470         }
2471 }
2472
2473
2474 /*
2475  * RedirectionThink:
2476  * returns TRUE if redirecting
2477  */
2478 float redirection_timeout;
2479 float redirection_nextthink;
2480 float RedirectionThink()
2481 {
2482         float clients_found;
2483
2484         if(redirection_target == "")
2485                 return FALSE;
2486
2487         if(!redirection_timeout)
2488         {
2489                 cvar_set("sv_public", "-2");
2490                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2491                 if(redirection_target == "self")
2492                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2493                 else
2494                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2495         }
2496
2497         if(time < redirection_nextthink)
2498                 return TRUE;
2499
2500         redirection_nextthink = time + 1;
2501
2502         clients_found = 0;
2503         FOR_EACH_REALCLIENT(self)
2504         {
2505                 print("Redirecting: sending connect command to ", self.netname, "\n");
2506                 if(redirection_target == "self")
2507                         stuffcmd(self, "\ndisconnect; reconnect\n");
2508                 else
2509                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2510                 ++clients_found;
2511         }
2512
2513         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2514
2515         if(time > redirection_timeout || clients_found == 0)
2516                 localcmd("\nwait; wait; wait; quit\n");
2517
2518         return TRUE;
2519 }
2520
2521 void RestoreGame()
2522 {
2523         // Loaded from a save game
2524         // some things then break, so let's work around them...
2525
2526         // Progs DB (capture records)
2527         if(sv_cheats)
2528                 ServerProgsDB = db_create();
2529         else
2530                 ServerProgsDB = db_load("server.db");
2531
2532         // Mapinfo
2533         MapInfo_Shutdown();
2534         MapInfo_Enumerate();
2535         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
2536 }
2537
2538 void SV_Shutdown()
2539 {
2540         if(world_initialized > 0)
2541         {
2542                 world_initialized = 0;
2543                 print("Saving persistent data...\n");
2544                 Ban_SaveBans();
2545                 if(!sv_cheats)
2546                         db_save(ServerProgsDB, "server.db");
2547                 if(cvar("developer"))
2548                         db_save(TemporaryDB, "server-temp.db");
2549                 db_close(ServerProgsDB);
2550                 db_close(TemporaryDB);
2551                 print("done!\n");
2552                 // tell the bot system the game is ending now
2553                 bot_endgame();
2554
2555                 MapInfo_Shutdown();
2556         }
2557         else if(world_initialized == 0)
2558         {
2559                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2560         }
2561 }