data/qcsrc/server/g_hook.qc

   1 /*============================================
   2
   3       Wazat's Nexuiz Grappling Hook
   4
   5         Contact: Wazat1@gmail.com
   6
   7
   8 Installation instructions:
   9 --------------------------
  10
  11 1. Place hook.c in your gamec source directory with the other source files.
  12
  13 2. Add this line to the bottom of progs.src:
  14
  15 gamec/hook.c
  16
  17 3. Open defs.h and add these lines to the very bottom:
  18
  19 // Wazat's grappling hook
  20 .entity         hook;
  21 void GrapplingHookFrame();
  22 void RemoveGrapplingHook(entity pl);
  23 void SetGrappleHookBindings();
  24 // hook impulses
  25 float GRAPHOOK_FIRE             = 20;
  26 float GRAPHOOK_RELEASE          = 21;
  27 // (note: you can change the hook impulse #'s to whatever you please)
  28
  29 4. Open client.c and add this to the top of PutClientInServer():
  30
  31         RemoveGrapplingHook(self); // Wazat's Grappling Hook
  32
  33 5. Find ClientConnect() (in client.c) and add these lines to the bottom:
  34
  35         // Wazat's grappling hook
  36         SetGrappleHookBindings();
  37
  38 6. Still in client.c, find PlayerPreThink and add this line just above the call to W_WeaponFrame:
  39
  40         GrapplingHookFrame();
  41
  42 7. Build and test the mod.  You'll want to bind a key to "+hook" like this:
  43 bind ctrl "+hook"
  44
  45 And you should be done!
  46
  47
  48 ============================================*/
  49
  50 .float rope_length;
  51 .float button6_pressed_before;
  52
  53 void RemoveGrapplingHook(entity pl)
  54 {
  55         if(pl.hook == world)
  56                 return;
  57         remove(pl.hook);
  58         pl.hook = world;
  59         if(pl.movetype == MOVETYPE_FLY)
  60                 pl.movetype = MOVETYPE_WALK;
  61
  62         pl.hook_time = time + 0.0;
  63
  64         //pl.disableclientprediction = FALSE;
  65 }
  66
  67 void GrapplingHookThink()
  68 {
  69         float spd, dist, minlength, pullspeed, ropestretch, ropeairfriction, rubberforce, newlength, rubberforce_overstretch;
  70         vector dir, org, end;
  71         if(self.owner.health <= 0 || self.owner.hook != self)   // how did that happen?
  72         {                                                                                                               // well, better fix it anyway
  73                 remove(self);
  74                 return;
  75         }
  76
  77         self.nextthink = time;
  78
  79         makevectors(self.owner.v_angle);
  80         org = self.owner.origin + self.owner.view_ofs + v_forward * 15 - v_right * 5 + v_up * -12;
  81
  82         if(self.rope_length < 0)
  83                 self.rope_length = vlen(org - self.origin);
  84
  85         if(self.state == 1)
  86         {
  87                 pullspeed = cvar("g_balance_grapplehook_speed_pull");//2000;
  88                 // speed the rope is pulled with
  89
  90                 rubberforce = cvar("g_balance_grapplehook_force_rubber");//2000;
  91                 // force the rope will use if it is stretched
  92
  93                 rubberforce_overstretch = cvar("g_balance_grapplehook_force_rubber_overstretch");//1000;
  94                 // force the rope will use if it is stretched
  95
  96                 minlength = cvar("g_balance_grapplehook_length_min");//100;
  97                 // minimal rope length
  98                 // if the rope goes below this length, it isn't pulled any more
  99
 100                 ropestretch = cvar("g_balance_grapplehook_stretch");//400;
 101                 // if the rope is stretched by more than this amount, more rope is
 102                 // given to you again
 103
 104                 ropeairfriction = cvar("g_balance_grapplehook_airfriction");//0.2
 105                 // while hanging on the rope, this friction component will help you a
 106                 // bit to control the rope
 107
 108                 dir = self.origin - org;
 109                 dist = vlen(dir);
 110                 dir = normalize(dir);
 111
 112                 if(cvar("g_grappling_hook_tarzan"))
 113                 {
 114                         newlength = self.rope_length;
 115
 116                         // first pull the rope...
 117                         newlength = max(newlength - pullspeed * frametime, minlength);
 118
 119                         if(newlength < dist - ropestretch) // overstretched?
 120                         {
 121                                 newlength = dist - ropestretch;
 122                                 if(self.owner.velocity * dir < 0) // only if not already moving in hook direction
 123                                         self.owner.velocity = self.owner.velocity + frametime * dir * rubberforce_overstretch;
 124                         }
 125
 126                         if(!self.owner.button5) // crouch key = don't pull
 127                                 self.rope_length = newlength;
 128
 129                         // then pull the player
 130                         spd = bound(0, (dist - self.rope_length) / ropestretch, 1);
 131                         self.owner.velocity = self.owner.velocity * (1 - frametime * ropeairfriction);
 132                         self.owner.velocity = self.owner.velocity + frametime * dir * spd * rubberforce;
 133                 }
 134                 else
 135                 {
 136                         end = self.origin - dir*50;
 137                         dist = vlen(end - org);
 138                         if(dist < 200)
 139                                 spd = dist * (pullspeed / 200);
 140                         else
 141                                 spd = pullspeed;
 142                         if(spd < 50)
 143                                 spd = 0;
 144                         self.owner.velocity = dir*spd;
 145                         self.owner.movetype = MOVETYPE_FLY;
 146                 }
 147
 148                 self.owner.flags = self.owner.flags - (self.owner.flags & FL_ONGROUND);
 149
 150                 org = org + dir*50; // get the beam out of the player's eyes
 151         }
 152
 153         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
 154         WriteByte (MSG_BROADCAST, TE_BEAM);
 155         WriteEntity (MSG_BROADCAST, self);
 156         WriteCoord (MSG_BROADCAST, self.origin_x);
 157         WriteCoord (MSG_BROADCAST, self.origin_y);
 158         WriteCoord (MSG_BROADCAST, self.origin_z);
 159         WriteCoord (MSG_BROADCAST, org_x);
 160         WriteCoord (MSG_BROADCAST, org_y);
 161         WriteCoord (MSG_BROADCAST, org_z);
 162 }
 163
 164 void GrapplingHookTouch (void)
 165 {
 166         if (other == self.owner)
 167                 return;
 168         // altered for Nexuiz
 169         //else if (pointcontents (self.origin) == CONTENT_SKY)
 170         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 171         {
 172                 RemoveGrapplingHook(self.owner);
 173                 return;
 174         }
 175
 176         sound (self, CHAN_BODY, "weapons/hook_impact.ogg", 1, ATTN_NORM);
 177
 178         self.state = 1;
 179         self.think = GrapplingHookThink;
 180         self.nextthink = time;
 181         self.touch = SUB_Null;
 182         self.velocity = '0 0 0';
 183         self.movetype = MOVETYPE_NONE;
 184         self.rope_length = -1;
 185
 186         //self.owner.disableclientprediction = TRUE;
 187 }
 188
 189 void GrapplingHook_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 190 {
 191         if(self.health > 0)
 192         {
 193                 self.health = self.health - damage;
 194                 if (self.health <= 0)
 195                 {
 196                         if(attacker != self.owner)
 197                         {
 198                                 self.owner.pusher = attacker;
 199                                 self.owner.pushltime = time + cvar("g_maxpushtime");
 200                         }
 201                         RemoveGrapplingHook(self.owner);
 202                 }
 203         }
 204 }
 205
 206 void FireGrapplingHook (void)
 207 {
 208         local entity missile;
 209         local vector org;
 210
 211         if(arena_roundbased)
 212         if(time < warmup)
 213                 return;
 214
 215         makevectors(self.v_angle);
 216
 217         sound (self, CHAN_WEAPON, "weapons/hook_fire.ogg", 1, ATTN_NORM);
 218         org = self.origin + self.view_ofs + v_forward * 15 - v_right * 5 + v_up * -12;
 219         te_customflash(org, 160, 0.2, '1 0 0');
 220
 221         missile = spawn ();
 222         missile.owner = self;
 223         self.hook = missile;
 224         missile.classname = "grapplinghook";
 225
 226         missile.movetype = MOVETYPE_FLY;
 227         missile.solid = SOLID_BBOX;
 228
 229         setmodel (missile, "models/ebomb.mdl"); // replace by something CENTERED!, precision set below
 230         setsize (missile, '-3 -3 -3', '3 3 3');
 231         setorigin (missile, org);
 232
 233         missile.state = 0; // not latched onto anything
 234
 235         missile.velocity = v_forward * cvar("g_balance_grapplehook_speed_fly");
 236         missile.angles = vectoangles (missile.velocity);
 237         //missile.glow_color = 250; // 244, 250
 238         //missile.glow_size = 120;
 239         missile.touch = GrapplingHookTouch;
 240         missile.think = GrapplingHookThink;
 241         missile.nextthink = time + 0.1;
 242
 243         missile.effects = EF_FULLBRIGHT | EF_ADDITIVE | EF_LOWPRECISION;
 244
 245         missile.health = cvar("g_balance_grapplehook_health");//120
 246         missile.event_damage = GrapplingHook_Damage;
 247         missile.takedamage = DAMAGE_AIM;
 248         missile.damageforcescale = 0;
 249 }
 250
 251 void GrapplingHookFrame()
 252 {
 253         // this function has been modified for Nexuiz
 254         if (self.button6 && cvar("g_grappling_hook"))
 255         {
 256                 if (!self.hook && self.hook_time <= time && !self.button6_pressed_before)
 257                         FireGrapplingHook();
 258         }
 259         else
 260         {
 261                 if (self.hook)
 262                         RemoveGrapplingHook(self);
 263         }
 264         self.button6_pressed_before = self.button6;
 265         /*
 266         // if I have no hook or it's not pulling yet, make sure I'm not flying!
 267         if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
 268         {
 269                 self.movetype = MOVETYPE_WALK;
 270         }
 271         if(self.impulse == GRAPHOOK_FIRE && self.hook_time <= time && cvar("g_grappling_hook"))
 272         {
 273                 // fire hook
 274                 FireGrapplingHook();
 275                 return;
 276         }
 277         else if(self.hookimpulse == GRAPHOOK_RELEASE)
 278         {
 279                 // remove hook, reset movement type
 280                 RemoveGrapplingHook(self);
 281                 return;
 282         }
 283         */
 284         /*else // make sure the player's movetype is correct
 285         {
 286                 //if(self.hook == world && self.movetype == MOVETYPE_FLY)
 287                 if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
 288                 {
 289                         self.movetype = MOVETYPE_WALK;
 290                 }
 291         }*/
 292         // note: The hook entity does the actual pulling
 293 }
 294
 295 void SetGrappleHookBindings()
 296 {
 297         // this function has been modified for Nexuiz
 298         // don't remove these lines! old server or demos coud overwrite the new aliases
 299         stuffcmd(self, "alias +hook +button6\n");
 300         stuffcmd(self, "alias -hook -button6\n");
 301 }