data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 void GotoFirstMap()
 135 {
 136         float n;
 137         if(cvar("_sv_init"))
 138         {
 139                 // cvar_set("_sv_init", "0");
 140                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 141                 // to this "init" map on a dedicated server will cause no permanent
 142                 // harm
 143                 if(cvar("g_maplist_shuffle"))
 144                         ShuffleMaplist();
 145                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 146                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 147
 148                 MapInfo_Enumerate();
 149                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 150
 151                 if(!DoNextMapOverride())
 152                         GotoNextMap();
 153
 154                 return;
 155         }
 156
 157         if(time < 5)
 158         {
 159                 self.nextthink = time;
 160         }
 161         else
 162         {
 163                 self.nextthink = time + 1;
 164                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 165         }
 166 }
 167
 168 void cvar_changes_init()
 169 {
 170         float h;
 171         string k, v, d;
 172         float n, i;
 173
 174         if(cvar_changes)
 175                 strunzone(cvar_changes);
 176         cvar_changes = string_null;
 177
 178         h = buf_create();
 179         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 180         n = buf_getsize(h);
 181
 182         for(i = 0; i < n; ++i)
 183         {
 184                 k = bufstr_get(h, i);
 185
 186 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 187 #define BADCVAR(p) if(k == p) continue
 188                 // internal
 189                 BADPREFIX("csqc_");
 190                 BADPREFIX("cvar_check_");
 191                 BADCVAR("gamecfg");
 192                 BADCVAR("g_configversion");
 193                 BADCVAR("g_maplist_index");
 194                 BADCVAR("halflifebsp");
 195
 196                 // client
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("g_campaign");
 200                 BADPREFIX("gl_");
 201                 BADPREFIX("joy");
 202                 BADPREFIX("menu_");
 203                 BADPREFIX("net_slist_");
 204                 BADPREFIX("r_");
 205                 BADPREFIX("sbar_");
 206                 BADPREFIX("scr_");
 207                 BADPREFIX("userbind");
 208                 BADPREFIX("v_");
 209                 BADPREFIX("vid_");
 210                 BADPREFIX("crosshair");
 211                 BADCVAR("mod_q3bsp_lightmapmergepower");
 212                 BADCVAR("mod_q3bsp_nolightmaps");
 213
 214                 // private
 215                 BADPREFIX("g_ban_");
 216                 BADPREFIX("g_chat_flood_");
 217                 BADPREFIX("g_voice_flood_");
 218                 BADPREFIX("rcon_");
 219                 BADPREFIX("settemp_");
 220                 BADPREFIX("sv_allowdownloads_");
 221                 BADPREFIX("sv_autodemo");
 222                 BADPREFIX("sv_curl_");
 223                 BADPREFIX("sv_eventlog");
 224                 BADPREFIX("sv_logscores_");
 225                 BADPREFIX("sv_master");
 226                 BADCVAR("g_banned_list");
 227                 BADCVAR("log_dest_udp");
 228                 BADCVAR("log_file");
 229                 BADCVAR("net_address");
 230                 BADCVAR("port");
 231                 BADCVAR("savedgamecfg");
 232                 BADCVAR("sv_heartbeatperoid");
 233                 BADCVAR("sv_vote_master_password");
 234                 BADCVAR("sys_colortranslation");
 235                 BADCVAR("sys_specialcharactertranslation");
 236                 BADCVAR("timestamps");
 237
 238                 // mapinfo
 239                 BADCVAR("timelimit");
 240                 BADCVAR("fraglimit");
 241                 BADCVAR("g_arena");
 242                 BADCVAR("g_assault");
 243                 BADCVAR("g_ctf");
 244                 BADCVAR("g_dm");
 245                 BADCVAR("g_domination");
 246                 BADCVAR("g_keyhunt");
 247                 BADCVAR("g_keyhunt_teams");
 248                 BADCVAR("g_onslaught");
 249                 BADCVAR("g_race");
 250                 BADCVAR("g_runematch");
 251                 BADCVAR("g_tdm");
 252                 BADCVAR("teamplay");
 253
 254                 // long
 255                 BADCVAR("hostname");
 256                 BADCVAR("g_maplist");
 257                 BADCVAR("g_maplist_mostrecent");
 258                 BADCVAR("sv_motd");
 259 #undef BADPREFIX
 260 #undef BADCVAR
 261
 262                 v = cvar_string(k);
 263                 d = cvar_defstring(k);
 264                 if(v != d)
 265                 {
 266                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 267                         if(strlen(cvar_changes) > 16384)
 268                         {
 269                                 cvar_changes = "// too many settings have been changed to show them here\n";
 270                                 break;
 271                         }
 272                 }
 273         }
 274         buf_del(h);
 275         if(cvar_changes == "")
 276                 cvar_changes = "// this server runs at default settings\n";
 277         else
 278                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 279         cvar_changes = strzone(cvar_changes);
 280 }
 281
 282 void detect_maptype()
 283 {
 284 #if 0
 285         vector o, v;
 286         float i;
 287
 288         for(;;)
 289         {
 290                 o = world.mins;
 291                 o_x += random() * (world.maxs_x - world.mins_x);
 292                 o_y += random() * (world.maxs_y - world.mins_y);
 293                 o_z += random() * (world.maxs_z - world.mins_z);
 294
 295                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 296                 if(trace_fraction == 1)
 297                         continue;
 298
 299                 v = trace_endpos;
 300
 301                 for(i = 0; i < 64; i += 4)
 302                 {
 303                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 304         if(trace_fraction == 1)
 305                 continue;
 306                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 307                 }
 308
 309                 break;
 310         }
 311 #endif
 312 }
 313
 314 entity randomseed;
 315 float RandomSeed_Send(entity to, float sf)
 316 {
 317         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 318         WriteShort(MSG_ENTITY, self.cnt);
 319         return TRUE;
 320 }
 321 void RandomSeed_Think()
 322 {
 323         self.cnt = bound(0, floor(random() * 65536), 65535);
 324         self.nextthink = time + 5;
 325
 326         self.SendFlags |= 1;
 327 }
 328 void RandomSeed_Spawn()
 329 {
 330         randomseed = spawn();
 331         randomseed.think = RandomSeed_Think;
 332         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 333
 334         entity oldself;
 335         oldself = self;
 336         self = randomseed;
 337         self.think(); // sets random seed and nextthink
 338         self = oldself;
 339 }
 340
 341 void spawnfunc___init_dedicated_server(void)
 342 {
 343         // handler for _init/_init map (only for dedicated server initialization)
 344
 345         world_initialized = -1; // don't complain
 346         cvar = cvar_builtin;
 347         cvar_string = cvar_string_builtin;
 348         cvar_set = cvar_set_builtin;
 349         dprint_load(); // load dprint status from cvar
 350
 351         remove = remove_unsafely;
 352
 353         entity e;
 354         e = spawn();
 355         e.think = GotoFirstMap;
 356         e.nextthink = time; // this is usually 1 at this point
 357
 358         e = spawn();
 359         e.classname = "info_player_deathmatch"; // safeguard against player joining
 360
 361         self.classname = "worldspawn"; // safeguard against various stuff ;)
 362
 363         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 364         MapInfo_Enumerate();
 365         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 366 }
 367
 368 void Map_MarkAsRecent(string m);
 369 float world_already_spawned;
 370 void RegisterWeapons();
 371 void Nagger_Init();
 372 void ClientInit_Spawn();
 373 void spawnfunc_worldspawn (void)
 374 {
 375         float fd, l, i, j, n;
 376         string s, col;
 377
 378         cvar = cvar_builtin;
 379         cvar_string = cvar_string_builtin;
 380         cvar_set = cvar_set_builtin;
 381         dprint_load(); // load dprint status from cvar
 382
 383         if(world_already_spawned)
 384                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 385         world_already_spawned = TRUE;
 386
 387         remove = remove_safely; // during spawning, watch what you remove!
 388
 389         check_unacceptable_compiler_bugs();
 390
 391         if(cvar_string("cvar_check_default") != "bypass")
 392         {
 393                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 394                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 395
 396                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 397                         error("Config file mismatch! Please update weapons.cfg and weaponsHavoc.cfg to match the QuakeC code, and restart the engine!");
 398         }
 399
 400         compressShortVector_init();
 401
 402         local entity head;
 403         head = nextent(world);
 404         maxclients = 0;
 405         while(head)
 406         {
 407                 ++maxclients;
 408                 head = nextent(head);
 409         }
 410
 411         // needs to be done so early as they would still spawn
 412         RegisterWeapons();
 413
 414         if(sv_cheats)
 415                 ServerProgsDB = db_create();
 416         else
 417                 ServerProgsDB = db_load("server.db");
 418
 419         TemporaryDB = db_create();
 420
 421         /*
 422         TODO sound pack system
 423         // initialize sound pack system
 424         soundpack = cvar_string("g_soundpack");
 425         if(soundpack != "")
 426                 soundpack = strcat(soundpack, "/");
 427         soundpack = strzone(soundpack);
 428         */
 429
 430         // 0 normal
 431         lightstyle(0, "m");
 432
 433         // 1 FLICKER (first variety)
 434         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 435
 436         // 2 SLOW STRONG PULSE
 437         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 438
 439         // 3 CANDLE (first variety)
 440         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 441
 442         // 4 FAST STROBE
 443         lightstyle(4, "mamamamamama");
 444
 445         // 5 GENTLE PULSE 1
 446         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 447
 448         // 6 FLICKER (second variety)
 449         lightstyle(6, "nmonqnmomnmomomno");
 450
 451         // 7 CANDLE (second variety)
 452         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 453
 454         // 8 CANDLE (third variety)
 455         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 456
 457         // 9 SLOW STROBE (fourth variety)
 458         lightstyle(9, "aaaaaaaazzzzzzzz");
 459
 460         // 10 FLUORESCENT FLICKER
 461         lightstyle(10, "mmamammmmammamamaaamammma");
 462
 463         // 11 SLOW PULSE NOT FADE TO BLACK
 464         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 465
 466         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 467
 468         // 63 testing
 469         lightstyle(63, "a");
 470
 471         if(cvar("g_campaign"))
 472                 CampaignPreInit();
 473
 474         Map_MarkAsRecent(mapname);
 475
 476         precache_model ("null"); // we need this one before InitGameplayMode
 477         InitGameplayMode();
 478         readlevelcvars();
 479         GrappleHookInit();
 480
 481         player_count = 0;
 482         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 483         if(bot_waypoints_for_items == 1)
 484                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 485                         bot_waypoints_for_items = 0;
 486
 487         // for setting by mapinfo
 488         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 489         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 490
 491         precache();
 492
 493         WaypointSprite_Init();
 494
 495         //if (g_domination)
 496         //      dom_init();
 497
 498         GameLogInit(); // prepare everything
 499         if(cvar("sv_eventlog"))
 500         {
 501                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 502                 s = strcat(s, ftos(random()));
 503                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 504                 s = ":gameinfo:mutators:LIST";
 505                 if(cvar("g_grappling_hook"))
 506                         s = strcat(s, ":grappling_hook");
 507                 if(!cvar("g_use_ammunition"))
 508                         s = strcat(s, ":no_use_ammunition");
 509                 if(!cvar("g_pickup_items"))
 510                         s = strcat(s, ":no_pickup_items");
 511                 if(cvar("g_instagib"))
 512                         s = strcat(s, ":instagib");
 513                 if(cvar_string("g_weaponarena") != "0")
 514                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 515                 if(cvar("g_nixnex"))
 516                         s = strcat(s, ":nixnex");
 517                 if(cvar("g_vampire"))
 518                         s = strcat(s, ":vampire");
 519                 if(cvar("g_laserguided_missile"))
 520                         s = strcat(s, ":laserguided_missile");
 521                 if(cvar("g_norecoil"))
 522                         s = strcat(s, ":norecoil");
 523                 if(cvar("g_midair"))
 524                         s = strcat(s, ":midair");
 525                 if(cvar("g_minstagib"))
 526                         s = strcat(s, ":minstagib");
 527                 GameLogEcho(s);
 528                 GameLogEcho(":gameinfo:end");
 529         }
 530
 531         cvar_set("nextmap", "");
 532
 533         SetDefaultAlpha();
 534
 535         if(cvar("g_campaign"))
 536                 CampaignPostInit();
 537
 538         fteqcc_testbugs();
 539
 540         Ban_LoadBans();
 541
 542         //initialise globals related to sv_timeout
 543         sys_ticrate = cvar("sys_ticrate");
 544         orig_slowmo = cvar("slowmo");
 545
 546         MapInfo_Enumerate();
 547         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
 548
 549         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 550         {
 551                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 552                 if(fd != -1)
 553                 {
 554                         while((s = fgets(fd)))
 555                         {
 556                                 l = tokenize_console(s);
 557                                 if(l < 2)
 558                                         continue;
 559                                 if(argv(0) == "cd")
 560                                 {
 561                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 562                                         print("  cdtrack ", argv(2), "\n");
 563                                 }
 564                                 else if(argv(0) == "fog")
 565                                 {
 566                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 567                                         print("  \"fog\" \"", s, "\"\n");
 568                                 }
 569                                 else if(argv(0) == "set")
 570                                 {
 571                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 572                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 573                                 }
 574                                 else if(argv(0) != "//")
 575                                 {
 576                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 577                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 578                                 }
 579                         }
 580                         fclose(fd);
 581                 }
 582         }
 583
 584         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 585         addstat(STAT_WEAPONS, AS_INT, weapons);
 586         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 587         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 588         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 589         Nagger_Init();
 590
 591         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 592         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 593         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 594         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 595         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 596
 597         next_pingtime = time + 5;
 598         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 599
 600         detect_maptype();
 601
 602         lsmaps_reply = "^7Maps available: ";
 603         for(i = 0, j = 0; i < MapInfo_count; ++i)
 604         {
 605                 if(MapInfo_Get_ByID(i))
 606                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 607                         {
 608                                 if(mod(i, 2))
 609                                         col = "^2";
 610                                 else
 611                                         col = "^3";
 612                                 ++j;
 613                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 614                         }
 615         }
 616         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 617
 618         maplist_reply = "^7Maps in list: ";
 619         n = tokenize_console(cvar_string("g_maplist"));
 620         for(i = 0, j = 0; i < n; ++i)
 621         {
 622                 if(MapInfo_CheckMap(argv(i)))
 623                 {
 624                         if(mod(j, 2))
 625                                 col = "^2";
 626                         else
 627                                 col = "^3";
 628                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 629                         ++j;
 630                 }
 631         }
 632         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 633         MapInfo_ClearTemps();
 634
 635         records_reply = strzone(getrecords());
 636
 637         ClientInit_Spawn();
 638         RandomSeed_Spawn();
 639
 640         world_initialized = 1;
 641 }
 642
 643 void spawnfunc_light (void)
 644 {
 645         //makestatic (self); // Who the f___ did that?
 646         remove(self);
 647 }
 648
 649 float TryFile( string pFilename )
 650 {
 651         local float lHandle;
 652         dprint("TryFile(\"", pFilename, "\")\n");
 653         lHandle = fopen( pFilename, FILE_READ );
 654         if( lHandle != -1 ) {
 655                 fclose( lHandle );
 656                 return TRUE;
 657         } else {
 658                 return FALSE;
 659         }
 660 };
 661
 662 string GetGametype()
 663 {
 664         return GametypeNameFromType(game);
 665 }
 666
 667 string getmapname_stored;
 668 string GetMapname()
 669 {
 670         return mapname;
 671 }
 672
 673 float Map_Count, Map_Current;
 674 string Map_Current_Name;
 675
 676 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 677 float GetMaplistPosition()
 678 {
 679         float pos, idx;
 680         string map;
 681
 682         map = GetMapname();
 683         idx = cvar("g_maplist_index");
 684
 685         if(idx >= 0)
 686                 if(idx < Map_Count)
 687                         if(map == argv(idx))
 688                                 return idx;
 689
 690         for(pos = 0; pos < Map_Count; ++pos)
 691                 if(map == argv(pos))
 692                         return pos;
 693
 694         // resume normal maplist rotation if current map is not in g_maplist
 695         return idx;
 696 }
 697
 698 float MapHasRightSize(string map)
 699 {
 700         float fh;
 701         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 702         if(cvar("g_maplist_check_waypoints"))
 703         {
 704                 dprint("checkwp "); dprint(map);
 705                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 706                 if(fh < 0)
 707                 {
 708                         dprint(": no waypoints\n");
 709                         return FALSE;
 710                 }
 711                 dprint(": has waypoints\n");
 712                 fclose(fh);
 713         }
 714
 715         // open map size restriction file
 716         dprint("opensize "); dprint(map);
 717         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 718         if(fh >= 0)
 719         {
 720                 float mapmin, mapmax;
 721                 dprint(": ok, ");
 722                 mapmin = stof(fgets(fh));
 723                 mapmax = stof(fgets(fh));
 724                 fclose(fh);
 725                 if(player_count < mapmin)
 726                 {
 727                         dprint("not enough\n");
 728                         return FALSE;
 729                 }
 730                 if(player_count > mapmax)
 731                 {
 732                         dprint("too many\n");
 733                         return FALSE;
 734                 }
 735                 dprint("right size\n");
 736                 return TRUE;
 737         }
 738         dprint(": not found\n");
 739         return TRUE;
 740 }
 741
 742 string Map_Filename(float position)
 743 {
 744         return strcat("maps/", argv(position), ".bsp");
 745 }
 746
 747 string strwords(string s, float w)
 748 {
 749         float endpos;
 750         for(endpos = 0; w && endpos >= 0; --w)
 751                 endpos = strstrofs(s, " ", endpos + 1);
 752         if(endpos < 0)
 753                 return s;
 754         else
 755                 return substring(s, 0, endpos);
 756 }
 757
 758 float strhasword(string s, string w)
 759 {
 760         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 761 }
 762
 763 void Map_MarkAsRecent(string m)
 764 {
 765         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 766 }
 767
 768 float Map_IsRecent(string m)
 769 {
 770         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 771 }
 772
 773 float Map_Check(float position, float pass)
 774 {
 775         string filename;
 776         string map_next;
 777         map_next = argv(position);
 778         if(pass <= 1)
 779         {
 780                 if(Map_IsRecent(map_next))
 781                         return 0;
 782         }
 783         filename = Map_Filename(position);
 784         if(MapInfo_CheckMap(map_next))
 785         {
 786                 if(pass == 2)
 787                         return 1;
 788                 if(MapHasRightSize(map_next))
 789                         return 1;
 790                 return 0;
 791         }
 792         else
 793                 dprint( "Couldn't select '", filename, "'..\n" );
 794
 795         return 0;
 796 }
 797
 798 void Map_Goto_SetStr(string nextmapname)
 799 {
 800         if(getmapname_stored != "")
 801                 strunzone(getmapname_stored);
 802         if(nextmapname == "")
 803                 getmapname_stored = "";
 804         else
 805                 getmapname_stored = strzone(nextmapname);
 806 }
 807
 808 void Map_Goto_SetFloat(float position)
 809 {
 810         cvar_set("g_maplist_index", ftos(position));
 811         Map_Goto_SetStr(argv(position));
 812 }
 813
 814 void GameResetCfg()
 815 {
 816         // settings persist, except...
 817         localcmd("\nsettemp_restore\n");
 818 };
 819
 820 void Map_Goto()
 821 {
 822         GameResetCfg();
 823         MapInfo_LoadMap(getmapname_stored);
 824 }
 825
 826 // return codes of map selectors:
 827 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 828 //   -2 = permanent failure
 829 float() MaplistMethod_Iterate = // usual method
 830 {
 831         float pass, i;
 832
 833         for(pass = 1; pass <= 2; ++pass)
 834         {
 835                 for(i = 1; i < Map_Count; ++i)
 836                 {
 837                         float mapindex;
 838                         mapindex = mod(i + Map_Current, Map_Count);
 839                         if(Map_Check(mapindex, pass))
 840                                 return mapindex;
 841                 }
 842         }
 843         return -1;
 844 }
 845
 846 float() MaplistMethod_Repeat = // fallback method
 847 {
 848         if(Map_Check(Map_Current, 2))
 849                 return Map_Current;
 850         return -2;
 851 }
 852
 853 float() MaplistMethod_Random = // random map selection
 854 {
 855         float i, imax;
 856
 857         imax = 42;
 858
 859         for(i = 0; i <= imax; ++i)
 860         {
 861                 float mapindex;
 862                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 863                 if(Map_Check(mapindex, 1))
 864                         return mapindex;
 865         }
 866         return -1;
 867 }
 868
 869 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 870 // the exponent sets a bias on the map selection:
 871 // the higher the exponent, the less likely "shortly repeated" same maps are
 872 {
 873         float i, j, imax, insertpos;
 874
 875         imax = 42;
 876
 877         for(i = 0; i <= imax; ++i)
 878         {
 879                 string newlist;
 880
 881                 // now reinsert this at another position
 882                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 883                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 884                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 885                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 886
 887                 // insert the current map there
 888                 newlist = "";
 889                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 890                         newlist = strcat(newlist, " ", argv(j));
 891                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 892                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 893                         newlist = strcat(newlist, " ", argv(j));
 894                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 895                 cvar_set("g_maplist", newlist);
 896                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 897
 898                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 899                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 900                 if(Map_Check(Map_Current, 1))
 901                         return Map_Current;
 902         }
 903         return -1;
 904 }
 905
 906 void Maplist_Init()
 907 {
 908         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 909         if(Map_Count == 0)
 910         {
 911                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 912                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
 913                 if(cvar("g_maplist_shuffle"))
 914                         ShuffleMaplist();
 915                 localcmd("\nmenu_cmd sync\n");
 916                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 917         }
 918         if(Map_Count == 0)
 919                 error("empty maplist, cannot select a new map");
 920         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 921
 922         if(Map_Current_Name)
 923                 strunzone(Map_Current_Name);
 924         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 925         // this may or may not be correct, but who cares, in the worst case a map
 926         // isn't chosen in the first pass that should have been
 927 }
 928
 929 string GetNextMap()
 930 {
 931         float nextMap;
 932
 933         Maplist_Init();
 934         nextMap = -1;
 935
 936         if(nextMap == -1)
 937                 if(cvar("g_maplist_shuffle") > 0)
 938                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 939
 940         if(nextMap == -1)
 941                 if(cvar("g_maplist_selectrandom"))
 942                         nextMap = MaplistMethod_Random();
 943
 944         if(nextMap == -1)
 945                 nextMap = MaplistMethod_Iterate();
 946
 947         if(nextMap == -1)
 948                 nextMap = MaplistMethod_Repeat();
 949
 950         if(nextMap >= 0)
 951         {
 952                 Map_Goto_SetFloat(nextMap);
 953                 return getmapname_stored;
 954         }
 955
 956         return "";
 957 };
 958
 959 float DoNextMapOverride()
 960 {
 961         if(cvar("g_campaign"))
 962         {
 963                 CampaignPostIntermission();
 964                 alreadychangedlevel = TRUE;
 965                 return TRUE;
 966         }
 967         if(cvar("quit_when_empty"))
 968         {
 969                 if(player_count <= currentbots)
 970                 {
 971                         localcmd("quit\n");
 972                         alreadychangedlevel = TRUE;
 973                         return TRUE;
 974                 }
 975         }
 976         if(cvar_string("quit_and_redirect") != "")
 977         {
 978                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 979                 alreadychangedlevel = TRUE;
 980                 return TRUE;
 981         }
 982         if (cvar("samelevel")) // if samelevel is set, stay on same level
 983         {
 984                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 985                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 986                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 987                 localcmd("restart\n");
 988                 //changelevel (mapname);
 989                 alreadychangedlevel = TRUE;
 990                 return TRUE;
 991         }
 992         if(cvar_string("nextmap") != "")
 993                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 994                 {
 995                         Map_Goto_SetStr(cvar_string("nextmap"));
 996                         Map_Goto();
 997                         alreadychangedlevel = TRUE;
 998                         return TRUE;
 999                 }
1000         if(cvar("lastlevel"))
1001         {
1002                 GameResetCfg();
1003                 localcmd("set lastlevel 0\ntogglemenu\n");
1004                 alreadychangedlevel = TRUE;
1005                 return TRUE;
1006         }
1007         return FALSE;
1008 };
1009
1010 void GotoNextMap()
1011 {
1012         //local string nextmap;
1013         //local float n, nummaps;
1014         //local string s;
1015         if (alreadychangedlevel)
1016                 return;
1017         alreadychangedlevel = TRUE;
1018
1019         {
1020                 string nextMap;
1021                 float allowReset;
1022
1023                 for(allowReset = 1; allowReset >= 0; --allowReset)
1024                 {
1025                         nextMap = GetNextMap();
1026                         if(nextMap != "")
1027                                 break;
1028
1029                         if(allowReset)
1030                         {
1031                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1032                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
1033                                 if(cvar("g_maplist_shuffle"))
1034                                         ShuffleMaplist();
1035                                 localcmd("\nmenu_cmd sync\n");
1036                         }
1037                         else
1038                         {
1039                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1040                         }
1041                 }
1042                 Map_Goto();
1043         }
1044 };
1045
1046
1047 /*
1048 ============
1049 IntermissionThink
1050
1051 When the player presses attack or jump, change to the next level
1052 ============
1053 */
1054 .float autoscreenshot;
1055 void() MapVote_Start;
1056 void() MapVote_Think;
1057 float mapvote_initialized;
1058 void IntermissionThink()
1059 {
1060         FixIntermissionClient(self);
1061
1062         if(cvar("sv_autoscreenshot"))
1063         if(self.autoscreenshot > 0)
1064         if(time > self.autoscreenshot)
1065         {
1066                 self.autoscreenshot = -1;
1067                 if(clienttype(self) == CLIENTTYPE_REAL)
1068                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1069                 return;
1070         }
1071
1072         if (time < intermission_exittime)
1073                 return;
1074
1075         if(!mapvote_initialized)
1076                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1077                         return;
1078
1079         MapVote_Start();
1080 };
1081
1082 /*
1083 ============
1084 FindIntermission
1085
1086 Returns the entity to view from
1087 ============
1088 */
1089 /*
1090 entity FindIntermission()
1091 {
1092         local   entity spot;
1093         local   float cyc;
1094
1095 // look for info_intermission first
1096         spot = find (world, classname, "info_intermission");
1097         if (spot)
1098         {       // pick a random one
1099                 cyc = random() * 4;
1100                 while (cyc > 1)
1101                 {
1102                         spot = find (spot, classname, "info_intermission");
1103                         if (!spot)
1104                                 spot = find (spot, classname, "info_intermission");
1105                         cyc = cyc - 1;
1106                 }
1107                 return spot;
1108         }
1109
1110 // then look for the start position
1111         spot = find (world, classname, "info_player_start");
1112         if (spot)
1113                 return spot;
1114
1115 // testinfo_player_start is only found in regioned levels
1116         spot = find (world, classname, "testplayerstart");
1117         if (spot)
1118                 return spot;
1119
1120 // then look for the start position
1121         spot = find (world, classname, "info_player_deathmatch");
1122         if (spot)
1123                 return spot;
1124
1125         //objerror ("FindIntermission: no spot");
1126         return world;
1127 };
1128 */
1129
1130 /*
1131 ===============================================================================
1132
1133 RULES
1134
1135 ===============================================================================
1136 */
1137
1138 void DumpStats(float final)
1139 {
1140         local float file;
1141         local string s;
1142         local float to_console;
1143         local float to_eventlog;
1144         local float to_file;
1145         local float i;
1146
1147         to_console = cvar("sv_logscores_console");
1148         to_eventlog = cvar("sv_eventlog");
1149         to_file = cvar("sv_logscores_file");
1150
1151         if(!final)
1152         {
1153                 to_console = TRUE; // always print printstats replies
1154                 to_eventlog = FALSE; // but never print them to the event log
1155         }
1156
1157         if(to_eventlog)
1158                 if(cvar("sv_eventlog_console"))
1159                         to_console = FALSE; // otherwise we get the output twice
1160
1161         if(final)
1162                 s = ":scores:";
1163         else
1164                 s = ":status:";
1165         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1166
1167         if(to_console)
1168                 print(s, "\n");
1169         if(to_eventlog)
1170                 GameLogEcho(s);
1171         if(to_file)
1172         {
1173                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1174                 if(file == -1)
1175                         to_file = FALSE;
1176                 else
1177                         fputs(file, strcat(s, "\n"));
1178         }
1179
1180         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1181         if(to_console)
1182                 print(s, "\n");
1183         if(to_eventlog)
1184                 GameLogEcho(s);
1185         if(to_file)
1186                 fputs(file, strcat(s, "\n"));
1187
1188         FOR_EACH_CLIENT(other)
1189         {
1190                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1191                 {
1192                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1193                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1194                         if(other.classname == "player" || g_arena || g_lms)
1195                                 s = strcat(s, ftos(other.team), ":");
1196                         else
1197                                 s = strcat(s, "spectator:");
1198
1199                         if(to_console)
1200                                 print(s, other.netname, "\n");
1201                         if(to_eventlog)
1202                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1203                         if(to_file)
1204                                 fputs(file, strcat(s, other.netname, "\n"));
1205                 }
1206         }
1207
1208         if(teams_matter)
1209         {
1210                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1211                 if(to_console)
1212                         print(s, "\n");
1213                 if(to_eventlog)
1214                         GameLogEcho(s);
1215                 if(to_file)
1216                         fputs(file, strcat(s, "\n"));
1217
1218                 for(i = 1; i < 16; ++i)
1219                 {
1220                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1221                         s = strcat(s, ":", ftos(i));
1222                         if(to_console)
1223                                 print(s, "\n");
1224                         if(to_eventlog)
1225                                 GameLogEcho(s);
1226                         if(to_file)
1227                                 fputs(file, strcat(s, "\n"));
1228                 }
1229         }
1230
1231         if(to_console)
1232                 print(":end\n");
1233         if(to_eventlog)
1234                 GameLogEcho(":end");
1235         if(to_file)
1236         {
1237                 fputs(file, ":end\n");
1238                 fclose(file);
1239         }
1240 }
1241
1242 void FixIntermissionClient(entity e)
1243 {
1244         string s;
1245         if(!e.autoscreenshot) // initial call
1246         {
1247                 e.angles = e.v_angle;
1248                 e.angles_x = -e.angles_x;
1249                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1250                 e.health = -2342;
1251                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1252                 e.solid = SOLID_NOT;
1253                 e.movetype = MOVETYPE_NONE;
1254                 e.takedamage = DAMAGE_NO;
1255                 if(e.weaponentity)
1256                 {
1257                         e.weaponentity.effects = EF_NODRAW;
1258                         if (e.weaponentity.weaponentity)
1259                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1260                 }
1261                 if(clienttype(e) == CLIENTTYPE_REAL)
1262                 {
1263                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1264                         s = cvar_string("sv_intermission_cdtrack");
1265                         if(s != "")
1266                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1267                         msg_entity = e;
1268                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1269                 }
1270         }
1271
1272         //e.velocity = '0 0 0';
1273         //e.fixangle = TRUE;
1274
1275         // TODO halt weapon animation
1276 }
1277
1278
1279 /*
1280 go to the next level for deathmatch
1281 only called if a time or frag limit has expired
1282 */
1283 void NextLevel()
1284 {
1285         float minTotalFrags;
1286         float maxTotalFrags;
1287         float score;
1288         float f;
1289
1290         gameover = TRUE;
1291
1292         intermission_running = 1;
1293
1294 // enforce a wait time before allowing changelevel
1295         if(player_count > 0)
1296                 intermission_exittime = time + cvar("sv_mapchange_delay");
1297         else
1298                 intermission_exittime = -1;
1299
1300         /*
1301         WriteByte (MSG_ALL, SVC_CDTRACK);
1302         WriteByte (MSG_ALL, 3);
1303         WriteByte (MSG_ALL, 3);
1304         // done in FixIntermission
1305         */
1306
1307         //pos = FindIntermission ();
1308
1309         VoteReset();
1310
1311         DumpStats(TRUE);
1312
1313         if(cvar("sv_eventlog"))
1314                 GameLogEcho(":gameover");
1315
1316         GameLogClose();
1317
1318         FOR_EACH_CLIENT(other)
1319         {
1320                 FixIntermissionClient(other);
1321
1322                 if(other.winning)
1323                         bprint(other.netname, " ^7wins.\n");
1324         }
1325
1326         minTotalFrags = 0;
1327         maxTotalFrags = 0;
1328         FOR_EACH_PLAYER(other)
1329         {
1330                 if(maxTotalFrags < other.totalfrags)
1331                         maxTotalFrags = other.totalfrags;
1332                 if(minTotalFrags > other.totalfrags)
1333                         minTotalFrags = other.totalfrags;
1334         }
1335
1336         if(!currentbots)
1337         {
1338                 FOR_EACH_PLAYER(other)
1339                 {
1340                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1341                         f = bound(0, other.play_time / max(time, 1), 1);
1342                         // store some statistics?
1343                 }
1344         }
1345
1346         if(cvar("g_campaign"))
1347                 CampaignPreIntermission();
1348
1349         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1350 };
1351
1352 /*
1353 ============
1354 CheckRules_Player
1355
1356 Exit deathmatch games upon conditions
1357 ============
1358 */
1359 void CheckRules_Player()
1360 {
1361         if (gameover)   // someone else quit the game already
1362                 return;
1363
1364         if(self.deadflag == DEAD_NO)
1365                 self.play_time += frametime;
1366
1367         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1368         //   (div0: and that in CheckRules_World please)
1369 };
1370
1371 float checkrules_oneminutewarning;
1372
1373 float checkrules_equality;
1374 float checkrules_suddendeathwarning;
1375 float checkrules_suddendeathend;
1376 float checkrules_overtimesadded; //how many overtimes have been already added
1377 float checkrules_status;
1378
1379 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1380 float WINNING_YES = 1; // winner found
1381 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1382 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1383
1384 void InitiateOvertime()
1385 {
1386         // Check first whether normal overtimes could be added before initiating suddendeath mode
1387         // - for this timelimit_overtime needs to be >0 of course
1388         // - also check the winning condition calculated in the previous frame and only add normal overtime
1389         //   again, if at the point at which timelimit would be extended again, still no winner was found
1390         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1391         {
1392                 ++checkrules_overtimesadded;
1393                 //add one more overtime by simply extending the timelimit
1394                 float tl;
1395                 tl = cvar("timelimit");
1396                 tl += cvar("timelimit_overtime");
1397                 cvar_set("timelimit", ftos(tl));
1398                 string minutesPlural;
1399                 if (cvar("timelimit_overtime") == 1)
1400                         minutesPlural = " ^3minute";
1401                 else
1402                         minutesPlural = " ^3minutes";
1403
1404                 bcenterprint(
1405                         strcat(
1406                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1407                                 ftos(cvar("timelimit_overtime")),
1408                                 minutesPlural,
1409                                 " to the game!"
1410                         )
1411                 );
1412         }
1413         else
1414         {
1415                 if(!checkrules_suddendeathend)
1416                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1417         }
1418 }
1419
1420 float GetWinningCode(float fraglimitreached, float equality)
1421 {
1422         if(equality)
1423                 if(fraglimitreached)
1424                         return WINNING_STARTSUDDENDEATHOVERTIME;
1425                 else
1426                         return WINNING_NEVER;
1427         else
1428                 if(fraglimitreached)
1429                         return WINNING_YES;
1430                 else
1431                         return WINNING_NO;
1432 }
1433
1434 // set the .winning flag for exactly those players with a given field value
1435 void SetWinners(.float field, float value)
1436 {
1437         entity head;
1438         FOR_EACH_PLAYER(head)
1439                 head.winning = (head.field == value);
1440 }
1441
1442 // set the .winning flag for those players with a given field value
1443 void AddWinners(.float field, float value)
1444 {
1445         entity head;
1446         FOR_EACH_PLAYER(head)
1447                 if(head.field == value)
1448                         head.winning = 1;
1449 }
1450
1451 // clear the .winning flags
1452 void ClearWinners(void)
1453 {
1454         entity head;
1455         FOR_EACH_PLAYER(head)
1456                 head.winning = 0;
1457 }
1458
1459 // Onslaught winning condition:
1460 // game terminates if only one team has a working generator (or none)
1461 float WinningCondition_Onslaught()
1462 {
1463         entity head;
1464         local float t1, t2, t3, t4;
1465
1466         WinningConditionHelper(); // set worldstatus
1467
1468         // first check if the game has ended
1469         t1 = t2 = t3 = t4 = 0;
1470         head = find(world, classname, "onslaught_generator");
1471         while (head)
1472         {
1473                 if (head.health > 0)
1474                 {
1475                         if (head.team == COLOR_TEAM1) t1 = 1;
1476                         if (head.team == COLOR_TEAM2) t2 = 1;
1477                         if (head.team == COLOR_TEAM3) t3 = 1;
1478                         if (head.team == COLOR_TEAM4) t4 = 1;
1479                 }
1480                 head = find(head, classname, "onslaught_generator");
1481         }
1482         if (t1 + t2 + t3 + t4 < 2)
1483         {
1484                 // game over, only one team remains (or none)
1485                 ClearWinners();
1486                 if (t1) SetWinners(team, COLOR_TEAM1);
1487                 if (t2) SetWinners(team, COLOR_TEAM2);
1488                 if (t3) SetWinners(team, COLOR_TEAM3);
1489                 if (t4) SetWinners(team, COLOR_TEAM4);
1490                 dprint("Have a winner, ending game.\n");
1491                 return WINNING_YES;
1492         }
1493
1494         // Two or more teams remain
1495         return WINNING_NO;
1496 }
1497
1498 float LMS_NewPlayerLives()
1499 {
1500         float fl;
1501         fl = cvar("fraglimit");
1502         if(fl == 0)
1503                 fl = 999;
1504
1505         // first player has left the game for dying too much? Nobody else can get in.
1506         if(lms_lowest_lives < 1)
1507                 return 0;
1508
1509         if(!cvar("g_lms_join_anytime"))
1510                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1511                         return 0;
1512
1513         return bound(1, lms_lowest_lives, fl);
1514 }
1515
1516 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1517 // they win. Otherwise the defending team wins once the timelimit passes.
1518 void assault_new_round();
1519 float WinningCondition_Assault()
1520 {
1521         local float status;
1522
1523         WinningConditionHelper(); // set worldstatus
1524
1525         status = WINNING_NO;
1526         // as the timelimit has not yet passed just assume the defending team will win
1527         if(assault_attacker_team == COLOR_TEAM1)
1528         {
1529                 SetWinners(team, COLOR_TEAM2);
1530         }
1531         else
1532         {
1533                 SetWinners(team, COLOR_TEAM1);
1534         }
1535
1536         local entity ent;
1537         ent = find(world, classname, "target_assault_roundend");
1538         if(ent)
1539         {
1540                 if(ent.winning) // round end has been triggered by attacking team
1541                 {
1542                         bprint("ASSAULT: round completed...\n");
1543                         SetWinners(team, assault_attacker_team);
1544
1545                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1546
1547                         if(ent.cnt == 1) // this was the second round
1548                         {
1549                                 status = WINNING_YES;
1550                         }
1551                         else
1552                         {
1553                                 local entity oldself;
1554                                 oldself = self;
1555                                 self = ent;
1556                                 assault_new_round();
1557                                 self = oldself;
1558                         }
1559                 }
1560         }
1561
1562         return status;
1563 }
1564
1565 // LMS winning condition: game terminates if and only if there's at most one
1566 // one player who's living lives. Top two scores being equal cancels the time
1567 // limit.
1568 float WinningCondition_LMS()
1569 {
1570         entity head, head2;
1571         float have_player;
1572         float have_players;
1573         float l;
1574
1575         have_player = FALSE;
1576         have_players = FALSE;
1577         l = LMS_NewPlayerLives();
1578
1579         head = find(world, classname, "player");
1580         if(head)
1581                 have_player = TRUE;
1582         head2 = find(head, classname, "player");
1583         if(head2)
1584                 have_players = TRUE;
1585
1586         if(have_player)
1587         {
1588                 // we have at least one player
1589                 if(have_players)
1590                 {
1591                         // two or more active players - continue with the game
1592                 }
1593                 else
1594                 {
1595                         // exactly one player?
1596
1597                         ClearWinners();
1598                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1599
1600                         if(l)
1601                         {
1602                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1603                                 return WINNING_NO;
1604                         }
1605                         else
1606                         {
1607                                 // a winner!
1608                                 // and assign him his first place
1609                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1610                                 return WINNING_YES;
1611                         }
1612                 }
1613         }
1614         else
1615         {
1616                 // nobody is playing at all...
1617                 if(l)
1618                 {
1619                         // wait for players...
1620                 }
1621                 else
1622                 {
1623                         // SNAFU (maybe a draw game?)
1624                         ClearWinners();
1625                         dprint("No players, ending game.\n");
1626                         return WINNING_YES;
1627                 }
1628         }
1629
1630         // When we get here, we have at least two players who are actually LIVING,
1631         // now check if the top two players have equal score.
1632         WinningConditionHelper();
1633
1634         ClearWinners();
1635         if(WinningConditionHelper_winner)
1636                 WinningConditionHelper_winner.winning = TRUE;
1637         if(WinningConditionHelper_equality)
1638                 return WINNING_NEVER;
1639
1640         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1641         return WINNING_NO;
1642 }
1643
1644 void ShuffleMaplist()
1645 {
1646         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1647 }
1648
1649 float leaderfrags;
1650 float WinningCondition_Scores(float limit)
1651 {
1652         // TODO make everything use THIS winning condition (except LMS)
1653         WinningConditionHelper();
1654
1655         if(teams_matter)
1656         {
1657                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1658                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1659                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1660                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1661         }
1662
1663         ClearWinners();
1664         if(WinningConditionHelper_winner)
1665                 WinningConditionHelper_winner.winning = 1;
1666         if(WinningConditionHelper_winnerteam >= 0)
1667                 SetWinners(team, WinningConditionHelper_winnerteam);
1668
1669         if(WinningConditionHelper_lowerisbetter)
1670         {
1671                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1672                 limit = -limit;
1673         }
1674
1675         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying) || g_nexball)
1676         // these modes always score in increments of 1, thus this makes sense
1677         {
1678                 if(leaderfrags != WinningConditionHelper_topscore)
1679                 {
1680                         leaderfrags = WinningConditionHelper_topscore;
1681
1682                         if (limit)
1683                         if (leaderfrags == limit - 1)
1684                                 play2all("announcer/robotic/1fragleft.wav");
1685                         else if (leaderfrags == limit - 2)
1686                                 play2all("announcer/robotic/2fragsleft.wav");
1687                         else if (leaderfrags == limit - 3)
1688                                 play2all("announcer/robotic/3fragsleft.wav");
1689                 }
1690         }
1691
1692         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1693 }
1694
1695 float WinningCondition_Race(float fraglimit)
1696 {
1697         float wc;
1698         entity p;
1699         wc = WinningCondition_Scores(fraglimit);
1700
1701         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1702         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1703         // do NOT support equality when the laps are all raced!
1704         {
1705                 FOR_EACH_PLAYER(p)
1706                         if not(p.race_completed)
1707                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1708                 return WINNING_YES;
1709         }
1710         return wc;
1711 }
1712
1713 void ReadyRestart();
1714 float WinningCondition_QualifyingThenRace(float limit)
1715 {
1716         float wc;
1717         wc = WinningCondition_Scores(limit);
1718
1719         // NEVER initiate overtime
1720         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1721         {
1722                 return WINNING_YES;
1723         }
1724
1725         return wc;
1726 }
1727
1728 float WinningCondition_RanOutOfSpawns()
1729 {
1730         entity head;
1731
1732         if(!have_team_spawns)
1733                 return WINNING_NO;
1734
1735         if(!some_spawn_has_been_used)
1736                 return WINNING_NO;
1737
1738         team1_score = team2_score = team3_score = team4_score = 0;
1739
1740         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1741         {
1742                 if(head.team == COLOR_TEAM1)
1743                         team1_score = 1;
1744                 else if(head.team == COLOR_TEAM2)
1745                         team2_score = 1;
1746                 else if(head.team == COLOR_TEAM3)
1747                         team3_score = 1;
1748                 else if(head.team == COLOR_TEAM4)
1749                         team4_score = 1;
1750         }
1751
1752         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1753         {
1754                 if(head.team == COLOR_TEAM1)
1755                         team1_score = 1;
1756                 else if(head.team == COLOR_TEAM2)
1757                         team2_score = 1;
1758                 else if(head.team == COLOR_TEAM3)
1759                         team3_score = 1;
1760                 else if(head.team == COLOR_TEAM4)
1761                         team4_score = 1;
1762         }
1763
1764         ClearWinners();
1765         if(team1_score + team2_score + team3_score + team4_score == 0)
1766         {
1767                 checkrules_equality = TRUE;
1768                 return WINNING_YES;
1769         }
1770         else if(team1_score + team2_score + team3_score + team4_score == 1)
1771         {
1772                 float t, i;
1773                 if(team1_score) t = COLOR_TEAM1;
1774                 if(team2_score) t = COLOR_TEAM2;
1775                 if(team3_score) t = COLOR_TEAM3;
1776                 if(team4_score) t = COLOR_TEAM4;
1777                 CheckAllowedTeams(world);
1778                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1779                 {
1780                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1781                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1782                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1783                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1784                 }
1785
1786                 AddWinners(team, t);
1787                 return WINNING_YES;
1788         }
1789         else
1790                 return WINNING_NO;
1791 }
1792
1793 /*
1794 ============
1795 CheckRules_World
1796
1797 Exit deathmatch games upon conditions
1798 ============
1799 */
1800 void CheckRules_World()
1801 {
1802         local float timelimit;
1803         local float fraglimit;
1804
1805         VoteThink();
1806         MapVote_Think();
1807
1808         SetDefaultAlpha();
1809
1810         /*
1811         MapVote_Think should now do that part
1812         if (intermission_running)
1813                 if (time >= intermission_exittime + 60)
1814                 {
1815                         if(!DoNextMapOverride())
1816                                 GotoNextMap();
1817                         return;
1818                 }
1819         */
1820
1821         if (gameover)   // someone else quit the game already
1822         {
1823                 if(player_count == 0) // Nobody there? Then let's go to the next map
1824                         MapVote_Start();
1825                         // this will actually check the player count in the next frame
1826                         // again, but this shouldn't hurt
1827                 return;
1828         }
1829
1830         timelimit = cvar("timelimit") * 60;
1831         fraglimit = cvar("fraglimit");
1832
1833         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1834         {
1835                 if(timelimit > 0)
1836                         timelimit = 0; // timelimit is not made for warmup
1837                 if(fraglimit > 0)
1838                         fraglimit = 0; // no fraglimit for now
1839         }
1840
1841         if(timelimit > 0)
1842         {
1843                 timelimit += game_starttime;
1844         }
1845         else if (timelimit < 0)
1846         {
1847                 // endmatch
1848                 NextLevel();
1849                 return;
1850         }
1851
1852         if(checkrules_suddendeathend)
1853         {
1854                 if(!checkrules_suddendeathwarning)
1855                 {
1856                         checkrules_suddendeathwarning = TRUE;
1857                         if(g_race && !g_race_qualifying)
1858                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1859                         else
1860                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1861                 }
1862         }
1863         else
1864         {
1865                 if (timelimit && time >= timelimit)
1866                 {
1867                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1868                         {
1869                                 float totalplayers;
1870                                 float playerswithlaps;
1871                                 float readyplayers;
1872                                 entity head;
1873                                 totalplayers = playerswithlaps = readyplayers = 0;
1874                                 FOR_EACH_PLAYER(head)
1875                                 {
1876                                         ++totalplayers;
1877                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1878                                                 ++playerswithlaps;
1879                                         if(head.ready)
1880                                                 ++readyplayers;
1881                                 }
1882
1883                                 // at least 2/3 of the players have completed a lap: start the RACE
1884                                 // otherwise, the players should end the qualifying on their own
1885                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1886                                 {
1887                                         checkrules_suddendeathend = 0;
1888                                         ReadyRestart(); // go to race
1889                                 }
1890                                 else
1891                                         InitiateOvertime();
1892                         }
1893                         else
1894                                 InitiateOvertime();
1895                 }
1896         }
1897
1898         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1899         {
1900                 NextLevel();
1901                 return;
1902         }
1903
1904         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1905         {
1906                 checkrules_oneminutewarning = TRUE;
1907                 play2all("announcer/robotic/1minuteremains.wav");
1908         }
1909
1910         checkrules_status = WinningCondition_RanOutOfSpawns();
1911         if(checkrules_status == WINNING_YES)
1912         {
1913                 bprint("Hey! Someone ran out of spawns!\n");
1914         }
1915         else if(g_race && !g_race_qualifying && timelimit >= 0)
1916         {
1917                 checkrules_status = WinningCondition_Race(fraglimit);
1918         }
1919         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1920         {
1921                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1922         }
1923         else if(g_assault)
1924         {
1925                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1926         }
1927         else if(g_lms)
1928         {
1929                 checkrules_status = WinningCondition_LMS();
1930         }
1931         else if (g_onslaught)
1932         {
1933                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1934         }
1935         else
1936         {
1937                 checkrules_status = WinningCondition_Scores(fraglimit);
1938         }
1939
1940         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1941         {
1942                 checkrules_status = WINNING_NEVER;
1943                 InitiateOvertime();
1944         }
1945
1946         if(checkrules_status == WINNING_NEVER)
1947                 // equality cases! Nobody wins if the overtime ends in a draw.
1948                 ClearWinners();
1949
1950         if(checkrules_suddendeathend)
1951                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1952                         checkrules_status = WINNING_YES;
1953
1954         if(checkrules_status == WINNING_YES)
1955                 NextLevel();
1956 };
1957
1958 float mapvote_nextthink;
1959 float mapvote_initialized;
1960 float mapvote_keeptwotime;
1961 float mapvote_timeout;
1962 string mapvote_message;
1963 string mapvote_screenshot_dir;
1964
1965 float mapvote_count;
1966 float mapvote_count_real;
1967 string mapvote_maps[MAPVOTE_COUNT];
1968 float mapvote_maps_suggested[MAPVOTE_COUNT];
1969 string mapvote_suggestions[MAPVOTE_COUNT];
1970 float mapvote_suggestion_ptr;
1971 float mapvote_maxlen;
1972 float mapvote_voters;
1973 float mapvote_votes[MAPVOTE_COUNT];
1974 float mapvote_run;
1975 float mapvote_detail;
1976 float mapvote_abstain;
1977 .float mapvote;
1978
1979 void MapVote_ClearAllVotes()
1980 {
1981         FOR_EACH_CLIENT(other)
1982                 other.mapvote = 0;
1983 }
1984
1985 string MapVote_Suggest(string m)
1986 {
1987         float i;
1988         if(m == "")
1989                 return "That's not how to use this command.";
1990         if(!cvar("g_maplist_votable_suggestions"))
1991                 return "Suggestions are not accepted on this server.";
1992         if(mapvote_initialized)
1993                 return "Can't suggest - voting is already in progress!";
1994         m = MapInfo_FixName(m);
1995         if(!m)
1996                 return "The map you suggested is not available on this server.";
1997         if(!cvar("g_maplist_votable_override_mostrecent"))
1998                 if(Map_IsRecent(m))
1999                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2000
2001         if(!MapInfo_CheckMap(m))
2002                 return "The map you suggested does not support the current game mode.";
2003         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2004                 if(mapvote_suggestions[i] == m)
2005                         return "This map was already suggested.";
2006         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2007         {
2008                 i = floor(random() * mapvote_suggestion_ptr);
2009         }
2010         else
2011         {
2012                 i = mapvote_suggestion_ptr;
2013                 mapvote_suggestion_ptr += 1;
2014         }
2015         if(mapvote_suggestions[i] != "")
2016                 strunzone(mapvote_suggestions[i]);
2017         mapvote_suggestions[i] = strzone(m);
2018         if(cvar("sv_eventlog"))
2019                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2020         return strcat("Suggestion of ", m, " accepted.");
2021 }
2022
2023 void MapVote_AddVotable(string nextMap, float isSuggestion)
2024 {
2025         float j;
2026         if(nextMap == "")
2027                 return;
2028         for(j = 0; j < mapvote_count; ++j)
2029                 if(mapvote_maps[j] == nextMap)
2030                         return;
2031         if(strlen(nextMap) > mapvote_maxlen)
2032                 mapvote_maxlen = strlen(nextMap);
2033         mapvote_maps[mapvote_count] = strzone(nextMap);
2034         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2035         mapvote_count += 1;
2036 }
2037
2038 void MapVote_Spawn();
2039 void MapVote_Init()
2040 {
2041         float i;
2042         float nmax, smax;
2043
2044         MapVote_ClearAllVotes();
2045
2046         mapvote_count = 0;
2047         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2048         mapvote_abstain = cvar("g_maplist_votable_abstain");
2049
2050         if(mapvote_abstain)
2051                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2052         else
2053                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2054         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2055
2056         if(mapvote_suggestion_ptr)
2057                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2058                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2059
2060         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2061                 MapVote_AddVotable(GetNextMap(), FALSE);
2062
2063         if(mapvote_count == 0)
2064         {
2065                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2066                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
2067                 if(cvar("g_maplist_shuffle"))
2068                         ShuffleMaplist();
2069                 localcmd("\nmenu_cmd sync\n");
2070                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2071                         MapVote_AddVotable(GetNextMap(), FALSE);
2072         }
2073
2074         mapvote_count_real = mapvote_count;
2075         if(mapvote_abstain)
2076                 MapVote_AddVotable("don't care", 0);
2077
2078         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2079
2080         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2081         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2082         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2083                 mapvote_keeptwotime = 0;
2084         mapvote_message = "Choose a map and press its key!";
2085
2086         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2087         if(mapvote_screenshot_dir == "")
2088                 mapvote_screenshot_dir = "maps";
2089         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2090
2091         MapVote_Spawn();
2092 }
2093
2094 void MapVote_SendPicture(float id)
2095 {
2096         msg_entity = self;
2097         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2098         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2099         WriteByte(MSG_ONE, id);
2100         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2101 }
2102
2103 float GameCommand_MapVote(string cmd)
2104 {
2105         if(!intermission_running)
2106                 return FALSE;
2107
2108         if(cmd == "mv_getpic")
2109         {
2110                 MapVote_SendPicture(stof(argv(1)));
2111                 return TRUE;
2112         }
2113
2114         return FALSE;
2115 }
2116
2117 float MapVote_GetMapMask()
2118 {
2119         float mask, i, power;
2120         mask = 0;
2121         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2122                 if(mapvote_maps[i] != "")
2123                         mask |= power;
2124         return mask;
2125 }
2126
2127 entity mapvote_ent;
2128 float MapVote_SendEntity(entity to, float sf)
2129 {
2130         string mapfile, pakfile;
2131         float i, o;
2132
2133         if(sf & 1)
2134                 sf &~= 2; // if we send 1, we don't need to also send 2
2135
2136         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2137         WriteByte(MSG_ENTITY, sf);
2138
2139         if(sf & 1)
2140         {
2141                 // flag 1 == initialization
2142                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2143                 WriteByte(MSG_ENTITY, mapvote_count);
2144                 WriteByte(MSG_ENTITY, mapvote_abstain);
2145                 WriteByte(MSG_ENTITY, mapvote_detail);
2146                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2147                 if(mapvote_count <= 8)
2148                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2149                 else
2150                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2151                 for(i = 0; i < mapvote_count; ++i)
2152                         if(mapvote_maps[i] != "")
2153                         {
2154                                 if(mapvote_abstain && i == mapvote_count - 1)
2155                                 {
2156                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2157                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2158                                 }
2159                                 else
2160                                 {
2161                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2162                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2163                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2164                                         if(pakfile == "")
2165                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2166                                         if(pakfile == "")
2167                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2168                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2169                                                 pakfile = substring(pakfile, o, 999);
2170                                         WriteString(MSG_ENTITY, pakfile);
2171                                 }
2172                         }
2173         }
2174
2175         if(sf & 2)
2176         {
2177                 // flag 2 == update of mask
2178                 if(mapvote_count <= 8)
2179                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2180                 else
2181                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2182         }
2183
2184         if(sf & 4)
2185         {
2186                 if(mapvote_detail)
2187                         for(i = 0; i < mapvote_count; ++i)
2188                                 if(mapvote_maps[i] != "")
2189                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2190
2191                 WriteByte(MSG_ENTITY, to.mapvote);
2192         }
2193
2194         return TRUE;
2195 }
2196
2197 void MapVote_Spawn()
2198 {
2199         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2200 }
2201
2202 void MapVote_TouchMask()
2203 {
2204         mapvote_ent.SendFlags |= 2;
2205 }
2206
2207 void MapVote_TouchVotes(entity voter)
2208 {
2209         mapvote_ent.SendFlags |= 4;
2210 }
2211
2212 float MapVote_Finished(float mappos)
2213 {
2214         string result;
2215         float i;
2216         float didntvote;
2217
2218         if(cvar("sv_eventlog"))
2219         {
2220                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2221                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2222                 didntvote = mapvote_voters;
2223                 for(i = 0; i < mapvote_count; ++i)
2224                         if(mapvote_maps[i] != "")
2225                         {
2226                                 didntvote -= mapvote_votes[i];
2227                                 if(i != mappos)
2228                                 {
2229                                         result = strcat(result, ":", mapvote_maps[i]);
2230                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2231                                 }
2232                         }
2233                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2234
2235                 GameLogEcho(result);
2236                 if(mapvote_maps_suggested[mappos])
2237                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2238         }
2239
2240         FOR_EACH_REALCLIENT(other)
2241                 FixClientCvars(other);
2242
2243         Map_Goto_SetStr(mapvote_maps[mappos]);
2244         Map_Goto();
2245         alreadychangedlevel = TRUE;
2246         return TRUE;
2247 }
2248 void MapVote_CheckRules_1()
2249 {
2250         float i;
2251
2252         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2253         {
2254                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2255                 mapvote_votes[i] = 0;
2256         }
2257
2258         mapvote_voters = 0;
2259         FOR_EACH_REALCLIENT(other)
2260         {
2261                 ++mapvote_voters;
2262                 if(other.mapvote)
2263                 {
2264                         i = other.mapvote - 1;
2265                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2266                         mapvote_votes[i] = mapvote_votes[i] + 1;
2267                 }
2268         }
2269 }
2270
2271 float MapVote_CheckRules_2()
2272 {
2273         float i;
2274         float firstPlace, secondPlace;
2275         float firstPlaceVotes, secondPlaceVotes;
2276         float mapvote_voters_real;
2277         string result;
2278
2279         if(mapvote_count_real == 1)
2280                 return MapVote_Finished(0);
2281
2282         mapvote_voters_real = mapvote_voters;
2283         if(mapvote_abstain)
2284                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2285
2286         RandomSelection_Init();
2287         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2288                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2289         firstPlace = RandomSelection_chosen_float;
2290         firstPlaceVotes = RandomSelection_best_priority;
2291         //dprint("First place: ", ftos(firstPlace), "\n");
2292         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2293
2294         RandomSelection_Init();
2295         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2296                 if(i != firstPlace)
2297                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2298         secondPlace = RandomSelection_chosen_float;
2299         secondPlaceVotes = RandomSelection_best_priority;
2300         //dprint("Second place: ", ftos(secondPlace), "\n");
2301         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2302
2303         if(firstPlace == -1)
2304                 error("No first place in map vote... WTF?");
2305
2306         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2307                 return MapVote_Finished(firstPlace);
2308
2309         if(mapvote_keeptwotime)
2310                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2311                 {
2312                         float didntvote;
2313                         MapVote_TouchMask();
2314                         mapvote_message = "Now decide between the TOP TWO!";
2315                         mapvote_keeptwotime = 0;
2316                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2317                         result = strcat(result, ":", ftos(firstPlaceVotes));
2318                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2319                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2320                         didntvote = mapvote_voters;
2321                         for(i = 0; i < mapvote_count; ++i)
2322                                 if(mapvote_maps[i] != "")
2323                                 {
2324                                         didntvote -= mapvote_votes[i];
2325                                         if(i != firstPlace)
2326                                                 if(i != secondPlace)
2327                                                 {
2328                                                         result = strcat(result, ":", mapvote_maps[i]);
2329                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2330                                                         if(i < mapvote_count_real)
2331                                                         {
2332                                                                 strunzone(mapvote_maps[i]);
2333                                                                 mapvote_maps[i] = "";
2334                                                         }
2335                                                 }
2336                                 }
2337                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2338                         if(cvar("sv_eventlog"))
2339                                 GameLogEcho(result);
2340                 }
2341
2342         return FALSE;
2343 }
2344 void MapVote_Tick()
2345 {
2346         float keeptwo;
2347         float totalvotes;
2348
2349         keeptwo = mapvote_keeptwotime;
2350         MapVote_CheckRules_1(); // count
2351         if(MapVote_CheckRules_2()) // decide
2352                 return;
2353
2354         totalvotes = 0;
2355         FOR_EACH_REALCLIENT(other)
2356         {
2357                 // hide scoreboard again
2358                 if(other.health != 2342)
2359                 {
2360                         other.health = 2342;
2361                         other.impulse = 0;
2362                         if(clienttype(other) == CLIENTTYPE_REAL)
2363                         {
2364                                 msg_entity = other;
2365                                 WriteByte(MSG_ONE, SVC_FINALE);
2366                                 WriteString(MSG_ONE, "");
2367                         }
2368                 }
2369
2370                 // clear possibly invalid votes
2371                 if(mapvote_maps[other.mapvote - 1] == "")
2372                         other.mapvote = 0;
2373                 // use impulses as new vote
2374                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2375                         if(mapvote_maps[other.impulse - 1] != "")
2376                         {
2377                                 other.mapvote = other.impulse;
2378                                 MapVote_TouchVotes(other);
2379                         }
2380                 other.impulse = 0;
2381
2382                 if(other.mapvote)
2383                         ++totalvotes;
2384         }
2385
2386         MapVote_CheckRules_1(); // just count
2387 }
2388 void MapVote_Start()
2389 {
2390         if(mapvote_run)
2391                 return;
2392
2393         MapInfo_Enumerate();
2394         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1))
2395                 mapvote_run = TRUE;
2396 }
2397 void MapVote_Think()
2398 {
2399         if(!mapvote_run)
2400                 return;
2401
2402         if(alreadychangedlevel)
2403                 return;
2404
2405         if(time < mapvote_nextthink)
2406                 return;
2407         //dprint("tick\n");
2408
2409         mapvote_nextthink = time + 0.5;
2410
2411         if(!mapvote_initialized)
2412         {
2413                 mapvote_initialized = TRUE;
2414                 if(DoNextMapOverride())
2415                         return;
2416                 if(!cvar("g_maplist_votable") || player_count <= 0)
2417                 {
2418                         GotoNextMap();
2419                         return;
2420                 }
2421                 MapVote_Init();
2422         }
2423
2424         MapVote_Tick();
2425 };
2426
2427 string GotoMap(string m)
2428 {
2429         if(!MapInfo_CheckMap(m))
2430                 return "The map you chose is not available on this server.";
2431         cvar_set("nextmap", m);
2432         cvar_set("timelimit", "-1");
2433         if(mapvote_initialized || alreadychangedlevel)
2434         {
2435                 if(DoNextMapOverride())
2436                         return "Map switch initiated.";
2437                 else
2438                         return "Hm... no. For some reason I like THIS map more.";
2439         }
2440         else
2441                 return "Map switch will happen after scoreboard.";
2442 }
2443
2444
2445 void EndFrame()
2446 {
2447         FOR_EACH_REALCLIENT(self)
2448         {
2449                 if(self.classname == "spectator")
2450                 {
2451                         if(self.enemy.typehitsound)
2452                                 play2(self, "misc/typehit.wav");
2453                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2454                                 play2(self, "misc/hit.wav");
2455                 }
2456                 else
2457                 {
2458                         if(self.typehitsound)
2459                                 play2(self, "misc/typehit.wav");
2460                         else if(self.hitsound && self.cvar_cl_hitsound)
2461                                 play2(self, "misc/hit.wav");
2462                 }
2463         }
2464         FOR_EACH_CLIENT(self)
2465         {
2466                 self.hitsound = FALSE;
2467                 self.typehitsound = FALSE;
2468         }
2469 }
2470
2471
2472 /*
2473  * RedirectionThink:
2474  * returns TRUE if redirecting
2475  */
2476 float redirection_timeout;
2477 float redirection_nextthink;
2478 float RedirectionThink()
2479 {
2480         float clients_found;
2481
2482         if(redirection_target == "")
2483                 return FALSE;
2484
2485         if(!redirection_timeout)
2486         {
2487                 cvar_set("sv_public", "-2");
2488                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2489                 if(redirection_target == "self")
2490                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2491                 else
2492                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2493         }
2494
2495         if(time < redirection_nextthink)
2496                 return TRUE;
2497
2498         redirection_nextthink = time + 1;
2499
2500         clients_found = 0;
2501         FOR_EACH_REALCLIENT(self)
2502         {
2503                 print("Redirecting: sending connect command to ", self.netname, "\n");
2504                 if(redirection_target == "self")
2505                         stuffcmd(self, "\ndisconnect; reconnect\n");
2506                 else
2507                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2508                 ++clients_found;
2509         }
2510
2511         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2512
2513         if(time > redirection_timeout || clients_found == 0)
2514                 localcmd("\nwait; wait; wait; quit\n");
2515
2516         return TRUE;
2517 }
2518
2519 void RestoreGame()
2520 {
2521         // Loaded from a save game
2522         // some things then break, so let's work around them...
2523
2524         // Progs DB (capture records)
2525         if(sv_cheats)
2526                 ServerProgsDB = db_create();
2527         else
2528                 ServerProgsDB = db_load("server.db");
2529
2530         // Mapinfo
2531         MapInfo_Shutdown();
2532         MapInfo_Enumerate();
2533         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
2534 }
2535
2536 void SV_Shutdown()
2537 {
2538         if(world_initialized > 0)
2539         {
2540                 world_initialized = 0;
2541                 print("Saving persistent data...\n");
2542                 Ban_SaveBans();
2543                 if(!sv_cheats)
2544                         db_save(ServerProgsDB, "server.db");
2545                 if(cvar("developer"))
2546                         db_save(TemporaryDB, "server-temp.db");
2547                 db_close(ServerProgsDB);
2548                 db_close(TemporaryDB);
2549                 print("done!\n");
2550                 // tell the bot system the game is ending now
2551                 bot_endgame();
2552
2553                 MapInfo_Shutdown();
2554         }
2555         else if(world_initialized == 0)
2556         {
2557                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2558         }
2559 }