data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         //reset all the flood variables
  83                         FOR_EACH_CLIENT(plr) {
  84                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
  85                         }
  86                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  87                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  88                         FOR_EACH_REALPLAYER(plr) {
  89                                 plr.lastV_angle = plr.v_angle;
  90                         }
  91                         self.nextthink = time;
  92                 }
  93         }
  94         else if (timeoutStatus == 2) {
  95                 if (remainingTimeoutTime > 0) {
  96                         timeStr = getTimeoutText(0);
  97                         FOR_EACH_REALCLIENT(plr) {
  98                                 if(plr.classname == "player") {
  99                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 100                                 }
 101                         }
 102                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 103                                 play2all("announcer/robotic/prepareforbattle.wav");
 104                         }
 105                         remainingTimeoutTime -= 1;
 106                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 107                 }
 108                 else {
 109                         //unpause the game again
 110                         remainingTimeoutTime = timeoutStatus = 0;
 111                         cvar_set("slowmo", ftos(orig_slowmo));
 112                         //and unlock the fixed view again once there is no timeout active anymore
 113                         FOR_EACH_REALPLAYER(plr) {
 114                                 plr.fixangle = FALSE;
 115                         }
 116                         //get rid of the countdown message
 117                         FOR_EACH_REALCLIENT(plr) {
 118                                 if(plr.classname == "player") {
 119                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 120                                 }
 121                         }
 122                         remove(self);
 123                         return;
 124                 }
 125
 126         }
 127         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 128                 FOR_EACH_REALCLIENT(plr) {
 129                         if(plr.classname == "player") {
 130                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 131                         }
 132                 }
 133                 remove(self);
 134                 return;
 135         }
 136 }
 137
 138 void GotoFirstMap()
 139 {
 140         float n;
 141         if(cvar("_sv_init"))
 142         {
 143                 // cvar_set("_sv_init", "0");
 144                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 145                 // to this "init" map on a dedicated server will cause no permanent
 146                 // harm
 147                 if(cvar("g_maplist_shuffle"))
 148                         ShuffleMaplist();
 149                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 150                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 151
 152                 MapInfo_Enumerate();
 153                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 154
 155                 if(!DoNextMapOverride())
 156                         GotoNextMap();
 157
 158                 return;
 159         }
 160
 161         if(time < 5)
 162         {
 163                 self.nextthink = time;
 164         }
 165         else
 166         {
 167                 self.nextthink = time + 1;
 168                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 169         }
 170 }
 171
 172 void cvar_changes_init()
 173 {
 174         float h;
 175         string k, v, d;
 176         float n, i;
 177
 178         if(cvar_changes)
 179                 strunzone(cvar_changes);
 180         cvar_changes = string_null;
 181
 182         h = buf_create();
 183         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 184         n = buf_getsize(h);
 185
 186         for(i = 0; i < n; ++i)
 187         {
 188                 k = bufstr_get(h, i);
 189
 190 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 191 #define BADCVAR(p) if(k == p) continue
 192                 // internal
 193                 BADPREFIX("csqc_");
 194                 BADPREFIX("cvar_check_");
 195                 BADCVAR("gamecfg");
 196                 BADCVAR("g_configversion");
 197                 BADCVAR("g_maplist_index");
 198                 BADCVAR("halflifebsp");
 199
 200                 // client
 201                 BADPREFIX("cl_");
 202                 BADPREFIX("con_");
 203                 BADPREFIX("g_campaign");
 204                 BADPREFIX("gl_");
 205                 BADPREFIX("joy");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("userbind");
 212                 BADPREFIX("v_");
 213                 BADPREFIX("vid_");
 214                 BADPREFIX("crosshair");
 215                 BADCVAR("mod_q3bsp_lightmapmergepower");
 216                 BADCVAR("mod_q3bsp_nolightmaps");
 217
 218                 // private
 219                 BADPREFIX("g_ban_");
 220                 BADPREFIX("g_chat_flood_");
 221                 BADPREFIX("g_voice_flood_");
 222                 BADPREFIX("rcon_");
 223                 BADPREFIX("settemp_");
 224                 BADPREFIX("sv_allowdownloads_");
 225                 BADPREFIX("sv_autodemo");
 226                 BADPREFIX("sv_curl_");
 227                 BADPREFIX("sv_eventlog");
 228                 BADPREFIX("sv_logscores_");
 229                 BADPREFIX("sv_master");
 230                 BADCVAR("g_banned_list");
 231                 BADCVAR("log_dest_udp");
 232                 BADCVAR("log_file");
 233                 BADCVAR("net_address");
 234                 BADCVAR("port");
 235                 BADCVAR("savedgamecfg");
 236                 BADCVAR("sv_heartbeatperoid");
 237                 BADCVAR("sv_vote_master_password");
 238                 BADCVAR("sys_colortranslation");
 239                 BADCVAR("sys_specialcharactertranslation");
 240                 BADCVAR("timestamps");
 241
 242                 // mapinfo
 243                 BADCVAR("timelimit");
 244                 BADCVAR("fraglimit");
 245                 BADCVAR("g_arena");
 246                 BADCVAR("g_ca");
 247                 BADCVAR("g_assault");
 248                 BADCVAR("g_ctf");
 249                 BADCVAR("g_dm");
 250                 BADCVAR("g_domination");
 251                 BADCVAR("g_keyhunt");
 252                 BADCVAR("g_keyhunt_teams");
 253                 BADCVAR("g_onslaught");
 254                 BADCVAR("g_race");
 255                 BADCVAR("g_cts");
 256                 BADCVAR("g_runematch");
 257                 BADCVAR("g_tdm");
 258                 BADCVAR("g_nexball");
 259                 BADCVAR("teamplay");
 260
 261                 // long
 262                 BADCVAR("hostname");
 263                 BADCVAR("g_maplist");
 264                 BADCVAR("g_maplist_mostrecent");
 265                 BADCVAR("sv_motd");
 266 #undef BADPREFIX
 267 #undef BADCVAR
 268
 269                 v = cvar_string(k);
 270                 d = cvar_defstring(k);
 271                 if(v != d)
 272                 {
 273                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 274                         if(strlen(cvar_changes) > 16384)
 275                         {
 276                                 cvar_changes = "// too many settings have been changed to show them here\n";
 277                                 break;
 278                         }
 279                 }
 280         }
 281         buf_del(h);
 282         if(cvar_changes == "")
 283                 cvar_changes = "// this server runs at default settings\n";
 284         else
 285                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 286         cvar_changes = strzone(cvar_changes);
 287 }
 288
 289 void detect_maptype()
 290 {
 291 #if 0
 292         vector o, v;
 293         float i;
 294
 295         for(;;)
 296         {
 297                 o = world.mins;
 298                 o_x += random() * (world.maxs_x - world.mins_x);
 299                 o_y += random() * (world.maxs_y - world.mins_y);
 300                 o_z += random() * (world.maxs_z - world.mins_z);
 301
 302                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 303                 if(trace_fraction == 1)
 304                         continue;
 305
 306                 v = trace_endpos;
 307
 308                 for(i = 0; i < 64; i += 4)
 309                 {
 310                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 311         if(trace_fraction == 1)
 312                 continue;
 313                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 314                 }
 315
 316                 break;
 317         }
 318 #endif
 319 }
 320
 321 entity randomseed;
 322 float RandomSeed_Send(entity to, float sf)
 323 {
 324         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 325         WriteShort(MSG_ENTITY, self.cnt);
 326         return TRUE;
 327 }
 328 void RandomSeed_Think()
 329 {
 330         self.cnt = bound(0, floor(random() * 65536), 65535);
 331         self.nextthink = time + 5;
 332
 333         self.SendFlags |= 1;
 334 }
 335 void RandomSeed_Spawn()
 336 {
 337         randomseed = spawn();
 338         randomseed.think = RandomSeed_Think;
 339         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 340
 341         entity oldself;
 342         oldself = self;
 343         self = randomseed;
 344         self.think(); // sets random seed and nextthink
 345         self = oldself;
 346 }
 347
 348 void spawnfunc___init_dedicated_server(void)
 349 {
 350         // handler for _init/_init map (only for dedicated server initialization)
 351
 352         world_initialized = -1; // don't complain
 353         cvar = cvar_builtin;
 354         cvar_string = cvar_string_builtin;
 355         cvar_set = cvar_set_builtin;
 356         dprint_load(); // load dprint status from cvar
 357
 358         remove = remove_unsafely;
 359
 360         entity e;
 361         e = spawn();
 362         e.think = GotoFirstMap;
 363         e.nextthink = time; // this is usually 1 at this point
 364
 365         e = spawn();
 366         e.classname = "info_player_deathmatch"; // safeguard against player joining
 367
 368         self.classname = "worldspawn"; // safeguard against various stuff ;)
 369
 370         MapInfo_Enumerate();
 371         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 372 }
 373
 374 void Map_MarkAsRecent(string m);
 375 float world_already_spawned;
 376 void RegisterWeapons();
 377 void Nagger_Init();
 378 void ClientInit_Spawn();
 379 void WeaponStats_Init();
 380 void WeaponStats_Shutdown();
 381 void spawnfunc_worldspawn (void)
 382 {
 383         float fd, l, i, j, n;
 384         string s, col;
 385
 386         cvar = cvar_builtin;
 387         cvar_string = cvar_string_builtin;
 388         cvar_set = cvar_set_builtin;
 389         dprint_load(); // load dprint status from cvar
 390
 391         if(world_already_spawned)
 392                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 393         world_already_spawned = TRUE;
 394
 395         remove = remove_safely; // during spawning, watch what you remove!
 396
 397         check_unacceptable_compiler_bugs();
 398
 399         if(cvar_string("cvar_check_default") != "bypass")
 400         {
 401                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 402                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 403
 404                 if(cvar_string("cvar_check_balance") != CVAR_CHECK_BALANCE)
 405                         error("Config file mismatch! Please update balance*.cfg to match the QuakeC code, and restart the engine!");
 406         }
 407
 408         compressShortVector_init();
 409
 410         local entity head;
 411         head = nextent(world);
 412         maxclients = 0;
 413         while(head)
 414         {
 415                 ++maxclients;
 416                 head = nextent(head);
 417         }
 418
 419         // needs to be done so early as they would still spawn
 420         RegisterWeapons();
 421
 422         if(sv_cheats)
 423                 ServerProgsDB = db_create();
 424         else
 425                 ServerProgsDB = db_load("server.db");
 426
 427         TemporaryDB = db_create();
 428
 429         /*
 430         TODO sound pack system
 431         // initialize sound pack system
 432         soundpack = cvar_string("g_soundpack");
 433         if(soundpack != "")
 434                 soundpack = strcat(soundpack, "/");
 435         soundpack = strzone(soundpack);
 436         */
 437
 438         // 0 normal
 439         lightstyle(0, "m");
 440
 441         // 1 FLICKER (first variety)
 442         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 443
 444         // 2 SLOW STRONG PULSE
 445         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 446
 447         // 3 CANDLE (first variety)
 448         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 449
 450         // 4 FAST STROBE
 451         lightstyle(4, "mamamamamama");
 452
 453         // 5 GENTLE PULSE 1
 454         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 455
 456         // 6 FLICKER (second variety)
 457         lightstyle(6, "nmonqnmomnmomomno");
 458
 459         // 7 CANDLE (second variety)
 460         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 461
 462         // 8 CANDLE (third variety)
 463         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 464
 465         // 9 SLOW STROBE (fourth variety)
 466         lightstyle(9, "aaaaaaaazzzzzzzz");
 467
 468         // 10 FLUORESCENT FLICKER
 469         lightstyle(10, "mmamammmmammamamaaamammma");
 470
 471         // 11 SLOW PULSE NOT FADE TO BLACK
 472         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 473
 474         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 475
 476         // 63 testing
 477         lightstyle(63, "a");
 478
 479         if(cvar("g_campaign"))
 480                 CampaignPreInit();
 481
 482         Map_MarkAsRecent(mapname);
 483
 484         precache_model ("null"); // we need this one before InitGameplayMode
 485         InitGameplayMode();
 486         readlevelcvars();
 487         GrappleHookInit();
 488
 489         player_count = 0;
 490         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 491         if(bot_waypoints_for_items == 1)
 492                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 493                         bot_waypoints_for_items = 0;
 494
 495         // for setting by mapinfo
 496         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 497         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 498
 499         precache();
 500
 501         WaypointSprite_Init();
 502
 503         //if (g_domination)
 504         //      dom_init();
 505
 506         GameLogInit(); // prepare everything
 507         if(cvar("sv_eventlog"))
 508         {
 509                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 510                 s = strcat(s, ftos(random()));
 511                 matchid = strzone(s);
 512
 513                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 514                 s = ":gameinfo:mutators:LIST";
 515                 if(cvar("g_grappling_hook"))
 516                         s = strcat(s, ":grappling_hook");
 517                 if(!cvar("g_use_ammunition"))
 518                         s = strcat(s, ":no_use_ammunition");
 519                 if(!cvar("g_pickup_items"))
 520                         s = strcat(s, ":no_pickup_items");
 521                 if(cvar("g_instagib"))
 522                         s = strcat(s, ":instagib");
 523                 if(cvar_string("g_weaponarena") != "0")
 524                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 525                 if(cvar("g_nixnex"))
 526                         s = strcat(s, ":nixnex");
 527                 if(cvar("g_vampire"))
 528                         s = strcat(s, ":vampire");
 529                 if(cvar("g_laserguided_missile"))
 530                         s = strcat(s, ":laserguided_missile");
 531                 if(cvar("g_norecoil"))
 532                         s = strcat(s, ":norecoil");
 533                 if(cvar("g_midair"))
 534                         s = strcat(s, ":midair");
 535                 if(cvar("g_minstagib"))
 536                         s = strcat(s, ":minstagib");
 537                 GameLogEcho(s);
 538                 GameLogEcho(":gameinfo:end");
 539         }
 540         else
 541                 matchid = strzone(ftos(random()));
 542
 543         cvar_set("nextmap", "");
 544
 545         SetDefaultAlpha();
 546
 547         if(cvar("g_campaign"))
 548                 CampaignPostInit();
 549
 550         fteqcc_testbugs();
 551
 552         Ban_LoadBans();
 553
 554         MapInfo_Enumerate();
 555         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 556
 557         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 558         {
 559                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 560                 if(fd != -1)
 561                 {
 562                         while((s = fgets(fd)))
 563                         {
 564                                 l = tokenize_console(s);
 565                                 if(l < 2)
 566                                         continue;
 567                                 if(argv(0) == "cd")
 568                                 {
 569                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 570                                         print("  cdtrack ", argv(2), "\n");
 571                                 }
 572                                 else if(argv(0) == "fog")
 573                                 {
 574                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 575                                         print("  \"fog\" \"", s, "\"\n");
 576                                 }
 577                                 else if(argv(0) == "set")
 578                                 {
 579                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 580                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 581                                 }
 582                                 else if(argv(0) != "//")
 583                                 {
 584                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 585                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 586                                 }
 587                         }
 588                         fclose(fd);
 589                 }
 590         }
 591
 592         WeaponStats_Init();
 593
 594         addstat(STAT_WEAPONS, AS_INT, weapons);
 595         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 596         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 597         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 598         Nagger_Init();
 599
 600         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 601         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 602         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 603         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 604         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 605         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 606         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 607         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 608         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 609
 610         next_pingtime = time + 5;
 611         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 612
 613         detect_maptype();
 614
 615         lsmaps_reply = "^7Maps available: ";
 616         for(i = 0, j = 0; i < MapInfo_count; ++i)
 617         {
 618                 if(MapInfo_Get_ByID(i))
 619                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 620                         {
 621                                 if(mod(i, 2))
 622                                         col = "^2";
 623                                 else
 624                                         col = "^3";
 625                                 ++j;
 626                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 627                         }
 628         }
 629         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 630
 631         maplist_reply = "^7Maps in list: ";
 632         n = tokenize_console(cvar_string("g_maplist"));
 633         for(i = 0, j = 0; i < n; ++i)
 634         {
 635                 if(MapInfo_CheckMap(argv(i)))
 636                 {
 637                         if(mod(j, 2))
 638                                 col = "^2";
 639                         else
 640                                 col = "^3";
 641                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 642                         ++j;
 643                 }
 644         }
 645         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 646         MapInfo_ClearTemps();
 647
 648         records_reply = strzone(getrecords());
 649
 650         ClientInit_Spawn();
 651         RandomSeed_Spawn();
 652
 653         localcmd("\n_sv_hook_gamestart ", GetGametype(), ";");
 654
 655         world_initialized = 1;
 656 }
 657
 658 void spawnfunc_light (void)
 659 {
 660         //makestatic (self); // Who the f___ did that?
 661         remove(self);
 662 }
 663
 664 float TryFile( string pFilename )
 665 {
 666         local float lHandle;
 667         dprint("TryFile(\"", pFilename, "\")\n");
 668         lHandle = fopen( pFilename, FILE_READ );
 669         if( lHandle != -1 ) {
 670                 fclose( lHandle );
 671                 return TRUE;
 672         } else {
 673                 return FALSE;
 674         }
 675 };
 676
 677 string GetGametype()
 678 {
 679         return GametypeNameFromType(game);
 680 }
 681
 682 string getmapname_stored;
 683 string GetMapname()
 684 {
 685         return mapname;
 686 }
 687
 688 float Map_Count, Map_Current;
 689 string Map_Current_Name;
 690
 691 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 692 float GetMaplistPosition()
 693 {
 694         float pos, idx;
 695         string map;
 696
 697         map = GetMapname();
 698         idx = cvar("g_maplist_index");
 699
 700         if(idx >= 0)
 701                 if(idx < Map_Count)
 702                         if(map == argv(idx))
 703                                 return idx;
 704
 705         for(pos = 0; pos < Map_Count; ++pos)
 706                 if(map == argv(pos))
 707                         return pos;
 708
 709         // resume normal maplist rotation if current map is not in g_maplist
 710         return idx;
 711 }
 712
 713 float MapHasRightSize(string map)
 714 {
 715         float fh;
 716         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 717         if(cvar("g_maplist_check_waypoints"))
 718         {
 719                 dprint("checkwp "); dprint(map);
 720                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 721                 if(fh < 0)
 722                 {
 723                         dprint(": no waypoints\n");
 724                         return FALSE;
 725                 }
 726                 dprint(": has waypoints\n");
 727                 fclose(fh);
 728         }
 729
 730         // open map size restriction file
 731         dprint("opensize "); dprint(map);
 732         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 733         if(fh >= 0)
 734         {
 735                 float mapmin, mapmax;
 736                 dprint(": ok, ");
 737                 mapmin = stof(fgets(fh));
 738                 mapmax = stof(fgets(fh));
 739                 fclose(fh);
 740                 if(player_count < mapmin)
 741                 {
 742                         dprint("not enough\n");
 743                         return FALSE;
 744                 }
 745                 if(player_count > mapmax)
 746                 {
 747                         dprint("too many\n");
 748                         return FALSE;
 749                 }
 750                 dprint("right size\n");
 751                 return TRUE;
 752         }
 753         dprint(": not found\n");
 754         return TRUE;
 755 }
 756
 757 string Map_Filename(float position)
 758 {
 759         return strcat("maps/", argv(position), ".bsp");
 760 }
 761
 762 string strwords(string s, float w)
 763 {
 764         float endpos;
 765         for(endpos = 0; w && endpos >= 0; --w)
 766                 endpos = strstrofs(s, " ", endpos + 1);
 767         if(endpos < 0)
 768                 return s;
 769         else
 770                 return substring(s, 0, endpos);
 771 }
 772
 773 float strhasword(string s, string w)
 774 {
 775         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 776 }
 777
 778 void Map_MarkAsRecent(string m)
 779 {
 780         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 781 }
 782
 783 float Map_IsRecent(string m)
 784 {
 785         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 786 }
 787
 788 float Map_Check(float position, float pass)
 789 {
 790         string filename;
 791         string map_next;
 792         map_next = argv(position);
 793         if(pass <= 1)
 794         {
 795                 if(Map_IsRecent(map_next))
 796                         return 0;
 797         }
 798         filename = Map_Filename(position);
 799         if(MapInfo_CheckMap(map_next))
 800         {
 801                 if(pass == 2)
 802                         return 1;
 803                 if(MapHasRightSize(map_next))
 804                         return 1;
 805                 return 0;
 806         }
 807         else
 808                 dprint( "Couldn't select '", filename, "'..\n" );
 809
 810         return 0;
 811 }
 812
 813 void Map_Goto_SetStr(string nextmapname)
 814 {
 815         if(getmapname_stored != "")
 816                 strunzone(getmapname_stored);
 817         if(nextmapname == "")
 818                 getmapname_stored = "";
 819         else
 820                 getmapname_stored = strzone(nextmapname);
 821 }
 822
 823 void Map_Goto_SetFloat(float position)
 824 {
 825         cvar_set("g_maplist_index", ftos(position));
 826         Map_Goto_SetStr(argv(position));
 827 }
 828
 829 void GameResetCfg()
 830 {
 831         // settings persist, except...
 832         localcmd("\nsettemp_restore\n");
 833 };
 834
 835 void Map_Goto()
 836 {
 837         GameResetCfg();
 838         MapInfo_LoadMap(getmapname_stored);
 839 }
 840
 841 // return codes of map selectors:
 842 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 843 //   -2 = permanent failure
 844 float() MaplistMethod_Iterate = // usual method
 845 {
 846         float pass, i;
 847
 848         for(pass = 1; pass <= 2; ++pass)
 849         {
 850                 for(i = 1; i < Map_Count; ++i)
 851                 {
 852                         float mapindex;
 853                         mapindex = mod(i + Map_Current, Map_Count);
 854                         if(Map_Check(mapindex, pass))
 855                                 return mapindex;
 856                 }
 857         }
 858         return -1;
 859 }
 860
 861 float() MaplistMethod_Repeat = // fallback method
 862 {
 863         if(Map_Check(Map_Current, 2))
 864                 return Map_Current;
 865         return -2;
 866 }
 867
 868 float() MaplistMethod_Random = // random map selection
 869 {
 870         float i, imax;
 871
 872         imax = 42;
 873
 874         for(i = 0; i <= imax; ++i)
 875         {
 876                 float mapindex;
 877                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 878                 if(Map_Check(mapindex, 1))
 879                         return mapindex;
 880         }
 881         return -1;
 882 }
 883
 884 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 885 // the exponent sets a bias on the map selection:
 886 // the higher the exponent, the less likely "shortly repeated" same maps are
 887 {
 888         float i, j, imax, insertpos;
 889
 890         imax = 42;
 891
 892         for(i = 0; i <= imax; ++i)
 893         {
 894                 string newlist;
 895
 896                 // now reinsert this at another position
 897                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 898                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 899                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 900                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 901
 902                 // insert the current map there
 903                 newlist = "";
 904                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 905                         newlist = strcat(newlist, " ", argv(j));
 906                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 907                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 908                         newlist = strcat(newlist, " ", argv(j));
 909                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 910                 cvar_set("g_maplist", newlist);
 911                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 912
 913                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 914                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 915                 if(Map_Check(Map_Current, 1))
 916                         return Map_Current;
 917         }
 918         return -1;
 919 }
 920
 921 void Maplist_Init()
 922 {
 923         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 924         if(Map_Count == 0)
 925         {
 926                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 927                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
 928                 if(cvar("g_maplist_shuffle"))
 929                         ShuffleMaplist();
 930                 localcmd("\nmenu_cmd sync\n");
 931                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 932         }
 933         if(Map_Count == 0)
 934                 error("empty maplist, cannot select a new map");
 935         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 936
 937         if(Map_Current_Name)
 938                 strunzone(Map_Current_Name);
 939         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 940         // this may or may not be correct, but who cares, in the worst case a map
 941         // isn't chosen in the first pass that should have been
 942 }
 943
 944 string GetNextMap()
 945 {
 946         float nextMap;
 947
 948         Maplist_Init();
 949         nextMap = -1;
 950
 951         if(nextMap == -1)
 952                 if(cvar("g_maplist_shuffle") > 0)
 953                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 954
 955         if(nextMap == -1)
 956                 if(cvar("g_maplist_selectrandom"))
 957                         nextMap = MaplistMethod_Random();
 958
 959         if(nextMap == -1)
 960                 nextMap = MaplistMethod_Iterate();
 961
 962         if(nextMap == -1)
 963                 nextMap = MaplistMethod_Repeat();
 964
 965         if(nextMap >= 0)
 966         {
 967                 Map_Goto_SetFloat(nextMap);
 968                 return getmapname_stored;
 969         }
 970
 971         return "";
 972 };
 973
 974 float DoNextMapOverride()
 975 {
 976         if(cvar("g_campaign"))
 977         {
 978                 CampaignPostIntermission();
 979                 alreadychangedlevel = TRUE;
 980                 return TRUE;
 981         }
 982         if(cvar("quit_when_empty"))
 983         {
 984                 if(player_count <= currentbots)
 985                 {
 986                         localcmd("quit\n");
 987                         alreadychangedlevel = TRUE;
 988                         return TRUE;
 989                 }
 990         }
 991         if(cvar_string("quit_and_redirect") != "")
 992         {
 993                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 994                 alreadychangedlevel = TRUE;
 995                 return TRUE;
 996         }
 997         if (cvar("samelevel")) // if samelevel is set, stay on same level
 998         {
 999                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1000                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1001                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1002                 localcmd("restart\n");
1003                 //changelevel (mapname);
1004                 alreadychangedlevel = TRUE;
1005                 return TRUE;
1006         }
1007         if(cvar_string("nextmap") != "")
1008                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1009                 {
1010                         Map_Goto_SetStr(cvar_string("nextmap"));
1011                         Map_Goto();
1012                         alreadychangedlevel = TRUE;
1013                         return TRUE;
1014                 }
1015         if(cvar("lastlevel"))
1016         {
1017                 GameResetCfg();
1018                 localcmd("set lastlevel 0\ntogglemenu\n");
1019                 alreadychangedlevel = TRUE;
1020                 return TRUE;
1021         }
1022         return FALSE;
1023 };
1024
1025 void GotoNextMap()
1026 {
1027         //local string nextmap;
1028         //local float n, nummaps;
1029         //local string s;
1030         if (alreadychangedlevel)
1031                 return;
1032         alreadychangedlevel = TRUE;
1033
1034         {
1035                 string nextMap;
1036                 float allowReset;
1037
1038                 for(allowReset = 1; allowReset >= 0; --allowReset)
1039                 {
1040                         nextMap = GetNextMap();
1041                         if(nextMap != "")
1042                                 break;
1043
1044                         if(allowReset)
1045                         {
1046                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1047                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1048                                 if(cvar("g_maplist_shuffle"))
1049                                         ShuffleMaplist();
1050                                 localcmd("\nmenu_cmd sync\n");
1051                         }
1052                         else
1053                         {
1054                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1055                         }
1056                 }
1057                 Map_Goto();
1058         }
1059 };
1060
1061
1062 /*
1063 ============
1064 IntermissionThink
1065
1066 When the player presses attack or jump, change to the next level
1067 ============
1068 */
1069 .float autoscreenshot;
1070 void() MapVote_Start;
1071 void() MapVote_Think;
1072 float mapvote_initialized;
1073 void IntermissionThink()
1074 {
1075         FixIntermissionClient(self);
1076
1077         if(cvar("sv_autoscreenshot"))
1078         if(self.autoscreenshot > 0)
1079         if(time > self.autoscreenshot)
1080         {
1081                 self.autoscreenshot = -1;
1082                 if(clienttype(self) == CLIENTTYPE_REAL)
1083                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1084                 return;
1085         }
1086
1087         if (time < intermission_exittime)
1088                 return;
1089
1090         if(!mapvote_initialized)
1091                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1092                         return;
1093
1094         MapVote_Start();
1095 };
1096
1097 /*
1098 ============
1099 FindIntermission
1100
1101 Returns the entity to view from
1102 ============
1103 */
1104 /*
1105 entity FindIntermission()
1106 {
1107         local   entity spot;
1108         local   float cyc;
1109
1110 // look for info_intermission first
1111         spot = find (world, classname, "info_intermission");
1112         if (spot)
1113         {       // pick a random one
1114                 cyc = random() * 4;
1115                 while (cyc > 1)
1116                 {
1117                         spot = find (spot, classname, "info_intermission");
1118                         if (!spot)
1119                                 spot = find (spot, classname, "info_intermission");
1120                         cyc = cyc - 1;
1121                 }
1122                 return spot;
1123         }
1124
1125 // then look for the start position
1126         spot = find (world, classname, "info_player_start");
1127         if (spot)
1128                 return spot;
1129
1130 // testinfo_player_start is only found in regioned levels
1131         spot = find (world, classname, "testplayerstart");
1132         if (spot)
1133                 return spot;
1134
1135 // then look for the start position
1136         spot = find (world, classname, "info_player_deathmatch");
1137         if (spot)
1138                 return spot;
1139
1140         //objerror ("FindIntermission: no spot");
1141         return world;
1142 };
1143 */
1144
1145 /*
1146 ===============================================================================
1147
1148 RULES
1149
1150 ===============================================================================
1151 */
1152
1153 void DumpStats(float final)
1154 {
1155         local float file;
1156         local string s;
1157         local float to_console;
1158         local float to_eventlog;
1159         local float to_file;
1160         local float i;
1161
1162         to_console = cvar("sv_logscores_console");
1163         to_eventlog = cvar("sv_eventlog");
1164         to_file = cvar("sv_logscores_file");
1165
1166         if(!final)
1167         {
1168                 to_console = TRUE; // always print printstats replies
1169                 to_eventlog = FALSE; // but never print them to the event log
1170         }
1171
1172         if(to_eventlog)
1173                 if(cvar("sv_eventlog_console"))
1174                         to_console = FALSE; // otherwise we get the output twice
1175
1176         if(final)
1177                 s = ":scores:";
1178         else
1179                 s = ":status:";
1180         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1181
1182         if(to_console)
1183                 print(s, "\n");
1184         if(to_eventlog)
1185                 GameLogEcho(s);
1186         if(to_file)
1187         {
1188                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1189                 if(file == -1)
1190                         to_file = FALSE;
1191                 else
1192                         fputs(file, strcat(s, "\n"));
1193         }
1194
1195         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1196         if(to_console)
1197                 print(s, "\n");
1198         if(to_eventlog)
1199                 GameLogEcho(s);
1200         if(to_file)
1201                 fputs(file, strcat(s, "\n"));
1202
1203         FOR_EACH_CLIENT(other)
1204         {
1205                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1206                 {
1207                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1208                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1209                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1210                                 s = strcat(s, ftos(other.team), ":");
1211                         else
1212                                 s = strcat(s, "spectator:");
1213
1214                         if(to_console)
1215                                 print(s, other.netname, "\n");
1216                         if(to_eventlog)
1217                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1218                         if(to_file)
1219                                 fputs(file, strcat(s, other.netname, "\n"));
1220                 }
1221         }
1222
1223         if(teams_matter)
1224         {
1225                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1226                 if(to_console)
1227                         print(s, "\n");
1228                 if(to_eventlog)
1229                         GameLogEcho(s);
1230                 if(to_file)
1231                         fputs(file, strcat(s, "\n"));
1232
1233                 for(i = 1; i < 16; ++i)
1234                 {
1235                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1236                         s = strcat(s, ":", ftos(i));
1237                         if(to_console)
1238                                 print(s, "\n");
1239                         if(to_eventlog)
1240                                 GameLogEcho(s);
1241                         if(to_file)
1242                                 fputs(file, strcat(s, "\n"));
1243                 }
1244         }
1245
1246         if(to_console)
1247                 print(":end\n");
1248         if(to_eventlog)
1249                 GameLogEcho(":end");
1250         if(to_file)
1251         {
1252                 fputs(file, ":end\n");
1253                 fclose(file);
1254         }
1255 }
1256
1257 void FixIntermissionClient(entity e)
1258 {
1259         string s;
1260         if(!e.autoscreenshot) // initial call
1261         {
1262                 e.angles = e.v_angle;
1263                 e.angles_x = -e.angles_x;
1264                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1265                 e.health = -2342;
1266                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1267                 e.solid = SOLID_NOT;
1268                 e.movetype = MOVETYPE_NONE;
1269                 e.takedamage = DAMAGE_NO;
1270                 if(e.weaponentity)
1271                 {
1272                         e.weaponentity.effects = EF_NODRAW;
1273                         if (e.weaponentity.weaponentity)
1274                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1275                 }
1276                 if(clienttype(e) == CLIENTTYPE_REAL)
1277                 {
1278                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1279                         s = cvar_string("sv_intermission_cdtrack");
1280                         if(s != "")
1281                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1282                         msg_entity = e;
1283                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1284                 }
1285         }
1286
1287         //e.velocity = '0 0 0';
1288         //e.fixangle = TRUE;
1289
1290         // TODO halt weapon animation
1291 }
1292
1293
1294 /*
1295 go to the next level for deathmatch
1296 only called if a time or frag limit has expired
1297 */
1298 void NextLevel()
1299 {
1300         float i;
1301
1302         gameover = TRUE;
1303
1304         intermission_running = 1;
1305
1306 // enforce a wait time before allowing changelevel
1307         if(player_count > 0)
1308                 intermission_exittime = time + cvar("sv_mapchange_delay");
1309         else
1310                 intermission_exittime = -1;
1311
1312         /*
1313         WriteByte (MSG_ALL, SVC_CDTRACK);
1314         WriteByte (MSG_ALL, 3);
1315         WriteByte (MSG_ALL, 3);
1316         // done in FixIntermission
1317         */
1318
1319         //pos = FindIntermission ();
1320
1321         VoteReset();
1322
1323         DumpStats(TRUE);
1324
1325         if(cvar("sv_eventlog"))
1326                 GameLogEcho(":gameover");
1327
1328         GameLogClose();
1329
1330 // TO DO
1331
1332 // save the stats to a text file on the client
1333 // stuffcmd(other, log_stats "stats/file_name");
1334 // bprint stats
1335 // stuffcmd(other, log_stats "");
1336 // use a filename similar to the demo name
1337         // string file_name;
1338         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1339
1340 // write a stats parser for the menu
1341
1342         if(cvar("sv_accuracy_data_send")) {
1343                 string stats_to_send;
1344
1345                 FOR_EACH_CLIENT(other) {  // make the string to send
1346                         FixIntermissionClient(other);
1347
1348                         if(other.cvar_cl_accuracy_data_share) {
1349                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1350
1351                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1352                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1353
1354                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1355
1356                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1357                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1358
1359                                 stats_to_send = strcat(stats_to_send, "\n");
1360                         }
1361                 }
1362
1363                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1364                         Score_NicePrint(other);  // print the score
1365
1366                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1367                                 bprint(stats_to_send);
1368                 }
1369         } else { // ye olde message
1370                 FOR_EACH_PLAYER(other) {
1371                         FixIntermissionClient(other);
1372
1373                         if(other.winning)
1374                                 bprint(other.netname, " ^7wins.\n");
1375                 }
1376         }
1377
1378         if(cvar("g_campaign"))
1379                 CampaignPreIntermission();
1380
1381         localcmd("\nsv_hook_gameend;");
1382 }
1383
1384 /*
1385 ============
1386 CheckRules_Player
1387
1388 Exit deathmatch games upon conditions
1389 ============
1390 */
1391 void CheckRules_Player()
1392 {
1393         if (gameover)   // someone else quit the game already
1394                 return;
1395
1396         if(self.deadflag == DEAD_NO)
1397                 self.play_time += frametime;
1398
1399         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1400         //   (div0: and that in CheckRules_World please)
1401 };
1402
1403 float checkrules_equality;
1404 float checkrules_suddendeathwarning;
1405 float checkrules_suddendeathend;
1406 float checkrules_overtimesadded; //how many overtimes have been already added
1407
1408 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1409 float WINNING_YES = 1; // winner found
1410 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1411 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1412
1413 float InitiateSuddenDeath()
1414 {
1415         // Check first whether normal overtimes could be added before initiating suddendeath mode
1416         // - for this timelimit_overtime needs to be >0 of course
1417         // - also check the winning condition calculated in the previous frame and only add normal overtime
1418         //   again, if at the point at which timelimit would be extended again, still no winner was found
1419         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1420         {
1421                 return 1; // need to call InitiateOvertime later
1422         }
1423         else
1424         {
1425                 if(!checkrules_suddendeathend)
1426                 {
1427                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1428                         if(g_race && !g_race_qualifying)
1429                                 race_StartCompleting();
1430                 }
1431                 return 0;
1432         }
1433 }
1434
1435 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1436 {
1437         ++checkrules_overtimesadded;
1438         //add one more overtime by simply extending the timelimit
1439         float tl;
1440         tl = cvar("timelimit");
1441         tl += cvar("timelimit_overtime");
1442         cvar_set("timelimit", ftos(tl));
1443         string minutesPlural;
1444         if (cvar("timelimit_overtime") == 1)
1445                 minutesPlural = " ^3minute";
1446         else
1447                 minutesPlural = " ^3minutes";
1448
1449         bcenterprint(
1450                 strcat(
1451                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1452                         ftos(cvar("timelimit_overtime")),
1453                         minutesPlural,
1454                         " to the game!"
1455                 )
1456         );
1457 }
1458
1459 float GetWinningCode(float fraglimitreached, float equality)
1460 {
1461         if(equality)
1462                 if(fraglimitreached)
1463                         return WINNING_STARTSUDDENDEATHOVERTIME;
1464                 else
1465                         return WINNING_NEVER;
1466         else
1467                 if(fraglimitreached)
1468                         return WINNING_YES;
1469                 else
1470                         return WINNING_NO;
1471 }
1472
1473 // set the .winning flag for exactly those players with a given field value
1474 void SetWinners(.float field, float value)
1475 {
1476         entity head;
1477         FOR_EACH_PLAYER(head)
1478                 head.winning = (head.field == value);
1479 }
1480
1481 // set the .winning flag for those players with a given field value
1482 void AddWinners(.float field, float value)
1483 {
1484         entity head;
1485         FOR_EACH_PLAYER(head)
1486                 if(head.field == value)
1487                         head.winning = 1;
1488 }
1489
1490 // clear the .winning flags
1491 void ClearWinners(void)
1492 {
1493         entity head;
1494         FOR_EACH_PLAYER(head)
1495                 head.winning = 0;
1496 }
1497
1498 // Onslaught winning condition:
1499 // game terminates if only one team has a working generator (or none)
1500 float WinningCondition_Onslaught()
1501 {
1502         entity head;
1503         local float t1, t2, t3, t4;
1504
1505         WinningConditionHelper(); // set worldstatus
1506
1507         if(inWarmupStage)
1508                 return WINNING_NO;
1509
1510         // first check if the game has ended
1511         t1 = t2 = t3 = t4 = 0;
1512         head = find(world, classname, "onslaught_generator");
1513         while (head)
1514         {
1515                 if (head.health > 0)
1516                 {
1517                         if (head.team == COLOR_TEAM1) t1 = 1;
1518                         if (head.team == COLOR_TEAM2) t2 = 1;
1519                         if (head.team == COLOR_TEAM3) t3 = 1;
1520                         if (head.team == COLOR_TEAM4) t4 = 1;
1521                 }
1522                 head = find(head, classname, "onslaught_generator");
1523         }
1524         if (t1 + t2 + t3 + t4 < 2)
1525         {
1526                 // game over, only one team remains (or none)
1527                 ClearWinners();
1528                 if (t1) SetWinners(team, COLOR_TEAM1);
1529                 if (t2) SetWinners(team, COLOR_TEAM2);
1530                 if (t3) SetWinners(team, COLOR_TEAM3);
1531                 if (t4) SetWinners(team, COLOR_TEAM4);
1532                 dprint("Have a winner, ending game.\n");
1533                 return WINNING_YES;
1534         }
1535
1536         // Two or more teams remain
1537         return WINNING_NO;
1538 }
1539
1540 float LMS_NewPlayerLives()
1541 {
1542         float fl;
1543         fl = cvar("fraglimit");
1544         if(fl == 0)
1545                 fl = 999;
1546
1547         // first player has left the game for dying too much? Nobody else can get in.
1548         if(lms_lowest_lives < 1)
1549                 return 0;
1550
1551         if(!cvar("g_lms_join_anytime"))
1552                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1553                         return 0;
1554
1555         return bound(1, lms_lowest_lives, fl);
1556 }
1557
1558 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1559 // they win. Otherwise the defending team wins once the timelimit passes.
1560 void assault_new_round();
1561 float WinningCondition_Assault()
1562 {
1563         local float status;
1564
1565         WinningConditionHelper(); // set worldstatus
1566
1567         status = WINNING_NO;
1568         // as the timelimit has not yet passed just assume the defending team will win
1569         if(assault_attacker_team == COLOR_TEAM1)
1570         {
1571                 SetWinners(team, COLOR_TEAM2);
1572         }
1573         else
1574         {
1575                 SetWinners(team, COLOR_TEAM1);
1576         }
1577
1578         local entity ent;
1579         ent = find(world, classname, "target_assault_roundend");
1580         if(ent)
1581         {
1582                 if(ent.winning) // round end has been triggered by attacking team
1583                 {
1584                         bprint("ASSAULT: round completed...\n");
1585                         SetWinners(team, assault_attacker_team);
1586
1587                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1588
1589                         if(ent.cnt == 1) // this was the second round
1590                         {
1591                                 status = WINNING_YES;
1592                         }
1593                         else
1594                         {
1595                                 local entity oldself;
1596                                 oldself = self;
1597                                 self = ent;
1598                                 assault_new_round();
1599                                 self = oldself;
1600                         }
1601                 }
1602         }
1603
1604         return status;
1605 }
1606
1607 // LMS winning condition: game terminates if and only if there's at most one
1608 // one player who's living lives. Top two scores being equal cancels the time
1609 // limit.
1610 float WinningCondition_LMS()
1611 {
1612         entity head, head2;
1613         float have_player;
1614         float have_players;
1615         float l;
1616
1617         have_player = FALSE;
1618         have_players = FALSE;
1619         l = LMS_NewPlayerLives();
1620
1621         head = find(world, classname, "player");
1622         if(head)
1623                 have_player = TRUE;
1624         head2 = find(head, classname, "player");
1625         if(head2)
1626                 have_players = TRUE;
1627
1628         if(have_player)
1629         {
1630                 // we have at least one player
1631                 if(have_players)
1632                 {
1633                         // two or more active players - continue with the game
1634                 }
1635                 else
1636                 {
1637                         // exactly one player?
1638
1639                         ClearWinners();
1640                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1641
1642                         if(l)
1643                         {
1644                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1645                                 return WINNING_NO;
1646                         }
1647                         else
1648                         {
1649                                 // a winner!
1650                                 // and assign him his first place
1651                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1652                                 return WINNING_YES;
1653                         }
1654                 }
1655         }
1656         else
1657         {
1658                 // nobody is playing at all...
1659                 if(l)
1660                 {
1661                         // wait for players...
1662                 }
1663                 else
1664                 {
1665                         // SNAFU (maybe a draw game?)
1666                         ClearWinners();
1667                         dprint("No players, ending game.\n");
1668                         return WINNING_YES;
1669                 }
1670         }
1671
1672         // When we get here, we have at least two players who are actually LIVING,
1673         // now check if the top two players have equal score.
1674         WinningConditionHelper();
1675
1676         ClearWinners();
1677         if(WinningConditionHelper_winner)
1678                 WinningConditionHelper_winner.winning = TRUE;
1679         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1680                 return WINNING_NEVER;
1681
1682         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1683         return WINNING_NO;
1684 }
1685
1686 void ShuffleMaplist()
1687 {
1688         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1689 }
1690
1691 float leaderfrags;
1692 float WinningCondition_Scores(float limit, float leadlimit)
1693 {
1694         // TODO make everything use THIS winning condition (except LMS)
1695         WinningConditionHelper();
1696
1697         if(teams_matter)
1698         {
1699                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1700                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1701                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1702                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1703         }
1704
1705         ClearWinners();
1706         if(WinningConditionHelper_winner)
1707                 WinningConditionHelper_winner.winning = 1;
1708         if(WinningConditionHelper_winnerteam >= 0)
1709                 SetWinners(team, WinningConditionHelper_winnerteam);
1710
1711         if(WinningConditionHelper_lowerisbetter)
1712         {
1713                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1714                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1715                 limit = -limit;
1716         }
1717
1718         if(WinningConditionHelper_zeroisworst)
1719                 leadlimit = 0; // not supported in this mode
1720
1721         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1722         // these modes always score in increments of 1, thus this makes sense
1723         {
1724                 if(leaderfrags != WinningConditionHelper_topscore)
1725                 {
1726                         leaderfrags = WinningConditionHelper_topscore;
1727
1728                         if (limit)
1729                         if (leaderfrags == limit - 1)
1730                                 play2all("announcer/robotic/1fragleft.wav");
1731                         else if (leaderfrags == limit - 2)
1732                                 play2all("announcer/robotic/2fragsleft.wav");
1733                         else if (leaderfrags == limit - 3)
1734                                 play2all("announcer/robotic/3fragsleft.wav");
1735                 }
1736         }
1737
1738         return GetWinningCode(
1739                 WinningConditionHelper_topscore &&
1740                 (
1741                         (limit && (WinningConditionHelper_topscore >= limit))
1742                         ||
1743                         (leadlimit && (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit))
1744                 ),
1745                 WinningConditionHelper_equality
1746         );
1747 }
1748
1749 float WinningCondition_Race(float fraglimit)
1750 {
1751         float wc;
1752         entity p;
1753         float n, c;
1754
1755         n = 0;
1756         c = 0;
1757         FOR_EACH_PLAYER(p)
1758         {
1759                 ++n;
1760                 if(p.race_completed)
1761                         ++c;
1762         }
1763         if(n && (n == c))
1764                 return WINNING_YES;
1765         wc = WinningCondition_Scores(fraglimit, 0);
1766
1767         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1768         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1769         // do NOT support equality when the laps are all raced!
1770                 return WINNING_STARTSUDDENDEATHOVERTIME;
1771         else
1772                 return WINNING_NEVER;
1773         return wc;
1774 }
1775
1776 void ReadyRestart();
1777 float WinningCondition_QualifyingThenRace(float limit)
1778 {
1779         float wc;
1780         wc = WinningCondition_Scores(limit, 0);
1781
1782         // NEVER initiate overtime
1783         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1784         {
1785                 return WINNING_YES;
1786         }
1787
1788         return wc;
1789 }
1790
1791 float WinningCondition_RanOutOfSpawns()
1792 {
1793         entity head;
1794
1795         if(have_team_spawns <= 0)
1796                 return WINNING_NO;
1797
1798         if(!some_spawn_has_been_used)
1799                 return WINNING_NO;
1800
1801         team1_score = team2_score = team3_score = team4_score = 0;
1802
1803         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1804         {
1805                 if(head.team == COLOR_TEAM1)
1806                         team1_score = 1;
1807                 else if(head.team == COLOR_TEAM2)
1808                         team2_score = 1;
1809                 else if(head.team == COLOR_TEAM3)
1810                         team3_score = 1;
1811                 else if(head.team == COLOR_TEAM4)
1812                         team4_score = 1;
1813         }
1814
1815         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1816         {
1817                 if(head.team == COLOR_TEAM1)
1818                         team1_score = 1;
1819                 else if(head.team == COLOR_TEAM2)
1820                         team2_score = 1;
1821                 else if(head.team == COLOR_TEAM3)
1822                         team3_score = 1;
1823                 else if(head.team == COLOR_TEAM4)
1824                         team4_score = 1;
1825         }
1826
1827         ClearWinners();
1828         if(team1_score + team2_score + team3_score + team4_score == 0)
1829         {
1830                 checkrules_equality = TRUE;
1831                 return WINNING_YES;
1832         }
1833         else if(team1_score + team2_score + team3_score + team4_score == 1)
1834         {
1835                 float t, i;
1836                 if(team1_score) t = COLOR_TEAM1;
1837                 if(team2_score) t = COLOR_TEAM2;
1838                 if(team3_score) t = COLOR_TEAM3;
1839                 if(team4_score) t = COLOR_TEAM4;
1840                 CheckAllowedTeams(world);
1841                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1842                 {
1843                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1844                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1845                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1846                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1847                 }
1848
1849                 AddWinners(team, t);
1850                 return WINNING_YES;
1851         }
1852         else
1853                 return WINNING_NO;
1854 }
1855
1856 /*
1857 ============
1858 CheckRules_World
1859
1860 Exit deathmatch games upon conditions
1861 ============
1862 */
1863 void CheckRules_World()
1864 {
1865         float timelimit;
1866         float fraglimit;
1867         float leadlimit;
1868
1869         VoteThink();
1870         MapVote_Think();
1871
1872         SetDefaultAlpha();
1873
1874         /*
1875         MapVote_Think should now do that part
1876         if (intermission_running)
1877                 if (time >= intermission_exittime + 60)
1878                 {
1879                         if(!DoNextMapOverride())
1880                                 GotoNextMap();
1881                         return;
1882                 }
1883         */
1884
1885         if (gameover)   // someone else quit the game already
1886         {
1887                 if(player_count == 0) // Nobody there? Then let's go to the next map
1888                         MapVote_Start();
1889                         // this will actually check the player count in the next frame
1890                         // again, but this shouldn't hurt
1891                 return;
1892         }
1893
1894         timelimit = cvar("timelimit") * 60;
1895         fraglimit = cvar("fraglimit");
1896         leadlimit = cvar("leadlimit");
1897
1898         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1899         {
1900                 if(timelimit > 0)
1901                         timelimit = 0; // timelimit is not made for warmup
1902                 if(fraglimit > 0)
1903                         fraglimit = 0; // no fraglimit for now
1904                 leadlimit = 0; // no leadlimit for now
1905         }
1906
1907         if(g_onslaught)
1908                 timelimit = 0; // ONS has its own overtime rule
1909
1910         if(timelimit > 0)
1911         {
1912                 timelimit += game_starttime;
1913         }
1914         else if (timelimit < 0)
1915         {
1916                 // endmatch
1917                 NextLevel();
1918                 return;
1919         }
1920
1921         float wantovertime;
1922         wantovertime = 0;
1923
1924         if(checkrules_suddendeathend)
1925         {
1926                 if(!checkrules_suddendeathwarning)
1927                 {
1928                         checkrules_suddendeathwarning = TRUE;
1929                         if(g_race && !g_race_qualifying)
1930                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1931                         else
1932                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1933                 }
1934         }
1935         else
1936         {
1937                 if (timelimit && time >= timelimit)
1938                 {
1939                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1940                         {
1941                                 float totalplayers;
1942                                 float playerswithlaps;
1943                                 float readyplayers;
1944                                 entity head;
1945                                 totalplayers = playerswithlaps = readyplayers = 0;
1946                                 FOR_EACH_PLAYER(head)
1947                                 {
1948                                         ++totalplayers;
1949                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1950                                                 ++playerswithlaps;
1951                                         if(head.ready)
1952                                                 ++readyplayers;
1953                                 }
1954
1955                                 // at least 2 of the players have completed a lap: start the RACE
1956                                 // otherwise, the players should end the qualifying on their own
1957                                 if(readyplayers || playerswithlaps >= 2)
1958                                 {
1959                                         checkrules_suddendeathend = 0;
1960                                         ReadyRestart(); // go to race
1961                                         return;
1962                                 }
1963                                 else
1964                                         wantovertime |= InitiateSuddenDeath();
1965                         }
1966                         else
1967                                 wantovertime |= InitiateSuddenDeath();
1968                 }
1969         }
1970
1971         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1972         {
1973                 NextLevel();
1974                 return;
1975         }
1976
1977         float checkrules_status;
1978         checkrules_status = WinningCondition_RanOutOfSpawns();
1979         if(checkrules_status == WINNING_YES)
1980         {
1981                 bprint("Hey! Someone ran out of spawns!\n");
1982         }
1983         else if(g_race && !g_race_qualifying && timelimit >= 0)
1984         {
1985                 checkrules_status = WinningCondition_Race(fraglimit);
1986                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
1987         }
1988         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1989         {
1990                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1991                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
1992         }
1993         else if(g_assault)
1994         {
1995                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1996         }
1997         else if(g_lms)
1998         {
1999                 checkrules_status = WinningCondition_LMS();
2000         }
2001         else if (g_onslaught)
2002         {
2003                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2004         }
2005         else
2006         {
2007                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2008                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2009         }
2010
2011         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2012         {
2013                 checkrules_status = WINNING_NEVER;
2014                 checkrules_overtimesadded = -1;
2015                 wantovertime |= InitiateSuddenDeath();
2016         }
2017
2018         if(checkrules_status == WINNING_NEVER)
2019                 // equality cases! Nobody wins if the overtime ends in a draw.
2020                 ClearWinners();
2021
2022         if(wantovertime)
2023         {
2024                 if(checkrules_status == WINNING_NEVER)
2025                         InitiateOvertime();
2026                 else
2027                         checkrules_status = WINNING_YES;
2028         }
2029
2030         if(checkrules_suddendeathend)
2031                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2032                         checkrules_status = WINNING_YES;
2033
2034         if(checkrules_status == WINNING_YES)
2035         {
2036                 //print("WINNING\n");
2037                 NextLevel();
2038         }
2039 };
2040
2041 float mapvote_nextthink;
2042 float mapvote_initialized;
2043 float mapvote_keeptwotime;
2044 float mapvote_timeout;
2045 string mapvote_message;
2046 string mapvote_screenshot_dir;
2047
2048 float mapvote_count;
2049 float mapvote_count_real;
2050 string mapvote_maps[MAPVOTE_COUNT];
2051 float mapvote_maps_suggested[MAPVOTE_COUNT];
2052 string mapvote_suggestions[MAPVOTE_COUNT];
2053 float mapvote_suggestion_ptr;
2054 float mapvote_maxlen;
2055 float mapvote_voters;
2056 float mapvote_votes[MAPVOTE_COUNT];
2057 float mapvote_run;
2058 float mapvote_detail;
2059 float mapvote_abstain;
2060 .float mapvote;
2061
2062 void MapVote_ClearAllVotes()
2063 {
2064         FOR_EACH_CLIENT(other)
2065                 other.mapvote = 0;
2066 }
2067
2068 string MapVote_Suggest(string m)
2069 {
2070         float i;
2071         if(m == "")
2072                 return "That's not how to use this command.";
2073         if(!cvar("g_maplist_votable_suggestions"))
2074                 return "Suggestions are not accepted on this server.";
2075         if(mapvote_initialized)
2076                 return "Can't suggest - voting is already in progress!";
2077         m = MapInfo_FixName(m);
2078         if(!m)
2079                 return "The map you suggested is not available on this server.";
2080         if(!cvar("g_maplist_votable_override_mostrecent"))
2081                 if(Map_IsRecent(m))
2082                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2083
2084         if(!MapInfo_CheckMap(m))
2085                 return "The map you suggested does not support the current game mode.";
2086         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2087                 if(mapvote_suggestions[i] == m)
2088                         return "This map was already suggested.";
2089         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2090         {
2091                 i = floor(random() * mapvote_suggestion_ptr);
2092         }
2093         else
2094         {
2095                 i = mapvote_suggestion_ptr;
2096                 mapvote_suggestion_ptr += 1;
2097         }
2098         if(mapvote_suggestions[i] != "")
2099                 strunzone(mapvote_suggestions[i]);
2100         mapvote_suggestions[i] = strzone(m);
2101         if(cvar("sv_eventlog"))
2102                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2103         return strcat("Suggestion of ", m, " accepted.");
2104 }
2105
2106 void MapVote_AddVotable(string nextMap, float isSuggestion)
2107 {
2108         float j;
2109         if(nextMap == "")
2110                 return;
2111         for(j = 0; j < mapvote_count; ++j)
2112                 if(mapvote_maps[j] == nextMap)
2113                         return;
2114         if(strlen(nextMap) > mapvote_maxlen)
2115                 mapvote_maxlen = strlen(nextMap);
2116         mapvote_maps[mapvote_count] = strzone(nextMap);
2117         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2118         mapvote_count += 1;
2119 }
2120
2121 void MapVote_Spawn();
2122 void MapVote_Init()
2123 {
2124         float i;
2125         float nmax, smax;
2126
2127         MapVote_ClearAllVotes();
2128
2129         mapvote_count = 0;
2130         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2131         mapvote_abstain = cvar("g_maplist_votable_abstain");
2132
2133         if(mapvote_abstain)
2134                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2135         else
2136                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2137         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2138
2139         if(mapvote_suggestion_ptr)
2140                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2141                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2142
2143         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2144                 MapVote_AddVotable(GetNextMap(), FALSE);
2145
2146         if(mapvote_count == 0)
2147         {
2148                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2149                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2150                 if(cvar("g_maplist_shuffle"))
2151                         ShuffleMaplist();
2152                 localcmd("\nmenu_cmd sync\n");
2153                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2154                         MapVote_AddVotable(GetNextMap(), FALSE);
2155         }
2156
2157         mapvote_count_real = mapvote_count;
2158         if(mapvote_abstain)
2159                 MapVote_AddVotable("don't care", 0);
2160
2161         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2162
2163         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2164         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2165         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2166                 mapvote_keeptwotime = 0;
2167         mapvote_message = "Choose a map and press its key!";
2168
2169         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2170         if(mapvote_screenshot_dir == "")
2171                 mapvote_screenshot_dir = "maps";
2172         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2173
2174         MapVote_Spawn();
2175 }
2176
2177 void MapVote_SendPicture(float id)
2178 {
2179         msg_entity = self;
2180         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2181         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2182         WriteByte(MSG_ONE, id);
2183         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2184 }
2185
2186 float GameCommand_MapVote(string cmd)
2187 {
2188         if(!intermission_running)
2189                 return FALSE;
2190
2191         if(cmd == "mv_getpic")
2192         {
2193                 MapVote_SendPicture(stof(argv(1)));
2194                 return TRUE;
2195         }
2196
2197         return FALSE;
2198 }
2199
2200 float MapVote_GetMapMask()
2201 {
2202         float mask, i, power;
2203         mask = 0;
2204         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2205                 if(mapvote_maps[i] != "")
2206                         mask |= power;
2207         return mask;
2208 }
2209
2210 entity mapvote_ent;
2211 float MapVote_SendEntity(entity to, float sf)
2212 {
2213         string mapfile, pakfile;
2214         float i, o;
2215
2216         if(sf & 1)
2217                 sf &~= 2; // if we send 1, we don't need to also send 2
2218
2219         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2220         WriteByte(MSG_ENTITY, sf);
2221
2222         if(sf & 1)
2223         {
2224                 // flag 1 == initialization
2225                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2226                 WriteByte(MSG_ENTITY, mapvote_count);
2227                 WriteByte(MSG_ENTITY, mapvote_abstain);
2228                 WriteByte(MSG_ENTITY, mapvote_detail);
2229                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2230                 if(mapvote_count <= 8)
2231                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2232                 else
2233                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2234                 for(i = 0; i < mapvote_count; ++i)
2235                         if(mapvote_maps[i] != "")
2236                         {
2237                                 if(mapvote_abstain && i == mapvote_count - 1)
2238                                 {
2239                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2240                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2241                                 }
2242                                 else
2243                                 {
2244                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2245                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2246                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2247                                         if(pakfile == "")
2248                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2249                                         if(pakfile == "")
2250                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2251                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2252                                                 pakfile = substring(pakfile, o, 999);
2253                                         WriteString(MSG_ENTITY, pakfile);
2254                                 }
2255                         }
2256         }
2257
2258         if(sf & 2)
2259         {
2260                 // flag 2 == update of mask
2261                 if(mapvote_count <= 8)
2262                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2263                 else
2264                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2265         }
2266
2267         if(sf & 4)
2268         {
2269                 if(mapvote_detail)
2270                         for(i = 0; i < mapvote_count; ++i)
2271                                 if(mapvote_maps[i] != "")
2272                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2273
2274                 WriteByte(MSG_ENTITY, to.mapvote);
2275         }
2276
2277         return TRUE;
2278 }
2279
2280 void MapVote_Spawn()
2281 {
2282         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2283 }
2284
2285 void MapVote_TouchMask()
2286 {
2287         mapvote_ent.SendFlags |= 2;
2288 }
2289
2290 void MapVote_TouchVotes(entity voter)
2291 {
2292         mapvote_ent.SendFlags |= 4;
2293 }
2294
2295 float MapVote_Finished(float mappos)
2296 {
2297         string result;
2298         float i;
2299         float didntvote;
2300
2301         if(cvar("sv_eventlog"))
2302         {
2303                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2304                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2305                 didntvote = mapvote_voters;
2306                 for(i = 0; i < mapvote_count; ++i)
2307                         if(mapvote_maps[i] != "")
2308                         {
2309                                 didntvote -= mapvote_votes[i];
2310                                 if(i != mappos)
2311                                 {
2312                                         result = strcat(result, ":", mapvote_maps[i]);
2313                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2314                                 }
2315                         }
2316                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2317
2318                 GameLogEcho(result);
2319                 if(mapvote_maps_suggested[mappos])
2320                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2321         }
2322
2323         FOR_EACH_REALCLIENT(other)
2324                 FixClientCvars(other);
2325
2326         Map_Goto_SetStr(mapvote_maps[mappos]);
2327         Map_Goto();
2328         alreadychangedlevel = TRUE;
2329         return TRUE;
2330 }
2331 void MapVote_CheckRules_1()
2332 {
2333         float i;
2334
2335         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2336         {
2337                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2338                 mapvote_votes[i] = 0;
2339         }
2340
2341         mapvote_voters = 0;
2342         FOR_EACH_REALCLIENT(other)
2343         {
2344                 ++mapvote_voters;
2345                 if(other.mapvote)
2346                 {
2347                         i = other.mapvote - 1;
2348                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2349                         mapvote_votes[i] = mapvote_votes[i] + 1;
2350                 }
2351         }
2352 }
2353
2354 float MapVote_CheckRules_2()
2355 {
2356         float i;
2357         float firstPlace, secondPlace;
2358         float firstPlaceVotes, secondPlaceVotes;
2359         float mapvote_voters_real;
2360         string result;
2361
2362         if(mapvote_count_real == 1)
2363                 return MapVote_Finished(0);
2364
2365         mapvote_voters_real = mapvote_voters;
2366         if(mapvote_abstain)
2367                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2368
2369         RandomSelection_Init();
2370         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2371                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2372         firstPlace = RandomSelection_chosen_float;
2373         firstPlaceVotes = RandomSelection_best_priority;
2374         //dprint("First place: ", ftos(firstPlace), "\n");
2375         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2376
2377         RandomSelection_Init();
2378         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2379                 if(i != firstPlace)
2380                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2381         secondPlace = RandomSelection_chosen_float;
2382         secondPlaceVotes = RandomSelection_best_priority;
2383         //dprint("Second place: ", ftos(secondPlace), "\n");
2384         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2385
2386         if(firstPlace == -1)
2387                 error("No first place in map vote... WTF?");
2388
2389         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2390                 return MapVote_Finished(firstPlace);
2391
2392         if(mapvote_keeptwotime)
2393                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2394                 {
2395                         float didntvote;
2396                         MapVote_TouchMask();
2397                         mapvote_message = "Now decide between the TOP TWO!";
2398                         mapvote_keeptwotime = 0;
2399                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2400                         result = strcat(result, ":", ftos(firstPlaceVotes));
2401                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2402                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2403                         didntvote = mapvote_voters;
2404                         for(i = 0; i < mapvote_count; ++i)
2405                                 if(mapvote_maps[i] != "")
2406                                 {
2407                                         didntvote -= mapvote_votes[i];
2408                                         if(i != firstPlace)
2409                                                 if(i != secondPlace)
2410                                                 {
2411                                                         result = strcat(result, ":", mapvote_maps[i]);
2412                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2413                                                         if(i < mapvote_count_real)
2414                                                         {
2415                                                                 strunzone(mapvote_maps[i]);
2416                                                                 mapvote_maps[i] = "";
2417                                                         }
2418                                                 }
2419                                 }
2420                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2421                         if(cvar("sv_eventlog"))
2422                                 GameLogEcho(result);
2423                 }
2424
2425         return FALSE;
2426 }
2427 void MapVote_Tick()
2428 {
2429         float keeptwo;
2430         float totalvotes;
2431
2432         keeptwo = mapvote_keeptwotime;
2433         MapVote_CheckRules_1(); // count
2434         if(MapVote_CheckRules_2()) // decide
2435                 return;
2436
2437         totalvotes = 0;
2438         FOR_EACH_REALCLIENT(other)
2439         {
2440                 // hide scoreboard again
2441                 if(other.health != 2342)
2442                 {
2443                         other.health = 2342;
2444                         other.impulse = 0;
2445                         if(clienttype(other) == CLIENTTYPE_REAL)
2446                         {
2447                                 msg_entity = other;
2448                                 WriteByte(MSG_ONE, SVC_FINALE);
2449                                 WriteString(MSG_ONE, "");
2450                         }
2451                 }
2452
2453                 // clear possibly invalid votes
2454                 if(mapvote_maps[other.mapvote - 1] == "")
2455                         other.mapvote = 0;
2456                 // use impulses as new vote
2457                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2458                         if(mapvote_maps[other.impulse - 1] != "")
2459                         {
2460                                 other.mapvote = other.impulse;
2461                                 MapVote_TouchVotes(other);
2462                         }
2463                 other.impulse = 0;
2464
2465                 if(other.mapvote)
2466                         ++totalvotes;
2467         }
2468
2469         MapVote_CheckRules_1(); // just count
2470 }
2471 void MapVote_Start()
2472 {
2473         if(mapvote_run)
2474                 return;
2475
2476         MapInfo_Enumerate();
2477         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2478                 mapvote_run = TRUE;
2479 }
2480 void MapVote_Think()
2481 {
2482         if(!mapvote_run)
2483                 return;
2484
2485         if(alreadychangedlevel)
2486                 return;
2487
2488         if(time < mapvote_nextthink)
2489                 return;
2490         //dprint("tick\n");
2491
2492         mapvote_nextthink = time + 0.5;
2493
2494         if(!mapvote_initialized)
2495         {
2496                 if(cvar("rescan_pending") == 1)
2497                 {
2498                         cvar_set("rescan_pending", "2");
2499                         localcmd("fs_rescan\nrescan_pending 3\n");
2500                         return;
2501                 }
2502                 else if(cvar("rescan_pending") == 2)
2503                 {
2504                         return;
2505                 }
2506                 else if(cvar("rescan_pending") == 3)
2507                 {
2508                         // now build missing mapinfo files
2509                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2510                                 return;
2511
2512                         // we're done, start the timer
2513                         cvar_set("rescan_pending", "0");
2514                 }
2515
2516                 mapvote_initialized = TRUE;
2517                 if(DoNextMapOverride())
2518                         return;
2519                 if(!cvar("g_maplist_votable") || player_count <= 0)
2520                 {
2521                         GotoNextMap();
2522                         return;
2523                 }
2524                 MapVote_Init();
2525         }
2526
2527         MapVote_Tick();
2528 };
2529
2530 string GotoMap(string m)
2531 {
2532         if(!MapInfo_CheckMap(m))
2533                 return "The map you chose is not available on this server.";
2534         cvar_set("nextmap", m);
2535         cvar_set("timelimit", "-1");
2536         if(mapvote_initialized || alreadychangedlevel)
2537         {
2538                 if(DoNextMapOverride())
2539                         return "Map switch initiated.";
2540                 else
2541                         return "Hm... no. For some reason I like THIS map more.";
2542         }
2543         else
2544                 return "Map switch will happen after scoreboard.";
2545 }
2546
2547
2548 void EndFrame()
2549 {
2550         float altime;
2551         FOR_EACH_REALCLIENT(self)
2552         {
2553                 if(self.classname == "spectator")
2554                 {
2555                         if(self.enemy.typehitsound)
2556                                 play2(self, "misc/typehit.wav");
2557                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2558                                 play2(self, "misc/hit.wav");
2559                 }
2560                 else
2561                 {
2562                         if(self.typehitsound)
2563                                 play2(self, "misc/typehit.wav");
2564                         else if(self.hitsound && self.cvar_cl_hitsound)
2565                                 play2(self, "misc/hit.wav");
2566                 }
2567         }
2568         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2569         // add 1 frametime because after this, engine SV_Physics
2570         // increases time by a frametime and then networks the frame
2571         // add another frametime because client shows everything with
2572         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2573         // needed!
2574         FOR_EACH_CLIENT(self)
2575         {
2576                 self.hitsound = FALSE;
2577                 self.typehitsound = FALSE;
2578                 antilag_record(self, altime);
2579         }
2580 }
2581
2582
2583 /*
2584  * RedirectionThink:
2585  * returns TRUE if redirecting
2586  */
2587 float redirection_timeout;
2588 float redirection_nextthink;
2589 float RedirectionThink()
2590 {
2591         float clients_found;
2592
2593         if(redirection_target == "")
2594                 return FALSE;
2595
2596         if(!redirection_timeout)
2597         {
2598                 cvar_set("sv_public", "-2");
2599                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2600                 if(redirection_target == "self")
2601                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2602                 else
2603                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2604         }
2605
2606         if(time < redirection_nextthink)
2607                 return TRUE;
2608
2609         redirection_nextthink = time + 1;
2610
2611         clients_found = 0;
2612         FOR_EACH_REALCLIENT(self)
2613         {
2614                 print("Redirecting: sending connect command to ", self.netname, "\n");
2615                 if(redirection_target == "self")
2616                         stuffcmd(self, "\ndisconnect; reconnect\n");
2617                 else
2618                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2619                 ++clients_found;
2620         }
2621
2622         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2623
2624         if(time > redirection_timeout || clients_found == 0)
2625                 localcmd("\nwait; wait; wait; quit\n");
2626
2627         return TRUE;
2628 }
2629
2630 void RestoreGame()
2631 {
2632         // Loaded from a save game
2633         // some things then break, so let's work around them...
2634
2635         // Progs DB (capture records)
2636         if(sv_cheats)
2637                 ServerProgsDB = db_create();
2638         else
2639                 ServerProgsDB = db_load("server.db");
2640
2641         // Mapinfo
2642         MapInfo_Shutdown();
2643         MapInfo_Enumerate();
2644         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2645         WeaponStats_Init();
2646 }
2647
2648 void SV_Shutdown()
2649 {
2650         if(gameover > 1) // shutting down already?
2651                 return;
2652
2653         gameover = 2; // 2 = server shutting down
2654
2655         if(world_initialized > 0)
2656         {
2657                 world_initialized = 0;
2658                 print("Saving persistent data...\n");
2659                 Ban_SaveBans();
2660                 if(!sv_cheats)
2661                         db_save(ServerProgsDB, "server.db");
2662                 if(cvar("developer"))
2663                         db_save(TemporaryDB, "server-temp.db");
2664                 db_close(ServerProgsDB);
2665                 db_close(TemporaryDB);
2666                 print("done!\n");
2667                 // tell the bot system the game is ending now
2668                 bot_endgame();
2669
2670                 WeaponStats_Shutdown();
2671                 MapInfo_Shutdown();
2672         }
2673         else if(world_initialized == 0)
2674         {
2675                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2676         }
2677 }