data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         //reset all the flood variables
  83                         FOR_EACH_CLIENT(plr) {
  84                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
  85                         }
  86                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  87                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  88                         FOR_EACH_REALPLAYER(plr) {
  89                                 plr.lastV_angle = plr.v_angle;
  90                         }
  91                         self.nextthink = time;
  92                 }
  93         }
  94         else if (timeoutStatus == 2) {
  95                 if (remainingTimeoutTime > 0) {
  96                         timeStr = getTimeoutText(0);
  97                         FOR_EACH_REALCLIENT(plr) {
  98                                 if(plr.classname == "player") {
  99                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 100                                 }
 101                         }
 102                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 103                                 play2all("announcer/robotic/prepareforbattle.wav");
 104                         }
 105                         remainingTimeoutTime -= 1;
 106                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 107                 }
 108                 else {
 109                         //unpause the game again
 110                         remainingTimeoutTime = timeoutStatus = 0;
 111                         cvar_set("slowmo", ftos(orig_slowmo));
 112                         //and unlock the fixed view again once there is no timeout active anymore
 113                         FOR_EACH_REALPLAYER(plr) {
 114                                 plr.fixangle = FALSE;
 115                         }
 116                         //get rid of the countdown message
 117                         FOR_EACH_REALCLIENT(plr) {
 118                                 if(plr.classname == "player") {
 119                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 120                                 }
 121                         }
 122                         remove(self);
 123                         return;
 124                 }
 125
 126         }
 127         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 128                 FOR_EACH_REALCLIENT(plr) {
 129                         if(plr.classname == "player") {
 130                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 131                         }
 132                 }
 133                 remove(self);
 134                 return;
 135         }
 136 }
 137
 138 void GotoFirstMap()
 139 {
 140         float n;
 141         if(cvar("_sv_init"))
 142         {
 143                 // cvar_set("_sv_init", "0");
 144                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 145                 // to this "init" map on a dedicated server will cause no permanent
 146                 // harm
 147                 if(cvar("g_maplist_shuffle"))
 148                         ShuffleMaplist();
 149                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 150                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 151
 152                 MapInfo_Enumerate();
 153                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 154
 155                 if(!DoNextMapOverride())
 156                         GotoNextMap();
 157
 158                 return;
 159         }
 160
 161         if(time < 5)
 162         {
 163                 self.nextthink = time;
 164         }
 165         else
 166         {
 167                 self.nextthink = time + 1;
 168                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 169         }
 170 }
 171
 172 void cvar_changes_init()
 173 {
 174         float h;
 175         string k, v, d;
 176         float n, i;
 177
 178         if(cvar_changes)
 179                 strunzone(cvar_changes);
 180         cvar_changes = string_null;
 181
 182         h = buf_create();
 183         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 184         n = buf_getsize(h);
 185
 186         for(i = 0; i < n; ++i)
 187         {
 188                 k = bufstr_get(h, i);
 189
 190 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 191 #define BADCVAR(p) if(k == p) continue
 192                 // internal
 193                 BADPREFIX("csqc_");
 194                 BADPREFIX("cvar_check_");
 195                 BADCVAR("gamecfg");
 196                 BADCVAR("g_configversion");
 197                 BADCVAR("g_maplist_index");
 198                 BADCVAR("halflifebsp");
 199
 200                 // client
 201                 BADPREFIX("cl_");
 202                 BADPREFIX("con_");
 203                 BADPREFIX("g_campaign");
 204                 BADPREFIX("gl_");
 205                 BADPREFIX("joy");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("userbind");
 212                 BADPREFIX("v_");
 213                 BADPREFIX("vid_");
 214                 BADPREFIX("crosshair");
 215                 BADCVAR("mod_q3bsp_lightmapmergepower");
 216                 BADCVAR("mod_q3bsp_nolightmaps");
 217
 218                 // private
 219                 BADPREFIX("g_ban_");
 220                 BADPREFIX("g_chat_flood_");
 221                 BADPREFIX("g_voice_flood_");
 222                 BADPREFIX("rcon_");
 223                 BADPREFIX("settemp_");
 224                 BADPREFIX("sv_allowdownloads_");
 225                 BADPREFIX("sv_autodemo");
 226                 BADPREFIX("sv_curl_");
 227                 BADPREFIX("sv_eventlog");
 228                 BADPREFIX("sv_logscores_");
 229                 BADPREFIX("sv_master");
 230                 BADCVAR("g_banned_list");
 231                 BADCVAR("log_dest_udp");
 232                 BADCVAR("log_file");
 233                 BADCVAR("net_address");
 234                 BADCVAR("port");
 235                 BADCVAR("savedgamecfg");
 236                 BADCVAR("sv_heartbeatperoid");
 237                 BADCVAR("sv_vote_master_password");
 238                 BADCVAR("sys_colortranslation");
 239                 BADCVAR("sys_specialcharactertranslation");
 240                 BADCVAR("timestamps");
 241
 242                 // mapinfo
 243                 BADCVAR("timelimit");
 244                 BADCVAR("fraglimit");
 245                 BADCVAR("g_arena");
 246                 BADCVAR("g_ca");
 247                 BADCVAR("g_assault");
 248                 BADCVAR("g_ctf");
 249                 BADCVAR("g_dm");
 250                 BADCVAR("g_domination");
 251                 BADCVAR("g_keyhunt");
 252                 BADCVAR("g_keyhunt_teams");
 253                 BADCVAR("g_onslaught");
 254                 BADCVAR("g_race");
 255                 BADCVAR("g_cts");
 256                 BADCVAR("g_runematch");
 257                 BADCVAR("g_tdm");
 258                 BADCVAR("g_nexball");
 259                 BADCVAR("teamplay");
 260
 261                 // long
 262                 BADCVAR("hostname");
 263                 BADCVAR("g_maplist");
 264                 BADCVAR("g_maplist_mostrecent");
 265                 BADCVAR("sv_motd");
 266 #undef BADPREFIX
 267 #undef BADCVAR
 268
 269                 v = cvar_string(k);
 270                 d = cvar_defstring(k);
 271                 if(v != d)
 272                 {
 273                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 274                         if(strlen(cvar_changes) > 16384)
 275                         {
 276                                 cvar_changes = "// too many settings have been changed to show them here\n";
 277                                 break;
 278                         }
 279                 }
 280         }
 281         buf_del(h);
 282         if(cvar_changes == "")
 283                 cvar_changes = "// this server runs at default settings\n";
 284         else
 285                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 286         cvar_changes = strzone(cvar_changes);
 287 }
 288
 289 void detect_maptype()
 290 {
 291 #if 0
 292         vector o, v;
 293         float i;
 294
 295         for(;;)
 296         {
 297                 o = world.mins;
 298                 o_x += random() * (world.maxs_x - world.mins_x);
 299                 o_y += random() * (world.maxs_y - world.mins_y);
 300                 o_z += random() * (world.maxs_z - world.mins_z);
 301
 302                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 303                 if(trace_fraction == 1)
 304                         continue;
 305
 306                 v = trace_endpos;
 307
 308                 for(i = 0; i < 64; i += 4)
 309                 {
 310                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 311         if(trace_fraction == 1)
 312                 continue;
 313                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 314                 }
 315
 316                 break;
 317         }
 318 #endif
 319 }
 320
 321 entity randomseed;
 322 float RandomSeed_Send(entity to, float sf)
 323 {
 324         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 325         WriteShort(MSG_ENTITY, self.cnt);
 326         return TRUE;
 327 }
 328 void RandomSeed_Think()
 329 {
 330         self.cnt = bound(0, floor(random() * 65536), 65535);
 331         self.nextthink = time + 5;
 332
 333         self.SendFlags |= 1;
 334 }
 335 void RandomSeed_Spawn()
 336 {
 337         randomseed = spawn();
 338         randomseed.think = RandomSeed_Think;
 339         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 340
 341         entity oldself;
 342         oldself = self;
 343         self = randomseed;
 344         self.think(); // sets random seed and nextthink
 345         self = oldself;
 346 }
 347
 348 void spawnfunc___init_dedicated_server(void)
 349 {
 350         // handler for _init/_init map (only for dedicated server initialization)
 351
 352         world_initialized = -1; // don't complain
 353         cvar = cvar_builtin;
 354         cvar_string = cvar_string_builtin;
 355         cvar_set = cvar_set_builtin;
 356         dprint_load(); // load dprint status from cvar
 357
 358         remove = remove_unsafely;
 359
 360         entity e;
 361         e = spawn();
 362         e.think = GotoFirstMap;
 363         e.nextthink = time; // this is usually 1 at this point
 364
 365         e = spawn();
 366         e.classname = "info_player_deathmatch"; // safeguard against player joining
 367
 368         self.classname = "worldspawn"; // safeguard against various stuff ;)
 369
 370         MapInfo_Enumerate();
 371         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 372 }
 373
 374 void Map_MarkAsRecent(string m);
 375 float world_already_spawned;
 376 void RegisterWeapons();
 377 void Nagger_Init();
 378 void ClientInit_Spawn();
 379 void WeaponStats_Init();
 380 void WeaponStats_Shutdown();
 381 void spawnfunc_worldspawn (void)
 382 {
 383         float fd, l, i, j, n;
 384         string s, col;
 385
 386         cvar = cvar_builtin;
 387         cvar_string = cvar_string_builtin;
 388         cvar_set = cvar_set_builtin;
 389         dprint_load(); // load dprint status from cvar
 390
 391         if(world_already_spawned)
 392                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 393         world_already_spawned = TRUE;
 394
 395         remove = remove_safely; // during spawning, watch what you remove!
 396
 397         check_unacceptable_compiler_bugs();
 398
 399         if(cvar_string("cvar_check_default") != "bypass")
 400         {
 401                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 402                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 403
 404                 if(cvar_string("cvar_check_balance") != CVAR_CHECK_BALANCE)
 405                         error("Config file mismatch! Please update balance*.cfg to match the QuakeC code, and restart the engine!");
 406         }
 407
 408         compressShortVector_init();
 409
 410         local entity head;
 411         head = nextent(world);
 412         maxclients = 0;
 413         while(head)
 414         {
 415                 ++maxclients;
 416                 head = nextent(head);
 417         }
 418
 419         // needs to be done so early as they would still spawn
 420         RegisterWeapons();
 421
 422         if(sv_cheats)
 423                 ServerProgsDB = db_create();
 424         else
 425                 ServerProgsDB = db_load("server.db");
 426
 427         TemporaryDB = db_create();
 428
 429         /*
 430         TODO sound pack system
 431         // initialize sound pack system
 432         soundpack = cvar_string("g_soundpack");
 433         if(soundpack != "")
 434                 soundpack = strcat(soundpack, "/");
 435         soundpack = strzone(soundpack);
 436         */
 437
 438         // 0 normal
 439         lightstyle(0, "m");
 440
 441         // 1 FLICKER (first variety)
 442         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 443
 444         // 2 SLOW STRONG PULSE
 445         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 446
 447         // 3 CANDLE (first variety)
 448         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 449
 450         // 4 FAST STROBE
 451         lightstyle(4, "mamamamamama");
 452
 453         // 5 GENTLE PULSE 1
 454         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 455
 456         // 6 FLICKER (second variety)
 457         lightstyle(6, "nmonqnmomnmomomno");
 458
 459         // 7 CANDLE (second variety)
 460         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 461
 462         // 8 CANDLE (third variety)
 463         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 464
 465         // 9 SLOW STROBE (fourth variety)
 466         lightstyle(9, "aaaaaaaazzzzzzzz");
 467
 468         // 10 FLUORESCENT FLICKER
 469         lightstyle(10, "mmamammmmammamamaaamammma");
 470
 471         // 11 SLOW PULSE NOT FADE TO BLACK
 472         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 473
 474         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 475
 476         // 63 testing
 477         lightstyle(63, "a");
 478
 479         if(cvar("g_campaign"))
 480                 CampaignPreInit();
 481
 482         Map_MarkAsRecent(mapname);
 483
 484         precache_model ("null"); // we need this one before InitGameplayMode
 485         InitGameplayMode();
 486         readlevelcvars();
 487         GrappleHookInit();
 488
 489         player_count = 0;
 490         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 491         if(bot_waypoints_for_items == 1)
 492                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 493                         bot_waypoints_for_items = 0;
 494
 495         // for setting by mapinfo
 496         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 497         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 498
 499         precache();
 500
 501         WaypointSprite_Init();
 502
 503         //if (g_domination)
 504         //      dom_init();
 505
 506         GameLogInit(); // prepare everything
 507         if(cvar("sv_eventlog"))
 508         {
 509                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 510                 s = strcat(s, ftos(random()));
 511                 matchid = strzone(s);
 512
 513                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 514                 s = ":gameinfo:mutators:LIST";
 515                 if(cvar("g_grappling_hook"))
 516                         s = strcat(s, ":grappling_hook");
 517                 if(!cvar("g_use_ammunition"))
 518                         s = strcat(s, ":no_use_ammunition");
 519                 if(!cvar("g_pickup_items"))
 520                         s = strcat(s, ":no_pickup_items");
 521                 if(cvar("g_instagib"))
 522                         s = strcat(s, ":instagib");
 523                 if(cvar_string("g_weaponarena") != "0")
 524                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 525                 if(cvar("g_nixnex"))
 526                         s = strcat(s, ":nixnex");
 527                 if(cvar("g_vampire"))
 528                         s = strcat(s, ":vampire");
 529                 if(cvar("g_laserguided_missile"))
 530                         s = strcat(s, ":laserguided_missile");
 531                 if(cvar("g_norecoil"))
 532                         s = strcat(s, ":norecoil");
 533                 if(cvar("g_midair"))
 534                         s = strcat(s, ":midair");
 535                 if(cvar("g_minstagib"))
 536                         s = strcat(s, ":minstagib");
 537                 GameLogEcho(s);
 538                 GameLogEcho(":gameinfo:end");
 539         }
 540         else
 541                 matchid = strzone(ftos(random()));
 542
 543         cvar_set("nextmap", "");
 544
 545         SetDefaultAlpha();
 546
 547         if(cvar("g_campaign"))
 548                 CampaignPostInit();
 549
 550         fteqcc_testbugs();
 551
 552         Ban_LoadBans();
 553
 554         MapInfo_Enumerate();
 555         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 556
 557         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 558         {
 559                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 560                 if(fd != -1)
 561                 {
 562                         while((s = fgets(fd)))
 563                         {
 564                                 l = tokenize_console(s);
 565                                 if(l < 2)
 566                                         continue;
 567                                 if(argv(0) == "cd")
 568                                 {
 569                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 570                                         print("  cdtrack ", argv(2), "\n");
 571                                 }
 572                                 else if(argv(0) == "fog")
 573                                 {
 574                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 575                                         print("  \"fog\" \"", s, "\"\n");
 576                                 }
 577                                 else if(argv(0) == "set")
 578                                 {
 579                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 580                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 581                                 }
 582                                 else if(argv(0) != "//")
 583                                 {
 584                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 585                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 586                                 }
 587                         }
 588                         fclose(fd);
 589                 }
 590         }
 591
 592         WeaponStats_Init();
 593
 594         addstat(STAT_WEAPONS, AS_INT, weapons);
 595         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 596         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 597         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 598         Nagger_Init();
 599
 600         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 601         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 602         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 603         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 604         addstat(STAT_DAMAGE_HITS, AS_INT, damage_hits);
 605         addstat(STAT_DAMAGE_FIRED, AS_INT, maxdamage_fired);
 606         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 607         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 608         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 609
 610         next_pingtime = time + 5;
 611         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 612
 613         detect_maptype();
 614
 615         lsmaps_reply = "^7Maps available: ";
 616         for(i = 0, j = 0; i < MapInfo_count; ++i)
 617         {
 618                 if(MapInfo_Get_ByID(i))
 619                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 620                         {
 621                                 if(mod(i, 2))
 622                                         col = "^2";
 623                                 else
 624                                         col = "^3";
 625                                 ++j;
 626                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 627                         }
 628         }
 629         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 630
 631         maplist_reply = "^7Maps in list: ";
 632         n = tokenize_console(cvar_string("g_maplist"));
 633         for(i = 0, j = 0; i < n; ++i)
 634         {
 635                 if(MapInfo_CheckMap(argv(i)))
 636                 {
 637                         if(mod(j, 2))
 638                                 col = "^2";
 639                         else
 640                                 col = "^3";
 641                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 642                         ++j;
 643                 }
 644         }
 645         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 646         MapInfo_ClearTemps();
 647
 648         records_reply = strzone(getrecords());
 649
 650         ClientInit_Spawn();
 651         RandomSeed_Spawn();
 652
 653         localcmd("\n_sv_hook_gamestart ", GetGametype(), ";");
 654
 655         world_initialized = 1;
 656 }
 657
 658 void spawnfunc_light (void)
 659 {
 660         //makestatic (self); // Who the f___ did that?
 661         remove(self);
 662 }
 663
 664 float TryFile( string pFilename )
 665 {
 666         local float lHandle;
 667         dprint("TryFile(\"", pFilename, "\")\n");
 668         lHandle = fopen( pFilename, FILE_READ );
 669         if( lHandle != -1 ) {
 670                 fclose( lHandle );
 671                 return TRUE;
 672         } else {
 673                 return FALSE;
 674         }
 675 };
 676
 677 string GetGametype()
 678 {
 679         return GametypeNameFromType(game);
 680 }
 681
 682 string getmapname_stored;
 683 string GetMapname()
 684 {
 685         return mapname;
 686 }
 687
 688 float Map_Count, Map_Current;
 689 string Map_Current_Name;
 690
 691 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 692 float GetMaplistPosition()
 693 {
 694         float pos, idx;
 695         string map;
 696
 697         map = GetMapname();
 698         idx = cvar("g_maplist_index");
 699
 700         if(idx >= 0)
 701                 if(idx < Map_Count)
 702                         if(map == argv(idx))
 703                                 return idx;
 704
 705         for(pos = 0; pos < Map_Count; ++pos)
 706                 if(map == argv(pos))
 707                         return pos;
 708
 709         // resume normal maplist rotation if current map is not in g_maplist
 710         return idx;
 711 }
 712
 713 float MapHasRightSize(string map)
 714 {
 715         float fh;
 716         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 717         if(cvar("g_maplist_check_waypoints"))
 718         {
 719                 dprint("checkwp "); dprint(map);
 720                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 721                 if(fh < 0)
 722                 {
 723                         dprint(": no waypoints\n");
 724                         return FALSE;
 725                 }
 726                 dprint(": has waypoints\n");
 727                 fclose(fh);
 728         }
 729
 730         // open map size restriction file
 731         dprint("opensize "); dprint(map);
 732         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 733         if(fh >= 0)
 734         {
 735                 float mapmin, mapmax;
 736                 dprint(": ok, ");
 737                 mapmin = stof(fgets(fh));
 738                 mapmax = stof(fgets(fh));
 739                 fclose(fh);
 740                 if(player_count < mapmin)
 741                 {
 742                         dprint("not enough\n");
 743                         return FALSE;
 744                 }
 745                 if(player_count > mapmax)
 746                 {
 747                         dprint("too many\n");
 748                         return FALSE;
 749                 }
 750                 dprint("right size\n");
 751                 return TRUE;
 752         }
 753         dprint(": not found\n");
 754         return TRUE;
 755 }
 756
 757 string Map_Filename(float position)
 758 {
 759         return strcat("maps/", argv(position), ".bsp");
 760 }
 761
 762 string strwords(string s, float w)
 763 {
 764         float endpos;
 765         for(endpos = 0; w && endpos >= 0; --w)
 766                 endpos = strstrofs(s, " ", endpos + 1);
 767         if(endpos < 0)
 768                 return s;
 769         else
 770                 return substring(s, 0, endpos);
 771 }
 772
 773 float strhasword(string s, string w)
 774 {
 775         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 776 }
 777
 778 void Map_MarkAsRecent(string m)
 779 {
 780         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 781 }
 782
 783 float Map_IsRecent(string m)
 784 {
 785         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 786 }
 787
 788 float Map_Check(float position, float pass)
 789 {
 790         string filename;
 791         string map_next;
 792         map_next = argv(position);
 793         if(pass <= 1)
 794         {
 795                 if(Map_IsRecent(map_next))
 796                         return 0;
 797         }
 798         filename = Map_Filename(position);
 799         if(MapInfo_CheckMap(map_next))
 800         {
 801                 if(pass == 2)
 802                         return 1;
 803                 if(MapHasRightSize(map_next))
 804                         return 1;
 805                 return 0;
 806         }
 807         else
 808                 dprint( "Couldn't select '", filename, "'..\n" );
 809
 810         return 0;
 811 }
 812
 813 void Map_Goto_SetStr(string nextmapname)
 814 {
 815         if(getmapname_stored != "")
 816                 strunzone(getmapname_stored);
 817         if(nextmapname == "")
 818                 getmapname_stored = "";
 819         else
 820                 getmapname_stored = strzone(nextmapname);
 821 }
 822
 823 void Map_Goto_SetFloat(float position)
 824 {
 825         cvar_set("g_maplist_index", ftos(position));
 826         Map_Goto_SetStr(argv(position));
 827 }
 828
 829 void GameResetCfg()
 830 {
 831         // settings persist, except...
 832         localcmd("\nsettemp_restore\n");
 833 };
 834
 835 void Map_Goto()
 836 {
 837         GameResetCfg();
 838         MapInfo_LoadMap(getmapname_stored);
 839 }
 840
 841 // return codes of map selectors:
 842 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 843 //   -2 = permanent failure
 844 float() MaplistMethod_Iterate = // usual method
 845 {
 846         float pass, i;
 847
 848         for(pass = 1; pass <= 2; ++pass)
 849         {
 850                 for(i = 1; i < Map_Count; ++i)
 851                 {
 852                         float mapindex;
 853                         mapindex = mod(i + Map_Current, Map_Count);
 854                         if(Map_Check(mapindex, pass))
 855                                 return mapindex;
 856                 }
 857         }
 858         return -1;
 859 }
 860
 861 float() MaplistMethod_Repeat = // fallback method
 862 {
 863         if(Map_Check(Map_Current, 2))
 864                 return Map_Current;
 865         return -2;
 866 }
 867
 868 float() MaplistMethod_Random = // random map selection
 869 {
 870         float i, imax;
 871
 872         imax = 42;
 873
 874         for(i = 0; i <= imax; ++i)
 875         {
 876                 float mapindex;
 877                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 878                 if(Map_Check(mapindex, 1))
 879                         return mapindex;
 880         }
 881         return -1;
 882 }
 883
 884 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 885 // the exponent sets a bias on the map selection:
 886 // the higher the exponent, the less likely "shortly repeated" same maps are
 887 {
 888         float i, j, imax, insertpos;
 889
 890         imax = 42;
 891
 892         for(i = 0; i <= imax; ++i)
 893         {
 894                 string newlist;
 895
 896                 // now reinsert this at another position
 897                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 898                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 899                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 900                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 901
 902                 // insert the current map there
 903                 newlist = "";
 904                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 905                         newlist = strcat(newlist, " ", argv(j));
 906                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 907                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 908                         newlist = strcat(newlist, " ", argv(j));
 909                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 910                 cvar_set("g_maplist", newlist);
 911                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 912
 913                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 914                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 915                 if(Map_Check(Map_Current, 1))
 916                         return Map_Current;
 917         }
 918         return -1;
 919 }
 920
 921 void Maplist_Init()
 922 {
 923         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 924         if(Map_Count == 0)
 925         {
 926                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 927                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
 928                 if(cvar("g_maplist_shuffle"))
 929                         ShuffleMaplist();
 930                 localcmd("\nmenu_cmd sync\n");
 931                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 932         }
 933         if(Map_Count == 0)
 934                 error("empty maplist, cannot select a new map");
 935         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 936
 937         if(Map_Current_Name)
 938                 strunzone(Map_Current_Name);
 939         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 940         // this may or may not be correct, but who cares, in the worst case a map
 941         // isn't chosen in the first pass that should have been
 942 }
 943
 944 string GetNextMap()
 945 {
 946         float nextMap;
 947
 948         Maplist_Init();
 949         nextMap = -1;
 950
 951         if(nextMap == -1)
 952                 if(cvar("g_maplist_shuffle") > 0)
 953                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 954
 955         if(nextMap == -1)
 956                 if(cvar("g_maplist_selectrandom"))
 957                         nextMap = MaplistMethod_Random();
 958
 959         if(nextMap == -1)
 960                 nextMap = MaplistMethod_Iterate();
 961
 962         if(nextMap == -1)
 963                 nextMap = MaplistMethod_Repeat();
 964
 965         if(nextMap >= 0)
 966         {
 967                 Map_Goto_SetFloat(nextMap);
 968                 return getmapname_stored;
 969         }
 970
 971         return "";
 972 };
 973
 974 float DoNextMapOverride()
 975 {
 976         if(cvar("g_campaign"))
 977         {
 978                 CampaignPostIntermission();
 979                 alreadychangedlevel = TRUE;
 980                 return TRUE;
 981         }
 982         if(cvar("quit_when_empty"))
 983         {
 984                 if(player_count <= currentbots)
 985                 {
 986                         localcmd("quit\n");
 987                         alreadychangedlevel = TRUE;
 988                         return TRUE;
 989                 }
 990         }
 991         if(cvar_string("quit_and_redirect") != "")
 992         {
 993                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 994                 alreadychangedlevel = TRUE;
 995                 return TRUE;
 996         }
 997         if (cvar("samelevel")) // if samelevel is set, stay on same level
 998         {
 999                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1000                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1001                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1002                 localcmd("restart\n");
1003                 //changelevel (mapname);
1004                 alreadychangedlevel = TRUE;
1005                 return TRUE;
1006         }
1007         if(cvar_string("nextmap") != "")
1008                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1009                 {
1010                         Map_Goto_SetStr(cvar_string("nextmap"));
1011                         Map_Goto();
1012                         alreadychangedlevel = TRUE;
1013                         return TRUE;
1014                 }
1015         if(cvar("lastlevel"))
1016         {
1017                 GameResetCfg();
1018                 localcmd("set lastlevel 0\ntogglemenu\n");
1019                 alreadychangedlevel = TRUE;
1020                 return TRUE;
1021         }
1022         return FALSE;
1023 };
1024
1025 void GotoNextMap()
1026 {
1027         //local string nextmap;
1028         //local float n, nummaps;
1029         //local string s;
1030         if (alreadychangedlevel)
1031                 return;
1032         alreadychangedlevel = TRUE;
1033
1034         {
1035                 string nextMap;
1036                 float allowReset;
1037
1038                 for(allowReset = 1; allowReset >= 0; --allowReset)
1039                 {
1040                         nextMap = GetNextMap();
1041                         if(nextMap != "")
1042                                 break;
1043
1044                         if(allowReset)
1045                         {
1046                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1047                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1048                                 if(cvar("g_maplist_shuffle"))
1049                                         ShuffleMaplist();
1050                                 localcmd("\nmenu_cmd sync\n");
1051                         }
1052                         else
1053                         {
1054                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1055                         }
1056                 }
1057                 Map_Goto();
1058         }
1059 };
1060
1061
1062 /*
1063 ============
1064 IntermissionThink
1065
1066 When the player presses attack or jump, change to the next level
1067 ============
1068 */
1069 .float autoscreenshot;
1070 void() MapVote_Start;
1071 void() MapVote_Think;
1072 float mapvote_initialized;
1073 void IntermissionThink()
1074 {
1075         FixIntermissionClient(self);
1076
1077         if(cvar("sv_autoscreenshot"))
1078         if(self.autoscreenshot > 0)
1079         if(time > self.autoscreenshot)
1080         {
1081                 self.autoscreenshot = -1;
1082                 if(clienttype(self) == CLIENTTYPE_REAL)
1083                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1084                 return;
1085         }
1086
1087         if (time < intermission_exittime)
1088                 return;
1089
1090         if(!mapvote_initialized)
1091                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1092                         return;
1093
1094         MapVote_Start();
1095 };
1096
1097 /*
1098 ============
1099 FindIntermission
1100
1101 Returns the entity to view from
1102 ============
1103 */
1104 /*
1105 entity FindIntermission()
1106 {
1107         local   entity spot;
1108         local   float cyc;
1109
1110 // look for info_intermission first
1111         spot = find (world, classname, "info_intermission");
1112         if (spot)
1113         {       // pick a random one
1114                 cyc = random() * 4;
1115                 while (cyc > 1)
1116                 {
1117                         spot = find (spot, classname, "info_intermission");
1118                         if (!spot)
1119                                 spot = find (spot, classname, "info_intermission");
1120                         cyc = cyc - 1;
1121                 }
1122                 return spot;
1123         }
1124
1125 // then look for the start position
1126         spot = find (world, classname, "info_player_start");
1127         if (spot)
1128                 return spot;
1129
1130 // testinfo_player_start is only found in regioned levels
1131         spot = find (world, classname, "testplayerstart");
1132         if (spot)
1133                 return spot;
1134
1135 // then look for the start position
1136         spot = find (world, classname, "info_player_deathmatch");
1137         if (spot)
1138                 return spot;
1139
1140         //objerror ("FindIntermission: no spot");
1141         return world;
1142 };
1143 */
1144
1145 /*
1146 ===============================================================================
1147
1148 RULES
1149
1150 ===============================================================================
1151 */
1152
1153 void DumpStats(float final)
1154 {
1155         local float file;
1156         local string s;
1157         local float to_console;
1158         local float to_eventlog;
1159         local float to_file;
1160         local float i;
1161
1162         to_console = cvar("sv_logscores_console");
1163         to_eventlog = cvar("sv_eventlog");
1164         to_file = cvar("sv_logscores_file");
1165
1166         if(!final)
1167         {
1168                 to_console = TRUE; // always print printstats replies
1169                 to_eventlog = FALSE; // but never print them to the event log
1170         }
1171
1172         if(to_eventlog)
1173                 if(cvar("sv_eventlog_console"))
1174                         to_console = FALSE; // otherwise we get the output twice
1175
1176         if(final)
1177                 s = ":scores:";
1178         else
1179                 s = ":status:";
1180         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1181
1182         if(to_console)
1183                 print(s, "\n");
1184         if(to_eventlog)
1185                 GameLogEcho(s);
1186         if(to_file)
1187         {
1188                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1189                 if(file == -1)
1190                         to_file = FALSE;
1191                 else
1192                         fputs(file, strcat(s, "\n"));
1193         }
1194
1195         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1196         if(to_console)
1197                 print(s, "\n");
1198         if(to_eventlog)
1199                 GameLogEcho(s);
1200         if(to_file)
1201                 fputs(file, strcat(s, "\n"));
1202
1203         FOR_EACH_CLIENT(other)
1204         {
1205                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1206                 {
1207                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1208                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1209                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1210                                 s = strcat(s, ftos(other.team), ":");
1211                         else
1212                                 s = strcat(s, "spectator:");
1213
1214                         if(to_console)
1215                                 print(s, other.netname, "\n");
1216                         if(to_eventlog)
1217                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1218                         if(to_file)
1219                                 fputs(file, strcat(s, other.netname, "\n"));
1220                 }
1221         }
1222
1223         if(teams_matter)
1224         {
1225                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1226                 if(to_console)
1227                         print(s, "\n");
1228                 if(to_eventlog)
1229                         GameLogEcho(s);
1230                 if(to_file)
1231                         fputs(file, strcat(s, "\n"));
1232
1233                 for(i = 1; i < 16; ++i)
1234                 {
1235                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1236                         s = strcat(s, ":", ftos(i));
1237                         if(to_console)
1238                                 print(s, "\n");
1239                         if(to_eventlog)
1240                                 GameLogEcho(s);
1241                         if(to_file)
1242                                 fputs(file, strcat(s, "\n"));
1243                 }
1244         }
1245
1246         if(to_console)
1247                 print(":end\n");
1248         if(to_eventlog)
1249                 GameLogEcho(":end");
1250         if(to_file)
1251         {
1252                 fputs(file, ":end\n");
1253                 fclose(file);
1254         }
1255 }
1256
1257 void FixIntermissionClient(entity e)
1258 {
1259         string s;
1260         if(!e.autoscreenshot) // initial call
1261         {
1262                 e.angles = e.v_angle;
1263                 e.angles_x = -e.angles_x;
1264                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1265                 e.health = -2342;
1266                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1267                 e.solid = SOLID_NOT;
1268                 e.movetype = MOVETYPE_NONE;
1269                 e.takedamage = DAMAGE_NO;
1270                 if(e.weaponentity)
1271                 {
1272                         e.weaponentity.effects = EF_NODRAW;
1273                         if (e.weaponentity.weaponentity)
1274                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1275                 }
1276                 if(clienttype(e) == CLIENTTYPE_REAL)
1277                 {
1278                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1279                         s = cvar_string("sv_intermission_cdtrack");
1280                         if(s != "")
1281                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1282                         msg_entity = e;
1283                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1284                 }
1285         }
1286
1287         //e.velocity = '0 0 0';
1288         //e.fixangle = TRUE;
1289
1290         // TODO halt weapon animation
1291 }
1292
1293
1294 /*
1295 go to the next level for deathmatch
1296 only called if a time or frag limit has expired
1297 */
1298 void NextLevel()
1299 {
1300         float minTotalFrags;
1301         float maxTotalFrags;
1302         float score;
1303         float f;
1304
1305         gameover = TRUE;
1306
1307         intermission_running = 1;
1308
1309 // enforce a wait time before allowing changelevel
1310         if(player_count > 0)
1311                 intermission_exittime = time + cvar("sv_mapchange_delay");
1312         else
1313                 intermission_exittime = -1;
1314
1315         /*
1316         WriteByte (MSG_ALL, SVC_CDTRACK);
1317         WriteByte (MSG_ALL, 3);
1318         WriteByte (MSG_ALL, 3);
1319         // done in FixIntermission
1320         */
1321
1322         //pos = FindIntermission ();
1323
1324         VoteReset();
1325
1326         DumpStats(TRUE);
1327
1328         if(cvar("sv_eventlog"))
1329                 GameLogEcho(":gameover");
1330
1331         GameLogClose();
1332
1333         FOR_EACH_CLIENT(other)
1334         {
1335                 FixIntermissionClient(other);
1336
1337                 if(other.winning)
1338                         bprint(other.netname, " ^7wins.\n");
1339         }
1340
1341         minTotalFrags = 0;
1342         maxTotalFrags = 0;
1343         FOR_EACH_PLAYER(other)
1344         {
1345                 if(maxTotalFrags < other.totalfrags)
1346                         maxTotalFrags = other.totalfrags;
1347                 if(minTotalFrags > other.totalfrags)
1348                         minTotalFrags = other.totalfrags;
1349         }
1350
1351         if(!currentbots)
1352         {
1353                 FOR_EACH_PLAYER(other)
1354                 {
1355                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1356                         f = bound(0, other.play_time / max(time, 1), 1);
1357                         // store some statistics?
1358                 }
1359         }
1360
1361         if(cvar("g_campaign"))
1362                 CampaignPreIntermission();
1363
1364         localcmd("\nsv_hook_gameend;");
1365
1366         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1367 };
1368
1369 /*
1370 ============
1371 CheckRules_Player
1372
1373 Exit deathmatch games upon conditions
1374 ============
1375 */
1376 void CheckRules_Player()
1377 {
1378         if (gameover)   // someone else quit the game already
1379                 return;
1380
1381         if(self.deadflag == DEAD_NO)
1382                 self.play_time += frametime;
1383
1384         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1385         //   (div0: and that in CheckRules_World please)
1386 };
1387
1388 float checkrules_equality;
1389 float checkrules_suddendeathwarning;
1390 float checkrules_suddendeathend;
1391 float checkrules_overtimesadded; //how many overtimes have been already added
1392
1393 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1394 float WINNING_YES = 1; // winner found
1395 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1396 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1397
1398 float InitiateSuddenDeath()
1399 {
1400         // Check first whether normal overtimes could be added before initiating suddendeath mode
1401         // - for this timelimit_overtime needs to be >0 of course
1402         // - also check the winning condition calculated in the previous frame and only add normal overtime
1403         //   again, if at the point at which timelimit would be extended again, still no winner was found
1404         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1405         {
1406                 return 1; // need to call InitiateOvertime later
1407         }
1408         else
1409         {
1410                 if(!checkrules_suddendeathend)
1411                 {
1412                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1413                         if(g_race && !g_race_qualifying)
1414                                 race_StartCompleting();
1415                 }
1416                 return 0;
1417         }
1418 }
1419
1420 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1421 {
1422         ++checkrules_overtimesadded;
1423         //add one more overtime by simply extending the timelimit
1424         float tl;
1425         tl = cvar("timelimit");
1426         tl += cvar("timelimit_overtime");
1427         cvar_set("timelimit", ftos(tl));
1428         string minutesPlural;
1429         if (cvar("timelimit_overtime") == 1)
1430                 minutesPlural = " ^3minute";
1431         else
1432                 minutesPlural = " ^3minutes";
1433
1434         bcenterprint(
1435                 strcat(
1436                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1437                         ftos(cvar("timelimit_overtime")),
1438                         minutesPlural,
1439                         " to the game!"
1440                 )
1441         );
1442 }
1443
1444 float GetWinningCode(float fraglimitreached, float equality)
1445 {
1446         if(equality)
1447                 if(fraglimitreached)
1448                         return WINNING_STARTSUDDENDEATHOVERTIME;
1449                 else
1450                         return WINNING_NEVER;
1451         else
1452                 if(fraglimitreached)
1453                         return WINNING_YES;
1454                 else
1455                         return WINNING_NO;
1456 }
1457
1458 // set the .winning flag for exactly those players with a given field value
1459 void SetWinners(.float field, float value)
1460 {
1461         entity head;
1462         FOR_EACH_PLAYER(head)
1463                 head.winning = (head.field == value);
1464 }
1465
1466 // set the .winning flag for those players with a given field value
1467 void AddWinners(.float field, float value)
1468 {
1469         entity head;
1470         FOR_EACH_PLAYER(head)
1471                 if(head.field == value)
1472                         head.winning = 1;
1473 }
1474
1475 // clear the .winning flags
1476 void ClearWinners(void)
1477 {
1478         entity head;
1479         FOR_EACH_PLAYER(head)
1480                 head.winning = 0;
1481 }
1482
1483 // Onslaught winning condition:
1484 // game terminates if only one team has a working generator (or none)
1485 float WinningCondition_Onslaught()
1486 {
1487         entity head;
1488         local float t1, t2, t3, t4;
1489
1490         WinningConditionHelper(); // set worldstatus
1491
1492         if(inWarmupStage)
1493                 return WINNING_NO;
1494
1495         // first check if the game has ended
1496         t1 = t2 = t3 = t4 = 0;
1497         head = find(world, classname, "onslaught_generator");
1498         while (head)
1499         {
1500                 if (head.health > 0)
1501                 {
1502                         if (head.team == COLOR_TEAM1) t1 = 1;
1503                         if (head.team == COLOR_TEAM2) t2 = 1;
1504                         if (head.team == COLOR_TEAM3) t3 = 1;
1505                         if (head.team == COLOR_TEAM4) t4 = 1;
1506                 }
1507                 head = find(head, classname, "onslaught_generator");
1508         }
1509         if (t1 + t2 + t3 + t4 < 2)
1510         {
1511                 // game over, only one team remains (or none)
1512                 ClearWinners();
1513                 if (t1) SetWinners(team, COLOR_TEAM1);
1514                 if (t2) SetWinners(team, COLOR_TEAM2);
1515                 if (t3) SetWinners(team, COLOR_TEAM3);
1516                 if (t4) SetWinners(team, COLOR_TEAM4);
1517                 dprint("Have a winner, ending game.\n");
1518                 return WINNING_YES;
1519         }
1520
1521         // Two or more teams remain
1522         return WINNING_NO;
1523 }
1524
1525 float LMS_NewPlayerLives()
1526 {
1527         float fl;
1528         fl = cvar("fraglimit");
1529         if(fl == 0)
1530                 fl = 999;
1531
1532         // first player has left the game for dying too much? Nobody else can get in.
1533         if(lms_lowest_lives < 1)
1534                 return 0;
1535
1536         if(!cvar("g_lms_join_anytime"))
1537                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1538                         return 0;
1539
1540         return bound(1, lms_lowest_lives, fl);
1541 }
1542
1543 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1544 // they win. Otherwise the defending team wins once the timelimit passes.
1545 void assault_new_round();
1546 float WinningCondition_Assault()
1547 {
1548         local float status;
1549
1550         WinningConditionHelper(); // set worldstatus
1551
1552         status = WINNING_NO;
1553         // as the timelimit has not yet passed just assume the defending team will win
1554         if(assault_attacker_team == COLOR_TEAM1)
1555         {
1556                 SetWinners(team, COLOR_TEAM2);
1557         }
1558         else
1559         {
1560                 SetWinners(team, COLOR_TEAM1);
1561         }
1562
1563         local entity ent;
1564         ent = find(world, classname, "target_assault_roundend");
1565         if(ent)
1566         {
1567                 if(ent.winning) // round end has been triggered by attacking team
1568                 {
1569                         bprint("ASSAULT: round completed...\n");
1570                         SetWinners(team, assault_attacker_team);
1571
1572                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1573
1574                         if(ent.cnt == 1) // this was the second round
1575                         {
1576                                 status = WINNING_YES;
1577                         }
1578                         else
1579                         {
1580                                 local entity oldself;
1581                                 oldself = self;
1582                                 self = ent;
1583                                 assault_new_round();
1584                                 self = oldself;
1585                         }
1586                 }
1587         }
1588
1589         return status;
1590 }
1591
1592 // LMS winning condition: game terminates if and only if there's at most one
1593 // one player who's living lives. Top two scores being equal cancels the time
1594 // limit.
1595 float WinningCondition_LMS()
1596 {
1597         entity head, head2;
1598         float have_player;
1599         float have_players;
1600         float l;
1601
1602         have_player = FALSE;
1603         have_players = FALSE;
1604         l = LMS_NewPlayerLives();
1605
1606         head = find(world, classname, "player");
1607         if(head)
1608                 have_player = TRUE;
1609         head2 = find(head, classname, "player");
1610         if(head2)
1611                 have_players = TRUE;
1612
1613         if(have_player)
1614         {
1615                 // we have at least one player
1616                 if(have_players)
1617                 {
1618                         // two or more active players - continue with the game
1619                 }
1620                 else
1621                 {
1622                         // exactly one player?
1623
1624                         ClearWinners();
1625                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1626
1627                         if(l)
1628                         {
1629                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1630                                 return WINNING_NO;
1631                         }
1632                         else
1633                         {
1634                                 // a winner!
1635                                 // and assign him his first place
1636                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1637                                 return WINNING_YES;
1638                         }
1639                 }
1640         }
1641         else
1642         {
1643                 // nobody is playing at all...
1644                 if(l)
1645                 {
1646                         // wait for players...
1647                 }
1648                 else
1649                 {
1650                         // SNAFU (maybe a draw game?)
1651                         ClearWinners();
1652                         dprint("No players, ending game.\n");
1653                         return WINNING_YES;
1654                 }
1655         }
1656
1657         // When we get here, we have at least two players who are actually LIVING,
1658         // now check if the top two players have equal score.
1659         WinningConditionHelper();
1660
1661         ClearWinners();
1662         if(WinningConditionHelper_winner)
1663                 WinningConditionHelper_winner.winning = TRUE;
1664         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1665                 return WINNING_NEVER;
1666
1667         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1668         return WINNING_NO;
1669 }
1670
1671 void ShuffleMaplist()
1672 {
1673         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1674 }
1675
1676 float leaderfrags;
1677 float WinningCondition_Scores(float limit, float leadlimit)
1678 {
1679         // TODO make everything use THIS winning condition (except LMS)
1680         WinningConditionHelper();
1681
1682         if(teams_matter)
1683         {
1684                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1685                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1686                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1687                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1688         }
1689
1690         ClearWinners();
1691         if(WinningConditionHelper_winner)
1692                 WinningConditionHelper_winner.winning = 1;
1693         if(WinningConditionHelper_winnerteam >= 0)
1694                 SetWinners(team, WinningConditionHelper_winnerteam);
1695
1696         if(WinningConditionHelper_lowerisbetter)
1697         {
1698                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1699                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1700                 limit = -limit;
1701         }
1702
1703         if(WinningConditionHelper_zeroisworst)
1704                 leadlimit = 0; // not supported in this mode
1705
1706         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1707         // these modes always score in increments of 1, thus this makes sense
1708         {
1709                 if(leaderfrags != WinningConditionHelper_topscore)
1710                 {
1711                         leaderfrags = WinningConditionHelper_topscore;
1712
1713                         if (limit)
1714                         if (leaderfrags == limit - 1)
1715                                 play2all("announcer/robotic/1fragleft.wav");
1716                         else if (leaderfrags == limit - 2)
1717                                 play2all("announcer/robotic/2fragsleft.wav");
1718                         else if (leaderfrags == limit - 3)
1719                                 play2all("announcer/robotic/3fragsleft.wav");
1720                 }
1721         }
1722
1723         return GetWinningCode(
1724                 WinningConditionHelper_topscore &&
1725                 (
1726                         (limit && (WinningConditionHelper_topscore >= limit))
1727                         ||
1728                         (leadlimit && (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit))
1729                 ),
1730                 WinningConditionHelper_equality
1731         );
1732 }
1733
1734 float WinningCondition_Race(float fraglimit)
1735 {
1736         float wc;
1737         entity p;
1738         float n, c;
1739
1740         n = 0;
1741         c = 0;
1742         FOR_EACH_PLAYER(p)
1743         {
1744                 ++n;
1745                 if(p.race_completed)
1746                         ++c;
1747         }
1748         if(n && (n == c))
1749                 return WINNING_YES;
1750         wc = WinningCondition_Scores(fraglimit, 0);
1751
1752         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1753         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1754         // do NOT support equality when the laps are all raced!
1755                 return WINNING_STARTSUDDENDEATHOVERTIME;
1756         else
1757                 return WINNING_NEVER;
1758         return wc;
1759 }
1760
1761 void ReadyRestart();
1762 float WinningCondition_QualifyingThenRace(float limit)
1763 {
1764         float wc;
1765         wc = WinningCondition_Scores(limit, 0);
1766
1767         // NEVER initiate overtime
1768         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1769         {
1770                 return WINNING_YES;
1771         }
1772
1773         return wc;
1774 }
1775
1776 float WinningCondition_RanOutOfSpawns()
1777 {
1778         entity head;
1779
1780         if(have_team_spawns <= 0)
1781                 return WINNING_NO;
1782
1783         if(!some_spawn_has_been_used)
1784                 return WINNING_NO;
1785
1786         team1_score = team2_score = team3_score = team4_score = 0;
1787
1788         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1789         {
1790                 if(head.team == COLOR_TEAM1)
1791                         team1_score = 1;
1792                 else if(head.team == COLOR_TEAM2)
1793                         team2_score = 1;
1794                 else if(head.team == COLOR_TEAM3)
1795                         team3_score = 1;
1796                 else if(head.team == COLOR_TEAM4)
1797                         team4_score = 1;
1798         }
1799
1800         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1801         {
1802                 if(head.team == COLOR_TEAM1)
1803                         team1_score = 1;
1804                 else if(head.team == COLOR_TEAM2)
1805                         team2_score = 1;
1806                 else if(head.team == COLOR_TEAM3)
1807                         team3_score = 1;
1808                 else if(head.team == COLOR_TEAM4)
1809                         team4_score = 1;
1810         }
1811
1812         ClearWinners();
1813         if(team1_score + team2_score + team3_score + team4_score == 0)
1814         {
1815                 checkrules_equality = TRUE;
1816                 return WINNING_YES;
1817         }
1818         else if(team1_score + team2_score + team3_score + team4_score == 1)
1819         {
1820                 float t, i;
1821                 if(team1_score) t = COLOR_TEAM1;
1822                 if(team2_score) t = COLOR_TEAM2;
1823                 if(team3_score) t = COLOR_TEAM3;
1824                 if(team4_score) t = COLOR_TEAM4;
1825                 CheckAllowedTeams(world);
1826                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1827                 {
1828                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1829                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1830                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1831                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1832                 }
1833
1834                 AddWinners(team, t);
1835                 return WINNING_YES;
1836         }
1837         else
1838                 return WINNING_NO;
1839 }
1840
1841 /*
1842 ============
1843 CheckRules_World
1844
1845 Exit deathmatch games upon conditions
1846 ============
1847 */
1848 void CheckRules_World()
1849 {
1850         float timelimit;
1851         float fraglimit;
1852         float leadlimit;
1853
1854         VoteThink();
1855         MapVote_Think();
1856
1857         SetDefaultAlpha();
1858
1859         /*
1860         MapVote_Think should now do that part
1861         if (intermission_running)
1862                 if (time >= intermission_exittime + 60)
1863                 {
1864                         if(!DoNextMapOverride())
1865                                 GotoNextMap();
1866                         return;
1867                 }
1868         */
1869
1870         if (gameover)   // someone else quit the game already
1871         {
1872                 if(player_count == 0) // Nobody there? Then let's go to the next map
1873                         MapVote_Start();
1874                         // this will actually check the player count in the next frame
1875                         // again, but this shouldn't hurt
1876                 return;
1877         }
1878
1879         timelimit = cvar("timelimit") * 60;
1880         fraglimit = cvar("fraglimit");
1881         leadlimit = cvar("leadlimit");
1882
1883         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1884         {
1885                 if(timelimit > 0)
1886                         timelimit = 0; // timelimit is not made for warmup
1887                 if(fraglimit > 0)
1888                         fraglimit = 0; // no fraglimit for now
1889                 leadlimit = 0; // no leadlimit for now
1890         }
1891
1892         if(g_onslaught)
1893                 timelimit = 0; // ONS has its own overtime rule
1894
1895         if(timelimit > 0)
1896         {
1897                 timelimit += game_starttime;
1898         }
1899         else if (timelimit < 0)
1900         {
1901                 // endmatch
1902                 NextLevel();
1903                 return;
1904         }
1905
1906         float wantovertime;
1907         wantovertime = 0;
1908
1909         if(checkrules_suddendeathend)
1910         {
1911                 if(!checkrules_suddendeathwarning)
1912                 {
1913                         checkrules_suddendeathwarning = TRUE;
1914                         if(g_race && !g_race_qualifying)
1915                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1916                         else
1917                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1918                 }
1919         }
1920         else
1921         {
1922                 if (timelimit && time >= timelimit)
1923                 {
1924                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1925                         {
1926                                 float totalplayers;
1927                                 float playerswithlaps;
1928                                 float readyplayers;
1929                                 entity head;
1930                                 totalplayers = playerswithlaps = readyplayers = 0;
1931                                 FOR_EACH_PLAYER(head)
1932                                 {
1933                                         ++totalplayers;
1934                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1935                                                 ++playerswithlaps;
1936                                         if(head.ready)
1937                                                 ++readyplayers;
1938                                 }
1939
1940                                 // at least 2 of the players have completed a lap: start the RACE
1941                                 // otherwise, the players should end the qualifying on their own
1942                                 if(readyplayers || playerswithlaps >= 2)
1943                                 {
1944                                         checkrules_suddendeathend = 0;
1945                                         ReadyRestart(); // go to race
1946                                         return;
1947                                 }
1948                                 else
1949                                         wantovertime |= InitiateSuddenDeath();
1950                         }
1951                         else
1952                                 wantovertime |= InitiateSuddenDeath();
1953                 }
1954         }
1955
1956         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1957         {
1958                 NextLevel();
1959                 return;
1960         }
1961
1962         float checkrules_status;
1963         checkrules_status = WinningCondition_RanOutOfSpawns();
1964         if(checkrules_status == WINNING_YES)
1965         {
1966                 bprint("Hey! Someone ran out of spawns!\n");
1967         }
1968         else if(g_race && !g_race_qualifying && timelimit >= 0)
1969         {
1970                 checkrules_status = WinningCondition_Race(fraglimit);
1971                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
1972         }
1973         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1974         {
1975                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1976                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
1977         }
1978         else if(g_assault)
1979         {
1980                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1981         }
1982         else if(g_lms)
1983         {
1984                 checkrules_status = WinningCondition_LMS();
1985         }
1986         else if (g_onslaught)
1987         {
1988                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1989         }
1990         else
1991         {
1992                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1993                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
1994         }
1995
1996         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1997         {
1998                 checkrules_status = WINNING_NEVER;
1999                 checkrules_overtimesadded = -1;
2000                 wantovertime |= InitiateSuddenDeath();
2001         }
2002
2003         if(checkrules_status == WINNING_NEVER)
2004                 // equality cases! Nobody wins if the overtime ends in a draw.
2005                 ClearWinners();
2006
2007         if(wantovertime)
2008         {
2009                 if(checkrules_status == WINNING_NEVER)
2010                         InitiateOvertime();
2011                 else
2012                         checkrules_status = WINNING_YES;
2013         }
2014
2015         if(checkrules_suddendeathend)
2016                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2017                         checkrules_status = WINNING_YES;
2018
2019         if(checkrules_status == WINNING_YES)
2020         {
2021                 //print("WINNING\n");
2022                 NextLevel();
2023         }
2024 };
2025
2026 float mapvote_nextthink;
2027 float mapvote_initialized;
2028 float mapvote_keeptwotime;
2029 float mapvote_timeout;
2030 string mapvote_message;
2031 string mapvote_screenshot_dir;
2032
2033 float mapvote_count;
2034 float mapvote_count_real;
2035 string mapvote_maps[MAPVOTE_COUNT];
2036 float mapvote_maps_suggested[MAPVOTE_COUNT];
2037 string mapvote_suggestions[MAPVOTE_COUNT];
2038 float mapvote_suggestion_ptr;
2039 float mapvote_maxlen;
2040 float mapvote_voters;
2041 float mapvote_votes[MAPVOTE_COUNT];
2042 float mapvote_run;
2043 float mapvote_detail;
2044 float mapvote_abstain;
2045 .float mapvote;
2046
2047 void MapVote_ClearAllVotes()
2048 {
2049         FOR_EACH_CLIENT(other)
2050                 other.mapvote = 0;
2051 }
2052
2053 string MapVote_Suggest(string m)
2054 {
2055         float i;
2056         if(m == "")
2057                 return "That's not how to use this command.";
2058         if(!cvar("g_maplist_votable_suggestions"))
2059                 return "Suggestions are not accepted on this server.";
2060         if(mapvote_initialized)
2061                 return "Can't suggest - voting is already in progress!";
2062         m = MapInfo_FixName(m);
2063         if(!m)
2064                 return "The map you suggested is not available on this server.";
2065         if(!cvar("g_maplist_votable_override_mostrecent"))
2066                 if(Map_IsRecent(m))
2067                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2068
2069         if(!MapInfo_CheckMap(m))
2070                 return "The map you suggested does not support the current game mode.";
2071         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2072                 if(mapvote_suggestions[i] == m)
2073                         return "This map was already suggested.";
2074         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2075         {
2076                 i = floor(random() * mapvote_suggestion_ptr);
2077         }
2078         else
2079         {
2080                 i = mapvote_suggestion_ptr;
2081                 mapvote_suggestion_ptr += 1;
2082         }
2083         if(mapvote_suggestions[i] != "")
2084                 strunzone(mapvote_suggestions[i]);
2085         mapvote_suggestions[i] = strzone(m);
2086         if(cvar("sv_eventlog"))
2087                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2088         return strcat("Suggestion of ", m, " accepted.");
2089 }
2090
2091 void MapVote_AddVotable(string nextMap, float isSuggestion)
2092 {
2093         float j;
2094         if(nextMap == "")
2095                 return;
2096         for(j = 0; j < mapvote_count; ++j)
2097                 if(mapvote_maps[j] == nextMap)
2098                         return;
2099         if(strlen(nextMap) > mapvote_maxlen)
2100                 mapvote_maxlen = strlen(nextMap);
2101         mapvote_maps[mapvote_count] = strzone(nextMap);
2102         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2103         mapvote_count += 1;
2104 }
2105
2106 void MapVote_Spawn();
2107 void MapVote_Init()
2108 {
2109         float i;
2110         float nmax, smax;
2111
2112         MapVote_ClearAllVotes();
2113
2114         mapvote_count = 0;
2115         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2116         mapvote_abstain = cvar("g_maplist_votable_abstain");
2117
2118         if(mapvote_abstain)
2119                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2120         else
2121                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2122         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2123
2124         if(mapvote_suggestion_ptr)
2125                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2126                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2127
2128         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2129                 MapVote_AddVotable(GetNextMap(), FALSE);
2130
2131         if(mapvote_count == 0)
2132         {
2133                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2134                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2135                 if(cvar("g_maplist_shuffle"))
2136                         ShuffleMaplist();
2137                 localcmd("\nmenu_cmd sync\n");
2138                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2139                         MapVote_AddVotable(GetNextMap(), FALSE);
2140         }
2141
2142         mapvote_count_real = mapvote_count;
2143         if(mapvote_abstain)
2144                 MapVote_AddVotable("don't care", 0);
2145
2146         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2147
2148         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2149         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2150         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2151                 mapvote_keeptwotime = 0;
2152         mapvote_message = "Choose a map and press its key!";
2153
2154         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2155         if(mapvote_screenshot_dir == "")
2156                 mapvote_screenshot_dir = "maps";
2157         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2158
2159         MapVote_Spawn();
2160 }
2161
2162 void MapVote_SendPicture(float id)
2163 {
2164         msg_entity = self;
2165         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2166         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2167         WriteByte(MSG_ONE, id);
2168         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2169 }
2170
2171 float GameCommand_MapVote(string cmd)
2172 {
2173         if(!intermission_running)
2174                 return FALSE;
2175
2176         if(cmd == "mv_getpic")
2177         {
2178                 MapVote_SendPicture(stof(argv(1)));
2179                 return TRUE;
2180         }
2181
2182         return FALSE;
2183 }
2184
2185 float MapVote_GetMapMask()
2186 {
2187         float mask, i, power;
2188         mask = 0;
2189         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2190                 if(mapvote_maps[i] != "")
2191                         mask |= power;
2192         return mask;
2193 }
2194
2195 entity mapvote_ent;
2196 float MapVote_SendEntity(entity to, float sf)
2197 {
2198         string mapfile, pakfile;
2199         float i, o;
2200
2201         if(sf & 1)
2202                 sf &~= 2; // if we send 1, we don't need to also send 2
2203
2204         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2205         WriteByte(MSG_ENTITY, sf);
2206
2207         if(sf & 1)
2208         {
2209                 // flag 1 == initialization
2210                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2211                 WriteByte(MSG_ENTITY, mapvote_count);
2212                 WriteByte(MSG_ENTITY, mapvote_abstain);
2213                 WriteByte(MSG_ENTITY, mapvote_detail);
2214                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2215                 if(mapvote_count <= 8)
2216                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2217                 else
2218                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2219                 for(i = 0; i < mapvote_count; ++i)
2220                         if(mapvote_maps[i] != "")
2221                         {
2222                                 if(mapvote_abstain && i == mapvote_count - 1)
2223                                 {
2224                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2225                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2226                                 }
2227                                 else
2228                                 {
2229                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2230                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2231                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2232                                         if(pakfile == "")
2233                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2234                                         if(pakfile == "")
2235                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2236                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2237                                                 pakfile = substring(pakfile, o, 999);
2238                                         WriteString(MSG_ENTITY, pakfile);
2239                                 }
2240                         }
2241         }
2242
2243         if(sf & 2)
2244         {
2245                 // flag 2 == update of mask
2246                 if(mapvote_count <= 8)
2247                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2248                 else
2249                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2250         }
2251
2252         if(sf & 4)
2253         {
2254                 if(mapvote_detail)
2255                         for(i = 0; i < mapvote_count; ++i)
2256                                 if(mapvote_maps[i] != "")
2257                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2258
2259                 WriteByte(MSG_ENTITY, to.mapvote);
2260         }
2261
2262         return TRUE;
2263 }
2264
2265 void MapVote_Spawn()
2266 {
2267         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2268 }
2269
2270 void MapVote_TouchMask()
2271 {
2272         mapvote_ent.SendFlags |= 2;
2273 }
2274
2275 void MapVote_TouchVotes(entity voter)
2276 {
2277         mapvote_ent.SendFlags |= 4;
2278 }
2279
2280 float MapVote_Finished(float mappos)
2281 {
2282         string result;
2283         float i;
2284         float didntvote;
2285
2286         if(cvar("sv_eventlog"))
2287         {
2288                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2289                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2290                 didntvote = mapvote_voters;
2291                 for(i = 0; i < mapvote_count; ++i)
2292                         if(mapvote_maps[i] != "")
2293                         {
2294                                 didntvote -= mapvote_votes[i];
2295                                 if(i != mappos)
2296                                 {
2297                                         result = strcat(result, ":", mapvote_maps[i]);
2298                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2299                                 }
2300                         }
2301                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2302
2303                 GameLogEcho(result);
2304                 if(mapvote_maps_suggested[mappos])
2305                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2306         }
2307
2308         FOR_EACH_REALCLIENT(other)
2309                 FixClientCvars(other);
2310
2311         Map_Goto_SetStr(mapvote_maps[mappos]);
2312         Map_Goto();
2313         alreadychangedlevel = TRUE;
2314         return TRUE;
2315 }
2316 void MapVote_CheckRules_1()
2317 {
2318         float i;
2319
2320         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2321         {
2322                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2323                 mapvote_votes[i] = 0;
2324         }
2325
2326         mapvote_voters = 0;
2327         FOR_EACH_REALCLIENT(other)
2328         {
2329                 ++mapvote_voters;
2330                 if(other.mapvote)
2331                 {
2332                         i = other.mapvote - 1;
2333                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2334                         mapvote_votes[i] = mapvote_votes[i] + 1;
2335                 }
2336         }
2337 }
2338
2339 float MapVote_CheckRules_2()
2340 {
2341         float i;
2342         float firstPlace, secondPlace;
2343         float firstPlaceVotes, secondPlaceVotes;
2344         float mapvote_voters_real;
2345         string result;
2346
2347         if(mapvote_count_real == 1)
2348                 return MapVote_Finished(0);
2349
2350         mapvote_voters_real = mapvote_voters;
2351         if(mapvote_abstain)
2352                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2353
2354         RandomSelection_Init();
2355         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2356                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2357         firstPlace = RandomSelection_chosen_float;
2358         firstPlaceVotes = RandomSelection_best_priority;
2359         //dprint("First place: ", ftos(firstPlace), "\n");
2360         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2361
2362         RandomSelection_Init();
2363         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2364                 if(i != firstPlace)
2365                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2366         secondPlace = RandomSelection_chosen_float;
2367         secondPlaceVotes = RandomSelection_best_priority;
2368         //dprint("Second place: ", ftos(secondPlace), "\n");
2369         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2370
2371         if(firstPlace == -1)
2372                 error("No first place in map vote... WTF?");
2373
2374         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2375                 return MapVote_Finished(firstPlace);
2376
2377         if(mapvote_keeptwotime)
2378                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2379                 {
2380                         float didntvote;
2381                         MapVote_TouchMask();
2382                         mapvote_message = "Now decide between the TOP TWO!";
2383                         mapvote_keeptwotime = 0;
2384                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2385                         result = strcat(result, ":", ftos(firstPlaceVotes));
2386                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2387                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2388                         didntvote = mapvote_voters;
2389                         for(i = 0; i < mapvote_count; ++i)
2390                                 if(mapvote_maps[i] != "")
2391                                 {
2392                                         didntvote -= mapvote_votes[i];
2393                                         if(i != firstPlace)
2394                                                 if(i != secondPlace)
2395                                                 {
2396                                                         result = strcat(result, ":", mapvote_maps[i]);
2397                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2398                                                         if(i < mapvote_count_real)
2399                                                         {
2400                                                                 strunzone(mapvote_maps[i]);
2401                                                                 mapvote_maps[i] = "";
2402                                                         }
2403                                                 }
2404                                 }
2405                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2406                         if(cvar("sv_eventlog"))
2407                                 GameLogEcho(result);
2408                 }
2409
2410         return FALSE;
2411 }
2412 void MapVote_Tick()
2413 {
2414         float keeptwo;
2415         float totalvotes;
2416
2417         keeptwo = mapvote_keeptwotime;
2418         MapVote_CheckRules_1(); // count
2419         if(MapVote_CheckRules_2()) // decide
2420                 return;
2421
2422         totalvotes = 0;
2423         FOR_EACH_REALCLIENT(other)
2424         {
2425                 // hide scoreboard again
2426                 if(other.health != 2342)
2427                 {
2428                         other.health = 2342;
2429                         other.impulse = 0;
2430                         if(clienttype(other) == CLIENTTYPE_REAL)
2431                         {
2432                                 msg_entity = other;
2433                                 WriteByte(MSG_ONE, SVC_FINALE);
2434                                 WriteString(MSG_ONE, "");
2435                         }
2436                 }
2437
2438                 // clear possibly invalid votes
2439                 if(mapvote_maps[other.mapvote - 1] == "")
2440                         other.mapvote = 0;
2441                 // use impulses as new vote
2442                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2443                         if(mapvote_maps[other.impulse - 1] != "")
2444                         {
2445                                 other.mapvote = other.impulse;
2446                                 MapVote_TouchVotes(other);
2447                         }
2448                 other.impulse = 0;
2449
2450                 if(other.mapvote)
2451                         ++totalvotes;
2452         }
2453
2454         MapVote_CheckRules_1(); // just count
2455 }
2456 void MapVote_Start()
2457 {
2458         if(mapvote_run)
2459                 return;
2460
2461         MapInfo_Enumerate();
2462         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2463                 mapvote_run = TRUE;
2464 }
2465 void MapVote_Think()
2466 {
2467         if(!mapvote_run)
2468                 return;
2469
2470         if(alreadychangedlevel)
2471                 return;
2472
2473         if(time < mapvote_nextthink)
2474                 return;
2475         //dprint("tick\n");
2476
2477         mapvote_nextthink = time + 0.5;
2478
2479         if(!mapvote_initialized)
2480         {
2481                 if(cvar("rescan_pending") == 1)
2482                 {
2483                         cvar_set("rescan_pending", "2");
2484                         localcmd("fs_rescan\nrescan_pending 3\n");
2485                         return;
2486                 }
2487                 else if(cvar("rescan_pending") == 2)
2488                 {
2489                         return;
2490                 }
2491                 else if(cvar("rescan_pending") == 3)
2492                 {
2493                         // now build missing mapinfo files
2494                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2495                                 return;
2496
2497                         // we're done, start the timer
2498                         cvar_set("rescan_pending", "0");
2499                 }
2500
2501                 mapvote_initialized = TRUE;
2502                 if(DoNextMapOverride())
2503                         return;
2504                 if(!cvar("g_maplist_votable") || player_count <= 0)
2505                 {
2506                         GotoNextMap();
2507                         return;
2508                 }
2509                 MapVote_Init();
2510         }
2511
2512         MapVote_Tick();
2513 };
2514
2515 string GotoMap(string m)
2516 {
2517         if(!MapInfo_CheckMap(m))
2518                 return "The map you chose is not available on this server.";
2519         cvar_set("nextmap", m);
2520         cvar_set("timelimit", "-1");
2521         if(mapvote_initialized || alreadychangedlevel)
2522         {
2523                 if(DoNextMapOverride())
2524                         return "Map switch initiated.";
2525                 else
2526                         return "Hm... no. For some reason I like THIS map more.";
2527         }
2528         else
2529                 return "Map switch will happen after scoreboard.";
2530 }
2531
2532
2533 void EndFrame()
2534 {
2535         float altime;
2536         FOR_EACH_REALCLIENT(self)
2537         {
2538                 if(self.classname == "spectator")
2539                 {
2540                         if(self.enemy.typehitsound)
2541                                 play2(self, "misc/typehit.wav");
2542                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2543                                 play2(self, "misc/hit.wav");
2544                 }
2545                 else
2546                 {
2547                         if(self.typehitsound)
2548                                 play2(self, "misc/typehit.wav");
2549                         else if(self.hitsound && self.cvar_cl_hitsound)
2550                                 play2(self, "misc/hit.wav");
2551                 }
2552         }
2553         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2554         // add 1 frametime because after this, engine SV_Physics
2555         // increases time by a frametime and then networks the frame
2556         // add another frametime because client shows everything with
2557         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2558         // needed!
2559         FOR_EACH_CLIENT(self)
2560         {
2561                 self.hitsound = FALSE;
2562                 self.typehitsound = FALSE;
2563                 antilag_record(self, altime);
2564         }
2565 }
2566
2567
2568 /*
2569  * RedirectionThink:
2570  * returns TRUE if redirecting
2571  */
2572 float redirection_timeout;
2573 float redirection_nextthink;
2574 float RedirectionThink()
2575 {
2576         float clients_found;
2577
2578         if(redirection_target == "")
2579                 return FALSE;
2580
2581         if(!redirection_timeout)
2582         {
2583                 cvar_set("sv_public", "-2");
2584                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2585                 if(redirection_target == "self")
2586                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2587                 else
2588                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2589         }
2590
2591         if(time < redirection_nextthink)
2592                 return TRUE;
2593
2594         redirection_nextthink = time + 1;
2595
2596         clients_found = 0;
2597         FOR_EACH_REALCLIENT(self)
2598         {
2599                 print("Redirecting: sending connect command to ", self.netname, "\n");
2600                 if(redirection_target == "self")
2601                         stuffcmd(self, "\ndisconnect; reconnect\n");
2602                 else
2603                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2604                 ++clients_found;
2605         }
2606
2607         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2608
2609         if(time > redirection_timeout || clients_found == 0)
2610                 localcmd("\nwait; wait; wait; quit\n");
2611
2612         return TRUE;
2613 }
2614
2615 void RestoreGame()
2616 {
2617         // Loaded from a save game
2618         // some things then break, so let's work around them...
2619
2620         // Progs DB (capture records)
2621         if(sv_cheats)
2622                 ServerProgsDB = db_create();
2623         else
2624                 ServerProgsDB = db_load("server.db");
2625
2626         // Mapinfo
2627         MapInfo_Shutdown();
2628         MapInfo_Enumerate();
2629         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2630         WeaponStats_Init();
2631 }
2632
2633 void SV_Shutdown()
2634 {
2635         if(gameover > 1) // shutting down already?
2636                 return;
2637
2638         gameover = 2; // 2 = server shutting down
2639
2640         if(world_initialized > 0)
2641         {
2642                 world_initialized = 0;
2643                 print("Saving persistent data...\n");
2644                 Ban_SaveBans();
2645                 if(!sv_cheats)
2646                         db_save(ServerProgsDB, "server.db");
2647                 if(cvar("developer"))
2648                         db_save(TemporaryDB, "server-temp.db");
2649                 db_close(ServerProgsDB);
2650                 db_close(TemporaryDB);
2651                 print("done!\n");
2652                 // tell the bot system the game is ending now
2653                 bot_endgame();
2654
2655                 WeaponStats_Shutdown();
2656                 MapInfo_Shutdown();
2657         }
2658         else if(world_initialized == 0)
2659         {
2660                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2661         }
2662 }