data/qcsrc/server/g_world.qc

   1 float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
   2 string redirection_target;
   3 float world_initialized;
   4
   5 string GetMapname();
   6 string GetGametype();
   7 void GotoNextMap();
   8 void ShuffleMaplist()
   9 float() DoNextMapOverride;
  10
  11 void SetDefaultAlpha()
  12 {
  13         if(cvar("g_running_guns"))
  14         {
  15                 default_player_alpha = -1;
  16                 default_weapon_alpha = +1;
  17         }
  18         else if(g_cloaked)
  19         {
  20                 default_player_alpha = cvar("g_balance_cloaked_alpha");
  21                 default_weapon_alpha = default_player_alpha;
  22         }
  23         else
  24         {
  25                 default_player_alpha = cvar("g_player_alpha");
  26                 if(default_player_alpha == 0)
  27                         default_player_alpha = 1;
  28                 default_weapon_alpha = default_player_alpha;
  29         }
  30 }
  31
  32 void fteqcc_testbugs()
  33 {
  34         float a, b;
  35
  36         if(!cvar("developer_fteqccbugs"))
  37                 return;
  38
  39         dprint("*** fteqcc test: checking for bugs...\n");
  40
  41         a = 1;
  42         b = 5;
  43         if(sqrt(a) - sqrt(b - a) == 0)
  44                 dprint("*** fteqcc test: found same-function-twice bug\n");
  45         else
  46                 dprint("*** fteqcc test: same-function-twice bug got FINALLY FIXED! HOORAY!\n");
  47
  48         world.cnt = -10;
  49         world.enemy = world;
  50         world.enemy.cnt += 10;
  51         if(world.cnt > 0.2 || world.cnt < -0.2) // don't error out if it's just roundoff errors
  52                 dprint("*** fteqcc test: found += bug\n");
  53         else
  54                 dprint("*** fteqcc test: += bug got FINALLY FIXED! HOORAY!\n");
  55         world.cnt = 0;
  56 }
  57
  58 /**
  59  * Takes care of pausing and unpausing the game.
  60  * Centerprints the information about an upcoming or active timeout to all active
  61  * players. Also plays reminder sounds.
  62  */
  63 void timeoutHandler_Think() {
  64         local string timeStr;
  65         local entity plr;
  66         if (timeoutStatus == 1) {
  67                 if (remainingLeadTime > 0) {
  68                         //centerprint the information to every player
  69                         timeStr = getTimeoutText(0);
  70                         FOR_EACH_REALCLIENT(plr) {
  71                                 if(plr.classname == "player") {
  72                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
  73                                 }
  74                         }
  75                         remainingLeadTime -= 1;
  76                         //think again in 1 second:
  77                         self.nextthink = time + 1;
  78                 }
  79                 else {
  80                         //now pause the game:
  81                         timeoutStatus = 2;
  82                         //reset all the flood variables
  83                         FOR_EACH_CLIENT(plr) {
  84                                 plr.nickspamcount = plr.nickspamtime = plr.floodcontrol_chat = plr.floodcontrol_chatteam = plr.floodcontrol_chattell = plr.floodcontrol_voice = plr.floodcontrol_voiceteam = 0;
  85                         }
  86                         cvar_set("slowmo", ftos(TIMEOUT_SLOWMO_VALUE));
  87                         //copy .v_angle to .lastV_angle for every player in order to fix their view during pause (see PlayerPreThink)
  88                         FOR_EACH_REALPLAYER(plr) {
  89                                 plr.lastV_angle = plr.v_angle;
  90                         }
  91                         self.nextthink = time;
  92                 }
  93         }
  94         else if (timeoutStatus == 2) {
  95                 if (remainingTimeoutTime > 0) {
  96                         timeStr = getTimeoutText(0);
  97                         FOR_EACH_REALCLIENT(plr) {
  98                                 if(plr.classname == "player") {
  99                                         centerprint_atprio(plr, CENTERPRIO_SPAM, timeStr);
 100                                 }
 101                         }
 102                         if(remainingTimeoutTime == cvar("sv_timeout_resumetime")) { //play a warning sound when only <sv_timeout_resumetime> seconds are left
 103                                 play2all("announcer/robotic/prepareforbattle.wav");
 104                         }
 105                         remainingTimeoutTime -= 1;
 106                         self.nextthink = time + TIMEOUT_SLOWMO_VALUE;
 107                 }
 108                 else {
 109                         //unpause the game again
 110                         remainingTimeoutTime = timeoutStatus = 0;
 111                         cvar_set("slowmo", ftos(orig_slowmo));
 112                         //and unlock the fixed view again once there is no timeout active anymore
 113                         FOR_EACH_REALPLAYER(plr) {
 114                                 plr.fixangle = FALSE;
 115                         }
 116                         //get rid of the countdown message
 117                         FOR_EACH_REALCLIENT(plr) {
 118                                 if(plr.classname == "player") {
 119                                         centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 120                                 }
 121                         }
 122                         remove(self);
 123                         return;
 124                 }
 125
 126         }
 127         else if (timeoutStatus == 0) { //if a player called the resumegame command (which set timeoutStatus to 0 already)
 128                 FOR_EACH_REALCLIENT(plr) {
 129                         if(plr.classname == "player") {
 130                                 centerprint_atprio(plr, CENTERPRIO_SPAM, "");
 131                         }
 132                 }
 133                 remove(self);
 134                 return;
 135         }
 136 }
 137
 138 void GotoFirstMap()
 139 {
 140         float n;
 141         if(cvar("_sv_init"))
 142         {
 143                 // cvar_set("_sv_init", "0");
 144                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 145                 // to this "init" map on a dedicated server will cause no permanent
 146                 // harm
 147                 if(cvar("g_maplist_shuffle"))
 148                         ShuffleMaplist();
 149                 n = tokenizebyseparator(cvar_string("g_maplist"), " ");
 150                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 151
 152                 MapInfo_Enumerate();
 153                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 154
 155                 if(!DoNextMapOverride())
 156                         GotoNextMap();
 157
 158                 return;
 159         }
 160
 161         if(time < 5)
 162         {
 163                 self.nextthink = time;
 164         }
 165         else
 166         {
 167                 self.nextthink = time + 1;
 168                 print("Waiting for _sv_init being set to 1 by initialization scripts...\n");
 169         }
 170 }
 171
 172 void cvar_changes_init()
 173 {
 174         float h;
 175         string k, v, d;
 176         float n, i;
 177
 178         if(cvar_changes)
 179                 strunzone(cvar_changes);
 180         cvar_changes = string_null;
 181
 182         h = buf_create();
 183         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 184         n = buf_getsize(h);
 185
 186         for(i = 0; i < n; ++i)
 187         {
 188                 k = bufstr_get(h, i);
 189
 190 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 191 #define BADCVAR(p) if(k == p) continue
 192                 // internal
 193                 BADPREFIX("csqc_");
 194                 BADPREFIX("cvar_check_");
 195                 BADCVAR("gamecfg");
 196                 BADCVAR("g_configversion");
 197                 BADCVAR("g_maplist_index");
 198                 BADCVAR("halflifebsp");
 199
 200                 // client
 201                 BADPREFIX("cl_");
 202                 BADPREFIX("con_");
 203                 BADPREFIX("g_campaign");
 204                 BADPREFIX("gl_");
 205                 BADPREFIX("joy");
 206                 BADPREFIX("menu_");
 207                 BADPREFIX("net_slist_");
 208                 BADPREFIX("r_");
 209                 BADPREFIX("sbar_");
 210                 BADPREFIX("scr_");
 211                 BADPREFIX("userbind");
 212                 BADPREFIX("v_");
 213                 BADPREFIX("vid_");
 214                 BADPREFIX("crosshair");
 215                 BADCVAR("mod_q3bsp_lightmapmergepower");
 216                 BADCVAR("mod_q3bsp_nolightmaps");
 217
 218                 // private
 219                 BADPREFIX("g_ban_");
 220                 BADPREFIX("g_chat_flood_");
 221                 BADPREFIX("g_voice_flood_");
 222                 BADPREFIX("rcon_");
 223                 BADPREFIX("settemp_");
 224                 BADPREFIX("sv_allowdownloads_");
 225                 BADPREFIX("sv_autodemo");
 226                 BADPREFIX("sv_curl_");
 227                 BADPREFIX("sv_eventlog");
 228                 BADPREFIX("sv_logscores_");
 229                 BADPREFIX("sv_master");
 230                 BADCVAR("g_banned_list");
 231                 BADCVAR("log_dest_udp");
 232                 BADCVAR("log_file");
 233                 BADCVAR("net_address");
 234                 BADCVAR("port");
 235                 BADCVAR("savedgamecfg");
 236                 BADCVAR("sv_heartbeatperoid");
 237                 BADCVAR("sv_vote_master_password");
 238                 BADCVAR("sys_colortranslation");
 239                 BADCVAR("sys_specialcharactertranslation");
 240                 BADCVAR("timestamps");
 241
 242                 // mapinfo
 243                 BADCVAR("timelimit");
 244                 BADCVAR("fraglimit");
 245                 BADCVAR("g_arena");
 246                 BADCVAR("g_assault");
 247                 BADCVAR("g_ctf");
 248                 BADCVAR("g_dm");
 249                 BADCVAR("g_domination");
 250                 BADCVAR("g_keyhunt");
 251                 BADCVAR("g_keyhunt_teams");
 252                 BADCVAR("g_onslaught");
 253                 BADCVAR("g_race");
 254                 BADCVAR("g_runematch");
 255                 BADCVAR("g_tdm");
 256                 BADCVAR("teamplay");
 257
 258                 // long
 259                 BADCVAR("hostname");
 260                 BADCVAR("g_maplist");
 261                 BADCVAR("g_maplist_mostrecent");
 262                 BADCVAR("sv_motd");
 263 #undef BADPREFIX
 264 #undef BADCVAR
 265
 266                 v = cvar_string(k);
 267                 d = cvar_defstring(k);
 268                 if(v != d)
 269                 {
 270                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 271                         if(strlen(cvar_changes) > 16384)
 272                         {
 273                                 cvar_changes = "// too many settings have been changed to show them here\n";
 274                                 break;
 275                         }
 276                 }
 277         }
 278         buf_del(h);
 279         if(cvar_changes == "")
 280                 cvar_changes = "// this server runs at default settings\n";
 281         else
 282                 cvar_changes = strcat("// this server runs at modified settings:\n", cvar_changes);
 283         cvar_changes = strzone(cvar_changes);
 284 }
 285
 286 void detect_maptype()
 287 {
 288 #if 0
 289         vector o, v;
 290         float i;
 291
 292         for(;;)
 293         {
 294                 o = world.mins;
 295                 o_x += random() * (world.maxs_x - world.mins_x);
 296                 o_y += random() * (world.maxs_y - world.mins_y);
 297                 o_z += random() * (world.maxs_z - world.mins_z);
 298
 299                 tracebox(o, PL_MIN, PL_MAX, o - '0 0 32768', MOVE_WORLDONLY, world);
 300                 if(trace_fraction == 1)
 301                         continue;
 302
 303                 v = trace_endpos;
 304
 305                 for(i = 0; i < 64; i += 4)
 306                 {
 307                         tracebox(o, '-1 -1 -1' * i, '1 1 1' * i, o - '0 0 32768', MOVE_WORLDONLY, world);
 308         if(trace_fraction == 1)
 309                 continue;
 310                         print(ftos(i), " -> ", vtos(trace_endpos), "\n");
 311                 }
 312
 313                 break;
 314         }
 315 #endif
 316 }
 317
 318 entity randomseed;
 319 float RandomSeed_Send(entity to, float sf)
 320 {
 321         WriteByte(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 322         WriteShort(MSG_ENTITY, self.cnt);
 323         return TRUE;
 324 }
 325 void RandomSeed_Think()
 326 {
 327         self.cnt = bound(0, floor(random() * 65536), 65535);
 328         self.nextthink = time + 5;
 329
 330         self.SendFlags |= 1;
 331 }
 332 void RandomSeed_Spawn()
 333 {
 334         randomseed = spawn();
 335         randomseed.think = RandomSeed_Think;
 336         Net_LinkEntity(randomseed, FALSE, 0, RandomSeed_Send);
 337
 338         entity oldself;
 339         oldself = self;
 340         self = randomseed;
 341         self.think(); // sets random seed and nextthink
 342         self = oldself;
 343 }
 344
 345 void spawnfunc___init_dedicated_server(void)
 346 {
 347         // handler for _init/_init map (only for dedicated server initialization)
 348
 349         world_initialized = -1; // don't complain
 350         cvar = cvar_builtin;
 351         cvar_string = cvar_string_builtin;
 352         cvar_set = cvar_set_builtin;
 353         dprint_load(); // load dprint status from cvar
 354
 355         remove = remove_unsafely;
 356
 357         entity e;
 358         e = spawn();
 359         e.think = GotoFirstMap;
 360         e.nextthink = time; // this is usually 1 at this point
 361
 362         e = spawn();
 363         e.classname = "info_player_deathmatch"; // safeguard against player joining
 364
 365         self.classname = "worldspawn"; // safeguard against various stuff ;)
 366
 367         g_maplist_allow_hidden = cvar("g_maplist_allow_hidden");
 368         MapInfo_Enumerate();
 369         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 0);
 370 }
 371
 372 void Map_MarkAsRecent(string m);
 373 float world_already_spawned;
 374 void RegisterWeapons();
 375 void Nagger_Init();
 376 void ClientInit_Spawn();
 377 void spawnfunc_worldspawn (void)
 378 {
 379         float fd, l, i, j, n;
 380         string s, col;
 381
 382         cvar = cvar_builtin;
 383         cvar_string = cvar_string_builtin;
 384         cvar_set = cvar_set_builtin;
 385         dprint_load(); // load dprint status from cvar
 386
 387         if(world_already_spawned)
 388                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 389         world_already_spawned = TRUE;
 390
 391         remove = remove_safely; // during spawning, watch what you remove!
 392
 393         check_unacceptable_compiler_bugs();
 394
 395         if(cvar_string("cvar_check_default") != "bypass")
 396         {
 397                 if(cvar_string("cvar_check_default") != CVAR_CHECK_DEFAULT)
 398                         error("Config file mismatch! Please update defaultNexuiz.cfg to match the QuakeC code, and restart the engine!");
 399
 400                 if(cvar_string("cvar_check_weapons") != CVAR_CHECK_WEAPONS)
 401                         error("Config file mismatch! Please update weapons.cfg and weaponsHavoc.cfg to match the QuakeC code, and restart the engine!");
 402         }
 403
 404         compressShortVector_init();
 405
 406         local entity head;
 407         head = nextent(world);
 408         maxclients = 0;
 409         while(head)
 410         {
 411                 ++maxclients;
 412                 head = nextent(head);
 413         }
 414
 415         // needs to be done so early as they would still spawn
 416         RegisterWeapons();
 417
 418         if(sv_cheats)
 419                 ServerProgsDB = db_create();
 420         else
 421                 ServerProgsDB = db_load("server.db");
 422
 423         TemporaryDB = db_create();
 424
 425         /*
 426         TODO sound pack system
 427         // initialize sound pack system
 428         soundpack = cvar_string("g_soundpack");
 429         if(soundpack != "")
 430                 soundpack = strcat(soundpack, "/");
 431         soundpack = strzone(soundpack);
 432         */
 433
 434         // 0 normal
 435         lightstyle(0, "m");
 436
 437         // 1 FLICKER (first variety)
 438         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 439
 440         // 2 SLOW STRONG PULSE
 441         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 442
 443         // 3 CANDLE (first variety)
 444         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 445
 446         // 4 FAST STROBE
 447         lightstyle(4, "mamamamamama");
 448
 449         // 5 GENTLE PULSE 1
 450         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 451
 452         // 6 FLICKER (second variety)
 453         lightstyle(6, "nmonqnmomnmomomno");
 454
 455         // 7 CANDLE (second variety)
 456         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 457
 458         // 8 CANDLE (third variety)
 459         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 460
 461         // 9 SLOW STROBE (fourth variety)
 462         lightstyle(9, "aaaaaaaazzzzzzzz");
 463
 464         // 10 FLUORESCENT FLICKER
 465         lightstyle(10, "mmamammmmammamamaaamammma");
 466
 467         // 11 SLOW PULSE NOT FADE TO BLACK
 468         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 469
 470         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 471
 472         // 63 testing
 473         lightstyle(63, "a");
 474
 475         if(cvar("g_campaign"))
 476                 CampaignPreInit();
 477
 478         Map_MarkAsRecent(mapname);
 479
 480         precache_model ("null"); // we need this one before InitGameplayMode
 481         InitGameplayMode();
 482         readlevelcvars();
 483         GrappleHookInit();
 484
 485         player_count = 0;
 486         bot_waypoints_for_items = cvar("g_waypoints_for_items");
 487         if(bot_waypoints_for_items == 1)
 488                 if(self.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 489                         bot_waypoints_for_items = 0;
 490
 491         // for setting by mapinfo
 492         q3acompat_machineshotgunswap = cvar("sv_q3acompat_machineshotgunswap");
 493         cvar_set("sv_q3acompat_machineshotgunswap", "0");
 494
 495         precache();
 496
 497         WaypointSprite_Init();
 498
 499         //if (g_domination)
 500         //      dom_init();
 501
 502         GameLogInit(); // prepare everything
 503         if(cvar("sv_eventlog"))
 504         {
 505                 s = strcat(cvar_string("sv_eventlog_files_counter"), ".");
 506                 s = strcat(s, ftos(random()));
 507                 matchid = strzone(s);
 508
 509                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 510                 s = ":gameinfo:mutators:LIST";
 511                 if(cvar("g_grappling_hook"))
 512                         s = strcat(s, ":grappling_hook");
 513                 if(!cvar("g_use_ammunition"))
 514                         s = strcat(s, ":no_use_ammunition");
 515                 if(!cvar("g_pickup_items"))
 516                         s = strcat(s, ":no_pickup_items");
 517                 if(cvar("g_instagib"))
 518                         s = strcat(s, ":instagib");
 519                 if(cvar_string("g_weaponarena") != "0")
 520                         s = strcat(s, ":", cvar_string("g_weaponarena"), " arena");
 521                 if(cvar("g_nixnex"))
 522                         s = strcat(s, ":nixnex");
 523                 if(cvar("g_vampire"))
 524                         s = strcat(s, ":vampire");
 525                 if(cvar("g_laserguided_missile"))
 526                         s = strcat(s, ":laserguided_missile");
 527                 if(cvar("g_norecoil"))
 528                         s = strcat(s, ":norecoil");
 529                 if(cvar("g_midair"))
 530                         s = strcat(s, ":midair");
 531                 if(cvar("g_minstagib"))
 532                         s = strcat(s, ":minstagib");
 533                 GameLogEcho(s);
 534                 GameLogEcho(":gameinfo:end");
 535         }
 536         else
 537                 matchid = strzone(ftos(random()));
 538
 539         cvar_set("nextmap", "");
 540
 541         SetDefaultAlpha();
 542
 543         if(cvar("g_campaign"))
 544                 CampaignPostInit();
 545
 546         fteqcc_testbugs();
 547
 548         Ban_LoadBans();
 549
 550         MapInfo_Enumerate();
 551         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
 552
 553         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 554         {
 555                 fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 556                 if(fd != -1)
 557                 {
 558                         while((s = fgets(fd)))
 559                         {
 560                                 l = tokenize_console(s);
 561                                 if(l < 2)
 562                                         continue;
 563                                 if(argv(0) == "cd")
 564                                 {
 565                                         print("Found ^1DEPRECATED^7 cd loop command in .cfg file; put this line in mapinfo instead:\n");
 566                                         print("  cdtrack ", argv(2), "\n");
 567                                 }
 568                                 else if(argv(0) == "fog")
 569                                 {
 570                                         print("Found ^1DEPRECATED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:\n");
 571                                         print("  \"fog\" \"", s, "\"\n");
 572                                 }
 573                                 else if(argv(0) == "set")
 574                                 {
 575                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 576                                         print("  clientsettemp_for_type all ", argv(1), " ", argv(2), "\n");
 577                                 }
 578                                 else if(argv(0) != "//")
 579                                 {
 580                                         print("Found ^1DEPRECATED^7 set command in .cfg file; put this line in mapinfo instead:\n");
 581                                         print("  clientsettemp_for_type all ", argv(0), " ", argv(1), "\n");
 582                                 }
 583                         }
 584                         fclose(fd);
 585                 }
 586         }
 587
 588         addstat(STAT_WEAPONS, AS_INT, weapons);
 589         addstat(STAT_SWITCHWEAPON, AS_INT, switchweapon);
 590         addstat(STAT_GAMESTARTTIME, AS_FLOAT, stat_game_starttime);
 591         addstat(STAT_ALLOW_OLDNEXBEAM, AS_INT, stat_allow_oldnexbeam);
 592         Nagger_Init();
 593
 594         addstat(STAT_STRENGTH_FINISHED, AS_FLOAT, strength_finished);
 595         addstat(STAT_INVINCIBLE_FINISHED, AS_FLOAT, invincible_finished);
 596         addstat(STAT_PRESSED_KEYS, AS_FLOAT, pressedkeys);
 597         addstat(STAT_FUEL, AS_INT, ammo_fuel);
 598         addstat(STAT_DAMAGE_HITS, AS_INT, damage_hits);
 599         addstat(STAT_DAMAGE_FIRED, AS_INT, maxdamage_fired);
 600         addstat(STAT_SHOTORG, AS_INT, stat_shotorg);
 601         addstat(STAT_LEADLIMIT, AS_FLOAT, stat_leadlimit);
 602
 603         next_pingtime = time + 5;
 604         InitializeEntity(self, cvar_changes_init, INITPRIO_CVARS);
 605
 606         detect_maptype();
 607
 608         lsmaps_reply = "^7Maps available: ";
 609         for(i = 0, j = 0; i < MapInfo_count; ++i)
 610         {
 611                 if(MapInfo_Get_ByID(i))
 612                         if not(MapInfo_Map_flags & (MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN))
 613                         {
 614                                 if(mod(i, 2))
 615                                         col = "^2";
 616                                 else
 617                                         col = "^3";
 618                                 ++j;
 619                                 lsmaps_reply = strcat(lsmaps_reply, col, MapInfo_Map_bspname, " ");
 620                         }
 621         }
 622         lsmaps_reply = strzone(strcat(lsmaps_reply, "\n"));
 623
 624         maplist_reply = "^7Maps in list: ";
 625         n = tokenize_console(cvar_string("g_maplist"));
 626         for(i = 0, j = 0; i < n; ++i)
 627         {
 628                 if(MapInfo_CheckMap(argv(i)))
 629                 {
 630                         if(mod(j, 2))
 631                                 col = "^2";
 632                         else
 633                                 col = "^3";
 634                         maplist_reply = strcat(maplist_reply, col, argv(i), " ");
 635                         ++j;
 636                 }
 637         }
 638         maplist_reply = strzone(strcat(maplist_reply, "\n"));
 639         MapInfo_ClearTemps();
 640
 641         records_reply = strzone(getrecords());
 642
 643         ClientInit_Spawn();
 644         RandomSeed_Spawn();
 645
 646         world_initialized = 1;
 647 }
 648
 649 void spawnfunc_light (void)
 650 {
 651         //makestatic (self); // Who the f___ did that?
 652         remove(self);
 653 }
 654
 655 float TryFile( string pFilename )
 656 {
 657         local float lHandle;
 658         dprint("TryFile(\"", pFilename, "\")\n");
 659         lHandle = fopen( pFilename, FILE_READ );
 660         if( lHandle != -1 ) {
 661                 fclose( lHandle );
 662                 return TRUE;
 663         } else {
 664                 return FALSE;
 665         }
 666 };
 667
 668 string GetGametype()
 669 {
 670         return GametypeNameFromType(game);
 671 }
 672
 673 string getmapname_stored;
 674 string GetMapname()
 675 {
 676         return mapname;
 677 }
 678
 679 float Map_Count, Map_Current;
 680 string Map_Current_Name;
 681
 682 // NOTE: this now expects the map list to be already tokenize()d and the count in Map_Count
 683 float GetMaplistPosition()
 684 {
 685         float pos, idx;
 686         string map;
 687
 688         map = GetMapname();
 689         idx = cvar("g_maplist_index");
 690
 691         if(idx >= 0)
 692                 if(idx < Map_Count)
 693                         if(map == argv(idx))
 694                                 return idx;
 695
 696         for(pos = 0; pos < Map_Count; ++pos)
 697                 if(map == argv(pos))
 698                         return pos;
 699
 700         // resume normal maplist rotation if current map is not in g_maplist
 701         return idx;
 702 }
 703
 704 float MapHasRightSize(string map)
 705 {
 706         float fh;
 707         if(currentbots || cvar("bot_number") || player_count < cvar("minplayers"))
 708         if(cvar("g_maplist_check_waypoints"))
 709         {
 710                 dprint("checkwp "); dprint(map);
 711                 fh = fopen(strcat("maps/", map, ".waypoints"), FILE_READ);
 712                 if(fh < 0)
 713                 {
 714                         dprint(": no waypoints\n");
 715                         return FALSE;
 716                 }
 717                 dprint(": has waypoints\n");
 718                 fclose(fh);
 719         }
 720
 721         // open map size restriction file
 722         dprint("opensize "); dprint(map);
 723         fh = fopen(strcat("maps/", map, ".sizes"), FILE_READ);
 724         if(fh >= 0)
 725         {
 726                 float mapmin, mapmax;
 727                 dprint(": ok, ");
 728                 mapmin = stof(fgets(fh));
 729                 mapmax = stof(fgets(fh));
 730                 fclose(fh);
 731                 if(player_count < mapmin)
 732                 {
 733                         dprint("not enough\n");
 734                         return FALSE;
 735                 }
 736                 if(player_count > mapmax)
 737                 {
 738                         dprint("too many\n");
 739                         return FALSE;
 740                 }
 741                 dprint("right size\n");
 742                 return TRUE;
 743         }
 744         dprint(": not found\n");
 745         return TRUE;
 746 }
 747
 748 string Map_Filename(float position)
 749 {
 750         return strcat("maps/", argv(position), ".bsp");
 751 }
 752
 753 string strwords(string s, float w)
 754 {
 755         float endpos;
 756         for(endpos = 0; w && endpos >= 0; --w)
 757                 endpos = strstrofs(s, " ", endpos + 1);
 758         if(endpos < 0)
 759                 return s;
 760         else
 761                 return substring(s, 0, endpos);
 762 }
 763
 764 float strhasword(string s, string w)
 765 {
 766         return strstrofs(strcat(" ", s, " "), strcat(" ", w, " "), 0) >= 0;
 767 }
 768
 769 void Map_MarkAsRecent(string m)
 770 {
 771         cvar_set("g_maplist_mostrecent", strwords(strcat(m, " ", cvar_string("g_maplist_mostrecent")), max(0, cvar("g_maplist_mostrecent_count"))));
 772 }
 773
 774 float Map_IsRecent(string m)
 775 {
 776         return strhasword(cvar_string("g_maplist_mostrecent"), m);
 777 }
 778
 779 float Map_Check(float position, float pass)
 780 {
 781         string filename;
 782         string map_next;
 783         map_next = argv(position);
 784         if(pass <= 1)
 785         {
 786                 if(Map_IsRecent(map_next))
 787                         return 0;
 788         }
 789         filename = Map_Filename(position);
 790         if(MapInfo_CheckMap(map_next))
 791         {
 792                 if(pass == 2)
 793                         return 1;
 794                 if(MapHasRightSize(map_next))
 795                         return 1;
 796                 return 0;
 797         }
 798         else
 799                 dprint( "Couldn't select '", filename, "'..\n" );
 800
 801         return 0;
 802 }
 803
 804 void Map_Goto_SetStr(string nextmapname)
 805 {
 806         if(getmapname_stored != "")
 807                 strunzone(getmapname_stored);
 808         if(nextmapname == "")
 809                 getmapname_stored = "";
 810         else
 811                 getmapname_stored = strzone(nextmapname);
 812 }
 813
 814 void Map_Goto_SetFloat(float position)
 815 {
 816         cvar_set("g_maplist_index", ftos(position));
 817         Map_Goto_SetStr(argv(position));
 818 }
 819
 820 void GameResetCfg()
 821 {
 822         // settings persist, except...
 823         localcmd("\nsettemp_restore\n");
 824 };
 825
 826 void Map_Goto()
 827 {
 828         GameResetCfg();
 829         MapInfo_LoadMap(getmapname_stored);
 830 }
 831
 832 // return codes of map selectors:
 833 //   -1 = temporary failure (that is, try some method that is guaranteed to succeed)
 834 //   -2 = permanent failure
 835 float() MaplistMethod_Iterate = // usual method
 836 {
 837         float pass, i;
 838
 839         for(pass = 1; pass <= 2; ++pass)
 840         {
 841                 for(i = 1; i < Map_Count; ++i)
 842                 {
 843                         float mapindex;
 844                         mapindex = mod(i + Map_Current, Map_Count);
 845                         if(Map_Check(mapindex, pass))
 846                                 return mapindex;
 847                 }
 848         }
 849         return -1;
 850 }
 851
 852 float() MaplistMethod_Repeat = // fallback method
 853 {
 854         if(Map_Check(Map_Current, 2))
 855                 return Map_Current;
 856         return -2;
 857 }
 858
 859 float() MaplistMethod_Random = // random map selection
 860 {
 861         float i, imax;
 862
 863         imax = 42;
 864
 865         for(i = 0; i <= imax; ++i)
 866         {
 867                 float mapindex;
 868                 mapindex = mod(Map_Current + floor(random() * (Map_Count - 1) + 1), Map_Count); // any OTHER map
 869                 if(Map_Check(mapindex, 1))
 870                         return mapindex;
 871         }
 872         return -1;
 873 }
 874
 875 float(float exponent) MaplistMethod_Shuffle = // more clever shuffling
 876 // the exponent sets a bias on the map selection:
 877 // the higher the exponent, the less likely "shortly repeated" same maps are
 878 {
 879         float i, j, imax, insertpos;
 880
 881         imax = 42;
 882
 883         for(i = 0; i <= imax; ++i)
 884         {
 885                 string newlist;
 886
 887                 // now reinsert this at another position
 888                 insertpos = pow(random(), 1 / exponent);       // ]0, 1]
 889                 insertpos = insertpos * (Map_Count - 1);       // ]0, Map_Count - 1]
 890                 insertpos = ceil(insertpos) + 1;               // {2, 3, 4, ..., Map_Count}
 891                 dprint("SHUFFLE: insert pos = ", ftos(insertpos), "\n");
 892
 893                 // insert the current map there
 894                 newlist = "";
 895                 for(j = 1; j < insertpos; ++j)                 // i == 1: no loop, will be inserted as first; however, i == 1 has been excluded above
 896                         newlist = strcat(newlist, " ", argv(j));
 897                 newlist = strcat(newlist, " ", argv(0));       // now insert the just selected map
 898                 for(j = insertpos; j < Map_Count; ++j)         // i == Map_Count: no loop, has just been inserted as last
 899                         newlist = strcat(newlist, " ", argv(j));
 900                 newlist = substring(newlist, 1, strlen(newlist) - 1);
 901                 cvar_set("g_maplist", newlist);
 902                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 903
 904                 // NOTE: the selected map has just been inserted at (insertpos-1)th position
 905                 Map_Current = insertpos - 1; // this is not really valid, but this way the fallback has a chance of working
 906                 if(Map_Check(Map_Current, 1))
 907                         return Map_Current;
 908         }
 909         return -1;
 910 }
 911
 912 void Maplist_Init()
 913 {
 914         Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 915         if(Map_Count == 0)
 916         {
 917                 bprint( "Maplist is empty!  Resetting it to default map list.\n" );
 918                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
 919                 if(cvar("g_maplist_shuffle"))
 920                         ShuffleMaplist();
 921                 localcmd("\nmenu_cmd sync\n");
 922                 Map_Count = tokenizebyseparator(cvar_string("g_maplist"), " ");
 923         }
 924         if(Map_Count == 0)
 925                 error("empty maplist, cannot select a new map");
 926         Map_Current = bound(0, GetMaplistPosition(), Map_Count - 1);
 927
 928         if(Map_Current_Name)
 929                 strunzone(Map_Current_Name);
 930         Map_Current_Name = strzone(argv(Map_Current)); // will be automatically freed on exit thanks to DP
 931         // this may or may not be correct, but who cares, in the worst case a map
 932         // isn't chosen in the first pass that should have been
 933 }
 934
 935 string GetNextMap()
 936 {
 937         float nextMap;
 938
 939         Maplist_Init();
 940         nextMap = -1;
 941
 942         if(nextMap == -1)
 943                 if(cvar("g_maplist_shuffle") > 0)
 944                         nextMap = MaplistMethod_Shuffle(cvar("g_maplist_shuffle") + 1);
 945
 946         if(nextMap == -1)
 947                 if(cvar("g_maplist_selectrandom"))
 948                         nextMap = MaplistMethod_Random();
 949
 950         if(nextMap == -1)
 951                 nextMap = MaplistMethod_Iterate();
 952
 953         if(nextMap == -1)
 954                 nextMap = MaplistMethod_Repeat();
 955
 956         if(nextMap >= 0)
 957         {
 958                 Map_Goto_SetFloat(nextMap);
 959                 return getmapname_stored;
 960         }
 961
 962         return "";
 963 };
 964
 965 float DoNextMapOverride()
 966 {
 967         if(cvar("g_campaign"))
 968         {
 969                 CampaignPostIntermission();
 970                 alreadychangedlevel = TRUE;
 971                 return TRUE;
 972         }
 973         if(cvar("quit_when_empty"))
 974         {
 975                 if(player_count <= currentbots)
 976                 {
 977                         localcmd("quit\n");
 978                         alreadychangedlevel = TRUE;
 979                         return TRUE;
 980                 }
 981         }
 982         if(cvar_string("quit_and_redirect") != "")
 983         {
 984                 redirection_target = strzone(cvar_string("quit_and_redirect"));
 985                 alreadychangedlevel = TRUE;
 986                 return TRUE;
 987         }
 988         if (cvar("samelevel")) // if samelevel is set, stay on same level
 989         {
 990                 // this does not work because it tries to exec maps/nexdm01.mapcfg (which doesn't exist, it should be trying maps/dm_nexdm01.mapcfg for example)
 991                 //localcmd(strcat("exec \"maps/", mapname, ".mapcfg\"\n"));
 992                 // so instead just restart the current map using the restart command (DOES NOT WORK PROPERLY WITH exit_cfg STUFF)
 993                 localcmd("restart\n");
 994                 //changelevel (mapname);
 995                 alreadychangedlevel = TRUE;
 996                 return TRUE;
 997         }
 998         if(cvar_string("nextmap") != "")
 999                 if(MapInfo_CheckMap(cvar_string("nextmap")))
1000                 {
1001                         Map_Goto_SetStr(cvar_string("nextmap"));
1002                         Map_Goto();
1003                         alreadychangedlevel = TRUE;
1004                         return TRUE;
1005                 }
1006         if(cvar("lastlevel"))
1007         {
1008                 GameResetCfg();
1009                 localcmd("set lastlevel 0\ntogglemenu\n");
1010                 alreadychangedlevel = TRUE;
1011                 return TRUE;
1012         }
1013         return FALSE;
1014 };
1015
1016 void GotoNextMap()
1017 {
1018         //local string nextmap;
1019         //local float n, nummaps;
1020         //local string s;
1021         if (alreadychangedlevel)
1022                 return;
1023         alreadychangedlevel = TRUE;
1024
1025         {
1026                 string nextMap;
1027                 float allowReset;
1028
1029                 for(allowReset = 1; allowReset >= 0; --allowReset)
1030                 {
1031                         nextMap = GetNextMap();
1032                         if(nextMap != "")
1033                                 break;
1034
1035                         if(allowReset)
1036                         {
1037                                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
1038                                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
1039                                 if(cvar("g_maplist_shuffle"))
1040                                         ShuffleMaplist();
1041                                 localcmd("\nmenu_cmd sync\n");
1042                         }
1043                         else
1044                         {
1045                                 error("Everything is broken - not even the default map list works. Please report this to the developers.");
1046                         }
1047                 }
1048                 Map_Goto();
1049         }
1050 };
1051
1052
1053 /*
1054 ============
1055 IntermissionThink
1056
1057 When the player presses attack or jump, change to the next level
1058 ============
1059 */
1060 .float autoscreenshot;
1061 void() MapVote_Start;
1062 void() MapVote_Think;
1063 float mapvote_initialized;
1064 void IntermissionThink()
1065 {
1066         FixIntermissionClient(self);
1067
1068         if(cvar("sv_autoscreenshot"))
1069         if(self.autoscreenshot > 0)
1070         if(time > self.autoscreenshot)
1071         {
1072                 self.autoscreenshot = -1;
1073                 if(clienttype(self) == CLIENTTYPE_REAL)
1074                         stuffcmd(self, "\nscreenshot\necho \"^5A screenshot has been taken at request of the server.\"\n");
1075                 return;
1076         }
1077
1078         if (time < intermission_exittime)
1079                 return;
1080
1081         if(!mapvote_initialized)
1082                 if (time < intermission_exittime + 10 && !self.BUTTON_ATCK && !self.BUTTON_JUMP && !self.BUTTON_ATCK2 && !self.BUTTON_HOOK && !self.BUTTON_USE)
1083                         return;
1084
1085         MapVote_Start();
1086 };
1087
1088 /*
1089 ============
1090 FindIntermission
1091
1092 Returns the entity to view from
1093 ============
1094 */
1095 /*
1096 entity FindIntermission()
1097 {
1098         local   entity spot;
1099         local   float cyc;
1100
1101 // look for info_intermission first
1102         spot = find (world, classname, "info_intermission");
1103         if (spot)
1104         {       // pick a random one
1105                 cyc = random() * 4;
1106                 while (cyc > 1)
1107                 {
1108                         spot = find (spot, classname, "info_intermission");
1109                         if (!spot)
1110                                 spot = find (spot, classname, "info_intermission");
1111                         cyc = cyc - 1;
1112                 }
1113                 return spot;
1114         }
1115
1116 // then look for the start position
1117         spot = find (world, classname, "info_player_start");
1118         if (spot)
1119                 return spot;
1120
1121 // testinfo_player_start is only found in regioned levels
1122         spot = find (world, classname, "testplayerstart");
1123         if (spot)
1124                 return spot;
1125
1126 // then look for the start position
1127         spot = find (world, classname, "info_player_deathmatch");
1128         if (spot)
1129                 return spot;
1130
1131         //objerror ("FindIntermission: no spot");
1132         return world;
1133 };
1134 */
1135
1136 /*
1137 ===============================================================================
1138
1139 RULES
1140
1141 ===============================================================================
1142 */
1143
1144 void DumpStats(float final)
1145 {
1146         local float file;
1147         local string s;
1148         local float to_console;
1149         local float to_eventlog;
1150         local float to_file;
1151         local float i;
1152
1153         to_console = cvar("sv_logscores_console");
1154         to_eventlog = cvar("sv_eventlog");
1155         to_file = cvar("sv_logscores_file");
1156
1157         if(!final)
1158         {
1159                 to_console = TRUE; // always print printstats replies
1160                 to_eventlog = FALSE; // but never print them to the event log
1161         }
1162
1163         if(to_eventlog)
1164                 if(cvar("sv_eventlog_console"))
1165                         to_console = FALSE; // otherwise we get the output twice
1166
1167         if(final)
1168                 s = ":scores:";
1169         else
1170                 s = ":status:";
1171         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1172
1173         if(to_console)
1174                 print(s, "\n");
1175         if(to_eventlog)
1176                 GameLogEcho(s);
1177         if(to_file)
1178         {
1179                 file = fopen(cvar_string("sv_logscores_filename"), FILE_APPEND);
1180                 if(file == -1)
1181                         to_file = FALSE;
1182                 else
1183                         fputs(file, strcat(s, "\n"));
1184         }
1185
1186         s = strcat(":labels:player:", GetPlayerScoreString(world, 0));
1187         if(to_console)
1188                 print(s, "\n");
1189         if(to_eventlog)
1190                 GameLogEcho(s);
1191         if(to_file)
1192                 fputs(file, strcat(s, "\n"));
1193
1194         FOR_EACH_CLIENT(other)
1195         {
1196                 if ((clienttype(other) == CLIENTTYPE_REAL) || (clienttype(other) == CLIENTTYPE_BOT && cvar("sv_logscores_bots")))
1197                 {
1198                         s = strcat(":player:see-labels:", GetPlayerScoreString(other, 0), ":");
1199                         s = strcat(s, ftos(rint(time - other.jointime)), ":");
1200                         if(other.classname == "player" || g_arena || g_lms)
1201                                 s = strcat(s, ftos(other.team), ":");
1202                         else
1203                                 s = strcat(s, "spectator:");
1204
1205                         if(to_console)
1206                                 print(s, other.netname, "\n");
1207                         if(to_eventlog)
1208                                 GameLogEcho(strcat(s, ftos(other.playerid), ":", other.netname));
1209                         if(to_file)
1210                                 fputs(file, strcat(s, other.netname, "\n"));
1211                 }
1212         }
1213
1214         if(teams_matter)
1215         {
1216                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1217                 if(to_console)
1218                         print(s, "\n");
1219                 if(to_eventlog)
1220                         GameLogEcho(s);
1221                 if(to_file)
1222                         fputs(file, strcat(s, "\n"));
1223
1224                 for(i = 1; i < 16; ++i)
1225                 {
1226                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1227                         s = strcat(s, ":", ftos(i));
1228                         if(to_console)
1229                                 print(s, "\n");
1230                         if(to_eventlog)
1231                                 GameLogEcho(s);
1232                         if(to_file)
1233                                 fputs(file, strcat(s, "\n"));
1234                 }
1235         }
1236
1237         if(to_console)
1238                 print(":end\n");
1239         if(to_eventlog)
1240                 GameLogEcho(":end");
1241         if(to_file)
1242         {
1243                 fputs(file, ":end\n");
1244                 fclose(file);
1245         }
1246 }
1247
1248 void FixIntermissionClient(entity e)
1249 {
1250         string s;
1251         if(!e.autoscreenshot) // initial call
1252         {
1253                 e.angles = e.v_angle;
1254                 e.angles_x = -e.angles_x;
1255                 e.autoscreenshot = time + 0.8;  // used for autoscreenshot
1256                 e.health = -2342;
1257                 // first intermission phase; voting phase has positive health (used to decide whether to send SVC_FINALE or not)
1258                 e.solid = SOLID_NOT;
1259                 e.movetype = MOVETYPE_NONE;
1260                 e.takedamage = DAMAGE_NO;
1261                 if(e.weaponentity)
1262                 {
1263                         e.weaponentity.effects = EF_NODRAW;
1264                         if (e.weaponentity.weaponentity)
1265                                 e.weaponentity.weaponentity.effects = EF_NODRAW;
1266                 }
1267                 if(clienttype(e) == CLIENTTYPE_REAL)
1268                 {
1269                         stuffcmd(e, "\nscr_printspeed 1000000\n");
1270                         s = cvar_string("sv_intermission_cdtrack");
1271                         if(s != "")
1272                                 stuffcmd(e, strcat("\ncd loop ", s, "\n"));
1273                         msg_entity = e;
1274                         WriteByte(MSG_ONE, SVC_INTERMISSION);
1275                 }
1276         }
1277
1278         //e.velocity = '0 0 0';
1279         //e.fixangle = TRUE;
1280
1281         // TODO halt weapon animation
1282 }
1283
1284
1285 /*
1286 go to the next level for deathmatch
1287 only called if a time or frag limit has expired
1288 */
1289 void NextLevel()
1290 {
1291         float minTotalFrags;
1292         float maxTotalFrags;
1293         float score;
1294         float f;
1295
1296         gameover = TRUE;
1297
1298         intermission_running = 1;
1299
1300 // enforce a wait time before allowing changelevel
1301         if(player_count > 0)
1302                 intermission_exittime = time + cvar("sv_mapchange_delay");
1303         else
1304                 intermission_exittime = -1;
1305
1306         /*
1307         WriteByte (MSG_ALL, SVC_CDTRACK);
1308         WriteByte (MSG_ALL, 3);
1309         WriteByte (MSG_ALL, 3);
1310         // done in FixIntermission
1311         */
1312
1313         //pos = FindIntermission ();
1314
1315         VoteReset();
1316
1317         DumpStats(TRUE);
1318
1319         if(cvar("sv_eventlog"))
1320                 GameLogEcho(":gameover");
1321
1322         GameLogClose();
1323
1324         FOR_EACH_CLIENT(other)
1325         {
1326                 FixIntermissionClient(other);
1327
1328                 if(other.winning)
1329                         bprint(other.netname, " ^7wins.\n");
1330         }
1331
1332         minTotalFrags = 0;
1333         maxTotalFrags = 0;
1334         FOR_EACH_PLAYER(other)
1335         {
1336                 if(maxTotalFrags < other.totalfrags)
1337                         maxTotalFrags = other.totalfrags;
1338                 if(minTotalFrags > other.totalfrags)
1339                         minTotalFrags = other.totalfrags;
1340         }
1341
1342         if(!currentbots)
1343         {
1344                 FOR_EACH_PLAYER(other)
1345                 {
1346                         score = (other.totalfrags - minTotalFrags) / max(maxTotalFrags - minTotalFrags, 1);
1347                         f = bound(0, other.play_time / max(time, 1), 1);
1348                         // store some statistics?
1349                 }
1350         }
1351
1352         if(cvar("g_campaign"))
1353                 CampaignPreIntermission();
1354
1355         // WriteByte (MSG_ALL, SVC_INTERMISSION);
1356 };
1357
1358 /*
1359 ============
1360 CheckRules_Player
1361
1362 Exit deathmatch games upon conditions
1363 ============
1364 */
1365 void CheckRules_Player()
1366 {
1367         if (gameover)   // someone else quit the game already
1368                 return;
1369
1370         if(self.deadflag == DEAD_NO)
1371                 self.play_time += frametime;
1372
1373         // fixme: don't check players; instead check spawnfunc_dom_team and spawnfunc_ctf_team entities
1374         //   (div0: and that in CheckRules_World please)
1375 };
1376
1377 float checkrules_equality;
1378 float checkrules_suddendeathwarning;
1379 float checkrules_suddendeathend;
1380 float checkrules_overtimesadded; //how many overtimes have been already added
1381 float checkrules_status;
1382
1383 float WINNING_NO = 0; // no winner, but time limits may terminate the game
1384 float WINNING_YES = 1; // winner found
1385 float WINNING_NEVER = 2; // no winner, enter overtime if time limit is reached
1386 float WINNING_STARTSUDDENDEATHOVERTIME = 3; // no winner, enter suddendeath overtime NOW
1387
1388 void InitiateOvertime()
1389 {
1390         // Check first whether normal overtimes could be added before initiating suddendeath mode
1391         // - for this timelimit_overtime needs to be >0 of course
1392         // - also check the winning condition calculated in the previous frame and only add normal overtime
1393         //   again, if at the point at which timelimit would be extended again, still no winner was found
1394         if ((checkrules_overtimesadded < cvar("timelimit_overtimes")) && cvar("timelimit_overtime") && (checkrules_status == WINNING_NEVER))
1395         {
1396                 ++checkrules_overtimesadded;
1397                 //add one more overtime by simply extending the timelimit
1398                 float tl;
1399                 tl = cvar("timelimit");
1400                 tl += cvar("timelimit_overtime");
1401                 cvar_set("timelimit", ftos(tl));
1402                 string minutesPlural;
1403                 if (cvar("timelimit_overtime") == 1)
1404                         minutesPlural = " ^3minute";
1405                 else
1406                         minutesPlural = " ^3minutes";
1407
1408                 bcenterprint(
1409                         strcat(
1410                                 "^3Now playing ^1OVERTIME^3!\n\n^3Added ^1",
1411                                 ftos(cvar("timelimit_overtime")),
1412                                 minutesPlural,
1413                                 " to the game!"
1414                         )
1415                 );
1416         }
1417         else
1418         {
1419                 if(!checkrules_suddendeathend)
1420                         checkrules_suddendeathend = time + 60 * cvar("timelimit_suddendeath");
1421         }
1422 }
1423
1424 float GetWinningCode(float fraglimitreached, float equality)
1425 {
1426         if(equality)
1427                 if(fraglimitreached)
1428                         return WINNING_STARTSUDDENDEATHOVERTIME;
1429                 else
1430                         return WINNING_NEVER;
1431         else
1432                 if(fraglimitreached)
1433                         return WINNING_YES;
1434                 else
1435                         return WINNING_NO;
1436 }
1437
1438 // set the .winning flag for exactly those players with a given field value
1439 void SetWinners(.float field, float value)
1440 {
1441         entity head;
1442         FOR_EACH_PLAYER(head)
1443                 head.winning = (head.field == value);
1444 }
1445
1446 // set the .winning flag for those players with a given field value
1447 void AddWinners(.float field, float value)
1448 {
1449         entity head;
1450         FOR_EACH_PLAYER(head)
1451                 if(head.field == value)
1452                         head.winning = 1;
1453 }
1454
1455 // clear the .winning flags
1456 void ClearWinners(void)
1457 {
1458         entity head;
1459         FOR_EACH_PLAYER(head)
1460                 head.winning = 0;
1461 }
1462
1463 // Onslaught winning condition:
1464 // game terminates if only one team has a working generator (or none)
1465 float WinningCondition_Onslaught()
1466 {
1467         entity head;
1468         local float t1, t2, t3, t4;
1469
1470         WinningConditionHelper(); // set worldstatus
1471
1472         // first check if the game has ended
1473         t1 = t2 = t3 = t4 = 0;
1474         head = find(world, classname, "onslaught_generator");
1475         while (head)
1476         {
1477                 if (head.health > 0)
1478                 {
1479                         if (head.team == COLOR_TEAM1) t1 = 1;
1480                         if (head.team == COLOR_TEAM2) t2 = 1;
1481                         if (head.team == COLOR_TEAM3) t3 = 1;
1482                         if (head.team == COLOR_TEAM4) t4 = 1;
1483                 }
1484                 head = find(head, classname, "onslaught_generator");
1485         }
1486         if (t1 + t2 + t3 + t4 < 2)
1487         {
1488                 // game over, only one team remains (or none)
1489                 ClearWinners();
1490                 if (t1) SetWinners(team, COLOR_TEAM1);
1491                 if (t2) SetWinners(team, COLOR_TEAM2);
1492                 if (t3) SetWinners(team, COLOR_TEAM3);
1493                 if (t4) SetWinners(team, COLOR_TEAM4);
1494                 dprint("Have a winner, ending game.\n");
1495                 return WINNING_YES;
1496         }
1497
1498         // Two or more teams remain
1499         return WINNING_NO;
1500 }
1501
1502 float LMS_NewPlayerLives()
1503 {
1504         float fl;
1505         fl = cvar("fraglimit");
1506         if(fl == 0)
1507                 fl = 999;
1508
1509         // first player has left the game for dying too much? Nobody else can get in.
1510         if(lms_lowest_lives < 1)
1511                 return 0;
1512
1513         if(!cvar("g_lms_join_anytime"))
1514                 if(lms_lowest_lives < fl - cvar("g_lms_last_join"))
1515                         return 0;
1516
1517         return bound(1, lms_lowest_lives, fl);
1518 }
1519
1520 // Assault winning condition: If the attackers triggered a round end (by fulfilling all objectives)
1521 // they win. Otherwise the defending team wins once the timelimit passes.
1522 void assault_new_round();
1523 float WinningCondition_Assault()
1524 {
1525         local float status;
1526
1527         WinningConditionHelper(); // set worldstatus
1528
1529         status = WINNING_NO;
1530         // as the timelimit has not yet passed just assume the defending team will win
1531         if(assault_attacker_team == COLOR_TEAM1)
1532         {
1533                 SetWinners(team, COLOR_TEAM2);
1534         }
1535         else
1536         {
1537                 SetWinners(team, COLOR_TEAM1);
1538         }
1539
1540         local entity ent;
1541         ent = find(world, classname, "target_assault_roundend");
1542         if(ent)
1543         {
1544                 if(ent.winning) // round end has been triggered by attacking team
1545                 {
1546                         bprint("ASSAULT: round completed...\n");
1547                         SetWinners(team, assault_attacker_team);
1548
1549                         TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 666 - TeamScore_AddToTeam(assault_attacker_team, ST_ASSAULT_OBJECTIVES, 0));
1550
1551                         if(ent.cnt == 1) // this was the second round
1552                         {
1553                                 status = WINNING_YES;
1554                         }
1555                         else
1556                         {
1557                                 local entity oldself;
1558                                 oldself = self;
1559                                 self = ent;
1560                                 assault_new_round();
1561                                 self = oldself;
1562                         }
1563                 }
1564         }
1565
1566         return status;
1567 }
1568
1569 // LMS winning condition: game terminates if and only if there's at most one
1570 // one player who's living lives. Top two scores being equal cancels the time
1571 // limit.
1572 float WinningCondition_LMS()
1573 {
1574         entity head, head2;
1575         float have_player;
1576         float have_players;
1577         float l;
1578
1579         have_player = FALSE;
1580         have_players = FALSE;
1581         l = LMS_NewPlayerLives();
1582
1583         head = find(world, classname, "player");
1584         if(head)
1585                 have_player = TRUE;
1586         head2 = find(head, classname, "player");
1587         if(head2)
1588                 have_players = TRUE;
1589
1590         if(have_player)
1591         {
1592                 // we have at least one player
1593                 if(have_players)
1594                 {
1595                         // two or more active players - continue with the game
1596                 }
1597                 else
1598                 {
1599                         // exactly one player?
1600
1601                         ClearWinners();
1602                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
1603
1604                         if(l)
1605                         {
1606                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
1607                                 return WINNING_NO;
1608                         }
1609                         else
1610                         {
1611                                 // a winner!
1612                                 // and assign him his first place
1613                                 PlayerScore_Add(head, SP_LMS_RANK, 1);
1614                                 return WINNING_YES;
1615                         }
1616                 }
1617         }
1618         else
1619         {
1620                 // nobody is playing at all...
1621                 if(l)
1622                 {
1623                         // wait for players...
1624                 }
1625                 else
1626                 {
1627                         // SNAFU (maybe a draw game?)
1628                         ClearWinners();
1629                         dprint("No players, ending game.\n");
1630                         return WINNING_YES;
1631                 }
1632         }
1633
1634         // When we get here, we have at least two players who are actually LIVING,
1635         // now check if the top two players have equal score.
1636         WinningConditionHelper();
1637
1638         ClearWinners();
1639         if(WinningConditionHelper_winner)
1640                 WinningConditionHelper_winner.winning = TRUE;
1641         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
1642                 return WINNING_NEVER;
1643
1644         // Top two have different scores? Way to go for our beloved TIMELIMIT!
1645         return WINNING_NO;
1646 }
1647
1648 void ShuffleMaplist()
1649 {
1650         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
1651 }
1652
1653 float leaderfrags;
1654 float WinningCondition_Scores(float limit, float leadlimit)
1655 {
1656         // TODO make everything use THIS winning condition (except LMS)
1657         WinningConditionHelper();
1658
1659         if(teams_matter)
1660         {
1661                 team1_score = TeamScore_GetCompareValue(COLOR_TEAM1);
1662                 team2_score = TeamScore_GetCompareValue(COLOR_TEAM2);
1663                 team3_score = TeamScore_GetCompareValue(COLOR_TEAM3);
1664                 team4_score = TeamScore_GetCompareValue(COLOR_TEAM4);
1665         }
1666
1667         ClearWinners();
1668         if(WinningConditionHelper_winner)
1669                 WinningConditionHelper_winner.winning = 1;
1670         if(WinningConditionHelper_winnerteam >= 0)
1671                 SetWinners(team, WinningConditionHelper_winnerteam);
1672
1673         if(WinningConditionHelper_lowerisbetter)
1674         {
1675                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1676                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1677                 limit = -limit;
1678         }
1679
1680         if(WinningConditionHelper_zeroisworst)
1681                 leadlimit = 0; // not supported in this mode
1682
1683         if(g_dm || g_tdm || g_arena || (g_race && !g_race_qualifying) || g_nexball)
1684         // these modes always score in increments of 1, thus this makes sense
1685         {
1686                 if(leaderfrags != WinningConditionHelper_topscore)
1687                 {
1688                         leaderfrags = WinningConditionHelper_topscore;
1689
1690                         if (limit)
1691                         if (leaderfrags == limit - 1)
1692                                 play2all("announcer/robotic/1fragleft.wav");
1693                         else if (leaderfrags == limit - 2)
1694                                 play2all("announcer/robotic/2fragsleft.wav");
1695                         else if (leaderfrags == limit - 3)
1696                                 play2all("announcer/robotic/3fragsleft.wav");
1697                 }
1698         }
1699
1700         return GetWinningCode(
1701                 WinningConditionHelper_topscore &&
1702                 (
1703                         (limit && (WinningConditionHelper_topscore >= limit))
1704                         ||
1705                         (leadlimit && (WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit))
1706                 ),
1707                 WinningConditionHelper_equality
1708         );
1709 }
1710
1711 float WinningCondition_Race(float fraglimit)
1712 {
1713         float wc;
1714         entity p;
1715         wc = WinningCondition_Scores(fraglimit, 0);
1716
1717         // ALWAYS initiate overtime, unless EVERYONE has finished the race!
1718         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1719         // do NOT support equality when the laps are all raced!
1720         {
1721                 FOR_EACH_PLAYER(p)
1722                         if not(p.race_completed)
1723                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1724                 return WINNING_YES;
1725         }
1726         return wc;
1727 }
1728
1729 void ReadyRestart();
1730 float WinningCondition_QualifyingThenRace(float limit)
1731 {
1732         float wc;
1733         wc = WinningCondition_Scores(limit, 0);
1734
1735         // NEVER initiate overtime
1736         if(wc == WINNING_YES || wc == WINNING_STARTSUDDENDEATHOVERTIME)
1737         {
1738                 return WINNING_YES;
1739         }
1740
1741         return wc;
1742 }
1743
1744 float WinningCondition_RanOutOfSpawns()
1745 {
1746         entity head;
1747
1748         if(!have_team_spawns)
1749                 return WINNING_NO;
1750
1751         if(!some_spawn_has_been_used)
1752                 return WINNING_NO;
1753
1754         team1_score = team2_score = team3_score = team4_score = 0;
1755
1756         FOR_EACH_PLAYER(head) if(head.deadflag == DEAD_NO)
1757         {
1758                 if(head.team == COLOR_TEAM1)
1759                         team1_score = 1;
1760                 else if(head.team == COLOR_TEAM2)
1761                         team2_score = 1;
1762                 else if(head.team == COLOR_TEAM3)
1763                         team3_score = 1;
1764                 else if(head.team == COLOR_TEAM4)
1765                         team4_score = 1;
1766         }
1767
1768         for(head = world; (head = find(head, classname, "info_player_deathmatch")) != world; )
1769         {
1770                 if(head.team == COLOR_TEAM1)
1771                         team1_score = 1;
1772                 else if(head.team == COLOR_TEAM2)
1773                         team2_score = 1;
1774                 else if(head.team == COLOR_TEAM3)
1775                         team3_score = 1;
1776                 else if(head.team == COLOR_TEAM4)
1777                         team4_score = 1;
1778         }
1779
1780         ClearWinners();
1781         if(team1_score + team2_score + team3_score + team4_score == 0)
1782         {
1783                 checkrules_equality = TRUE;
1784                 return WINNING_YES;
1785         }
1786         else if(team1_score + team2_score + team3_score + team4_score == 1)
1787         {
1788                 float t, i;
1789                 if(team1_score) t = COLOR_TEAM1;
1790                 if(team2_score) t = COLOR_TEAM2;
1791                 if(team3_score) t = COLOR_TEAM3;
1792                 if(team4_score) t = COLOR_TEAM4;
1793                 CheckAllowedTeams(world);
1794                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1795                 {
1796                         if(t != COLOR_TEAM1) if(c1 >= 0) TeamScore_AddToTeam(COLOR_TEAM1, i, -1000);
1797                         if(t != COLOR_TEAM2) if(c2 >= 0) TeamScore_AddToTeam(COLOR_TEAM2, i, -1000);
1798                         if(t != COLOR_TEAM3) if(c3 >= 0) TeamScore_AddToTeam(COLOR_TEAM3, i, -1000);
1799                         if(t != COLOR_TEAM4) if(c4 >= 0) TeamScore_AddToTeam(COLOR_TEAM4, i, -1000);
1800                 }
1801
1802                 AddWinners(team, t);
1803                 return WINNING_YES;
1804         }
1805         else
1806                 return WINNING_NO;
1807 }
1808
1809 /*
1810 ============
1811 CheckRules_World
1812
1813 Exit deathmatch games upon conditions
1814 ============
1815 */
1816 void CheckRules_World()
1817 {
1818         float timelimit;
1819         float fraglimit;
1820         float leadlimit;
1821
1822         VoteThink();
1823         MapVote_Think();
1824
1825         SetDefaultAlpha();
1826
1827         /*
1828         MapVote_Think should now do that part
1829         if (intermission_running)
1830                 if (time >= intermission_exittime + 60)
1831                 {
1832                         if(!DoNextMapOverride())
1833                                 GotoNextMap();
1834                         return;
1835                 }
1836         */
1837
1838         if (gameover)   // someone else quit the game already
1839         {
1840                 if(player_count == 0) // Nobody there? Then let's go to the next map
1841                         MapVote_Start();
1842                         // this will actually check the player count in the next frame
1843                         // again, but this shouldn't hurt
1844                 return;
1845         }
1846
1847         timelimit = cvar("timelimit") * 60;
1848         fraglimit = cvar("fraglimit");
1849         leadlimit = cvar("leadlimit");
1850
1851         if(inWarmupStage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1852         {
1853                 if(timelimit > 0)
1854                         timelimit = 0; // timelimit is not made for warmup
1855                 if(fraglimit > 0)
1856                         fraglimit = 0; // no fraglimit for now
1857                 leadlimit = 0; // no leadlimit for now
1858         }
1859
1860         if(timelimit > 0)
1861         {
1862                 timelimit += game_starttime;
1863         }
1864         else if (timelimit < 0)
1865         {
1866                 // endmatch
1867                 NextLevel();
1868                 return;
1869         }
1870
1871         if(checkrules_suddendeathend)
1872         {
1873                 if(!checkrules_suddendeathwarning)
1874                 {
1875                         checkrules_suddendeathwarning = TRUE;
1876                         if(g_race && !g_race_qualifying)
1877                                 bcenterprint("^3Everyone, finish your lap! The race is over!");
1878                         else
1879                                 bcenterprint("^3Now playing ^1OVERTIME^3!\n\n^3Keep fragging until we have a ^1winner^3!");
1880                 }
1881         }
1882         else
1883         {
1884                 if (timelimit && time >= timelimit)
1885                 {
1886                         if(g_race && g_race_qualifying == 2 && timelimit > 0)
1887                         {
1888                                 float totalplayers;
1889                                 float playerswithlaps;
1890                                 float readyplayers;
1891                                 entity head;
1892                                 totalplayers = playerswithlaps = readyplayers = 0;
1893                                 FOR_EACH_PLAYER(head)
1894                                 {
1895                                         ++totalplayers;
1896                                         if(PlayerScore_Add(head, SP_RACE_FASTEST, 0))
1897                                                 ++playerswithlaps;
1898                                         if(head.ready)
1899                                                 ++readyplayers;
1900                                 }
1901
1902                                 // at least 2/3 of the players have completed a lap: start the RACE
1903                                 // otherwise, the players should end the qualifying on their own
1904                                 if(readyplayers || ((totalplayers >= 3) && (playerswithlaps * 3 >= totalplayers * 2)))
1905                                 {
1906                                         checkrules_suddendeathend = 0;
1907                                         ReadyRestart(); // go to race
1908                                 }
1909                                 else
1910                                         InitiateOvertime();
1911                         }
1912                         else
1913                                 InitiateOvertime();
1914                 }
1915         }
1916
1917         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1918         {
1919                 NextLevel();
1920                 return;
1921         }
1922
1923         checkrules_status = WinningCondition_RanOutOfSpawns();
1924         if(checkrules_status == WINNING_YES)
1925         {
1926                 bprint("Hey! Someone ran out of spawns!\n");
1927         }
1928         else if(g_race && !g_race_qualifying && timelimit >= 0)
1929         {
1930                 checkrules_status = WinningCondition_Race(fraglimit);
1931         }
1932         else if(g_race && g_race_qualifying == 2 && timelimit >= 0)
1933         {
1934                 checkrules_status = WinningCondition_QualifyingThenRace(fraglimit);
1935         }
1936         else if(g_assault)
1937         {
1938                 checkrules_status = WinningCondition_Assault(); // TODO remove this?
1939         }
1940         else if(g_lms)
1941         {
1942                 checkrules_status = WinningCondition_LMS();
1943         }
1944         else if (g_onslaught)
1945         {
1946                 checkrules_status = WinningCondition_Onslaught(); // TODO remove this?
1947         }
1948         else
1949         {
1950                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1951         }
1952
1953         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1954         {
1955                 checkrules_status = WINNING_NEVER;
1956                 InitiateOvertime();
1957         }
1958
1959         if(checkrules_status == WINNING_NEVER)
1960                 // equality cases! Nobody wins if the overtime ends in a draw.
1961                 ClearWinners();
1962
1963         if(checkrules_suddendeathend)
1964                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1965                         checkrules_status = WINNING_YES;
1966
1967         if(checkrules_status == WINNING_YES)
1968                 NextLevel();
1969 };
1970
1971 float mapvote_nextthink;
1972 float mapvote_initialized;
1973 float mapvote_keeptwotime;
1974 float mapvote_timeout;
1975 string mapvote_message;
1976 string mapvote_screenshot_dir;
1977
1978 float mapvote_count;
1979 float mapvote_count_real;
1980 string mapvote_maps[MAPVOTE_COUNT];
1981 float mapvote_maps_suggested[MAPVOTE_COUNT];
1982 string mapvote_suggestions[MAPVOTE_COUNT];
1983 float mapvote_suggestion_ptr;
1984 float mapvote_maxlen;
1985 float mapvote_voters;
1986 float mapvote_votes[MAPVOTE_COUNT];
1987 float mapvote_run;
1988 float mapvote_detail;
1989 float mapvote_abstain;
1990 .float mapvote;
1991
1992 void MapVote_ClearAllVotes()
1993 {
1994         FOR_EACH_CLIENT(other)
1995                 other.mapvote = 0;
1996 }
1997
1998 string MapVote_Suggest(string m)
1999 {
2000         float i;
2001         if(m == "")
2002                 return "That's not how to use this command.";
2003         if(!cvar("g_maplist_votable_suggestions"))
2004                 return "Suggestions are not accepted on this server.";
2005         if(mapvote_initialized)
2006                 return "Can't suggest - voting is already in progress!";
2007         m = MapInfo_FixName(m);
2008         if(!m)
2009                 return "The map you suggested is not available on this server.";
2010         if(!cvar("g_maplist_votable_override_mostrecent"))
2011                 if(Map_IsRecent(m))
2012                         return "This server does not allow for recent maps to be played again. Please be patient for some rounds.";
2013
2014         if(!MapInfo_CheckMap(m))
2015                 return "The map you suggested does not support the current game mode.";
2016         for(i = 0; i < mapvote_suggestion_ptr; ++i)
2017                 if(mapvote_suggestions[i] == m)
2018                         return "This map was already suggested.";
2019         if(mapvote_suggestion_ptr >= MAPVOTE_COUNT)
2020         {
2021                 i = floor(random() * mapvote_suggestion_ptr);
2022         }
2023         else
2024         {
2025                 i = mapvote_suggestion_ptr;
2026                 mapvote_suggestion_ptr += 1;
2027         }
2028         if(mapvote_suggestions[i] != "")
2029                 strunzone(mapvote_suggestions[i]);
2030         mapvote_suggestions[i] = strzone(m);
2031         if(cvar("sv_eventlog"))
2032                 GameLogEcho(strcat(":vote:suggested:", m, ":", ftos(self.playerid)));
2033         return strcat("Suggestion of ", m, " accepted.");
2034 }
2035
2036 void MapVote_AddVotable(string nextMap, float isSuggestion)
2037 {
2038         float j;
2039         if(nextMap == "")
2040                 return;
2041         for(j = 0; j < mapvote_count; ++j)
2042                 if(mapvote_maps[j] == nextMap)
2043                         return;
2044         if(strlen(nextMap) > mapvote_maxlen)
2045                 mapvote_maxlen = strlen(nextMap);
2046         mapvote_maps[mapvote_count] = strzone(nextMap);
2047         mapvote_maps_suggested[mapvote_count] = isSuggestion;
2048         mapvote_count += 1;
2049 }
2050
2051 void MapVote_Spawn();
2052 void MapVote_Init()
2053 {
2054         float i;
2055         float nmax, smax;
2056
2057         MapVote_ClearAllVotes();
2058
2059         mapvote_count = 0;
2060         mapvote_detail = !cvar("g_maplist_votable_nodetail");
2061         mapvote_abstain = cvar("g_maplist_votable_abstain");
2062
2063         if(mapvote_abstain)
2064                 nmax = min(MAPVOTE_COUNT - 1, cvar("g_maplist_votable"));
2065         else
2066                 nmax = min(MAPVOTE_COUNT, cvar("g_maplist_votable"));
2067         smax = min3(nmax, cvar("g_maplist_votable_suggestions"), mapvote_suggestion_ptr);
2068
2069         if(mapvote_suggestion_ptr)
2070                 for(i = 0; i < 100 && mapvote_count < smax; ++i)
2071                         MapVote_AddVotable(mapvote_suggestions[floor(random() * mapvote_suggestion_ptr)], TRUE);
2072
2073         for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2074                 MapVote_AddVotable(GetNextMap(), FALSE);
2075
2076         if(mapvote_count == 0)
2077         {
2078                 bprint( "Maplist contains no single playable map!  Resetting it to default map list.\n" );
2079                 cvar_set("g_maplist", MapInfo_ListAllowedMaps(0, MAPINFO_FLAG_HIDDEN | MAPINFO_FLAG_FORBIDDEN));
2080                 if(cvar("g_maplist_shuffle"))
2081                         ShuffleMaplist();
2082                 localcmd("\nmenu_cmd sync\n");
2083                 for(i = 0; i < 100 && mapvote_count < nmax; ++i)
2084                         MapVote_AddVotable(GetNextMap(), FALSE);
2085         }
2086
2087         mapvote_count_real = mapvote_count;
2088         if(mapvote_abstain)
2089                 MapVote_AddVotable("don't care", 0);
2090
2091         //dprint("mapvote count is ", ftos(mapvote_count), "\n");
2092
2093         mapvote_keeptwotime = time + cvar("g_maplist_votable_keeptwotime");
2094         mapvote_timeout = time + cvar("g_maplist_votable_timeout");
2095         if(mapvote_count_real < 3 || mapvote_keeptwotime <= time)
2096                 mapvote_keeptwotime = 0;
2097         mapvote_message = "Choose a map and press its key!";
2098
2099         mapvote_screenshot_dir = cvar_string("g_maplist_votable_screenshot_dir");
2100         if(mapvote_screenshot_dir == "")
2101                 mapvote_screenshot_dir = "maps";
2102         mapvote_screenshot_dir = strzone(mapvote_screenshot_dir);
2103
2104         MapVote_Spawn();
2105 }
2106
2107 void MapVote_SendPicture(float id)
2108 {
2109         msg_entity = self;
2110         WriteByte(MSG_ONE, SVC_TEMPENTITY);
2111         WriteByte(MSG_ONE, TE_CSQC_PICTURE);
2112         WriteByte(MSG_ONE, id);
2113         WritePicture(MSG_ONE, strcat(mapvote_screenshot_dir, "/", mapvote_maps[id]), 3072);
2114 }
2115
2116 float GameCommand_MapVote(string cmd)
2117 {
2118         if(!intermission_running)
2119                 return FALSE;
2120
2121         if(cmd == "mv_getpic")
2122         {
2123                 MapVote_SendPicture(stof(argv(1)));
2124                 return TRUE;
2125         }
2126
2127         return FALSE;
2128 }
2129
2130 float MapVote_GetMapMask()
2131 {
2132         float mask, i, power;
2133         mask = 0;
2134         for(i = 0, power = 1; i < mapvote_count; ++i, power *= 2)
2135                 if(mapvote_maps[i] != "")
2136                         mask |= power;
2137         return mask;
2138 }
2139
2140 entity mapvote_ent;
2141 float MapVote_SendEntity(entity to, float sf)
2142 {
2143         string mapfile, pakfile;
2144         float i, o;
2145
2146         if(sf & 1)
2147                 sf &~= 2; // if we send 1, we don't need to also send 2
2148
2149         WriteByte(MSG_ENTITY, ENT_CLIENT_MAPVOTE);
2150         WriteByte(MSG_ENTITY, sf);
2151
2152         if(sf & 1)
2153         {
2154                 // flag 1 == initialization
2155                 WriteString(MSG_ENTITY, mapvote_screenshot_dir);
2156                 WriteByte(MSG_ENTITY, mapvote_count);
2157                 WriteByte(MSG_ENTITY, mapvote_abstain);
2158                 WriteByte(MSG_ENTITY, mapvote_detail);
2159                 WriteCoord(MSG_ENTITY, mapvote_timeout);
2160                 if(mapvote_count <= 8)
2161                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2162                 else
2163                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2164                 for(i = 0; i < mapvote_count; ++i)
2165                         if(mapvote_maps[i] != "")
2166                         {
2167                                 if(mapvote_abstain && i == mapvote_count - 1)
2168                                 {
2169                                         WriteString(MSG_ENTITY, ""); // abstain needs no text
2170                                         WriteString(MSG_ENTITY, ""); // abstain needs no pack
2171                                 }
2172                                 else
2173                                 {
2174                                         WriteString(MSG_ENTITY, mapvote_maps[i]);
2175                                         mapfile = strcat(mapvote_screenshot_dir, "/", mapvote_maps[i]);
2176                                         pakfile = whichpack(strcat(mapfile, ".tga"));
2177                                         if(pakfile == "")
2178                                                 pakfile = whichpack(strcat(mapfile, ".jpg"));
2179                                         if(pakfile == "")
2180                                                 pakfile = whichpack(strcat(mapfile, ".png"));
2181                                         for(o = strstr(pakfile, "/", 0)+1; o > 0; o = strstr(pakfile, "/", 0)+1)
2182                                                 pakfile = substring(pakfile, o, 999);
2183                                         WriteString(MSG_ENTITY, pakfile);
2184                                 }
2185                         }
2186         }
2187
2188         if(sf & 2)
2189         {
2190                 // flag 2 == update of mask
2191                 if(mapvote_count <= 8)
2192                         WriteByte(MSG_ENTITY, MapVote_GetMapMask());
2193                 else
2194                         WriteShort(MSG_ENTITY, MapVote_GetMapMask());
2195         }
2196
2197         if(sf & 4)
2198         {
2199                 if(mapvote_detail)
2200                         for(i = 0; i < mapvote_count; ++i)
2201                                 if(mapvote_maps[i] != "")
2202                                         WriteByte(MSG_ENTITY, mapvote_votes[i]);
2203
2204                 WriteByte(MSG_ENTITY, to.mapvote);
2205         }
2206
2207         return TRUE;
2208 }
2209
2210 void MapVote_Spawn()
2211 {
2212         Net_LinkEntity(mapvote_ent = spawn(), FALSE, 0, MapVote_SendEntity);
2213 }
2214
2215 void MapVote_TouchMask()
2216 {
2217         mapvote_ent.SendFlags |= 2;
2218 }
2219
2220 void MapVote_TouchVotes(entity voter)
2221 {
2222         mapvote_ent.SendFlags |= 4;
2223 }
2224
2225 float MapVote_Finished(float mappos)
2226 {
2227         string result;
2228         float i;
2229         float didntvote;
2230
2231         if(cvar("sv_eventlog"))
2232         {
2233                 result = strcat(":vote:finished:", mapvote_maps[mappos]);
2234                 result = strcat(result, ":", ftos(mapvote_votes[mappos]), "::");
2235                 didntvote = mapvote_voters;
2236                 for(i = 0; i < mapvote_count; ++i)
2237                         if(mapvote_maps[i] != "")
2238                         {
2239                                 didntvote -= mapvote_votes[i];
2240                                 if(i != mappos)
2241                                 {
2242                                         result = strcat(result, ":", mapvote_maps[i]);
2243                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2244                                 }
2245                         }
2246                 result = strcat(result, ":didn't vote:", ftos(didntvote));
2247
2248                 GameLogEcho(result);
2249                 if(mapvote_maps_suggested[mappos])
2250                         GameLogEcho(strcat(":vote:suggestion_accepted:", mapvote_maps[mappos]));
2251         }
2252
2253         FOR_EACH_REALCLIENT(other)
2254                 FixClientCvars(other);
2255
2256         Map_Goto_SetStr(mapvote_maps[mappos]);
2257         Map_Goto();
2258         alreadychangedlevel = TRUE;
2259         return TRUE;
2260 }
2261 void MapVote_CheckRules_1()
2262 {
2263         float i;
2264
2265         for(i = 0; i < mapvote_count; ++i) if(mapvote_maps[i] != "")
2266         {
2267                 //dprint("Map ", ftos(i), ": "); dprint(mapvote_maps[i], "\n");
2268                 mapvote_votes[i] = 0;
2269         }
2270
2271         mapvote_voters = 0;
2272         FOR_EACH_REALCLIENT(other)
2273         {
2274                 ++mapvote_voters;
2275                 if(other.mapvote)
2276                 {
2277                         i = other.mapvote - 1;
2278                         //dprint("Player ", other.netname, " vote = ", ftos(other.mapvote - 1), "\n");
2279                         mapvote_votes[i] = mapvote_votes[i] + 1;
2280                 }
2281         }
2282 }
2283
2284 float MapVote_CheckRules_2()
2285 {
2286         float i;
2287         float firstPlace, secondPlace;
2288         float firstPlaceVotes, secondPlaceVotes;
2289         float mapvote_voters_real;
2290         string result;
2291
2292         if(mapvote_count_real == 1)
2293                 return MapVote_Finished(0);
2294
2295         mapvote_voters_real = mapvote_voters;
2296         if(mapvote_abstain)
2297                 mapvote_voters_real -= mapvote_votes[mapvote_count - 1];
2298
2299         RandomSelection_Init();
2300         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2301                 RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2302         firstPlace = RandomSelection_chosen_float;
2303         firstPlaceVotes = RandomSelection_best_priority;
2304         //dprint("First place: ", ftos(firstPlace), "\n");
2305         //dprint("First place votes: ", ftos(firstPlaceVotes), "\n");
2306
2307         RandomSelection_Init();
2308         for(i = 0; i < mapvote_count_real; ++i) if(mapvote_maps[i] != "")
2309                 if(i != firstPlace)
2310                         RandomSelection_Add(world, i, string_null, 1, mapvote_votes[i]);
2311         secondPlace = RandomSelection_chosen_float;
2312         secondPlaceVotes = RandomSelection_best_priority;
2313         //dprint("Second place: ", ftos(secondPlace), "\n");
2314         //dprint("Second place votes: ", ftos(secondPlaceVotes), "\n");
2315
2316         if(firstPlace == -1)
2317                 error("No first place in map vote... WTF?");
2318
2319         if(secondPlace == -1 || time > mapvote_timeout || (mapvote_voters_real - firstPlaceVotes) < firstPlaceVotes)
2320                 return MapVote_Finished(firstPlace);
2321
2322         if(mapvote_keeptwotime)
2323                 if(time > mapvote_keeptwotime || (mapvote_voters_real - firstPlaceVotes - secondPlaceVotes) < secondPlaceVotes)
2324                 {
2325                         float didntvote;
2326                         MapVote_TouchMask();
2327                         mapvote_message = "Now decide between the TOP TWO!";
2328                         mapvote_keeptwotime = 0;
2329                         result = strcat(":vote:keeptwo:", mapvote_maps[firstPlace]);
2330                         result = strcat(result, ":", ftos(firstPlaceVotes));
2331                         result = strcat(result, ":", mapvote_maps[secondPlace]);
2332                         result = strcat(result, ":", ftos(secondPlaceVotes), "::");
2333                         didntvote = mapvote_voters;
2334                         for(i = 0; i < mapvote_count; ++i)
2335                                 if(mapvote_maps[i] != "")
2336                                 {
2337                                         didntvote -= mapvote_votes[i];
2338                                         if(i != firstPlace)
2339                                                 if(i != secondPlace)
2340                                                 {
2341                                                         result = strcat(result, ":", mapvote_maps[i]);
2342                                                         result = strcat(result, ":", ftos(mapvote_votes[i]));
2343                                                         if(i < mapvote_count_real)
2344                                                         {
2345                                                                 strunzone(mapvote_maps[i]);
2346                                                                 mapvote_maps[i] = "";
2347                                                         }
2348                                                 }
2349                                 }
2350                         result = strcat(result, ":didn't vote:", ftos(didntvote));
2351                         if(cvar("sv_eventlog"))
2352                                 GameLogEcho(result);
2353                 }
2354
2355         return FALSE;
2356 }
2357 void MapVote_Tick()
2358 {
2359         float keeptwo;
2360         float totalvotes;
2361
2362         keeptwo = mapvote_keeptwotime;
2363         MapVote_CheckRules_1(); // count
2364         if(MapVote_CheckRules_2()) // decide
2365                 return;
2366
2367         totalvotes = 0;
2368         FOR_EACH_REALCLIENT(other)
2369         {
2370                 // hide scoreboard again
2371                 if(other.health != 2342)
2372                 {
2373                         other.health = 2342;
2374                         other.impulse = 0;
2375                         if(clienttype(other) == CLIENTTYPE_REAL)
2376                         {
2377                                 msg_entity = other;
2378                                 WriteByte(MSG_ONE, SVC_FINALE);
2379                                 WriteString(MSG_ONE, "");
2380                         }
2381                 }
2382
2383                 // clear possibly invalid votes
2384                 if(mapvote_maps[other.mapvote - 1] == "")
2385                         other.mapvote = 0;
2386                 // use impulses as new vote
2387                 if(other.impulse >= 1 && other.impulse <= mapvote_count)
2388                         if(mapvote_maps[other.impulse - 1] != "")
2389                         {
2390                                 other.mapvote = other.impulse;
2391                                 MapVote_TouchVotes(other);
2392                         }
2393                 other.impulse = 0;
2394
2395                 if(other.mapvote)
2396                         ++totalvotes;
2397         }
2398
2399         MapVote_CheckRules_1(); // just count
2400 }
2401 void MapVote_Start()
2402 {
2403         if(mapvote_run)
2404                 return;
2405
2406         MapInfo_Enumerate();
2407         if(MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1))
2408                 mapvote_run = TRUE;
2409 }
2410 void MapVote_Think()
2411 {
2412         if(!mapvote_run)
2413                 return;
2414
2415         if(alreadychangedlevel)
2416                 return;
2417
2418         if(time < mapvote_nextthink)
2419                 return;
2420         //dprint("tick\n");
2421
2422         mapvote_nextthink = time + 0.5;
2423
2424         if(!mapvote_initialized)
2425         {
2426                 mapvote_initialized = TRUE;
2427                 if(DoNextMapOverride())
2428                         return;
2429                 if(!cvar("g_maplist_votable") || player_count <= 0)
2430                 {
2431                         GotoNextMap();
2432                         return;
2433                 }
2434                 MapVote_Init();
2435         }
2436
2437         MapVote_Tick();
2438 };
2439
2440 string GotoMap(string m)
2441 {
2442         if(!MapInfo_CheckMap(m))
2443                 return "The map you chose is not available on this server.";
2444         cvar_set("nextmap", m);
2445         cvar_set("timelimit", "-1");
2446         if(mapvote_initialized || alreadychangedlevel)
2447         {
2448                 if(DoNextMapOverride())
2449                         return "Map switch initiated.";
2450                 else
2451                         return "Hm... no. For some reason I like THIS map more.";
2452         }
2453         else
2454                 return "Map switch will happen after scoreboard.";
2455 }
2456
2457
2458 void EndFrame()
2459 {
2460         FOR_EACH_REALCLIENT(self)
2461         {
2462                 if(self.classname == "spectator")
2463                 {
2464                         if(self.enemy.typehitsound)
2465                                 play2(self, "misc/typehit.wav");
2466                         else if(self.enemy.hitsound && self.cvar_cl_hitsound)
2467                                 play2(self, "misc/hit.wav");
2468                 }
2469                 else
2470                 {
2471                         if(self.typehitsound)
2472                                 play2(self, "misc/typehit.wav");
2473                         else if(self.hitsound && self.cvar_cl_hitsound)
2474                                 play2(self, "misc/hit.wav");
2475                 }
2476         }
2477         FOR_EACH_CLIENT(self)
2478         {
2479                 self.hitsound = FALSE;
2480                 self.typehitsound = FALSE;
2481         }
2482 }
2483
2484
2485 /*
2486  * RedirectionThink:
2487  * returns TRUE if redirecting
2488  */
2489 float redirection_timeout;
2490 float redirection_nextthink;
2491 float RedirectionThink()
2492 {
2493         float clients_found;
2494
2495         if(redirection_target == "")
2496                 return FALSE;
2497
2498         if(!redirection_timeout)
2499         {
2500                 cvar_set("sv_public", "-2");
2501                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2502                 if(redirection_target == "self")
2503                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2504                 else
2505                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2506         }
2507
2508         if(time < redirection_nextthink)
2509                 return TRUE;
2510
2511         redirection_nextthink = time + 1;
2512
2513         clients_found = 0;
2514         FOR_EACH_REALCLIENT(self)
2515         {
2516                 print("Redirecting: sending connect command to ", self.netname, "\n");
2517                 if(redirection_target == "self")
2518                         stuffcmd(self, "\ndisconnect; reconnect\n");
2519                 else
2520                         stuffcmd(self, strcat("\ndisconnect; connect ", redirection_target, "\n"));
2521                 ++clients_found;
2522         }
2523
2524         print("Redirecting: ", ftos(clients_found), " clients left.\n");
2525
2526         if(time > redirection_timeout || clients_found == 0)
2527                 localcmd("\nwait; wait; wait; quit\n");
2528
2529         return TRUE;
2530 }
2531
2532 void RestoreGame()
2533 {
2534         // Loaded from a save game
2535         // some things then break, so let's work around them...
2536
2537         // Progs DB (capture records)
2538         if(sv_cheats)
2539                 ServerProgsDB = db_create();
2540         else
2541                 ServerProgsDB = db_load("server.db");
2542
2543         // Mapinfo
2544         MapInfo_Shutdown();
2545         MapInfo_Enumerate();
2546         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), 0, (g_maplist_allow_hidden ? 0 : MAPINFO_FLAG_HIDDEN) | MAPINFO_FLAG_FORBIDDEN, 1);
2547 }
2548
2549 void SV_Shutdown()
2550 {
2551         if(world_initialized > 0)
2552         {
2553                 world_initialized = 0;
2554                 print("Saving persistent data...\n");
2555                 Ban_SaveBans();
2556                 if(!sv_cheats)
2557                         db_save(ServerProgsDB, "server.db");
2558                 if(cvar("developer"))
2559                         db_save(TemporaryDB, "server-temp.db");
2560                 db_close(ServerProgsDB);
2561                 db_close(TemporaryDB);
2562                 print("done!\n");
2563                 // tell the bot system the game is ending now
2564                 bot_endgame();
2565
2566                 MapInfo_Shutdown();
2567         }
2568         else if(world_initialized == 0)
2569         {
2570                 print("NOTE: crashed before even initializing the world, not saving persistent data\n");
2571         }
2572 }