data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         //reset all the flood variables
  83                         FOR_EACH_CLIENT(plr) {
  84                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
  85                         }
  86                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  87                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  88                         FOR_EACH_REALPLAYER(plr) {
  89                                 plr.lastV_angle = plr.v_angle;
  90                         }
  91                         self.nextthink = time;
  92                 }
  93         }
  94         else if (timeoutStatus == 2) {
  95                 if (remainingTimeoutTime > 0) {
  96                         timeStr = getTimeoutText(0);
  97                         FOR_EACH_REALCLIENT(plr) {
  98                                 if(plr.classname == "player") {
  99                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 100                                 }
 101                         }
 102                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 103                                 play2all("announcer/robotic/prepareforbattle.wav");
 104                         }
 105                         remainingTimeoutTime -= 1;
 106                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 107                 }
 108                 else {
 109                         //unpause the game again
 110                         remainingTimeoutTime = timeoutStatus = 0;
 111                         cvar_set("slowmo", ftos(orig_slowmo));
 112                         //and unlock the fixed view again once there is no timeout active anymore
 113                         FOR_EACH_REALPLAYER(plr) {
 114                                 plr.fixangle = FALSE;
 115                         }
 116                         //get rid of the countdown message
 117                         FOR_EACH_REALCLIENT(plr) {
 118                                 if(plr.classname == "player") {
 119                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 120                                 }
 121                         }
 122                         remove(self);
 123                         return;
 124                 }
 125
 126         }
 127         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 128                 FOR_EACH_REALCLIENT(plr) {
 129                         if(plr.classname == "player") {
 130                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 131                         }
 132                 }
 133                 remove(self);
 134                 return;
 135         }
 136 }
 137
 138 void GotoFirstMap()
 139 {
 140         float n;
 141         if(cvar("_sv_init"))
 142         {
 143                 // cvar_set("_sv_init", "0");
 144                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 145                 // to this "init" map on a dedicated server will cause no permanent
 146                 // harm
 147                 if(cvar("g_maplist_shuffle"))
 148                         ShuffleMaplist();
 149                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 150                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 151
 152                 MapInfo_Enumerate();
 153                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 154
 155                 if(!DoNextMapOverride())
 156                         GotoNextMap();
 157
 158                 return;
 159         }
 160
 161         if(time < 5)
 162         {
 163                 self.nextthink = time;
 164         }
 165         else
 166         {
 167                 self.nextthink = time + 1;
 168                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 169         }
 170 }
 171
 172 void cvar_changes_init()
 173 {
 174         float h;
 175         string k, v, d;
 176         float n, i;
 177
 178         if(cvar_changes)
 179                 strunzone(cvar_changes);
 180         cvar_changes = string_null;
 181
 182         h = buf_create();
 183         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 184         n = buf_getsize(h);
 185
 186         for(i = 0; i < n; ++i)
 187         {
 188                 k = bufstr_get(h, i);
 189
 190 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 191 #define BADCVAR(p) if(k == p) continue
 192                 // internal
 193                 BADPREFIX("csqc_");
 194                 BADPREFIX("cvar_check_");
 195                 BADCVAR("gamecfg");
 196                 BADCVAR("g_configversion");
 197                 BADCVAR("g_maplist_index");
 198                 BADCVAR("halflifebsp");
 199
 200                 // client
 201                 BADPREFIX("cl_");
 202                 BADPREFIX("con_");
 203                 BADPREFIX("g_campaign");
 204                 BADPREFIX("gl_");
 205                 BADPREFIX("joy");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("userbind");
 212                 BADPREFIX("v_");
 213                 BADPREFIX("vid_");
 214                 BADPREFIX("crosshair");
 215                 BADCVAR("mod_q3bsp_lightmapmergepower");
 216                 BADCVAR("mod_q3bsp_nolightmaps");
 217
 218                 // private
 219                 BADPREFIX("g_ban_");
 220                 BADPREFIX("g_chat_flood_");
 221                 BADPREFIX("g_voice_flood_");
 222                 BADPREFIX("rcon_");
 223                 BADPREFIX("settemp_");
 224                 BADPREFIX("sv_allowdownloads_");
 225                 BADPREFIX("sv_autodemo");
 226                 BADPREFIX("sv_curl_");
 227                 BADPREFIX("sv_eventlog");
 228                 BADPREFIX("sv_logscores_");
 229                 BADPREFIX("sv_master");
 230                 BADCVAR("g_banned_list");
 231                 BADCVAR("log_dest_udp");
 232                 BADCVAR("log_file");
 233                 BADCVAR("net_address");
 234                 BADCVAR("port");
 235                 BADCVAR("savedgamecfg");
 236                 BADCVAR("sv_heartbeatperoid");
 237                 BADCVAR("sv_vote_master_password");
 238                 BADCVAR("sys_colortranslation");
 239                 BADCVAR("sys_specialcharactertranslation");
 240                 BADCVAR("timestamps");
 241
 242                 // mapinfo
 243                 BADCVAR("timelimit");
 244                 BADCVAR("fraglimit");
 245                 BADCVAR("g_arena");
 246                 BADCVAR("g_assault");
 247                 BADCVAR("g_ctf");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_keyhunt");
 251                 BADCVAR("g_keyhunt_teams");
 252                 BADCVAR("g_onslaught");
 253                 BADCVAR("g_race");
 254                 BADCVAR("g_cts");
 255                 BADCVAR("g_runematch");
 256                 BADCVAR("g_tdm");
 257                 BADCVAR("teamplay");
 258
 259                 // long
 260                 BADCVAR("hostname");
 261                 BADCVAR("g_maplist");
 262                 BADCVAR("g_maplist_mostrecent");
 263                 BADCVAR("sv_motd");
 264 #undef BADPREFIX
 265 #undef BADCVAR
 266
 267                 v = cvar_string(k);
 268                 d = cvar_defstring(k);
 269                 if(v != d)
 270                 {
 271                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 272                         if(strlen(cvar_changes) > 16384)
 273                         {
 274                                 cvar_changes = "// too many settings have been changed to show them here\n";
 275                                 break;
 276                         }
 277                 }
 278         }
 279         buf_del(h);
 280         if(cvar_changes == "")
 281                 cvar_changes = "// this server runs at default settings\n";
 282         else
 283                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 284         cvar_changes = strzone(cvar_changes);
 285 }
 286
 287 void detect_maptype()
 288 {
 289 #if 0
 290         vector o, v;
 291         float i;
 292
 293         for(;;)
 294         {
 295                 o = world.mins;
 296                 o_x += random() * (world.maxs_x - world.mins_x);
 297                 o_y += random() * (world.maxs_y - world.mins_y);
 298                 o_z += random() * (world.maxs_z - world.mins_z);
 299
 300                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 301                 if(trace_fraction == 1)
 302                         continue;
 303
 304                 v = trace_endpos;
 305
 306                 for(i = 0; i < 64; i += 4)
 307                 {
 308                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 309         if(trace_fraction == 1)
 310                 continue;
 311                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 312                 }
 313
 314                 break;
 315         }
 316 #endif
 317 }
 318
 319 entity randomseed;
 320 float RandomSeed_Send(entity to, float sf)
 321 {
 322         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 323         WriteShort(MSG_ENTITY, self.cnt);
 324         return TRUE;
 325 }
 326 void RandomSeed_Think()
 327 {
 328         self.cnt = bound(0, floor(random() * 65536), 65535);
 329         self.nextthink = time + 5;
 330
 331         self.SendFlags |= 1;
 332 }
 333 void RandomSeed_Spawn()
 334 {
 335         randomseed = spawn();
 336         randomseed.think = RandomSeed_Think;
 337         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 338
 339         entity oldself;
 340         oldself = self;
 341         self = randomseed;
 342         self.think(); // sets random seed and nextthink
 343         self = oldself;
 344 }
 345
 346 void spawnfunc___init_dedicated_server(void)
 347 {
 348         // handler for _init/_init map (only for dedicated server initialization)
 349
 350         world_initialized = -1; // don't complain
 351         cvar = cvar_builtin;
 352         cvar_string = cvar_string_builtin;
 353         cvar_set = cvar_set_builtin;
 354         dprint_load(); // load dprint status from cvar
 355
 356         remove = remove_unsafely;
 357
 358         entity e;
 359         e = spawn();
 360         e.think = GotoFirstMap;
 361         e.nextthink = time; // this is usually 1 at this point
 362
 363         e = spawn();
 364         e.classname = "info_player_deathmatch"; // safeguard against player joining
 365
 366         self.classname = "worldspawn"; // safeguard against various stuff ;)
 367
 368         MapInfo_Enumerate();
 369         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 370 }
 371
 372 void Map_MarkAsRecent(string m);
 373 float world_already_spawned;
 374 void RegisterWeapons();
 375 void Nagger_Init();
 376 void ClientInit_Spawn();
 377 void spawnfunc_worldspawn (void)
 378 {
 379         float fd, l, i, j, n;
 380         string s, col;
 381
 382         cvar = cvar_builtin;
 383         cvar_string = cvar_string_builtin;
 384         cvar_set = cvar_set_builtin;
 385         dprint_load(); // load dprint status from cvar
 386
 387         if(world_already_spawned)
 388                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 389         world_already_spawned = TRUE;
 390
 391         remove = remove_safely; // during spawning, watch what you remove!
 392
 393         check_unacceptable_compiler_bugs();
 394
 395         if(cvar_string("cvar_check_default") != "bypass")
 396         {
 397                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 398                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 399
 400                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 401                         error("Config file mismatch! Please update weapons.cfg and weaponsHavoc.cfg to match the QuakeC code, and restart the engine!");
 402         }
 403
 404         compressShortVector_init();
 405
 406         local entity head;
 407         head = nextent(world);
 408         maxclients = 0;
 409         while(head)
 410         {
 411                 ++maxclients;
 412                 head = nextent(head);
 413         }
 414
 415         // needs to be done so early as they would still spawn
 416         RegisterWeapons();
 417
 418         if(sv_cheats)
 419                 ServerProgsDB = db_create();
 420         else
 421                 ServerProgsDB = db_load("server.db");
 422
 423         TemporaryDB = db_create();
 424
 425         /*
 426         TODO sound pack system
 427         // initialize sound pack system
 428         soundpack = cvar_string("g_soundpack");
 429         if(soundpack != "")
 430                 soundpack = strcat(soundpack, "/");
 431         soundpack = strzone(soundpack);
 432         */
 433
 434         // 0 normal
 435         lightstyle(0, "m");
 436
 437         // 1 FLICKER (first variety)
 438         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 439
 440         // 2 SLOW STRONG PULSE
 441         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 442
 443         // 3 CANDLE (first variety)
 444         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 445
 446         // 4 FAST STROBE
 447         lightstyle(4, "mamamamamama");
 448
 449         // 5 GENTLE PULSE 1
 450         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 451
 452         // 6 FLICKER (second variety)
 453         lightstyle(6, "nmonqnmomnmomomno");
 454
 455         // 7 CANDLE (second variety)
 456         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 457
 458         // 8 CANDLE (third variety)
 459         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 460
 461         // 9 SLOW STROBE (fourth variety)
 462         lightstyle(9, "aaaaaaaazzzzzzzz");
 463
 464         // 10 FLUORESCENT FLICKER
 465         lightstyle(10, "mmamammmmammamamaaamammma");
 466
 467         // 11 SLOW PULSE NOT FADE TO BLACK
 468         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 469
 470         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 471
 472         // 63 testing
 473         lightstyle(63, "a");
 474
 475         if(cvar("g_campaign"))
 476                 CampaignPreInit();
 477
 478         Map_MarkAsRecent(mapname);
 479
 480         precache_model ("null"); // we need this one before InitGameplayMode
 481         InitGameplayMode();
 482         readlevelcvars();
 483         GrappleHookInit();
 484
 485         player_count = 0;
 486         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 487         if(bot_waypoints_for_items == 1)
 488                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 489                         bot_waypoints_for_items = 0;
 490
 491         // for setting by mapinfo
 492         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 493         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 494
 495         precache();
 496
 497         WaypointSprite_Init();
 498
 499         //if (g_domination)
 500         //      dom_init();
 501
 502         GameLogInit(); // prepare everything
 503         if(cvar("sv_eventlog"))
 504         {
 505                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 506                 s = strcat(s, ftos(random()));
 507                 matchid = strzone(s);
 508
 509                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 510                 s = ":gameinfo:mutators:LIST";
 511                 if(cvar("g_grappling_hook"))
 512                         s = strcat(s, ":grappling_hook");
 513                 if(!cvar("g_use_ammunition"))
 514                         s = strcat(s, ":no_use_ammunition");
 515                 if(!cvar("g_pickup_items"))
 516                         s = strcat(s, ":no_pickup_items");
 517                 if(cvar("g_instagib"))
 518                         s = strcat(s, ":instagib");
 519                 if(cvar_string("g_weaponarena") != "0")
 520                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 521                 if(cvar("g_nixnex"))
 522                         s = strcat(s, ":nixnex");
 523                 if(cvar("g_vampire"))
 524                         s = strcat(s, ":vampire");
 525                 if(cvar("g_laserguided_missile"))
 526                         s = strcat(s, ":laserguided_missile");
 527                 if(cvar("g_norecoil"))
 528                         s = strcat(s, ":norecoil");
 529                 if(cvar("g_midair"))
 530                         s = strcat(s, ":midair");
 531                 if(cvar("g_minstagib"))
 532                         s = strcat(s, ":minstagib");
 533                 GameLogEcho(s);
 534                 GameLogEcho(":gameinfo:end");
 535         }
 536         else
 537                 matchid = strzone(ftos(random()));
 538
 539         cvar_set("nextmap", "");
 540
 541         SetDefaultAlpha();
 542
 543         if(cvar("g_campaign"))
 544                 CampaignPostInit();
 545
 546         fteqcc_testbugs();
 547
 548         Ban_LoadBans();
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 552
 553         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 554         {
 555                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 556                 if(fd != -1)
 557                 {
 558                         while((s = fgets(fd)))
 559                         {
 560                                 l = tokenize_console(s);
 561                                 if(l < 2)
 562                                         continue;
 563                                 if(argv(0) == "cd")
 564                                 {
 565                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 566                                         print("  cdtrack ", argv(2), "\n");
 567                                 }
 568                                 else if(argv(0) == "fog")
 569                                 {
 570                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 571                                         print("  \"fog\" \"", s, "\"\n");
 572                                 }
 573                                 else if(argv(0) == "set")
 574                                 {
 575                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 576                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 577                                 }
 578                                 else if(argv(0) != "//")
 579                                 {
 580                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 581                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 582                                 }
 583                         }
 584                         fclose(fd);
 585                 }
 586         }
 587
 588         addstat(STAT_WEAPONS, AS_INT, weapons);
 589         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 590         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 591         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 592         Nagger_Init();
 593
 594         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 595         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 596         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 597         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 598         addstat(STAT_DAMAGE_HITS, AS_INT, damage_hits);
 599         addstat(STAT_DAMAGE_FIRED, AS_INT, maxdamage_fired);
 600         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 601         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 602         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 603
 604         next_pingtime = time + 5;
 605         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 606
 607         detect_maptype();
 608
 609         lsmaps_reply = "^7Maps available: ";
 610         for(i = 0, j = 0; i < MapInfo_count; ++i)
 611         {
 612                 if(MapInfo_Get_ByID(i))
 613                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 614                         {
 615                                 if(mod(i, 2))
 616                                         col = "^2";
 617                                 else
 618                                         col = "^3";
 619                                 ++j;
 620                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 621                         }
 622         }
 623         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 624
 625         maplist_reply = "^7Maps in list: ";
 626         n = tokenize_console(cvar_string("g_maplist"));
 627         for(i = 0, j = 0; i < n; ++i)
 628         {
 629                 if(MapInfo_CheckMap(argv(i)))
 630                 {
 631                         if(mod(j, 2))
 632                                 col = "^2";
 633                         else
 634                                 col = "^3";
 635                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 636                         ++j;
 637                 }
 638         }
 639         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 640         MapInfo_ClearTemps();
 641
 642         records_reply = strzone(getrecords());
 643
 644         ClientInit_Spawn();
 645         RandomSeed_Spawn();
 646
 647         world_initialized = 1;
 648 }
 649
 650 void spawnfunc_light (void)
 651 {
 652         //makestatic (self); // Who the f___ did that?
 653         remove(self);
 654 }
 655
 656 float TryFile( string pFilename )
 657 {
 658         local float lHandle;
 659         dprint("TryFile(\"", pFilename, "\")\n");
 660         lHandle = fopen( pFilename, FILE_READ );
 661         if( lHandle != -1 ) {
 662                 fclose( lHandle );
 663                 return TRUE;
 664         } else {
 665                 return FALSE;
 666         }
 667 };
 668
 669 string GetGametype()
 670 {
 671         return GametypeNameFromType(game);
 672 }
 673
 674 string getmapname_stored;
 675 string GetMapname()
 676 {
 677         return mapname;
 678 }
 679
 680 float Map_Count, Map_Current;
 681 string Map_Current_Name;
 682
 683 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 684 float GetMaplistPosition()
 685 {
 686         float pos, idx;
 687         string map;
 688
 689         map = GetMapname();
 690         idx = cvar("g_maplist_index");
 691
 692         if(idx >= 0)
 693                 if(idx < Map_Count)
 694                         if(map == argv(idx))
 695                                 return idx;
 696
 697         for(pos = 0; pos < Map_Count; ++pos)
 698                 if(map == argv(pos))
 699                         return pos;
 700
 701         // resume normal maplist rotation if current map is not in g_maplist
 702         return idx;
 703 }
 704
 705 float MapHasRightSize(string map)
 706 {
 707         float fh;
 708         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 709         if(cvar("g_maplist_check_waypoints"))
 710         {
 711                 dprint("checkwp "); dprint(map);
 712                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 713                 if(fh < 0)
 714                 {
 715                         dprint(": no waypoints\n");
 716                         return FALSE;
 717                 }
 718                 dprint(": has waypoints\n");
 719                 fclose(fh);
 720         }
 721
 722         // open map size restriction file
 723         dprint("opensize "); dprint(map);
 724         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 725         if(fh >= 0)
 726         {
 727                 float mapmin, mapmax;
 728                 dprint(": ok, ");
 729                 mapmin = stof(fgets(fh));
 730                 mapmax = stof(fgets(fh));
 731                 fclose(fh);
 732                 if(player_count < mapmin)
 733                 {
 734                         dprint("not enough\n");
 735                         return FALSE;
 736                 }
 737                 if(player_count > mapmax)
 738                 {
 739                         dprint("too many\n");
 740                         return FALSE;
 741                 }
 742                 dprint("right size\n");
 743                 return TRUE;
 744         }
 745         dprint(": not found\n");
 746         return TRUE;
 747 }
 748
 749 string Map_Filename(float position)
 750 {
 751         return strcat("maps/", argv(position), ".bsp");
 752 }
 753
 754 string strwords(string s, float w)
 755 {
 756         float endpos;
 757         for(endpos = 0; w && endpos >= 0; --w)
 758                 endpos = strstrofs(s, " ", endpos + 1);
 759         if(endpos < 0)
 760                 return s;
 761         else
 762                 return substring(s, 0, endpos);
 763 }
 764
 765 float strhasword(string s, string w)
 766 {
 767         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 768 }
 769
 770 void Map_MarkAsRecent(string m)
 771 {
 772         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 773 }
 774
 775 float Map_IsRecent(string m)
 776 {
 777         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 778 }
 779
 780 float Map_Check(float position, float pass)
 781 {
 782         string filename;
 783         string map_next;
 784         map_next = argv(position);
 785         if(pass <= 1)
 786         {
 787                 if(Map_IsRecent(map_next))
 788                         return 0;
 789         }
 790         filename = Map_Filename(position);
 791         if(MapInfo_CheckMap(map_next))
 792         {
 793                 if(pass == 2)
 794                         return 1;
 795                 if(MapHasRightSize(map_next))
 796                         return 1;
 797                 return 0;
 798         }
 799         else
 800                 dprint( "Couldn't select '", filename, "'..\n" );
 801
 802         return 0;
 803 }
 804
 805 void Map_Goto_SetStr(string nextmapname)
 806 {
 807         if(getmapname_stored != "")
 808                 strunzone(getmapname_stored);
 809         if(nextmapname == "")
 810                 getmapname_stored = "";
 811         else
 812                 getmapname_stored = strzone(nextmapname);
 813 }
 814
 815 void Map_Goto_SetFloat(float position)
 816 {
 817         cvar_set("g_maplist_index", ftos(position));
 818         Map_Goto_SetStr(argv(position));
 819 }
 820
 821 void GameResetCfg()
 822 {
 823         // settings persist, except...
 824         localcmd("\nsettemp_restore\n");
 825 };
 826
 827 void Map_Goto()
 828 {
 829         GameResetCfg();
 830         MapInfo_LoadMap(getmapname_stored);
 831 }
 832
 833 // return codes of map selectors:
 834 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 835 //   -2 = permanent failure
 836 float() MaplistMethod_Iterate = // usual method
 837 {
 838         float pass, i;
 839
 840         for(pass = 1; pass <= 2; ++pass)
 841         {
 842                 for(i = 1; i < Map_Count; ++i)
 843                 {
 844                         float mapindex;
 845                         mapindex = mod(i + Map_Current, Map_Count);
 846                         if(Map_Check(mapindex, pass))
 847                                 return mapindex;
 848                 }
 849         }
 850         return -1;
 851 }
 852
 853 float() MaplistMethod_Repeat = // fallback method
 854 {
 855         if(Map_Check(Map_Current, 2))
 856                 return Map_Current;
 857         return -2;
 858 }
 859
 860 float() MaplistMethod_Random = // random map selection
 861 {
 862         float i, imax;
 863
 864         imax = 42;
 865
 866         for(i = 0; i <= imax; ++i)
 867         {
 868                 float mapindex;
 869                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 870                 if(Map_Check(mapindex, 1))
 871                         return mapindex;
 872         }
 873         return -1;
 874 }
 875
 876 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 877 // the exponent sets a bias on the map selection:
 878 // the higher the exponent, the less likely "shortly repeated" same maps are
 879 {
 880         float i, j, imax, insertpos;
 881
 882         imax = 42;
 883
 884         for(i = 0; i <= imax; ++i)
 885         {
 886                 string newlist;
 887
 888                 // now reinsert this at another position
 889                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 890                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 891                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 892                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 893
 894                 // insert the current map there
 895                 newlist = "";
 896                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 897                         newlist = strcat(newlist, " ", argv(j));
 898                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 899                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 900                         newlist = strcat(newlist, " ", argv(j));
 901                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 902                 cvar_set("g_maplist", newlist);
 903                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 904
 905                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 906                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 907                 if(Map_Check(Map_Current, 1))
 908                         return Map_Current;
 909         }
 910         return -1;
 911 }
 912
 913 void Maplist_Init()
 914 {
 915         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 916         if(Map_Count == 0)
 917         {
 918                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 919                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
 920                 if(cvar("g_maplist_shuffle"))
 921                         ShuffleMaplist();
 922                 localcmd("\nmenu_cmd sync\n");
 923                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 924         }
 925         if(Map_Count == 0)
 926                 error("empty maplist, cannot select a new map");
 927         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 928
 929         if(Map_Current_Name)
 930                 strunzone(Map_Current_Name);
 931         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 932         // this may or may not be correct, but who cares, in the worst case a map
 933         // isn't chosen in the first pass that should have been
 934 }
 935
 936 string GetNextMap()
 937 {
 938         float nextMap;
 939
 940         Maplist_Init();
 941         nextMap = -1;
 942
 943         if(nextMap == -1)
 944                 if(cvar("g_maplist_shuffle") > 0)
 945                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 946
 947         if(nextMap == -1)
 948                 if(cvar("g_maplist_selectrandom"))
 949                         nextMap = MaplistMethod_Random();
 950
 951         if(nextMap == -1)
 952                 nextMap = MaplistMethod_Iterate();
 953
 954         if(nextMap == -1)
 955                 nextMap = MaplistMethod_Repeat();
 956
 957         if(nextMap >= 0)
 958         {
 959                 Map_Goto_SetFloat(nextMap);
 960                 return getmapname_stored;
 961         }
 962
 963         return "";
 964 };
 965
 966 float DoNextMapOverride()
 967 {
 968         if(cvar("g_campaign"))
 969         {
 970                 CampaignPostIntermission();
 971                 alreadychangedlevel = TRUE;
 972                 return TRUE;
 973         }
 974         if(cvar("quit_when_empty"))
 975         {
 976                 if(player_count <= currentbots)
 977                 {
 978                         localcmd("quit\n");
 979                         alreadychangedlevel = TRUE;
 980                         return TRUE;
 981                 }
 982         }
 983         if(cvar_string("quit_and_redirect") != "")
 984         {
 985                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 986                 alreadychangedlevel = TRUE;
 987                 return TRUE;
 988         }
 989         if (cvar("samelevel")) // if samelevel is set, stay on same level
 990         {
 991                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 992                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 993                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 994                 localcmd("restart\n");
 995                 //changelevel (mapname);
 996                 alreadychangedlevel = TRUE;
 997                 return TRUE;
 998         }
 999         if(cvar_string("nextmap") != "")
1000                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1001                 {
1002                         Map_Goto_SetStr(cvar_string("nextmap"));
1003                         Map_Goto();
1004                         alreadychangedlevel = TRUE;
1005                         return TRUE;
1006                 }
1007         if(cvar("lastlevel"))
1008         {
1009                 GameResetCfg();
1010                 localcmd("set lastlevel 0\ntogglemenu\n");
1011                 alreadychangedlevel = TRUE;
1012                 return TRUE;
1013         }
1014         return FALSE;
1015 };
1016
1017 void GotoNextMap()
1018 {
1019         //local string nextmap;
1020         //local float n, nummaps;
1021         //local string s;
1022         if (alreadychangedlevel)
1023                 return;
1024         alreadychangedlevel = TRUE;
1025
1026         {
1027                 string nextMap;
1028                 float allowReset;
1029
1030                 for(allowReset = 1; allowReset >= 0; --allowReset)
1031                 {
1032                         nextMap = GetNextMap();
1033                         if(nextMap != "")
1034                                 break;
1035
1036                         if(allowReset)
1037                         {
1038                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1039                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1040                                 if(cvar("g_maplist_shuffle"))
1041                                         ShuffleMaplist();
1042                                 localcmd("\nmenu_cmd sync\n");
1043                         }
1044                         else
1045                         {
1046                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1047                         }
1048                 }
1049                 Map_Goto();
1050         }
1051 };
1052
1053
1054 /*
1055 ============
1056 IntermissionThink
1057
1058 When the player presses attack or jump, change to the next level
1059 ============
1060 */
1061 .float autoscreenshot;
1062 void() MapVote_Start;
1063 void() MapVote_Think;
1064 float mapvote_initialized;
1065 void IntermissionThink()
1066 {
1067         FixIntermissionClient(self);
1068
1069         if(cvar("sv_autoscreenshot"))
1070         if(self.autoscreenshot > 0)
1071         if(time > self.autoscreenshot)
1072         {
1073                 self.autoscreenshot = -1;
1074                 if(clienttype(self) == CLIENTTYPE_REAL)
1075                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1076                 return;
1077         }
1078
1079         if (time < intermission_exittime)
1080                 return;
1081
1082         if(!mapvote_initialized)
1083                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1084                         return;
1085
1086         MapVote_Start();
1087 };
1088
1089 /*
1090 ============
1091 FindIntermission
1092
1093 Returns the entity to view from
1094 ============
1095 */
1096 /*
1097 entity FindIntermission()
1098 {
1099         local   entity spot;
1100         local   float cyc;
1101
1102 // look for info_intermission first
1103         spot = find (world, classname, "info_intermission");
1104         if (spot)
1105         {       // pick a random one
1106                 cyc = random() * 4;
1107                 while (cyc > 1)
1108                 {
1109                         spot = find (spot, classname, "info_intermission");
1110                         if (!spot)
1111                                 spot = find (spot, classname, "info_intermission");
1112                         cyc = cyc - 1;
1113                 }
1114                 return spot;
1115         }
1116
1117 // then look for the start position
1118         spot = find (world, classname, "info_player_start");
1119         if (spot)
1120                 return spot;
1121
1122 // testinfo_player_start is only found in regioned levels
1123         spot = find (world, classname, "testplayerstart");
1124         if (spot)
1125                 return spot;
1126
1127 // then look for the start position
1128         spot = find (world, classname, "info_player_deathmatch");
1129         if (spot)
1130                 return spot;
1131
1132         //objerror ("FindIntermission: no spot");
1133         return world;
1134 };
1135 */
1136
1137 /*
1138 ===============================================================================
1139
1140 RULES
1141
1142 ===============================================================================
1143 */
1144
1145 void DumpStats(float final)
1146 {
1147         local float file;
1148         local string s;
1149         local float to_console;
1150         local float to_eventlog;
1151         local float to_file;
1152         local float i;
1153
1154         to_console = cvar("sv_logscores_console");
1155         to_eventlog = cvar("sv_eventlog");
1156         to_file = cvar("sv_logscores_file");
1157
1158         if(!final)
1159         {
1160                 to_console = TRUE; // always print printstats replies
1161                 to_eventlog = FALSE; // but never print them to the event log
1162         }
1163
1164         if(to_eventlog)
1165                 if(cvar("sv_eventlog_console"))
1166                         to_console = FALSE; // otherwise we get the output twice
1167
1168         if(final)
1169                 s = ":scores:";
1170         else
1171                 s = ":status:";
1172         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1173
1174         if(to_console)
1175                 print(s, "\n");
1176         if(to_eventlog)
1177                 GameLogEcho(s);
1178         if(to_file)
1179         {
1180                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1181                 if(file == -1)
1182                         to_file = FALSE;
1183                 else
1184                         fputs(file, strcat(s, "\n"));
1185         }
1186
1187         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1188         if(to_console)
1189                 print(s, "\n");
1190         if(to_eventlog)
1191                 GameLogEcho(s);
1192         if(to_file)
1193                 fputs(file, strcat(s, "\n"));
1194
1195         FOR_EACH_CLIENT(other)
1196         {
1197                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1198                 {
1199                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1200                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1201                         if(other.classname == "player" || g_arena || g_lms)
1202                                 s = strcat(s, ftos(other.team), ":");
1203                         else
1204                                 s = strcat(s, "spectator:");
1205
1206                         if(to_console)
1207                                 print(s, other.netname, "\n");
1208                         if(to_eventlog)
1209                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1210                         if(to_file)
1211                                 fputs(file, strcat(s, other.netname, "\n"));
1212                 }
1213         }
1214
1215         if(teams_matter)
1216         {
1217                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1218                 if(to_console)
1219                         print(s, "\n");
1220                 if(to_eventlog)
1221                         GameLogEcho(s);
1222                 if(to_file)
1223                         fputs(file, strcat(s, "\n"));
1224
1225                 for(i = 1; i < 16; ++i)
1226                 {
1227                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1228                         s = strcat(s, ":", ftos(i));
1229                         if(to_console)
1230                                 print(s, "\n");
1231                         if(to_eventlog)
1232                                 GameLogEcho(s);
1233                         if(to_file)
1234                                 fputs(file, strcat(s, "\n"));
1235                 }
1236         }
1237
1238         if(to_console)
1239                 print(":end\n");
1240         if(to_eventlog)
1241                 GameLogEcho(":end");
1242         if(to_file)
1243         {
1244                 fputs(file, ":end\n");
1245                 fclose(file);
1246         }
1247 }
1248
1249 void FixIntermissionClient(entity e)
1250 {
1251         string s;
1252         if(!e.autoscreenshot) // initial call
1253         {
1254                 e.angles = e.v_angle;
1255                 e.angles_x = -e.angles_x;
1256                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1257                 e.health = -2342;
1258                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1259                 e.solid = SOLID_NOT;
1260                 e.movetype = MOVETYPE_NONE;
1261                 e.takedamage = DAMAGE_NO;
1262                 if(e.weaponentity)
1263                 {
1264                         e.weaponentity.effects = EF_NODRAW;
1265                         if (e.weaponentity.weaponentity)
1266                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1267                 }
1268                 if(clienttype(e) == CLIENTTYPE_REAL)
1269                 {
1270                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1271                         s = cvar_string("sv_intermission_cdtrack");
1272                         if(s != "")
1273                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1274                         msg_entity = e;
1275                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1276                 }
1277         }
1278
1279         //e.velocity = '0 0 0';
1280         //e.fixangle = TRUE;
1281
1282         // TODO halt weapon animation
1283 }
1284
1285
1286 /*
1287 go to the next level for deathmatch
1288 only called if a time or frag limit has expired
1289 */
1290 void NextLevel()
1291 {
1292         float minTotalFrags;
1293         float maxTotalFrags;
1294         float score;
1295         float f;
1296
1297         gameover = TRUE;
1298
1299         intermission_running = 1;
1300
1301 // enforce a wait time before allowing changelevel
1302         if(player_count > 0)
1303                 intermission_exittime = time + cvar("sv_mapchange_delay");
1304         else
1305                 intermission_exittime = -1;
1306
1307         /*
1308         WriteByte (MSG_ALL, SVC_CDTRACK);
1309         WriteByte (MSG_ALL, 3);
1310         WriteByte (MSG_ALL, 3);
1311         // done in FixIntermission
1312         */
1313
1314         //pos = FindIntermission ();
1315
1316         VoteReset();
1317
1318         DumpStats(TRUE);
1319
1320         if(cvar("sv_eventlog"))
1321                 GameLogEcho(":gameover");
1322
1323         GameLogClose();
1324
1325         FOR_EACH_CLIENT(other)
1326         {
1327                 FixIntermissionClient(other);
1328
1329                 if(other.winning)
1330                         bprint(other.netname, " ^7wins.\n");
1331         }
1332
1333         minTotalFrags = 0;
1334         maxTotalFrags = 0;
1335         FOR_EACH_PLAYER(other)
1336         {
1337                 if(maxTotalFrags < other.totalfrags)
1338                         maxTotalFrags = other.totalfrags;
1339                 if(minTotalFrags > other.totalfrags)
1340                         minTotalFrags = other.totalfrags;
1341         }
1342
1343         if(!currentbots)
1344         {
1345                 FOR_EACH_PLAYER(other)
1346                 {
1347                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1348                         f = bound(0, other.play_time / max(time, 1), 1);
1349                         // store some statistics?
1350                 }
1351         }
1352
1353         if(cvar("g_campaign"))
1354                 CampaignPreIntermission();
1355
1356         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1357 };
1358
1359 /*
1360 ============
1361 CheckRules_Player
1362
1363 Exit deathmatch games upon conditions
1364 ============
1365 */
1366 void CheckRules_Player()
1367 {
1368         if (gameover)   // someone else quit the game already
1369                 return;
1370
1371         if(self.deadflag == DEAD_NO)
1372                 self.play_time += frametime;
1373
1374         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1375         //   (div0: and that in CheckRules_World please)
1376 };
1377
1378 float checkrules_equality;
1379 float checkrules_suddendeathwarning;
1380 float checkrules_suddendeathend;
1381 float checkrules_overtimesadded; //how many overtimes have been already added
1382 float checkrules_status;
1383
1384 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1385 float WINNING_YES = 1; // winner found
1386 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1387 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1388
1389 void InitiateOvertime()
1390 {
1391         // Check first whether normal overtimes could be added before initiating suddendeath mode
1392         // - for this timelimit_overtime needs to be >0 of course
1393         // - also check the winning condition calculated in the previous frame and only add normal overtime
1394         //   again, if at the point at which timelimit would be extended again, still no winner was found
1395         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1396         {
1397                 ++checkrules_overtimesadded;
1398                 //add one more overtime by simply extending the timelimit
1399                 float tl;
1400                 tl = cvar("timelimit");
1401                 tl += cvar("timelimit_overtime");
1402                 cvar_set("timelimit", ftos(tl));
1403                 string minutesPlural;
1404                 if (cvar("timelimit_overtime") == 1)
1405                         minutesPlural = " ^3minute";
1406                 else
1407                         minutesPlural = " ^3minutes";
1408
1409                 bcenterprint(
1410                         strcat(
1411                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1412                                 ftos(cvar("timelimit_overtime")),
1413                                 minutesPlural,
1414                                 " to the game!"
1415                         )
1416                 );
1417         }
1418         else
1419         {
1420                 if(!checkrules_suddendeathend)
1421                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1422         }
1423 }
1424
1425 float GetWinningCode(float fraglimitreached, float equality)
1426 {
1427         if(equality)
1428                 if(fraglimitreached)
1429                         return WINNING_STARTSUDDENDEATHOVERTIME;
1430                 else
1431                         return WINNING_NEVER;
1432         else
1433                 if(fraglimitreached)
1434                         return WINNING_YES;
1435                 else
1436                         return WINNING_NO;
1437 }
1438
1439 // set the .winning flag for exactly those players with a given field value
1440 void SetWinners(.float field, float value)
1441 {
1442         entity head;
1443         FOR_EACH_PLAYER(head)
1444                 head.winning = (head.field == value);
1445 }
1446
1447 // set the .winning flag for those players with a given field value
1448 void AddWinners(.float field, float value)
1449 {
1450         entity head;
1451         FOR_EACH_PLAYER(head)
1452                 if(head.field == value)
1453                         head.winning = 1;
1454 }
1455
1456 // clear the .winning flags
1457 void ClearWinners(void)
1458 {
1459         entity head;
1460         FOR_EACH_PLAYER(head)
1461                 head.winning = 0;
1462 }
1463
1464 // Onslaught winning condition:
1465 // game terminates if only one team has a working generator (or none)
1466 float WinningCondition_Onslaught()
1467 {
1468         entity head;
1469         local float t1, t2, t3, t4;
1470
1471         WinningConditionHelper(); // set worldstatus
1472
1473         // first check if the game has ended
1474         t1 = t2 = t3 = t4 = 0;
1475         head = find(world, classname, "onslaught_generator");
1476         while (head)
1477         {
1478                 if (head.health > 0)
1479                 {
1480                         if (head.team == COLOR_TEAM1) t1 = 1;
1481                         if (head.team == COLOR_TEAM2) t2 = 1;
1482                         if (head.team == COLOR_TEAM3) t3 = 1;
1483                         if (head.team == COLOR_TEAM4) t4 = 1;
1484                 }
1485                 head = find(head, classname, "onslaught_generator");
1486         }
1487         if (t1 + t2 + t3 + t4 < 2)
1488         {
1489                 // game over, only one team remains (or none)
1490                 ClearWinners();
1491                 if (t1) SetWinners(team, COLOR_TEAM1);
1492                 if (t2) SetWinners(team, COLOR_TEAM2);
1493                 if (t3) SetWinners(team, COLOR_TEAM3);
1494                 if (t4) SetWinners(team, COLOR_TEAM4);
1495                 dprint("Have a winner, ending game.\n");
1496                 return WINNING_YES;
1497         }
1498
1499         // Two or more teams remain
1500         return WINNING_NO;
1501 }
1502
1503 float LMS_NewPlayerLives()
1504 {
1505         float fl;
1506         fl = cvar("fraglimit");
1507         if(fl == 0)
1508                 fl = 999;
1509
1510         // first player has left the game for dying too much? Nobody else can get in.
1511         if(lms_lowest_lives < 1)
1512                 return 0;
1513
1514         if(!cvar("g_lms_join_anytime"))
1515                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1516                         return 0;
1517
1518         return bound(1, lms_lowest_lives, fl);
1519 }
1520
1521 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1522 // they win. Otherwise the defending team wins once the timelimit passes.
1523 void assault_new_round();
1524 float WinningCondition_Assault()
1525 {
1526         local float status;
1527
1528         WinningConditionHelper(); // set worldstatus
1529
1530         status = WINNING_NO;
1531         // as the timelimit has not yet passed just assume the defending team will win
1532         if(assault_attacker_team == COLOR_TEAM1)
1533         {
1534                 SetWinners(team, COLOR_TEAM2);
1535         }
1536         else
1537         {
1538                 SetWinners(team, COLOR_TEAM1);
1539         }
1540
1541         local entity ent;
1542         ent = find(world, classname, "target_assault_roundend");
1543         if(ent)
1544         {
1545                 if(ent.winning) // round end has been triggered by attacking team
1546                 {
1547                         bprint("ASSAULT: round completed...\n");
1548                         SetWinners(team, assault_attacker_team);
1549
1550                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1551
1552                         if(ent.cnt == 1) // this was the second round
1553                         {
1554                                 status = WINNING_YES;
1555                         }
1556                         else
1557                         {
1558                                 local entity oldself;
1559                                 oldself = self;
1560                                 self = ent;
1561                                 assault_new_round();
1562                                 self = oldself;
1563                         }
1564                 }
1565         }
1566
1567         return status;
1568 }
1569
1570 // LMS winning condition: game terminates if and only if there's at most one
1571 // one player who's living lives. Top two scores being equal cancels the time
1572 // limit.
1573 float WinningCondition_LMS()
1574 {
1575         entity head, head2;
1576         float have_player;
1577         float have_players;
1578         float l;
1579
1580         have_player = FALSE;
1581         have_players = FALSE;
1582         l = LMS_NewPlayerLives();
1583
1584         head = find(world, classname, "player");
1585         if(head)
1586                 have_player = TRUE;
1587         head2 = find(head, classname, "player");
1588         if(head2)
1589                 have_players = TRUE;
1590
1591         if(have_player)
1592         {
1593                 // we have at least one player
1594                 if(have_players)
1595                 {
1596                         // two or more active players - continue with the game
1597                 }
1598                 else
1599                 {
1600                         // exactly one player?
1601
1602                         ClearWinners();
1603                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1604
1605                         if(l)
1606                         {
1607                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1608                                 return WINNING_NO;
1609                         }
1610                         else
1611                         {
1612                                 // a winner!
1613                                 // and assign him his first place
1614                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1615                                 return WINNING_YES;
1616                         }
1617                 }
1618         }
1619         else
1620         {
1621                 // nobody is playing at all...
1622                 if(l)
1623                 {
1624                         // wait for players...
1625                 }
1626                 else
1627                 {
1628                         // SNAFU (maybe a draw game?)
1629                         ClearWinners();
1630                         dprint("No players, ending game.\n");
1631                         return WINNING_YES;
1632                 }
1633         }
1634
1635         // When we get here, we have at least two players who are actually LIVING,
1636         // now check if the top two players have equal score.
1637         WinningConditionHelper();
1638
1639         ClearWinners();
1640         if(WinningConditionHelper_winner)
1641                 WinningConditionHelper_winner.winning = TRUE;
1642         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1643                 return WINNING_NEVER;
1644
1645         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1646         return WINNING_NO;
1647 }
1648
1649 void ShuffleMaplist()
1650 {
1651         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1652 }
1653
1654 float leaderfrags;
1655 float WinningCondition_Scores(float limit, float leadlimit)
1656 {
1657         // TODO make everything use THIS winning condition (except LMS)
1658         WinningConditionHelper();
1659
1660         if(teams_matter)
1661         {
1662                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1663                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1664                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1665                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1666         }
1667
1668         ClearWinners();
1669         if(WinningConditionHelper_winner)
1670                 WinningConditionHelper_winner.winning = 1;
1671         if(WinningConditionHelper_winnerteam >= 0)
1672                 SetWinners(team, WinningConditionHelper_winnerteam);
1673
1674         if(WinningConditionHelper_lowerisbetter)
1675         {
1676                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1677                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1678                 limit = -limit;
1679         }
1680
1681         if(WinningConditionHelper_zeroisworst)
1682                 leadlimit = 0; // not supported in this mode
1683
1684         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying) || g_nexball)
1685         // these modes always score in increments of 1, thus this makes sense
1686         {
1687                 if(leaderfrags != WinningConditionHelper_topscore)
1688                 {
1689                         leaderfrags = WinningConditionHelper_topscore;
1690
1691                         if (limit)
1692                         if (leaderfrags == limit - 1)
1693                                 play2all("announcer/robotic/1fragleft.wav");
1694                         else if (leaderfrags == limit - 2)
1695                                 play2all("announcer/robotic/2fragsleft.wav");
1696                         else if (leaderfrags == limit - 3)
1697                                 play2all("announcer/robotic/3fragsleft.wav");
1698                 }
1699         }
1700
1701         return GetWinningCode(
1702                 WinningConditionHelper_topscore &&
1703                 (
1704                         (limit && (WinningConditionHelper_topscore >= limit))
1705                         ||
1706                         (leadlimit && (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit))
1707                 ),
1708                 WinningConditionHelper_equality
1709         );
1710 }
1711
1712 float WinningCondition_Race(float fraglimit)
1713 {
1714         float wc;
1715         entity p;
1716         wc = WinningCondition_Scores(fraglimit, 0);
1717
1718         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1719         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1720         // do NOT support equality when the laps are all raced!
1721         {
1722                 FOR_EACH_PLAYER(p)
1723                         if not(p.race_completed)
1724                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1725                 return WINNING_YES;
1726         }
1727         return wc;
1728 }
1729
1730 void ReadyRestart();
1731 float WinningCondition_QualifyingThenRace(float limit)
1732 {
1733         float wc;
1734         wc = WinningCondition_Scores(limit, 0);
1735
1736         // NEVER initiate overtime
1737         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1738         {
1739                 return WINNING_YES;
1740         }
1741
1742         return wc;
1743 }
1744
1745 float WinningCondition_RanOutOfSpawns()
1746 {
1747         entity head;
1748
1749         if(!have_team_spawns)
1750                 return WINNING_NO;
1751
1752         if(!some_spawn_has_been_used)
1753                 return WINNING_NO;
1754
1755         team1_score = team2_score = team3_score = team4_score = 0;
1756
1757         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1758         {
1759                 if(head.team == COLOR_TEAM1)
1760                         team1_score = 1;
1761                 else if(head.team == COLOR_TEAM2)
1762                         team2_score = 1;
1763                 else if(head.team == COLOR_TEAM3)
1764                         team3_score = 1;
1765                 else if(head.team == COLOR_TEAM4)
1766                         team4_score = 1;
1767         }
1768
1769         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1770         {
1771                 if(head.team == COLOR_TEAM1)
1772                         team1_score = 1;
1773                 else if(head.team == COLOR_TEAM2)
1774                         team2_score = 1;
1775                 else if(head.team == COLOR_TEAM3)
1776                         team3_score = 1;
1777                 else if(head.team == COLOR_TEAM4)
1778                         team4_score = 1;
1779         }
1780
1781         ClearWinners();
1782         if(team1_score + team2_score + team3_score + team4_score == 0)
1783         {
1784                 checkrules_equality = TRUE;
1785                 return WINNING_YES;
1786         }
1787         else if(team1_score + team2_score + team3_score + team4_score == 1)
1788         {
1789                 float t, i;
1790                 if(team1_score) t = COLOR_TEAM1;
1791                 if(team2_score) t = COLOR_TEAM2;
1792                 if(team3_score) t = COLOR_TEAM3;
1793                 if(team4_score) t = COLOR_TEAM4;
1794                 CheckAllowedTeams(world);
1795                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1796                 {
1797                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1798                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1799                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1800                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1801                 }
1802
1803                 AddWinners(team, t);
1804                 return WINNING_YES;
1805         }
1806         else
1807                 return WINNING_NO;
1808 }
1809
1810 /*
1811 ============
1812 CheckRules_World
1813
1814 Exit deathmatch games upon conditions
1815 ============
1816 */
1817 void CheckRules_World()
1818 {
1819         float timelimit;
1820         float fraglimit;
1821         float leadlimit;
1822
1823         VoteThink();
1824         MapVote_Think();
1825
1826         SetDefaultAlpha();
1827
1828         /*
1829         MapVote_Think should now do that part
1830         if (intermission_running)
1831                 if (time >= intermission_exittime + 60)
1832                 {
1833                         if(!DoNextMapOverride())
1834                                 GotoNextMap();
1835                         return;
1836                 }
1837         */
1838
1839         if (gameover)   // someone else quit the game already
1840         {
1841                 if(player_count == 0) // Nobody there? Then let's go to the next map
1842                         MapVote_Start();
1843                         // this will actually check the player count in the next frame
1844                         // again, but this shouldn't hurt
1845                 return;
1846         }
1847
1848         timelimit = cvar("timelimit") * 60;
1849         fraglimit = cvar("fraglimit");
1850         leadlimit = cvar("leadlimit");
1851
1852         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1853         {
1854                 if(timelimit > 0)
1855                         timelimit = 0; // timelimit is not made for warmup
1856                 if(fraglimit > 0)
1857                         fraglimit = 0; // no fraglimit for now
1858                 leadlimit = 0; // no leadlimit for now
1859         }
1860
1861         if(timelimit > 0)
1862         {
1863                 timelimit += game_starttime;
1864         }
1865         else if (timelimit < 0)
1866         {
1867                 // endmatch
1868                 NextLevel();
1869                 return;
1870         }
1871
1872         if(checkrules_suddendeathend)
1873         {
1874                 if(!checkrules_suddendeathwarning)
1875                 {
1876                         checkrules_suddendeathwarning = TRUE;
1877                         if(g_race && !g_race_qualifying)
1878                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1879                         else
1880                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1881                 }
1882         }
1883         else
1884         {
1885                 if (timelimit && time >= timelimit)
1886                 {
1887                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1888                         {
1889                                 float totalplayers;
1890                                 float playerswithlaps;
1891                                 float readyplayers;
1892                                 entity head;
1893                                 totalplayers = playerswithlaps = readyplayers = 0;
1894                                 FOR_EACH_PLAYER(head)
1895                                 {
1896                                         ++totalplayers;
1897                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1898                                                 ++playerswithlaps;
1899                                         if(head.ready)
1900                                                 ++readyplayers;
1901                                 }
1902
1903                                 // at least 2 of the players have completed a lap: start the RACE
1904                                 // otherwise, the players should end the qualifying on their own
1905                                 if(readyplayers || playerswithlaps >= 2)
1906                                 {
1907                                         checkrules_suddendeathend = 0;
1908                                         ReadyRestart(); // go to race
1909                                 }
1910                                 else
1911                                         InitiateOvertime();
1912                         }
1913                         else
1914                                 InitiateOvertime();
1915                 }
1916         }
1917
1918         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1919         {
1920                 NextLevel();
1921                 return;
1922         }
1923
1924         checkrules_status = WinningCondition_RanOutOfSpawns();
1925         if(checkrules_status == WINNING_YES)
1926         {
1927                 bprint("Hey! Someone ran out of spawns!\n");
1928         }
1929         else if(g_race && !g_race_qualifying && timelimit >= 0)
1930         {
1931                 checkrules_status = WinningCondition_Race(fraglimit);
1932         }
1933         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1934         {
1935                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1936         }
1937         else if(g_assault)
1938         {
1939                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1940         }
1941         else if(g_lms)
1942         {
1943                 checkrules_status = WinningCondition_LMS();
1944         }
1945         else if (g_onslaught)
1946         {
1947                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1948         }
1949         else
1950         {
1951                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1952         }
1953
1954         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1955         {
1956                 checkrules_status = WINNING_NEVER;
1957                 InitiateOvertime();
1958         }
1959
1960         if(checkrules_status == WINNING_NEVER)
1961                 // equality cases! Nobody wins if the overtime ends in a draw.
1962                 ClearWinners();
1963
1964         if(checkrules_suddendeathend)
1965                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1966                         checkrules_status = WINNING_YES;
1967
1968         if(checkrules_status == WINNING_YES)
1969                 NextLevel();
1970 };
1971
1972 float mapvote_nextthink;
1973 float mapvote_initialized;
1974 float mapvote_keeptwotime;
1975 float mapvote_timeout;
1976 string mapvote_message;
1977 string mapvote_screenshot_dir;
1978
1979 float mapvote_count;
1980 float mapvote_count_real;
1981 string mapvote_maps[MAPVOTE_COUNT];
1982 float mapvote_maps_suggested[MAPVOTE_COUNT];
1983 string mapvote_suggestions[MAPVOTE_COUNT];
1984 float mapvote_suggestion_ptr;
1985 float mapvote_maxlen;
1986 float mapvote_voters;
1987 float mapvote_votes[MAPVOTE_COUNT];
1988 float mapvote_run;
1989 float mapvote_detail;
1990 float mapvote_abstain;
1991 .float mapvote;
1992
1993 void MapVote_ClearAllVotes()
1994 {
1995         FOR_EACH_CLIENT(other)
1996                 other.mapvote = 0;
1997 }
1998
1999 string MapVote_Suggest(string m)
2000 {
2001         float i;
2002         if(m == "")
2003                 return "That's not how to use this command.";
2004         if(!cvar("g_maplist_votable_suggestions"))
2005                 return "Suggestions are not accepted on this server.";
2006         if(mapvote_initialized)
2007                 return "Can't suggest - voting is already in progress!";
2008         m = MapInfo_FixName(m);
2009         if(!m)
2010                 return "The map you suggested is not available on this server.";
2011         if(!cvar("g_maplist_votable_override_mostrecent"))
2012                 if(Map_IsRecent(m))
2013                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2014
2015         if(!MapInfo_CheckMap(m))
2016                 return "The map you suggested does not support the current game mode.";
2017         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2018                 if(mapvote_suggestions[i] == m)
2019                         return "This map was already suggested.";
2020         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2021         {
2022                 i = floor(random() * mapvote_suggestion_ptr);
2023         }
2024         else
2025         {
2026                 i = mapvote_suggestion_ptr;
2027                 mapvote_suggestion_ptr += 1;
2028         }
2029         if(mapvote_suggestions[i] != "")
2030                 strunzone(mapvote_suggestions[i]);
2031         mapvote_suggestions[i] = strzone(m);
2032         if(cvar("sv_eventlog"))
2033                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2034         return strcat("Suggestion of ", m, " accepted.");
2035 }
2036
2037 void MapVote_AddVotable(string nextMap, float isSuggestion)
2038 {
2039         float j;
2040         if(nextMap == "")
2041                 return;
2042         for(j = 0; j < mapvote_count; ++j)
2043                 if(mapvote_maps[j] == nextMap)
2044                         return;
2045         if(strlen(nextMap) > mapvote_maxlen)
2046                 mapvote_maxlen = strlen(nextMap);
2047         mapvote_maps[mapvote_count] = strzone(nextMap);
2048         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2049         mapvote_count += 1;
2050 }
2051
2052 void MapVote_Spawn();
2053 void MapVote_Init()
2054 {
2055         float i;
2056         float nmax, smax;
2057
2058         MapVote_ClearAllVotes();
2059
2060         mapvote_count = 0;
2061         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2062         mapvote_abstain = cvar("g_maplist_votable_abstain");
2063
2064         if(mapvote_abstain)
2065                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2066         else
2067                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2068         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2069
2070         if(mapvote_suggestion_ptr)
2071                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2072                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2073
2074         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2075                 MapVote_AddVotable(GetNextMap(), FALSE);
2076
2077         if(mapvote_count == 0)
2078         {
2079                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2080                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2081                 if(cvar("g_maplist_shuffle"))
2082                         ShuffleMaplist();
2083                 localcmd("\nmenu_cmd sync\n");
2084                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2085                         MapVote_AddVotable(GetNextMap(), FALSE);
2086         }
2087
2088         mapvote_count_real = mapvote_count;
2089         if(mapvote_abstain)
2090                 MapVote_AddVotable("don't care", 0);
2091
2092         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2093
2094         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2095         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2096         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2097                 mapvote_keeptwotime = 0;
2098         mapvote_message = "Choose a map and press its key!";
2099
2100         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2101         if(mapvote_screenshot_dir == "")
2102                 mapvote_screenshot_dir = "maps";
2103         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2104
2105         MapVote_Spawn();
2106 }
2107
2108 void MapVote_SendPicture(float id)
2109 {
2110         msg_entity = self;
2111         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2112         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2113         WriteByte(MSG_ONE, id);
2114         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2115 }
2116
2117 float GameCommand_MapVote(string cmd)
2118 {
2119         if(!intermission_running)
2120                 return FALSE;
2121
2122         if(cmd == "mv_getpic")
2123         {
2124                 MapVote_SendPicture(stof(argv(1)));
2125                 return TRUE;
2126         }
2127
2128         return FALSE;
2129 }
2130
2131 float MapVote_GetMapMask()
2132 {
2133         float mask, i, power;
2134         mask = 0;
2135         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2136                 if(mapvote_maps[i] != "")
2137                         mask |= power;
2138         return mask;
2139 }
2140
2141 entity mapvote_ent;
2142 float MapVote_SendEntity(entity to, float sf)
2143 {
2144         string mapfile, pakfile;
2145         float i, o;
2146
2147         if(sf & 1)
2148                 sf &~= 2; // if we send 1, we don't need to also send 2
2149
2150         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2151         WriteByte(MSG_ENTITY, sf);
2152
2153         if(sf & 1)
2154         {
2155                 // flag 1 == initialization
2156                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2157                 WriteByte(MSG_ENTITY, mapvote_count);
2158                 WriteByte(MSG_ENTITY, mapvote_abstain);
2159                 WriteByte(MSG_ENTITY, mapvote_detail);
2160                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2161                 if(mapvote_count <= 8)
2162                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2163                 else
2164                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2165                 for(i = 0; i < mapvote_count; ++i)
2166                         if(mapvote_maps[i] != "")
2167                         {
2168                                 if(mapvote_abstain && i == mapvote_count - 1)
2169                                 {
2170                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2171                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2172                                 }
2173                                 else
2174                                 {
2175                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2176                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2177                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2178                                         if(pakfile == "")
2179                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2180                                         if(pakfile == "")
2181                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2182                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2183                                                 pakfile = substring(pakfile, o, 999);
2184                                         WriteString(MSG_ENTITY, pakfile);
2185                                 }
2186                         }
2187         }
2188
2189         if(sf & 2)
2190         {
2191                 // flag 2 == update of mask
2192                 if(mapvote_count <= 8)
2193                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2194                 else
2195                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2196         }
2197
2198         if(sf & 4)
2199         {
2200                 if(mapvote_detail)
2201                         for(i = 0; i < mapvote_count; ++i)
2202                                 if(mapvote_maps[i] != "")
2203                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2204
2205                 WriteByte(MSG_ENTITY, to.mapvote);
2206         }
2207
2208         return TRUE;
2209 }
2210
2211 void MapVote_Spawn()
2212 {
2213         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2214 }
2215
2216 void MapVote_TouchMask()
2217 {
2218         mapvote_ent.SendFlags |= 2;
2219 }
2220
2221 void MapVote_TouchVotes(entity voter)
2222 {
2223         mapvote_ent.SendFlags |= 4;
2224 }
2225
2226 float MapVote_Finished(float mappos)
2227 {
2228         string result;
2229         float i;
2230         float didntvote;
2231
2232         if(cvar("sv_eventlog"))
2233         {
2234                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2235                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2236                 didntvote = mapvote_voters;
2237                 for(i = 0; i < mapvote_count; ++i)
2238                         if(mapvote_maps[i] != "")
2239                         {
2240                                 didntvote -= mapvote_votes[i];
2241                                 if(i != mappos)
2242                                 {
2243                                         result = strcat(result, ":", mapvote_maps[i]);
2244                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2245                                 }
2246                         }
2247                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2248
2249                 GameLogEcho(result);
2250                 if(mapvote_maps_suggested[mappos])
2251                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2252         }
2253
2254         FOR_EACH_REALCLIENT(other)
2255                 FixClientCvars(other);
2256
2257         Map_Goto_SetStr(mapvote_maps[mappos]);
2258         Map_Goto();
2259         alreadychangedlevel = TRUE;
2260         return TRUE;
2261 }
2262 void MapVote_CheckRules_1()
2263 {
2264         float i;
2265
2266         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2267         {
2268                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2269                 mapvote_votes[i] = 0;
2270         }
2271
2272         mapvote_voters = 0;
2273         FOR_EACH_REALCLIENT(other)
2274         {
2275                 ++mapvote_voters;
2276                 if(other.mapvote)
2277                 {
2278                         i = other.mapvote - 1;
2279                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2280                         mapvote_votes[i] = mapvote_votes[i] + 1;
2281                 }
2282         }
2283 }
2284
2285 float MapVote_CheckRules_2()
2286 {
2287         float i;
2288         float firstPlace, secondPlace;
2289         float firstPlaceVotes, secondPlaceVotes;
2290         float mapvote_voters_real;
2291         string result;
2292
2293         if(mapvote_count_real == 1)
2294                 return MapVote_Finished(0);
2295
2296         mapvote_voters_real = mapvote_voters;
2297         if(mapvote_abstain)
2298                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2299
2300         RandomSelection_Init();
2301         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2302                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2303         firstPlace = RandomSelection_chosen_float;
2304         firstPlaceVotes = RandomSelection_best_priority;
2305         //dprint("First place: ", ftos(firstPlace), "\n");
2306         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2307
2308         RandomSelection_Init();
2309         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2310                 if(i != firstPlace)
2311                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2312         secondPlace = RandomSelection_chosen_float;
2313         secondPlaceVotes = RandomSelection_best_priority;
2314         //dprint("Second place: ", ftos(secondPlace), "\n");
2315         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2316
2317         if(firstPlace == -1)
2318                 error("No first place in map vote... WTF?");
2319
2320         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2321                 return MapVote_Finished(firstPlace);
2322
2323         if(mapvote_keeptwotime)
2324                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2325                 {
2326                         float didntvote;
2327                         MapVote_TouchMask();
2328                         mapvote_message = "Now decide between the TOP TWO!";
2329                         mapvote_keeptwotime = 0;
2330                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2331                         result = strcat(result, ":", ftos(firstPlaceVotes));
2332                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2333                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2334                         didntvote = mapvote_voters;
2335                         for(i = 0; i < mapvote_count; ++i)
2336                                 if(mapvote_maps[i] != "")
2337                                 {
2338                                         didntvote -= mapvote_votes[i];
2339                                         if(i != firstPlace)
2340                                                 if(i != secondPlace)
2341                                                 {
2342                                                         result = strcat(result, ":", mapvote_maps[i]);
2343                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2344                                                         if(i < mapvote_count_real)
2345                                                         {
2346                                                                 strunzone(mapvote_maps[i]);
2347                                                                 mapvote_maps[i] = "";
2348                                                         }
2349                                                 }
2350                                 }
2351                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2352                         if(cvar("sv_eventlog"))
2353                                 GameLogEcho(result);
2354                 }
2355
2356         return FALSE;
2357 }
2358 void MapVote_Tick()
2359 {
2360         float keeptwo;
2361         float totalvotes;
2362
2363         keeptwo = mapvote_keeptwotime;
2364         MapVote_CheckRules_1(); // count
2365         if(MapVote_CheckRules_2()) // decide
2366                 return;
2367
2368         totalvotes = 0;
2369         FOR_EACH_REALCLIENT(other)
2370         {
2371                 // hide scoreboard again
2372                 if(other.health != 2342)
2373                 {
2374                         other.health = 2342;
2375                         other.impulse = 0;
2376                         if(clienttype(other) == CLIENTTYPE_REAL)
2377                         {
2378                                 msg_entity = other;
2379                                 WriteByte(MSG_ONE, SVC_FINALE);
2380                                 WriteString(MSG_ONE, "");
2381                         }
2382                 }
2383
2384                 // clear possibly invalid votes
2385                 if(mapvote_maps[other.mapvote - 1] == "")
2386                         other.mapvote = 0;
2387                 // use impulses as new vote
2388                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2389                         if(mapvote_maps[other.impulse - 1] != "")
2390                         {
2391                                 other.mapvote = other.impulse;
2392                                 MapVote_TouchVotes(other);
2393                         }
2394                 other.impulse = 0;
2395
2396                 if(other.mapvote)
2397                         ++totalvotes;
2398         }
2399
2400         MapVote_CheckRules_1(); // just count
2401 }
2402 void MapVote_Start()
2403 {
2404         if(mapvote_run)
2405                 return;
2406
2407         MapInfo_Enumerate();
2408         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2409                 mapvote_run = TRUE;
2410 }
2411 void MapVote_Think()
2412 {
2413         if(!mapvote_run)
2414                 return;
2415
2416         if(alreadychangedlevel)
2417                 return;
2418
2419         if(time < mapvote_nextthink)
2420                 return;
2421         //dprint("tick\n");
2422
2423         mapvote_nextthink = time + 0.5;
2424
2425         if(!mapvote_initialized)
2426         {
2427                 mapvote_initialized = TRUE;
2428                 if(DoNextMapOverride())
2429                         return;
2430                 if(!cvar("g_maplist_votable") || player_count <= 0)
2431                 {
2432                         GotoNextMap();
2433                         return;
2434                 }
2435                 MapVote_Init();
2436         }
2437
2438         MapVote_Tick();
2439 };
2440
2441 string GotoMap(string m)
2442 {
2443         if(!MapInfo_CheckMap(m))
2444                 return "The map you chose is not available on this server.";
2445         cvar_set("nextmap", m);
2446         cvar_set("timelimit", "-1");
2447         if(mapvote_initialized || alreadychangedlevel)
2448         {
2449                 if(DoNextMapOverride())
2450                         return "Map switch initiated.";
2451                 else
2452                         return "Hm... no. For some reason I like THIS map more.";
2453         }
2454         else
2455                 return "Map switch will happen after scoreboard.";
2456 }
2457
2458
2459 void EndFrame()
2460 {
2461         FOR_EACH_REALCLIENT(self)
2462         {
2463                 if(self.classname == "spectator")
2464                 {
2465                         if(self.enemy.typehitsound)
2466                                 play2(self, "misc/typehit.wav");
2467                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2468                                 play2(self, "misc/hit.wav");
2469                 }
2470                 else
2471                 {
2472                         if(self.typehitsound)
2473                                 play2(self, "misc/typehit.wav");
2474                         else if(self.hitsound && self.cvar_cl_hitsound)
2475                                 play2(self, "misc/hit.wav");
2476                 }
2477         }
2478         FOR_EACH_CLIENT(self)
2479         {
2480                 self.hitsound = FALSE;
2481                 self.typehitsound = FALSE;
2482         }
2483 }
2484
2485
2486 /*
2487  * RedirectionThink:
2488  * returns TRUE if redirecting
2489  */
2490 float redirection_timeout;
2491 float redirection_nextthink;
2492 float RedirectionThink()
2493 {
2494         float clients_found;
2495
2496         if(redirection_target == "")
2497                 return FALSE;
2498
2499         if(!redirection_timeout)
2500         {
2501                 cvar_set("sv_public", "-2");
2502                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2503                 if(redirection_target == "self")
2504                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2505                 else
2506                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2507         }
2508
2509         if(time < redirection_nextthink)
2510                 return TRUE;
2511
2512         redirection_nextthink = time + 1;
2513
2514         clients_found = 0;
2515         FOR_EACH_REALCLIENT(self)
2516         {
2517                 print("Redirecting: sending connect command to ", self.netname, "\n");
2518                 if(redirection_target == "self")
2519                         stuffcmd(self, "\ndisconnect; reconnect\n");
2520                 else
2521                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2522                 ++clients_found;
2523         }
2524
2525         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2526
2527         if(time > redirection_timeout || clients_found == 0)
2528                 localcmd("\nwait; wait; wait; quit\n");
2529
2530         return TRUE;
2531 }
2532
2533 void RestoreGame()
2534 {
2535         // Loaded from a save game
2536         // some things then break, so let's work around them...
2537
2538         // Progs DB (capture records)
2539         if(sv_cheats)
2540                 ServerProgsDB = db_create();
2541         else
2542                 ServerProgsDB = db_load("server.db");
2543
2544         // Mapinfo
2545         MapInfo_Shutdown();
2546         MapInfo_Enumerate();
2547         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2548 }
2549
2550 void SV_Shutdown()
2551 {
2552         if(world_initialized > 0)
2553         {
2554                 world_initialized = 0;
2555                 print("Saving persistent data...\n");
2556                 Ban_SaveBans();
2557                 if(!sv_cheats)
2558                         db_save(ServerProgsDB, "server.db");
2559                 if(cvar("developer"))
2560                         db_save(TemporaryDB, "server-temp.db");
2561                 db_close(ServerProgsDB);
2562                 db_close(TemporaryDB);
2563                 print("done!\n");
2564                 // tell the bot system the game is ending now
2565                 bot_endgame();
2566
2567                 MapInfo_Shutdown();
2568         }
2569         else if(world_initialized == 0)
2570         {
2571                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2572         }
2573 }