tZork's grappling hook;
[divverent/nexuiz.git] / data / qcsrc / server / g_hook.qc
1 /*============================================
2
3       Wazat's Nexuiz Grappling Hook
4
5         Contact: Wazat1@gmail.com
6
7
8 Installation instructions:
9 --------------------------
10
11 1. Place hook.c in your gamec source directory with the other source files.
12
13 2. Add this line to the bottom of progs.src:
14
15 gamec/hook.c
16
17 3. Open defs.h and add these lines to the very bottom:
18
19 // Wazat's grappling hook
20 .entity         hook;
21 void GrapplingHookFrame();
22 void RemoveGrapplingHook(entity pl);
23 void SetGrappleHookBindings();
24 // hook impulses
25 float GRAPHOOK_FIRE             = 20;
26 float GRAPHOOK_RELEASE          = 21;
27 // (note: you can change the hook impulse #'s to whatever you please)
28
29 4. Open client.c and add this to the top of PutClientInServer():
30
31         RemoveGrapplingHook(self); // Wazat's Grappling Hook
32
33 5. Find ClientConnect() (in client.c) and add these lines to the bottom:
34
35         // Wazat's grappling hook
36         SetGrappleHookBindings();
37
38 6. Still in client.c, find PlayerPreThink and add this line just above the call to W_WeaponFrame:
39
40         GrapplingHookFrame();
41
42 7. Build and test the mod.  You'll want to bind a key to "+hook" like this:
43 bind ctrl "+hook"
44
45 And you should be done!
46
47
48 ============================================*/
49
50 .float rope_length;
51 .float button6_pressed_before;
52
53 void RemoveGrapplingHook(entity pl)
54 {
55         if(pl.hook == world)
56                 return;
57         remove(pl.hook);
58         pl.hook = world;
59         if(pl.movetype == MOVETYPE_FLY)
60                 pl.movetype = MOVETYPE_WALK;
61
62         pl.hook_time = time + 0.0;
63
64         //pl.disableclientprediction = FALSE;
65 }
66
67 void GrapplingHookThink()
68 {
69         float spd, dist, minlength, pullspeed, ropestretch, ropeairfriction, rubberforce, newlength, rubberforce_overstretch;
70         vector dir, org, end;
71         if(self.owner.health <= 0 || self.owner.hook != self)   // how did that happen?
72         {                                                                                                               // well, better fix it anyway
73                 remove(self);
74                 return;
75         }
76
77         self.nextthink = time;
78
79         makevectors(self.owner.v_angle);
80         org = self.owner.origin + self.owner.view_ofs + v_forward * 8 - v_right * 8 + v_up * -12;
81
82         if(self.rope_length < 0)
83                 self.rope_length = vlen(org - self.origin);
84
85         if(self.state == 1)
86         {
87                 pullspeed = cvar("g_balance_grapplehook_speed_pull");//2000;
88                 // speed the rope is pulled with
89
90                 rubberforce = cvar("g_balance_grapplehook_force_rubber");//2000;
91                 // force the rope will use if it is stretched
92
93                 rubberforce_overstretch = cvar("g_balance_grapplehook_force_rubber_overstretch");//1000;
94                 // force the rope will use if it is stretched
95
96                 minlength = cvar("g_balance_grapplehook_length_min");//100;
97                 // minimal rope length
98                 // if the rope goes below this length, it isn't pulled any more
99
100                 ropestretch = cvar("g_balance_grapplehook_stretch");//400;
101                 // if the rope is stretched by more than this amount, more rope is
102                 // given to you again
103
104                 ropeairfriction = cvar("g_balance_grapplehook_airfriction");//0.2
105                 // while hanging on the rope, this friction component will help you a
106                 // bit to control the rope
107
108                 dir = self.origin - org;
109                 dist = vlen(dir);
110                 dir = normalize(dir);
111
112                 if(cvar("g_grappling_hook_tarzan"))
113                 {
114                         newlength = self.rope_length;
115
116                         // first pull the rope...
117                         newlength = max(newlength - pullspeed * frametime, minlength);
118
119                         if(newlength < dist - ropestretch) // overstretched?
120                         {
121                                 newlength = dist - ropestretch;
122                                 if(self.owner.velocity * dir < 0) // only if not already moving in hook direction
123                                         self.owner.velocity = self.owner.velocity + frametime * dir * rubberforce_overstretch;
124                         }
125
126                         if(!self.owner.button5) // crouch key = don't pull
127                                 self.rope_length = newlength;
128
129                         // then pull the player
130                         spd = bound(0, (dist - self.rope_length) / ropestretch, 1);
131                         self.owner.velocity = self.owner.velocity * (1 - frametime * ropeairfriction);
132                         self.owner.velocity = self.owner.velocity + frametime * dir * spd * rubberforce;
133                 }
134                 else
135                 {
136                         end = self.origin - dir*50;
137                         dist = vlen(end - org);
138                         if(dist < 200)
139                                 spd = dist * (pullspeed / 200);
140                         else
141                                 spd = pullspeed;
142                         if(spd < 50)
143                                 spd = 0;
144                         self.owner.velocity = dir*spd;
145                         self.owner.movetype = MOVETYPE_FLY;
146                 }
147
148                 self.owner.flags = self.owner.flags - (self.owner.flags & FL_ONGROUND);
149
150                 org = org + dir*50; // get the beam out of the player's eyes
151         }
152
153         makevectors(self.angles);
154
155         te_beam(self, self.origin - v_forward * 4, org);
156 }
157
158 void GrapplingHookTouch (void)
159 {
160         if (other == self.owner)
161                 return;
162         // altered for Nexuiz
163         //else if (pointcontents (self.origin) == CONTENT_SKY)
164         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
165         {
166                 RemoveGrapplingHook(self.owner);
167                 return;
168         }
169
170         sound (self, CHAN_BODY, "weapons/hook_impact.wav", 1, ATTN_NORM);
171
172         self.state = 1;
173         self.think = GrapplingHookThink;
174         self.nextthink = time;
175         self.touch = SUB_Null;
176         self.velocity = '0 0 0';
177         self.movetype = MOVETYPE_NONE;
178         self.rope_length = -1;
179
180         //self.owner.disableclientprediction = TRUE;
181 }
182
183 void GrapplingHook_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
184 {
185         if(self.health > 0)
186         {
187                 self.health = self.health - damage;
188                 if (self.health <= 0)
189                 {
190                         if(attacker != self.owner)
191                         {
192                                 self.owner.pusher = attacker;
193                                 self.owner.pushltime = time + cvar("g_maxpushtime");
194                         }
195                         RemoveGrapplingHook(self.owner);
196                 }
197         }
198 }
199
200 void FireGrapplingHook (void)
201 {
202         local entity missile;
203         local vector org;
204
205         if(arena_roundbased)
206         if(time < warmup)
207                 return;
208
209         makevectors(self.v_angle);
210
211         sound (self, CHAN_WEAPON, "weapons/hook_fire.wav", 1, ATTN_NORM);
212         org = self.origin + self.view_ofs + v_forward * 8 - v_right * 8 + '0 0 -12';
213         te_customflash(org, 160, 0.2, '1 0 0');
214
215         missile = spawn ();
216         missile.owner = self;
217         self.hook = missile;
218         missile.classname = "grapplinghook";
219
220         missile.movetype = MOVETYPE_FLY;
221         missile.solid = SOLID_BBOX;
222
223         setmodel (missile, "models/hook.md3"); // precision set below
224         setsize (missile, '-3 -3 -3', '3 3 3');
225         setorigin (missile, org);
226
227         missile.state = 0; // not latched onto anything
228
229         missile.velocity = v_forward * cvar("g_balance_grapplehook_speed_fly");
230         W_SetupProjectileVelocity(missile);
231
232         missile.angles = vectoangles (missile.velocity);
233         //missile.glow_color = 250; // 244, 250
234         //missile.glow_size = 120;
235         missile.touch = GrapplingHookTouch;
236         missile.think = GrapplingHookThink;
237         missile.nextthink = time + 0.1;
238
239         missile.effects = /*EF_FULLBRIGHT | EF_ADDITIVE |*/ EF_LOWPRECISION;
240
241         missile.health = cvar("g_balance_grapplehook_health");//120
242         missile.event_damage = GrapplingHook_Damage;
243         missile.takedamage = DAMAGE_AIM;
244         missile.damageforcescale = 0;
245 }
246
247 void GrapplingHookFrame()
248 {
249         // this function has been modified for Nexuiz
250         if (self.button6 && cvar("g_grappling_hook"))
251         {
252                 if (!self.hook && self.hook_time <= time && !self.button6_pressed_before)
253                         FireGrapplingHook();
254         }
255         else
256         {
257                 if (self.hook)
258                         RemoveGrapplingHook(self);
259         }
260         self.button6_pressed_before = self.button6;
261         /*
262         // if I have no hook or it's not pulling yet, make sure I'm not flying!
263         if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
264         {
265                 self.movetype = MOVETYPE_WALK;
266         }
267         if(self.impulse == GRAPHOOK_FIRE && self.hook_time <= time && cvar("g_grappling_hook"))
268         {
269                 // fire hook
270                 FireGrapplingHook();
271                 return;
272         }
273         else if(self.hookimpulse == GRAPHOOK_RELEASE)
274         {
275                 // remove hook, reset movement type
276                 RemoveGrapplingHook(self);
277                 return;
278         }
279         */
280         /*else // make sure the player's movetype is correct
281         {
282                 //if(self.hook == world && self.movetype == MOVETYPE_FLY)
283                 if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
284                 {
285                         self.movetype = MOVETYPE_WALK;
286                 }
287         }*/
288         // note: The hook entity does the actual pulling
289 }
290
291 void SetGrappleHookBindings()
292 {
293         // this function has been modified for Nexuiz
294         // don't remove these lines! old server or demos coud overwrite the new aliases
295         stuffcmd(self, "alias +hook +button6\n");
296         stuffcmd(self, "alias -hook -button6\n");
297 }