data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  83                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  84                         FOR_EACH_REALPLAYER(plr) {
  85                                 plr.lastV_angle = plr.v_angle;
  86                         }
  87                         self.nextthink = time;
  88                 }
  89         }
  90         else if (timeoutStatus == 2) {
  91                 if (remainingTimeoutTime > 0) {
  92                         timeStr = getTimeoutText(0);
  93                         FOR_EACH_REALCLIENT(plr) {
  94                                 if(plr.classname == "player") {
  95                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  96                                 }
  97                         }
  98                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
  99                                 play2all("announcer/robotic/prepareforbattle.wav");
 100                         }
 101                         remainingTimeoutTime -= 1;
 102                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 103                 }
 104                 else {
 105                         //unpause the game again
 106                         remainingTimeoutTime = timeoutStatus = 0;
 107                         cvar_set("slowmo", ftos(orig_slowmo));
 108                         //and unlock the fixed view again once there is no timeout active anymore
 109                         FOR_EACH_REALPLAYER(plr) {
 110                                 plr.fixangle = FALSE;
 111                         }
 112                         //get rid of the countdown message
 113                         FOR_EACH_REALCLIENT(plr) {
 114                                 if(plr.classname == "player") {
 115                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 116                                 }
 117                         }
 118                         remove(self);
 119                         return;
 120                 }
 121
 122         }
 123         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 124                 FOR_EACH_REALCLIENT(plr) {
 125                         if(plr.classname == "player") {
 126                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 127                         }
 128                 }
 129                 remove(self);
 130                 return;
 131         }
 132 }
 133
 134 void GotoFirstMap()
 135 {
 136         float n;
 137         if(cvar("_sv_init"))
 138         {
 139                 // cvar_set("_sv_init", "0");
 140                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 141                 // to this "init" map on a dedicated server will cause no permanent
 142                 // harm
 143                 if(cvar("g_maplist_shuffle"))
 144                         ShuffleMaplist();
 145                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 146                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 147
 148                 MapInfo_Enumerate();
 149                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 0);
 150
 151                 if(!DoNextMapOverride())
 152                         GotoNextMap();
 153
 154                 return;
 155         }
 156
 157         if(time < 5)
 158         {
 159                 self.nextthink = time;
 160         }
 161         else
 162         {
 163                 self.nextthink = time + 1;
 164                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 165         }
 166 }
 167
 168 void cvar_changes_init()
 169 {
 170         float h;
 171         string k, v, d;
 172         float n, i;
 173
 174         if(cvar_changes)
 175                 strunzone(cvar_changes);
 176         cvar_changes = string_null;
 177
 178         h = buf_create();
 179         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 180         n = buf_getsize(h);
 181
 182         for(i = 0; i < n; ++i)
 183         {
 184                 k = bufstr_get(h, i);
 185
 186 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 187 #define BADCVAR(p) if(k == p) continue
 188                 // internal
 189                 BADPREFIX("csqc_");
 190                 BADPREFIX("cvar_check_");
 191                 BADCVAR("gamecfg");
 192                 BADCVAR("g_configversion");
 193                 BADCVAR("g_maplist_index");
 194                 BADCVAR("halflifebsp");
 195
 196                 // client
 197                 BADPREFIX("cl_");
 198                 BADPREFIX("con_");
 199                 BADPREFIX("g_campaign");
 200                 BADPREFIX("gl_");
 201                 BADPREFIX("joy");
 202                 BADPREFIX("menu_");
 203                 BADPREFIX("net_slist_");
 204                 BADPREFIX("r_");
 205                 BADPREFIX("sbar_");
 206                 BADPREFIX("scr_");
 207                 BADPREFIX("userbind");
 208                 BADPREFIX("v_");
 209                 BADPREFIX("vid_");
 210                 BADPREFIX("crosshair");
 211                 BADCVAR("mod_q3bsp_lightmapmergepower");
 212                 BADCVAR("mod_q3bsp_nolightmaps");
 213
 214                 // private
 215                 BADPREFIX("g_ban_");
 216                 BADPREFIX("g_chat_flood_");
 217                 BADPREFIX("rcon_");
 218                 BADPREFIX("settemp_");
 219                 BADPREFIX("sv_allowdownloads_");
 220                 BADPREFIX("sv_autodemo");
 221                 BADPREFIX("sv_curl_");
 222                 BADPREFIX("sv_eventlog");
 223                 BADPREFIX("sv_logscores_");
 224                 BADPREFIX("sv_master");
 225                 BADCVAR("g_banned_list");
 226                 BADCVAR("log_dest_udp");
 227                 BADCVAR("log_file");
 228                 BADCVAR("net_address");
 229                 BADCVAR("port");
 230                 BADCVAR("savedgamecfg");
 231                 BADCVAR("sv_heartbeatperoid");
 232                 BADCVAR("sv_vote_master_password");
 233                 BADCVAR("sys_colortranslation");
 234                 BADCVAR("sys_specialcharactertranslation");
 235                 BADCVAR("timestamps");
 236
 237                 // mapinfo
 238                 BADCVAR("timelimit");
 239                 BADCVAR("fraglimit");
 240                 BADCVAR("g_arena");
 241                 BADCVAR("g_assault");
 242                 BADCVAR("g_ctf");
 243                 BADCVAR("g_dm");
 244                 BADCVAR("g_domination");
 245                 BADCVAR("g_keyhunt");
 246                 BADCVAR("g_keyhunt_teams");
 247                 BADCVAR("g_onslaught");
 248                 BADCVAR("g_race");
 249                 BADCVAR("g_runematch");
 250                 BADCVAR("g_tdm");
 251                 BADCVAR("teamplay");
 252
 253                 // long
 254                 BADCVAR("hostname");
 255                 BADCVAR("g_maplist");
 256                 BADCVAR("g_maplist_mostrecent");
 257                 BADCVAR("sv_motd");
 258 #undef BADPREFIX
 259 #undef BADCVAR
 260
 261                 v = cvar_string(k);
 262                 d = cvar_defstring(k);
 263                 if(v != d)
 264                 {
 265                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 266                         if(strlen(cvar_changes) > 16384)
 267                         {
 268                                 cvar_changes = "// too many settings have been changed to show them here\n";
 269                                 break;
 270                         }
 271                 }
 272         }
 273         buf_del(h);
 274         if(cvar_changes == "")
 275                 cvar_changes = "// this server runs at default settings\n";
 276         else
 277                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 278         cvar_changes = strzone(cvar_changes);
 279 }
 280
 281 void detect_maptype()
 282 {
 283 #if 0
 284         vector o, v;
 285         float i;
 286
 287         for(;;)
 288         {
 289                 o = world.mins;
 290                 o_x += random() * (world.maxs_x - world.mins_x);
 291                 o_y += random() * (world.maxs_y - world.mins_y);
 292                 o_z += random() * (world.maxs_z - world.mins_z);
 293
 294                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 295                 if(trace_fraction == 1)
 296                         continue;
 297
 298                 v = trace_endpos;
 299
 300                 for(i = 0; i < 64; i += 4)
 301                 {
 302                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 303         if(trace_fraction == 1)
 304                 continue;
 305                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 306                 }
 307
 308                 break;
 309         }
 310 #endif
 311 }
 312
 313 entity randomseed;
 314 float RandomSeed_Send(entity to, float sf)
 315 {
 316         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 317         WriteShort(MSG_ENTITY, self.cnt);
 318         return TRUE;
 319 }
 320 void RandomSeed_Think()
 321 {
 322         self.cnt = bound(0, floor(random() * 65536), 65535);
 323         self.nextthink = time + 5;
 324
 325         self.SendFlags |= 1;
 326 }
 327 void RandomSeed_Spawn()
 328 {
 329         randomseed = spawn();
 330         randomseed.think = RandomSeed_Think;
 331         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 332
 333         entity oldself;
 334         oldself = self;
 335         self = randomseed;
 336         self.think(); // sets random seed and nextthink
 337         self = oldself;
 338 }
 339
 340 void spawnfunc___init_dedicated_server(void)
 341 {
 342         // handler for _init/_init map (only for dedicated server initialization)
 343
 344         world_initialized = -1; // don't complain
 345         cvar = cvar_builtin;
 346         cvar_string = cvar_string_builtin;
 347         cvar_set = cvar_set_builtin;
 348         dprint_load(); // load dprint status from cvar
 349
 350         remove = remove_unsafely;
 351
 352         entity e;
 353         e = spawn();
 354         e.think = GotoFirstMap;
 355         e.nextthink = time; // this is usually 1 at this point
 356
 357         e = spawn();
 358         e.classname = "info_player_deathmatch"; // safeguard against player joining
 359
 360         self.classname = "worldspawn"; // safeguard against various stuff ;)
 361
 362         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 363         MapInfo_Enumerate();
 364         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 0);
 365 }
 366
 367 void Map_MarkAsRecent(string m);
 368 float world_already_spawned;
 369 void RegisterWeapons();
 370 void Nagger_Init();
 371 void ClientInit_Spawn();
 372 void spawnfunc_worldspawn (void)
 373 {
 374         float fd, l, i, j, n;
 375         string s, col;
 376
 377         cvar = cvar_builtin;
 378         cvar_string = cvar_string_builtin;
 379         cvar_set = cvar_set_builtin;
 380         dprint_load(); // load dprint status from cvar
 381
 382         if(world_already_spawned)
 383                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 384         world_already_spawned = TRUE;
 385
 386         remove = remove_safely; // during spawning, watch what you remove!
 387
 388         if(cvar_string("cvar_check_default") != "bypass")
 389         {
 390                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 391                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 392
 393                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 394                         error("Config file mismatch! Please update weapons.cfg and weaponsHavoc.cfg to match the QuakeC code, and restart the engine!");
 395         }
 396
 397         compressShortVector_init();
 398
 399         local entity head;
 400         head = nextent(world);
 401         maxclients = 0;
 402         while(head)
 403         {
 404                 ++maxclients;
 405                 head = nextent(head);
 406         }
 407
 408         // needs to be done so early as they would still spawn
 409         RegisterWeapons();
 410
 411         if(sv_cheats)
 412                 ServerProgsDB = db_create();
 413         else
 414                 ServerProgsDB = db_load("server.db");
 415
 416         TemporaryDB = db_create();
 417
 418         /*
 419         TODO sound pack system
 420         // initialize sound pack system
 421         soundpack = cvar_string("g_soundpack");
 422         if(soundpack != "")
 423                 soundpack = strcat(soundpack, "/");
 424         soundpack = strzone(soundpack);
 425         */
 426
 427         // 0 normal
 428         lightstyle(0, "m");
 429
 430         // 1 FLICKER (first variety)
 431         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 432
 433         // 2 SLOW STRONG PULSE
 434         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 435
 436         // 3 CANDLE (first variety)
 437         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 438
 439         // 4 FAST STROBE
 440         lightstyle(4, "mamamamamama");
 441
 442         // 5 GENTLE PULSE 1
 443         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 444
 445         // 6 FLICKER (second variety)
 446         lightstyle(6, "nmonqnmomnmomomno");
 447
 448         // 7 CANDLE (second variety)
 449         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 450
 451         // 8 CANDLE (third variety)
 452         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 453
 454         // 9 SLOW STROBE (fourth variety)
 455         lightstyle(9, "aaaaaaaazzzzzzzz");
 456
 457         // 10 FLUORESCENT FLICKER
 458         lightstyle(10, "mmamammmmammamamaaamammma");
 459
 460         // 11 SLOW PULSE NOT FADE TO BLACK
 461         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 462
 463         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 464
 465         // 63 testing
 466         lightstyle(63, "a");
 467
 468         if(cvar("g_campaign"))
 469                 CampaignPreInit();
 470
 471         Map_MarkAsRecent(mapname);
 472
 473         precache_model ("null"); // we need this one before InitGameplayMode
 474         InitGameplayMode();
 475         readlevelcvars();
 476         GrappleHookInit();
 477
 478         player_count = 0;
 479         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 480         if(bot_waypoints_for_items == 1)
 481                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 482                         bot_waypoints_for_items = 0;
 483
 484         // for setting by mapinfo
 485         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 486         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 487
 488         precache();
 489
 490         WaypointSprite_Init();
 491
 492         //if (g_domination)
 493         //      dom_init();
 494
 495         GameLogInit(); // prepare everything
 496         if(cvar("sv_eventlog"))
 497         {
 498                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 499                 s = strcat(s, ftos(random()));
 500                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 501                 s = ":gameinfo:mutators:LIST";
 502                 if(cvar("g_grappling_hook"))
 503                         s = strcat(s, ":grappling_hook");
 504                 if(!cvar("g_use_ammunition"))
 505                         s = strcat(s, ":no_use_ammunition");
 506                 if(!cvar("g_pickup_items"))
 507                         s = strcat(s, ":no_pickup_items");
 508                 if(cvar("g_instagib"))
 509                         s = strcat(s, ":instagib");
 510                 if(cvar_string("g_weaponarena") != "0")
 511                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 512                 if(cvar("g_nixnex"))
 513                         s = strcat(s, ":nixnex");
 514                 if(cvar("g_vampire"))
 515                         s = strcat(s, ":vampire");
 516                 if(cvar("g_laserguided_missile"))
 517                         s = strcat(s, ":laserguided_missile");
 518                 if(cvar("g_norecoil"))
 519                         s = strcat(s, ":norecoil");
 520                 if(cvar("g_midair"))
 521                         s = strcat(s, ":midair");
 522                 if(cvar("g_minstagib"))
 523                         s = strcat(s, ":minstagib");
 524                 GameLogEcho(s);
 525                 GameLogEcho(":gameinfo:end");
 526         }
 527
 528         cvar_set("nextmap", "");
 529
 530         SetDefaultAlpha();
 531
 532         if(cvar("g_campaign"))
 533                 CampaignPostInit();
 534
 535         fteqcc_testbugs();
 536
 537         Ban_LoadBans();
 538
 539         //initialise globals related to sv_timeout
 540         sys_ticrate = cvar("sys_ticrate");
 541         orig_slowmo = cvar("slowmo");
 542
 543         MapInfo_Enumerate();
 544         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1);
 545
 546         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 547         {
 548                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 549                 if(fd != -1)
 550                 {
 551                         while((s = fgets(fd)))
 552                         {
 553                                 l = tokenize_sane(s);
 554                                 if(l < 2)
 555                                         continue;
 556                                 if(argv(0) == "cd")
 557                                 {
 558                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 559                                         print("  cdtrack ", argv(2), "\n");
 560                                 }
 561                                 else if(argv(0) == "fog")
 562                                 {
 563                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 564                                         print("  \"fog\" \"", s, "\"\n");
 565                                 }
 566                                 else if(argv(0) == "set")
 567                                 {
 568                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 569                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 570                                 }
 571                                 else if(argv(0) != "//")
 572                                 {
 573                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 574                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 575                                 }
 576                         }
 577                         fclose(fd);
 578                 }
 579         }
 580
 581         addstat(STAT_SYS_TICRATE, AS_FLOAT, stat_sys_ticrate);
 582         addstat(STAT_WEAPONS, AS_INT, weapons);
 583         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 584         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 585         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 586         Nagger_Init();
 587
 588         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 589         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 590
 591         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 592
 593         next_pingtime = time + 5;
 594         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 595
 596         detect_maptype();
 597
 598         lsmaps_reply = "^7Maps available: ";
 599         for(i = 0, j = 0; i < MapInfo_count; ++i)
 600         {
 601                 if(MapInfo_Get_ByID(i))
 602                         if not(MapInfo_Map_flags & MAPINFO_FLAG_HIDDEN)
 603                         {
 604                                 if(mod(i, 2))
 605                                         col = "^2";
 606                                 else
 607                                         col = "^3";
 608                                 ++j;
 609                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 610                         }
 611         }
 612         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 613
 614         maplist_reply = "^7Maps in list: ";
 615         n = tokenize_sane(cvar_string("g_maplist"));
 616         for(i = 0, j = 0; i < n; ++i)
 617         {
 618                 if(MapInfo_CheckMap(argv(i)))
 619                 {
 620                         if(mod(j, 2))
 621                                 col = "^2";
 622                         else
 623                                 col = "^3";
 624                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 625                         ++j;
 626                 }
 627         }
 628         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 629         MapInfo_ClearTemps();
 630
 631         records_reply = strzone(getrecords());
 632
 633         ClientInit_Spawn();
 634         RandomSeed_Spawn();
 635
 636         world_initialized = 1;
 637 }
 638
 639 void spawnfunc_light (void)
 640 {
 641         //makestatic (self); // Who the f___ did that?
 642         remove(self);
 643 }
 644
 645 float TryFile( string pFilename )
 646 {
 647         local float lHandle;
 648         dprint("TryFile(\"", pFilename, "\")\n");
 649         lHandle = fopen( pFilename, FILE_READ );
 650         if( lHandle != -1 ) {
 651                 fclose( lHandle );
 652                 return TRUE;
 653         } else {
 654                 return FALSE;
 655         }
 656 };
 657
 658 string GetGametype()
 659 {
 660         return GametypeNameFromType(game);
 661 }
 662
 663 string getmapname_stored;
 664 string GetMapname()
 665 {
 666         return mapname;
 667 }
 668
 669 float Map_Count, Map_Current;
 670 string Map_Current_Name;
 671
 672 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 673 float GetMaplistPosition()
 674 {
 675         float pos, idx;
 676         string map;
 677
 678         map = GetMapname();
 679         idx = cvar("g_maplist_index");
 680
 681         if(idx >= 0)
 682                 if(idx < Map_Count)
 683                         if(map == argv(idx))
 684                                 return idx;
 685
 686         for(pos = 0; pos < Map_Count; ++pos)
 687                 if(map == argv(pos))
 688                         return pos;
 689
 690         // resume normal maplist rotation if current map is not in g_maplist
 691         return idx;
 692 }
 693
 694 float MapHasRightSize(string map)
 695 {
 696         float fh;
 697         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 698         if(cvar("g_maplist_check_waypoints"))
 699         {
 700                 dprint("checkwp "); dprint(map);
 701                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 702                 if(fh < 0)
 703                 {
 704                         dprint(": no waypoints\n");
 705                         return FALSE;
 706                 }
 707                 dprint(": has waypoints\n");
 708                 fclose(fh);
 709         }
 710
 711         // open map size restriction file
 712         dprint("opensize "); dprint(map);
 713         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 714         if(fh >= 0)
 715         {
 716                 float mapmin, mapmax;
 717                 dprint(": ok, ");
 718                 mapmin = stof(fgets(fh));
 719                 mapmax = stof(fgets(fh));
 720                 fclose(fh);
 721                 if(player_count < mapmin)
 722                 {
 723                         dprint("not enough\n");
 724                         return FALSE;
 725                 }
 726                 if(player_count > mapmax)
 727                 {
 728                         dprint("too many\n");
 729                         return FALSE;
 730                 }
 731                 dprint("right size\n");
 732                 return TRUE;
 733         }
 734         dprint(": not found\n");
 735         return TRUE;
 736 }
 737
 738 string Map_Filename(float position)
 739 {
 740         return strcat("maps/", argv(position), ".bsp");
 741 }
 742
 743 string strwords(string s, float w)
 744 {
 745         float endpos;
 746         for(endpos = 0; w && endpos >= 0; --w)
 747                 endpos = strstrofs(s, " ", endpos + 1);
 748         if(endpos < 0)
 749                 return s;
 750         else
 751                 return substring(s, 0, endpos);
 752 }
 753
 754 float strhasword(string s, string w)
 755 {
 756         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 757 }
 758
 759 void Map_MarkAsRecent(string m)
 760 {
 761         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 762 }
 763
 764 float Map_IsRecent(string m)
 765 {
 766         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 767 }
 768
 769 float Map_Check(float position, float pass)
 770 {
 771         string filename;
 772         string map_next;
 773         map_next = argv(position);
 774         if(pass <= 1)
 775         {
 776                 if(Map_IsRecent(map_next))
 777                         return 0;
 778         }
 779         filename = Map_Filename(position);
 780         if(MapInfo_CheckMap(map_next))
 781         {
 782                 if(pass == 2)
 783                         return 1;
 784                 if(MapHasRightSize(map_next))
 785                         return 1;
 786                 return 0;
 787         }
 788         else
 789                 dprint( "Couldn't select '", filename, "'..\n" );
 790
 791         return 0;
 792 }
 793
 794 void Map_Goto_SetStr(string nextmapname)
 795 {
 796         if(getmapname_stored != "")
 797                 strunzone(getmapname_stored);
 798         if(nextmapname == "")
 799                 getmapname_stored = "";
 800         else
 801                 getmapname_stored = strzone(nextmapname);
 802 }
 803
 804 void Map_Goto_SetFloat(float position)
 805 {
 806         cvar_set("g_maplist_index", ftos(position));
 807         Map_Goto_SetStr(argv(position));
 808 }
 809
 810 void GameResetCfg()
 811 {
 812         // settings persist, except...
 813         if(cvar("g_campaign"))
 814                 localcmd("\nexec mutator_reset.cfg\n");
 815         localcmd("\nsettemp_restore\n");
 816 };
 817
 818 void Map_Goto()
 819 {
 820         GameResetCfg();
 821         MapInfo_LoadMap(getmapname_stored);
 822 }
 823
 824 // return codes of map selectors:
 825 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 826 //   -2 = permanent failure
 827 float() MaplistMethod_Iterate = // usual method
 828 {
 829         float pass, i;
 830
 831         for(pass = 1; pass <= 2; ++pass)
 832         {
 833                 for(i = 1; i < Map_Count; ++i)
 834                 {
 835                         float mapindex;
 836                         mapindex = mod(i + Map_Current, Map_Count);
 837                         if(Map_Check(mapindex, pass))
 838                                 return mapindex;
 839                 }
 840         }
 841         return -1;
 842 }
 843
 844 float() MaplistMethod_Repeat = // fallback method
 845 {
 846         if(Map_Check(Map_Current, 2))
 847                 return Map_Current;
 848         return -2;
 849 }
 850
 851 float() MaplistMethod_Random = // random map selection
 852 {
 853         float i, imax;
 854
 855         imax = 42;
 856
 857         for(i = 0; i <= imax; ++i)
 858         {
 859                 float mapindex;
 860                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 861                 if(Map_Check(mapindex, 1))
 862                         return mapindex;
 863         }
 864         return -1;
 865 }
 866
 867 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 868 // the exponent sets a bias on the map selection:
 869 // the higher the exponent, the less likely "shortly repeated" same maps are
 870 {
 871         float i, j, imax, insertpos;
 872
 873         imax = 42;
 874
 875         for(i = 0; i <= imax; ++i)
 876         {
 877                 string newlist;
 878
 879                 // now reinsert this at another position
 880                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 881                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 882                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 883                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 884
 885                 // insert the current map there
 886                 newlist = "";
 887                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 888                         newlist = strcat(newlist, " ", argv(j));
 889                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 890                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 891                         newlist = strcat(newlist, " ", argv(j));
 892                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 893                 cvar_set("g_maplist", newlist);
 894                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 895
 896                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 897                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 898                 if(Map_Check(Map_Current, 1))
 899                         return Map_Current;
 900         }
 901         return -1;
 902 }
 903
 904 void Maplist_Init()
 905 {
 906         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 907         if(Map_Count == 0)
 908         {
 909                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 910                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
 911                 if(cvar("g_maplist_shuffle"))
 912                         ShuffleMaplist();
 913                 localcmd("\nmenu_cmd sync\n");
 914                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 915         }
 916         if(Map_Count == 0)
 917                 error("empty maplist, cannot select a new map");
 918         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 919
 920         if(Map_Current_Name)
 921                 strunzone(Map_Current_Name);
 922         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 923         // this may or may not be correct, but who cares, in the worst case a map
 924         // isn't chosen in the first pass that should have been
 925 }
 926
 927 string GetNextMap()
 928 {
 929         float nextMap;
 930
 931         Maplist_Init();
 932         nextMap = -1;
 933
 934         if(nextMap == -1)
 935                 if(cvar("g_maplist_shuffle") > 0)
 936                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 937
 938         if(nextMap == -1)
 939                 if(cvar("g_maplist_selectrandom"))
 940                         nextMap = MaplistMethod_Random();
 941
 942         if(nextMap == -1)
 943                 nextMap = MaplistMethod_Iterate();
 944
 945         if(nextMap == -1)
 946                 nextMap = MaplistMethod_Repeat();
 947
 948         if(nextMap >= 0)
 949         {
 950                 Map_Goto_SetFloat(nextMap);
 951                 return getmapname_stored;
 952         }
 953
 954         return "";
 955 };
 956
 957 float DoNextMapOverride()
 958 {
 959         if(cvar("g_campaign"))
 960         {
 961                 CampaignPostIntermission();
 962                 alreadychangedlevel = TRUE;
 963                 return TRUE;
 964         }
 965         if(cvar("quit_when_empty"))
 966         {
 967                 if(player_count <= currentbots)
 968                 {
 969                         localcmd("quit\n");
 970                         alreadychangedlevel = TRUE;
 971                         return TRUE;
 972                 }
 973         }
 974         if(cvar_string("quit_and_redirect") != "")
 975         {
 976                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 977                 alreadychangedlevel = TRUE;
 978                 return TRUE;
 979         }
 980         if (cvar("samelevel")) // if samelevel is set, stay on same level
 981         {
 982                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 983                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 984                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 985                 localcmd("restart\n");
 986                 //changelevel (mapname);
 987                 alreadychangedlevel = TRUE;
 988                 return TRUE;
 989         }
 990         if(cvar_string("nextmap") != "")
 991                 if(MapInfo_CheckMap(cvar_string("nextmap")))
 992                 {
 993                         Map_Goto_SetStr(cvar_string("nextmap"));
 994                         Map_Goto();
 995                         alreadychangedlevel = TRUE;
 996                         return TRUE;
 997                 }
 998         if(cvar("lastlevel"))
 999         {
1000                 GameResetCfg();
1001                 localcmd("set lastlevel 0\ntogglemenu\n");
1002                 alreadychangedlevel = TRUE;
1003                 return TRUE;
1004         }
1005         return FALSE;
1006 };
1007
1008 void GotoNextMap()
1009 {
1010         //local string nextmap;
1011         //local float n, nummaps;
1012         //local string s;
1013         if (alreadychangedlevel)
1014                 return;
1015         alreadychangedlevel = TRUE;
1016
1017         {
1018                 string nextMap;
1019                 float allowReset;
1020
1021                 for(allowReset = 1; allowReset >= 0; --allowReset)
1022                 {
1023                         nextMap = GetNextMap();
1024                         if(nextMap != "")
1025                                 break;
1026
1027                         if(allowReset)
1028                         {
1029                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1030                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
1031                                 if(cvar("g_maplist_shuffle"))
1032                                         ShuffleMaplist();
1033                                 localcmd("\nmenu_cmd sync\n");
1034                         }
1035                         else
1036                         {
1037                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1038                         }
1039                 }
1040                 Map_Goto();
1041         }
1042 };
1043
1044
1045 /*
1046 ============
1047 IntermissionThink
1048
1049 When the player presses attack or jump, change to the next level
1050 ============
1051 */
1052 .float autoscreenshot;
1053 void() MapVote_Start;
1054 void() MapVote_Think;
1055 float mapvote_initialized;
1056 void IntermissionThink()
1057 {
1058         FixIntermissionClient(self);
1059
1060         if(cvar("sv_autoscreenshot"))
1061         if(self.autoscreenshot > 0)
1062         if(time > self.autoscreenshot)
1063         {
1064                 self.autoscreenshot = -1;
1065                 if(clienttype(self) == CLIENTTYPE_REAL)
1066                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1067                 return;
1068         }
1069
1070         if (time < intermission_exittime)
1071                 return;
1072
1073         if(!mapvote_initialized)
1074                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1075                         return;
1076
1077         MapVote_Start();
1078 };
1079
1080 /*
1081 ============
1082 FindIntermission
1083
1084 Returns the entity to view from
1085 ============
1086 */
1087 /*
1088 entity FindIntermission()
1089 {
1090         local   entity spot;
1091         local   float cyc;
1092
1093 // look for info_intermission first
1094         spot = find (world, classname, "info_intermission");
1095         if (spot)
1096         {       // pick a random one
1097                 cyc = random() * 4;
1098                 while (cyc > 1)
1099                 {
1100                         spot = find (spot, classname, "info_intermission");
1101                         if (!spot)
1102                                 spot = find (spot, classname, "info_intermission");
1103                         cyc = cyc - 1;
1104                 }
1105                 return spot;
1106         }
1107
1108 // then look for the start position
1109         spot = find (world, classname, "info_player_start");
1110         if (spot)
1111                 return spot;
1112
1113 // testinfo_player_start is only found in regioned levels
1114         spot = find (world, classname, "testplayerstart");
1115         if (spot)
1116                 return spot;
1117
1118 // then look for the start position
1119         spot = find (world, classname, "info_player_deathmatch");
1120         if (spot)
1121                 return spot;
1122
1123         //objerror ("FindIntermission: no spot");
1124         return world;
1125 };
1126 */
1127
1128 /*
1129 ===============================================================================
1130
1131 RULES
1132
1133 ===============================================================================
1134 */
1135
1136 void DumpStats(float final)
1137 {
1138         local float file;
1139         local string s;
1140         local float to_console;
1141         local float to_eventlog;
1142         local float to_file;
1143         local float i;
1144
1145         to_console = cvar("sv_logscores_console");
1146         to_eventlog = cvar("sv_eventlog");
1147         to_file = cvar("sv_logscores_file");
1148
1149         if(!final)
1150         {
1151                 to_console = TRUE; // always print printstats replies
1152                 to_eventlog = FALSE; // but never print them to the event log
1153         }
1154
1155         if(to_eventlog)
1156                 if(cvar("sv_eventlog_console"))
1157                         to_console = FALSE; // otherwise we get the output twice
1158
1159         if(final)
1160                 s = ":scores:";
1161         else
1162                 s = ":status:";
1163         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1164
1165         if(to_console)
1166                 print(s, "\n");
1167         if(to_eventlog)
1168                 GameLogEcho(s);
1169         if(to_file)
1170         {
1171                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1172                 if(file == -1)
1173                         to_file = FALSE;
1174                 else
1175                         fputs(file, strcat(s, "\n"));
1176         }
1177
1178         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1179         if(to_console)
1180                 print(s, "\n");
1181         if(to_eventlog)
1182                 GameLogEcho(s);
1183         if(to_file)
1184                 fputs(file, strcat(s, "\n"));
1185
1186         FOR_EACH_CLIENT(other)
1187         {
1188                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1189                 {
1190                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1191                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1192                         if(other.classname == "player" || g_arena || g_lms)
1193                                 s = strcat(s, ftos(other.team), ":");
1194                         else
1195                                 s = strcat(s, "spectator:");
1196
1197                         if(to_console)
1198                                 print(s, other.netname, "\n");
1199                         if(to_eventlog)
1200                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1201                         if(to_file)
1202                                 fputs(file, strcat(s, other.netname, "\n"));
1203                 }
1204         }
1205
1206         if(teams_matter)
1207         {
1208                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1209                 if(to_console)
1210                         print(s, "\n");
1211                 if(to_eventlog)
1212                         GameLogEcho(s);
1213                 if(to_file)
1214                         fputs(file, strcat(s, "\n"));
1215
1216                 for(i = 1; i < 16; ++i)
1217                 {
1218                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1219                         s = strcat(s, ":", ftos(i));
1220                         if(to_console)
1221                                 print(s, "\n");
1222                         if(to_eventlog)
1223                                 GameLogEcho(s);
1224                         if(to_file)
1225                                 fputs(file, strcat(s, "\n"));
1226                 }
1227         }
1228
1229         if(to_console)
1230                 print(":end\n");
1231         if(to_eventlog)
1232                 GameLogEcho(":end");
1233         if(to_file)
1234         {
1235                 fputs(file, ":end\n");
1236                 fclose(file);
1237         }
1238 }
1239
1240 void FixIntermissionClient(entity e)
1241 {
1242         string s;
1243         if(!e.autoscreenshot) // initial call
1244         {
1245                 e.angles = e.v_angle;
1246                 e.angles_x = -e.angles_x;
1247                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1248                 e.health = -2342;
1249                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1250                 e.solid = SOLID_NOT;
1251                 e.movetype = MOVETYPE_NONE;
1252                 e.takedamage = DAMAGE_NO;
1253                 if(e.weaponentity)
1254                 {
1255                         e.weaponentity.effects = EF_NODRAW;
1256                         if (e.weaponentity.weaponentity)
1257                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1258                 }
1259                 if(clienttype(e) == CLIENTTYPE_REAL)
1260                 {
1261                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1262                         s = cvar_string("sv_intermission_cdtrack");
1263                         if(s != "")
1264                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1265                         msg_entity = e;
1266                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1267                 }
1268         }
1269
1270         //e.velocity = '0 0 0';
1271         //e.fixangle = TRUE;
1272
1273         // TODO halt weapon animation
1274 }
1275
1276
1277 /*
1278 go to the next level for deathmatch
1279 only called if a time or frag limit has expired
1280 */
1281 void NextLevel()
1282 {
1283         float minTotalFrags;
1284         float maxTotalFrags;
1285         float score;
1286         float f;
1287
1288         gameover = TRUE;
1289
1290         intermission_running = 1;
1291
1292 // enforce a wait time before allowing changelevel
1293         if(player_count > 0)
1294                 intermission_exittime = time + cvar("sv_mapchange_delay");
1295         else
1296                 intermission_exittime = -1;
1297
1298         /*
1299         WriteByte (MSG_ALL, SVC_CDTRACK);
1300         WriteByte (MSG_ALL, 3);
1301         WriteByte (MSG_ALL, 3);
1302         // done in FixIntermission
1303         */
1304
1305         //pos = FindIntermission ();
1306
1307         VoteReset();
1308
1309         DumpStats(TRUE);
1310
1311         if(cvar("sv_eventlog"))
1312                 GameLogEcho(":gameover");
1313
1314         GameLogClose();
1315
1316         FOR_EACH_CLIENT(other)
1317         {
1318                 FixIntermissionClient(other);
1319
1320                 if(other.winning)
1321                         bprint(other.netname, " ^7wins.\n");
1322         }
1323
1324         minTotalFrags = 0;
1325         maxTotalFrags = 0;
1326         FOR_EACH_PLAYER(other)
1327         {
1328                 if(maxTotalFrags < other.totalfrags)
1329                         maxTotalFrags = other.totalfrags;
1330                 if(minTotalFrags > other.totalfrags)
1331                         minTotalFrags = other.totalfrags;
1332         }
1333
1334         if(!currentbots)
1335         {
1336                 FOR_EACH_PLAYER(other)
1337                 {
1338                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1339                         f = bound(0, other.play_time / max(time, 1), 1);
1340                         // store some statistics?
1341                 }
1342         }
1343
1344         if(cvar("g_campaign"))
1345                 CampaignPreIntermission();
1346
1347         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1348 };
1349
1350 /*
1351 ============
1352 CheckRules_Player
1353
1354 Exit deathmatch games upon conditions
1355 ============
1356 */
1357 void CheckRules_Player()
1358 {
1359         if (gameover)   // someone else quit the game already
1360                 return;
1361
1362         if(self.deadflag == DEAD_NO)
1363                 self.play_time += frametime;
1364
1365         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1366         //   (div0: and that in CheckRules_World please)
1367 };
1368
1369 float checkrules_oneminutewarning;
1370
1371 float checkrules_equality;
1372 float checkrules_suddendeathwarning;
1373 float checkrules_suddendeathend;
1374 float checkrules_overtimesadded; //how many overtimes have been already added
1375 float checkrules_status;
1376
1377 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1378 float WINNING_YES = 1; // winner found
1379 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1380 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1381
1382 void InitiateOvertime()
1383 {
1384         // Check first whether normal overtimes could be added before initiating suddendeath mode
1385         // - for this timelimit_overtime needs to be >0 of course
1386         // - also check the winning condition calculated in the previous frame and only add normal overtime
1387         //   again, if at the point at which timelimit would be extended again, still no winner was found
1388         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1389         {
1390                 ++checkrules_overtimesadded;
1391                 //add one more overtime by simply extending the timelimit
1392                 float tl;
1393                 tl = cvar("timelimit");
1394                 tl += cvar("timelimit_overtime");
1395                 cvar_set("timelimit", ftos(tl));
1396                 string minutesPlural;
1397                 if (cvar("timelimit_overtime") == 1)
1398                         minutesPlural = " ^3minute";
1399                 else
1400                         minutesPlural = " ^3minutes";
1401
1402                 bcenterprint(
1403                         strcat(
1404                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1405                                 ftos(cvar("timelimit_overtime")),
1406                                 minutesPlural,
1407                                 " to the game!"
1408                         )
1409                 );
1410         }
1411         else
1412         {
1413                 if(!checkrules_suddendeathend)
1414                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1415         }
1416 }
1417
1418 float GetWinningCode(float fraglimitreached, float equality)
1419 {
1420         if(equality)
1421                 if(fraglimitreached)
1422                         return WINNING_STARTSUDDENDEATHOVERTIME;
1423                 else
1424                         return WINNING_NEVER;
1425         else
1426                 if(fraglimitreached)
1427                         return WINNING_YES;
1428                 else
1429                         return WINNING_NO;
1430 }
1431
1432 // set the .winning flag for exactly those players with a given field value
1433 void SetWinners(.float field, float value)
1434 {
1435         entity head;
1436         FOR_EACH_PLAYER(head)
1437                 head.winning = (head.field == value);
1438 }
1439
1440 // set the .winning flag for those players with a given field value
1441 void AddWinners(.float field, float value)
1442 {
1443         entity head;
1444         FOR_EACH_PLAYER(head)
1445                 if(head.field == value)
1446                         head.winning = 1;
1447 }
1448
1449 // clear the .winning flags
1450 void ClearWinners(void)
1451 {
1452         entity head;
1453         FOR_EACH_PLAYER(head)
1454                 head.winning = 0;
1455 }
1456
1457 // Onslaught winning condition:
1458 // game terminates if only one team has a working generator (or none)
1459 float WinningCondition_Onslaught()
1460 {
1461         entity head;
1462         local float t1, t2, t3, t4;
1463
1464         WinningConditionHelper(); // set worldstatus
1465
1466         // first check if the game has ended
1467         t1 = t2 = t3 = t4 = 0;
1468         head = find(world, classname, "onslaught_generator");
1469         while (head)
1470         {
1471                 if (head.health > 0)
1472                 {
1473                         if (head.team == COLOR_TEAM1) t1 = 1;
1474                         if (head.team == COLOR_TEAM2) t2 = 1;
1475                         if (head.team == COLOR_TEAM3) t3 = 1;
1476                         if (head.team == COLOR_TEAM4) t4 = 1;
1477                 }
1478                 head = find(head, classname, "onslaught_generator");
1479         }
1480         if (t1 + t2 + t3 + t4 < 2)
1481         {
1482                 // game over, only one team remains (or none)
1483                 ClearWinners();
1484                 if (t1) SetWinners(team, COLOR_TEAM1);
1485                 if (t2) SetWinners(team, COLOR_TEAM2);
1486                 if (t3) SetWinners(team, COLOR_TEAM3);
1487                 if (t4) SetWinners(team, COLOR_TEAM4);
1488                 dprint("Have a winner, ending game.\n");
1489                 return WINNING_YES;
1490         }
1491
1492         // Two or more teams remain
1493         return WINNING_NO;
1494 }
1495
1496 float LMS_NewPlayerLives()
1497 {
1498         float fl;
1499         fl = cvar("fraglimit");
1500         if(fl == 0)
1501                 fl = 999;
1502
1503         // first player has left the game for dying too much? Nobody else can get in.
1504         if(lms_lowest_lives < 1)
1505                 return 0;
1506
1507         if(!cvar("g_lms_join_anytime"))
1508                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1509                         return 0;
1510
1511         return bound(1, lms_lowest_lives, fl);
1512 }
1513
1514 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1515 // they win. Otherwise the defending team wins once the timelimit passes.
1516 void assault_new_round();
1517 float WinningCondition_Assault()
1518 {
1519         local float status;
1520
1521         WinningConditionHelper(); // set worldstatus
1522
1523         status = WINNING_NO;
1524         // as the timelimit has not yet passed just assume the defending team will win
1525         if(assault_attacker_team == COLOR_TEAM1)
1526         {
1527                 SetWinners(team, COLOR_TEAM2);
1528         }
1529         else
1530         {
1531                 SetWinners(team, COLOR_TEAM1);
1532         }
1533
1534         local entity ent;
1535         ent = find(world, classname, "target_assault_roundend");
1536         if(ent)
1537         {
1538                 if(ent.winning) // round end has been triggered by attacking team
1539                 {
1540                         bprint("ASSAULT: round completed...\n");
1541                         SetWinners(team, assault_attacker_team);
1542
1543                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1544
1545                         if(ent.cnt == 1) // this was the second round
1546                         {
1547                                 status = WINNING_YES;
1548                         }
1549                         else
1550                         {
1551                                 local entity oldself;
1552                                 oldself = self;
1553                                 self = ent;
1554                                 assault_new_round();
1555                                 self = oldself;
1556                         }
1557                 }
1558         }
1559
1560         return status;
1561 }
1562
1563 // LMS winning condition: game terminates if and only if there's at most one
1564 // one player who's living lives. Top two scores being equal cancels the time
1565 // limit.
1566 float WinningCondition_LMS()
1567 {
1568         entity head, head2;
1569         float have_player;
1570         float have_players;
1571         float l;
1572
1573         have_player = FALSE;
1574         have_players = FALSE;
1575         l = LMS_NewPlayerLives();
1576
1577         head = find(world, classname, "player");
1578         if(head)
1579                 have_player = TRUE;
1580         head2 = find(head, classname, "player");
1581         if(head2)
1582                 have_players = TRUE;
1583
1584         if(have_player)
1585         {
1586                 // we have at least one player
1587                 if(have_players)
1588                 {
1589                         // two or more active players - continue with the game
1590                 }
1591                 else
1592                 {
1593                         // exactly one player?
1594
1595                         ClearWinners();
1596                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1597
1598                         if(l)
1599                         {
1600                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1601                                 return WINNING_NO;
1602                         }
1603                         else
1604                         {
1605                                 // a winner!
1606                                 // and assign him his first place
1607                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1608                                 return WINNING_YES;
1609                         }
1610                 }
1611         }
1612         else
1613         {
1614                 // nobody is playing at all...
1615                 if(l)
1616                 {
1617                         // wait for players...
1618                 }
1619                 else
1620                 {
1621                         // SNAFU (maybe a draw game?)
1622                         ClearWinners();
1623                         dprint("No players, ending game.\n");
1624                         return WINNING_YES;
1625                 }
1626         }
1627
1628         // When we get here, we have at least two players who are actually LIVING,
1629         // now check if the top two players have equal score.
1630         WinningConditionHelper();
1631
1632         ClearWinners();
1633         if(WinningConditionHelper_winner)
1634                 WinningConditionHelper_winner.winning = TRUE;
1635         if(WinningConditionHelper_equality)
1636                 return WINNING_NEVER;
1637
1638         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1639         return WINNING_NO;
1640 }
1641
1642 void ShuffleMaplist()
1643 {
1644         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1645 }
1646
1647 float leaderfrags;
1648 float WinningCondition_Scores(float limit)
1649 {
1650         // TODO make everything use THIS winning condition (except LMS)
1651         WinningConditionHelper();
1652
1653         if(teams_matter)
1654         {
1655                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1656                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1657                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1658                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1659         }
1660
1661         ClearWinners();
1662         if(WinningConditionHelper_winner)
1663                 WinningConditionHelper_winner.winning = 1;
1664         if(WinningConditionHelper_winnerteam >= 0)
1665                 SetWinners(team, WinningConditionHelper_winnerteam);
1666
1667         if(WinningConditionHelper_lowerisbetter)
1668         {
1669                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1670                 limit = -limit;
1671         }
1672
1673         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying))
1674         // these modes always score in increments of 1, thus this makes sense
1675         {
1676                 if(leaderfrags != WinningConditionHelper_topscore)
1677                 {
1678                         leaderfrags = WinningConditionHelper_topscore;
1679
1680                         if (limit)
1681                         if (leaderfrags == limit - 1)
1682                                 play2all("announcer/robotic/1fragleft.wav");
1683                         else if (leaderfrags == limit - 2)
1684                                 play2all("announcer/robotic/2fragsleft.wav");
1685                         else if (leaderfrags == limit - 3)
1686                                 play2all("announcer/robotic/3fragsleft.wav");
1687                 }
1688         }
1689
1690         return GetWinningCode(limit && WinningConditionHelper_topscore && (WinningConditionHelper_topscore >= limit), WinningConditionHelper_equality);
1691 }
1692
1693 float WinningCondition_Race(float fraglimit)
1694 {
1695         float wc;
1696         entity p;
1697         wc = WinningCondition_Scores(fraglimit);
1698
1699         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1700         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1701         // do NOT support equality when the laps are all raced!
1702         {
1703                 FOR_EACH_PLAYER(p)
1704                         if not(p.race_completed)
1705                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1706                 return WINNING_YES;
1707         }
1708         return wc;
1709 }
1710
1711 void ReadyRestart();
1712 float WinningCondition_QualifyingThenRace(float limit)
1713 {
1714         float wc;
1715         wc = WinningCondition_Scores(limit);
1716
1717         // NEVER initiate overtime
1718         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1719         {
1720                 return WINNING_YES;
1721         }
1722
1723         return wc;
1724 }
1725
1726 float WinningCondition_RanOutOfSpawns()
1727 {
1728         entity head;
1729
1730         if(!have_team_spawns)
1731                 return WINNING_NO;
1732
1733         if(!some_spawn_has_been_used)
1734                 return WINNING_NO;
1735
1736         team1_score = team2_score = team3_score = team4_score = 0;
1737
1738         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1739         {
1740                 if(head.team == COLOR_TEAM1)
1741                         team1_score = 1;
1742                 else if(head.team == COLOR_TEAM2)
1743                         team2_score = 1;
1744                 else if(head.team == COLOR_TEAM3)
1745                         team3_score = 1;
1746                 else if(head.team == COLOR_TEAM4)
1747                         team4_score = 1;
1748         }
1749
1750         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1751         {
1752                 if(head.team == COLOR_TEAM1)
1753                         team1_score = 1;
1754                 else if(head.team == COLOR_TEAM2)
1755                         team2_score = 1;
1756                 else if(head.team == COLOR_TEAM3)
1757                         team3_score = 1;
1758                 else if(head.team == COLOR_TEAM4)
1759                         team4_score = 1;
1760         }
1761
1762         ClearWinners();
1763         if(team1_score + team2_score + team3_score + team4_score == 0)
1764         {
1765                 checkrules_equality = TRUE;
1766                 return WINNING_YES;
1767         }
1768         else if(team1_score + team2_score + team3_score + team4_score == 1)
1769         {
1770                 float t, i;
1771                 if(team1_score) t = COLOR_TEAM1;
1772                 if(team2_score) t = COLOR_TEAM2;
1773                 if(team3_score) t = COLOR_TEAM3;
1774                 if(team4_score) t = COLOR_TEAM4;
1775                 CheckAllowedTeams(world);
1776                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1777                 {
1778                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1779                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1780                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1781                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1782                 }
1783
1784                 AddWinners(team, t);
1785                 return WINNING_YES;
1786         }
1787         else
1788                 return WINNING_NO;
1789 }
1790
1791 /*
1792 ============
1793 CheckRules_World
1794
1795 Exit deathmatch games upon conditions
1796 ============
1797 */
1798 void CheckRules_World()
1799 {
1800         local float timelimit;
1801         local float fraglimit;
1802
1803         VoteThink();
1804         MapVote_Think();
1805
1806         SetDefaultAlpha();
1807
1808         /*
1809         MapVote_Think should now do that part
1810         if (intermission_running)
1811                 if (time >= intermission_exittime + 60)
1812                 {
1813                         if(!DoNextMapOverride())
1814                                 GotoNextMap();
1815                         return;
1816                 }
1817         */
1818
1819         if (gameover)   // someone else quit the game already
1820         {
1821                 if(player_count == 0) // Nobody there? Then let's go to the next map
1822                         MapVote_Start();
1823                         // this will actually check the player count in the next frame
1824                         // again, but this shouldn't hurt
1825                 return;
1826         }
1827
1828         timelimit = cvar("timelimit") * 60;
1829         fraglimit = cvar("fraglimit");
1830
1831         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1832         {
1833                 if(timelimit > 0)
1834                         timelimit = 0; // timelimit is not made for warmup
1835                 if(fraglimit > 0)
1836                         fraglimit = 0; // no fraglimit for now
1837         }
1838
1839         if(timelimit > 0)
1840         {
1841                 timelimit += game_starttime;
1842         }
1843         else if (timelimit < 0)
1844         {
1845                 // endmatch
1846                 NextLevel();
1847                 return;
1848         }
1849
1850         if(checkrules_suddendeathend)
1851         {
1852                 if(!checkrules_suddendeathwarning)
1853                 {
1854                         checkrules_suddendeathwarning = TRUE;
1855                         if(g_race && !g_race_qualifying)
1856                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1857                         else
1858                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1859                 }
1860         }
1861         else
1862         {
1863                 if (timelimit && time >= timelimit)
1864                 {
1865                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1866                         {
1867                                 float totalplayers;
1868                                 float playerswithlaps;
1869                                 float readyplayers;
1870                                 entity head;
1871                                 totalplayers = playerswithlaps = readyplayers = 0;
1872                                 FOR_EACH_PLAYER(head)
1873                                 {
1874                                         ++totalplayers;
1875                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1876                                                 ++playerswithlaps;
1877                                         if(head.ready)
1878                                                 ++readyplayers;
1879                                 }
1880
1881                                 // at least 2/3 of the players have completed a lap: start the RACE
1882                                 // otherwise, the players should end the qualifying on their own
1883                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1884                                 {
1885                                         checkrules_suddendeathend = 0;
1886                                         ReadyRestart(); // go to race
1887                                 }
1888                                 else
1889                                         InitiateOvertime();
1890                         }
1891                         else
1892                                 InitiateOvertime();
1893                 }
1894         }
1895
1896         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1897         {
1898                 NextLevel();
1899                 return;
1900         }
1901
1902         if (!checkrules_oneminutewarning && timelimit > 0 && time > timelimit - 60)
1903         {
1904                 checkrules_oneminutewarning = TRUE;
1905                 play2all("announcer/robotic/1minuteremains.wav");
1906         }
1907
1908         checkrules_status = WinningCondition_RanOutOfSpawns();
1909         if(checkrules_status == WINNING_YES)
1910         {
1911                 bprint("Hey! Someone ran out of spawns!\n");
1912         }
1913         else if(g_race && !g_race_qualifying && timelimit >= 0)
1914         {
1915                 checkrules_status = WinningCondition_Race(fraglimit);
1916         }
1917         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1918         {
1919                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1920         }
1921         else if(g_assault)
1922         {
1923                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1924         }
1925         else if(g_lms)
1926         {
1927                 checkrules_status = WinningCondition_LMS();
1928         }
1929         else if (g_onslaught)
1930         {
1931                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1932         }
1933         else
1934         {
1935                 checkrules_status = WinningCondition_Scores(fraglimit);
1936         }
1937
1938         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1939         {
1940                 checkrules_status = WINNING_NEVER;
1941                 InitiateOvertime();
1942         }
1943
1944         if(checkrules_status == WINNING_NEVER)
1945                 // equality cases! Nobody wins if the overtime ends in a draw.
1946                 ClearWinners();
1947
1948         if(checkrules_suddendeathend)
1949                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1950                         checkrules_status = WINNING_YES;
1951
1952         if(checkrules_status == WINNING_YES)
1953                 NextLevel();
1954 };
1955
1956 float mapvote_nextthink;
1957 float mapvote_initialized;
1958 float mapvote_keeptwotime;
1959 float mapvote_timeout;
1960 string mapvote_message;
1961 string mapvote_screenshot_dir;
1962
1963 float mapvote_count;
1964 float mapvote_count_real;
1965 string mapvote_maps[MAPVOTE_COUNT];
1966 float mapvote_maps_suggested[MAPVOTE_COUNT];
1967 string mapvote_suggestions[MAPVOTE_COUNT];
1968 float mapvote_suggestion_ptr;
1969 float mapvote_maxlen;
1970 float mapvote_voters;
1971 float mapvote_votes[MAPVOTE_COUNT];
1972 float mapvote_run;
1973 float mapvote_detail;
1974 float mapvote_abstain;
1975 .float mapvote;
1976
1977 void MapVote_ClearAllVotes()
1978 {
1979         FOR_EACH_CLIENT(other)
1980                 other.mapvote = 0;
1981 }
1982
1983 string MapVote_Suggest(string m)
1984 {
1985         float i;
1986         if(m == "")
1987                 return "That's not how to use this command.";
1988         if(!cvar("g_maplist_votable_suggestions"))
1989                 return "Suggestions are not accepted on this server.";
1990         if(mapvote_initialized)
1991                 return "Can't suggest - voting is already in progress!";
1992         m = MapInfo_FixName(m);
1993         if(!m)
1994                 return "The map you suggested is not available on this server.";
1995         if(!cvar("g_maplist_votable_override_mostrecent"))
1996                 if(Map_IsRecent(m))
1997                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
1998
1999         if(!MapInfo_CheckMap(m))
2000                 return "The map you suggested does not support the current game mode.";
2001         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2002                 if(mapvote_suggestions[i] == m)
2003                         return "This map was already suggested.";
2004         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2005         {
2006                 i = floor(random() * mapvote_suggestion_ptr);
2007         }
2008         else
2009         {
2010                 i = mapvote_suggestion_ptr;
2011                 mapvote_suggestion_ptr += 1;
2012         }
2013         if(mapvote_suggestions[i] != "")
2014                 strunzone(mapvote_suggestions[i]);
2015         mapvote_suggestions[i] = strzone(m);
2016         if(cvar("sv_eventlog"))
2017                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2018         return strcat("Suggestion of ", m, " accepted.");
2019 }
2020
2021 void MapVote_AddVotable(string nextMap, float isSuggestion)
2022 {
2023         float j;
2024         if(nextMap == "")
2025                 return;
2026         for(j = 0; j < mapvote_count; ++j)
2027                 if(mapvote_maps[j] == nextMap)
2028                         return;
2029         if(strlen(nextMap) > mapvote_maxlen)
2030                 mapvote_maxlen = strlen(nextMap);
2031         mapvote_maps[mapvote_count] = strzone(nextMap);
2032         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2033         mapvote_count += 1;
2034 }
2035
2036 void MapVote_Spawn();
2037 void MapVote_Init()
2038 {
2039         float i;
2040         float nmax, smax;
2041
2042         MapVote_ClearAllVotes();
2043
2044         mapvote_count = 0;
2045         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2046         mapvote_abstain = cvar("g_maplist_votable_abstain");
2047
2048         if(mapvote_abstain)
2049                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2050         else
2051                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2052         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2053
2054         if(mapvote_suggestion_ptr)
2055                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2056                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2057
2058         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2059                 MapVote_AddVotable(GetNextMap(), FALSE);
2060
2061         if(mapvote_count == 0)
2062         {
2063                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2064                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN));
2065                 if(cvar("g_maplist_shuffle"))
2066                         ShuffleMaplist();
2067                 localcmd("\nmenu_cmd sync\n");
2068                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2069                         MapVote_AddVotable(GetNextMap(), FALSE);
2070         }
2071
2072         mapvote_count_real = mapvote_count;
2073         if(mapvote_abstain)
2074                 MapVote_AddVotable("don't care", 0);
2075
2076         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2077
2078         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2079         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2080         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2081                 mapvote_keeptwotime = 0;
2082         mapvote_message = "Choose a map and press its key!";
2083
2084         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2085         if(mapvote_screenshot_dir == "")
2086                 mapvote_screenshot_dir = "maps";
2087         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2088
2089         MapVote_Spawn();
2090 }
2091
2092 void MapVote_SendPicture(float id)
2093 {
2094         msg_entity = self;
2095         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2096         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2097         WriteByte(MSG_ONE, id);
2098         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2099 }
2100
2101 float GameCommand_MapVote(string cmd)
2102 {
2103         if(!intermission_running)
2104                 return FALSE;
2105
2106         if(cmd == "mv_getpic")
2107         {
2108                 MapVote_SendPicture(stof(argv(1)));
2109                 return TRUE;
2110         }
2111
2112         return FALSE;
2113 }
2114
2115 float MapVote_GetMapMask()
2116 {
2117         float mask, i, power;
2118         mask = 0;
2119         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2120                 if(mapvote_maps[i] != "")
2121                         mask |= power;
2122         return mask;
2123 }
2124
2125 entity mapvote_ent;
2126 float MapVote_SendEntity(entity to, float sf)
2127 {
2128         string mapfile, pakfile;
2129         float i, o;
2130
2131         if(sf & 1)
2132                 sf &~= 2; // if we send 1, we don't need to also send 2
2133
2134         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2135         WriteByte(MSG_ENTITY, sf);
2136
2137         if(sf & 1)
2138         {
2139                 // flag 1 == initialization
2140                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2141                 WriteByte(MSG_ENTITY, mapvote_count);
2142                 WriteByte(MSG_ENTITY, mapvote_abstain);
2143                 WriteByte(MSG_ENTITY, mapvote_detail);
2144                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2145                 if(mapvote_count <= 8)
2146                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2147                 else
2148                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2149                 for(i = 0; i < mapvote_count; ++i)
2150                         if(mapvote_maps[i] != "")
2151                         {
2152                                 if(mapvote_abstain && i == mapvote_count - 1)
2153                                 {
2154                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2155                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2156                                 }
2157                                 else
2158                                 {
2159                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2160                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2161                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2162                                         if(pakfile == "")
2163                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2164                                         if(pakfile == "")
2165                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2166                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2167                                                 pakfile = substring(pakfile, o, 999);
2168                                         WriteString(MSG_ENTITY, pakfile);
2169                                 }
2170                         }
2171         }
2172
2173         if(sf & 2)
2174         {
2175                 // flag 2 == update of mask
2176                 if(mapvote_count <= 8)
2177                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2178                 else
2179                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2180         }
2181
2182         if(sf & 4)
2183         {
2184                 if(mapvote_detail)
2185                         for(i = 0; i < mapvote_count; ++i)
2186                                 if(mapvote_maps[i] != "")
2187                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2188
2189                 WriteByte(MSG_ENTITY, to.mapvote);
2190         }
2191
2192         return TRUE;
2193 }
2194
2195 void MapVote_Spawn()
2196 {
2197         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2198 }
2199
2200 void MapVote_TouchMask()
2201 {
2202         mapvote_ent.SendFlags |= 2;
2203 }
2204
2205 void MapVote_TouchVotes(entity voter)
2206 {
2207         mapvote_ent.SendFlags |= 4;
2208 }
2209
2210 float MapVote_Finished(float mappos)
2211 {
2212         string result;
2213         float i;
2214         float didntvote;
2215
2216         if(cvar("sv_eventlog"))
2217         {
2218                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2219                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2220                 didntvote = mapvote_voters;
2221                 for(i = 0; i < mapvote_count; ++i)
2222                         if(mapvote_maps[i] != "")
2223                         {
2224                                 didntvote -= mapvote_votes[i];
2225                                 if(i != mappos)
2226                                 {
2227                                         result = strcat(result, ":", mapvote_maps[i]);
2228                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2229                                 }
2230                         }
2231                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2232
2233                 GameLogEcho(result);
2234                 if(mapvote_maps_suggested[mappos])
2235                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2236         }
2237
2238         FOR_EACH_REALCLIENT(other)
2239                 FixClientCvars(other);
2240
2241         Map_Goto_SetStr(mapvote_maps[mappos]);
2242         Map_Goto();
2243         alreadychangedlevel = TRUE;
2244         return TRUE;
2245 }
2246 void MapVote_CheckRules_1()
2247 {
2248         float i;
2249
2250         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2251         {
2252                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2253                 mapvote_votes[i] = 0;
2254         }
2255
2256         mapvote_voters = 0;
2257         FOR_EACH_REALCLIENT(other)
2258         {
2259                 ++mapvote_voters;
2260                 if(other.mapvote)
2261                 {
2262                         i = other.mapvote - 1;
2263                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2264                         mapvote_votes[i] = mapvote_votes[i] + 1;
2265                 }
2266         }
2267 }
2268
2269 float MapVote_CheckRules_2()
2270 {
2271         float i;
2272         float firstPlace, secondPlace;
2273         float firstPlaceVotes, secondPlaceVotes;
2274         float mapvote_voters_real;
2275         string result;
2276
2277         if(mapvote_count_real == 1)
2278                 return MapVote_Finished(0);
2279
2280         mapvote_voters_real = mapvote_voters;
2281         if(mapvote_abstain)
2282                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2283
2284         RandomSelection_Init();
2285         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2286                 RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2287         firstPlace = RandomSelection_chosen_float;
2288         firstPlaceVotes = RandomSelection_best_priority;
2289         //dprint("First place: ", ftos(firstPlace), "\n");
2290         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2291
2292         RandomSelection_Init();
2293         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2294                 if(i != firstPlace)
2295                         RandomSelection_Add(world, i, 1, mapvote_votes[i]);
2296         secondPlace = RandomSelection_chosen_float;
2297         secondPlaceVotes = RandomSelection_best_priority;
2298         //dprint("Second place: ", ftos(secondPlace), "\n");
2299         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2300
2301         if(firstPlace == -1)
2302                 error("No first place in map vote... WTF?");
2303
2304         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2305                 return MapVote_Finished(firstPlace);
2306
2307         if(mapvote_keeptwotime)
2308                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2309                 {
2310                         float didntvote;
2311                         MapVote_TouchMask();
2312                         mapvote_message = "Now decide between the TOP TWO!";
2313                         mapvote_keeptwotime = 0;
2314                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2315                         result = strcat(result, ":", ftos(firstPlaceVotes));
2316                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2317                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2318                         didntvote = mapvote_voters;
2319                         for(i = 0; i < mapvote_count; ++i)
2320                                 if(mapvote_maps[i] != "")
2321                                 {
2322                                         didntvote -= mapvote_votes[i];
2323                                         if(i != firstPlace)
2324                                                 if(i != secondPlace)
2325                                                 {
2326                                                         result = strcat(result, ":", mapvote_maps[i]);
2327                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2328                                                         if(i < mapvote_count_real)
2329                                                         {
2330                                                                 strunzone(mapvote_maps[i]);
2331                                                                 mapvote_maps[i] = "";
2332                                                         }
2333                                                 }
2334                                 }
2335                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2336                         if(cvar("sv_eventlog"))
2337                                 GameLogEcho(result);
2338                 }
2339
2340         return FALSE;
2341 }
2342 void MapVote_Tick()
2343 {
2344         float keeptwo;
2345         float totalvotes;
2346
2347         keeptwo = mapvote_keeptwotime;
2348         MapVote_CheckRules_1(); // count
2349         if(MapVote_CheckRules_2()) // decide
2350                 return;
2351
2352         totalvotes = 0;
2353         FOR_EACH_REALCLIENT(other)
2354         {
2355                 // hide scoreboard again
2356                 if(other.health != 2342)
2357                 {
2358                         other.health = 2342;
2359                         other.impulse = 0;
2360                         if(clienttype(other) == CLIENTTYPE_REAL)
2361                         {
2362                                 msg_entity = other;
2363                                 WriteByte(MSG_ONE, SVC_FINALE);
2364                                 WriteString(MSG_ONE, "");
2365                         }
2366                 }
2367
2368                 // clear possibly invalid votes
2369                 if(mapvote_maps[other.mapvote - 1] == "")
2370                         other.mapvote = 0;
2371                 // use impulses as new vote
2372                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2373                         if(mapvote_maps[other.impulse - 1] != "")
2374                         {
2375                                 other.mapvote = other.impulse;
2376                                 MapVote_TouchVotes(other);
2377                         }
2378                 other.impulse = 0;
2379
2380                 if(other.mapvote)
2381                         ++totalvotes;
2382         }
2383
2384         MapVote_CheckRules_1(); // just count
2385 }
2386 void MapVote_Start()
2387 {
2388         if(mapvote_run)
2389                 return;
2390
2391         MapInfo_Enumerate();
2392         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1))
2393                 mapvote_run = TRUE;
2394 }
2395 void MapVote_Think()
2396 {
2397         if(!mapvote_run)
2398                 return;
2399
2400         if(alreadychangedlevel)
2401                 return;
2402
2403         if(time < mapvote_nextthink)
2404                 return;
2405         //dprint("tick\n");
2406
2407         mapvote_nextthink = time + 0.5;
2408
2409         if(!mapvote_initialized)
2410         {
2411                 mapvote_initialized = TRUE;
2412                 if(DoNextMapOverride())
2413                         return;
2414                 if(!cvar("g_maplist_votable") || player_count <= 0)
2415                 {
2416                         GotoNextMap();
2417                         return;
2418                 }
2419                 MapVote_Init();
2420         }
2421
2422         MapVote_Tick();
2423 };
2424
2425 string GotoMap(string m)
2426 {
2427         if(!MapInfo_CheckMap(m))
2428                 return "The map you chose is not available on this server.";
2429         cvar_set("nextmap", m);
2430         cvar_set("timelimit", "-1");
2431         if(mapvote_initialized || alreadychangedlevel)
2432         {
2433                 if(DoNextMapOverride())
2434                         return "Map switch initiated.";
2435                 else
2436                         return "Hm... no. For some reason I like THIS map more.";
2437         }
2438         else
2439                 return "Map switch will happen after scoreboard.";
2440 }
2441
2442
2443 void EndFrame()
2444 {
2445         FOR_EACH_REALCLIENT(self)
2446         {
2447                 if(self.classname == "spectator")
2448                 {
2449                         if(self.enemy.typehitsound)
2450                                 play2(self, "misc/typehit.wav");
2451                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2452                                 play2(self, "misc/hit.wav");
2453                 }
2454                 else
2455                 {
2456                         if(self.typehitsound)
2457                                 play2(self, "misc/typehit.wav");
2458                         else if(self.hitsound && self.cvar_cl_hitsound)
2459                                 play2(self, "misc/hit.wav");
2460                 }
2461         }
2462         FOR_EACH_CLIENT(self)
2463         {
2464                 self.hitsound = FALSE;
2465                 self.typehitsound = FALSE;
2466         }
2467 }
2468
2469
2470 /*
2471  * RedirectionThink:
2472  * returns TRUE if redirecting
2473  */
2474 float redirection_timeout;
2475 float redirection_nextthink;
2476 float RedirectionThink()
2477 {
2478         float clients_found;
2479
2480         if(redirection_target == "")
2481                 return FALSE;
2482
2483         if(!redirection_timeout)
2484         {
2485                 cvar_set("sv_public", "-2");
2486                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2487                 if(redirection_target == "self")
2488                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2489                 else
2490                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2491         }
2492
2493         if(time < redirection_nextthink)
2494                 return TRUE;
2495
2496         redirection_nextthink = time + 1;
2497
2498         clients_found = 0;
2499         FOR_EACH_REALCLIENT(self)
2500         {
2501                 print("Redirecting: sending connect command to ", self.netname, "\n");
2502                 if(redirection_target == "self")
2503                         stuffcmd(self, "\ndisconnect; reconnect\n");
2504                 else
2505                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2506                 ++clients_found;
2507         }
2508
2509         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2510
2511         if(time > redirection_timeout || clients_found == 0)
2512                 localcmd("\nwait; wait; wait; quit\n");
2513
2514         return TRUE;
2515 }
2516
2517 void RestoreGame()
2518 {
2519         // Loaded from a save game
2520         // some things then break, so let's work around them...
2521
2522         // Progs DB (capture records)
2523         if(sv_cheats)
2524                 ServerProgsDB = db_create();
2525         else
2526                 ServerProgsDB = db_load("server.db");
2527
2528         // Mapinfo
2529         MapInfo_Shutdown();
2530         MapInfo_Enumerate();
2531         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN), 1);
2532 }
2533
2534 void SV_Shutdown()
2535 {
2536         if(world_initialized > 0)
2537         {
2538                 world_initialized = 0;
2539                 print("Saving persistent data...\n");
2540                 Ban_SaveBans();
2541                 if(!sv_cheats)
2542                         db_save(ServerProgsDB, "server.db");
2543                 if(cvar("developer"))
2544                         db_save(TemporaryDB, "server-temp.db");
2545                 db_close(ServerProgsDB);
2546                 db_close(TemporaryDB);
2547                 print("done!\n");
2548                 // tell the bot system the game is ending now
2549                 bot_endgame();
2550
2551                 MapInfo_Shutdown();
2552         }
2553         else if(world_initialized == 0)
2554         {
2555                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2556         }
2557 }