data/qcsrc/server/g_world.qc

   1 entity pingplreport;
   2 void PingPLReport_Think()
   3 {
   4         float delta;
   5         entity e;
   6
   7         delta = 3 / maxclients;
   8         if(delta < sys_frametime)
   9                 delta = 0;
  10         self.nextthink = time + delta;
  11
  12         e = edict_num(self.cnt + 1);
  13         if(clienttype(e) == CLIENTTYPE_REAL)
  14         {
  15                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  16                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  17                 WriteByte(MSG_BROADCAST, self.cnt);
  18                 WriteShort(MSG_BROADCAST, max(1, e.ping));
  19                 WriteByte(MSG_BROADCAST, ceil(e.ping_packetloss * 255));
  20                 WriteByte(MSG_BROADCAST, ceil(e.ping_movementloss * 255));
  21         }
  22         else
  23         {
  24                 WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  25                 WriteByte(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  26                 WriteByte(MSG_BROADCAST, self.cnt);
  27                 WriteShort(MSG_BROADCAST, 0);
  28                 WriteByte(MSG_BROADCAST, 0);
  29                 WriteByte(MSG_BROADCAST, 0);
  30         }
  31         self.cnt = mod(self.cnt + 1, maxclients);
  32 }
  33 void PingPLReport_Spawn()
  34 {
  35         pingplreport = spawn();
  36         pingplreport.classname = "pingplreport";
  37         pingplreport.think = PingPLReport_Think;
  38         pingplreport.nextthink = time;
  39 }
  40
  41 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
  42 string redirection_target;
  43 float world_initialized;
  44
  45 string GetMapname();
  46 string GetGametype();
  47 void GotoNextMap();
  48 void ShuffleMaplist()
  49 float() DoNextMapOverride;
  50
  51 void SetDefaultAlpha()
  52 {
  53         if(cvar("g_running_guns"))
  54         {
  55                 default_player_alpha = -1;
  56                 default_weapon_alpha = +1;
  57         }
  58         else if(g_cloaked)
  59         {
  60                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  61                 default_weapon_alpha = default_player_alpha;
  62         }
  63         else
  64         {
  65                 default_player_alpha = cvar("g_player_alpha");
  66                 if(default_player_alpha == 0)
  67                         default_player_alpha = 1;
  68                 default_weapon_alpha = default_player_alpha;
  69         }
  70 }
  71
  72 void fteqcc_testbugs()
  73 {
  74         float a, b;
  75
  76         if(!cvar("developer_fteqccbugs"))
  77                 return;
  78
  79         dprint("*** fteqcc test: checking for bugs...\n");
  80
  81         a = 1;
  82         b = 5;
  83         if(sqrt(a) - sqrt(b - a) == 0)
  84                 dprint("*** fteqcc test: found same-function-twice bug\n");
  85         else
  86                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  87
  88         world.cnt = -10;
  89         world.enemy = world;
  90         world.enemy.cnt += 10;
  91         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  92                 dprint("*** fteqcc test: found += bug\n");
  93         else
  94                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  95         world.cnt = 0;
  96 }
  97
  98 /**
  99  * Takes care of pausing and unpausing the game.
 100  * Centerprints the information about an upcoming or active timeout to all active
 101  * players. Also plays reminder sounds.
 102  */
 103 void timeoutHandler_Think() {
 104         local string timeStr;
 105         local entity plr;
 106         if (timeoutStatus == 1) {
 107                 if (remainingLeadTime > 0) {
 108                         //centerprint the information to every player
 109                         timeStr = getTimeoutText(0);
 110                         FOR_EACH_REALCLIENT(plr) {
 111                                 if(plr.classname == "player") {
 112                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 113                                 }
 114                         }
 115                         remainingLeadTime -= 1;
 116                         //think again in 1 second:
 117                         self.nextthink = time + 1;
 118                 }
 119                 else {
 120                         //now pause the game:
 121                         timeoutStatus = 2;
 122                         //reset all the flood variables
 123                         FOR_EACH_CLIENT(plr) {
 124                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
 125                         }
 126                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
 127                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
 128                         FOR_EACH_REALPLAYER(plr) {
 129                                 plr.lastV_angle = plr.v_angle;
 130                         }
 131                         self.nextthink = time;
 132                 }
 133         }
 134         else if (timeoutStatus == 2) {
 135                 if (remainingTimeoutTime > 0) {
 136                         timeStr = getTimeoutText(0);
 137                         FOR_EACH_REALCLIENT(plr) {
 138                                 if(plr.classname == "player") {
 139                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 140                                 }
 141                         }
 142                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 143                                 play2all("announcer/robotic/prepareforbattle.wav");
 144                         }
 145                         remainingTimeoutTime -= 1;
 146                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 147                 }
 148                 else {
 149                         //unpause the game again
 150                         remainingTimeoutTime = timeoutStatus = 0;
 151                         cvar_set("slowmo", ftos(orig_slowmo));
 152                         //and unlock the fixed view again once there is no timeout active anymore
 153                         FOR_EACH_REALPLAYER(plr) {
 154                                 plr.fixangle = FALSE;
 155                         }
 156                         //get rid of the countdown message
 157                         FOR_EACH_REALCLIENT(plr) {
 158                                 if(plr.classname == "player") {
 159                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 160                                 }
 161                         }
 162                         remove(self);
 163                         return;
 164                 }
 165
 166         }
 167         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 168                 FOR_EACH_REALCLIENT(plr) {
 169                         if(plr.classname == "player") {
 170                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 171                         }
 172                 }
 173                 remove(self);
 174                 return;
 175         }
 176 }
 177
 178 void GotoFirstMap()
 179 {
 180         float n;
 181         if(cvar("_sv_init"))
 182         {
 183                 // cvar_set("_sv_init", "0");
 184                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 185                 // to this "init" map on a dedicated server will cause no permanent
 186                 // harm
 187                 if(cvar("g_maplist_shuffle"))
 188                         ShuffleMaplist();
 189                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 190                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 191
 192                 MapInfo_Enumerate();
 193                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 194
 195                 if(!DoNextMapOverride())
 196                         GotoNextMap();
 197
 198                 return;
 199         }
 200
 201         if(time < 5)
 202         {
 203                 self.nextthink = time;
 204         }
 205         else
 206         {
 207                 self.nextthink = time + 1;
 208                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 209         }
 210 }
 211
 212 void cvar_changes_init()
 213 {
 214         float h;
 215         string k, v, d;
 216         float n, i;
 217
 218         if(cvar_changes)
 219                 strunzone(cvar_changes);
 220         cvar_changes = string_null;
 221
 222         h = buf_create();
 223         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 224         n = buf_getsize(h);
 225
 226         for(i = 0; i < n; ++i)
 227         {
 228                 k = bufstr_get(h, i);
 229
 230 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 231 #define BADCVAR(p) if(k == p) continue
 232                 // internal
 233                 BADPREFIX("csqc_");
 234                 BADPREFIX("cvar_check_");
 235                 BADCVAR("gamecfg");
 236                 BADCVAR("g_configversion");
 237                 BADCVAR("g_maplist_index");
 238                 BADCVAR("halflifebsp");
 239
 240                 // client
 241                 BADPREFIX("cl_");
 242                 BADPREFIX("con_");
 243                 BADPREFIX("g_campaign");
 244                 BADPREFIX("gl_");
 245                 BADPREFIX("joy");
 246                 BADPREFIX("menu_");
 247                 BADPREFIX("net_slist_");
 248                 BADPREFIX("r_");
 249                 BADPREFIX("sbar_");
 250                 BADPREFIX("scr_");
 251                 BADPREFIX("userbind");
 252                 BADPREFIX("v_");
 253                 BADPREFIX("vid_");
 254                 BADPREFIX("crosshair");
 255                 BADCVAR("mod_q3bsp_lightmapmergepower");
 256                 BADCVAR("mod_q3bsp_nolightmaps");
 257
 258                 // private
 259                 BADCVAR("serverconfig");
 260                 BADPREFIX("g_ban_");
 261                 BADPREFIX("g_chat_flood_");
 262                 BADPREFIX("g_voice_flood_");
 263                 BADPREFIX("rcon_");
 264                 BADPREFIX("settemp_");
 265                 BADPREFIX("sv_allowdownloads_");
 266                 BADPREFIX("sv_autodemo");
 267                 BADPREFIX("sv_curl_");
 268                 BADPREFIX("sv_eventlog");
 269                 BADPREFIX("sv_logscores_");
 270                 BADPREFIX("sv_master");
 271                 BADCVAR("g_banned_list");
 272                 BADCVAR("log_dest_udp");
 273                 BADCVAR("log_file");
 274                 BADCVAR("net_address");
 275                 BADCVAR("port");
 276                 BADCVAR("savedgamecfg");
 277                 BADCVAR("sv_heartbeatperiod");
 278                 BADCVAR("sv_vote_master_password");
 279                 BADCVAR("sys_colortranslation");
 280                 BADCVAR("sys_specialcharactertranslation");
 281                 BADCVAR("timestamps");
 282
 283                 // mapinfo
 284                 BADCVAR("timelimit");
 285                 BADCVAR("fraglimit");
 286                 BADCVAR("g_arena");
 287                 BADCVAR("g_ca");
 288                 BADCVAR("g_assault");
 289                 BADCVAR("g_ctf");
 290                 BADCVAR("g_dm");
 291                 BADCVAR("g_domination");
 292                 BADCVAR("g_keyhunt");
 293                 BADCVAR("g_keyhunt_teams");
 294                 BADCVAR("g_onslaught");
 295                 BADCVAR("g_race");
 296                 BADCVAR("g_cts");
 297                 BADCVAR("g_runematch");
 298                 BADCVAR("g_tdm");
 299                 BADCVAR("g_nexball");
 300                 BADCVAR("teamplay");
 301
 302                 // long
 303                 BADCVAR("hostname");
 304                 BADCVAR("g_maplist");
 305                 BADCVAR("g_maplist_mostrecent");
 306                 BADCVAR("sv_motd");
 307 #undef BADPREFIX
 308 #undef BADCVAR
 309
 310                 v = cvar_string(k);
 311                 d = cvar_defstring(k);
 312                 if(v != d)
 313                 {
 314                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 315                         if(strlen(cvar_changes) > 16384)
 316                         {
 317                                 cvar_changes = "// too many settings have been changed to show them here\n";
 318                                 break;
 319                         }
 320                 }
 321         }
 322         buf_del(h);
 323         if(cvar_changes == "")
 324                 cvar_changes = "// this server runs at default settings\n";
 325         else
 326                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 327         cvar_changes = strzone(cvar_changes);
 328 }
 329
 330 void detect_maptype()
 331 {
 332 #if 0
 333         vector o, v;
 334         float i;
 335
 336         for(;;)
 337         {
 338                 o = world.mins;
 339                 o_x += random() * (world.maxs_x - world.mins_x);
 340                 o_y += random() * (world.maxs_y - world.mins_y);
 341                 o_z += random() * (world.maxs_z - world.mins_z);
 342
 343                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 344                 if(trace_fraction == 1)
 345                         continue;
 346
 347                 v = trace_endpos;
 348
 349                 for(i = 0; i < 64; i += 4)
 350                 {
 351                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 352         if(trace_fraction == 1)
 353                 continue;
 354                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 355                 }
 356
 357                 break;
 358         }
 359 #endif
 360 }
 361
 362 entity randomseed;
 363 float RandomSeed_Send(entity to, float sf)
 364 {
 365         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 366         WriteShort(MSG_ENTITY, self.cnt);
 367         return TRUE;
 368 }
 369 void RandomSeed_Think()
 370 {
 371         self.cnt = bound(0, floor(random() * 65536), 65535);
 372         self.nextthink = time + 5;
 373
 374         self.SendFlags |= 1;
 375 }
 376 void RandomSeed_Spawn()
 377 {
 378         randomseed = spawn();
 379         randomseed.think = RandomSeed_Think;
 380         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 381
 382         entity oldself;
 383         oldself = self;
 384         self = randomseed;
 385         self.think(); // sets random seed and nextthink
 386         self = oldself;
 387 }
 388
 389 void spawnfunc___init_dedicated_server(void)
 390 {
 391         // handler for _init/_init map (only for dedicated server initialization)
 392
 393         world_initialized = -1; // don't complain
 394         cvar = cvar_normal;
 395         cvar_string = cvar_string_normal;
 396         cvar_set = cvar_set_normal;
 397
 398         remove = remove_unsafely;
 399
 400         entity e;
 401         e = spawn();
 402         e.think = GotoFirstMap;
 403         e.nextthink = time; // this is usually 1 at this point
 404
 405         e = spawn();
 406         e.classname = "info_player_deathmatch"; // safeguard against player joining
 407
 408         self.classname = "worldspawn"; // safeguard against various stuff ;)
 409
 410         MapInfo_Enumerate();
 411         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 412 }
 413
 414 void Map_MarkAsRecent(string m);
 415 float world_already_spawned;
 416 void RegisterWeapons();
 417 void Nagger_Init();
 418 void ClientInit_Spawn();
 419 void WeaponStats_Init();
 420 void WeaponStats_Shutdown();
 421 void spawnfunc_worldspawn (void)
 422 {
 423         float fd, l, i, j, n;
 424         string s, col;
 425
 426         cvar = cvar_normal;
 427         cvar_string = cvar_string_normal;
 428         cvar_set = cvar_set_normal;
 429
 430         if(world_already_spawned)
 431                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 432         world_already_spawned = TRUE;
 433
 434         remove = remove_safely; // during spawning, watch what you remove!
 435
 436         check_unacceptable_compiler_bugs();
 437
 438         compressShortVector_init();
 439
 440         local entity head;
 441         head = nextent(world);
 442         maxclients = 0;
 443         while(head)
 444         {
 445                 ++maxclients;
 446                 head = nextent(head);
 447         }
 448
 449         // needs to be done so early as they would still spawn
 450         RegisterWeapons();
 451
 452         ServerProgsDB = db_load("server.db");
 453
 454         TemporaryDB = db_create();
 455
 456         /*
 457         TODO sound pack system
 458         // initialize sound pack system
 459         soundpack = cvar_string("g_soundpack");
 460         if(soundpack != "")
 461                 soundpack = strcat(soundpack, "/");
 462         soundpack = strzone(soundpack);
 463         */
 464
 465         // 0 normal
 466         lightstyle(0, "m");
 467
 468         // 1 FLICKER (first variety)
 469         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 470
 471         // 2 SLOW STRONG PULSE
 472         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 473
 474         // 3 CANDLE (first variety)
 475         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 476
 477         // 4 FAST STROBE
 478         lightstyle(4, "mamamamamama");
 479
 480         // 5 GENTLE PULSE 1
 481         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 482
 483         // 6 FLICKER (second variety)
 484         lightstyle(6, "nmonqnmomnmomomno");
 485
 486         // 7 CANDLE (second variety)
 487         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 488
 489         // 8 CANDLE (third variety)
 490         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 491
 492         // 9 SLOW STROBE (fourth variety)
 493         lightstyle(9, "aaaaaaaazzzzzzzz");
 494
 495         // 10 FLUORESCENT FLICKER
 496         lightstyle(10, "mmamammmmammamamaaamammma");
 497
 498         // 11 SLOW PULSE NOT FADE TO BLACK
 499         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 500
 501         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 502
 503         // 63 testing
 504         lightstyle(63, "a");
 505
 506         if(cvar("g_campaign"))
 507                 CampaignPreInit();
 508
 509         Map_MarkAsRecent(mapname);
 510
 511         precache_model ("null"); // we need this one before InitGameplayMode
 512         InitGameplayMode();
 513         readlevelcvars();
 514         GrappleHookInit();
 515
 516         player_count = 0;
 517         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 518         if(bot_waypoints_for_items == 1)
 519                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 520                         bot_waypoints_for_items = 0;
 521
 522         // for setting by mapinfo
 523         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 524         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 525
 526         precache();
 527
 528         WaypointSprite_Init();
 529
 530         //if (g_domination)
 531         //      dom_init();
 532
 533         GameLogInit(); // prepare everything
 534         if(cvar("sv_eventlog"))
 535         {
 536                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 537                 s = strcat(s, ftos(random()));
 538                 matchid = strzone(s);
 539
 540                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 541                 s = ":gameinfo:mutators:LIST";
 542                 if(cvar("g_grappling_hook"))
 543                         s = strcat(s, ":grappling_hook");
 544                 if(!cvar("g_use_ammunition"))
 545                         s = strcat(s, ":no_use_ammunition");
 546                 if(!cvar("g_pickup_items"))
 547                         s = strcat(s, ":no_pickup_items");
 548                 if(cvar_string("g_weaponarena") != "0")
 549                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 550                 if(cvar("g_nixnex"))
 551                         s = strcat(s, ":nixnex");
 552                 if(cvar("g_vampire"))
 553                         s = strcat(s, ":vampire");
 554                 if(cvar("g_laserguided_missile"))
 555                         s = strcat(s, ":laserguided_missile");
 556                 if(cvar("g_norecoil"))
 557                         s = strcat(s, ":norecoil");
 558                 if(cvar("g_midair"))
 559                         s = strcat(s, ":midair");
 560                 if(cvar("g_minstagib"))
 561                         s = strcat(s, ":minstagib");
 562                 GameLogEcho(s);
 563                 GameLogEcho(":gameinfo:end");
 564         }
 565         else
 566                 matchid = strzone(ftos(random()));
 567
 568         cvar_set("nextmap", "");
 569
 570         SetDefaultAlpha();
 571
 572         if(cvar("g_campaign"))
 573                 CampaignPostInit();
 574
 575         fteqcc_testbugs();
 576
 577         Ban_LoadBans();
 578
 579         MapInfo_Enumerate();
 580         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 581
 582         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 583         {
 584                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 585                 if(fd != -1)
 586                 {
 587                         while((s = fgets(fd)))
 588                         {
 589                                 l = tokenize_console(s);
 590                                 if(l < 2)
 591                                         continue;
 592                                 if(argv(0) == "cd")
 593                                 {
 594                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 595                                         print("  cdtrack ", argv(2), "\n");
 596                                 }
 597                                 else if(argv(0) == "fog")
 598                                 {
 599                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 600                                         print("  \"fog\" \"", s, "\"\n");
 601                                 }
 602                                 else if(argv(0) == "set")
 603                                 {
 604                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 605                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 606                                 }
 607                                 else if(argv(0) != "//")
 608                                 {
 609                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 610                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 611                                 }
 612                         }
 613                         fclose(fd);
 614                 }
 615         }
 616
 617         WeaponStats_Init();
 618
 619         addstat(STAT_WEAPONS, AS_INT, weapons);
 620         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 621         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 622         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 623         Nagger_Init();
 624
 625         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 626         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 627         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 628         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 629         addstat(STAT_DAMAGE_HITS, AS_INT, stat_hit);
 630         addstat(STAT_DAMAGE_FIRED, AS_INT, stat_fired);
 631         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 632         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 633         addstat(STAT_BULLETS_LOADED, AS_INT, campingrifle_bulletcounter);
 634
 635         next_pingtime = time + 5;
 636         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 637
 638         detect_maptype();
 639
 640         lsmaps_reply = "^7Maps available: ";
 641         for(i = 0, j = 0; i < MapInfo_count; ++i)
 642         {
 643                 if(MapInfo_Get_ByID(i))
 644                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 645                         {
 646                                 if(mod(i, 2))
 647                                         col = "^2";
 648                                 else
 649                                         col = "^3";
 650                                 ++j;
 651                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 652                         }
 653         }
 654         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 655
 656         maplist_reply = "^7Maps in list: ";
 657         n = tokenize_console(cvar_string("g_maplist"));
 658         for(i = 0, j = 0; i < n; ++i)
 659         {
 660                 if(MapInfo_CheckMap(argv(i)))
 661                 {
 662                         if(mod(j, 2))
 663                                 col = "^2";
 664                         else
 665                                 col = "^3";
 666                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 667                         ++j;
 668                 }
 669         }
 670         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 671         MapInfo_ClearTemps();
 672
 673         records_reply = strzone(getrecords());
 674         rankings_reply = strzone(getrankings());
 675
 676         ClientInit_Spawn();
 677         RandomSeed_Spawn();
 678         PingPLReport_Spawn();
 679
 680         CheatInit();
 681
 682         localcmd("\n_sv_hook_gamestart ", GetGametype(), ";");
 683
 684         world_initialized = 1;
 685 }
 686
 687 void spawnfunc_light (void)
 688 {
 689         //makestatic (self); // Who the f___ did that?
 690         remove(self);
 691 }
 692
 693 float TryFile( string pFilename )
 694 {
 695         local float lHandle;
 696         dprint("TryFile(\"", pFilename, "\")\n");
 697         lHandle = fopen( pFilename, FILE_READ );
 698         if( lHandle != -1 ) {
 699                 fclose( lHandle );
 700                 return TRUE;
 701         } else {
 702                 return FALSE;
 703         }
 704 };
 705
 706 string GetGametype()
 707 {
 708         return GametypeNameFromType(game);
 709 }
 710
 711 string getmapname_stored;
 712 string GetMapname()
 713 {
 714         return mapname;
 715 }
 716
 717 float Map_Count, Map_Current;
 718 string Map_Current_Name;
 719
 720 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 721 float GetMaplistPosition()
 722 {
 723         float pos, idx;
 724         string map;
 725
 726         map = GetMapname();
 727         idx = cvar("g_maplist_index");
 728
 729         if(idx >= 0)
 730                 if(idx < Map_Count)
 731                         if(map == argv(idx))
 732                                 return idx;
 733
 734         for(pos = 0; pos < Map_Count; ++pos)
 735                 if(map == argv(pos))
 736                         return pos;
 737
 738         // resume normal maplist rotation if current map is not in g_maplist
 739         return idx;
 740 }
 741
 742 float MapHasRightSize(string map)
 743 {
 744         float fh;
 745         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 746         if(cvar("g_maplist_check_waypoints"))
 747         {
 748                 dprint("checkwp "); dprint(map);
 749                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 750                 if(fh < 0)
 751                 {
 752                         dprint(": no waypoints\n");
 753                         return FALSE;
 754                 }
 755                 dprint(": has waypoints\n");
 756                 fclose(fh);
 757         }
 758
 759         // open map size restriction file
 760         dprint("opensize "); dprint(map);
 761         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 762         if(fh >= 0)
 763         {
 764                 float mapmin, mapmax;
 765                 dprint(": ok, ");
 766                 mapmin = stof(fgets(fh));
 767                 mapmax = stof(fgets(fh));
 768                 fclose(fh);
 769                 if(player_count < mapmin)
 770                 {
 771                         dprint("not enough\n");
 772                         return FALSE;
 773                 }
 774                 if(player_count > mapmax)
 775                 {
 776                         dprint("too many\n");
 777                         return FALSE;
 778                 }
 779                 dprint("right size\n");
 780                 return TRUE;
 781         }
 782         dprint(": not found\n");
 783         return TRUE;
 784 }
 785
 786 string Map_Filename(float position)
 787 {
 788         return strcat("maps/", argv(position), ".bsp");
 789 }
 790
 791 string strwords(string s, float w)
 792 {
 793         float endpos;
 794         for(endpos = 0; w && endpos >= 0; --w)
 795                 endpos = strstrofs(s, " ", endpos + 1);
 796         if(endpos < 0)
 797                 return s;
 798         else
 799                 return substring(s, 0, endpos);
 800 }
 801
 802 float strhasword(string s, string w)
 803 {
 804         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 805 }
 806
 807 void Map_MarkAsRecent(string m)
 808 {
 809         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 810 }
 811
 812 float Map_IsRecent(string m)
 813 {
 814         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 815 }
 816
 817 float Map_Check(float position, float pass)
 818 {
 819         string filename;
 820         string map_next;
 821         map_next = argv(position);
 822         if(pass <= 1)
 823         {
 824                 if(Map_IsRecent(map_next))
 825                         return 0;
 826         }
 827         filename = Map_Filename(position);
 828         if(MapInfo_CheckMap(map_next))
 829         {
 830                 if(pass == 2)
 831                         return 1;
 832                 if(MapHasRightSize(map_next))
 833                         return 1;
 834                 return 0;
 835         }
 836         else
 837                 dprint( "Couldn't select '", filename, "'..\n" );
 838
 839         return 0;
 840 }
 841
 842 void Map_Goto_SetStr(string nextmapname)
 843 {
 844         if(getmapname_stored != "")
 845                 strunzone(getmapname_stored);
 846         if(nextmapname == "")
 847                 getmapname_stored = "";
 848         else
 849                 getmapname_stored = strzone(nextmapname);
 850 }
 851
 852 void Map_Goto_SetFloat(float position)
 853 {
 854         cvar_set("g_maplist_index", ftos(position));
 855         Map_Goto_SetStr(argv(position));
 856 }
 857
 858 void GameResetCfg()
 859 {
 860         // settings persist, except...
 861         localcmd("\nsettemp_restore\n");
 862 };
 863
 864 void Map_Goto()
 865 {
 866         GameResetCfg();
 867         MapInfo_LoadMap(getmapname_stored);
 868 }
 869
 870 // return codes of map selectors:
 871 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 872 //   -2 = permanent failure
 873 float() MaplistMethod_Iterate = // usual method
 874 {
 875         float pass, i;
 876
 877         for(pass = 1; pass <= 2; ++pass)
 878         {
 879                 for(i = 1; i < Map_Count; ++i)
 880                 {
 881                         float mapindex;
 882                         mapindex = mod(i + Map_Current, Map_Count);
 883                         if(Map_Check(mapindex, pass))
 884                                 return mapindex;
 885                 }
 886         }
 887         return -1;
 888 }
 889
 890 float() MaplistMethod_Repeat = // fallback method
 891 {
 892         if(Map_Check(Map_Current, 2))
 893                 return Map_Current;
 894         return -2;
 895 }
 896
 897 float() MaplistMethod_Random = // random map selection
 898 {
 899         float i, imax;
 900
 901         imax = 42;
 902
 903         for(i = 0; i <= imax; ++i)
 904         {
 905                 float mapindex;
 906                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 907                 if(Map_Check(mapindex, 1))
 908                         return mapindex;
 909         }
 910         return -1;
 911 }
 912
 913 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 914 // the exponent sets a bias on the map selection:
 915 // the higher the exponent, the less likely "shortly repeated" same maps are
 916 {
 917         float i, j, imax, insertpos;
 918
 919         imax = 42;
 920
 921         for(i = 0; i <= imax; ++i)
 922         {
 923                 string newlist;
 924
 925                 // now reinsert this at another position
 926                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 927                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 928                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 929                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 930
 931                 // insert the current map there
 932                 newlist = "";
 933                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 934                         newlist = strcat(newlist, " ", argv(j));
 935                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 936                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 937                         newlist = strcat(newlist, " ", argv(j));
 938                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 939                 cvar_set("g_maplist", newlist);
 940                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 941
 942                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 943                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 944                 if(Map_Check(Map_Current, 1))
 945                         return Map_Current;
 946         }
 947         return -1;
 948 }
 949
 950 void Maplist_Init()
 951 {
 952         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 953         if(Map_Count == 0)
 954         {
 955                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 956                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
 957                 if(cvar("g_maplist_shuffle"))
 958                         ShuffleMaplist();
 959                 localcmd("\nmenu_cmd sync\n");
 960                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 961         }
 962         if(Map_Count == 0)
 963                 error("empty maplist, cannot select a new map");
 964         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 965
 966         if(Map_Current_Name)
 967                 strunzone(Map_Current_Name);
 968         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 969         // this may or may not be correct, but who cares, in the worst case a map
 970         // isn't chosen in the first pass that should have been
 971 }
 972
 973 string GetNextMap()
 974 {
 975         float nextMap;
 976
 977         Maplist_Init();
 978         nextMap = -1;
 979
 980         if(nextMap == -1)
 981                 if(cvar("g_maplist_shuffle") > 0)
 982                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 983
 984         if(nextMap == -1)
 985                 if(cvar("g_maplist_selectrandom"))
 986                         nextMap = MaplistMethod_Random();
 987
 988         if(nextMap == -1)
 989                 nextMap = MaplistMethod_Iterate();
 990
 991         if(nextMap == -1)
 992                 nextMap = MaplistMethod_Repeat();
 993
 994         if(nextMap >= 0)
 995         {
 996                 Map_Goto_SetFloat(nextMap);
 997                 return getmapname_stored;
 998         }
 999
1000         return "";
1001 };
1002
1003 float DoNextMapOverride()
1004 {
1005         if(cvar("g_campaign"))
1006         {
1007                 CampaignPostIntermission();
1008                 alreadychangedlevel = TRUE;
1009                 return TRUE;
1010         }
1011         if(cvar("quit_when_empty"))
1012         {
1013                 if(player_count <= currentbots)
1014                 {
1015                         localcmd("quit\n");
1016                         alreadychangedlevel = TRUE;
1017                         return TRUE;
1018                 }
1019         }
1020         if(cvar_string("quit_and_redirect") != "")
1021         {
1022                 redirection_target = strzone(cvar_string("quit_and_redirect"));
1023                 alreadychangedlevel = TRUE;
1024                 return TRUE;
1025         }
1026         if (cvar("samelevel")) // if samelevel is set, stay on same level
1027         {
1028                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
1029                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
1030                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
1031                 localcmd("restart\n");
1032                 //changelevel (mapname);
1033                 alreadychangedlevel = TRUE;
1034                 return TRUE;
1035         }
1036         if(cvar_string("nextmap") != "")
1037                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1038                 {
1039                         Map_Goto_SetStr(cvar_string("nextmap"));
1040                         Map_Goto();
1041                         alreadychangedlevel = TRUE;
1042                         return TRUE;
1043                 }
1044         if(cvar("lastlevel"))
1045         {
1046                 GameResetCfg();
1047                 localcmd("set lastlevel 0\ntogglemenu\n");
1048                 alreadychangedlevel = TRUE;
1049                 return TRUE;
1050         }
1051         return FALSE;
1052 };
1053
1054 void GotoNextMap()
1055 {
1056         //local string nextmap;
1057         //local float n, nummaps;
1058         //local string s;
1059         if (alreadychangedlevel)
1060                 return;
1061         alreadychangedlevel = TRUE;
1062
1063         {
1064                 string nextMap;
1065                 float allowReset;
1066
1067                 for(allowReset = 1; allowReset >= 0; --allowReset)
1068                 {
1069                         nextMap = GetNextMap();
1070                         if(nextMap != "")
1071                                 break;
1072
1073                         if(allowReset)
1074                         {
1075                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1076                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
1077                                 if(cvar("g_maplist_shuffle"))
1078                                         ShuffleMaplist();
1079                                 localcmd("\nmenu_cmd sync\n");
1080                         }
1081                         else
1082                         {
1083                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1084                         }
1085                 }
1086                 Map_Goto();
1087         }
1088 };
1089
1090
1091 /*
1092 ============
1093 IntermissionThink
1094
1095 When the player presses attack or jump, change to the next level
1096 ============
1097 */
1098 .float autoscreenshot;
1099 void() MapVote_Start;
1100 void() MapVote_Think;
1101 float mapvote_initialized;
1102 void IntermissionThink()
1103 {
1104         FixIntermissionClient(self);
1105
1106         if(cvar("sv_autoscreenshot"))
1107         if(self.autoscreenshot > 0)
1108         if(time > self.autoscreenshot)
1109         {
1110                 self.autoscreenshot = -1;
1111                 if(clienttype(self) == CLIENTTYPE_REAL)
1112                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1113                 return;
1114         }
1115
1116         if (time < intermission_exittime)
1117                 return;
1118
1119         if(!mapvote_initialized)
1120                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1121                         return;
1122
1123         MapVote_Start();
1124 };
1125
1126 /*
1127 ============
1128 FindIntermission
1129
1130 Returns the entity to view from
1131 ============
1132 */
1133 /*
1134 entity FindIntermission()
1135 {
1136         local   entity spot;
1137         local   float cyc;
1138
1139 // look for info_intermission first
1140         spot = find (world, classname, "info_intermission");
1141         if (spot)
1142         {       // pick a random one
1143                 cyc = random() * 4;
1144                 while (cyc > 1)
1145                 {
1146                         spot = find (spot, classname, "info_intermission");
1147                         if (!spot)
1148                                 spot = find (spot, classname, "info_intermission");
1149                         cyc = cyc - 1;
1150                 }
1151                 return spot;
1152         }
1153
1154 // then look for the start position
1155         spot = find (world, classname, "info_player_start");
1156         if (spot)
1157                 return spot;
1158
1159 // testinfo_player_start is only found in regioned levels
1160         spot = find (world, classname, "testplayerstart");
1161         if (spot)
1162                 return spot;
1163
1164 // then look for the start position
1165         spot = find (world, classname, "info_player_deathmatch");
1166         if (spot)
1167                 return spot;
1168
1169         //objerror ("FindIntermission: no spot");
1170         return world;
1171 };
1172 */
1173
1174 /*
1175 ===============================================================================
1176
1177 RULES
1178
1179 ===============================================================================
1180 */
1181
1182 void DumpStats(float final)
1183 {
1184         local float file;
1185         local string s;
1186         local float to_console;
1187         local float to_eventlog;
1188         local float to_file;
1189         local float i;
1190
1191         to_console = cvar("sv_logscores_console");
1192         to_eventlog = cvar("sv_eventlog");
1193         to_file = cvar("sv_logscores_file");
1194
1195         if(!final)
1196         {
1197                 to_console = TRUE; // always print printstats replies
1198                 to_eventlog = FALSE; // but never print them to the event log
1199         }
1200
1201         if(to_eventlog)
1202                 if(cvar("sv_eventlog_console"))
1203                         to_console = FALSE; // otherwise we get the output twice
1204
1205         if(final)
1206                 s = ":scores:";
1207         else
1208                 s = ":status:";
1209         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1210
1211         if(to_console)
1212                 print(s, "\n");
1213         if(to_eventlog)
1214                 GameLogEcho(s);
1215         if(to_file)
1216         {
1217                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1218                 if(file == -1)
1219                         to_file = FALSE;
1220                 else
1221                         fputs(file, strcat(s, "\n"));
1222         }
1223
1224         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1225         if(to_console)
1226                 print(s, "\n");
1227         if(to_eventlog)
1228                 GameLogEcho(s);
1229         if(to_file)
1230                 fputs(file, strcat(s, "\n"));
1231
1232         FOR_EACH_CLIENT(other)
1233         {
1234                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1235                 {
1236                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1237                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1238                         if(other.classname == "player" || g_arena || g_ca || g_lms)
1239                                 s = strcat(s, ftos(other.team), ":");
1240                         else
1241                                 s = strcat(s, "spectator:");
1242
1243                         if(to_console)
1244                                 print(s, other.netname, "\n");
1245                         if(to_eventlog)
1246                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1247                         if(to_file)
1248                                 fputs(file, strcat(s, other.netname, "\n"));
1249                 }
1250         }
1251
1252         if(teams_matter)
1253         {
1254                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1255                 if(to_console)
1256                         print(s, "\n");
1257                 if(to_eventlog)
1258                         GameLogEcho(s);
1259                 if(to_file)
1260                         fputs(file, strcat(s, "\n"));
1261
1262                 for(i = 1; i < 16; ++i)
1263                 {
1264                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1265                         s = strcat(s, ":", ftos(i));
1266                         if(to_console)
1267                                 print(s, "\n");
1268                         if(to_eventlog)
1269                                 GameLogEcho(s);
1270                         if(to_file)
1271                                 fputs(file, strcat(s, "\n"));
1272                 }
1273         }
1274
1275         if(to_console)
1276                 print(":end\n");
1277         if(to_eventlog)
1278                 GameLogEcho(":end");
1279         if(to_file)
1280         {
1281                 fputs(file, ":end\n");
1282                 fclose(file);
1283         }
1284 }
1285
1286 void FixIntermissionClient(entity e)
1287 {
1288         string s;
1289         if(!e.autoscreenshot) // initial call
1290         {
1291                 e.angles = e.v_angle;
1292                 e.angles_x = -e.angles_x;
1293                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1294                 e.health = -2342;
1295                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1296                 e.solid = SOLID_NOT;
1297                 e.movetype = MOVETYPE_NONE;
1298                 e.takedamage = DAMAGE_NO;
1299                 if(e.weaponentity)
1300                 {
1301                         e.weaponentity.effects = EF_NODRAW;
1302                         if (e.weaponentity.weaponentity)
1303                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1304                 }
1305                 if(clienttype(e) == CLIENTTYPE_REAL)
1306                 {
1307                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1308                         s = cvar_string("sv_intermission_cdtrack");
1309                         if(s != "")
1310                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1311                         msg_entity = e;
1312                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1313                 }
1314         }
1315
1316         //e.velocity = '0 0 0';
1317         //e.fixangle = TRUE;
1318
1319         // TODO halt weapon animation
1320 }
1321
1322
1323 /*
1324 go to the next level for deathmatch
1325 only called if a time or frag limit has expired
1326 */
1327 void NextLevel()
1328 {
1329         float i;
1330
1331         gameover = TRUE;
1332
1333         intermission_running = 1;
1334
1335 // enforce a wait time before allowing changelevel
1336         if(player_count > 0)
1337                 intermission_exittime = time + cvar("sv_mapchange_delay");
1338         else
1339                 intermission_exittime = -1;
1340
1341         /*
1342         WriteByte (MSG_ALL, SVC_CDTRACK);
1343         WriteByte (MSG_ALL, 3);
1344         WriteByte (MSG_ALL, 3);
1345         // done in FixIntermission
1346         */
1347
1348         //pos = FindIntermission ();
1349
1350         VoteReset();
1351
1352         DumpStats(TRUE);
1353
1354         if(cvar("sv_eventlog"))
1355                 GameLogEcho(":gameover");
1356
1357         GameLogClose();
1358
1359 // TO DO
1360
1361 // save the stats to a text file on the client
1362 // stuffcmd(other, log_stats "stats/file_name");
1363 // bprint stats
1364 // stuffcmd(other, log_stats "");
1365 // use a filename similar to the demo name
1366         // string file_name;
1367         // file_name = strcat("\nlog_file \"stats/", strftime(TRUE, "%Y-%m-%d_%H-%M"), "_", mapname, ".txt\"");  // open the log file
1368
1369 // write a stats parser for the menu
1370
1371         if(cvar("sv_accuracy_data_send")) {
1372                 string stats_to_send;
1373
1374                 FOR_EACH_CLIENT(other) {  // make the string to send
1375                         FixIntermissionClient(other);
1376
1377                         if(other.cvar_cl_accuracy_data_share) {
1378                                 stats_to_send = strcat(stats_to_send, ":hits:", other.netname);
1379
1380                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1381                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_hit[i-1]));
1382
1383                                 stats_to_send = strcat(stats_to_send, "\n:fired:", other.netname);
1384
1385                                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
1386                                         stats_to_send = strcat(stats_to_send, ":", ftos(other.stats_fired[i-1]));
1387
1388                                 stats_to_send = strcat(stats_to_send, "\n");
1389                         }
1390                 }
1391
1392                 FOR_EACH_REALCLIENT(other) {  // only spam humans
1393                         Score_NicePrint(other);  // print the score
1394
1395                         if(other.cvar_cl_accuracy_data_receive)  // send the stats string to all the willing clients
1396                                 bprint(stats_to_send);
1397                 }
1398         } else { // ye olde message
1399                 FOR_EACH_PLAYER(other) {
1400                         FixIntermissionClient(other);
1401
1402                         if(other.winning)
1403                                 bprint(other.netname, " ^7wins.\n");
1404                 }
1405         }
1406
1407         if(cvar("g_campaign"))
1408                 CampaignPreIntermission();
1409
1410         localcmd("\nsv_hook_gameend;");
1411 }
1412
1413 /*
1414 ============
1415 CheckRules_Player
1416
1417 Exit deathmatch games upon conditions
1418 ============
1419 */
1420 void CheckRules_Player()
1421 {
1422         if (gameover)   // someone else quit the game already
1423                 return;
1424
1425         if(self.deadflag == DEAD_NO)
1426                 self.play_time += frametime;
1427
1428         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1429         //   (div0: and that in CheckRules_World please)
1430 };
1431
1432 float checkrules_equality;
1433 float checkrules_suddendeathwarning;
1434 float checkrules_suddendeathend;
1435 float checkrules_overtimesadded; //how many overtimes have been already added
1436
1437 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1438 float WINNING_YES = 1; // winner found
1439 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1440 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1441
1442 float InitiateSuddenDeath()
1443 {
1444         // Check first whether normal overtimes could be added before initiating suddendeath mode
1445         // - for this timelimit_overtime needs to be >0 of course
1446         // - also check the winning condition calculated in the previous frame and only add normal overtime
1447         //   again, if at the point at which timelimit would be extended again, still no winner was found
1448         if ((checkrules_overtimesadded >= 0) && (checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && !(g_race && !g_race_qualifying))
1449         {
1450                 return 1; // need to call InitiateOvertime later
1451         }
1452         else
1453         {
1454                 if(!checkrules_suddendeathend)
1455                 {
1456                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1457                         if(g_race && !g_race_qualifying)
1458                                 race_StartCompleting();
1459                 }
1460                 return 0;
1461         }
1462 }
1463
1464 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1465 {
1466         ++checkrules_overtimesadded;
1467         //add one more overtime by simply extending the timelimit
1468         float tl;
1469         tl = cvar("timelimit");
1470         tl += cvar("timelimit_overtime");
1471         cvar_set("timelimit", ftos(tl));
1472         string minutesPlural;
1473         if (cvar("timelimit_overtime") == 1)
1474                 minutesPlural = " ^3minute";
1475         else
1476                 minutesPlural = " ^3minutes";
1477
1478         bcenterprint(
1479                 strcat(
1480                         "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1481                         ftos(cvar("timelimit_overtime")),
1482                         minutesPlural,
1483                         " to the game!"
1484                 )
1485         );
1486 }
1487
1488 float GetWinningCode(float fraglimitreached, float equality)
1489 {
1490         if(equality)
1491                 if(fraglimitreached)
1492                         return WINNING_STARTSUDDENDEATHOVERTIME;
1493                 else
1494                         return WINNING_NEVER;
1495         else
1496                 if(fraglimitreached)
1497                         return WINNING_YES;
1498                 else
1499                         return WINNING_NO;
1500 }
1501
1502 // set the .winning flag for exactly those players with a given field value
1503 void SetWinners(.float field, float value)
1504 {
1505         entity head;
1506         FOR_EACH_PLAYER(head)
1507                 head.winning = (head.field == value);
1508 }
1509
1510 // set the .winning flag for those players with a given field value
1511 void AddWinners(.float field, float value)
1512 {
1513         entity head;
1514         FOR_EACH_PLAYER(head)
1515                 if(head.field == value)
1516                         head.winning = 1;
1517 }
1518
1519 // clear the .winning flags
1520 void ClearWinners(void)
1521 {
1522         entity head;
1523         FOR_EACH_PLAYER(head)
1524                 head.winning = 0;
1525 }
1526
1527 // Onslaught winning condition:
1528 // game terminates if only one team has a working generator (or none)
1529 float WinningCondition_Onslaught()
1530 {
1531         entity head;
1532         local float t1, t2, t3, t4;
1533
1534         WinningConditionHelper(); // set worldstatus
1535
1536         if(inWarmupStage)
1537                 return WINNING_NO;
1538
1539         // first check if the game has ended
1540         t1 = t2 = t3 = t4 = 0;
1541         head = find(world, classname, "onslaught_generator");
1542         while (head)
1543         {
1544                 if (head.health > 0)
1545                 {
1546                         if (head.team == COLOR_TEAM1) t1 = 1;
1547                         if (head.team == COLOR_TEAM2) t2 = 1;
1548                         if (head.team == COLOR_TEAM3) t3 = 1;
1549                         if (head.team == COLOR_TEAM4) t4 = 1;
1550                 }
1551                 head = find(head, classname, "onslaught_generator");
1552         }
1553         if (t1 + t2 + t3 + t4 < 2)
1554         {
1555                 // game over, only one team remains (or none)
1556                 ClearWinners();
1557                 if (t1) SetWinners(team, COLOR_TEAM1);
1558                 if (t2) SetWinners(team, COLOR_TEAM2);
1559                 if (t3) SetWinners(team, COLOR_TEAM3);
1560                 if (t4) SetWinners(team, COLOR_TEAM4);
1561                 dprint("Have a winner, ending game.\n");
1562                 return WINNING_YES;
1563         }
1564
1565         // Two or more teams remain
1566         return WINNING_NO;
1567 }
1568
1569 float LMS_NewPlayerLives()
1570 {
1571         float fl;
1572         fl = cvar("fraglimit");
1573         if(fl == 0)
1574                 fl = 999;
1575
1576         // first player has left the game for dying too much? Nobody else can get in.
1577         if(lms_lowest_lives < 1)
1578                 return 0;
1579
1580         if(!cvar("g_lms_join_anytime"))
1581                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1582                         return 0;
1583
1584         return bound(1, lms_lowest_lives, fl);
1585 }
1586
1587 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1588 // they win. Otherwise the defending team wins once the timelimit passes.
1589 void assault_new_round();
1590 float WinningCondition_Assault()
1591 {
1592         local float status;
1593
1594         WinningConditionHelper(); // set worldstatus
1595
1596         status = WINNING_NO;
1597         // as the timelimit has not yet passed just assume the defending team will win
1598         if(assault_attacker_team == COLOR_TEAM1)
1599         {
1600                 SetWinners(team, COLOR_TEAM2);
1601         }
1602         else
1603         {
1604                 SetWinners(team, COLOR_TEAM1);
1605         }
1606
1607         local entity ent;
1608         ent = find(world, classname, "target_assault_roundend");
1609         if(ent)
1610         {
1611                 if(ent.winning) // round end has been triggered by attacking team
1612                 {
1613                         bprint("ASSAULT: round completed...\n");
1614                         SetWinners(team, assault_attacker_team);
1615
1616                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1617
1618                         if(ent.cnt == 1) // this was the second round
1619                         {
1620                                 status = WINNING_YES;
1621                         }
1622                         else
1623                         {
1624                                 local entity oldself;
1625                                 oldself = self;
1626                                 self = ent;
1627                                 assault_new_round();
1628                                 self = oldself;
1629                         }
1630                 }
1631         }
1632
1633         return status;
1634 }
1635
1636 // LMS winning condition: game terminates if and only if there's at most one
1637 // one player who's living lives. Top two scores being equal cancels the time
1638 // limit.
1639 float WinningCondition_LMS()
1640 {
1641         entity head, head2;
1642         float have_player;
1643         float have_players;
1644         float l;
1645
1646         have_player = FALSE;
1647         have_players = FALSE;
1648         l = LMS_NewPlayerLives();
1649
1650         head = find(world, classname, "player");
1651         if(head)
1652                 have_player = TRUE;
1653         head2 = find(head, classname, "player");
1654         if(head2)
1655                 have_players = TRUE;
1656
1657         if(have_player)
1658         {
1659                 // we have at least one player
1660                 if(have_players)
1661                 {
1662                         // two or more active players - continue with the game
1663                 }
1664                 else
1665                 {
1666                         // exactly one player?
1667
1668                         ClearWinners();
1669                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1670
1671                         if(l)
1672                         {
1673                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1674                                 return WINNING_NO;
1675                         }
1676                         else
1677                         {
1678                                 // a winner!
1679                                 // and assign him his first place
1680                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1681                                 return WINNING_YES;
1682                         }
1683                 }
1684         }
1685         else
1686         {
1687                 // nobody is playing at all...
1688                 if(l)
1689                 {
1690                         // wait for players...
1691                 }
1692                 else
1693                 {
1694                         // SNAFU (maybe a draw game?)
1695                         ClearWinners();
1696                         dprint("No players, ending game.\n");
1697                         return WINNING_YES;
1698                 }
1699         }
1700
1701         // When we get here, we have at least two players who are actually LIVING,
1702         // now check if the top two players have equal score.
1703         WinningConditionHelper();
1704
1705         ClearWinners();
1706         if(WinningConditionHelper_winner)
1707                 WinningConditionHelper_winner.winning = TRUE;
1708         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1709                 return WINNING_NEVER;
1710
1711         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1712         return WINNING_NO;
1713 }
1714
1715 void ShuffleMaplist()
1716 {
1717         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1718 }
1719
1720 float leaderfrags;
1721 float WinningCondition_Scores(float limit, float leadlimit)
1722 {
1723         // TODO make everything use THIS winning condition (except LMS)
1724         WinningConditionHelper();
1725
1726         if(teams_matter)
1727         {
1728                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1729                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1730                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1731                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1732         }
1733
1734         ClearWinners();
1735         if(WinningConditionHelper_winner)
1736                 WinningConditionHelper_winner.winning = 1;
1737         if(WinningConditionHelper_winnerteam >= 0)
1738                 SetWinners(team, WinningConditionHelper_winnerteam);
1739
1740         if(WinningConditionHelper_lowerisbetter)
1741         {
1742                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1743                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1744                 limit = -limit;
1745         }
1746
1747         if(WinningConditionHelper_zeroisworst)
1748                 leadlimit = 0; // not supported in this mode
1749
1750         if(g_dm || g_tdm || g_arena || g_ca || (g_race && !g_race_qualifying) || g_nexball)
1751         // these modes always score in increments of 1, thus this makes sense
1752         {
1753                 if(leaderfrags != WinningConditionHelper_topscore)
1754                 {
1755                         leaderfrags = WinningConditionHelper_topscore;
1756
1757                         if (limit)
1758                         if (leaderfrags == limit - 1)
1759                                 play2all("announcer/robotic/1fragleft.wav");
1760                         else if (leaderfrags == limit - 2)
1761                                 play2all("announcer/robotic/2fragsleft.wav");
1762                         else if (leaderfrags == limit - 3)
1763                                 play2all("announcer/robotic/3fragsleft.wav");
1764                 }
1765         }
1766
1767         return GetWinningCode(
1768                 WinningConditionHelper_topscore &&
1769                 (
1770                         (limit && (WinningConditionHelper_topscore >= limit))
1771                         ||
1772                         (leadlimit && (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit))
1773                 ),
1774                 WinningConditionHelper_equality
1775         );
1776 }
1777
1778 float WinningCondition_Race(float fraglimit)
1779 {
1780         float wc;
1781         entity p;
1782         float n, c;
1783
1784         n = 0;
1785         c = 0;
1786         FOR_EACH_PLAYER(p)
1787         {
1788                 ++n;
1789                 if(p.race_completed)
1790                         ++c;
1791         }
1792         if(n && (n == c))
1793                 return WINNING_YES;
1794         wc = WinningCondition_Scores(fraglimit, 0);
1795
1796         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1797         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1798         // do NOT support equality when the laps are all raced!
1799                 return WINNING_STARTSUDDENDEATHOVERTIME;
1800         else
1801                 return WINNING_NEVER;
1802         return wc;
1803 }
1804
1805 void ReadyRestart();
1806 float WinningCondition_QualifyingThenRace(float limit)
1807 {
1808         float wc;
1809         wc = WinningCondition_Scores(limit, 0);
1810
1811         // NEVER initiate overtime
1812         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1813         {
1814                 return WINNING_YES;
1815         }
1816
1817         return wc;
1818 }
1819
1820 float WinningCondition_RanOutOfSpawns()
1821 {
1822         entity head;
1823
1824         if(have_team_spawns <= 0)
1825                 return WINNING_NO;
1826
1827         if(!some_spawn_has_been_used)
1828                 return WINNING_NO;
1829
1830         team1_score = team2_score = team3_score = team4_score = 0;
1831
1832         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1833         {
1834                 if(head.team == COLOR_TEAM1)
1835                         team1_score = 1;
1836                 else if(head.team == COLOR_TEAM2)
1837                         team2_score = 1;
1838                 else if(head.team == COLOR_TEAM3)
1839                         team3_score = 1;
1840                 else if(head.team == COLOR_TEAM4)
1841                         team4_score = 1;
1842         }
1843
1844         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1845         {
1846                 if(head.team == COLOR_TEAM1)
1847                         team1_score = 1;
1848                 else if(head.team == COLOR_TEAM2)
1849                         team2_score = 1;
1850                 else if(head.team == COLOR_TEAM3)
1851                         team3_score = 1;
1852                 else if(head.team == COLOR_TEAM4)
1853                         team4_score = 1;
1854         }
1855
1856         ClearWinners();
1857         if(team1_score + team2_score + team3_score + team4_score == 0)
1858         {
1859                 checkrules_equality = TRUE;
1860                 return WINNING_YES;
1861         }
1862         else if(team1_score + team2_score + team3_score + team4_score == 1)
1863         {
1864                 float t, i;
1865                 if(team1_score) t = COLOR_TEAM1;
1866                 if(team2_score) t = COLOR_TEAM2;
1867                 if(team3_score) t = COLOR_TEAM3;
1868                 if(team4_score) t = COLOR_TEAM4;
1869                 CheckAllowedTeams(world);
1870                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1871                 {
1872                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1873                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1874                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1875                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1876                 }
1877
1878                 AddWinners(team, t);
1879                 return WINNING_YES;
1880         }
1881         else
1882                 return WINNING_NO;
1883 }
1884
1885 /*
1886 ============
1887 CheckRules_World
1888
1889 Exit deathmatch games upon conditions
1890 ============
1891 */
1892 void CheckRules_World()
1893 {
1894         float timelimit;
1895         float fraglimit;
1896         float leadlimit;
1897
1898         VoteThink();
1899         MapVote_Think();
1900
1901         SetDefaultAlpha();
1902
1903         /*
1904         MapVote_Think should now do that part
1905         if (intermission_running)
1906                 if (time >= intermission_exittime + 60)
1907                 {
1908                         if(!DoNextMapOverride())
1909                                 GotoNextMap();
1910                         return;
1911                 }
1912         */
1913
1914         if (gameover)   // someone else quit the game already
1915         {
1916                 if(player_count == 0) // Nobody there? Then let's go to the next map
1917                         MapVote_Start();
1918                         // this will actually check the player count in the next frame
1919                         // again, but this shouldn't hurt
1920                 return;
1921         }
1922
1923         timelimit = cvar("timelimit") * 60;
1924         fraglimit = cvar("fraglimit");
1925         leadlimit = cvar("leadlimit");
1926
1927         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1928         {
1929                 if(timelimit > 0)
1930                         timelimit = 0; // timelimit is not made for warmup
1931                 if(fraglimit > 0)
1932                         fraglimit = 0; // no fraglimit for now
1933                 leadlimit = 0; // no leadlimit for now
1934         }
1935
1936         if(g_onslaught)
1937                 timelimit = 0; // ONS has its own overtime rule
1938
1939         if(timelimit > 0)
1940         {
1941                 timelimit += game_starttime;
1942         }
1943         else if (timelimit < 0)
1944         {
1945                 // endmatch
1946                 NextLevel();
1947                 return;
1948         }
1949
1950         float wantovertime;
1951         wantovertime = 0;
1952
1953         if(checkrules_suddendeathend)
1954         {
1955                 if(!checkrules_suddendeathwarning)
1956                 {
1957                         checkrules_suddendeathwarning = TRUE;
1958                         if(g_race && !g_race_qualifying)
1959                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1960                         else
1961                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1962                 }
1963         }
1964         else
1965         {
1966                 if (timelimit && time >= timelimit)
1967                 {
1968                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1969                         {
1970                                 float totalplayers;
1971                                 float playerswithlaps;
1972                                 float readyplayers;
1973                                 entity head;
1974                                 totalplayers = playerswithlaps = readyplayers = 0;
1975                                 FOR_EACH_PLAYER(head)
1976                                 {
1977                                         ++totalplayers;
1978                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1979                                                 ++playerswithlaps;
1980                                         if(head.ready)
1981                                                 ++readyplayers;
1982                                 }
1983
1984                                 // at least 2 of the players have completed a lap: start the RACE
1985                                 // otherwise, the players should end the qualifying on their own
1986                                 if(readyplayers || playerswithlaps >= 2)
1987                                 {
1988                                         checkrules_suddendeathend = 0;
1989                                         ReadyRestart(); // go to race
1990                                         return;
1991                                 }
1992                                 else
1993                                         wantovertime |= InitiateSuddenDeath();
1994                         }
1995                         else
1996                                 wantovertime |= InitiateSuddenDeath();
1997                 }
1998         }
1999
2000         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
2001         {
2002                 NextLevel();
2003                 return;
2004         }
2005
2006         float checkrules_status;
2007         checkrules_status = WinningCondition_RanOutOfSpawns();
2008         if(checkrules_status == WINNING_YES)
2009         {
2010                 bprint("Hey! Someone ran out of spawns!\n");
2011         }
2012         else if(g_race && !g_race_qualifying && timelimit >= 0)
2013         {
2014                 checkrules_status = WinningCondition_Race(fraglimit);
2015                 //print("WC_RACE yields ", ftos(checkrules_status), "\n");
2016         }
2017         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
2018         {
2019                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
2020                 //print("WC_QUALIFYING_THEN_RACE yields ", ftos(checkrules_status), "\n");
2021         }
2022         else if(g_assault)
2023         {
2024                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
2025         }
2026         else if(g_lms)
2027         {
2028                 checkrules_status = WinningCondition_LMS();
2029         }
2030         else if (g_onslaught)
2031         {
2032                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
2033         }
2034         else
2035         {
2036                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
2037                 //print("WC_SCORES yields ", ftos(checkrules_status), "\n");
2038         }
2039
2040         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
2041         {
2042                 checkrules_status = WINNING_NEVER;
2043                 checkrules_overtimesadded = -1;
2044                 wantovertime |= InitiateSuddenDeath();
2045         }
2046
2047         if(checkrules_status == WINNING_NEVER)
2048                 // equality cases! Nobody wins if the overtime ends in a draw.
2049                 ClearWinners();
2050
2051         if(wantovertime)
2052         {
2053                 if(checkrules_status == WINNING_NEVER)
2054                         InitiateOvertime();
2055                 else
2056                         checkrules_status = WINNING_YES;
2057         }
2058
2059         if(checkrules_suddendeathend)
2060                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
2061                         checkrules_status = WINNING_YES;
2062
2063         if(checkrules_status == WINNING_YES)
2064         {
2065                 //print("WINNING\n");
2066                 NextLevel();
2067         }
2068 };
2069
2070 float mapvote_nextthink;
2071 float mapvote_initialized;
2072 float mapvote_keeptwotime;
2073 float mapvote_timeout;
2074 string mapvote_message;
2075 #define MAPVOTE_SCREENSHOT_DIRS_COUNT 4
2076 string mapvote_screenshot_dirs[MAPVOTE_SCREENSHOT_DIRS_COUNT];
2077 float mapvote_screenshot_dirs_count;
2078
2079 float mapvote_count;
2080 float mapvote_count_real;
2081 string mapvote_maps[MAPVOTE_COUNT];
2082 float mapvote_maps_screenshot_dir[MAPVOTE_COUNT];
2083 string mapvote_maps_pakfile[MAPVOTE_COUNT];
2084 float mapvote_maps_suggested[MAPVOTE_COUNT];
2085 string mapvote_suggestions[MAPVOTE_COUNT];
2086 float mapvote_suggestion_ptr;
2087 float mapvote_maxlen;
2088 float mapvote_voters;
2089 float mapvote_votes[MAPVOTE_COUNT];
2090 float mapvote_run;
2091 float mapvote_detail;
2092 float mapvote_abstain;
2093 .float mapvote;
2094
2095 void MapVote_ClearAllVotes()
2096 {
2097         FOR_EACH_CLIENT(other)
2098                 other.mapvote = 0;
2099 }
2100
2101 string MapVote_Suggest(string m)
2102 {
2103         float i;
2104         if(m == "")
2105                 return "That's not how to use this command.";
2106         if(!cvar("g_maplist_votable_suggestions"))
2107                 return "Suggestions are not accepted on this server.";
2108         if(mapvote_initialized)
2109                 return "Can't suggest - voting is already in progress!";
2110         m = MapInfo_FixName(m);
2111         if(!m)
2112                 return "The map you suggested is not available on this server.";
2113         if(!cvar("g_maplist_votable_suggestions_override_mostrecent"))
2114                 if(Map_IsRecent(m))
2115                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2116
2117         if(!MapInfo_CheckMap(m))
2118                 return "The map you suggested does not support the current game mode.";
2119         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2120                 if(mapvote_suggestions[i] == m)
2121                         return "This map was already suggested.";
2122         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2123         {
2124                 i = floor(random() * mapvote_suggestion_ptr);
2125         }
2126         else
2127         {
2128                 i = mapvote_suggestion_ptr;
2129                 mapvote_suggestion_ptr += 1;
2130         }
2131         if(mapvote_suggestions[i] != "")
2132                 strunzone(mapvote_suggestions[i]);
2133         mapvote_suggestions[i] = strzone(m);
2134         if(cvar("sv_eventlog"))
2135                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2136         return strcat("Suggestion of ", m, " accepted.");
2137 }
2138
2139 void MapVote_AddVotable(string nextMap, float isSuggestion)
2140 {
2141         float j, i, o;
2142         string pakfile, mapfile;
2143
2144         if(nextMap == "")
2145                 return;
2146         for(j = 0; j < mapvote_count; ++j)
2147                 if(mapvote_maps[j] == nextMap)
2148                         return;
2149         if(strlen(nextMap) > mapvote_maxlen)
2150                 mapvote_maxlen = strlen(nextMap);
2151         mapvote_maps[mapvote_count] = strzone(nextMap);
2152         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2153
2154         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2155         {
2156                 mapfile = strcat(mapvote_screenshot_dirs[i], "/", mapvote_maps[i]);
2157                 pakfile = whichpack(strcat(mapfile, ".tga"));
2158                 if(pakfile == "")
2159                         pakfile = whichpack(strcat(mapfile, ".jpg"));
2160                 if(pakfile == "")
2161                         pakfile = whichpack(strcat(mapfile, ".png"));
2162                 if(pakfile != "")
2163                         break;
2164         }
2165         if(i >= mapvote_screenshot_dirs_count)
2166                 i = 0; // FIXME maybe network this error case, as that means there is no mapshot on the server?
2167         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2168                 pakfile = substring(pakfile, o, -1);
2169
2170         mapvote_maps_screenshot_dir[mapvote_count] = i;
2171         mapvote_maps_pakfile[mapvote_count] = strzone(pakfile);
2172
2173         mapvote_count += 1;
2174 }
2175
2176 void MapVote_Spawn();
2177 void MapVote_Init()
2178 {
2179         float i;
2180         float nmax, smax;
2181
2182         MapVote_ClearAllVotes();
2183
2184         mapvote_count = 0;
2185         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2186         mapvote_abstain = cvar("g_maplist_votable_abstain");
2187
2188         if(mapvote_abstain)
2189                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2190         else
2191                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2192         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2193
2194         // we need this for AddVotable, as that cycles through the screenshot dirs
2195         mapvote_screenshot_dirs_count = tokenize_console(cvar_string("g_maplist_votable_screenshot_dir"));
2196         if(mapvote_screenshot_dirs_count == 0)
2197                 mapvote_screenshot_dirs_count = tokenize_console("maps levelshots");
2198         mapvote_screenshot_dirs_count = min(mapvote_screenshot_dirs_count, MAPVOTE_SCREENSHOT_DIRS_COUNT);
2199         for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2200                 mapvote_screenshot_dirs[i] = strzone(argv(i));
2201
2202         if(mapvote_suggestion_ptr)
2203                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2204                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2205
2206         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2207                 MapVote_AddVotable(GetNextMap(), FALSE);
2208
2209         if(mapvote_count == 0)
2210         {
2211                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2212                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags()));
2213                 if(cvar("g_maplist_shuffle"))
2214                         ShuffleMaplist();
2215                 localcmd("\nmenu_cmd sync\n");
2216                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2217                         MapVote_AddVotable(GetNextMap(), FALSE);
2218         }
2219
2220         mapvote_count_real = mapvote_count;
2221         if(mapvote_abstain)
2222                 MapVote_AddVotable("don't care", 0);
2223
2224         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2225
2226         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2227         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2228         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2229                 mapvote_keeptwotime = 0;
2230         mapvote_message = "Choose a map and press its key!";
2231
2232         MapVote_Spawn();
2233 }
2234
2235 void MapVote_SendPicture(float id)
2236 {
2237         msg_entity = self;
2238         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2239         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2240         WriteByte(MSG_ONE, id);
2241         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dirs[mapvote_maps_screenshot_dir[id]], "/", mapvote_maps[id]), 3072);
2242 }
2243
2244 float GameCommand_MapVote(string cmd)
2245 {
2246         if(!intermission_running)
2247                 return FALSE;
2248
2249         if(cmd == "mv_getpic")
2250         {
2251                 MapVote_SendPicture(stof(argv(1)));
2252                 return TRUE;
2253         }
2254
2255         return FALSE;
2256 }
2257
2258 float MapVote_GetMapMask()
2259 {
2260         float mask, i, power;
2261         mask = 0;
2262         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2263                 if(mapvote_maps[i] != "")
2264                         mask |= power;
2265         return mask;
2266 }
2267
2268 entity mapvote_ent;
2269 float MapVote_SendEntity(entity to, float sf)
2270 {
2271         float i;
2272
2273         if(sf & 1)
2274                 sf &~= 2; // if we send 1, we don't need to also send 2
2275
2276         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2277         WriteByte(MSG_ENTITY, sf);
2278
2279         if(sf & 1)
2280         {
2281                 // flag 1 == initialization
2282                 for(i = 0; i < mapvote_screenshot_dirs_count; ++i)
2283                         WriteString(MSG_ENTITY, mapvote_screenshot_dirs[i]);
2284                 WriteString(MSG_ENTITY, "");
2285                 WriteByte(MSG_ENTITY, mapvote_count);
2286                 WriteByte(MSG_ENTITY, mapvote_abstain);
2287                 WriteByte(MSG_ENTITY, mapvote_detail);
2288                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2289                 if(mapvote_count <= 8)
2290                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2291                 else
2292                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2293                 for(i = 0; i < mapvote_count; ++i)
2294                         if(mapvote_maps[i] != "")
2295                         {
2296                                 if(mapvote_abstain && i == mapvote_count - 1)
2297                                 {
2298                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2299                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2300                                         WriteByte(MSG_ENTITY, 0); // abstain needs no screenshot dir
2301                                 }
2302                                 else
2303                                 {
2304                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2305                                         WriteString(MSG_ENTITY, mapvote_maps_pakfile[i]);
2306                                         WriteByte(MSG_ENTITY, mapvote_maps_screenshot_dir[i]);
2307                                 }
2308                         }
2309         }
2310
2311         if(sf & 2)
2312         {
2313                 // flag 2 == update of mask
2314                 if(mapvote_count <= 8)
2315                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2316                 else
2317                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2318         }
2319
2320         if(sf & 4)
2321         {
2322                 if(mapvote_detail)
2323                         for(i = 0; i < mapvote_count; ++i)
2324                                 if(mapvote_maps[i] != "")
2325                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2326
2327                 WriteByte(MSG_ENTITY, to.mapvote);
2328         }
2329
2330         return TRUE;
2331 }
2332
2333 void MapVote_Spawn()
2334 {
2335         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2336 }
2337
2338 void MapVote_TouchMask()
2339 {
2340         mapvote_ent.SendFlags |= 2;
2341 }
2342
2343 void MapVote_TouchVotes(entity voter)
2344 {
2345         mapvote_ent.SendFlags |= 4;
2346 }
2347
2348 float MapVote_Finished(float mappos)
2349 {
2350         string result;
2351         float i;
2352         float didntvote;
2353
2354         if(cvar("sv_eventlog"))
2355         {
2356                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2357                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2358                 didntvote = mapvote_voters;
2359                 for(i = 0; i < mapvote_count; ++i)
2360                         if(mapvote_maps[i] != "")
2361                         {
2362                                 didntvote -= mapvote_votes[i];
2363                                 if(i != mappos)
2364                                 {
2365                                         result = strcat(result, ":", mapvote_maps[i]);
2366                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2367                                 }
2368                         }
2369                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2370
2371                 GameLogEcho(result);
2372                 if(mapvote_maps_suggested[mappos])
2373                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2374         }
2375
2376         FOR_EACH_REALCLIENT(other)
2377                 FixClientCvars(other);
2378
2379         Map_Goto_SetStr(mapvote_maps[mappos]);
2380         Map_Goto();
2381         alreadychangedlevel = TRUE;
2382         return TRUE;
2383 }
2384 void MapVote_CheckRules_1()
2385 {
2386         float i;
2387
2388         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2389         {
2390                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2391                 mapvote_votes[i] = 0;
2392         }
2393
2394         mapvote_voters = 0;
2395         FOR_EACH_REALCLIENT(other)
2396         {
2397                 ++mapvote_voters;
2398                 if(other.mapvote)
2399                 {
2400                         i = other.mapvote - 1;
2401                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2402                         mapvote_votes[i] = mapvote_votes[i] + 1;
2403                 }
2404         }
2405 }
2406
2407 float MapVote_CheckRules_2()
2408 {
2409         float i;
2410         float firstPlace, secondPlace;
2411         float firstPlaceVotes, secondPlaceVotes;
2412         float mapvote_voters_real;
2413         string result;
2414
2415         if(mapvote_count_real == 1)
2416                 return MapVote_Finished(0);
2417
2418         mapvote_voters_real = mapvote_voters;
2419         if(mapvote_abstain)
2420                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2421
2422         RandomSelection_Init();
2423         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2424                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2425         firstPlace = RandomSelection_chosen_float;
2426         firstPlaceVotes = RandomSelection_best_priority;
2427         //dprint("First place: ", ftos(firstPlace), "\n");
2428         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2429
2430         RandomSelection_Init();
2431         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2432                 if(i != firstPlace)
2433                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2434         secondPlace = RandomSelection_chosen_float;
2435         secondPlaceVotes = RandomSelection_best_priority;
2436         //dprint("Second place: ", ftos(secondPlace), "\n");
2437         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2438
2439         if(firstPlace == -1)
2440                 error("No first place in map vote... WTF?");
2441
2442         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2443                 return MapVote_Finished(firstPlace);
2444
2445         if(mapvote_keeptwotime)
2446                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2447                 {
2448                         float didntvote;
2449                         MapVote_TouchMask();
2450                         mapvote_message = "Now decide between the TOP TWO!";
2451                         mapvote_keeptwotime = 0;
2452                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2453                         result = strcat(result, ":", ftos(firstPlaceVotes));
2454                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2455                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2456                         didntvote = mapvote_voters;
2457                         for(i = 0; i < mapvote_count; ++i)
2458                                 if(mapvote_maps[i] != "")
2459                                 {
2460                                         didntvote -= mapvote_votes[i];
2461                                         if(i != firstPlace)
2462                                                 if(i != secondPlace)
2463                                                 {
2464                                                         result = strcat(result, ":", mapvote_maps[i]);
2465                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2466                                                         if(i < mapvote_count_real)
2467                                                         {
2468                                                                 strunzone(mapvote_maps[i]);
2469                                                                 mapvote_maps[i] = "";
2470                                                                 strunzone(mapvote_maps_pakfile[i]);
2471                                                                 mapvote_maps_pakfile[i] = "";
2472                                                         }
2473                                                 }
2474                                 }
2475                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2476                         if(cvar("sv_eventlog"))
2477                                 GameLogEcho(result);
2478                 }
2479
2480         return FALSE;
2481 }
2482 void MapVote_Tick()
2483 {
2484         float keeptwo;
2485         float totalvotes;
2486
2487         keeptwo = mapvote_keeptwotime;
2488         MapVote_CheckRules_1(); // count
2489         if(MapVote_CheckRules_2()) // decide
2490                 return;
2491
2492         totalvotes = 0;
2493         FOR_EACH_REALCLIENT(other)
2494         {
2495                 // hide scoreboard again
2496                 if(other.health != 2342)
2497                 {
2498                         other.health = 2342;
2499                         other.impulse = 0;
2500                         if(clienttype(other) == CLIENTTYPE_REAL)
2501                         {
2502                                 msg_entity = other;
2503                                 WriteByte(MSG_ONE, SVC_FINALE);
2504                                 WriteString(MSG_ONE, "");
2505                         }
2506                 }
2507
2508                 // clear possibly invalid votes
2509                 if(mapvote_maps[other.mapvote - 1] == "")
2510                         other.mapvote = 0;
2511                 // use impulses as new vote
2512                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2513                         if(mapvote_maps[other.impulse - 1] != "")
2514                         {
2515                                 other.mapvote = other.impulse;
2516                                 MapVote_TouchVotes(other);
2517                         }
2518                 other.impulse = 0;
2519
2520                 if(other.mapvote)
2521                         ++totalvotes;
2522         }
2523
2524         MapVote_CheckRules_1(); // just count
2525 }
2526 void MapVote_Start()
2527 {
2528         if(mapvote_run)
2529                 return;
2530
2531         MapInfo_Enumerate();
2532         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2533                 mapvote_run = TRUE;
2534 }
2535 void MapVote_Think()
2536 {
2537         if(!mapvote_run)
2538                 return;
2539
2540         if(alreadychangedlevel)
2541                 return;
2542
2543         if(time < mapvote_nextthink)
2544                 return;
2545         //dprint("tick\n");
2546
2547         mapvote_nextthink = time + 0.5;
2548
2549         if(!mapvote_initialized)
2550         {
2551                 if(cvar("rescan_pending") == 1)
2552                 {
2553                         cvar_set("rescan_pending", "2");
2554                         localcmd("fs_rescan\nrescan_pending 3\n");
2555                         return;
2556                 }
2557                 else if(cvar("rescan_pending") == 2)
2558                 {
2559                         return;
2560                 }
2561                 else if(cvar("rescan_pending") == 3)
2562                 {
2563                         // now build missing mapinfo files
2564                         if(!MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1))
2565                                 return;
2566
2567                         // we're done, start the timer
2568                         cvar_set("rescan_pending", "0");
2569                 }
2570
2571                 mapvote_initialized = TRUE;
2572                 if(DoNextMapOverride())
2573                         return;
2574                 if(!cvar("g_maplist_votable") || player_count <= 0)
2575                 {
2576                         GotoNextMap();
2577                         return;
2578                 }
2579                 MapVote_Init();
2580         }
2581
2582         MapVote_Tick();
2583 };
2584
2585 string GotoMap(string m)
2586 {
2587         if(!MapInfo_CheckMap(m))
2588                 return "The map you chose is not available on this server.";
2589         cvar_set("nextmap", m);
2590         cvar_set("timelimit", "-1");
2591         if(mapvote_initialized || alreadychangedlevel)
2592         {
2593                 if(DoNextMapOverride())
2594                         return "Map switch initiated.";
2595                 else
2596                         return "Hm... no. For some reason I like THIS map more.";
2597         }
2598         else
2599                 return "Map switch will happen after scoreboard.";
2600 }
2601
2602
2603 void EndFrame()
2604 {
2605         float altime;
2606         FOR_EACH_REALCLIENT(self)
2607         {
2608                 if(self.classname == "spectator")
2609                 {
2610                         if(self.enemy.typehitsound)
2611                                 play2(self, "misc/typehit.wav");
2612                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2613                                 play2(self, "misc/hit.wav");
2614                 }
2615                 else
2616                 {
2617                         if(self.typehitsound)
2618                                 play2(self, "misc/typehit.wav");
2619                         else if(self.hitsound && self.cvar_cl_hitsound)
2620                                 play2(self, "misc/hit.wav");
2621                 }
2622         }
2623         altime = time + frametime * (1 + cvar("g_antilag_nudge"));
2624         // add 1 frametime because after this, engine SV_Physics
2625         // increases time by a frametime and then networks the frame
2626         // add another frametime because client shows everything with
2627         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2628         // needed!
2629         FOR_EACH_CLIENT(self)
2630         {
2631                 self.hitsound = FALSE;
2632                 self.typehitsound = FALSE;
2633                 antilag_record(self, altime);
2634         }
2635 }
2636
2637
2638 /*
2639  * RedirectionThink:
2640  * returns TRUE if redirecting
2641  */
2642 float redirection_timeout;
2643 float redirection_nextthink;
2644 float RedirectionThink()
2645 {
2646         float clients_found;
2647
2648         if(redirection_target == "")
2649                 return FALSE;
2650
2651         if(!redirection_timeout)
2652         {
2653                 cvar_set("sv_public", "-2");
2654                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2655                 if(redirection_target == "self")
2656                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2657                 else
2658                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2659         }
2660
2661         if(time < redirection_nextthink)
2662                 return TRUE;
2663
2664         redirection_nextthink = time + 1;
2665
2666         clients_found = 0;
2667         FOR_EACH_REALCLIENT(self)
2668         {
2669                 print("Redirecting: sending connect command to ", self.netname, "\n");
2670                 if(redirection_target == "self")
2671                         stuffcmd(self, "\ndisconnect; reconnect\n");
2672                 else
2673                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2674                 ++clients_found;
2675         }
2676
2677         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2678
2679         if(time > redirection_timeout || clients_found == 0)
2680                 localcmd("\nwait; wait; wait; quit\n");
2681
2682         return TRUE;
2683 }
2684
2685 void RestoreGame()
2686 {
2687         // Loaded from a save game
2688         // some things then break, so let's work around them...
2689
2690         // Progs DB (capture records)
2691         ServerProgsDB = db_load("server.db");
2692
2693         // Mapinfo
2694         MapInfo_Shutdown();
2695         MapInfo_Enumerate();
2696         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2697         WeaponStats_Init();
2698 }
2699
2700 void SV_Shutdown()
2701 {
2702         if(gameover > 1) // shutting down already?
2703                 return;
2704
2705         gameover = 2; // 2 = server shutting down
2706
2707         if(world_initialized > 0)
2708         {
2709                 world_initialized = 0;
2710                 print("Saving persistent data...\n");
2711                 Ban_SaveBans();
2712                 if(!cheatcount_total)
2713                         db_save(ServerProgsDB, "server.db");
2714                 if(cvar("developer"))
2715                         db_save(TemporaryDB, "server-temp.db");
2716                 CheatShutdown(); // must be after cheatcount check
2717                 db_close(ServerProgsDB);
2718                 db_close(TemporaryDB);
2719                 print("done!\n");
2720                 // tell the bot system the game is ending now
2721                 bot_endgame();
2722
2723                 WeaponStats_Shutdown();
2724                 MapInfo_Shutdown();
2725         }
2726         else if(world_initialized == 0)
2727         {
2728                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2729         }
2730 }