data/qcsrc/server/g_hook.qc

   1 /*============================================
   2
   3       Wazat's Nexuiz Grappling Hook
   4
   5         Contact: Wazat1@gmail.com
   6
   7
   8 Installation instructions:
   9 --------------------------
  10
  11 1. Place hook.c in your gamec source directory with the other source files.
  12
  13 2. Add this line to the bottom of progs.src:
  14
  15 gamec/hook.c
  16
  17 3. Open defs.h and add these lines to the very bottom:
  18
  19 // Wazat's grappling hook
  20 .entity         hook;
  21 void GrapplingHookFrame();
  22 void RemoveGrapplingHook(entity pl);
  23 void SetGrappleHookBindings();
  24 // hook impulses
  25 float GRAPHOOK_FIRE             = 20;
  26 float GRAPHOOK_RELEASE          = 21;
  27 // (note: you can change the hook impulse #'s to whatever you please)
  28
  29 4. Open client.c and add this to the top of PutClientInServer():
  30
  31         RemoveGrapplingHook(self); // Wazat's Grappling Hook
  32
  33 5. Find ClientConnect() (in client.c) and add these lines to the bottom:
  34
  35         // Wazat's grappling hook
  36         SetGrappleHookBindings();
  37
  38 6. Still in client.c, find PlayerPreThink and add this line just above the call to W_WeaponFrame:
  39
  40         GrapplingHookFrame();
  41
  42 7. Build and test the mod.  You'll want to bind a key to "+hook" like this:
  43 bind ctrl "+hook"
  44
  45 And you should be done!
  46
  47
  48 ============================================*/
  49
  50 .float rope_length;
  51 .float button6_pressed_before;
  52
  53 void RemoveGrapplingHook(entity pl)
  54 {
  55         if(pl.hook == world)
  56                 return;
  57         remove(pl.hook);
  58         pl.hook = world;
  59         if(pl.movetype == MOVETYPE_FLY)
  60                 pl.movetype = MOVETYPE_WALK;
  61
  62         pl.hook_time = time + 0.0;
  63
  64         //pl.disableclientprediction = FALSE;
  65 }
  66
  67 void GrapplingHookThink()
  68 {
  69         float spd, dist, minlength, pullspeed, ropestretch, ropeairfriction, rubberforce, newlength, rubberforce_overstretch;
  70         vector dir, org, end;
  71         if(self.owner.health <= 0 || self.owner.hook != self)   // how did that happen?
  72         {                                                                                                               // well, better fix it anyway
  73                 remove(self);
  74                 return;
  75         }
  76
  77         self.nextthink = time;
  78
  79         makevectors(self.owner.v_angle);
  80         org = self.owner.origin + self.owner.view_ofs + v_forward * 8 - v_right * 8 + v_up * -12;
  81
  82         if(self.rope_length < 0)
  83                 self.rope_length = vlen(org - self.origin);
  84
  85         if(self.state == 1)
  86         {
  87                 pullspeed = cvar("g_balance_grapplehook_speed_pull");//2000;
  88                 // speed the rope is pulled with
  89
  90                 rubberforce = cvar("g_balance_grapplehook_force_rubber");//2000;
  91                 // force the rope will use if it is stretched
  92
  93                 rubberforce_overstretch = cvar("g_balance_grapplehook_force_rubber_overstretch");//1000;
  94                 // force the rope will use if it is stretched
  95
  96                 minlength = cvar("g_balance_grapplehook_length_min");//100;
  97                 // minimal rope length
  98                 // if the rope goes below this length, it isn't pulled any more
  99
 100                 ropestretch = cvar("g_balance_grapplehook_stretch");//400;
 101                 // if the rope is stretched by more than this amount, more rope is
 102                 // given to you again
 103
 104                 ropeairfriction = cvar("g_balance_grapplehook_airfriction");//0.2
 105                 // while hanging on the rope, this friction component will help you a
 106                 // bit to control the rope
 107
 108                 dir = self.origin - org;
 109                 dist = vlen(dir);
 110                 dir = normalize(dir);
 111
 112                 if(cvar("g_grappling_hook_tarzan"))
 113                 {
 114                         newlength = self.rope_length;
 115
 116                         // first pull the rope...
 117                         newlength = max(newlength - pullspeed * frametime, minlength);
 118
 119                         if(newlength < dist - ropestretch) // overstretched?
 120                         {
 121                                 newlength = dist - ropestretch;
 122                                 if(self.owner.velocity * dir < 0) // only if not already moving in hook direction
 123                                         self.owner.velocity = self.owner.velocity + frametime * dir * rubberforce_overstretch;
 124                         }
 125
 126                         if(!self.owner.button5) // crouch key = don't pull
 127                                 self.rope_length = newlength;
 128
 129                         // then pull the player
 130                         spd = bound(0, (dist - self.rope_length) / ropestretch, 1);
 131                         self.owner.velocity = self.owner.velocity * (1 - frametime * ropeairfriction);
 132                         self.owner.velocity = self.owner.velocity + frametime * dir * spd * rubberforce;
 133                 }
 134                 else
 135                 {
 136                         end = self.origin - dir*50;
 137                         dist = vlen(end - org);
 138                         if(dist < 200)
 139                                 spd = dist * (pullspeed / 200);
 140                         else
 141                                 spd = pullspeed;
 142                         if(spd < 50)
 143                                 spd = 0;
 144                         self.owner.velocity = dir*spd;
 145                         self.owner.movetype = MOVETYPE_FLY;
 146                 }
 147
 148                 self.owner.flags = self.owner.flags - (self.owner.flags & FL_ONGROUND);
 149
 150                 org = org + dir*50; // get the beam out of the player's eyes
 151         }
 152
 153         makevectors(self.angles_x * '-1 0 0' + self.angles_y * '0 1 0');
 154         te_beam(self, self.origin + v_forward * (-9), org);
 155 }
 156
 157 void GrapplingHookTouch (void)
 158 {
 159         if (other == self.owner)
 160                 return;
 161         // altered for Nexuiz
 162         //else if (pointcontents (self.origin) == CONTENT_SKY)
 163         else if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 164         {
 165                 RemoveGrapplingHook(self.owner);
 166                 return;
 167         }
 168
 169         sound (self, CHAN_BODY, "weapons/hook_impact.wav", 1, ATTN_NORM);
 170
 171         self.state = 1;
 172         self.think = GrapplingHookThink;
 173         self.nextthink = time;
 174         self.touch = SUB_Null;
 175         self.velocity = '0 0 0';
 176         self.movetype = MOVETYPE_NONE;
 177         self.rope_length = -1;
 178
 179         //self.owner.disableclientprediction = TRUE;
 180 }
 181
 182 void GrapplingHook_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 183 {
 184         if(self.health > 0)
 185         {
 186                 self.health = self.health - damage;
 187                 if (self.health <= 0)
 188                 {
 189                         if(attacker != self.owner)
 190                         {
 191                                 self.owner.pusher = attacker;
 192                                 self.owner.pushltime = time + cvar("g_maxpushtime");
 193                         }
 194                         RemoveGrapplingHook(self.owner);
 195                 }
 196         }
 197 }
 198
 199 void FireGrapplingHook (void)
 200 {
 201         local entity missile;
 202         local vector org;
 203
 204         if((arena_roundbased && time < warmup) || (time < restart_countdown))
 205                 return;
 206
 207         makevectors(self.v_angle);
 208
 209         sound (self, CHAN_WEAPON, "weapons/hook_fire.wav", 1, ATTN_NORM);
 210         org = self.origin + self.view_ofs + v_forward * 8 - v_right * 8 + '0 0 -12';
 211         te_customflash(org, 160, 0.2, '1 0 0');
 212
 213         missile = spawn ();
 214         missile.owner = self;
 215         self.hook = missile;
 216         missile.classname = "grapplinghook";
 217
 218         missile.movetype = MOVETYPE_FLY;
 219         missile.solid = SOLID_BBOX;
 220
 221         setmodel (missile, "models/hook.md3"); // precision set below
 222         setsize (missile, '-3 -3 -3', '3 3 3');
 223         setorigin (missile, org);
 224
 225         missile.state = 0; // not latched onto anything
 226
 227         missile.velocity = v_forward * cvar("g_balance_grapplehook_speed_fly");
 228         W_SetupProjectileVelocity(missile);
 229
 230         missile.angles = vectoangles (missile.velocity);
 231         //missile.glow_color = 250; // 244, 250
 232         //missile.glow_size = 120;
 233         missile.touch = GrapplingHookTouch;
 234         missile.think = GrapplingHookThink;
 235         missile.nextthink = time + 0.1;
 236
 237         missile.effects = /*EF_FULLBRIGHT | EF_ADDITIVE |*/ EF_LOWPRECISION;
 238
 239         missile.health = cvar("g_balance_grapplehook_health");//120
 240         missile.event_damage = GrapplingHook_Damage;
 241         missile.takedamage = DAMAGE_AIM;
 242         missile.damageforcescale = 0;
 243 }
 244
 245 void GrapplingHookFrame()
 246 {
 247         // this function has been modified for Nexuiz
 248         if (self.button6 && g_grappling_hook)
 249         {
 250                 if (!self.hook && self.hook_time <= time && !self.button6_pressed_before)
 251                         FireGrapplingHook();
 252         }
 253         else
 254         {
 255                 if (self.hook)
 256                         RemoveGrapplingHook(self);
 257         }
 258         self.button6_pressed_before = self.button6;
 259         /*
 260         // if I have no hook or it's not pulling yet, make sure I'm not flying!
 261         if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
 262         {
 263                 self.movetype = MOVETYPE_WALK;
 264         }
 265         if(self.impulse == GRAPHOOK_FIRE && self.hook_time <= time && g_grappling_hook)
 266         {
 267                 // fire hook
 268                 FireGrapplingHook();
 269                 return;
 270         }
 271         else if(self.hookimpulse == GRAPHOOK_RELEASE)
 272         {
 273                 // remove hook, reset movement type
 274                 RemoveGrapplingHook(self);
 275                 return;
 276         }
 277         */
 278         /*else // make sure the player's movetype is correct
 279         {
 280                 //if(self.hook == world && self.movetype == MOVETYPE_FLY)
 281                 if((self.hook == world || !self.hook.state) && self.movetype == MOVETYPE_FLY)
 282                 {
 283                         self.movetype = MOVETYPE_WALK;
 284                 }
 285         }*/
 286         // note: The hook entity does the actual pulling
 287 }
 288
 289 void SetGrappleHookBindings()
 290 {
 291         // this function has been modified for Nexuiz
 292         // don't remove these lines! old server or demos coud overwrite the new aliases
 293         stuffcmd(self, "alias +hook +button6\n");
 294         stuffcmd(self, "alias -hook -button6\n");
 295 }